qcsrc/server/mutators/gamemode_keyhunt.qc

   1 #define FOR_EACH_KH_KEY(v) for(v = kh_worldkeylist; v; v = v.kh_worldkeynext )
   2
   3 // #define KH_PLAYER_USE_ATTACHMENT
   4 // #define KH_PLAYER_USE_CARRIEDMODEL
   5
   6 #ifdef KH_PLAYER_USE_ATTACHMENT
   7 vector KH_PLAYER_ATTACHMENT_DIST_ROTATED = '0 -4 0';
   8 vector KH_PLAYER_ATTACHMENT_DIST = '4 0 0';
   9 vector KH_PLAYER_ATTACHMENT = '0 0 0';
  10 vector KH_PLAYER_ATTACHMENT_ANGLES = '0 0 0';
  11 string KH_PLAYER_ATTACHMENT_BONE = "";
  12 #else
  13 float KH_KEY_ZSHIFT = 22;
  14 float KH_KEY_XYDIST = 24;
  15 float KH_KEY_XYSPEED = 45;
  16 #endif
  17 float KH_KEY_WP_ZSHIFT = 20;
  18
  19 vector KH_KEY_MIN = '-10 -10 -46';
  20 vector KH_KEY_MAX = '10 10 3';
  21 float KH_KEY_BRIGHTNESS = 2;
  22
  23 string kh_Controller_Waitmsg;
  24 float kh_no_radar_circles;
  25
  26 // kh_state
  27 //     bits  0- 4: team of key 1, or 0 for no such key, or 30 for dropped, or 31 for self
  28 //     bits  5- 9: team of key 2, or 0 for no such key, or 30 for dropped, or 31 for self
  29 //     bits 10-14: team of key 3, or 0 for no such key, or 30 for dropped, or 31 for self
  30 //     bits 15-19: team of key 4, or 0 for no such key, or 30 for dropped, or 31 for self
  31 .float kh_state;
  32 .float siren_time;  //  time delay the siren
  33 //.float stuff_time;  //  time delay to stuffcmd a cvar
  34
  35 float kh_keystatus[17];
  36 //kh_keystatus[0] = status of dropped keys, kh_keystatus[1 - 16] = player #
  37 //replace 17 with cvar("maxplayers") or similar !!!!!!!!!
  38 //for(i = 0; i < maxplayers; ++i)
  39 //      kh_keystatus[i] = "0";
  40
  41 float kh_Team_ByID(float t)
  42 {
  43         if(t == 0) return COLOR_TEAM1;
  44         if(t == 1) return COLOR_TEAM2;
  45         if(t == 2) return COLOR_TEAM3;
  46         if(t == 3) return COLOR_TEAM4;
  47         return 0;
  48 }
  49
  50 entity kh_worldkeylist;
  51 .entity kh_worldkeynext;
  52 entity kh_controller;
  53 float kh_tracking_enabled;
  54 float kh_teams;
  55 float kh_interferemsg_time, kh_interferemsg_team;
  56 .entity kh_next, kh_prev; // linked list
  57 .float kh_droptime;
  58 .float kh_dropperteam;
  59 .entity kh_previous_owner;
  60 .float kh_previous_owner_playerid;
  61 .float kh_cp_duration;
  62
  63 string kh_sound_capture = "kh/capture.wav";
  64 string kh_sound_destroy = "kh/destroy.wav";
  65 string kh_sound_drop = "kh/drop.wav";
  66 string kh_sound_collect = "kh/collect.wav";
  67 string kh_sound_alarm = "kh/alarm.wav";  // the new siren/alarm
  68
  69 float kh_key_dropped, kh_key_carried;
  70
  71 float kh_KeyCarrier_waypointsprite_visible_for_player(entity e)  // runs all the time
  72 {
  73         if(!IS_PLAYER(e) || self.team != e.team)
  74                 if(!kh_tracking_enabled)
  75                         return FALSE;
  76
  77         return TRUE;
  78 }
  79
  80 float kh_Key_waypointsprite_visible_for_player(entity e) // ??
  81 {
  82         if(!kh_tracking_enabled)
  83                 return FALSE;
  84         if(!self.owner)
  85                 return TRUE;
  86         if(!self.owner.owner)
  87                 return TRUE;
  88         return FALSE;  // draw only when key is not owned
  89 }
  90
  91 void kh_update_state()
  92 {
  93         entity player;
  94         entity key;
  95         float s;
  96         float f;
  97
  98         s = 0;
  99         FOR_EACH_KH_KEY(key)
 100         {
 101                 if(key.owner)
 102                         f = key.team;
 103                 else
 104                         f = 30;
 105                 s |= pow(32, key.count) * f;
 106         }
 107
 108         FOR_EACH_CLIENT(player)
 109         {
 110                 player.kh_state = s;
 111         }
 112
 113         FOR_EACH_KH_KEY(key)
 114         {
 115                 if(key.owner)
 116                         key.owner.kh_state |= pow(32, key.count) * 31;
 117         }
 118         //print(ftos((nextent(world)).kh_state), "\n");
 119 }
 120
 121
 122
 123
 124 var kh_Think_t kh_Controller_Thinkfunc;
 125 void kh_Controller_SetThink(float t, string msg, float centerprint_duration, kh_Think_t func)  // runs occasionaly
 126 {
 127         kh_Controller_Thinkfunc = func;
 128         kh_controller.cnt = ceil(t);
 129         if(kh_Controller_Waitmsg != "")
 130                 strunzone(kh_Controller_Waitmsg);
 131         if(msg == "")
 132                 kh_Controller_Waitmsg = "";
 133         else
 134         {
 135                 kh_controller.kh_cp_duration = centerprint_duration;
 136                 kh_Controller_Waitmsg = strzone(msg);
 137         }
 138         if(t == 0)
 139                 kh_controller.nextthink = time; // force
 140 }
 141 void kh_Controller_SetThink_NoMsg(float t, kh_Think_t func)  // runs occasionaly
 142 {
 143         kh_Controller_SetThink(t, "", 0, func);
 144 }
 145
 146 void kh_Controller_Think()  // called a lot
 147 {
 148         entity e;
 149         if(intermission_running)
 150                 return;
 151         if(self.cnt > 0)
 152         {
 153                 if(kh_Controller_Waitmsg != "")
 154                 {
 155                         string s;
 156                         if(substring(kh_Controller_Waitmsg, strlen(kh_Controller_Waitmsg)-1, 1) == " ")
 157                                 s = strcat(kh_Controller_Waitmsg, ftos(self.cnt));
 158                         else
 159                                 s = kh_Controller_Waitmsg;
 160
 161                         //dprint(s, "\n");
 162
 163                         FOR_EACH_PLAYER(e)
 164                                 if(IS_REAL_CLIENT(e))
 165                                         Send_CSQC_Centerprint_Generic(e, CPID_KH_MSG, s, self.kh_cp_duration, 0);
 166                 }
 167                 self.cnt -= 1;
 168         }
 169         else if(self.cnt == 0)
 170         {
 171                 self.cnt -= 1;
 172                 kh_Controller_Thinkfunc();
 173         }
 174         self.nextthink = time + 1;
 175 }
 176
 177 // frags f: take from cvar * f
 178 // frags 0: no frags
 179 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)  // update the score when a key is captured
 180 {
 181         string s;
 182         if(intermission_running)
 183                 return;
 184
 185         if(frags_player)
 186                 UpdateFrags(player, frags_player);
 187
 188         if(key && key.owner && frags_owner)
 189                 UpdateFrags(key.owner, frags_owner);
 190
 191         if(!autocvar_sv_eventlog)  //output extra info to the console or text file
 192                 return;
 193
 194         s = strcat(":keyhunt:", what, ":", ftos(player.playerid), ":", ftos(frags_player));
 195
 196         if(key && key.owner)
 197                 s = strcat(s, ":", ftos(key.owner.playerid));
 198         else
 199                 s = strcat(s, ":0");
 200
 201         s = strcat(s, ":", ftos(frags_owner), ":");
 202
 203         if(key)
 204                 s = strcat(s, key.netname);
 205
 206         GameLogEcho(s);
 207 }
 208
 209 vector kh_AttachedOrigin(entity e)  // runs when a team captures the flag, it can run 2 or 3 times.
 210 {
 211         if(e.tag_entity)
 212         {
 213                 makevectors(e.tag_entity.angles);
 214                 return e.tag_entity.origin + e.origin_x * v_forward - e.origin_y * v_right + e.origin_z * v_up;
 215         }
 216         else
 217                 return e.origin;
 218 }
 219
 220 void kh_Key_Attach(entity key)  // runs when a player picks up a key and several times when a key is assigned to a player at the start of a round
 221 {
 222 #ifdef KH_PLAYER_USE_ATTACHMENT
 223         entity first;
 224         first = key.owner.kh_next;
 225         if(key == first)
 226         {
 227                 setattachment(key, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 228                 if(key.kh_next)
 229                 {
 230                         setattachment(key.kh_next, key, "");
 231                         setorigin(key, key.kh_next.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 232                         setorigin(key.kh_next, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 233                         key.kh_next.angles = '0 0 0';
 234                 }
 235                 else
 236                         setorigin(key, KH_PLAYER_ATTACHMENT);
 237                 key.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 238         }
 239         else
 240         {
 241                 setattachment(key, key.kh_prev, "");
 242                 if(key.kh_next)
 243                         setattachment(key.kh_next, key, "");
 244                 setorigin(key, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 245                 setorigin(first, first.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 246                 key.angles = '0 0 0';
 247         }
 248 #else
 249         setattachment(key, key.owner, "");
 250         setorigin(key, '0 0 1' * KH_KEY_ZSHIFT);  // fixing x, y in think
 251         key.angles_y -= key.owner.angles_y;
 252 #endif
 253         key.flags = 0;
 254         key.solid = SOLID_NOT;
 255         key.movetype = MOVETYPE_NONE;
 256         key.team = key.owner.team;
 257         key.nextthink = time;
 258         key.damageforcescale = 0;
 259         key.takedamage = DAMAGE_NO;
 260         key.modelindex = kh_key_carried;
 261 }
 262
 263 void kh_Key_Detach(entity key) // runs every time a key is dropped or lost. Runs several times times when all the keys are captured
 264 {
 265 #ifdef KH_PLAYER_USE_ATTACHMENT
 266         entity first;
 267         first = key.owner.kh_next;
 268         if(key == first)
 269         {
 270                 if(key.kh_next)
 271                 {
 272                         setattachment(key.kh_next, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 273                         setorigin(key.kh_next, key.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 274                         key.kh_next.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 275                 }
 276         }
 277         else
 278         {
 279                 if(key.kh_next)
 280                         setattachment(key.kh_next, key.kh_prev, "");
 281                 setorigin(first, first.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 282         }
 283         // in any case:
 284         setattachment(key, world, "");
 285         setorigin(key, key.owner.origin + '0 0 1' * (PL_MIN_z - KH_KEY_MIN_z));
 286         key.angles = key.owner.angles;
 287 #else
 288         setorigin(key, key.owner.origin + key.origin_z * '0 0 1');
 289         setattachment(key, world, "");
 290         key.angles_y += key.owner.angles_y;
 291 #endif
 292         key.flags = FL_ITEM;
 293         key.solid = SOLID_TRIGGER;
 294         key.movetype = MOVETYPE_TOSS;
 295         key.pain_finished = time + autocvar_g_balance_keyhunt_delay_return;
 296         key.damageforcescale = autocvar_g_balance_keyhunt_damageforcescale;
 297         key.takedamage = DAMAGE_YES;
 298         // let key.team stay
 299         key.modelindex = kh_key_dropped;
 300         key.kh_previous_owner = key.owner;
 301         key.kh_previous_owner_playerid = key.owner.playerid;
 302 }
 303
 304 void kh_Key_AssignTo(entity key, entity player)  // runs every time a key is picked up or assigned. Runs prior to kh_key_attach
 305 {
 306         entity k;
 307         float ownerteam0, ownerteam;
 308         if(key.owner == player)
 309                 return;
 310
 311         ownerteam0 = kh_Key_AllOwnedByWhichTeam();
 312
 313         if(key.owner)
 314         {
 315                 kh_Key_Detach(key);
 316
 317                 // remove from linked list
 318                 if(key.kh_next)
 319                         key.kh_next.kh_prev = key.kh_prev;
 320                 key.kh_prev.kh_next = key.kh_next;
 321                 key.kh_next = world;
 322                 key.kh_prev = world;
 323
 324                 if(key.owner.kh_next == world)
 325                 {
 326                         // No longer a key carrier
 327                         if(!kh_no_radar_circles)
 328                                 WaypointSprite_Ping(key.owner.waypointsprite_attachedforcarrier);
 329                         WaypointSprite_DetachCarrier(key.owner);
 330                 }
 331         }
 332
 333         key.owner = player;
 334
 335         if(player)
 336         {
 337                 // insert into linked list
 338                 key.kh_next = player.kh_next;
 339                 key.kh_prev = player;
 340                 player.kh_next = key;
 341                 if(key.kh_next)
 342                         key.kh_next.kh_prev = key;
 343
 344                 float i;
 345                 i = kh_keystatus[key.owner.playerid];
 346                         if(key.netname == "^1red key")
 347                                 i += 1;
 348                         if(key.netname == "^4blue key")
 349                                 i += 2;
 350                         if(key.netname == "^3yellow key")
 351                                 i += 4;
 352                         if(key.netname == "^6pink key")
 353                                 i += 8;
 354                 kh_keystatus[key.owner.playerid] = i;
 355
 356                 kh_Key_Attach(key);
 357
 358                 if(key.kh_next == world)
 359                 {
 360                         // player is now a key carrier
 361                         WaypointSprite_AttachCarrier("", player, RADARICON_FLAGCARRIER, colormapPaletteColor(player.team - 1, 0));
 362                         player.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_KeyCarrier_waypointsprite_visible_for_player;
 363                         WaypointSprite_UpdateRule(player.waypointsprite_attachedforcarrier, player.team, SPRITERULE_TEAMPLAY);
 364                         if(player.team == COLOR_TEAM1)
 365                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-red", "keycarrier-friend", "keycarrier-red");
 366                         else if(player.team == COLOR_TEAM2)
 367                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-blue", "keycarrier-friend", "keycarrier-blue");
 368                         else if(player.team == COLOR_TEAM3)
 369                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-yellow", "keycarrier-friend", "keycarrier-yellow");
 370                         else if(player.team == COLOR_TEAM4)
 371                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-pink", "keycarrier-friend", "keycarrier-pink");
 372                         if(!kh_no_radar_circles)
 373                                 WaypointSprite_Ping(player.waypointsprite_attachedforcarrier);
 374                 }
 375         }
 376
 377         // moved that here, also update if there's no player
 378         kh_update_state();
 379
 380         key.pusher = world;
 381
 382         ownerteam = kh_Key_AllOwnedByWhichTeam();
 383         if(ownerteam != ownerteam0)
 384         {
 385                 if(ownerteam != -1)
 386                 {
 387                         kh_interferemsg_time = time + 0.2;
 388                         kh_interferemsg_team = player.team;
 389
 390                         // audit all key carrier sprites, update them to RUN HERE
 391                         FOR_EACH_KH_KEY(k)
 392                         {
 393                                 if(k.owner)
 394                                         WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, k.owner.waypointsprite_attachedforcarrier.model1, "keycarrier-finish", k.owner.waypointsprite_attachedforcarrier.model3);
 395                         }
 396                 }
 397                 else
 398                 {
 399                         kh_interferemsg_time = 0;
 400
 401                         // audit all key carrier sprites, update them to RUN HERE
 402                         FOR_EACH_KH_KEY(k)
 403                         {
 404                                 if(k.owner)
 405                                         WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, k.owner.waypointsprite_attachedforcarrier.model1, "keycarrier-friend", k.owner.waypointsprite_attachedforcarrier.model3);
 406                         }
 407                 }
 408         }
 409 }
 410
 411 void kh_Key_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 412 {
 413         if(self.owner)
 414                 return;
 415         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 416         {
 417                 // touching lava, or hurt trigger
 418                 // what shall we do?
 419                 // immediately return is bad
 420                 // maybe start a shorter countdown?
 421         }
 422         if(vlen(force) <= 0)
 423                 return;
 424         if(time > self.pushltime)
 425                 if(IS_PLAYER(attacker))
 426                         self.team = attacker.team;
 427 }
 428
 429 void kh_Key_Collect(entity key, entity player)  //a player picks up a dropped key
 430 {
 431         sound(player, CH_TRIGGER, kh_sound_collect, VOL_BASE, ATTN_NORM);
 432
 433         if(key.kh_dropperteam != player.team)
 434         {
 435                 kh_Scores_Event(player, key, "collect", autocvar_g_balance_keyhunt_score_collect, 0);
 436                 PlayerScore_Add(player, SP_KH_PICKUPS, 1);
 437         }
 438         key.kh_dropperteam = 0;
 439         bprint(player.netname, "^7 picked up the ", key.netname, "\n");
 440
 441         kh_Key_AssignTo(key, player); // this also updates .kh_state
 442 }
 443
 444 void kh_Key_Touch()  // runs many, many times when a key has been dropped and can be picked up
 445 {
 446         if(intermission_running)
 447                 return;
 448
 449         if(self.owner) // already carried
 450                 return;
 451
 452         if(ITEM_TOUCH_NEEDKILL())
 453         {
 454                 // touching sky, or nodrop
 455                 // what shall we do?
 456                 // immediately return is bad
 457                 // maybe start a shorter countdown?
 458         }
 459
 460         if not(IS_PLAYER(other))
 461                 return;
 462         if(other.deadflag != DEAD_NO)
 463                 return;
 464         if(other == self.enemy)
 465                 if(time < self.kh_droptime + autocvar_g_balance_keyhunt_delay_collect)
 466                         return;  // you just dropped it!
 467         kh_Key_Collect(self, other);
 468 }
 469
 470 void kh_Key_Remove(entity key)  // runs after when all the keys have been collected or when a key has been dropped for more than X seconds
 471 {
 472         entity o;
 473         o = key.owner;
 474         kh_Key_AssignTo(key, world);
 475         if(o) // it was attached
 476                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 477         else // it was dropped
 478                 WaypointSprite_DetachCarrier(key);
 479
 480         // remove key from key list
 481         if (kh_worldkeylist == key)
 482                 kh_worldkeylist = kh_worldkeylist.kh_worldkeynext;
 483         else
 484         {
 485                 o = kh_worldkeylist;
 486                 while (o)
 487                 {
 488                         if (o.kh_worldkeynext == key)
 489                         {
 490                                 o.kh_worldkeynext = o.kh_worldkeynext.kh_worldkeynext;
 491                                 break;
 492                         }
 493                         o = o.kh_worldkeynext;
 494                 }
 495         }
 496
 497         remove(key);
 498
 499         kh_update_state();
 500 }
 501
 502 void kh_FinishRound()  // runs when a team captures the keys
 503 {
 504         // prepare next round
 505         kh_interferemsg_time = 0;
 506         entity key;
 507
 508         kh_no_radar_circles = TRUE;
 509         FOR_EACH_KH_KEY(key)
 510                 kh_Key_Remove(key);
 511         kh_no_radar_circles = FALSE;
 512
 513         kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round, "Round starts in ", 1, kh_StartRound);
 514 }
 515
 516 void kh_WinnerTeam(float teem)  // runs when a team wins
 517 {
 518         // all key carriers get some points
 519         vector firstorigin, lastorigin, midpoint;
 520         float first;
 521         entity key;
 522         float score;
 523         score = (kh_teams - 1) * autocvar_g_balance_keyhunt_score_capture;
 524         DistributeEvenly_Init(score, kh_teams);
 525         // twice the score for 3 team games, three times the score for 4 team games!
 526         // note: for a win by destroying the key, this should NOT be applied
 527         FOR_EACH_KH_KEY(key)
 528         {
 529                 float f;
 530                 f = DistributeEvenly_Get(1);
 531                 kh_Scores_Event(key.owner, key, "capture", f, 0);
 532                 PlayerTeamScore_Add(key.owner, SP_KH_CAPS, ST_KH_CAPS, 1);
 533         }
 534
 535         first = TRUE;
 536         FOR_EACH_KH_KEY(key)
 537                 if(key.owner.kh_next == key)
 538                 {
 539                         if(!first)
 540                                 bprint("^7, ");
 541                         bprint(key.owner.netname);
 542                         first = FALSE;
 543                 }
 544         bprint("^7 captured the keys for the ", ColoredTeamName(teem), "\n");
 545
 546         first = TRUE;
 547         midpoint = '0 0 0';
 548         firstorigin = '0 0 0';
 549         lastorigin = '0 0 0';
 550         FOR_EACH_KH_KEY(key)
 551         {
 552                 vector thisorigin;
 553
 554                 thisorigin = kh_AttachedOrigin(key);
 555                 //dprint("Key origin: ", vtos(thisorigin), "\n");
 556                 midpoint += thisorigin;
 557
 558                 if(!first)
 559                         te_lightning2(world, lastorigin, thisorigin);
 560                 lastorigin = thisorigin;
 561                 if(first)
 562                         firstorigin = thisorigin;
 563                 first = FALSE;
 564         }
 565         if(kh_teams > 2)
 566         {
 567                 te_lightning2(world, lastorigin, firstorigin);
 568         }
 569         midpoint = midpoint * (1 / kh_teams);
 570         te_customflash(midpoint, 1000, 1, TeamColor(teem) * 0.5 + '0.5 0.5 0.5');  // make the color >=0.5 in each component
 571
 572         play2all(kh_sound_capture);
 573         kh_FinishRound();
 574 }
 575
 576 void kh_LoserTeam(float teem, entity lostkey)  // runs when a player pushes a flag carrier off the map
 577 {
 578         entity player, key, attacker;
 579         float players;
 580         float keys;
 581         float f;
 582
 583         attacker = world;
 584         if(lostkey.pusher)
 585                 if(lostkey.pusher.team != teem)
 586                         if(IS_PLAYER(lostkey.pusher))
 587                                 attacker = lostkey.pusher;
 588
 589         players = keys = 0;
 590
 591         if(attacker)
 592         {
 593                 if(lostkey.kh_previous_owner)
 594                         kh_Scores_Event(lostkey.kh_previous_owner, world, "pushed", 0, -autocvar_g_balance_keyhunt_score_push);
 595                         // don't actually GIVE him the -nn points, just log
 596                 kh_Scores_Event(attacker, world, "push", autocvar_g_balance_keyhunt_score_push, 0);
 597                 PlayerScore_Add(attacker, SP_KH_PUSHES, 1);
 598                 centerprint(attacker, "Your push is the best!");
 599                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "^7 when ", attacker.netname, "^7 came\n");
 600         }
 601         else
 602         {
 603                 float of, fragsleft, i, j, thisteam;
 604                 of = autocvar_g_balance_keyhunt_score_destroyed_ownfactor;
 605
 606                 FOR_EACH_PLAYER(player)
 607                         if(player.team != teem)
 608                                 ++players;
 609
 610                 FOR_EACH_KH_KEY(key)
 611                         if(key.owner && key.team != teem)
 612                                 ++keys;
 613
 614                 if(lostkey.kh_previous_owner)
 615                         kh_Scores_Event(lostkey.kh_previous_owner, world, "destroyed", 0, -autocvar_g_balance_keyhunt_score_destroyed);
 616                         // don't actually GIVE him the -nn points, just log
 617
 618                 if(lostkey.kh_previous_owner.playerid == lostkey.kh_previous_owner_playerid)
 619                         PlayerScore_Add(lostkey.kh_previous_owner, SP_KH_DESTROYS, 1);
 620
 621                 DistributeEvenly_Init(autocvar_g_balance_keyhunt_score_destroyed, keys * of + players);
 622
 623                 FOR_EACH_KH_KEY(key)
 624                         if(key.owner && key.team != teem)
 625                         {
 626                                 f = DistributeEvenly_Get(of);
 627                                 kh_Scores_Event(key.owner, world, "destroyed_holdingkey", f, 0);
 628                         }
 629
 630                 fragsleft = DistributeEvenly_Get(players);
 631
 632                 // Now distribute these among all other teams...
 633                 j = kh_teams - 1;
 634                 for(i = 0; i < kh_teams; ++i)
 635                 {
 636                         thisteam = kh_Team_ByID(i);
 637                         if(thisteam == teem) // bad boy, no cookie - this WILL happen
 638                                 continue;
 639
 640                         players = 0;
 641                         FOR_EACH_PLAYER(player)
 642                                 if(player.team == thisteam)
 643                                         ++players;
 644
 645                         DistributeEvenly_Init(fragsleft, j);
 646                         fragsleft = DistributeEvenly_Get(j - 1);
 647                         DistributeEvenly_Init(DistributeEvenly_Get(1), players);
 648
 649                         FOR_EACH_PLAYER(player)
 650                                 if(player.team == thisteam)
 651                                 {
 652                                         f = DistributeEvenly_Get(1);
 653                                         kh_Scores_Event(player, world, "destroyed", f, 0);
 654                                 }
 655
 656                         --j;
 657                 }
 658
 659                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 660         }
 661         play2all(kh_sound_destroy);
 662         te_tarexplosion(lostkey.origin);
 663
 664         kh_FinishRound();
 665 }
 666
 667 void kh_Key_Think()  // runs all the time
 668 {
 669         entity head;
 670         //entity player;  // needed by FOR_EACH_PLAYER
 671
 672         if(intermission_running)
 673                 return;
 674
 675         if(self.owner)
 676         {
 677 #ifndef KH_PLAYER_USE_ATTACHMENT
 678                 makevectors('0 1 0' * (self.cnt + mod(time, 360) * KH_KEY_XYSPEED));
 679                 setorigin(self, v_forward * KH_KEY_XYDIST + '0 0 1' * self.origin_z);
 680 #endif
 681         }
 682
 683         // if in nodrop or time over, end the round
 684         if(!self.owner)
 685                 if(time > self.pain_finished)
 686                         kh_LoserTeam(self.team, self);
 687
 688         if(self.owner)
 689         if(kh_Key_AllOwnedByWhichTeam() != -1)
 690         {
 691                 if(self.siren_time < time)
 692                 {
 693                         sound(self.owner, CH_TRIGGER, kh_sound_alarm, VOL_BASE, ATTN_NORM);  // play a simple alarm
 694                         self.siren_time = time + 2.5;  // repeat every 2.5 seconds
 695                 }
 696
 697                 entity key;
 698                 vector p;
 699                 p = self.owner.origin;
 700                 FOR_EACH_KH_KEY(key)
 701                         if(vlen(key.owner.origin - p) > autocvar_g_balance_keyhunt_maxdist)
 702                                 goto not_winning;
 703                 kh_WinnerTeam(self.team);
 704 :not_winning
 705         }
 706
 707         if(kh_interferemsg_time && time > kh_interferemsg_time)
 708         {
 709                 kh_interferemsg_time = 0;
 710                 FOR_EACH_PLAYER(head)
 711                 {
 712                         if(head.team == kh_interferemsg_team)
 713                                 if(head.kh_next)
 714                                         Send_CSQC_Centerprint_Generic(head, CPID_KH_MSG, "All keys are in your team's hands!\n\nMeet the other key carriers ^1NOW^7!", 0, 0);
 715                                 else
 716                                         Send_CSQC_Centerprint_Generic(head, CPID_KH_MSG, "All keys are in your team's hands!\n\nHelp the key carriers to meet!", 0, 0);
 717                         else
 718                                 Send_CSQC_Centerprint_Generic(head, CPID_KH_MSG, strcat("All keys are in the ", ColoredTeamName(kh_interferemsg_team), "^7's hands!\n\nInterfere ^1NOW^7!"), 0, 0);
 719                 }
 720         }
 721
 722         self.nextthink = time + 0.05;
 723 }
 724
 725 void key_reset()
 726 {
 727         kh_Key_AssignTo(self, world);
 728         kh_Key_Remove(self);
 729 }
 730
 731 string STR_ITEM_KH_KEY = "item_kh_key";
 732 void kh_Key_Spawn(entity initial_owner, float angle, float i)  // runs every time a new flag is created, ie after all the keys have been collected
 733 {
 734         entity key;
 735         key = spawn();
 736         key.count = i;
 737         key.classname = STR_ITEM_KH_KEY;
 738         key.touch = kh_Key_Touch;
 739         key.think = kh_Key_Think;
 740         key.nextthink = time;
 741         key.items = IT_KEY1 | IT_KEY2;
 742         key.cnt = angle;
 743         key.angles = '0 360 0' * random();
 744         key.event_damage = kh_Key_Damage;
 745         key.takedamage = DAMAGE_YES;
 746         key.modelindex = kh_key_dropped;
 747         key.model = "key";
 748         key.kh_dropperteam = 0;
 749         key.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 750         setsize(key, KH_KEY_MIN, KH_KEY_MAX);
 751         key.colormod = TeamColor(initial_owner.team) * KH_KEY_BRIGHTNESS;
 752         key.reset = key_reset;
 753
 754         switch(initial_owner.team)
 755         {
 756                 case COLOR_TEAM1:
 757                         key.netname = "^1red key";
 758                         break;
 759                 case COLOR_TEAM2:
 760                         key.netname = "^4blue key";
 761                         break;
 762                 case COLOR_TEAM3:
 763                         key.netname = "^3yellow key";
 764                         break;
 765                 case COLOR_TEAM4:
 766                         key.netname = "^6pink key";
 767                         break;
 768                 default:
 769                         key.netname = "NETGIER key";
 770                         break;
 771         }
 772
 773         // link into key list
 774         key.kh_worldkeynext = kh_worldkeylist;
 775         kh_worldkeylist = key;
 776
 777         centerprint(initial_owner, strcat("You are starting with the ", key.netname, "\n"));  // message to player at start of round
 778
 779         WaypointSprite_Spawn("key-dropped", 0, 0, key, '0 0 1' * KH_KEY_WP_ZSHIFT, world, key.team, key, waypointsprite_attachedforcarrier, FALSE, RADARICON_FLAG, '0 1 1');
 780         key.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_Key_waypointsprite_visible_for_player;
 781
 782         kh_Key_AssignTo(key, initial_owner);
 783 }
 784
 785 // -1 when no team completely owns all keys yet
 786 float kh_Key_AllOwnedByWhichTeam()  // constantly called. check to see if all the keys are owned by the same team
 787 {
 788         entity key;
 789         float teem;
 790         float keys;
 791
 792         teem = -1;
 793         keys = kh_teams;
 794         FOR_EACH_KH_KEY(key)
 795         {
 796                 if(!key.owner)
 797                         return -1;
 798                 if(teem == -1)
 799                         teem = key.team;
 800                 else if(teem != key.team)
 801                         return -1;
 802                 --keys;
 803         }
 804         if(keys != 0)
 805                 return -1;
 806         return teem;
 807 }
 808
 809 void kh_Key_DropOne(entity key)
 810 {
 811         // prevent collecting this one for some time
 812         entity player;
 813         player = key.owner;
 814
 815         key.kh_droptime = time;
 816         key.enemy = player;
 817
 818         kh_Scores_Event(player, key, "dropkey", 0, 0);
 819         PlayerScore_Add(player, SP_KH_LOSSES, 1);
 820         bprint(player.netname, "^7 dropped the ", key.netname, "\n");
 821         kh_Key_AssignTo(key, world);
 822         makevectors(player.v_angle);
 823         key.velocity = W_CalculateProjectileVelocity(player.velocity, autocvar_g_balance_keyhunt_throwvelocity * v_forward, FALSE);
 824         key.pusher = world;
 825         key.pushltime = time + autocvar_g_balance_keyhunt_protecttime;
 826         key.kh_dropperteam = key.team;
 827
 828         sound(player, CH_TRIGGER, kh_sound_drop, VOL_BASE, ATTN_NORM);
 829 }
 830
 831 void kh_Key_DropAll(entity player, float suicide) // runs whenever a player dies
 832 {
 833         entity key;
 834         entity mypusher;
 835         if(player.kh_next)
 836         {
 837                 mypusher = world;
 838                 if(player.pusher)
 839                         if(time < player.pushltime)
 840                                 mypusher = player.pusher;
 841                 while((key = player.kh_next))
 842                 {
 843                         kh_Scores_Event(player, key, "losekey", 0, 0);
 844                         PlayerScore_Add(player, SP_KH_LOSSES, 1);
 845                         bprint(player.netname, "^7 died and lost the ", key.netname, "\n");
 846                         kh_Key_AssignTo(key, world);
 847                         makevectors('-1 0 0' * (45 + 45 * random()) + '0 360 0' * random());
 848                         key.velocity = W_CalculateProjectileVelocity(player.velocity, autocvar_g_balance_keyhunt_dropvelocity * v_forward, FALSE);
 849                         key.pusher = mypusher;
 850                         key.pushltime = time + autocvar_g_balance_keyhunt_protecttime;
 851                         if(suicide)
 852                                 key.kh_dropperteam = player.team;
 853                 }
 854                 sound(player, CH_TRIGGER, kh_sound_drop, VOL_BASE, ATTN_NORM);
 855         }
 856 }
 857
 858 string kh_CheckEnoughPlayers()  // checks enough player are present, runs after every completed round
 859 {
 860         float i, players, teem;
 861         entity player;
 862         string result;
 863         result = "";
 864
 865         // find a random player per team
 866         for(i = 0; i < kh_teams; ++i)
 867         {
 868                 teem = kh_Team_ByID(i);
 869                 players = 0;
 870                 FOR_EACH_PLAYER(player)
 871                         if(player.deadflag == DEAD_NO)
 872                                 if(!player.BUTTON_CHAT)
 873                                         if(player.team == teem)
 874                                                 ++players;
 875                 if(players == 0)
 876                 {
 877                         if(result != "")
 878                                 result = strcat(result, ", ");
 879                         result = strcat(result, ColoredTeamName(teem));
 880                 }
 881         }
 882         return result;
 883 }
 884
 885 void kh_WaitForPlayers()  // delay start of the round until enough players are present
 886 {
 887         string teams_missing;
 888
 889         if(time < game_starttime)
 890         {
 891                 kh_Controller_SetThink_NoMsg(game_starttime - time + 0.1, kh_WaitForPlayers);
 892                 return;
 893         }
 894
 895         teams_missing = kh_CheckEnoughPlayers();
 896         if(teams_missing == "")
 897                 kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round, "Round starts in ", 1, kh_StartRound);
 898         else
 899                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), -1, kh_WaitForPlayers);
 900 }
 901
 902 void kh_EnableTrackingDevice()  // runs after each round
 903 {
 904         entity player;
 905
 906         FOR_EACH_PLAYER(player)
 907                 if(IS_REAL_CLIENT(player))
 908                         Send_CSQC_Centerprint_Generic_Expire(player, CPID_KH_MSG);
 909
 910         kh_tracking_enabled = TRUE;
 911 }
 912
 913 void kh_StartRound()  // runs at the start of each round
 914 {
 915         string teams_missing;
 916         float i, players, teem;
 917         entity player;
 918
 919         if(time < game_starttime)
 920         {
 921                 kh_Controller_SetThink_NoMsg(game_starttime - time + 0.1, kh_WaitForPlayers);
 922                 return;
 923         }
 924
 925         teams_missing = kh_CheckEnoughPlayers();
 926         if(teams_missing != "")
 927         {
 928                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), -1, kh_WaitForPlayers);
 929                 return;
 930         }
 931
 932         FOR_EACH_PLAYER(player)
 933                 if(IS_REAL_CLIENT(player))
 934                         Send_CSQC_Centerprint_Generic_Expire(player, CPID_KH_MSG);
 935
 936         for(i = 0; i < kh_teams; ++i)
 937         {
 938                 teem = kh_Team_ByID(i);
 939                 players = 0;
 940                 entity my_player = world;
 941                 FOR_EACH_PLAYER(player)
 942                         if(player.deadflag == DEAD_NO)
 943                                 if(!player.BUTTON_CHAT)
 944                                         if(player.team == teem)
 945                                         {
 946                                                 ++players;
 947                                                 if(random() * players <= 1)
 948                                                         my_player = player;
 949                                         }
 950                 kh_Key_Spawn(my_player, 360 * i / kh_teams, i);
 951         }
 952
 953         kh_tracking_enabled = FALSE;
 954         kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_tracking, "Scanning frequency range...", -1, kh_EnableTrackingDevice);
 955 }
 956
 957 float kh_HandleFrags(entity attacker, entity targ, float f)  // adds to the player score
 958 {
 959         if(attacker == targ)
 960                 return f;
 961
 962         if(targ.kh_next)
 963         {
 964                 if(attacker.team == targ.team)
 965                 {
 966                         entity k;
 967                         float nk;
 968                         nk = 0;
 969                         for(k = targ.kh_next; k != world; k = k.kh_next)
 970                                 ++nk;
 971                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", -nk * autocvar_g_balance_keyhunt_score_collect, 0);
 972                 }
 973                 else
 974                 {
 975                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", autocvar_g_balance_keyhunt_score_carrierfrag-1, 0);
 976                         PlayerScore_Add(attacker, SP_KH_KCKILLS, 1);
 977                         // the frag gets added later
 978                 }
 979         }
 980
 981         return f;
 982 }
 983
 984 void kh_Initialize()  // sets up th KH environment
 985 {
 986         precache_sound(kh_sound_capture);
 987         precache_sound(kh_sound_destroy);
 988         precache_sound(kh_sound_drop);
 989         precache_sound(kh_sound_collect);
 990         precache_sound(kh_sound_alarm);  // the new siren
 991
 992 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 993         precache_model("models/keyhunt/key-carried.md3");
 994 #endif
 995         precache_model("models/keyhunt/key.md3");
 996
 997         // setup variables
 998         kh_teams = autocvar_g_keyhunt_teams_override;
 999         if(kh_teams < 2)
1000                 kh_teams = autocvar_g_keyhunt_teams;
1001         kh_teams = bound(2, kh_teams, 4);
1002
1003         // make a KH entity for controlling the game
1004         kh_controller = spawn();
1005         kh_controller.think = kh_Controller_Think;
1006         kh_Controller_SetThink_NoMsg(0, kh_WaitForPlayers);
1007
1008         setmodel(kh_controller, "models/keyhunt/key.md3");
1009         kh_key_dropped = kh_controller.modelindex;
1010         /*
1011         dprint(vtos(kh_controller.mins));
1012         dprint(vtos(kh_controller.maxs));
1013         dprint("\n");
1014         */
1015 #ifdef KH_PLAYER_USE_CARRIEDMODEL
1016         setmodel(kh_controller, "models/keyhunt/key-carried.md3");
1017         kh_key_carried = kh_controller.modelindex;
1018 #else
1019         kh_key_carried = kh_key_dropped;
1020 #endif
1021
1022         kh_controller.model = "";
1023         kh_controller.modelindex = 0;
1024
1025         addstat(STAT_KH_KEYS, AS_INT, kh_state);
1026
1027         ScoreRules_kh(kh_teams);
1028 }
1029
1030 void kh_finalize()
1031 {
1032         // to be called before intermission
1033         kh_FinishRound();
1034         remove(kh_controller);
1035         kh_controller = world;
1036 }
1037
1038 // register this as a mutator
1039
1040 MUTATOR_HOOKFUNCTION(kh_Key_DropAll)
1041 {
1042         kh_Key_DropAll(self, TRUE);
1043         return 0;
1044 }
1045
1046 MUTATOR_HOOKFUNCTION(kh_PlayerDies)
1047 {
1048         if(self == other)
1049                 kh_Key_DropAll(self, TRUE);
1050         else if(IS_PLAYER(other))
1051                 kh_Key_DropAll(self, FALSE);
1052         else
1053                 kh_Key_DropAll(self, TRUE);
1054         return 0;
1055 }
1056
1057 MUTATOR_HOOKFUNCTION(kh_GiveFragsForKill)
1058 {
1059         frag_score = kh_HandleFrags(frag_attacker, frag_target, frag_score);
1060         return 0;
1061 }
1062
1063 MUTATOR_HOOKFUNCTION(kh_finalize)
1064 {
1065         kh_finalize();
1066         return 0;
1067 }
1068
1069 MUTATOR_HOOKFUNCTION(kh_GetTeamCount)
1070 {
1071         ret_float = kh_teams;
1072         return 0;
1073 }
1074
1075 MUTATOR_HOOKFUNCTION(kh_SpectateCopy)
1076 {
1077         self.kh_state = other.kh_state;
1078         return 0;
1079 }
1080
1081 MUTATOR_HOOKFUNCTION(kh_PlayerUseKey)
1082 {
1083         if(MUTATOR_RETURNVALUE == 0)
1084         {
1085                 entity k;
1086                 k = self.kh_next;
1087                 if(k)
1088                 {
1089                         kh_Key_DropOne(k);
1090                         return 1;
1091                 }
1092         }
1093         return 0;
1094 }
1095
1096 MUTATOR_DEFINITION(gamemode_keyhunt)
1097 {
1098         MUTATOR_HOOK(MakePlayerObserver, kh_Key_DropAll, CBC_ORDER_ANY);
1099         MUTATOR_HOOK(ClientDisconnect, kh_Key_DropAll, CBC_ORDER_ANY);
1100         MUTATOR_HOOK(PlayerDies, kh_PlayerDies, CBC_ORDER_ANY);
1101         MUTATOR_HOOK(GiveFragsForKill, kh_GiveFragsForKill, CBC_ORDER_FIRST);
1102         MUTATOR_HOOK(MatchEnd, kh_finalize, CBC_ORDER_ANY);
1103         MUTATOR_HOOK(GetTeamCount, kh_GetTeamCount, CBC_ORDER_EXCLUSIVE);
1104         MUTATOR_HOOK(SpectateCopy, kh_SpectateCopy, CBC_ORDER_ANY);
1105         MUTATOR_HOOK(PlayerUseKey, kh_PlayerUseKey, CBC_ORDER_ANY);
1106
1107         MUTATOR_ONADD
1108         {
1109                 if(time > 1) // game loads at time 1
1110                         error("This is a game type and it cannot be added at runtime.");
1111                 kh_Initialize();
1112         }
1113
1114         MUTATOR_ONROLLBACK_OR_REMOVE
1115         {
1116                 // we actually cannot roll back kh_Initialize here
1117                 // BUT: we don't need to! If this gets called, adding always
1118                 // succeeds.
1119         }
1120
1121         MUTATOR_ONREMOVE
1122         {
1123                 print("This is a game type and it cannot be removed at runtime.");
1124                 return -1;
1125         }
1126
1127         return 0;
1128 }