qcsrc/server/mutators/mutator/gamemode_ca.qc

   1 #ifndef GAMEMODE_CA_H
   2 #define GAMEMODE_CA_H
   3
   4 int autocvar_g_ca_point_limit;
   5 int autocvar_g_ca_point_leadlimit;
   6 float autocvar_g_ca_round_timelimit;
   7 bool autocvar_g_ca_team_spawns;
   8 int autocvar_g_ca_teams;
   9 int autocvar_g_ca_teams_override;
  10 float autocvar_g_ca_warmup;
  11
  12
  13 int ca_teams;
  14 bool allowed_to_spawn;
  15
  16 const int ST_CA_ROUNDS = 1;
  17
  18 bool CA_CheckTeams();
  19 bool CA_CheckWinner();
  20 void CA_RoundStart();
  21 bool ca_isEliminated(entity e);
  22
  23 REGISTER_MUTATOR(ca, false)
  24 {
  25         MUTATOR_ONADD
  26         {
  27                 // game loads at time 1
  28                 if (time > 1) error("This is a game type and it cannot be added at runtime.");
  29
  30                 allowed_to_spawn = true;
  31
  32                 ca_teams = autocvar_g_ca_teams_override;
  33                 if (ca_teams < 2) ca_teams = autocvar_g_ca_teams;
  34                 ca_teams = bound(2, ca_teams, 4);
  35                 ret_float = ca_teams;
  36
  37         ScoreRules_basics(ca_teams, SFL_SORT_PRIO_PRIMARY, 0, true);
  38         ScoreInfo_SetLabel_TeamScore(ST_CA_ROUNDS, "rounds", SFL_SORT_PRIO_PRIMARY);
  39         ScoreRules_basics_end();
  40
  41                 round_handler_Spawn(CA_CheckTeams, CA_CheckWinner, CA_RoundStart);
  42                 round_handler_Init(5, autocvar_g_ca_warmup, autocvar_g_ca_round_timelimit);
  43
  44                 EliminatedPlayers_Init(ca_isEliminated);
  45
  46                 ActivateTeamplay();
  47                 SetLimits(autocvar_g_ca_point_limit, autocvar_g_ca_point_leadlimit, -1, -1);
  48
  49                 if (autocvar_g_ca_team_spawns)
  50                         have_team_spawns = -1; // request team spawns
  51         }
  52
  53         MUTATOR_ONREMOVE
  54         {
  55                 LOG_INFO("This is a game type and it cannot be removed at runtime.");
  56                 return -1;
  57         }
  58
  59         return 0;
  60 }
  61
  62 // should be removed in the future, as other code should not have to care
  63 .float caplayer; // 0.5 if scheduled to join the next round
  64 #endif
  65
  66 #ifdef IMPLEMENTATION
  67 float autocvar_g_ca_damage2score_multiplier;
  68 bool autocvar_g_ca_spectate_enemies;
  69
  70 void CA_count_alive_players()
  71 {
  72         total_players = redalive = bluealive = yellowalive = pinkalive = 0;
  73         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
  74                 switch(it.team)
  75                 {
  76                         case NUM_TEAM_1: ++total_players; if(!IS_DEAD(it)) ++redalive; break;
  77                         case NUM_TEAM_2: ++total_players; if(!IS_DEAD(it)) ++bluealive; break;
  78                         case NUM_TEAM_3: ++total_players; if(!IS_DEAD(it)) ++yellowalive; break;
  79                         case NUM_TEAM_4: ++total_players; if(!IS_DEAD(it)) ++pinkalive; break;
  80                 }
  81         ));
  82         FOREACH_CLIENT(IS_REAL_CLIENT(it), LAMBDA(
  83                 it.redalive_stat = redalive;
  84                 it.bluealive_stat = bluealive;
  85                 it.yellowalive_stat = yellowalive;
  86                 it.pinkalive_stat = pinkalive;
  87         ));
  88 }
  89
  90 float CA_GetWinnerTeam()
  91 {
  92         float winner_team = 0;
  93         if(redalive >= 1)
  94                 winner_team = NUM_TEAM_1;
  95         if(bluealive >= 1)
  96         {
  97                 if(winner_team) return 0;
  98                 winner_team = NUM_TEAM_2;
  99         }
 100         if(yellowalive >= 1)
 101         {
 102                 if(winner_team) return 0;
 103                 winner_team = NUM_TEAM_3;
 104         }
 105         if(pinkalive >= 1)
 106         {
 107                 if(winner_team) return 0;
 108                 winner_team = NUM_TEAM_4;
 109         }
 110         if(winner_team)
 111                 return winner_team;
 112         return -1; // no player left
 113 }
 114
 115 #define CA_ALIVE_TEAMS() ((redalive > 0) + (bluealive > 0) + (yellowalive > 0) + (pinkalive > 0))
 116 #define CA_ALIVE_TEAMS_OK() (CA_ALIVE_TEAMS() == ca_teams)
 117 float CA_CheckWinner()
 118 {
 119         if(round_handler_GetEndTime() > 0 && round_handler_GetEndTime() - time <= 0)
 120         {
 121                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_ROUND_OVER);
 122                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ROUND_OVER);
 123                 allowed_to_spawn = false;
 124                 round_handler_Init(5, autocvar_g_ca_warmup, autocvar_g_ca_round_timelimit);
 125                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(nades_Clear(it)));
 126                 return 1;
 127         }
 128
 129         CA_count_alive_players();
 130         if(CA_ALIVE_TEAMS() > 1)
 131                 return 0;
 132
 133         int winner_team = CA_GetWinnerTeam();
 134         if(winner_team > 0)
 135         {
 136                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, APP_TEAM_NUM(winner_team, CENTER_ROUND_TEAM_WIN));
 137                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_NUM(winner_team, INFO_ROUND_TEAM_WIN));
 138                 TeamScore_AddToTeam(winner_team, ST_CA_ROUNDS, +1);
 139         }
 140         else if(winner_team == -1)
 141         {
 142                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_ROUND_TIED);
 143                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ROUND_TIED);
 144         }
 145
 146         allowed_to_spawn = false;
 147         round_handler_Init(5, autocvar_g_ca_warmup, autocvar_g_ca_round_timelimit);
 148
 149         FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(nades_Clear(it)));
 150
 151         return 1;
 152 }
 153
 154 void CA_RoundStart()
 155 {
 156     allowed_to_spawn = boolean(warmup_stage);
 157 }
 158
 159 bool CA_CheckTeams()
 160 {
 161         static int prev_missing_teams_mask;
 162         allowed_to_spawn = true;
 163         CA_count_alive_players();
 164         if(CA_ALIVE_TEAMS_OK())
 165         {
 166                 if(prev_missing_teams_mask > 0)
 167                         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, CPID_MISSING_TEAMS);
 168                 prev_missing_teams_mask = -1;
 169                 return true;
 170         }
 171         if(total_players == 0)
 172         {
 173                 if(prev_missing_teams_mask > 0)
 174                         Kill_Notification(NOTIF_ALL, world, MSG_CENTER, CPID_MISSING_TEAMS);
 175                 prev_missing_teams_mask = -1;
 176                 return false;
 177         }
 178         int missing_teams_mask = (!redalive) + (!bluealive) * 2;
 179         if(ca_teams >= 3) missing_teams_mask += (!yellowalive) * 4;
 180         if(ca_teams >= 4) missing_teams_mask += (!pinkalive) * 8;
 181         if(prev_missing_teams_mask != missing_teams_mask)
 182         {
 183                 Send_Notification(NOTIF_ALL, world, MSG_CENTER, CENTER_MISSING_TEAMS, missing_teams_mask);
 184                 prev_missing_teams_mask = missing_teams_mask;
 185         }
 186         return false;
 187 }
 188
 189 bool ca_isEliminated(entity e)
 190 {
 191         if(e.caplayer == 1 && (IS_DEAD(e) || e.frags == FRAGS_LMS_LOSER))
 192                 return true;
 193         if(e.caplayer == 0.5)
 194                 return true;
 195         return false;
 196 }
 197
 198 /** Returns next available player to spectate if g_ca_spectate_enemies == 0 */
 199 entity CA_SpectateNext(entity player, entity start)
 200 {
 201         if (SAME_TEAM(start, player)) return start;
 202         // continue from current player
 203         for (entity e = start; (e = find(e, classname, STR_PLAYER)); )
 204         {
 205                 if (SAME_TEAM(player, e)) return e;
 206         }
 207         // restart from begining
 208         for (entity e = NULL; (e = find(e, classname, STR_PLAYER)); )
 209         {
 210                 if (SAME_TEAM(player, e)) return e;
 211         }
 212         return start;
 213 }
 214
 215
 216 MUTATOR_HOOKFUNCTION(ca, PlayerSpawn)
 217 {
 218     SELFPARAM();
 219         this.caplayer = 1;
 220         if (!warmup_stage)
 221                 eliminatedPlayers.SendFlags |= 1;
 222 }
 223
 224 MUTATOR_HOOKFUNCTION(ca, PutClientInServer)
 225 {
 226     SELFPARAM();
 227         if (!allowed_to_spawn && IS_PLAYER(this)) // this is true even when player is trying to join
 228         {
 229                 this.classname = STR_OBSERVER;
 230                 if (this.jointime != time && !this.caplayer) // not when connecting
 231                 {
 232                         this.caplayer = 0.5;
 233                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CA_JOIN_LATE);
 234                 }
 235         }
 236 }
 237
 238 MUTATOR_HOOKFUNCTION(ca, reset_map_players)
 239 {
 240         FOREACH_CLIENT(true, {
 241                 it.killcount = 0;
 242                 if (!it.caplayer && IS_BOT_CLIENT(it))
 243                 {
 244                         it.team = -1;
 245                         it.caplayer = 1;
 246                 }
 247                 if (it.caplayer)
 248                 {
 249                         it.classname = STR_PLAYER;
 250                         it.caplayer = 1;
 251                         WITH(entity, self, it, PutClientInServer());
 252                 }
 253         });
 254         return true;
 255 }
 256
 257 MUTATOR_HOOKFUNCTION(ca, ClientConnect)
 258 {
 259     SELFPARAM();
 260         this.classname = STR_OBSERVER;
 261         return true;
 262 }
 263
 264 MUTATOR_HOOKFUNCTION(ca, reset_map_global)
 265 {
 266         allowed_to_spawn = true;
 267         return true;
 268 }
 269
 270 MUTATOR_HOOKFUNCTION(ca, GetTeamCount, CBC_ORDER_EXCLUSIVE)
 271 {
 272         ret_float = ca_teams;
 273         return false;
 274 }
 275
 276 entity ca_LastPlayerForTeam()
 277 {
 278     SELFPARAM();
 279         entity last_pl = NULL;
 280         FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
 281                 if (!IS_DEAD(it))
 282                 if (SAME_TEAM(this, it))
 283                 if (!last_pl)
 284                         last_pl = it;
 285                 else
 286                         return NULL;
 287         });
 288         return last_pl;
 289 }
 290
 291 void ca_LastPlayerForTeam_Notify()
 292 {
 293         if (round_handler_IsActive())
 294         if (round_handler_IsRoundStarted())
 295         {
 296                 entity pl = ca_LastPlayerForTeam();
 297                 if (pl)
 298                         Send_Notification(NOTIF_ONE, pl, MSG_CENTER, CENTER_ALONE);
 299         }
 300 }
 301
 302 MUTATOR_HOOKFUNCTION(ca, PlayerDies)
 303 {
 304         ca_LastPlayerForTeam_Notify();
 305         if (!allowed_to_spawn)
 306                 frag_target.respawn_flags =  RESPAWN_SILENT;
 307         if (!warmup_stage)
 308                 eliminatedPlayers.SendFlags |= 1;
 309         return 1;
 310 }
 311
 312 MUTATOR_HOOKFUNCTION(ca, ClientDisconnect)
 313 {
 314     SELFPARAM();
 315         if (this.caplayer == 1)
 316                 ca_LastPlayerForTeam_Notify();
 317         return 1;
 318 }
 319
 320 MUTATOR_HOOKFUNCTION(ca, ForbidPlayerScore_Clear)
 321 {
 322         return 1;
 323 }
 324
 325 MUTATOR_HOOKFUNCTION(ca, MakePlayerObserver)
 326 {
 327     SELFPARAM();
 328         if (this.caplayer == 1)
 329                 ca_LastPlayerForTeam_Notify();
 330         if (this.killindicator_teamchange == -2)
 331                 this.caplayer = 0;
 332         if (this.caplayer)
 333                 this.frags = FRAGS_LMS_LOSER;
 334         if (!warmup_stage)
 335                 eliminatedPlayers.SendFlags |= 1;
 336         return true;  // prevent team reset
 337 }
 338
 339 MUTATOR_HOOKFUNCTION(ca, ForbidThrowCurrentWeapon)
 340 {
 341         return 1;
 342 }
 343
 344 MUTATOR_HOOKFUNCTION(ca, GiveFragsForKill, CBC_ORDER_FIRST)
 345 {
 346         frag_score = 0; // score will be given to the winner team when the round ends
 347         return 1;
 348 }
 349
 350 MUTATOR_HOOKFUNCTION(ca, SetStartItems)
 351 {
 352         start_items       &= ~IT_UNLIMITED_AMMO;
 353         start_health       = warmup_start_health       = cvar("g_lms_start_health");
 354         start_armorvalue   = warmup_start_armorvalue   = cvar("g_lms_start_armor");
 355         start_ammo_shells  = warmup_start_ammo_shells  = cvar("g_lms_start_ammo_shells");
 356         start_ammo_nails   = warmup_start_ammo_nails   = cvar("g_lms_start_ammo_nails");
 357         start_ammo_rockets = warmup_start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 358         start_ammo_cells   = warmup_start_ammo_cells   = cvar("g_lms_start_ammo_cells");
 359         start_ammo_plasma  = warmup_start_ammo_plasma  = cvar("g_lms_start_ammo_plasma");
 360         start_ammo_fuel    = warmup_start_ammo_fuel    = cvar("g_lms_start_ammo_fuel");
 361
 362         return 0;
 363 }
 364
 365 MUTATOR_HOOKFUNCTION(ca, PlayerDamage_Calculate)
 366 {
 367         if (IS_PLAYER(frag_target))
 368         if (!IS_DEAD(frag_target))
 369         if (frag_target == frag_attacker || SAME_TEAM(frag_target, frag_attacker) || frag_deathtype == DEATH_FALL.m_id)
 370                 frag_damage = 0;
 371
 372         frag_mirrordamage = 0;
 373
 374         return false;
 375 }
 376
 377 MUTATOR_HOOKFUNCTION(ca, FilterItem)
 378 {
 379     SELFPARAM();
 380         if (autocvar_g_powerups <= 0)
 381         if (this.flags & FL_POWERUP)
 382                 return true;
 383
 384         if (autocvar_g_pickup_items <= 0)
 385                 return true;
 386
 387         return false;
 388 }
 389
 390 MUTATOR_HOOKFUNCTION(ca, PlayerDamage_SplitHealthArmor)
 391 {
 392         float excess = max(0, frag_damage - damage_take - damage_save);
 393
 394         if (frag_target != frag_attacker && IS_PLAYER(frag_attacker))
 395                 PlayerTeamScore_Add(frag_attacker, SP_SCORE, ST_SCORE, (frag_damage - excess) * autocvar_g_ca_damage2score_multiplier);
 396
 397         return false;
 398 }
 399
 400 MUTATOR_HOOKFUNCTION(ca, PlayerRegen)
 401 {
 402         // no regeneration in CA
 403         return true;
 404 }
 405
 406 MUTATOR_HOOKFUNCTION(ca, Scores_CountFragsRemaining)
 407 {
 408         // announce remaining frags
 409         return true;
 410 }
 411
 412 MUTATOR_HOOKFUNCTION(ca, SpectateSet)
 413 {
 414     SELFPARAM();
 415         if (!autocvar_g_ca_spectate_enemies && this.caplayer)
 416         if (DIFF_TEAM(spec_player, this))
 417                 return true;
 418         return false;
 419 }
 420
 421 MUTATOR_HOOKFUNCTION(ca, SpectateNext)
 422 {
 423     SELFPARAM();
 424         if (!autocvar_g_ca_spectate_enemies && this.caplayer)
 425         {
 426                 spec_player = CA_SpectateNext(this, spec_player);
 427                 return true;
 428         }
 429         return false;
 430 }
 431
 432 MUTATOR_HOOKFUNCTION(ca, SpectatePrev)
 433 {
 434     SELFPARAM();
 435         if (!autocvar_g_ca_spectate_enemies && this.caplayer)
 436         {
 437                 do { spec_player = spec_player.chain; }
 438                 while(spec_player && DIFF_TEAM(spec_player, this));
 439
 440                 if (!spec_player)
 441                 {
 442                         for (spec_player = spec_first; spec_player && DIFF_TEAM(spec_player, this); spec_player = spec_player.chain);
 443
 444                         if (spec_player == this.enemy)
 445                                 return MUT_SPECPREV_RETURN;
 446                 }
 447         }
 448
 449         return MUT_SPECPREV_FOUND;
 450 }
 451
 452 MUTATOR_HOOKFUNCTION(ca, Bot_FixCount, CBC_ORDER_EXCLUSIVE)
 453 {
 454         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 455                 if (IS_PLAYER(it) || it.caplayer == 1)
 456                         ++bot_activerealplayers;
 457                 ++bot_realplayers;
 458         });
 459         return true;
 460 }
 461
 462 MUTATOR_HOOKFUNCTION(ca, ClientCommand_Spectate)
 463 {
 464     SELFPARAM();
 465         if (this.caplayer)
 466         {
 467                 // they're going to spec, we can do other checks
 468                 if (autocvar_sv_spectate && (IS_SPEC(this) || IS_OBSERVER(this)))
 469                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CA_LEAVE);
 470                 return MUT_SPECCMD_FORCE;
 471         }
 472
 473         return MUT_SPECCMD_CONTINUE;
 474 }
 475
 476 MUTATOR_HOOKFUNCTION(ca, WantWeapon)
 477 {
 478         want_allguns = true;
 479         return false;
 480 }
 481
 482 MUTATOR_HOOKFUNCTION(ca, GetPlayerStatus)
 483 {
 484         return set_player.caplayer == 1;
 485 }
 486
 487 MUTATOR_HOOKFUNCTION(ca, SetWeaponArena)
 488 {
 489         // most weapons arena
 490         if (ret_string == "0" || ret_string == "") ret_string = "most";
 491 }
 492
 493 #endif