qcsrc/server/mutators/mutator/gamemode_lms.qc

   1 #ifndef GAMEMODE_LMS_H
   2 #define GAMEMODE_LMS_H
   3
   4 #define autocvar_g_lms_lives_override cvar("g_lms_lives_override")
   5 void lms_Initialize();
   6
   7 REGISTER_MUTATOR(lms, false)
   8 {
   9         SetLimits(((!autocvar_g_lms_lives_override) ? -1 : autocvar_g_lms_lives_override), 0, -1, -1);
  10
  11         MUTATOR_ONADD
  12         {
  13                 if (time > 1) // game loads at time 1
  14                         error("This is a game type and it cannot be added at runtime.");
  15                 lms_Initialize();
  16         }
  17
  18         MUTATOR_ONROLLBACK_OR_REMOVE
  19         {
  20                 // we actually cannot roll back lms_Initialize here
  21                 // BUT: we don't need to! If this gets called, adding always
  22                 // succeeds.
  23         }
  24
  25         MUTATOR_ONREMOVE
  26         {
  27                 LOG_INFO("This is a game type and it cannot be removed at runtime.");
  28                 return -1;
  29         }
  30
  31         return 0;
  32 }
  33
  34 // scoreboard stuff
  35 const float SP_LMS_LIVES = 4;
  36 const float SP_LMS_RANK = 5;
  37
  38 // lives related defs
  39 float lms_lowest_lives;
  40 float lms_next_place;
  41 float LMS_NewPlayerLives();
  42
  43 #endif
  44
  45 #ifdef IMPLEMENTATION
  46
  47 #include "../../campaign.qh"
  48 #include "../../command/cmd.qh"
  49
  50 int autocvar_g_lms_extra_lives;
  51 bool autocvar_g_lms_join_anytime;
  52 int autocvar_g_lms_last_join;
  53 bool autocvar_g_lms_regenerate;
  54
  55 // main functions
  56 float LMS_NewPlayerLives()
  57 {
  58         float fl;
  59         fl = autocvar_fraglimit;
  60         if(fl == 0)
  61                 fl = 999;
  62
  63         // first player has left the game for dying too much? Nobody else can get in.
  64         if(lms_lowest_lives < 1)
  65                 return 0;
  66
  67         if(!autocvar_g_lms_join_anytime)
  68                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
  69                         return 0;
  70
  71         return bound(1, lms_lowest_lives, fl);
  72 }
  73
  74 // LMS winning condition: game terminates if and only if there's at most one
  75 // one player who's living lives. Top two scores being equal cancels the time
  76 // limit.
  77 float WinningCondition_LMS()
  78 {
  79         entity head, head2;
  80         float have_player;
  81         float have_players;
  82         float l;
  83
  84         have_player = false;
  85         have_players = false;
  86         l = LMS_NewPlayerLives();
  87
  88         head = find(world, classname, "player");
  89         if(head)
  90                 have_player = true;
  91         head2 = find(head, classname, "player");
  92         if(head2)
  93                 have_players = true;
  94
  95         if(have_player)
  96         {
  97                 // we have at least one player
  98                 if(have_players)
  99                 {
 100                         // two or more active players - continue with the game
 101                 }
 102                 else
 103                 {
 104                         // exactly one player?
 105
 106                         ClearWinners();
 107                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
 108
 109                         if(l)
 110                         {
 111                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
 112                                 return WINNING_NO;
 113                         }
 114                         else
 115                         {
 116                                 // a winner!
 117                                 // and assign him his first place
 118                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
 119                                 return WINNING_YES;
 120                         }
 121                 }
 122         }
 123         else
 124         {
 125                 // nobody is playing at all...
 126                 if(l)
 127                 {
 128                         // wait for players...
 129                 }
 130                 else
 131                 {
 132                         // SNAFU (maybe a draw game?)
 133                         ClearWinners();
 134                         LOG_TRACE("No players, ending game.\n");
 135                         return WINNING_YES;
 136                 }
 137         }
 138
 139         // When we get here, we have at least two players who are actually LIVING,
 140         // now check if the top two players have equal score.
 141         WinningConditionHelper();
 142
 143         ClearWinners();
 144         if(WinningConditionHelper_winner)
 145                 WinningConditionHelper_winner.winning = true;
 146         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
 147                 return WINNING_NEVER;
 148
 149         // Top two have different scores? Way to go for our beloved TIMELIMIT!
 150         return WINNING_NO;
 151 }
 152
 153 // mutator hooks
 154 MUTATOR_HOOKFUNCTION(lms, reset_map_global)
 155 {
 156         lms_lowest_lives = 999;
 157         lms_next_place = player_count;
 158
 159         return false;
 160 }
 161
 162 MUTATOR_HOOKFUNCTION(lms, reset_map_players)
 163 {SELFPARAM();
 164         entity e;
 165         if(restart_mapalreadyrestarted || (time < game_starttime))
 166         FOR_EACH_CLIENT(e)
 167         if(IS_PLAYER(e))
 168         {
 169                 WITH(entity, self, e, PlayerScore_Add(e, SP_LMS_LIVES, LMS_NewPlayerLives()));
 170         }
 171
 172         return false;
 173 }
 174
 175 MUTATOR_HOOKFUNCTION(lms, PutClientInServer)
 176 {SELFPARAM();
 177         // player is dead and becomes observer
 178         // FIXME fix LMS scoring for new system
 179         if(PlayerScore_Add(self, SP_LMS_RANK, 0) > 0)
 180         {
 181                 self.classname = "observer";
 182                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_LMS_NOLIVES);
 183         }
 184
 185         return false;
 186 }
 187
 188 MUTATOR_HOOKFUNCTION(lms, PlayerDies)
 189 {SELFPARAM();
 190         self.respawn_flags |= RESPAWN_FORCE;
 191
 192         return false;
 193 }
 194
 195 void lms_RemovePlayer(entity player)
 196 {
 197         // Only if the player cannot play at all
 198         if(PlayerScore_Add(player, SP_LMS_RANK, 0) == 666)
 199                 player.frags = FRAGS_SPECTATOR;
 200         else
 201                 player.frags = FRAGS_LMS_LOSER;
 202
 203         if(player.killcount != -666)
 204                 if(PlayerScore_Add(player, SP_LMS_RANK, 0) > 0 && player.lms_spectate_warning != 2)
 205                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_LMS_NOLIVES, player.netname);
 206                 else
 207                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_LMS_FORFEIT, player.netname);
 208 }
 209
 210 MUTATOR_HOOKFUNCTION(lms, ClientDisconnect)
 211 {SELFPARAM();
 212         lms_RemovePlayer(self);
 213         return false;
 214 }
 215
 216 MUTATOR_HOOKFUNCTION(lms, MakePlayerObserver)
 217 {SELFPARAM();
 218         lms_RemovePlayer(self);
 219         return false;
 220 }
 221
 222 MUTATOR_HOOKFUNCTION(lms, ClientConnect)
 223 {SELFPARAM();
 224         self.classname = "player";
 225         campaign_bots_may_start = 1;
 226
 227         if(PlayerScore_Add(self, SP_LMS_LIVES, LMS_NewPlayerLives()) <= 0)
 228         {
 229                 PlayerScore_Add(self, SP_LMS_RANK, 666);
 230                 self.frags = FRAGS_SPECTATOR;
 231         }
 232
 233         return false;
 234 }
 235
 236 MUTATOR_HOOKFUNCTION(lms, PlayerPreThink)
 237 {SELFPARAM();
 238         if(self.deadflag == DEAD_DYING)
 239                 self.deadflag = DEAD_RESPAWNING;
 240
 241         return false;
 242 }
 243
 244 MUTATOR_HOOKFUNCTION(lms, PlayerRegen)
 245 {
 246         if(autocvar_g_lms_regenerate)
 247                 return false;
 248         return true;
 249 }
 250
 251 MUTATOR_HOOKFUNCTION(lms, ForbidThrowCurrentWeapon)
 252 {
 253         // forbode!
 254         return true;
 255 }
 256
 257 MUTATOR_HOOKFUNCTION(lms, GiveFragsForKill)
 258 {
 259         // remove a life
 260         float tl;
 261         tl = PlayerScore_Add(frag_target, SP_LMS_LIVES, -1);
 262         if(tl < lms_lowest_lives)
 263                 lms_lowest_lives = tl;
 264         if(tl <= 0)
 265         {
 266                 if(!lms_next_place)
 267                         lms_next_place = player_count;
 268                 else
 269                         lms_next_place = min(lms_next_place, player_count);
 270                 PlayerScore_Add(frag_target, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 271                 --lms_next_place;
 272         }
 273         frag_score = 0;
 274
 275         return true;
 276 }
 277
 278 MUTATOR_HOOKFUNCTION(lms, SetStartItems)
 279 {
 280         start_items &= ~IT_UNLIMITED_AMMO;
 281         start_health       = warmup_start_health       = cvar("g_lms_start_health");
 282         start_armorvalue   = warmup_start_armorvalue   = cvar("g_lms_start_armor");
 283         start_ammo_shells  = warmup_start_ammo_shells  = cvar("g_lms_start_ammo_shells");
 284         start_ammo_nails   = warmup_start_ammo_nails   = cvar("g_lms_start_ammo_nails");
 285         start_ammo_rockets = warmup_start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 286         start_ammo_cells   = warmup_start_ammo_cells   = cvar("g_lms_start_ammo_cells");
 287         start_ammo_plasma  = warmup_start_ammo_plasma  = cvar("g_lms_start_ammo_plasma");
 288         start_ammo_fuel    = warmup_start_ammo_fuel    = cvar("g_lms_start_ammo_fuel");
 289
 290         return false;
 291 }
 292
 293 MUTATOR_HOOKFUNCTION(lms, ForbidPlayerScore_Clear)
 294 {
 295         // don't clear player score
 296         return true;
 297 }
 298
 299 MUTATOR_HOOKFUNCTION(lms, FilterItem)
 300 {SELFPARAM();
 301         if(autocvar_g_lms_extra_lives)
 302         if(self.itemdef == ITEM_HealthMega)
 303         {
 304                 self.max_health = 1;
 305                 return false;
 306         }
 307
 308         return true;
 309 }
 310
 311 MUTATOR_HOOKFUNCTION(lms, ItemTouch)
 312 {SELFPARAM();
 313         // give extra lives for mega health
 314         if (self.items & ITEM_HealthMega.m_itemid)
 315         {
 316                 Send_Notification(NOTIF_ONE, other, MSG_CENTER, CENTER_EXTRALIVES);
 317                 PlayerScore_Add(other, SP_LMS_LIVES, autocvar_g_lms_extra_lives);
 318         }
 319
 320         return MUT_ITEMTOUCH_CONTINUE;
 321 }
 322
 323 MUTATOR_HOOKFUNCTION(lms, Bot_FixCount, CBC_ORDER_EXCLUSIVE)
 324 {
 325         entity head;
 326         FOR_EACH_REALCLIENT(head)
 327         {
 328                 ++bot_activerealplayers;
 329                 ++bot_realplayers;
 330         }
 331
 332         return true;
 333 }
 334
 335 MUTATOR_HOOKFUNCTION(lms, ClientCommand_Spectate)
 336 {
 337         if(self.lms_spectate_warning)
 338         {
 339                 // for the forfeit message...
 340                 self.lms_spectate_warning = 2;
 341                 // mark player as spectator
 342                 PlayerScore_Add(self, SP_LMS_RANK, 666 - PlayerScore_Add(self, SP_LMS_RANK, 0));
 343         }
 344         else
 345         {
 346                 self.lms_spectate_warning = 1;
 347                 sprint(self, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
 348                 return MUT_SPECCMD_RETURN;
 349         }
 350         return MUT_SPECCMD_CONTINUE;
 351 }
 352
 353 MUTATOR_HOOKFUNCTION(lms, CheckRules_World)
 354 {
 355         ret_float = WinningCondition_LMS();
 356         return true;
 357 }
 358
 359 MUTATOR_HOOKFUNCTION(lms, WantWeapon)
 360 {
 361         want_allguns = true;
 362         return false;
 363 }
 364
 365 MUTATOR_HOOKFUNCTION(lms, GetPlayerStatus)
 366 {
 367         return true;
 368 }
 369
 370 MUTATOR_HOOKFUNCTION(lms, AddPlayerScore)
 371 {
 372         if(gameover)
 373         if(score_field == SP_LMS_RANK)
 374                 return true; // allow writing to this field in intermission as it is needed for newly joining players
 375         return false;
 376 }
 377
 378 // scoreboard stuff
 379 void lms_ScoreRules()
 380 {
 381         ScoreRules_basics(0, 0, 0, false);
 382         ScoreInfo_SetLabel_PlayerScore(SP_LMS_LIVES,    "lives",     SFL_SORT_PRIO_SECONDARY);
 383         ScoreInfo_SetLabel_PlayerScore(SP_LMS_RANK,     "rank",      SFL_LOWER_IS_BETTER | SFL_RANK | SFL_SORT_PRIO_PRIMARY | SFL_ALLOW_HIDE);
 384         ScoreRules_basics_end();
 385 }
 386
 387 void lms_Initialize()
 388 {
 389         lms_lowest_lives = 9999;
 390         lms_next_place = 0;
 391
 392         lms_ScoreRules();
 393 }
 394
 395
 396 #endif