qcsrc/server/mutators/mutator_overkill.qc

   1 void ok_DecreaseCharge(entity ent, float wep)
   2 {
   3         if not(autocvar_g_overkill_ammo_charge) return;
   4
   5         entity wepent = get_weaponinfo(wep);
   6
   7         if(wepent.netname == "")
   8                 return; // dummy
   9
  10         ent.ammo_charge[wep] -= cvar(sprintf("g_overkill_ammo_decharge_%s", wepent.netname));
  11 }
  12
  13 void ok_IncreaseCharge(entity ent, float wep)
  14 {
  15         entity wepent = get_weaponinfo(wep);
  16
  17         if(wepent.netname == "")
  18                 return; // dummy
  19
  20         if(autocvar_g_overkill_ammo_charge)
  21         if not(ent.BUTTON_ATCK)
  22         if(ent.ammo_charge[wep] <= autocvar_g_overkill_ammo_charge_limit)
  23                 ent.ammo_charge[wep] = min(autocvar_g_overkill_ammo_charge_limit, ent.ammo_charge[wep] + cvar(sprintf("g_overkill_ammo_charge_rate_%s", wepent.netname)) * frametime / W_TICSPERFRAME);
  24 }
  25
  26 float ok_CheckWeaponCharge(entity ent, float wep, float swep)
  27 {
  28         if not(autocvar_g_overkill_ammo_charge) return TRUE;
  29         //if(wep != swep) return TRUE; // switching, don't even bother checking
  30
  31         entity wepent = get_weaponinfo(wep);
  32
  33         if(wepent.netname == "")
  34                 return 0; // dummy
  35
  36         return !(ent.ammo_charge[wep] < cvar(sprintf("g_overkill_ammo_decharge_%s", wepent.netname)));
  37 }
  38
  39 MUTATOR_HOOKFUNCTION(ok_PlayerDamage_Calculate)
  40 {
  41         if(DEATH_ISWEAPON(frag_deathtype, WEP_LASER) && frag_target == frag_attacker)
  42                 frag_damage = 0;
  43
  44         if(!IS_PLAYER(frag_target) || frag_target == frag_attacker)
  45                 return FALSE;
  46
  47         if not (DEATH_ISWEAPON(frag_deathtype, WEP_LASER))
  48                 return FALSE;
  49
  50         frag_damage = 0;
  51         if(frag_target.health >= 1 && !frag_target.freezetag_frozen)
  52                 Send_Notification(NOTIF_ONE, frag_attacker, MSG_CENTER, CENTER_MINSTA_SECONDARY);
  53
  54         frag_force = '0 0 0';
  55
  56         return FALSE;
  57 }
  58
  59 MUTATOR_HOOKFUNCTION(ok_BuildMutatorsString)
  60 {
  61         ret_string = strcat(ret_string, ":OK");
  62         return FALSE;
  63 }
  64
  65 MUTATOR_HOOKFUNCTION(ok_BuildMutatorsPrettyString)
  66 {
  67         ret_string = strcat(ret_string, ", Overkill");
  68         return FALSE;
  69 }
  70
  71 void ok_Item_Touch()
  72 {
  73         if(IS_PLAYER(other) && other.deadflag == DEAD_NO && !other.freezetag_frozen)
  74         {
  75                 Item_Touch();
  76                 remove(self);
  77         }
  78 }
  79
  80 MUTATOR_HOOKFUNCTION(ok_PlayerDies)
  81 {
  82         self.ok_lastwep = self.weapon;
  83         self.ok_deathloc = self.origin;
  84
  85         entity oldself = self;
  86         float gpi = autocvar_g_pickup_items;
  87
  88         cvar_set("g_pickup_items", "1");
  89         self = spawn();
  90         self.ok_item = TRUE;
  91         self.noalign = TRUE;
  92         spawnfunc_item_armor_small();
  93         self.movetype = MOVETYPE_TOSS;
  94         self.gravity = 1;
  95         setorigin(self, frag_target.origin + '0 0 32');
  96         self.velocity = '0 0 200' + normalize(frag_attacker.origin - self.origin) * 500;
  97         self.touch = ok_Item_Touch;
  98         SUB_SetFade(self, time + 5, 1);
  99         self = oldself;
 100         cvar_set("g_pickup_items", ftos(gpi));
 101
 102         return FALSE;
 103 }
 104
 105 MUTATOR_HOOKFUNCTION(ok_ForbidThrowCurrentWeapon)
 106 {
 107         return TRUE;
 108 }
 109
 110 MUTATOR_HOOKFUNCTION(ok_PlayerPreThink)
 111 {
 112         if(intermission_running || gameover)
 113                 return FALSE;
 114
 115         if(self.deadflag != DEAD_NO || !IS_PLAYER(self))
 116                 return FALSE;
 117
 118         if(self.freezetag_frozen)
 119                 return FALSE;
 120
 121         ok_IncreaseCharge(self, self.weapon);
 122
 123         if(self.BUTTON_ATCK2)
 124                 if(self.jump_interval <= time)
 125                 {
 126                         self.jump_interval = time + autocvar_g_balance_laser_primary_refire * W_WeaponRateFactor();
 127                         makevectors(self.v_angle);
 128                         float w = self.weapon;
 129                         self.weapon = WEP_LASER;
 130                         W_Laser_Attack(3);
 131                         self.weapon = w;
 132                 }
 133
 134         self.weapon_blocked = FALSE;
 135
 136         self.ok_ammo_charge = self.ammo_charge[self.weapon];
 137
 138         if(autocvar_g_overkill_ammo_charge)
 139         if(!ok_CheckWeaponCharge(self, self.weapon, self.switchweapon))
 140         {
 141                 if(autocvar_g_overkill_ammo_charge_notice && time > self.ok_notice_time && self.BUTTON_ATCK && IS_REAL_CLIENT(self))
 142                 {
 143                         //Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_OVERKILL_CHARGE);
 144                         self.ok_notice_time = time + 2;
 145                         play2(self, "weapons/dryfire.wav");
 146                 }
 147                 if(self.weaponentity.state != WS_CLEAR)
 148                         w_ready();
 149
 150                 self.weapon_blocked = TRUE;
 151         }
 152
 153         self.BUTTON_ATCK2 = 0;
 154
 155         return FALSE;
 156 }
 157
 158 MUTATOR_HOOKFUNCTION(ok_PlayerSpawn)
 159 {
 160         if(autocvar_g_overkill_ammo_charge)
 161         {
 162                 float i;
 163
 164                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 165                         self.ammo_charge[i] = autocvar_g_overkill_ammo_charge_limit;
 166
 167                 self.ok_use_ammocharge = 1;
 168                 self.ok_notice_time = time;
 169         }
 170         else
 171                 self.ok_use_ammocharge = 0;
 172
 173         return FALSE;
 174 }
 175
 176 void start_hmg()
 177 {
 178         float gpi = autocvar_g_pickup_items;
 179         cvar_set("g_pickup_items", "1");
 180         self.classname = "weapon_hmg";
 181         self.ok_item = TRUE;
 182         //self.weapons = WEP_HMG;
 183         //self.flags |= FL_POWERUP;
 184         self.respawntime = autocvar_g_overkill_superguns_respawn_time;
 185         setmodel(self, "models/weapons/g_ok_hmg.md3");
 186         spawnfunc_weapon_hmg();
 187
 188         cvar_set("g_pickup_items", ftos(gpi));
 189 }
 190
 191 void start_rpc()
 192 {
 193         float gpi = autocvar_g_pickup_items;
 194         cvar_set("g_pickup_items", "1");
 195         self.classname = "weapon_rpc";
 196         self.respawntime = autocvar_g_overkill_superguns_respawn_time;
 197         self.ok_item = TRUE;
 198         //self.weapons = WEP_RPC;
 199         //self.flags |= FL_POWERUP;
 200         setmodel(self, "models/weapons/g_ok_rl.md3");
 201         spawnfunc_weapon_rpc();
 202         cvar_set("g_pickup_items", ftos(gpi));
 203 }
 204
 205 void start_mh_anyway()
 206 {
 207         cvar_set("g_pickup_items", "1");
 208         self.classname = "item_health_mega";
 209         self.ok_item = TRUE;
 210         spawnfunc_item_health_mega();
 211         cvar_set("g_pickup_items", "0");
 212 }
 213
 214 void start_ma_anyway()
 215 {
 216         cvar_set("g_pickup_items", "1");
 217         self.classname = "item_armor_large";
 218         self.ok_item = TRUE;
 219         spawnfunc_item_armor_large();
 220         cvar_set("g_pickup_items", "0");
 221 }
 222
 223 MUTATOR_HOOKFUNCTION(ok_OnEntityPreSpawn)
 224 {
 225         if(autocvar_g_powerups)
 226         if(autocvar_g_overkill_powerups_replace)
 227         if(self.classname == "item_strength")
 228         {
 229                 entity wep = spawn();
 230                 setorigin(wep, self.origin);
 231                 wep.ok_item = TRUE;
 232                 wep.think = start_hmg;
 233                 wep.nextthink = time + 0.1;
 234                 return TRUE;
 235         }
 236
 237         if(autocvar_g_powerups)
 238         if(autocvar_g_overkill_powerups_replace)
 239         if(self.classname == "item_invincible")
 240         {
 241                 entity wep = spawn();
 242                 setorigin(wep, self.origin);
 243                 wep.ok_item = TRUE;
 244                 wep.think = start_rpc;
 245                 wep.nextthink = time + 0.1;
 246                 return TRUE;
 247         }
 248
 249         return FALSE;
 250 }
 251
 252 MUTATOR_HOOKFUNCTION(ok_ItemRemove)
 253 {
 254         if(self.ok_item)
 255                 return FALSE;
 256
 257         switch(self.items)
 258         {
 259                 case IT_HEALTH: return !(autocvar_g_overkill_100h_anyway);
 260                 case IT_ARMOR: return !(autocvar_g_overkill_100a_anyway);
 261         }
 262
 263         return TRUE;
 264 }
 265
 266 MUTATOR_HOOKFUNCTION(ok_SpectateCopy)
 267 {
 268         self.ammo_charge[self.weapon] = other.ammo_charge[other.weapon];
 269         self.ok_use_ammocharge = other.ok_use_ammocharge;
 270
 271         return FALSE;
 272 }
 273
 274 MUTATOR_HOOKFUNCTION(ok_SetModname)
 275 {
 276         modname = "Overkill";
 277         return TRUE;
 278 }
 279
 280 MUTATOR_HOOKFUNCTION(ok_StartItems)
 281 {
 282         start_items |= IT_UNLIMITED_WEAPON_AMMO;
 283         start_weapons = (WEPSET_UZI | WEPSET_NEX | WEPSET_SHOTGUN);
 284
 285         start_ammo_nails = start_ammo_cells = start_ammo_shells = start_ammo_rockets =
 286         warmup_start_ammo_nails = warmup_start_ammo_cells = warmup_start_ammo_shells = warmup_start_ammo_rockets = autocvar_g_overkill_ammo_start;
 287
 288         return FALSE;
 289 }
 290
 291 void ok_Initialize()
 292 {
 293         precache_all_playermodels("models/ok_player/*.dpm");
 294
 295         precache_model("models/weapons/h_ok_rl.iqm");
 296         precache_model("models/weapons/v_ok_rl.md3");
 297         precache_model("models/weapons/g_ok_rl.md3");
 298         precache_model("models/weapons/ok_rocket.md3");
 299
 300         precache_model("models/weapons/h_ok_mg.iqm");
 301         precache_model("models/weapons/v_ok_mg.md3");
 302         precache_model("models/weapons/g_ok_mg.md3");
 303
 304         precache_model("models/weapons/h_ok_hmg.iqm");
 305         precache_model("models/weapons/v_ok_hmg.md3");
 306         precache_model("models/weapons/g_ok_hmg.md3");
 307
 308         precache_model("models/weapons/h_ok_shotgun.iqm");
 309         precache_model("models/weapons/v_ok_shotgun.md3");
 310         precache_model("models/weapons/g_ok_shotgun.md3");
 311
 312         precache_model("models/weapons/h_ok_sniper.iqm");
 313         precache_model("models/weapons/v_ok_sniper.md3");
 314         precache_model("models/weapons/g_ok_sniper.md3");
 315
 316         precache_sound("weapons/dryfire.wav");
 317
 318         addstat(STAT_OK_AMMO_CHARGE, AS_FLOAT, ok_use_ammocharge);
 319         addstat(STAT_OK_AMMO_CHARGEPOOl, AS_FLOAT, ok_ammo_charge);
 320
 321         w_uzi(WR_PRECACHE);
 322         w_nex(WR_PRECACHE);
 323         w_shotgun(WR_PRECACHE);
 324         w_laser(WR_PRECACHE);
 325
 326         (get_weaponinfo(WEP_RPC)).spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
 327         (get_weaponinfo(WEP_HMG)).spawnflags &= ~WEP_FLAG_MUTATORBLOCKED;
 328
 329         (get_weaponinfo(WEP_SHOTGUN)).mdl = "ok_shotgun";
 330         (get_weaponinfo(WEP_UZI)).mdl = "ok_mg";
 331         (get_weaponinfo(WEP_NEX)).mdl = "ok_sniper";
 332
 333         string s;
 334         float fh = fopen("overkill.cfg", FILE_READ);
 335         if(fh >= 0)
 336         {
 337                 while((s = fgets(fh)))
 338                 {
 339                         tokenize_console(s);
 340                         if not(argv(0) == "" || argv(1) == "//" || argv(1) == "")
 341                                 cvar_settemp(argv(0), argv(1));
 342                 }
 343                 fclose(fh);
 344         }
 345         else
 346                 dprint("^1Mutator Overkill: WARNING! overkill.cfg NOT found, things will be strange!\n");
 347 }
 348
 349 MUTATOR_DEFINITION(mutator_overkill)
 350 {
 351         MUTATOR_HOOK(ForbidThrowCurrentWeapon, ok_ForbidThrowCurrentWeapon, CBC_ORDER_ANY);
 352         MUTATOR_HOOK(BuildMutatorsString, ok_BuildMutatorsString, CBC_ORDER_ANY);
 353         MUTATOR_HOOK(BuildMutatorsPrettyString, ok_BuildMutatorsPrettyString, CBC_ORDER_ANY);
 354         MUTATOR_HOOK(PlayerPreThink, ok_PlayerPreThink, CBC_ORDER_LAST);
 355         MUTATOR_HOOK(PlayerSpawn, ok_PlayerSpawn, CBC_ORDER_LAST);
 356         MUTATOR_HOOK(PlayerDamage_Calculate, ok_PlayerDamage_Calculate, CBC_ORDER_LAST);
 357         MUTATOR_HOOK(PlayerDies, ok_PlayerDies, CBC_ORDER_ANY);
 358         MUTATOR_HOOK(OnEntityPreSpawn, ok_OnEntityPreSpawn, CBC_ORDER_ANY);
 359         MUTATOR_HOOK(SetModname, ok_SetModname, CBC_ORDER_ANY);
 360         MUTATOR_HOOK(FilterItem, ok_ItemRemove, CBC_ORDER_ANY);
 361         MUTATOR_HOOK(SpectateCopy, ok_SpectateCopy, CBC_ORDER_ANY);
 362         MUTATOR_HOOK(SetStartItems, ok_StartItems, CBC_ORDER_ANY);
 363
 364         MUTATOR_ONADD
 365         {
 366                 ok_Initialize();
 367         }
 368
 369         MUTATOR_ONREMOVE
 370         {
 371                 (get_weaponinfo(WEP_RPC)).spawnflags |= WEP_FLAG_MUTATORBLOCKED;
 372                 (get_weaponinfo(WEP_HMG)).spawnflags |= WEP_FLAG_MUTATORBLOCKED;
 373         }
 374
 375         return FALSE;
 376 }