qcsrc/server/mutators/mutator/gamemode_keyhunt.qc

   1 #include "gamemode_keyhunt.qh"
   2
   3 float autocvar_g_balance_keyhunt_damageforcescale;
   4 float autocvar_g_balance_keyhunt_delay_collect;
   5 float autocvar_g_balance_keyhunt_delay_damage_return;
   6 float autocvar_g_balance_keyhunt_delay_return;
   7 float autocvar_g_balance_keyhunt_delay_round;
   8 float autocvar_g_balance_keyhunt_delay_tracking;
   9 float autocvar_g_balance_keyhunt_return_when_unreachable;
  10 float autocvar_g_balance_keyhunt_dropvelocity;
  11 float autocvar_g_balance_keyhunt_maxdist;
  12 float autocvar_g_balance_keyhunt_protecttime;
  13
  14 int autocvar_g_balance_keyhunt_score_capture;
  15 int autocvar_g_balance_keyhunt_score_carrierfrag;
  16 int autocvar_g_balance_keyhunt_score_collect;
  17 int autocvar_g_balance_keyhunt_score_destroyed;
  18 int autocvar_g_balance_keyhunt_score_destroyed_ownfactor;
  19 int autocvar_g_balance_keyhunt_score_push;
  20 float autocvar_g_balance_keyhunt_throwvelocity;
  21
  22 //int autocvar_g_keyhunt_teams;
  23 int autocvar_g_keyhunt_teams_override;
  24
  25 // #define KH_PLAYER_USE_ATTACHMENT
  26 // #define KH_PLAYER_USE_CARRIEDMODEL
  27
  28 #ifdef KH_PLAYER_USE_ATTACHMENT
  29 const vector KH_PLAYER_ATTACHMENT_DIST_ROTATED = '0 -4 0';
  30 const vector KH_PLAYER_ATTACHMENT_DIST = '4 0 0';
  31 const vector KH_PLAYER_ATTACHMENT = '0 0 0';
  32 const vector KH_PLAYER_ATTACHMENT_ANGLES = '0 0 0';
  33 const string KH_PLAYER_ATTACHMENT_BONE = "";
  34 #else
  35 const float KH_KEY_ZSHIFT = 22;
  36 const float KH_KEY_XYDIST = 24;
  37 const float KH_KEY_XYSPEED = 45;
  38 #endif
  39 const float KH_KEY_WP_ZSHIFT = 20;
  40
  41 const vector KH_KEY_MIN = '-10 -10 -46';
  42 const vector KH_KEY_MAX = '10 10 3';
  43 const float KH_KEY_BRIGHTNESS = 2;
  44
  45 bool kh_no_radar_circles;
  46
  47 // kh_state
  48 //     bits  0- 4: team of key 1, or 0 for no such key, or 30 for dropped, or 31 for self
  49 //     bits  5- 9: team of key 2, or 0 for no such key, or 30 for dropped, or 31 for self
  50 //     bits 10-14: team of key 3, or 0 for no such key, or 30 for dropped, or 31 for self
  51 //     bits 15-19: team of key 4, or 0 for no such key, or 30 for dropped, or 31 for self
  52 .int kh_state = _STAT(KH_KEYS);
  53 .float siren_time;  //  time delay the siren
  54 //.float stuff_time;  //  time delay to stuffcmd a cvar
  55
  56 int kh_keystatus[17];
  57 //kh_keystatus[0] = status of dropped keys, kh_keystatus[1 - 16] = player #
  58 //replace 17 with cvar("maxplayers") or similar !!!!!!!!!
  59 //for(i = 0; i < maxplayers; ++i)
  60 //      kh_keystatus[i] = "0";
  61
  62 int kh_Team_ByID(int t)
  63 {
  64         if(t == 0) return NUM_TEAM_1;
  65         if(t == 1) return NUM_TEAM_2;
  66         if(t == 2) return NUM_TEAM_3;
  67         if(t == 3) return NUM_TEAM_4;
  68         return 0;
  69 }
  70
  71 //entity kh_worldkeylist;
  72 .entity kh_worldkeynext;
  73 entity kh_controller;
  74 //bool kh_tracking_enabled;
  75 int kh_teams;
  76 int kh_interferemsg_team;
  77 float kh_interferemsg_time;
  78 .entity kh_next, kh_prev; // linked list
  79 .float kh_droptime;
  80 .int kh_dropperteam;
  81 .entity kh_previous_owner;
  82 .int kh_previous_owner_playerid;
  83
  84 int kh_key_dropped, kh_key_carried;
  85
  86 int kh_Key_AllOwnedByWhichTeam();
  87
  88 const float ST_KH_CAPS = 1;
  89 void kh_ScoreRules(int teams)
  90 {
  91         ScoreRules_basics(teams, SFL_SORT_PRIO_PRIMARY, SFL_SORT_PRIO_PRIMARY, true);
  92         ScoreInfo_SetLabel_TeamScore(  ST_KH_CAPS,      "caps",      SFL_SORT_PRIO_SECONDARY);
  93         ScoreInfo_SetLabel_PlayerScore(SP_KH_CAPS,      "caps",      SFL_SORT_PRIO_SECONDARY);
  94         ScoreInfo_SetLabel_PlayerScore(SP_KH_PUSHES,    "pushes",    0);
  95         ScoreInfo_SetLabel_PlayerScore(SP_KH_DESTROYS,  "destroyed", SFL_LOWER_IS_BETTER);
  96         ScoreInfo_SetLabel_PlayerScore(SP_KH_PICKUPS,   "pickups",   0);
  97         ScoreInfo_SetLabel_PlayerScore(SP_KH_KCKILLS,   "kckills",   0);
  98         ScoreInfo_SetLabel_PlayerScore(SP_KH_LOSSES,    "losses",    SFL_LOWER_IS_BETTER);
  99         ScoreRules_basics_end();
 100 }
 101
 102 bool kh_KeyCarrier_waypointsprite_visible_for_player(entity this, entity player, entity view)  // runs all the time
 103 {
 104         if(!IS_PLAYER(view) || DIFF_TEAM(this, view))
 105                 if(!kh_tracking_enabled)
 106                         return false;
 107
 108         return true;
 109 }
 110
 111 bool kh_Key_waypointsprite_visible_for_player(entity this, entity player, entity view)
 112 {
 113         if(!kh_tracking_enabled)
 114                 return false;
 115         if(!this.owner)
 116                 return true;
 117         if(!this.owner.owner)
 118                 return true;
 119         return false;  // draw only when key is not owned
 120 }
 121
 122 void kh_update_state()
 123 {
 124         entity key;
 125         int f;
 126         int s = 0;
 127         FOR_EACH_KH_KEY(key)
 128         {
 129                 if(key.owner)
 130                         f = key.team;
 131                 else
 132                         f = 30;
 133                 s |= pow(32, key.count) * f;
 134         }
 135
 136         FOREACH_CLIENT(true, LAMBDA(it.kh_state = s));
 137
 138         FOR_EACH_KH_KEY(key)
 139         {
 140                 if(key.owner)
 141                         key.owner.kh_state |= pow(32, key.count) * 31;
 142         }
 143         //print(ftos((nextent(NULL)).kh_state), "\n");
 144 }
 145
 146
 147
 148
 149 var kh_Think_t kh_Controller_Thinkfunc;
 150 void kh_Controller_SetThink(float t, kh_Think_t func)  // runs occasionaly
 151 {
 152         kh_Controller_Thinkfunc = func;
 153         kh_controller.cnt = ceil(t);
 154         if(t == 0)
 155                 kh_controller.nextthink = time; // force
 156 }
 157 void kh_WaitForPlayers();
 158 void kh_Controller_Think(entity this)  // called a lot
 159 {
 160         if(intermission_running)
 161                 return;
 162         if(this.cnt > 0)
 163         {
 164                 if(getthink(this) != kh_WaitForPlayers)
 165                         this.cnt -= 1;
 166         }
 167         else if(this.cnt == 0)
 168         {
 169                 this.cnt -= 1;
 170                 kh_Controller_Thinkfunc();
 171         }
 172         this.nextthink = time + 1;
 173 }
 174
 175 // frags f: take from cvar * f
 176 // frags 0: no frags
 177 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)  // update the score when a key is captured
 178 {
 179         string s;
 180         if(intermission_running)
 181                 return;
 182
 183         if(frags_player)
 184                 UpdateFrags(player, frags_player);
 185
 186         if(key && key.owner && frags_owner)
 187                 UpdateFrags(key.owner, frags_owner);
 188
 189         if(!autocvar_sv_eventlog)  //output extra info to the console or text file
 190                 return;
 191
 192         s = strcat(":keyhunt:", what, ":", ftos(player.playerid), ":", ftos(frags_player));
 193
 194         if(key && key.owner)
 195                 s = strcat(s, ":", ftos(key.owner.playerid));
 196         else
 197                 s = strcat(s, ":0");
 198
 199         s = strcat(s, ":", ftos(frags_owner), ":");
 200
 201         if(key)
 202                 s = strcat(s, key.netname);
 203
 204         GameLogEcho(s);
 205 }
 206
 207 vector kh_AttachedOrigin(entity e)  // runs when a team captures the flag, it can run 2 or 3 times.
 208 {
 209         if(e.tag_entity)
 210         {
 211                 makevectors(e.tag_entity.angles);
 212                 return e.tag_entity.origin + e.origin.x * v_forward - e.origin.y * v_right + e.origin.z * v_up;
 213         }
 214         else
 215                 return e.origin;
 216 }
 217
 218 void kh_Key_Attach(entity key)  // runs when a player picks up a key and several times when a key is assigned to a player at the start of a round
 219 {
 220 #ifdef KH_PLAYER_USE_ATTACHMENT
 221         entity first = key.owner.kh_next;
 222         if(key == first)
 223         {
 224                 setattachment(key, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 225                 if(key.kh_next)
 226                 {
 227                         setattachment(key.kh_next, key, "");
 228                         setorigin(key, key.kh_next.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 229                         setorigin(key.kh_next, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 230                         key.kh_next.angles = '0 0 0';
 231                 }
 232                 else
 233                         setorigin(key, KH_PLAYER_ATTACHMENT);
 234                 key.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 235         }
 236         else
 237         {
 238                 setattachment(key, key.kh_prev, "");
 239                 if(key.kh_next)
 240                         setattachment(key.kh_next, key, "");
 241                 setorigin(key, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 242                 setorigin(first, first.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 243                 key.angles = '0 0 0';
 244         }
 245 #else
 246         setattachment(key, key.owner, "");
 247         setorigin(key, '0 0 1' * KH_KEY_ZSHIFT);  // fixing x, y in think
 248         key.angles_y -= key.owner.angles.y;
 249 #endif
 250         key.flags = 0;
 251         IL_REMOVE(g_items, key);
 252         key.solid = SOLID_NOT;
 253         set_movetype(key, MOVETYPE_NONE);
 254         key.team = key.owner.team;
 255         key.nextthink = time;
 256         key.damageforcescale = 0;
 257         key.takedamage = DAMAGE_NO;
 258         key.modelindex = kh_key_carried;
 259 }
 260
 261 void kh_Key_Detach(entity key) // runs every time a key is dropped or lost. Runs several times times when all the keys are captured
 262 {
 263 #ifdef KH_PLAYER_USE_ATTACHMENT
 264         entity first = key.owner.kh_next;
 265         if(key == first)
 266         {
 267                 if(key.kh_next)
 268                 {
 269                         setattachment(key.kh_next, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 270                         setorigin(key.kh_next, key.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 271                         key.kh_next.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 272                 }
 273         }
 274         else
 275         {
 276                 if(key.kh_next)
 277                         setattachment(key.kh_next, key.kh_prev, "");
 278                 setorigin(first, first.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 279         }
 280         // in any case:
 281         setattachment(key, NULL, "");
 282         setorigin(key, key.owner.origin + '0 0 1' * (STAT(PL_MIN, NULL).z - KH_KEY_MIN_z));
 283         key.angles = key.owner.angles;
 284 #else
 285         setorigin(key, key.owner.origin + key.origin.z * '0 0 1');
 286         setattachment(key, NULL, "");
 287         key.angles_y += key.owner.angles.y;
 288 #endif
 289         key.flags = FL_ITEM;
 290         IL_PUSH(g_items, key);
 291         key.solid = SOLID_TRIGGER;
 292         set_movetype(key, MOVETYPE_TOSS);
 293         key.pain_finished = time + autocvar_g_balance_keyhunt_delay_return;
 294         key.damageforcescale = autocvar_g_balance_keyhunt_damageforcescale;
 295         key.takedamage = DAMAGE_YES;
 296         // let key.team stay
 297         key.modelindex = kh_key_dropped;
 298         key.kh_previous_owner = key.owner;
 299         key.kh_previous_owner_playerid = key.owner.playerid;
 300 }
 301
 302 void kh_Key_AssignTo(entity key, entity player)  // runs every time a key is picked up or assigned. Runs prior to kh_key_attach
 303 {
 304         if(key.owner == player)
 305                 return;
 306
 307         int ownerteam0 = kh_Key_AllOwnedByWhichTeam();
 308
 309         if(key.owner)
 310         {
 311                 kh_Key_Detach(key);
 312
 313                 // remove from linked list
 314                 if(key.kh_next)
 315                         key.kh_next.kh_prev = key.kh_prev;
 316                 key.kh_prev.kh_next = key.kh_next;
 317                 key.kh_next = NULL;
 318                 key.kh_prev = NULL;
 319
 320                 if(key.owner.kh_next == NULL)
 321                 {
 322                         // No longer a key carrier
 323                         if(!kh_no_radar_circles)
 324                                 WaypointSprite_Ping(key.owner.waypointsprite_attachedforcarrier);
 325                         WaypointSprite_DetachCarrier(key.owner);
 326                 }
 327         }
 328
 329         key.owner = player;
 330
 331         if(player)
 332         {
 333                 // insert into linked list
 334                 key.kh_next = player.kh_next;
 335                 key.kh_prev = player;
 336                 player.kh_next = key;
 337                 if(key.kh_next)
 338                         key.kh_next.kh_prev = key;
 339
 340                 float i;
 341                 i = kh_keystatus[key.owner.playerid];
 342                         if(key.netname == "^1red key")
 343                                 i += 1;
 344                         if(key.netname == "^4blue key")
 345                                 i += 2;
 346                         if(key.netname == "^3yellow key")
 347                                 i += 4;
 348                         if(key.netname == "^6pink key")
 349                                 i += 8;
 350                 kh_keystatus[key.owner.playerid] = i;
 351
 352                 kh_Key_Attach(key);
 353
 354                 if(key.kh_next == NULL)
 355                 {
 356                         // player is now a key carrier
 357                         entity wp = WaypointSprite_AttachCarrier(WP_Null, player, RADARICON_FLAGCARRIER);
 358                         wp.colormod = colormapPaletteColor(player.team - 1, 0);
 359                         player.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_KeyCarrier_waypointsprite_visible_for_player;
 360                         WaypointSprite_UpdateRule(player.waypointsprite_attachedforcarrier, player.team, SPRITERULE_TEAMPLAY);
 361                         if(player.team == NUM_TEAM_1)
 362                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierRed, WP_KeyCarrierFriend, WP_KeyCarrierRed);
 363                         else if(player.team == NUM_TEAM_2)
 364                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierBlue, WP_KeyCarrierFriend, WP_KeyCarrierBlue);
 365                         else if(player.team == NUM_TEAM_3)
 366                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierYellow, WP_KeyCarrierFriend, WP_KeyCarrierYellow);
 367                         else if(player.team == NUM_TEAM_4)
 368                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierPink, WP_KeyCarrierFriend, WP_KeyCarrierPink);
 369                         if(!kh_no_radar_circles)
 370                                 WaypointSprite_Ping(player.waypointsprite_attachedforcarrier);
 371                 }
 372         }
 373
 374         // moved that here, also update if there's no player
 375         kh_update_state();
 376
 377         key.pusher = NULL;
 378
 379         int ownerteam = kh_Key_AllOwnedByWhichTeam();
 380         if(ownerteam != ownerteam0)
 381         {
 382                 entity k;
 383                 if(ownerteam != -1)
 384                 {
 385                         kh_interferemsg_time = time + 0.2;
 386                         kh_interferemsg_team = player.team;
 387
 388                         // audit all key carrier sprites, update them to "Run here"
 389                         FOR_EACH_KH_KEY(k)
 390                         {
 391                                 if (!k.owner) continue;
 392                                 entity first = WP_Null;
 393                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model1, LAMBDA(first = it; break));
 394                                 entity third = WP_Null;
 395                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model3, LAMBDA(third = it; break));
 396                                 WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, first, WP_KeyCarrierFinish, third);
 397                         }
 398                 }
 399                 else
 400                 {
 401                         kh_interferemsg_time = 0;
 402
 403                         // audit all key carrier sprites, update them to "Key Carrier"
 404                         FOR_EACH_KH_KEY(k)
 405                         {
 406                                 if (!k.owner) continue;
 407                                 entity first = WP_Null;
 408                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model1, LAMBDA(first = it; break));
 409                                 entity third = WP_Null;
 410                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model3, LAMBDA(third = it; break));
 411                                 WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, first, WP_KeyCarrierFriend, third);
 412                         }
 413                 }
 414         }
 415 }
 416
 417 void kh_Key_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 418 {
 419         if(this.owner)
 420                 return;
 421         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 422         {
 423                 this.pain_finished = bound(time, time + autocvar_g_balance_keyhunt_delay_damage_return, this.pain_finished);
 424                 return;
 425         }
 426         if(force == '0 0 0')
 427                 return;
 428         if(time > this.pushltime)
 429                 if(IS_PLAYER(attacker))
 430                         this.team = attacker.team;
 431 }
 432
 433 void kh_Key_Collect(entity key, entity player)  //a player picks up a dropped key
 434 {
 435         sound(player, CH_TRIGGER, SND_KH_COLLECT, VOL_BASE, ATTEN_NORM);
 436
 437         if(key.kh_dropperteam != player.team)
 438         {
 439                 kh_Scores_Event(player, key, "collect", autocvar_g_balance_keyhunt_score_collect, 0);
 440                 PlayerScore_Add(player, SP_KH_PICKUPS, 1);
 441         }
 442         key.kh_dropperteam = 0;
 443         int realteam = kh_Team_ByID(key.count);
 444         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(realteam, INFO_KEYHUNT_PICKUP), player.netname);
 445
 446         kh_Key_AssignTo(key, player); // this also updates .kh_state
 447 }
 448
 449 void kh_Key_Touch(entity this, entity toucher)  // runs many, many times when a key has been dropped and can be picked up
 450 {
 451         if(intermission_running)
 452                 return;
 453
 454         if(this.owner) // already carried
 455                 return;
 456
 457         if(ITEM_TOUCH_NEEDKILL())
 458         {
 459                 this.pain_finished = bound(time, time + autocvar_g_balance_keyhunt_delay_damage_return, this.pain_finished);
 460                 return;
 461         }
 462
 463         if (!IS_PLAYER(toucher))
 464                 return;
 465         if(IS_DEAD(toucher))
 466                 return;
 467         if(toucher == this.enemy)
 468                 if(time < this.kh_droptime + autocvar_g_balance_keyhunt_delay_collect)
 469                         return;  // you just dropped it!
 470         kh_Key_Collect(this, toucher);
 471 }
 472
 473 void kh_Key_Remove(entity key)  // runs after when all the keys have been collected or when a key has been dropped for more than X seconds
 474 {
 475         entity o = key.owner;
 476         kh_Key_AssignTo(key, NULL);
 477         if(o) // it was attached
 478                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 479         else // it was dropped
 480                 WaypointSprite_DetachCarrier(key);
 481
 482         // remove key from key list
 483         if (kh_worldkeylist == key)
 484                 kh_worldkeylist = kh_worldkeylist.kh_worldkeynext;
 485         else
 486         {
 487                 o = kh_worldkeylist;
 488                 while (o)
 489                 {
 490                         if (o.kh_worldkeynext == key)
 491                         {
 492                                 o.kh_worldkeynext = o.kh_worldkeynext.kh_worldkeynext;
 493                                 break;
 494                         }
 495                         o = o.kh_worldkeynext;
 496                 }
 497         }
 498
 499         delete(key);
 500
 501         kh_update_state();
 502 }
 503
 504 void kh_FinishRound()  // runs when a team captures the keys
 505 {
 506         // prepare next round
 507         kh_interferemsg_time = 0;
 508         entity key;
 509
 510         kh_no_radar_circles = true;
 511         FOR_EACH_KH_KEY(key)
 512                 kh_Key_Remove(key);
 513         kh_no_radar_circles = false;
 514
 515         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_KEYHUNT_ROUNDSTART, autocvar_g_balance_keyhunt_delay_round);
 516         kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round, kh_StartRound);
 517 }
 518
 519 void nades_GiveBonus(entity player, float score);
 520
 521 void kh_WinnerTeam(int winner_team)  // runs when a team wins
 522 {
 523         // all key carriers get some points
 524         entity key;
 525         float score = (NumTeams(kh_teams) - 1) * autocvar_g_balance_keyhunt_score_capture;
 526         DistributeEvenly_Init(score, NumTeams(kh_teams));
 527         // twice the score for 3 team games, three times the score for 4 team games!
 528         // note: for a win by destroying the key, this should NOT be applied
 529         FOR_EACH_KH_KEY(key)
 530         {
 531                 float f = DistributeEvenly_Get(1);
 532                 kh_Scores_Event(key.owner, key, "capture", f, 0);
 533                 PlayerTeamScore_Add(key.owner, SP_KH_CAPS, ST_KH_CAPS, 1);
 534                 nades_GiveBonus(key.owner, autocvar_g_nades_bonus_score_high);
 535         }
 536
 537         bool first = true;
 538         string keyowner = "";
 539         FOR_EACH_KH_KEY(key)
 540                 if(key.owner.kh_next == key)
 541                 {
 542                         if(!first)
 543                                 keyowner = strcat(keyowner, ", ");
 544                         keyowner = key.owner.netname;
 545                         first = false;
 546                 }
 547
 548         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, APP_TEAM_NUM(winner_team, CENTER_ROUND_TEAM_WIN));
 549         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(winner_team, INFO_KEYHUNT_CAPTURE), keyowner);
 550
 551         first = true;
 552         vector firstorigin = '0 0 0', lastorigin = '0 0 0', midpoint = '0 0 0';
 553         FOR_EACH_KH_KEY(key)
 554         {
 555                 vector thisorigin = kh_AttachedOrigin(key);
 556                 //dprint("Key origin: ", vtos(thisorigin), "\n");
 557                 midpoint += thisorigin;
 558
 559                 if(!first)
 560                         te_lightning2(NULL, lastorigin, thisorigin);
 561                 lastorigin = thisorigin;
 562                 if(first)
 563                         firstorigin = thisorigin;
 564                 first = false;
 565         }
 566         if(NumTeams(kh_teams) > 2)
 567         {
 568                 te_lightning2(NULL, lastorigin, firstorigin);
 569         }
 570         midpoint = midpoint * (1 / NumTeams(kh_teams));
 571         te_customflash(midpoint, 1000, 1, Team_ColorRGB(winner_team) * 0.5 + '0.5 0.5 0.5');  // make the color >=0.5 in each component
 572
 573         play2all(SND(KH_CAPTURE));
 574         kh_FinishRound();
 575 }
 576
 577 void kh_LoserTeam(int loser_team, entity lostkey)  // runs when a player pushes a flag carrier off the map
 578 {
 579         float f;
 580         entity attacker = NULL;
 581         if(lostkey.pusher)
 582                 if(lostkey.pusher.team != loser_team)
 583                         if(IS_PLAYER(lostkey.pusher))
 584                                 attacker = lostkey.pusher;
 585
 586         if(attacker)
 587         {
 588                 if(lostkey.kh_previous_owner)
 589                         kh_Scores_Event(lostkey.kh_previous_owner, NULL, "pushed", 0, -autocvar_g_balance_keyhunt_score_push);
 590                         // don't actually GIVE him the -nn points, just log
 591                 kh_Scores_Event(attacker, NULL, "push", autocvar_g_balance_keyhunt_score_push, 0);
 592                 PlayerScore_Add(attacker, SP_KH_PUSHES, 1);
 593                 //centerprint(attacker, "Your push is the best!"); // does this really need to exist?
 594         }
 595         else
 596         {
 597                 int players = 0;
 598                 float of = autocvar_g_balance_keyhunt_score_destroyed_ownfactor;
 599
 600                 FOREACH_CLIENT(IS_PLAYER(it) && it.team != loser_team, LAMBDA(++players));
 601
 602                 entity key;
 603                 int keys = 0;
 604                 FOR_EACH_KH_KEY(key)
 605                         if(key.owner && key.team != loser_team)
 606                                 ++keys;
 607
 608                 if(lostkey.kh_previous_owner)
 609                         kh_Scores_Event(lostkey.kh_previous_owner, NULL, "destroyed", 0, -autocvar_g_balance_keyhunt_score_destroyed);
 610                         // don't actually GIVE him the -nn points, just log
 611
 612                 if(lostkey.kh_previous_owner.playerid == lostkey.kh_previous_owner_playerid)
 613                         PlayerScore_Add(lostkey.kh_previous_owner, SP_KH_DESTROYS, 1);
 614
 615                 DistributeEvenly_Init(autocvar_g_balance_keyhunt_score_destroyed, keys * of + players);
 616
 617                 FOR_EACH_KH_KEY(key)
 618                         if(key.owner && key.team != loser_team)
 619                         {
 620                                 f = DistributeEvenly_Get(of);
 621                                 kh_Scores_Event(key.owner, NULL, "destroyed_holdingkey", f, 0);
 622                         }
 623
 624                 int fragsleft = DistributeEvenly_Get(players);
 625
 626                 // Now distribute these among all other teams...
 627                 int j = NumTeams(kh_teams) - 1;
 628                 for(int i = 0; i < NumTeams(kh_teams); ++i)
 629                 {
 630                         int thisteam = kh_Team_ByID(i);
 631                         if(thisteam == loser_team) // bad boy, no cookie - this WILL happen
 632                                 continue;
 633
 634                         players = 0;
 635                         FOREACH_CLIENT(IS_PLAYER(it) && it.team == thisteam, LAMBDA(++players));
 636
 637                         DistributeEvenly_Init(fragsleft, j);
 638                         fragsleft = DistributeEvenly_Get(j - 1);
 639                         DistributeEvenly_Init(DistributeEvenly_Get(1), players);
 640
 641                         FOREACH_CLIENT(IS_PLAYER(it) && it.team == thisteam, LAMBDA(
 642                                 f = DistributeEvenly_Get(1);
 643                                 kh_Scores_Event(it, NULL, "destroyed", f, 0);
 644                         ));
 645
 646                         --j;
 647                 }
 648         }
 649
 650         int realteam = kh_Team_ByID(lostkey.count);
 651         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, APP_TEAM_NUM(loser_team, CENTER_ROUND_TEAM_LOSS));
 652         if(attacker)
 653                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(realteam, INFO_KEYHUNT_PUSHED), attacker.netname, lostkey.kh_previous_owner.netname);
 654         else
 655                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(realteam, INFO_KEYHUNT_DESTROYED), lostkey.kh_previous_owner.netname);
 656
 657         play2all(SND(KH_DESTROY));
 658         te_tarexplosion(lostkey.origin);
 659
 660         kh_FinishRound();
 661 }
 662
 663 void kh_Key_Think(entity this)  // runs all the time
 664 {
 665         if(intermission_running)
 666                 return;
 667
 668         if(this.owner)
 669         {
 670 #ifndef KH_PLAYER_USE_ATTACHMENT
 671                 makevectors('0 1 0' * (this.cnt + (time % 360) * KH_KEY_XYSPEED));
 672                 setorigin(this, v_forward * KH_KEY_XYDIST + '0 0 1' * this.origin.z);
 673 #endif
 674         }
 675
 676         // if in nodrop or time over, end the round
 677         if(!this.owner)
 678                 if(time > this.pain_finished)
 679                         kh_LoserTeam(this.team, this);
 680
 681         if(this.owner)
 682         if(kh_Key_AllOwnedByWhichTeam() != -1)
 683         {
 684                 if(this.siren_time < time)
 685                 {
 686                         sound(this.owner, CH_TRIGGER, SND_KH_ALARM, VOL_BASE, ATTEN_NORM);  // play a simple alarm
 687                         this.siren_time = time + 2.5;  // repeat every 2.5 seconds
 688                 }
 689
 690                 entity key;
 691                 vector p = this.owner.origin;
 692                 FOR_EACH_KH_KEY(key)
 693                         if(vdist(key.owner.origin - p, >, autocvar_g_balance_keyhunt_maxdist))
 694                                 goto not_winning;
 695                 kh_WinnerTeam(this.team);
 696 LABEL(not_winning)
 697         }
 698
 699         if(kh_interferemsg_time && time > kh_interferemsg_time)
 700         {
 701                 kh_interferemsg_time = 0;
 702                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
 703                         if(it.team == kh_interferemsg_team)
 704                                 if(it.kh_next)
 705                                         Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_KEYHUNT_MEET);
 706                                 else
 707                                         Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_KEYHUNT_HELP);
 708                         else
 709                                 Send_Notification(NOTIF_ONE, it, MSG_CENTER, APP_TEAM_NUM(kh_interferemsg_team, CENTER_KEYHUNT_INTERFERE));
 710                 ));
 711         }
 712
 713         this.nextthink = time + 0.05;
 714 }
 715
 716 void key_reset(entity this)
 717 {
 718         kh_Key_AssignTo(this, NULL);
 719         kh_Key_Remove(this);
 720 }
 721
 722 const string STR_ITEM_KH_KEY = "item_kh_key";
 723 void kh_Key_Spawn(entity initial_owner, float _angle, float i)  // runs every time a new flag is created, ie after all the keys have been collected
 724 {
 725         entity key = spawn();
 726         key.count = i;
 727         key.classname = STR_ITEM_KH_KEY;
 728         settouch(key, kh_Key_Touch);
 729         setthink(key, kh_Key_Think);
 730         key.nextthink = time;
 731         key.items = IT_KEY1 | IT_KEY2;
 732         key.cnt = _angle;
 733         key.angles = '0 360 0' * random();
 734         key.event_damage = kh_Key_Damage;
 735         key.takedamage = DAMAGE_YES;
 736         key.damagedbytriggers = autocvar_g_balance_keyhunt_return_when_unreachable;
 737         key.damagedbycontents = autocvar_g_balance_keyhunt_return_when_unreachable;
 738         key.modelindex = kh_key_dropped;
 739         key.model = "key";
 740         key.kh_dropperteam = 0;
 741         key.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 742         setsize(key, KH_KEY_MIN, KH_KEY_MAX);
 743         key.colormod = Team_ColorRGB(initial_owner.team) * KH_KEY_BRIGHTNESS;
 744         key.reset = key_reset;
 745
 746         switch(initial_owner.team)
 747         {
 748                 case NUM_TEAM_1:
 749                         key.netname = "^1red key";
 750                         break;
 751                 case NUM_TEAM_2:
 752                         key.netname = "^4blue key";
 753                         break;
 754                 case NUM_TEAM_3:
 755                         key.netname = "^3yellow key";
 756                         break;
 757                 case NUM_TEAM_4:
 758                         key.netname = "^6pink key";
 759                         break;
 760                 default:
 761                         key.netname = "NETGIER key";
 762                         break;
 763         }
 764
 765         // link into key list
 766         key.kh_worldkeynext = kh_worldkeylist;
 767         kh_worldkeylist = key;
 768
 769         Send_Notification(NOTIF_ONE, initial_owner, MSG_CENTER, APP_TEAM_NUM(initial_owner.team, CENTER_KEYHUNT_START));
 770
 771         WaypointSprite_Spawn(WP_KeyDropped, 0, 0, key, '0 0 1' * KH_KEY_WP_ZSHIFT, NULL, key.team, key, waypointsprite_attachedforcarrier, false, RADARICON_FLAG);
 772         key.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_Key_waypointsprite_visible_for_player;
 773
 774         kh_Key_AssignTo(key, initial_owner);
 775 }
 776
 777 // -1 when no team completely owns all keys yet
 778 int kh_Key_AllOwnedByWhichTeam()  // constantly called. check to see if all the keys are owned by the same team
 779 {
 780         entity key;
 781         int teem = -1;
 782         int keys = NumTeams(kh_teams);
 783         FOR_EACH_KH_KEY(key)
 784         {
 785                 if(!key.owner)
 786                         return -1;
 787                 if(teem == -1)
 788                         teem = key.team;
 789                 else if(teem != key.team)
 790                         return -1;
 791                 --keys;
 792         }
 793         if(keys != 0)
 794                 return -1;
 795         return teem;
 796 }
 797
 798 void kh_Key_DropOne(entity key)
 799 {
 800         // prevent collecting this one for some time
 801         entity player = key.owner;
 802
 803         key.kh_droptime = time;
 804         key.enemy = player;
 805
 806         kh_Scores_Event(player, key, "dropkey", 0, 0);
 807         PlayerScore_Add(player, SP_KH_LOSSES, 1);
 808         int realteam = kh_Team_ByID(key.count);
 809         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(realteam, INFO_KEYHUNT_DROP), player.netname);
 810
 811         kh_Key_AssignTo(key, NULL);
 812         makevectors(player.v_angle);
 813         key.velocity = W_CalculateProjectileVelocity(player, player.velocity, autocvar_g_balance_keyhunt_throwvelocity * v_forward, false);
 814         key.pusher = NULL;
 815         key.pushltime = time + autocvar_g_balance_keyhunt_protecttime;
 816         key.kh_dropperteam = key.team;
 817
 818         sound(player, CH_TRIGGER, SND_KH_DROP, VOL_BASE, ATTEN_NORM);
 819 }
 820
 821 void kh_Key_DropAll(entity player, float suicide) // runs whenever a player dies
 822 {
 823         if(player.kh_next)
 824         {
 825                 entity mypusher = NULL;
 826                 if(player.pusher)
 827                         if(time < player.pushltime)
 828                                 mypusher = player.pusher;
 829
 830                 entity key;
 831                 while((key = player.kh_next))
 832                 {
 833                         kh_Scores_Event(player, key, "losekey", 0, 0);
 834                         PlayerScore_Add(player, SP_KH_LOSSES, 1);
 835                         int realteam = kh_Team_ByID(key.count);
 836                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(realteam, INFO_KEYHUNT_LOST), player.netname);
 837                         kh_Key_AssignTo(key, NULL);
 838                         makevectors('-1 0 0' * (45 + 45 * random()) + '0 360 0' * random());
 839                         key.velocity = W_CalculateProjectileVelocity(player, player.velocity, autocvar_g_balance_keyhunt_dropvelocity * v_forward, false);
 840                         key.pusher = mypusher;
 841                         key.pushltime = time + autocvar_g_balance_keyhunt_protecttime;
 842                         if(suicide)
 843                                 key.kh_dropperteam = player.team;
 844                 }
 845                 sound(player, CH_TRIGGER, SND_KH_DROP, VOL_BASE, ATTEN_NORM);
 846         }
 847 }
 848
 849 int kh_GetMissingTeams()
 850 {
 851         int missing_teams = 0;
 852         for(int i = 0; i < NumTeams(kh_teams); ++i)
 853         {
 854                 int teem = kh_Team_ByID(i);
 855                 int players = 0;
 856                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
 857                         if(!IS_DEAD(it) && !PHYS_INPUT_BUTTON_CHAT(it) && it.team == teem)
 858                                 ++players;
 859                 ));
 860                 if (!players)
 861                         missing_teams |= pow(2, i);
 862         }
 863         return missing_teams;
 864 }
 865
 866 void kh_WaitForPlayers()  // delay start of the round until enough players are present
 867 {
 868         if(time < game_starttime)
 869         {
 870                 kh_Controller_SetThink(game_starttime - time + 0.1, kh_WaitForPlayers);
 871                 return;
 872         }
 873
 874         static int prev_missing_teams_mask;
 875         int missing_teams_mask = kh_GetMissingTeams();
 876         if(!missing_teams_mask)
 877         {
 878                 if(prev_missing_teams_mask > 0)
 879                         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
 880                 prev_missing_teams_mask = -1;
 881                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_KEYHUNT_ROUNDSTART, autocvar_g_balance_keyhunt_delay_round);
 882                 kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round, kh_StartRound);
 883         }
 884         else
 885         {
 886                 if(player_count == 0)
 887                 {
 888                         if(prev_missing_teams_mask > 0)
 889                                 Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
 890                         prev_missing_teams_mask = -1;
 891                 }
 892                 else
 893                 {
 894                         if(prev_missing_teams_mask != missing_teams_mask)
 895                         {
 896                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_MISSING_TEAMS, missing_teams_mask);
 897                                 prev_missing_teams_mask = missing_teams_mask;
 898                         }
 899                 }
 900                 kh_Controller_SetThink(1, kh_WaitForPlayers);
 901         }
 902 }
 903
 904 void kh_EnableTrackingDevice()  // runs after each round
 905 {
 906         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_KEYHUNT);
 907         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_KEYHUNT_OTHER);
 908
 909         kh_tracking_enabled = true;
 910 }
 911
 912 void kh_StartRound()  // runs at the start of each round
 913 {
 914         if(time < game_starttime)
 915         {
 916                 kh_Controller_SetThink(game_starttime - time + 0.1, kh_WaitForPlayers);
 917                 return;
 918         }
 919
 920         if(kh_GetMissingTeams())
 921         {
 922                 kh_Controller_SetThink(1, kh_WaitForPlayers);
 923                 return;
 924         }
 925
 926         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_KEYHUNT);
 927         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_KEYHUNT_OTHER);
 928
 929         for(int i = 0; i < NumTeams(kh_teams); ++i)
 930         {
 931                 int teem = kh_Team_ByID(i);
 932                 int players = 0;
 933                 entity my_player = NULL;
 934                 FOREACH_CLIENT(IS_PLAYER(it), LAMBDA(
 935                         if(!IS_DEAD(it) && !PHYS_INPUT_BUTTON_CHAT(it) && it.team == teem)
 936                         {
 937                                 ++players;
 938                                 if(random() * players <= 1)
 939                                         my_player = it;
 940                         }
 941                 ));
 942                 kh_Key_Spawn(my_player, 360 * i / NumTeams(kh_teams), i);
 943         }
 944
 945         kh_tracking_enabled = false;
 946         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_KEYHUNT_SCAN, autocvar_g_balance_keyhunt_delay_tracking);
 947         kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_tracking, kh_EnableTrackingDevice);
 948 }
 949
 950 float kh_HandleFrags(entity attacker, entity targ, float f)  // adds to the player score
 951 {
 952         if(attacker == targ)
 953                 return f;
 954
 955         if(targ.kh_next)
 956         {
 957                 if(attacker.team == targ.team)
 958                 {
 959                         int nk = 0;
 960                         for(entity k = targ.kh_next; k != NULL; k = k.kh_next)
 961                                 ++nk;
 962                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", -nk * autocvar_g_balance_keyhunt_score_collect, 0);
 963                 }
 964                 else
 965                 {
 966                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", autocvar_g_balance_keyhunt_score_carrierfrag-1, 0);
 967                         PlayerScore_Add(attacker, SP_KH_KCKILLS, 1);
 968                         // the frag gets added later
 969                 }
 970         }
 971
 972         return f;
 973 }
 974
 975 void kh_Initialize()  // sets up th KH environment
 976 {
 977         // setup variables
 978         kh_teams = autocvar_g_keyhunt_teams_override;
 979         if(kh_teams < 2)
 980                 kh_teams = cvar("g_keyhunt_teams"); // read the cvar directly as it gets written earlier in the same frame
 981         kh_teams = bound(2, kh_teams, 4);
 982
 983         int teams = 0;
 984         if(kh_teams >= 1) teams |= BIT(0);
 985         if(kh_teams >= 2) teams |= BIT(1);
 986         if(kh_teams >= 3) teams |= BIT(2);
 987         if(kh_teams >= 4) teams |= BIT(3);
 988
 989         kh_teams = teams; // now set it?
 990
 991         // make a KH entity for controlling the game
 992         kh_controller = spawn();
 993         setthink(kh_controller, kh_Controller_Think);
 994         kh_Controller_SetThink(0, kh_WaitForPlayers);
 995
 996         setmodel(kh_controller, MDL_KH_KEY);
 997         kh_key_dropped = kh_controller.modelindex;
 998         /*
 999         dprint(vtos(kh_controller.mins));
1000         dprint(vtos(kh_controller.maxs));
1001         dprint("\n");
1002         */
1003 #ifdef KH_PLAYER_USE_CARRIEDMODEL
1004         setmodel(kh_controller, MDL_KH_KEY_CARRIED);
1005         kh_key_carried = kh_controller.modelindex;
1006 #else
1007         kh_key_carried = kh_key_dropped;
1008 #endif
1009
1010         kh_controller.model = "";
1011         kh_controller.modelindex = 0;
1012
1013         kh_ScoreRules(kh_teams);
1014 }
1015
1016 void kh_finalize()
1017 {
1018         // to be called before intermission
1019         kh_FinishRound();
1020         delete(kh_controller);
1021         kh_controller = NULL;
1022 }
1023
1024 // legacy bot role
1025
1026 void(entity this) havocbot_role_kh_carrier;
1027 void(entity this) havocbot_role_kh_defense;
1028 void(entity this) havocbot_role_kh_offense;
1029 void(entity this) havocbot_role_kh_freelancer;
1030
1031
1032 void havocbot_goalrating_kh(entity this, float ratingscale_team, float ratingscale_dropped, float ratingscale_enemy)
1033 {
1034         entity head;
1035         for (head = kh_worldkeylist; head; head = head.kh_worldkeynext)
1036         {
1037                 if(head.owner == this)
1038                         continue;
1039                 if(!kh_tracking_enabled)
1040                 {
1041                         // if it's carried by our team we know about it
1042                         // otherwise we have to see it to know about it
1043                         if(!head.owner || head.team != this.team)
1044                         {
1045                                 traceline(this.origin + this.view_ofs, head.origin, MOVE_NOMONSTERS, this);
1046                                 if (trace_fraction < 1 && trace_ent != head)
1047                                         continue; // skip what I can't see
1048                         }
1049                 }
1050                 if(!head.owner)
1051                         navigation_routerating(this, head, ratingscale_dropped * BOT_PICKUP_RATING_HIGH, 100000);
1052                 else if(head.team == this.team)
1053                         navigation_routerating(this, head.owner, ratingscale_team * BOT_PICKUP_RATING_HIGH, 100000);
1054                 else
1055                         navigation_routerating(this, head.owner, ratingscale_enemy * BOT_PICKUP_RATING_HIGH, 100000);
1056         }
1057
1058         havocbot_goalrating_items(this, 1, this.origin, 10000);
1059 }
1060
1061 void havocbot_role_kh_carrier(entity this)
1062 {
1063         if(IS_DEAD(this))
1064                 return;
1065
1066         if (!(this.kh_next))
1067         {
1068                 LOG_TRACE("changing role to freelancer");
1069                 this.havocbot_role = havocbot_role_kh_freelancer;
1070                 this.havocbot_role_timeout = 0;
1071                 return;
1072         }
1073
1074         if (this.bot_strategytime < time)
1075         {
1076                 this.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
1077                 navigation_goalrating_start(this);
1078
1079                 if(kh_Key_AllOwnedByWhichTeam() == this.team)
1080                         havocbot_goalrating_kh(this, 10, 0.1, 0.1); // bring home
1081                 else
1082                         havocbot_goalrating_kh(this, 4, 4, 1); // play defensively
1083
1084                 navigation_goalrating_end(this);
1085         }
1086 }
1087
1088 void havocbot_role_kh_defense(entity this)
1089 {
1090         if(IS_DEAD(this))
1091                 return;
1092
1093         if (this.kh_next)
1094         {
1095                 LOG_TRACE("changing role to carrier");
1096                 this.havocbot_role = havocbot_role_kh_carrier;
1097                 this.havocbot_role_timeout = 0;
1098                 return;
1099         }
1100
1101         if (!this.havocbot_role_timeout)
1102                 this.havocbot_role_timeout = time + random() * 10 + 20;
1103         if (time > this.havocbot_role_timeout)
1104         {
1105                 LOG_TRACE("changing role to freelancer");
1106                 this.havocbot_role = havocbot_role_kh_freelancer;
1107                 this.havocbot_role_timeout = 0;
1108                 return;
1109         }
1110
1111         if (this.bot_strategytime < time)
1112         {
1113                 float key_owner_team;
1114                 this.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
1115                 navigation_goalrating_start(this);
1116
1117                 key_owner_team = kh_Key_AllOwnedByWhichTeam();
1118                 if(key_owner_team == this.team)
1119                         havocbot_goalrating_kh(this, 10, 0.1, 0.1); // defend key carriers
1120                 else if(key_owner_team == -1)
1121                         havocbot_goalrating_kh(this, 4, 1, 0.1); // play defensively
1122                 else
1123                         havocbot_goalrating_kh(this, 0.1, 0.1, 10); // ATTACK ANYWAY
1124
1125                 navigation_goalrating_end(this);
1126         }
1127 }
1128
1129 void havocbot_role_kh_offense(entity this)
1130 {
1131         if(IS_DEAD(this))
1132                 return;
1133
1134         if (this.kh_next)
1135         {
1136                 LOG_TRACE("changing role to carrier");
1137                 this.havocbot_role = havocbot_role_kh_carrier;
1138                 this.havocbot_role_timeout = 0;
1139                 return;
1140         }
1141
1142         if (!this.havocbot_role_timeout)
1143                 this.havocbot_role_timeout = time + random() * 10 + 20;
1144         if (time > this.havocbot_role_timeout)
1145         {
1146                 LOG_TRACE("changing role to freelancer");
1147                 this.havocbot_role = havocbot_role_kh_freelancer;
1148                 this.havocbot_role_timeout = 0;
1149                 return;
1150         }
1151
1152         if (this.bot_strategytime < time)
1153         {
1154                 float key_owner_team;
1155
1156                 this.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
1157                 navigation_goalrating_start(this);
1158
1159                 key_owner_team = kh_Key_AllOwnedByWhichTeam();
1160                 if(key_owner_team == this.team)
1161                         havocbot_goalrating_kh(this, 10, 0.1, 0.1); // defend anyway
1162                 else if(key_owner_team == -1)
1163                         havocbot_goalrating_kh(this, 0.1, 1, 4); // play offensively
1164                 else
1165                         havocbot_goalrating_kh(this, 0.1, 0.1, 10); // ATTACK! EMERGENCY!
1166
1167                 navigation_goalrating_end(this);
1168         }
1169 }
1170
1171 void havocbot_role_kh_freelancer(entity this)
1172 {
1173         if(IS_DEAD(this))
1174                 return;
1175
1176         if (this.kh_next)
1177         {
1178                 LOG_TRACE("changing role to carrier");
1179                 this.havocbot_role = havocbot_role_kh_carrier;
1180                 this.havocbot_role_timeout = 0;
1181                 return;
1182         }
1183
1184         if (!this.havocbot_role_timeout)
1185                 this.havocbot_role_timeout = time + random() * 10 + 10;
1186         if (time > this.havocbot_role_timeout)
1187         {
1188                 if (random() < 0.5)
1189                 {
1190                         LOG_TRACE("changing role to offense");
1191                         this.havocbot_role = havocbot_role_kh_offense;
1192                 }
1193                 else
1194                 {
1195                         LOG_TRACE("changing role to defense");
1196                         this.havocbot_role = havocbot_role_kh_defense;
1197                 }
1198                 this.havocbot_role_timeout = 0;
1199                 return;
1200         }
1201
1202         if (this.bot_strategytime < time)
1203         {
1204                 this.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
1205                 navigation_goalrating_start(this);
1206
1207                 int key_owner_team = kh_Key_AllOwnedByWhichTeam();
1208                 if(key_owner_team == this.team)
1209                         havocbot_goalrating_kh(this, 10, 0.1, 0.1); // defend anyway
1210                 else if(key_owner_team == -1)
1211                         havocbot_goalrating_kh(this, 1, 10, 4); // prefer dropped keys
1212                 else
1213                         havocbot_goalrating_kh(this, 0.1, 0.1, 10); // ATTACK ANYWAY
1214
1215                 navigation_goalrating_end(this);
1216         }
1217 }
1218
1219
1220 // register this as a mutator
1221
1222 MUTATOR_HOOKFUNCTION(kh, ClientDisconnect)
1223 {
1224         entity player = M_ARGV(0, entity);
1225
1226         kh_Key_DropAll(player, true);
1227 }
1228
1229 MUTATOR_HOOKFUNCTION(kh, MakePlayerObserver)
1230 {
1231         entity player = M_ARGV(0, entity);
1232
1233         kh_Key_DropAll(player, true);
1234 }
1235
1236 MUTATOR_HOOKFUNCTION(kh, PlayerDies)
1237 {
1238         entity frag_attacker = M_ARGV(1, entity);
1239         entity frag_target = M_ARGV(2, entity);
1240
1241         if(frag_target == frag_attacker)
1242                 kh_Key_DropAll(frag_target, true);
1243         else if(IS_PLAYER(frag_attacker))
1244                 kh_Key_DropAll(frag_target, false);
1245         else
1246                 kh_Key_DropAll(frag_target, true);
1247 }
1248
1249 MUTATOR_HOOKFUNCTION(kh, GiveFragsForKill, CBC_ORDER_FIRST)
1250 {
1251         entity frag_attacker = M_ARGV(0, entity);
1252         entity frag_target = M_ARGV(1, entity);
1253         float frag_score = M_ARGV(2, float);
1254         M_ARGV(2, float) = kh_HandleFrags(frag_attacker, frag_target, frag_score);
1255 }
1256
1257 MUTATOR_HOOKFUNCTION(kh, MatchEnd)
1258 {
1259         kh_finalize();
1260 }
1261
1262 MUTATOR_HOOKFUNCTION(kh, CheckAllowedTeams, CBC_ORDER_EXCLUSIVE)
1263 {
1264         M_ARGV(0, float) = kh_teams;
1265 }
1266
1267 MUTATOR_HOOKFUNCTION(kh, SpectateCopy)
1268 {
1269         entity spectatee = M_ARGV(0, entity);
1270         entity client = M_ARGV(1, entity);
1271
1272         client.kh_state = spectatee.kh_state;
1273 }
1274
1275 MUTATOR_HOOKFUNCTION(kh, PlayerUseKey)
1276 {
1277         entity player = M_ARGV(0, entity);
1278
1279         if(MUTATOR_RETURNVALUE == 0)
1280         {
1281                 entity k = player.kh_next;
1282                 if(k)
1283                 {
1284                         kh_Key_DropOne(k);
1285                         return true;
1286                 }
1287         }
1288 }
1289
1290 MUTATOR_HOOKFUNCTION(kh, HavocBot_ChooseRole)
1291 {
1292     entity bot = M_ARGV(0, entity);
1293
1294         if(IS_DEAD(bot))
1295                 return true;
1296
1297         float r = random() * 3;
1298         if (r < 1)
1299                 bot.havocbot_role = havocbot_role_kh_offense;
1300         else if (r < 2)
1301                 bot.havocbot_role = havocbot_role_kh_defense;
1302         else
1303                 bot.havocbot_role = havocbot_role_kh_freelancer;
1304
1305         return true;
1306 }
1307
1308 MUTATOR_HOOKFUNCTION(kh, DropSpecialItems)
1309 {
1310         entity frag_target = M_ARGV(0, entity);
1311
1312         kh_Key_DropAll(frag_target, false);
1313 }
1314
1315 MUTATOR_HOOKFUNCTION(kh, reset_map_global)
1316 {
1317         kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round + (game_starttime - time), kh_StartRound);
1318 }