qcsrc/server/mutators/mutator_buffs.qc

   1 float buffs_BuffModel_Customize()
   2 {
   3         entity player, myowner;
   4         float same_team;
   5
   6         player = WaypointSprite_getviewentity(other);
   7         myowner = self.owner;
   8         same_team = (SAME_TEAM(player, myowner) || SAME_TEAM(player, myowner));
   9
  10         if(myowner.alpha <= 0.5 && !same_team && myowner.alpha != 0)
  11                 return false;
  12
  13         if(player == myowner || (IS_SPEC(other) && other.enemy == myowner))
  14         {
  15                 // somewhat hide the model, but keep the glow
  16                 self.effects = 0;
  17                 self.alpha = -1;
  18         }
  19         else
  20         {
  21                 self.effects = EF_FULLBRIGHT | EF_LOWPRECISION;
  22                 self.alpha = 1;
  23         }
  24         return true;
  25 }
  26
  27 vector buff_GlowColor(entity buff)
  28 {
  29         //if(buff.team) { return Team_ColorRGB(buff.team); }
  30         return buff.color;
  31 }
  32
  33 // buff item
  34 float buff_Waypoint_visible_for_player(entity plr)
  35 {
  36     if(!self.owner.buff_active && !self.owner.buff_activetime)
  37         return false;
  38
  39         if(plr.buffs)
  40         {
  41                 if(plr.cvar_cl_buffs_autoreplace)
  42                 {
  43                         if(plr.buffs == self.owner.buffs)
  44                                 return false;
  45                 }
  46                 else
  47                         return false;
  48         }
  49
  50     return WaypointSprite_visible_for_player(plr);
  51 }
  52
  53 void buff_Waypoint_Spawn(entity e)
  54 {
  55     WaypointSprite_Spawn(Buff_Sprite(e.buffs), 0, autocvar_g_buffs_waypoint_distance, e, '0 0 1' * e.maxs.z, world, e.team, e, buff_waypoint, true, RADARICON_POWERUP, e.glowmod);
  56     WaypointSprite_UpdateTeamRadar(e.buff_waypoint, RADARICON_POWERUP, e.glowmod);
  57     e.buff_waypoint.waypointsprite_visible_for_player = buff_Waypoint_visible_for_player;
  58 }
  59
  60 void buff_SetCooldown(float cd)
  61 {
  62         cd = max(0, cd);
  63
  64         if(!self.buff_waypoint)
  65                 buff_Waypoint_Spawn(self);
  66
  67         WaypointSprite_UpdateBuildFinished(self.buff_waypoint, time + cd);
  68         self.buff_activetime = cd;
  69         self.buff_active = !cd;
  70 }
  71
  72 void buff_Respawn(entity ent)
  73 {
  74         if(gameover) { return; }
  75
  76         vector oldbufforigin = ent.origin;
  77
  78         if(!MoveToRandomMapLocation(ent, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY, ((autocvar_g_buffs_random_location_attempts > 0) ? autocvar_g_buffs_random_location_attempts : 10), 1024, 256))
  79         {
  80                 entity spot = SelectSpawnPoint(true);
  81                 setorigin(ent, ((spot.origin + '0 0 200') + (randomvec() * 300)));
  82                 ent.angles = spot.angles;
  83         }
  84
  85         tracebox(ent.origin, ent.mins * 1.5, self.maxs * 1.5, ent.origin, MOVE_NOMONSTERS, ent);
  86
  87         setorigin(ent, trace_endpos); // attempt to unstick
  88
  89         ent.movetype = MOVETYPE_TOSS;
  90
  91         makevectors(ent.angles);
  92         ent.velocity = '0 0 200';
  93         ent.angles = '0 0 0';
  94         if(autocvar_g_buffs_random_lifetime > 0)
  95                 ent.lifetime = time + autocvar_g_buffs_random_lifetime;
  96
  97         pointparticles(particleeffectnum("electro_combo"), oldbufforigin + ((ent.mins + ent.maxs) * 0.5), '0 0 0', 1);
  98         pointparticles(particleeffectnum("electro_combo"), CENTER_OR_VIEWOFS(ent), '0 0 0', 1);
  99
 100         WaypointSprite_Ping(ent.buff_waypoint);
 101
 102         sound(ent, CH_TRIGGER, "keepaway/respawn.wav", VOL_BASE, ATTEN_NONE); // ATTEN_NONE (it's a sound intended to be heard anywhere)
 103 }
 104
 105 void buff_Touch()
 106 {
 107         if(gameover) { return; }
 108
 109         if(ITEM_TOUCH_NEEDKILL())
 110         {
 111                 buff_Respawn(self);
 112                 return;
 113         }
 114
 115         if((self.team && DIFF_TEAM(other, self))
 116         || (other.frozen)
 117         || (other.vehicle)
 118         || (!IS_PLAYER(other))
 119         || (!self.buff_active)
 120         )
 121         {
 122                 // can't touch this
 123                 return;
 124         }
 125
 126         if(other.buffs)
 127         {
 128                 if(other.cvar_cl_buffs_autoreplace && other.buffs != self.buffs)
 129                 {
 130                         //Send_Notification(NOTIF_ONE, other, MSG_MULTI, ITEM_BUFF_DROP, other.buffs);
 131                         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_ITEM_BUFF_LOST, other.netname, other.buffs);
 132
 133                         other.buffs = 0;
 134                         //sound(other, CH_TRIGGER, "relics/relic_effect.wav", VOL_BASE, ATTN_NORM);
 135                 }
 136                 else { return; } // do nothing
 137         }
 138
 139         self.owner = other;
 140         self.buff_active = false;
 141         self.lifetime = 0;
 142
 143         Send_Notification(NOTIF_ONE, other, MSG_MULTI, ITEM_BUFF_GOT, self.buffs);
 144         Send_Notification(NOTIF_ALL_EXCEPT, other, MSG_INFO, INFO_ITEM_BUFF, other.netname, self.buffs);
 145
 146         pointparticles(particleeffectnum("item_pickup"), CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 147         sound(other, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);
 148         other.buffs |= (self.buffs);
 149 }
 150
 151 float buff_Available(float buffid)
 152 {
 153         if(buffid == BUFF_AMMO && ((start_items & IT_UNLIMITED_WEAPON_AMMO) || (start_items & IT_UNLIMITED_AMMO) || (cvar("g_melee_only"))))
 154                 return false;
 155
 156         if(buffid == BUFF_VAMPIRE && cvar("g_vampire"))
 157                 return false;
 158
 159         if(!cvar(strcat("g_buffs_", Buff_Name(buffid))))
 160                 return false;
 161
 162         return true;
 163 }
 164
 165 void buff_NewType(entity ent, float cb)
 166 {
 167         entity e;
 168         RandomSelection_Init();
 169         for(e = Buff_Type_first; e; e = e.enemy)
 170         if(buff_Available(e.items))
 171         {
 172                 RandomSelection_Add(world, e.items, string_null, 1, 1 / e.count); // if it's already been chosen, give it a lower priority
 173                 e.count += 1;
 174         }
 175         ent.buffs = RandomSelection_chosen_float;
 176 }
 177
 178 void buff_Think()
 179 {
 180         if(self.buffs != self.oldbuffs)
 181         {
 182                 self.color = Buff_Color(self.buffs);
 183                 self.glowmod = buff_GlowColor(self);
 184                 self.skin = Buff_Skin(self.buffs);
 185
 186                 setmodel(self, "models/relics/relic.md3");
 187
 188                 if(self.buff_waypoint)
 189                 {
 190                         //WaypointSprite_Disown(self.buff_waypoint, 1);
 191                         WaypointSprite_Kill(self.buff_waypoint);
 192                         buff_Waypoint_Spawn(self);
 193                         if(self.buff_activetime)
 194                                 WaypointSprite_UpdateBuildFinished(self.buff_waypoint, time + self.buff_activetime - frametime);
 195                 }
 196
 197                 self.oldbuffs = self.buffs;
 198         }
 199
 200         if(!gameover)
 201         if((round_handler_IsActive() && !round_handler_IsRoundStarted()) || time >= game_starttime)
 202         if(!self.buff_activetime_updated)
 203         {
 204                 buff_SetCooldown(self.buff_activetime);
 205                 self.buff_activetime_updated = true;
 206     }
 207
 208         if(!self.buff_active && !self.buff_activetime)
 209         if(!self.owner || self.owner.frozen || self.owner.deadflag != DEAD_NO || !self.owner.iscreature || !(self.owner.buffs & self.buffs))
 210         {
 211                 buff_SetCooldown(autocvar_g_buffs_cooldown_respawn + frametime);
 212                 self.owner = world;
 213                 if(autocvar_g_buffs_randomize)
 214                         buff_NewType(self, self.buffs);
 215
 216                 if(autocvar_g_buffs_random_location || (self.spawnflags & 1))
 217                         buff_Respawn(self);
 218         }
 219
 220         if(self.buff_activetime)
 221         if(!gameover)
 222         if((round_handler_IsActive() && !round_handler_IsRoundStarted()) || time >= game_starttime)
 223         {
 224                 self.buff_activetime = max(0, self.buff_activetime - frametime);
 225
 226                 if(!self.buff_activetime)
 227                 {
 228                         self.buff_active = true;
 229                         sound(self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);
 230                         pointparticles(particleeffectnum("item_respawn"), CENTER_OR_VIEWOFS(self), '0 0 0', 1);
 231                 }
 232         }
 233
 234         if(self.buff_active)
 235         {
 236                 if(self.team && !self.buff_waypoint)
 237                         buff_Waypoint_Spawn(self);
 238
 239                 if(self.lifetime)
 240                 if(time >= self.lifetime)
 241                         buff_Respawn(self);
 242         }
 243
 244         self.nextthink = time;
 245         //self.angles_y = time * 110.1;
 246 }
 247
 248 void buff_Waypoint_Reset()
 249 {
 250         WaypointSprite_Kill(self.buff_waypoint);
 251
 252         if(self.buff_activetime) { buff_Waypoint_Spawn(self); }
 253 }
 254
 255 void buff_Reset()
 256 {
 257         if(autocvar_g_buffs_randomize)
 258                 buff_NewType(self, self.buffs);
 259         self.owner = world;
 260         buff_SetCooldown(autocvar_g_buffs_cooldown_activate);
 261         buff_Waypoint_Reset();
 262         self.buff_activetime_updated = false;
 263
 264         if(autocvar_g_buffs_random_location || (self.spawnflags & 1))
 265                 buff_Respawn(self);
 266 }
 267
 268 float buff_Customize()
 269 {
 270         entity player = WaypointSprite_getviewentity(other);
 271         if(!self.buff_active || (self.team && DIFF_TEAM(player, self)))
 272         {
 273                 self.alpha = 0.3;
 274                 if(self.effects & EF_FULLBRIGHT) { self.effects &= ~(EF_FULLBRIGHT); }
 275                 self.pflags = 0;
 276         }
 277         else
 278         {
 279                 self.alpha = 1;
 280                 if(!(self.effects & EF_FULLBRIGHT)) { self.effects |= EF_FULLBRIGHT; }
 281                 self.light_lev = 220 + 36 * sin(time);
 282                 self.pflags = PFLAGS_FULLDYNAMIC;
 283         }
 284         return true;
 285 }
 286
 287 void buff_Init(entity ent)
 288 {
 289         if(!cvar("g_buffs")) { remove(self); return; }
 290
 291         if(!teamplay && self.team) { self.team = 0; }
 292
 293         entity oldself = self;
 294         self = ent;
 295         if(!self.buffs || buff_Available(self.buffs))
 296                 buff_NewType(self, 0);
 297
 298         self.classname = "item_buff";
 299         self.solid = SOLID_TRIGGER;
 300         self.flags = FL_ITEM;
 301         self.think = buff_Think;
 302         self.touch = buff_Touch;
 303         self.reset = buff_Reset;
 304         self.nextthink = time + 0.1;
 305         self.gravity = 1;
 306         self.movetype = MOVETYPE_TOSS;
 307         self.scale = 1;
 308         self.skin = Buff_Skin(self.buffs);
 309         self.effects = EF_FULLBRIGHT | EF_STARDUST | EF_NOSHADOW;
 310         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
 311         self.customizeentityforclient = buff_Customize;
 312         //self.gravity = 100;
 313         self.color = Buff_Color(self.buffs);
 314         self.glowmod = buff_GlowColor(self);
 315         buff_SetCooldown(autocvar_g_buffs_cooldown_activate + game_starttime);
 316         self.buff_active = !self.buff_activetime;
 317         self.pflags = PFLAGS_FULLDYNAMIC;
 318
 319         if(self.noalign)
 320                 self.movetype = MOVETYPE_NONE; // reset by random location
 321
 322         setmodel(self, "models/relics/relic.md3");
 323         setsize(self, BUFF_MIN, BUFF_MAX);
 324
 325         if(cvar("g_buffs_random_location") || (self.spawnflags & 1))
 326                 buff_Respawn(self);
 327
 328         self = oldself;
 329 }
 330
 331 void buff_Init_Compat(entity ent, float replacement)
 332 {
 333         if(ent.spawnflags & 2)
 334                 ent.team = NUM_TEAM_1;
 335         else if(ent.spawnflags & 4)
 336                 ent.team = NUM_TEAM_2;
 337
 338         ent.buffs = replacement;
 339
 340         buff_Init(ent);
 341 }
 342
 343 void buff_SpawnReplacement(entity ent, entity old)
 344 {
 345         setorigin(ent, old.origin);
 346         ent.angles = old.angles;
 347         ent.noalign = old.noalign;
 348
 349         buff_Init(ent);
 350 }
 351
 352 // mutator hooks
 353 MUTATOR_HOOKFUNCTION(buffs_PlayerDamage_SplitHealthArmor)
 354 {
 355         if(frag_deathtype == DEATH_BUFF) { return false; }
 356
 357         if(frag_target.buffs & BUFF_RESISTANCE)
 358         {
 359                 vector v = healtharmor_applydamage(50, autocvar_g_buffs_resistance_blockpercent, frag_deathtype, frag_damage);
 360                 damage_take = v.x;
 361                 damage_save = v.y;
 362         }
 363
 364         return false;
 365 }
 366
 367 void buff_Vengeance_DelayedDamage()
 368 {
 369         if(self.enemy)
 370                 Damage(self.enemy, self.owner, self.owner, self.dmg, DEATH_BUFF, self.enemy.origin, '0 0 0');
 371
 372         remove(self);
 373         return;
 374 }
 375
 376 MUTATOR_HOOKFUNCTION(buffs_PlayerDamage_Calculate)
 377 {
 378         if(frag_deathtype == DEATH_BUFF) { return false; }
 379
 380         if(frag_target.buffs & BUFF_SPEED)
 381         if(frag_target != frag_attacker)
 382                 frag_damage *= autocvar_g_buffs_speed_damage_take;
 383
 384         if(frag_target.buffs & BUFF_MEDIC)
 385         if((frag_target.health - frag_damage) <= 0)
 386         if(!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
 387         if(frag_attacker)
 388         if(random() <= autocvar_g_buffs_medic_survive_chance)
 389         if(frag_target.health - autocvar_g_buffs_medic_survive_health > 0) // not if the final result would be less than 0, medic must get health
 390                 frag_damage = frag_target.health - autocvar_g_buffs_medic_survive_health;
 391
 392         if(frag_target.buffs & BUFF_VENGEANCE)
 393         if(frag_attacker)
 394         if(frag_attacker != frag_target)
 395         if(!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
 396         {
 397                 entity dmgent = spawn();
 398
 399                 dmgent.dmg = frag_damage * autocvar_g_buffs_vengeance_damage_multiplier;
 400                 dmgent.enemy = frag_attacker;
 401                 dmgent.owner = frag_target;
 402                 dmgent.think = buff_Vengeance_DelayedDamage;
 403                 dmgent.nextthink = time + 0.1;
 404         }
 405
 406         if(frag_target.buffs & BUFF_BASH)
 407         if(frag_attacker != frag_target)
 408         if(vlen(frag_force))
 409                 frag_force = '0 0 0';
 410
 411         if(frag_attacker.buffs & BUFF_BASH)
 412         if(vlen(frag_force))
 413         if(frag_attacker == frag_target)
 414                 frag_force *= autocvar_g_buffs_bash_force_self;
 415         else
 416                 frag_force *= autocvar_g_buffs_bash_force;
 417
 418         if(frag_attacker.buffs & BUFF_DISABILITY)
 419         if(frag_target != frag_attacker)
 420                 frag_target.buff_disability_time = time + autocvar_g_buffs_disability_time;
 421
 422         if(frag_attacker.buffs & BUFF_MEDIC)
 423         if(DEATH_WEAPONOF(frag_deathtype) != WEP_ARC)
 424         if(SAME_TEAM(frag_attacker, frag_target))
 425         if(frag_attacker != frag_target)
 426         {
 427                 frag_target.health = min(g_pickup_healthmega_max, frag_target.health + frag_damage);
 428                 frag_damage = 0;
 429         }
 430
 431         // this... is ridiculous (TODO: fix!)
 432         if(frag_attacker.buffs & BUFF_VAMPIRE)
 433         if(!frag_target.vehicle)
 434         if(DEATH_WEAPONOF(frag_deathtype) != WEP_ARC)
 435         if(!ITEM_DAMAGE_NEEDKILL(frag_deathtype))
 436         if(frag_target.deadflag == DEAD_NO)
 437         if(IS_PLAYER(frag_target) || (frag_target.flags & FL_MONSTER))
 438         if(frag_attacker != frag_target)
 439         if(!frag_target.frozen)
 440         if(frag_target.takedamage)
 441         if(DIFF_TEAM(frag_attacker, frag_target))
 442                 frag_attacker.health = bound(0, frag_attacker.health + bound(0, frag_damage * autocvar_g_buffs_vampire_damage_steal, frag_target.health), g_pickup_healthsmall_max);
 443
 444         return false;
 445 }
 446
 447 MUTATOR_HOOKFUNCTION(buffs_PlayerSpawn)
 448 {
 449         self.buffs = 0;
 450         // reset timers here to prevent them continuing after re-spawn
 451         self.buff_disability_time = 0;
 452         self.buff_disability_effect_time = 0;
 453         return false;
 454 }
 455
 456 MUTATOR_HOOKFUNCTION(buffs_PlayerPhysics)
 457 {
 458         if(self.buffs & BUFF_SPEED)
 459         {
 460                 self.stat_sv_maxspeed *= autocvar_g_buffs_speed_speed;
 461                 self.stat_sv_airspeedlimit_nonqw *= autocvar_g_buffs_speed_speed;
 462         }
 463
 464         if(time < self.buff_disability_time)
 465         {
 466                 self.stat_sv_maxspeed *= autocvar_g_buffs_disability_speed;
 467                 self.stat_sv_airspeedlimit_nonqw *= autocvar_g_buffs_disability_speed;
 468         }
 469
 470         return false;
 471 }
 472
 473 MUTATOR_HOOKFUNCTION(buffs_PlayerJump)
 474 {
 475         if(self.buffs & BUFF_JUMP)
 476                 player_jumpheight = autocvar_g_buffs_jump_height;
 477         self.stat_jumpheight = player_jumpheight;
 478
 479         return false;
 480 }
 481
 482 MUTATOR_HOOKFUNCTION(buffs_MonsterMove)
 483 {
 484         if(time < self.buff_disability_time)
 485         {
 486                 monster_speed_walk *= autocvar_g_buffs_disability_speed;
 487                 monster_speed_run *= autocvar_g_buffs_disability_speed;
 488         }
 489
 490         return false;
 491 }
 492
 493 MUTATOR_HOOKFUNCTION(buffs_PlayerDies)
 494 {
 495         if(self.buffs)
 496         {
 497                 Send_Notification(NOTIF_ALL_EXCEPT, self, MSG_INFO, INFO_ITEM_BUFF_LOST, self.netname, self.buffs);
 498                 self.buffs = 0;
 499
 500                 if(self.buff_model)
 501                 {
 502                         remove(self.buff_model);
 503                         self.buff_model = world;
 504                 }
 505         }
 506         return false;
 507 }
 508
 509 MUTATOR_HOOKFUNCTION(buffs_PlayerUseKey)
 510 {
 511         if(MUTATOR_RETURNVALUE || gameover) { return false; }
 512         if(self.buffs)
 513         {
 514                 Send_Notification(NOTIF_ONE, self, MSG_MULTI, ITEM_BUFF_DROP, self.buffs);
 515                 Send_Notification(NOTIF_ALL_EXCEPT, self, MSG_INFO, INFO_ITEM_BUFF_LOST, self.netname, self.buffs);
 516
 517                 self.buffs = 0;
 518                 sound(self, CH_TRIGGER, "relics/relic_effect.wav", VOL_BASE, ATTN_NORM);
 519                 return true;
 520         }
 521         return false;
 522 }
 523
 524 MUTATOR_HOOKFUNCTION(buffs_RemovePlayer)
 525 {
 526         if(self.buff_model)
 527         {
 528                 remove(self.buff_model);
 529                 self.buff_model = world;
 530         }
 531
 532         // also reset timers here to prevent them continuing after spectating
 533         self.buff_disability_time = 0;
 534         self.buff_disability_effect_time = 0;
 535
 536         return false;
 537 }
 538
 539 MUTATOR_HOOKFUNCTION(buffs_CustomizeWaypoint)
 540 {
 541         entity e = WaypointSprite_getviewentity(other);
 542
 543         // if you have the invisibility powerup, sprites ALWAYS are restricted to your team
 544         // but only apply this to real players, not to spectators
 545         if((self.owner.flags & FL_CLIENT) && (self.owner.buffs & BUFF_INVISIBLE) && (e == other))
 546         if(DIFF_TEAM(self.owner, e))
 547                 return true;
 548
 549         return false;
 550 }
 551
 552 MUTATOR_HOOKFUNCTION(buffs_OnEntityPreSpawn)
 553 {
 554         if(autocvar_g_buffs_replace_powerups)
 555         switch(self.classname)
 556         {
 557                 case "item_strength":
 558                 case "item_invincible":
 559                 {
 560                         entity e = spawn();
 561                         buff_SpawnReplacement(e, self);
 562                         return true;
 563                 }
 564         }
 565         return false;
 566 }
 567
 568 MUTATOR_HOOKFUNCTION(buffs_WeaponRate)
 569 {
 570         if(self.buffs & BUFF_SPEED)
 571                 weapon_rate *= autocvar_g_buffs_speed_rate;
 572
 573         if(time < self.buff_disability_time)
 574                 weapon_rate *= autocvar_g_buffs_disability_rate;
 575
 576         return false;
 577 }
 578
 579 MUTATOR_HOOKFUNCTION(buffs_PlayerThink)
 580 {
 581         if(gameover || self.deadflag != DEAD_NO) { return false; }
 582
 583         if(time < self.buff_disability_time)
 584         if(time >= self.buff_disability_effect_time)
 585         {
 586                 pointparticles(particleeffectnum("smoking"), self.origin + ((self.mins + self.maxs) * 0.5), '0 0 0', 1);
 587                 self.buff_disability_effect_time = time + 0.5;
 588         }
 589
 590         if(self.frozen)
 591         {
 592                 if(self.buffs)
 593                 {
 594                         Send_Notification(NOTIF_ALL_EXCEPT, self, MSG_INFO, INFO_ITEM_BUFF_LOST, self.netname, self.buffs);
 595                         self.buffs = 0;
 596                 }
 597         }
 598
 599         if((self.buffs & BUFF_INVISIBLE) && (self.oldbuffs & BUFF_INVISIBLE))
 600         if(self.alpha != autocvar_g_buffs_invisible_alpha)
 601                 self.alpha = autocvar_g_buffs_invisible_alpha;
 602
 603         if(self.buffs != self.oldbuffs)
 604         {
 605                 if(self.oldbuffs & BUFF_AMMO)
 606                 {
 607                         if(self.buff_ammo_prev_infitems)
 608                                 self.items |= IT_UNLIMITED_WEAPON_AMMO;
 609                         else
 610                                 self.items &= ~IT_UNLIMITED_WEAPON_AMMO;
 611                 }
 612                 else if(self.buffs & BUFF_AMMO)
 613                 {
 614                         self.buff_ammo_prev_infitems = (self.items & IT_UNLIMITED_WEAPON_AMMO);
 615                         self.items |= IT_UNLIMITED_WEAPON_AMMO;
 616                         if(!self.ammo_shells) { self.ammo_shells = 20; }
 617                         if(!self.ammo_cells) { self.ammo_cells = 20; }
 618                         if(!self.ammo_rockets) { self.ammo_rockets = 20; }
 619                         if(!self.ammo_nails) { self.ammo_nails = 20; }
 620                         if(!self.ammo_fuel) { self.ammo_fuel = 20; }
 621                 }
 622
 623                 if(self.oldbuffs & BUFF_INVISIBLE)
 624                 {
 625                         if(time < self.strength_finished && g_instagib)
 626                                 self.alpha = autocvar_g_instagib_invis_alpha;
 627                         else
 628                                 self.alpha = self.buff_invisible_prev_alpha;
 629                 }
 630                 else if(self.buffs & BUFF_INVISIBLE)
 631                 {
 632                         if(time < self.strength_finished && g_instagib)
 633                                 self.buff_invisible_prev_alpha = default_player_alpha;
 634                         else
 635                                 self.buff_invisible_prev_alpha = self.alpha;
 636                         self.alpha = autocvar_g_buffs_invisible_alpha;
 637                 }
 638
 639                 if(self.oldbuffs & BUFF_FLIGHT)
 640                         self.gravity = self.buff_flight_prev_gravity;
 641                 else if(self.buffs & BUFF_FLIGHT)
 642                 {
 643                         self.buff_flight_prev_gravity = self.gravity;
 644                         self.gravity = autocvar_g_buffs_flight_gravity;
 645                 }
 646
 647                 self.oldbuffs = self.buffs;
 648                 if(self.buffs)
 649                 {
 650                         if(!self.buff_model)
 651                         {
 652                                 self.buff_model = spawn();
 653                                 setmodel(self.buff_model, "models/relics/relic.md3");
 654                                 setsize(self.buff_model, '0 0 -40', '0 0 40');
 655                                 setattachment(self.buff_model, self, "");
 656                                 setorigin(self.buff_model, '0 0 1' * (self.buff_model.maxs.z * 1));
 657                                 self.buff_model.owner = self;
 658                                 self.buff_model.scale = 0.7;
 659                                 self.buff_model.pflags = PFLAGS_FULLDYNAMIC;
 660                                 self.buff_model.light_lev = 200;
 661                                 self.buff_model.customizeentityforclient = buffs_BuffModel_Customize;
 662                         }
 663                         self.buff_model.color = Buff_Color(self.buffs);
 664                         self.buff_model.glowmod = buff_GlowColor(self.buff_model);
 665                         self.buff_model.skin = Buff_Skin(self.buffs);
 666
 667                         self.effects |= EF_NOSHADOW;
 668                 }
 669                 else
 670                 {
 671                         remove(self.buff_model);
 672                         self.buff_model = world;
 673
 674                         self.effects &= ~(EF_NOSHADOW);
 675                 }
 676         }
 677
 678         if(self.buff_model)
 679         {
 680                 self.buff_model.effects = self.effects;
 681                 self.buff_model.effects |= EF_LOWPRECISION;
 682                 self.buff_model.effects = self.buff_model.effects & EFMASK_CHEAP; // eat performance
 683
 684                 self.buff_model.alpha = self.alpha;
 685         }
 686
 687         return false;
 688 }
 689
 690 MUTATOR_HOOKFUNCTION(buffs_SpectateCopy)
 691 {
 692         self.buffs = other.buffs;
 693         return false;
 694 }
 695
 696 MUTATOR_HOOKFUNCTION(buffs_VehicleEnter)
 697 {
 698         vh_vehicle.buffs = vh_player.buffs;
 699         vh_player.buffs = 0;
 700         return false;
 701 }
 702
 703 MUTATOR_HOOKFUNCTION(buffs_VehicleExit)
 704 {
 705         vh_player.buffs = vh_vehicle.buffs;
 706         vh_vehicle.buffs = 0;
 707         return false;
 708 }
 709
 710 MUTATOR_HOOKFUNCTION(buffs_PlayerRegen)
 711 {
 712         if(self.buffs & BUFF_MEDIC)
 713         {
 714                 regen_mod_rot = autocvar_g_buffs_medic_rot;
 715                 regen_mod_limit = regen_mod_max = autocvar_g_buffs_medic_max;
 716                 regen_mod_regen = autocvar_g_buffs_medic_regen;
 717         }
 718
 719         if(self.buffs & BUFF_SPEED)
 720                 regen_mod_regen = autocvar_g_buffs_speed_regen;
 721
 722         return false;
 723 }
 724
 725 MUTATOR_HOOKFUNCTION(buffs_GetCvars)
 726 {
 727         GetCvars_handleFloat(get_cvars_s, get_cvars_f, cvar_cl_buffs_autoreplace, "cl_buffs_autoreplace");
 728         return false;
 729 }
 730
 731 MUTATOR_HOOKFUNCTION(buffs_BuildMutatorsString)
 732 {
 733         ret_string = strcat(ret_string, ":Buffs");
 734         return false;
 735 }
 736
 737 MUTATOR_HOOKFUNCTION(buffs_BuildMutatorsPrettyString)
 738 {
 739         ret_string = strcat(ret_string, ", Buffs");
 740         return false;
 741 }
 742
 743 void buffs_DelayedInit()
 744 {
 745         if(autocvar_g_buffs_spawn_count > 0)
 746         if(find(world, classname, "item_buff") == world)
 747         {
 748                 float i;
 749                 for(i = 0; i < autocvar_g_buffs_spawn_count; ++i)
 750                 {
 751                         entity e = spawn();
 752                         e.spawnflags |= 1; // always randomize
 753                         e.velocity = randomvec() * 250; // this gets reset anyway if random location works
 754                         buff_Init(e);
 755                 }
 756         }
 757 }
 758
 759 void buffs_Initialize()
 760 {
 761         precache_model("models/relics/relic.md3");
 762         precache_sound("misc/strength_respawn.wav");
 763         precache_sound("misc/shield_respawn.wav");
 764         precache_sound("relics/relic_effect.wav");
 765         precache_sound("weapons/rocket_impact.wav");
 766         precache_sound("keepaway/respawn.wav");
 767
 768         addstat(STAT_BUFFS, AS_INT, buffs);
 769         addstat(STAT_MOVEVARS_JUMPVELOCITY, AS_FLOAT, stat_jumpheight);
 770
 771         InitializeEntity(world, buffs_DelayedInit, INITPRIO_FINDTARGET);
 772 }
 773
 774 MUTATOR_DEFINITION(mutator_buffs)
 775 {
 776         MUTATOR_HOOK(PlayerDamage_SplitHealthArmor, buffs_PlayerDamage_SplitHealthArmor, CBC_ORDER_ANY);
 777         MUTATOR_HOOK(PlayerDamage_Calculate, buffs_PlayerDamage_Calculate, CBC_ORDER_ANY);
 778         MUTATOR_HOOK(PlayerSpawn, buffs_PlayerSpawn, CBC_ORDER_ANY);
 779         MUTATOR_HOOK(PlayerPhysics, buffs_PlayerPhysics, CBC_ORDER_ANY);
 780         MUTATOR_HOOK(PlayerJump, buffs_PlayerJump, CBC_ORDER_ANY);
 781         MUTATOR_HOOK(MonsterMove, buffs_MonsterMove, CBC_ORDER_ANY);
 782         MUTATOR_HOOK(SpectateCopy, buffs_SpectateCopy, CBC_ORDER_ANY);
 783         MUTATOR_HOOK(VehicleEnter, buffs_VehicleEnter, CBC_ORDER_ANY);
 784         MUTATOR_HOOK(VehicleExit, buffs_VehicleExit, CBC_ORDER_ANY);
 785         MUTATOR_HOOK(PlayerRegen, buffs_PlayerRegen, CBC_ORDER_ANY);
 786         MUTATOR_HOOK(PlayerDies, buffs_PlayerDies, CBC_ORDER_ANY);
 787         MUTATOR_HOOK(PlayerUseKey, buffs_PlayerUseKey, CBC_ORDER_FIRST);
 788         MUTATOR_HOOK(MakePlayerObserver, buffs_RemovePlayer, CBC_ORDER_ANY);
 789         MUTATOR_HOOK(ClientDisconnect, buffs_RemovePlayer, CBC_ORDER_ANY);
 790         MUTATOR_HOOK(OnEntityPreSpawn, buffs_OnEntityPreSpawn, CBC_ORDER_ANY);
 791         MUTATOR_HOOK(CustomizeWaypoint, buffs_CustomizeWaypoint, CBC_ORDER_ANY);
 792         MUTATOR_HOOK(WeaponRateFactor, buffs_WeaponRate, CBC_ORDER_ANY);
 793         MUTATOR_HOOK(PlayerPreThink, buffs_PlayerThink, CBC_ORDER_ANY);
 794         MUTATOR_HOOK(GetCvars, buffs_GetCvars, CBC_ORDER_ANY);
 795         MUTATOR_HOOK(BuildMutatorsString, buffs_BuildMutatorsString, CBC_ORDER_ANY);
 796         MUTATOR_HOOK(BuildMutatorsPrettyString, buffs_BuildMutatorsPrettyString, CBC_ORDER_ANY);
 797
 798         MUTATOR_ONADD
 799         {
 800                 buffs_Initialize();
 801         }
 802
 803         return false;
 804 }