qcsrc/server/mutators/mutator_overkill.qc

   1 void ok_DecreaseCharge(entity ent, float wep)
   2 {
   3         if not(autocvar_g_overkill_ammo_charge) return;
   4
   5         entity wepent = get_weaponinfo(wep);
   6
   7         if(wepent.netname == "")
   8                 return; // dummy
   9
  10         ent.ammo_charge[wep] -= cvar(sprintf("g_overkill_ammo_decharge_%s", wepent.netname));
  11 }
  12
  13 void ok_IncreaseCharge(entity ent, float wep)
  14 {
  15         entity wepent = get_weaponinfo(wep);
  16
  17         if(wepent.netname == "")
  18                 return; // dummy
  19
  20         if(autocvar_g_overkill_ammo_charge)
  21         if not(ent.BUTTON_ATCK)
  22         if(ent.ammo_charge[wep] <= autocvar_g_overkill_ammo_charge_limit)
  23                 ent.ammo_charge[wep] = min(autocvar_g_overkill_ammo_charge_limit, ent.ammo_charge[wep] + cvar(sprintf("g_overkill_ammo_charge_rate_%s", wepent.netname)) * frametime / W_TICSPERFRAME);
  24 }
  25
  26 float ok_CheckWeaponCharge(entity ent, float wep)
  27 {
  28         if not(autocvar_g_overkill_ammo_charge) return TRUE;
  29         //if(wep != swep) return TRUE; // switching, don't even bother checking
  30
  31         entity wepent = get_weaponinfo(wep);
  32
  33         if(wepent.netname == "")
  34                 return 0; // dummy
  35
  36         return !(ent.ammo_charge[wep] < cvar(sprintf("g_overkill_ammo_decharge_%s", wepent.netname)));
  37 }
  38
  39 void start_hmg()
  40 {
  41         self.classname = "weapon_hmg";
  42         self.respawntime = autocvar_g_overkill_superguns_respawn_time;
  43         self.ok_item = TRUE;
  44         setmodel(self, "models/weapons/g_ok_hmg.md3");
  45         spawnfunc_weapon_hmg();
  46 }
  47
  48 void start_rpc()
  49 {
  50         self.classname = "weapon_rpc";
  51         self.respawntime = autocvar_g_overkill_superguns_respawn_time;
  52         self.ok_item = TRUE;
  53         setmodel(self, "models/weapons/g_ok_rl.md3");
  54         spawnfunc_weapon_rpc();
  55 }
  56
  57 MUTATOR_HOOKFUNCTION(ok_PlayerDamage_Calculate)
  58 {
  59         if(DEATH_ISWEAPON(frag_deathtype, WEP_LASER) && frag_target == frag_attacker)
  60                 frag_damage = 0;
  61
  62         if(!IS_PLAYER(frag_target) || frag_target == frag_attacker)
  63                 return FALSE;
  64
  65         if not (DEATH_ISWEAPON(frag_deathtype, WEP_LASER))
  66                 return FALSE;
  67
  68         frag_damage = 0;
  69         if(frag_target.health >= 1 && !frag_target.freezetag_frozen)
  70                 Send_Notification(NOTIF_ONE, frag_attacker, MSG_CENTER, CENTER_MINSTA_SECONDARY);
  71
  72         frag_force = '0 0 0';
  73
  74         return FALSE;
  75 }
  76
  77 MUTATOR_HOOKFUNCTION(ok_BuildMutatorsString)
  78 {
  79         ret_string = strcat(ret_string, ":OK");
  80         return FALSE;
  81 }
  82
  83 MUTATOR_HOOKFUNCTION(ok_BuildMutatorsPrettyString)
  84 {
  85         ret_string = strcat(ret_string, ", Overkill");
  86         return FALSE;
  87 }
  88
  89 MUTATOR_HOOKFUNCTION(ok_PlayerDies)
  90 {
  91         self.ok_lastwep = self.weapon;
  92         self.ok_deathloc = self.origin;
  93
  94         entity oldself = self;
  95
  96         self = spawn();
  97         self.ok_item = TRUE;
  98         self.noalign = TRUE;
  99         spawnfunc_item_armor_small();
 100         self.movetype = MOVETYPE_TOSS;
 101         self.gravity = 1;
 102         self.reset = SUB_Remove;
 103         setorigin(self, frag_target.origin + '0 0 32');
 104         self.velocity = '0 0 200' + normalize(frag_attacker.origin - self.origin) * 500;
 105         self.classname = "droppedweapon"; // hax
 106         SUB_SetFade(self, time + 5, 1);
 107         self = oldself;
 108
 109         return FALSE;
 110 }
 111
 112 MUTATOR_HOOKFUNCTION(ok_ForbidThrowCurrentWeapon)
 113 {
 114         return TRUE;
 115 }
 116
 117 MUTATOR_HOOKFUNCTION(ok_PlayerPreThink)
 118 {
 119         if(intermission_running || gameover)
 120                 return FALSE;
 121
 122         if(self.deadflag != DEAD_NO || !IS_PLAYER(self))
 123                 return FALSE;
 124
 125         if(self.freezetag_frozen)
 126                 return FALSE;
 127
 128         ok_IncreaseCharge(self, self.weapon);
 129
 130         if(self.BUTTON_ATCK2)
 131         if(!forbidWeaponUse() || self.weapon_blocked) // allow if weapon is blocked
 132         if(self.jump_interval <= time)
 133         {
 134                 self.jump_interval = time + autocvar_g_balance_laser_primary_refire * W_WeaponRateFactor();
 135                 makevectors(self.v_angle);
 136                 float w = self.weapon;
 137                 self.weapon = WEP_LASER;
 138                 W_Laser_Attack(3);
 139                 self.weapon = w;
 140         }
 141
 142         self.weapon_blocked = FALSE;
 143
 144         self.stat_ok_ammo_charge = self.ammo_charge[self.weapon];
 145
 146         if(autocvar_g_overkill_ammo_charge)
 147         if(!ok_CheckWeaponCharge(self, self.weapon))
 148         {
 149                 if(autocvar_g_overkill_ammo_charge_notice && time > self.ok_notice_time && self.BUTTON_ATCK && IS_REAL_CLIENT(self))
 150                 {
 151                         //Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_OVERKILL_CHARGE);
 152                         self.ok_notice_time = time + 2;
 153                         play2(self, "weapons/dryfire.wav");
 154                 }
 155                 if(self.weaponentity.state != WS_CLEAR)
 156                         w_ready();
 157
 158                 self.weapon_blocked = TRUE;
 159         }
 160
 161         self.BUTTON_ATCK2 = 0;
 162
 163         return FALSE;
 164 }
 165
 166 MUTATOR_HOOKFUNCTION(ok_PlayerSpawn)
 167 {
 168         if(autocvar_g_overkill_ammo_charge)
 169         {
 170                 float i;
 171
 172                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 173                         self.ammo_charge[i] = autocvar_g_overkill_ammo_charge_limit;
 174
 175                 self.ok_use_ammocharge = 1;
 176                 self.ok_notice_time = time;
 177         }
 178         else
 179                 self.ok_use_ammocharge = 0;
 180
 181         return FALSE;
 182 }
 183
 184 MUTATOR_HOOKFUNCTION(ok_OnEntityPreSpawn)
 185 {
 186         if(autocvar_g_powerups)
 187         if(autocvar_g_overkill_powerups_replace)
 188         if(self.classname == "item_strength")
 189         {
 190                 entity wep = spawn();
 191                 setorigin(wep, self.origin);
 192                 wep.ok_item = TRUE;
 193                 wep.think = start_hmg;
 194                 wep.nextthink = time + 0.1;
 195                 wep.noalign = self.noalign;
 196                 return TRUE;
 197         }
 198
 199         if(autocvar_g_powerups)
 200         if(autocvar_g_overkill_powerups_replace)
 201         if(self.classname == "item_invincible")
 202         {
 203                 entity wep = spawn();
 204                 setorigin(wep, self.origin);
 205                 wep.ok_item = TRUE;
 206                 wep.think = start_rpc;
 207                 wep.nextthink = time + 0.1;
 208                 wep.noalign = self.noalign;
 209                 return TRUE;
 210         }
 211
 212         return FALSE;
 213 }
 214
 215 MUTATOR_HOOKFUNCTION(ok_FilterItem)
 216 {
 217         if(self.ok_item)
 218                 return FALSE;
 219
 220         switch(self.classname)
 221         {
 222                 case "item_health_mega": return !(autocvar_g_overkill_100h_anyway);
 223                 case "item_armor_large": return !(autocvar_g_overkill_100a_anyway);
 224         }
 225
 226         return TRUE;
 227 }
 228
 229 MUTATOR_HOOKFUNCTION(ok_SpectateCopy)
 230 {
 231         self.ammo_charge[self.weapon] = other.ammo_charge[other.weapon];
 232         self.ok_use_ammocharge = other.ok_use_ammocharge;
 233
 234         return FALSE;
 235 }
 236
 237 MUTATOR_HOOKFUNCTION(ok_SetModname)
 238 {
 239         modname = "Overkill";
 240         return TRUE;
 241 }
 242
 243 MUTATOR_HOOKFUNCTION(ok_StartItems)
 244 {
 245         start_items |= IT_UNLIMITED_WEAPON_AMMO;
 246         start_weapons = (WEPSET_UZI | WEPSET_NEX | WEPSET_SHOTGUN);
 247
 248         start_ammo_nails = start_ammo_cells = start_ammo_shells = start_ammo_rockets =
 249         warmup_start_ammo_nails = warmup_start_ammo_cells = warmup_start_ammo_shells = warmup_start_ammo_rockets = autocvar_g_overkill_ammo_start;
 250
 251         return FALSE;
 252 }
 253
 254 void ok_Initialize()
 255 {
 256         precache_all_playermodels("models/ok_player/*.dpm");
 257
 258         precache_model("models/weapons/h_ok_rl.iqm");
 259         precache_model("models/weapons/v_ok_rl.md3");
 260         precache_model("models/weapons/g_ok_rl.md3");
 261         precache_model("models/weapons/ok_rocket.md3");
 262
 263         precache_model("models/weapons/h_ok_mg.iqm");
 264         precache_model("models/weapons/v_ok_mg.md3");
 265         precache_model("models/weapons/g_ok_mg.md3");
 266
 267         precache_model("models/weapons/h_ok_hmg.iqm");
 268         precache_model("models/weapons/v_ok_hmg.md3");
 269         precache_model("models/weapons/g_ok_hmg.md3");
 270
 271         precache_model("models/weapons/h_ok_shotgun.iqm");
 272         precache_model("models/weapons/v_ok_shotgun.md3");
 273         precache_model("models/weapons/g_ok_shotgun.md3");
 274
 275         precache_model("models/weapons/h_ok_sniper.iqm");
 276         precache_model("models/weapons/v_ok_sniper.md3");
 277         precache_model("models/weapons/g_ok_sniper.md3");
 278
 279         precache_sound("weapons/dryfire.wav");
 280
 281         addstat(STAT_OK_AMMO_CHARGE, AS_FLOAT, ok_use_ammocharge);
 282         addstat(STAT_OK_AMMO_CHARGEPOOl, AS_FLOAT, stat_ok_ammo_charge);
 283
 284         w_uzi(WR_PRECACHE);
 285         w_nex(WR_PRECACHE);
 286         w_shotgun(WR_PRECACHE);
 287         w_laser(WR_PRECACHE);
 288
 289         (get_weaponinfo(WEP_RPC)).spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
 290         (get_weaponinfo(WEP_HMG)).spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
 291
 292         (get_weaponinfo(WEP_SHOTGUN)).mdl = "ok_shotgun";
 293         (get_weaponinfo(WEP_UZI)).mdl = "ok_mg";
 294         (get_weaponinfo(WEP_NEX)).mdl = "ok_sniper";
 295
 296         string s;
 297         float fh = fopen("overkill.cfg", FILE_READ);
 298         if(fh >= 0)
 299         {
 300                 while((s = fgets(fh)))
 301                 {
 302                         tokenize_console(s);
 303                         if not(argv(0) == "" || argv(1) == "//" || argv(1) == "")
 304                                 cvar_settemp(argv(0), argv(1));
 305                 }
 306                 fclose(fh);
 307         }
 308         else
 309                 dprint("^1Mutator Overkill: WARNING! overkill.cfg NOT found, things will be strange!\n");
 310 }
 311
 312 MUTATOR_DEFINITION(mutator_overkill)
 313 {
 314         MUTATOR_HOOK(ForbidThrowCurrentWeapon, ok_ForbidThrowCurrentWeapon, CBC_ORDER_ANY);
 315         MUTATOR_HOOK(BuildMutatorsString, ok_BuildMutatorsString, CBC_ORDER_ANY);
 316         MUTATOR_HOOK(BuildMutatorsPrettyString, ok_BuildMutatorsPrettyString, CBC_ORDER_ANY);
 317         MUTATOR_HOOK(PlayerPreThink, ok_PlayerPreThink, CBC_ORDER_LAST);
 318         MUTATOR_HOOK(PlayerSpawn, ok_PlayerSpawn, CBC_ORDER_LAST);
 319         MUTATOR_HOOK(PlayerDamage_Calculate, ok_PlayerDamage_Calculate, CBC_ORDER_LAST);
 320         MUTATOR_HOOK(PlayerDies, ok_PlayerDies, CBC_ORDER_ANY);
 321         MUTATOR_HOOK(OnEntityPreSpawn, ok_OnEntityPreSpawn, CBC_ORDER_ANY);
 322         MUTATOR_HOOK(SetModname, ok_SetModname, CBC_ORDER_ANY);
 323         MUTATOR_HOOK(FilterItem, ok_FilterItem, CBC_ORDER_ANY);
 324         MUTATOR_HOOK(SpectateCopy, ok_SpectateCopy, CBC_ORDER_ANY);
 325         MUTATOR_HOOK(SetStartItems, ok_StartItems, CBC_ORDER_ANY);
 326
 327         MUTATOR_ONADD
 328         {
 329                 ok_Initialize();
 330         }
 331
 332         MUTATOR_ONREMOVE
 333         {
 334                 (get_weaponinfo(WEP_RPC)).spawnflags |= WEP_FLAG_MUTATORBLOCKED;
 335                 (get_weaponinfo(WEP_HMG)).spawnflags |= WEP_FLAG_MUTATORBLOCKED;
 336         }
 337
 338         return FALSE;
 339 }