qcsrc/server/mutators/mutator_buffs.qc

   1 #include "../../common/triggers/target/music.qh"
   2 #include "mutator_buffs.qh"
   3 #include "../_all.qh"
   4
   5 #include "mutator.qh"
   6
   7 #include "../../common/buffs.qh"
   8
   9 float buffs_BuffModel_Customize()
  10 {
  11         entity player, myowner;
  12         float same_team;
  13
  14         player = WaypointSprite_getviewentity(other);
  15         myowner = self.owner;
  16         same_team = (SAME_TEAM(player, myowner) || SAME_TEAM(player, myowner));
  17
  18         if(myowner.alpha <= 0.5 && !same_team && myowner.alpha != 0)
  19                 return false;
  20
  21         if(player == myowner || (IS_SPEC(other) && other.enemy == myowner))
  22         {
  23                 // somewhat hide the model, but keep the glow
  24                 self.effects = 0;
  25                 self.alpha = -1;
  26         }
  27         else
  28         {
  29                 self.effects = EF_FULLBRIGHT | EF_LOWPRECISION;
  30                 self.alpha = 1;
  31         }
  32         return true;
  33 }
  34
  35 void buffs_BuffModel_Spawn(entity player)
  36 {
  37         player.buff_model = spawn();
  38         setmodel(player.buff_model, BUFF_MODEL);
  39         setsize(player.buff_model, '0 0 -40', '0 0 40');
  40         setattachment(player.buff_model, player, "");
  41         setorigin(player.buff_model, '0 0 1' * (player.buff_model.maxs.z * 1));
  42         player.buff_model.owner = player;
  43         player.buff_model.scale = 0.7;
  44         player.buff_model.pflags = PFLAGS_FULLDYNAMIC;
  45         player.buff_model.light_lev = 200;
  46         player.buff_model.customizeentityforclient = buffs_BuffModel_Customize;
  47 }
  48
  49 vector buff_GlowColor(entity buff)
  50 {
  51         //if(buff.team) { return Team_ColorRGB(buff.team); }
  52         return buff.color;
  53 }
  54
  55 void buff_Effect(entity player, string eff)
  56 {
  57         if(!autocvar_g_buffs_effects) { return; }
  58
  59         if(time >= self.buff_effect_delay)
  60         {
  61                 pointparticles(particleeffectnum(eff), player.origin + ((player.mins + player.maxs) * 0.5), '0 0 0', 1);
  62                 self.buff_effect_delay = time + 0.05; // prevent spam
  63         }
  64 }
  65
  66 // buff item
  67 float buff_Waypoint_visible_for_player(entity plr)
  68 {
  69     if(!self.owner.buff_active && !self.owner.buff_activetime)
  70         return false;
  71
  72         if(plr.buffs)
  73         {
  74                 if(plr.cvar_cl_buffs_autoreplace)
  75                 {
  76                         if(plr.buffs == self.owner.buffs)
  77                                 return false;
  78                 }
  79                 else
  80                         return false;
  81         }
  82
  83     return WaypointSprite_visible_for_player(plr);
  84 }
  85
  86 void buff_Waypoint_Spawn(entity e)
  87 {
  88     WaypointSprite_Spawn(Buff_Sprite(e.buffs), 0, autocvar_g_buffs_waypoint_distance, e, '0 0 1' * e.maxs.z, world, e.team, e, buff_waypoint, true, RADARICON_POWERUP, e.glowmod);
  89     WaypointSprite_UpdateTeamRadar(e.buff_waypoint, RADARICON_POWERUP, e.glowmod);
  90     e.buff_waypoint.waypointsprite_visible_for_player = buff_Waypoint_visible_for_player;
  91 }
  92
  93 void buff_SetCooldown(float cd)
  94 {
  95         cd = max(0, cd);
  96
  97         if(!self.buff_waypoint)
  98                 buff_Waypoint_Spawn(self);
  99
 100         WaypointSprite_UpdateBuildFinished(self.buff_waypoint, time + cd);
 101         self.buff_activetime = cd;
 102         self.buff_active = !cd;
 103 }
 104
 105 void buff_Respawn(entity ent)
 106 {
 107         if(gameover) { return; }
 108
 109         vector oldbufforigin = ent.origin;
 110
 111         if(!MoveToRandomMapLocation(ent, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY, ((autocvar_g_buffs_random_location_attempts > 0) ? autocvar_g_buffs_random_location_attempts : 10), 1024, 256))
 112         {
 113                 entity spot = SelectSpawnPoint(true);
 114                 setorigin(ent, ((spot.origin + '0 0 200') + (randomvec() * 300)));
 115                 ent.angles = spot.angles;
 116         }
 117
 118         tracebox(ent.origin, ent.mins * 1.5, self.maxs * 1.5, ent.origin, MOVE_NOMONSTERS, ent);
 119
 120         setorigin(ent, trace_endpos); // attempt to unstick
 121
 122         ent.movetype = MOVETYPE_TOSS;
 123
 124         makevectors(ent.angles);
 125         ent.velocity = '0 0 200';
 126         ent.angles = '0 0 0';
 127         if(autocvar_g_buffs_random_lifetime > 0)
 128                 ent.lifetime = time + autocvar_g_buffs_random_lifetime;
 129
 130         pointparticles(particleeffectnum("electro_combo"), oldbufforigin + ((ent.mins + ent.maxs) * 0.5), '0 0 0', 1);
 131         pointparticles(particleeffectnum("electro_combo"), CENTER_OR_VIEWOFS(ent), '0 0 0', 1);
 132
 133         WaypointSprite_Ping(ent.buff_waypoint);
 134
 135         sound(ent, CH_TRIGGER, "keepaway/respawn.wav", VOL_BASE, ATTEN_NONE); // ATTEN_NONE (it's a sound intended to be heard anywhere)
 136 }
 137
 138 void buff_Touch()
 139 {
 140         if(gameover) { return; }
 141
 142         if(ITEM_TOUCH_NEEDKILL())
 143         {
 144                 buff_Respawn(self);
 145                 return;
 146         }
 147
 148         if((self.team && DIFF_TEAM(other, self))
 149         || (other.frozen)
 150         || (other.vehicle)
 151         || (!IS_PLAYER(other))
 152         || (!self.buff_active)
 153         )
 154         {
 155                 // can't touch this
 156                 return;
 157         }
 158
 159         if(other.buffs)
 160         {
 161                 if(other.cvar_cl_buffs_autoreplace && other.buffs != self.buffs)
 162                 {
 163                         //Send_Notification(NOTIF_ONE, other, MSG_MULTI, ITEM_BUFF_DROP, other.buffs);
 164                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ITEM_BUFF_LOST, other.netname, other.buffs);
 165
 166                         other.buffs = 0;
 167                         //sound(other, CH_TRIGGER, "relics/relic_effect.wav", VOL_BASE, ATTN_NORM);
 168                 }
 169                 else { return; } // do nothing
 170         }
 171
 172         self.owner = other;
 173         self.buff_active = false;
 174         self.lifetime = 0;
 175
 176         Send_Notification(NOTIF_ONE, other, MSG_MULTI, ITEM_BUFF_GOT, self.buffs);
 177         Send_Notification(NOTIF_ALL_EXCEPT, other, MSG_INFO, INFO_ITEM_BUFF, other.netname, self.buffs);
 178
 179         pointparticles(particleeffectnum("item_pickup"), CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 180         sound(other, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);
 181         other.buffs |= (self.buffs);
 182 }
 183
 184 float buff_Available(float buffid)
 185 {
 186         if(buffid == BUFF_AMMO && ((start_items & IT_UNLIMITED_WEAPON_AMMO) || (start_items & IT_UNLIMITED_AMMO) || (cvar("g_melee_only"))))
 187                 return false;
 188
 189         if(buffid == BUFF_VAMPIRE && cvar("g_vampire"))
 190                 return false;
 191
 192         if(!cvar(strcat("g_buffs_", Buff_Name(buffid))))
 193                 return false;
 194
 195         return true;
 196 }
 197
 198 void buff_NewType(entity ent, float cb)
 199 {
 200         entity e;
 201         RandomSelection_Init();
 202         for(e = Buff_Type_first; e; e = e.enemy)
 203         if(buff_Available(e.items))
 204         {
 205                 RandomSelection_Add(world, e.items, string_null, 1, max(0.2, 1 / e.count)); // if it's already been chosen, give it a lower priority
 206                 e.count += 1;
 207         }
 208         ent.buffs = RandomSelection_chosen_float;
 209 }
 210
 211 void buff_Think()
 212 {
 213         if(self.buffs != self.oldbuffs)
 214         {
 215                 self.color = Buff_Color(self.buffs);
 216                 self.glowmod = buff_GlowColor(self);
 217                 self.skin = Buff_Skin(self.buffs);
 218
 219                 setmodel(self, BUFF_MODEL);
 220
 221                 if(self.buff_waypoint)
 222                 {
 223                         //WaypointSprite_Disown(self.buff_waypoint, 1);
 224                         WaypointSprite_Kill(self.buff_waypoint);
 225                         buff_Waypoint_Spawn(self);
 226                         if(self.buff_activetime)
 227                                 WaypointSprite_UpdateBuildFinished(self.buff_waypoint, time + self.buff_activetime - frametime);
 228                 }
 229
 230                 self.oldbuffs = self.buffs;
 231         }
 232
 233         if(!gameover)
 234         if((round_handler_IsActive() && !round_handler_IsRoundStarted()) || time >= game_starttime)
 235         if(!self.buff_activetime_updated)
 236         {
 237                 buff_SetCooldown(self.buff_activetime);
 238                 self.buff_activetime_updated = true;
 239     }
 240
 241         if(!self.buff_active && !self.buff_activetime)
 242         if(!self.owner || self.owner.frozen || self.owner.deadflag != DEAD_NO || !self.owner.iscreature || !(self.owner.buffs & self.buffs))
 243         {
 244                 buff_SetCooldown(autocvar_g_buffs_cooldown_respawn + frametime);
 245                 self.owner = world;
 246                 if(autocvar_g_buffs_randomize)
 247                         buff_NewType(self, self.buffs);
 248
 249                 if(autocvar_g_buffs_random_location || (self.spawnflags & 64))
 250                         buff_Respawn(self);
 251         }
 252
 253         if(self.buff_activetime)
 254         if(!gameover)
 255         if((round_handler_IsActive() && !round_handler_IsRoundStarted()) || time >= game_starttime)
 256         {
 257                 self.buff_activetime = max(0, self.buff_activetime - frametime);
 258
 259                 if(!self.buff_activetime)
 260                 {
 261                         self.buff_active = true;
 262                         sound(self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);
 263                         pointparticles(particleeffectnum("item_respawn"), CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 264                 }
 265         }
 266
 267         if(self.buff_active)
 268         {
 269                 if(self.team && !self.buff_waypoint)
 270                         buff_Waypoint_Spawn(self);
 271
 272                 if(self.lifetime)
 273                 if(time >= self.lifetime)
 274                         buff_Respawn(self);
 275         }
 276
 277         self.nextthink = time;
 278         //self.angles_y = time * 110.1;
 279 }
 280
 281 void buff_Waypoint_Reset()
 282 {
 283         WaypointSprite_Kill(self.buff_waypoint);
 284
 285         if(self.buff_activetime) { buff_Waypoint_Spawn(self); }
 286 }
 287
 288 void buff_Reset()
 289 {
 290         if(autocvar_g_buffs_randomize)
 291                 buff_NewType(self, self.buffs);
 292         self.owner = world;
 293         buff_SetCooldown(autocvar_g_buffs_cooldown_activate);
 294         buff_Waypoint_Reset();
 295         self.buff_activetime_updated = false;
 296
 297         if(autocvar_g_buffs_random_location || (self.spawnflags & 64))
 298                 buff_Respawn(self);
 299 }
 300
 301 float buff_Customize()
 302 {
 303         entity player = WaypointSprite_getviewentity(other);
 304         if(!self.buff_active || (self.team && DIFF_TEAM(player, self)))
 305         {
 306                 self.alpha = 0.3;
 307                 if(self.effects & EF_FULLBRIGHT) { self.effects &= ~(EF_FULLBRIGHT); }
 308                 self.pflags = 0;
 309         }
 310         else
 311         {
 312                 self.alpha = 1;
 313                 if(!(self.effects & EF_FULLBRIGHT)) { self.effects |= EF_FULLBRIGHT; }
 314                 self.light_lev = 220 + 36 * sin(time);
 315                 self.pflags = PFLAGS_FULLDYNAMIC;
 316         }
 317         return true;
 318 }
 319
 320 void buff_Init(entity ent)
 321 {
 322         if(!cvar("g_buffs")) { remove(ent); return; }
 323
 324         if(!teamplay && ent.team) { ent.team = 0; }
 325
 326         entity oldself = self;
 327         self = ent;
 328         if(!self.buffs || buff_Available(self.buffs))
 329                 buff_NewType(self, 0);
 330
 331         self.classname = "item_buff";
 332         self.solid = SOLID_TRIGGER;
 333         self.flags = FL_ITEM;
 334         self.think = buff_Think;
 335         self.touch = buff_Touch;
 336         self.reset = buff_Reset;
 337         self.nextthink = time + 0.1;
 338         self.gravity = 1;
 339         self.movetype = MOVETYPE_TOSS;
 340         self.scale = 1;
 341         self.skin = Buff_Skin(self.buffs);
 342         self.effects = EF_FULLBRIGHT | EF_STARDUST | EF_NOSHADOW;
 343         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
 344         self.customizeentityforclient = buff_Customize;
 345         //self.gravity = 100;
 346         self.color = Buff_Color(self.buffs);
 347         self.glowmod = buff_GlowColor(self);
 348         buff_SetCooldown(autocvar_g_buffs_cooldown_activate + game_starttime);
 349         self.buff_active = !self.buff_activetime;
 350         self.pflags = PFLAGS_FULLDYNAMIC;
 351
 352         if(self.spawnflags & 1)
 353                 self.noalign = true;
 354
 355         if(self.noalign)
 356                 self.movetype = MOVETYPE_NONE; // reset by random location
 357
 358         setmodel(self, BUFF_MODEL);
 359         setsize(self, BUFF_MIN, BUFF_MAX);
 360
 361         if(cvar("g_buffs_random_location") || (self.spawnflags & 64))
 362                 buff_Respawn(self);
 363
 364         self = oldself;
 365 }
 366
 367 void buff_Init_Compat(entity ent, float replacement)
 368 {
 369         if(ent.spawnflags & 2)
 370                 ent.team = NUM_TEAM_1;
 371         else if(ent.spawnflags & 4)
 372                 ent.team = NUM_TEAM_2;
 373
 374         ent.buffs = replacement;
 375
 376         buff_Init(ent);
 377 }
 378
 379 void buff_SpawnReplacement(entity ent, entity old)
 380 {
 381         setorigin(ent, old.origin);
 382         ent.angles = old.angles;
 383         ent.noalign = (old.noalign || (old.spawnflags & 1));
 384
 385         buff_Init(ent);
 386 }
 387
 388 void buff_Vengeance_DelayedDamage()
 389 {
 390         if(self.enemy)
 391                 Damage(self.enemy, self.owner, self.owner, self.dmg, DEATH_BUFF, self.enemy.origin, '0 0 0');
 392
 393         remove(self);
 394         return;
 395 }
 396
 397 float buff_Inferno_CalculateTime(float x, float offset_x, float offset_y, float intersect_x, float intersect_y, float base)
 398 {
 399         return offset_y + (intersect_y - offset_y) * logn(((x - offset_x) * ((base - 1) / intersect_x)) + 1, base);
 400 }
 401
 402 // mutator hooks
 403 MUTATOR_HOOKFUNCTION(buffs_PlayerDamage_SplitHealthArmor)
 404 {
 405         if(frag_deathtype == DEATH_BUFF) { return false; }
 406
 407         if(frag_target.buffs & BUFF_RESISTANCE)
 408         {
 409                 vector v = healtharmor_applydamage(50, autocvar_g_buffs_resistance_blockpercent, frag_deathtype, frag_damage);
 410                 damage_take = v.x;
 411                 damage_save = v.y;
 412         }
 413
 414         return false;
 415 }
 416
 417 MUTATOR_HOOKFUNCTION(buffs_PlayerDamage_Calculate)
 418 {
 419         if(frag_deathtype == DEATH_BUFF) { return false; }
 420
 421         if(frag_target.buffs & BUFF_SPEED)
 422         if(frag_target != frag_attacker)
 423                 frag_damage *= autocvar_g_buffs_speed_damage_take;
 424
 425         if(frag_target.buffs & BUFF_MEDIC)
 426         if((frag_target.health - frag_damage) <= 0)
 427         if(!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
 428         if(frag_attacker)
 429         if(random() <= autocvar_g_buffs_medic_survive_chance)
 430                 frag_damage = max(5, frag_target.health - autocvar_g_buffs_medic_survive_health);
 431
 432         if(frag_target.buffs & BUFF_JUMP)
 433         if(frag_deathtype == DEATH_FALL)
 434                 frag_damage = 0;
 435
 436         if(frag_target.buffs & BUFF_VENGEANCE)
 437         if(frag_attacker)
 438         if(frag_attacker != frag_target)
 439         if(!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
 440         {
 441                 entity dmgent = spawn();
 442
 443                 dmgent.dmg = frag_damage * autocvar_g_buffs_vengeance_damage_multiplier;
 444                 dmgent.enemy = frag_attacker;
 445                 dmgent.owner = frag_target;
 446                 dmgent.think = buff_Vengeance_DelayedDamage;
 447                 dmgent.nextthink = time + 0.1;
 448         }
 449
 450         if(frag_target.buffs & BUFF_BASH)
 451         if(frag_attacker != frag_target)
 452         if(vlen(frag_force))
 453                 frag_force = '0 0 0';
 454
 455         if(frag_attacker.buffs & BUFF_BASH)
 456         if(vlen(frag_force))
 457         if(frag_attacker == frag_target)
 458                 frag_force *= autocvar_g_buffs_bash_force_self;
 459         else
 460                 frag_force *= autocvar_g_buffs_bash_force;
 461
 462         if(frag_attacker.buffs & BUFF_DISABILITY)
 463         if(frag_target != frag_attacker)
 464                 frag_target.buff_disability_time = time + autocvar_g_buffs_disability_slowtime;
 465
 466         if(frag_attacker.buffs & BUFF_MEDIC)
 467         if(DEATH_WEAPONOF(frag_deathtype) != WEP_ARC)
 468         if(SAME_TEAM(frag_attacker, frag_target))
 469         if(frag_attacker != frag_target)
 470         {
 471                 frag_target.health = min(g_pickup_healthmega_max, frag_target.health + frag_damage);
 472                 frag_damage = 0;
 473         }
 474
 475         if(frag_attacker.buffs & BUFF_INFERNO)
 476         if(frag_target != frag_attacker) {
 477                 float time = buff_Inferno_CalculateTime(
 478                         frag_damage,
 479                         0,
 480                         autocvar_g_buffs_inferno_burntime_min_time,
 481                         autocvar_g_buffs_inferno_burntime_target_damage,
 482                         autocvar_g_buffs_inferno_burntime_target_time,
 483                         autocvar_g_buffs_inferno_burntime_factor
 484                 );
 485                 Fire_AddDamage(frag_target, frag_attacker, (frag_damage * autocvar_g_buffs_inferno_damagemultiplier) * time, time, DEATH_BUFF);
 486         }
 487
 488         // this... is ridiculous (TODO: fix!)
 489         if(frag_attacker.buffs & BUFF_VAMPIRE)
 490         if(!frag_target.vehicle)
 491         if(DEATH_WEAPONOF(frag_deathtype) != WEP_ARC)
 492         if(!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
 493         if(frag_target.deadflag == DEAD_NO)
 494         if(IS_PLAYER(frag_target) || (frag_target.flags & FL_MONSTER))
 495         if(frag_attacker != frag_target)
 496         if(!frag_target.frozen)
 497         if(frag_target.takedamage)
 498         if(DIFF_TEAM(frag_attacker, frag_target))
 499         {
 500                 frag_attacker.health = bound(0, frag_attacker.health + bound(0, frag_damage * autocvar_g_buffs_vampire_damage_steal, frag_target.health), g_pickup_healthsmall_max);
 501                 if(frag_target.armorvalue)
 502                         frag_attacker.armorvalue = bound(0, frag_attacker.armorvalue + bound(0, frag_damage * autocvar_g_buffs_vampire_damage_steal, frag_target.armorvalue), g_pickup_armorsmall_max);
 503         }
 504
 505         return false;
 506 }
 507
 508 MUTATOR_HOOKFUNCTION(buffs_PlayerSpawn)
 509 {
 510         self.buffs = 0;
 511         // reset timers here to prevent them continuing after re-spawn
 512         self.buff_disability_time = 0;
 513         self.buff_disability_effect_time = 0;
 514         return false;
 515 }
 516
 517 MUTATOR_HOOKFUNCTION(buffs_PlayerPhysics)
 518 {
 519         if(self.buffs & BUFF_SPEED)
 520         {
 521                 self.stat_sv_maxspeed *= autocvar_g_buffs_speed_speed;
 522                 self.stat_sv_airspeedlimit_nonqw *= autocvar_g_buffs_speed_speed;
 523         }
 524
 525         if(time < self.buff_disability_time)
 526         {
 527                 self.stat_sv_maxspeed *= autocvar_g_buffs_disability_speed;
 528                 self.stat_sv_airspeedlimit_nonqw *= autocvar_g_buffs_disability_speed;
 529         }
 530
 531         if(self.buffs & BUFF_JUMP)
 532         {
 533                 // automatically reset, no need to worry
 534                 self.stat_sv_jumpvelocity = autocvar_g_buffs_jump_height;
 535         }
 536
 537         return false;
 538 }
 539
 540 MUTATOR_HOOKFUNCTION(buffs_PlayerJump)
 541 {
 542         if(self.buffs & BUFF_JUMP)
 543                 player_jumpheight = autocvar_g_buffs_jump_height;
 544
 545         return false;
 546 }
 547
 548 MUTATOR_HOOKFUNCTION(buffs_MonsterMove)
 549 {
 550         if(time < self.buff_disability_time)
 551         {
 552                 monster_speed_walk *= autocvar_g_buffs_disability_speed;
 553                 monster_speed_run *= autocvar_g_buffs_disability_speed;
 554         }
 555
 556         return false;
 557 }
 558
 559 MUTATOR_HOOKFUNCTION(buffs_PlayerDies)
 560 {
 561         if(self.buffs)
 562         {
 563                 Send_Notification(NOTIF_ALL_EXCEPT, self, MSG_INFO, INFO_ITEM_BUFF_LOST, self.netname, self.buffs);
 564                 self.buffs = 0;
 565
 566                 if(self.buff_model)
 567                 {
 568                         remove(self.buff_model);
 569                         self.buff_model = world;
 570                 }
 571         }
 572         return false;
 573 }
 574
 575 MUTATOR_HOOKFUNCTION(buffs_PlayerUseKey)
 576 {
 577         if(MUTATOR_RETURNVALUE || gameover) { return false; }
 578         if(self.buffs)
 579         {
 580                 Send_Notification(NOTIF_ONE, self, MSG_MULTI, ITEM_BUFF_DROP, self.buffs);
 581                 Send_Notification(NOTIF_ALL_EXCEPT, self, MSG_INFO, INFO_ITEM_BUFF_LOST, self.netname, self.buffs);
 582
 583                 self.buffs = 0;
 584                 sound(self, CH_TRIGGER, "relics/relic_effect.wav", VOL_BASE, ATTN_NORM);
 585                 return true;
 586         }
 587         return false;
 588 }
 589
 590 MUTATOR_HOOKFUNCTION(buffs_PlayerThrowKey)
 591 {
 592         if(MUTATOR_RETURNVALUE || gameover) { return false; }
 593
 594         if(self.buffs & BUFF_SWAPPER)
 595         {
 596                 float best_distance = autocvar_g_buffs_swapper_range;
 597                 entity closest = world;
 598                 entity player;
 599                 FOR_EACH_PLAYER(player)
 600                 if(DIFF_TEAM(self, player))
 601                 if(player.deadflag == DEAD_NO && !player.frozen && !player.vehicle)
 602                 if(vlen(self.origin - player.origin) <= best_distance)
 603                 {
 604                         best_distance = vlen(self.origin - player.origin);
 605                         closest = player;
 606                 }
 607
 608                 if(closest)
 609                 {
 610                         vector my_org, my_vel, my_ang, their_org, their_vel, their_ang;
 611
 612                         my_org = self.origin;
 613                         my_vel = self.velocity;
 614                         my_ang = self.angles;
 615                         their_org = closest.origin;
 616                         their_vel = closest.velocity;
 617                         their_ang = closest.angles;
 618
 619                         if(closest.ballcarried)
 620                         if(g_keepaway) { ka_DropEvent(closest); }
 621                         else { DropBall(closest.ballcarried, closest.origin, closest.velocity);}
 622                         if(closest.flagcarried) { ctf_Handle_Throw(closest, world, DROP_THROW); }
 623                         if(closest.nade) { toss_nade(closest, '0 0 0', time + 0.05); }
 624
 625                         MUTATOR_CALLHOOK(PortalTeleport); // initiate flag dropper
 626
 627                         setorigin(self, their_org);
 628                         setorigin(closest, my_org);
 629
 630                         closest.velocity = my_vel;
 631                         closest.angles = my_ang;
 632                         closest.fixangle = true;
 633                         closest.oldorigin = my_org;
 634                         closest.oldvelocity = my_vel;
 635                         self.velocity = their_vel;
 636                         self.angles = their_ang;
 637                         self.fixangle = true;
 638                         self.oldorigin = their_org;
 639                         self.oldvelocity = their_vel;
 640
 641                         // set pusher so self gets the kill if they fall into void
 642                         closest.pusher = self;
 643                         closest.pushltime = time + autocvar_g_maxpushtime;
 644                         closest.istypefrag = closest.BUTTON_CHAT;
 645
 646                         pointparticles(particleeffectnum("electro_combo"), their_org, '0 0 0', 1);
 647                         pointparticles(particleeffectnum("electro_combo"), my_org, '0 0 0', 1);
 648
 649                         sound(self, CH_TRIGGER, "keepaway/respawn.wav", VOL_BASE, ATTEN_NORM);
 650                         sound(closest, CH_TRIGGER, "keepaway/respawn.wav", VOL_BASE, ATTEN_NORM);
 651
 652                         // TODO: add a counter to handle how many times one can teleport, and a delay to prevent spam
 653                         self.buffs = 0;
 654                         return true;
 655                 }
 656         }
 657         return false;
 658 }
 659
 660 MUTATOR_HOOKFUNCTION(buffs_RemovePlayer)
 661 {
 662         if(self.buff_model)
 663         {
 664                 remove(self.buff_model);
 665                 self.buff_model = world;
 666         }
 667
 668         // also reset timers here to prevent them continuing after spectating
 669         self.buff_disability_time = 0;
 670         self.buff_disability_effect_time = 0;
 671
 672         return false;
 673 }
 674
 675 MUTATOR_HOOKFUNCTION(buffs_CustomizeWaypoint)
 676 {
 677         entity e = WaypointSprite_getviewentity(other);
 678
 679         // if you have the invisibility powerup, sprites ALWAYS are restricted to your team
 680         // but only apply this to real players, not to spectators
 681         if((self.owner.flags & FL_CLIENT) && (self.owner.buffs & BUFF_INVISIBLE) && (e == other))
 682         if(DIFF_TEAM(self.owner, e))
 683                 return true;
 684
 685         return false;
 686 }
 687
 688 MUTATOR_HOOKFUNCTION(buffs_OnEntityPreSpawn)
 689 {
 690         if(autocvar_g_buffs_replace_powerups)
 691         switch(self.classname)
 692         {
 693                 case "item_strength":
 694                 case "item_invincible":
 695                 {
 696                         entity e = spawn();
 697                         buff_SpawnReplacement(e, self);
 698                         return true;
 699                 }
 700         }
 701         return false;
 702 }
 703
 704 MUTATOR_HOOKFUNCTION(buffs_WeaponRate)
 705 {
 706         if(self.buffs & BUFF_SPEED)
 707                 weapon_rate *= autocvar_g_buffs_speed_rate;
 708
 709         if(time < self.buff_disability_time)
 710                 weapon_rate *= autocvar_g_buffs_disability_rate;
 711
 712         return false;
 713 }
 714
 715 MUTATOR_HOOKFUNCTION(buffs_WeaponSpeed)
 716 {
 717         if(self.buffs & BUFF_SPEED)
 718                 ret_float *= autocvar_g_buffs_speed_weaponspeed;
 719
 720         if(time < self.buff_disability_time)
 721                 ret_float *= autocvar_g_buffs_disability_weaponspeed;
 722
 723         return false;
 724 }
 725
 726 MUTATOR_HOOKFUNCTION(buffs_PlayerThink)
 727 {
 728         if(gameover || self.deadflag != DEAD_NO) { return false; }
 729
 730         if(time < self.buff_disability_time)
 731         if(time >= self.buff_disability_effect_time)
 732         {
 733                 pointparticles(particleeffectnum("smoking"), self.origin + ((self.mins + self.maxs) * 0.5), '0 0 0', 1);
 734                 self.buff_disability_effect_time = time + 0.5;
 735         }
 736
 737         // handle buff lost status
 738         // 1: notify everyone else
 739         // 2: notify carrier as well
 740         int buff_lost = 0;
 741
 742         if(self.buff_time)
 743         if(time >= self.buff_time)
 744                 buff_lost = 2;
 745
 746         if(self.frozen) { buff_lost = 1; }
 747
 748         if(buff_lost)
 749         {
 750                 if(self.buffs)
 751                 {
 752                         Send_Notification(NOTIF_ALL_EXCEPT, self, MSG_INFO, INFO_ITEM_BUFF_LOST, self.netname, self.buffs);
 753                         if(buff_lost >= 2)
 754                         {
 755                                 Send_Notification(NOTIF_ONE, self, MSG_MULTI, ITEM_BUFF_DROP, self.buffs); // TODO: special timeout message?
 756                                 sound(self, CH_TRIGGER, "relics/relic_effect.wav", VOL_BASE, ATTN_NORM);
 757                         }
 758                         self.buffs = 0;
 759                 }
 760         }
 761
 762         if(self.buffs & BUFF_MAGNET)
 763         {
 764                 vector pickup_size = '1 1 1' * autocvar_g_buffs_magnet_range_item;
 765                 for(other = world; (other = findflags(other, flags, FL_ITEM)); )
 766                 if(boxesoverlap(self.absmin - pickup_size, self.absmax + pickup_size, other.absmin, other.absmax))
 767                 {
 768                         entity oldself = self;
 769                         self = other;
 770                         other = oldself;
 771                         if(self.touch)
 772                                 self.touch();
 773                         other = self;
 774                         self = oldself;
 775                 }
 776         }
 777
 778         if(self.buffs & BUFF_AMMO)
 779         if(self.clip_size)
 780                 self.clip_load = self.(weapon_load[self.switchweapon]) = self.clip_size;
 781
 782         if((self.buffs & BUFF_INVISIBLE) && (self.oldbuffs & BUFF_INVISIBLE))
 783         if(self.alpha != autocvar_g_buffs_invisible_alpha)
 784                 self.alpha = autocvar_g_buffs_invisible_alpha; // powerups reset alpha, so we must enforce this (TODO)
 785
 786 #define BUFF_ONADD(b) if((self.buffs & (b)) && !(self.oldbuffs & (b)))
 787 #define BUFF_ONREM(b) if(!(self.buffs & (b)) && (self.oldbuffs & (b)))
 788
 789         if(self.buffs != self.oldbuffs)
 790         {
 791                 if(self.buffs && Buff_Timer(self.buffs))
 792                         self.buff_time = time + Buff_Timer(self.buffs);
 793                 else
 794                         self.buff_time = 0;
 795
 796                 BUFF_ONADD(BUFF_AMMO)
 797                 {
 798                         self.buff_ammo_prev_infitems = (self.items & IT_UNLIMITED_WEAPON_AMMO);
 799                         self.items |= IT_UNLIMITED_WEAPON_AMMO;
 800
 801                         if(self.clip_load)
 802                                 self.buff_ammo_prev_clipload = self.clip_load;
 803                         self.clip_load = self.(weapon_load[self.switchweapon]) = self.clip_size;
 804                 }
 805
 806                 BUFF_ONREM(BUFF_AMMO)
 807                 {
 808                         if(self.buff_ammo_prev_infitems)
 809                                 self.items |= IT_UNLIMITED_WEAPON_AMMO;
 810                         else
 811                                 self.items &= ~IT_UNLIMITED_WEAPON_AMMO;
 812
 813                         if(self.buff_ammo_prev_clipload)
 814                                 self.clip_load = self.buff_ammo_prev_clipload;
 815                 }
 816
 817                 BUFF_ONADD(BUFF_INVISIBLE)
 818                 {
 819                         if(time < self.strength_finished && g_instagib)
 820                                 self.alpha = autocvar_g_instagib_invis_alpha;
 821                         else
 822                                 self.alpha = self.buff_invisible_prev_alpha;
 823                         self.alpha = autocvar_g_buffs_invisible_alpha;
 824                 }
 825
 826                 BUFF_ONREM(BUFF_INVISIBLE)
 827                         self.alpha = self.buff_invisible_prev_alpha;
 828
 829                 BUFF_ONADD(BUFF_FLIGHT)
 830                 {
 831                         self.buff_flight_prev_gravity = self.gravity;
 832                         self.gravity = autocvar_g_buffs_flight_gravity;
 833                 }
 834
 835                 BUFF_ONREM(BUFF_FLIGHT)
 836                         self.gravity = self.buff_flight_prev_gravity;
 837
 838                 self.oldbuffs = self.buffs;
 839                 if(self.buffs)
 840                 {
 841                         if(!self.buff_model)
 842                                 buffs_BuffModel_Spawn(self);
 843
 844                         self.buff_model.color = Buff_Color(self.buffs);
 845                         self.buff_model.glowmod = buff_GlowColor(self.buff_model);
 846                         self.buff_model.skin = Buff_Skin(self.buffs);
 847
 848                         self.effects |= EF_NOSHADOW;
 849                 }
 850                 else
 851                 {
 852                         remove(self.buff_model);
 853                         self.buff_model = world;
 854
 855                         self.effects &= ~(EF_NOSHADOW);
 856                 }
 857         }
 858
 859         if(self.buff_model)
 860         {
 861                 self.buff_model.effects = self.effects;
 862                 self.buff_model.effects |= EF_LOWPRECISION;
 863                 self.buff_model.effects = self.buff_model.effects & EFMASK_CHEAP; // eat performance
 864
 865                 self.buff_model.alpha = self.alpha;
 866         }
 867
 868 #undef BUFF_ONADD
 869 #undef BUFF_ONREM
 870         return false;
 871 }
 872
 873 MUTATOR_HOOKFUNCTION(buffs_SpectateCopy)
 874 {
 875         self.buffs = other.buffs;
 876         return false;
 877 }
 878
 879 MUTATOR_HOOKFUNCTION(buffs_VehicleEnter)
 880 {
 881         vh_vehicle.buffs = vh_player.buffs;
 882         vh_player.buffs = 0;
 883         return false;
 884 }
 885
 886 MUTATOR_HOOKFUNCTION(buffs_VehicleExit)
 887 {
 888         vh_player.buffs = vh_vehicle.buffs;
 889         vh_vehicle.buffs = 0;
 890         return false;
 891 }
 892
 893 MUTATOR_HOOKFUNCTION(buffs_PlayerRegen)
 894 {
 895         if(self.buffs & BUFF_MEDIC)
 896         {
 897                 regen_mod_rot = autocvar_g_buffs_medic_rot;
 898                 regen_mod_limit = regen_mod_max = autocvar_g_buffs_medic_max;
 899                 regen_mod_regen = autocvar_g_buffs_medic_regen;
 900         }
 901
 902         if(self.buffs & BUFF_SPEED)
 903                 regen_mod_regen = autocvar_g_buffs_speed_regen;
 904
 905         return false;
 906 }
 907
 908 MUTATOR_HOOKFUNCTION(buffs_GetCvars)
 909 {
 910         GetCvars_handleFloat(get_cvars_s, get_cvars_f, cvar_cl_buffs_autoreplace, "cl_buffs_autoreplace");
 911         return false;
 912 }
 913
 914 MUTATOR_HOOKFUNCTION(buffs_BuildMutatorsString)
 915 {
 916         ret_string = strcat(ret_string, ":Buffs");
 917         return false;
 918 }
 919
 920 MUTATOR_HOOKFUNCTION(buffs_BuildMutatorsPrettyString)
 921 {
 922         ret_string = strcat(ret_string, ", Buffs");
 923         return false;
 924 }
 925
 926 void buffs_DelayedInit()
 927 {
 928         if(autocvar_g_buffs_spawn_count > 0)
 929         if(find(world, classname, "item_buff") == world)
 930         {
 931                 float i;
 932                 for(i = 0; i < autocvar_g_buffs_spawn_count; ++i)
 933                 {
 934                         entity e = spawn();
 935                         e.spawnflags |= 64; // always randomize
 936                         e.velocity = randomvec() * 250; // this gets reset anyway if random location works
 937                         buff_Init(e);
 938                 }
 939         }
 940 }
 941
 942 void buffs_Initialize()
 943 {
 944         precache_model(BUFF_MODEL);
 945         precache_sound("misc/strength_respawn.wav");
 946         precache_sound("misc/shield_respawn.wav");
 947         precache_sound("relics/relic_effect.wav");
 948         precache_sound("weapons/rocket_impact.wav");
 949         precache_sound("keepaway/respawn.wav");
 950
 951         addstat(STAT_BUFFS, AS_INT, buffs);
 952         addstat(STAT_BUFF_TIME, AS_FLOAT, buff_time);
 953
 954         InitializeEntity(world, buffs_DelayedInit, INITPRIO_FINDTARGET);
 955 }
 956
 957 MUTATOR_DEFINITION(mutator_buffs)
 958 {
 959         MUTATOR_HOOK(PlayerDamage_SplitHealthArmor, buffs_PlayerDamage_SplitHealthArmor, CBC_ORDER_ANY);
 960         MUTATOR_HOOK(PlayerDamage_Calculate, buffs_PlayerDamage_Calculate, CBC_ORDER_ANY);
 961         MUTATOR_HOOK(PlayerSpawn, buffs_PlayerSpawn, CBC_ORDER_ANY);
 962         MUTATOR_HOOK(PlayerPhysics, buffs_PlayerPhysics, CBC_ORDER_ANY);
 963         MUTATOR_HOOK(PlayerJump, buffs_PlayerJump, CBC_ORDER_ANY);
 964         MUTATOR_HOOK(MonsterMove, buffs_MonsterMove, CBC_ORDER_ANY);
 965         MUTATOR_HOOK(SpectateCopy, buffs_SpectateCopy, CBC_ORDER_ANY);
 966         MUTATOR_HOOK(VehicleEnter, buffs_VehicleEnter, CBC_ORDER_ANY);
 967         MUTATOR_HOOK(VehicleExit, buffs_VehicleExit, CBC_ORDER_ANY);
 968         MUTATOR_HOOK(PlayerRegen, buffs_PlayerRegen, CBC_ORDER_ANY);
 969         MUTATOR_HOOK(PlayerDies, buffs_PlayerDies, CBC_ORDER_ANY);
 970         MUTATOR_HOOK(PlayerUseKey, buffs_PlayerUseKey, CBC_ORDER_FIRST);
 971         MUTATOR_HOOK(ForbidThrowCurrentWeapon, buffs_PlayerThrowKey, CBC_ORDER_ANY);
 972         MUTATOR_HOOK(MakePlayerObserver, buffs_RemovePlayer, CBC_ORDER_ANY);
 973         MUTATOR_HOOK(ClientDisconnect, buffs_RemovePlayer, CBC_ORDER_ANY);
 974         MUTATOR_HOOK(OnEntityPreSpawn, buffs_OnEntityPreSpawn, CBC_ORDER_LAST);
 975         MUTATOR_HOOK(CustomizeWaypoint, buffs_CustomizeWaypoint, CBC_ORDER_ANY);
 976         MUTATOR_HOOK(WeaponRateFactor, buffs_WeaponRate, CBC_ORDER_ANY);
 977         MUTATOR_HOOK(WeaponSpeedFactor, buffs_WeaponSpeed, CBC_ORDER_ANY);
 978         MUTATOR_HOOK(PlayerPreThink, buffs_PlayerThink, CBC_ORDER_ANY);
 979         MUTATOR_HOOK(GetCvars, buffs_GetCvars, CBC_ORDER_ANY);
 980         MUTATOR_HOOK(BuildMutatorsString, buffs_BuildMutatorsString, CBC_ORDER_ANY);
 981         MUTATOR_HOOK(BuildMutatorsPrettyString, buffs_BuildMutatorsPrettyString, CBC_ORDER_ANY);
 982
 983         MUTATOR_ONADD
 984         {
 985                 buffs_Initialize();
 986         }
 987
 988         return false;
 989 }