qcsrc/server/mutators/sandbox.qc

   1 const float MAX_STORAGE_ATTACHMENTS = 16;
   2 float object_count;
   3 .string object_clipboard;
   4 .entity object_attach;
   5 .string material;
   6
   7 .float touch_timer;
   8 void sandbox_ObjectFunction_Touch()
   9 {
  10         // apply material impact effects
  11
  12         if(!self.material)
  13                 return;
  14         if(self.touch_timer > time)
  15                 return; // don't execute each frame
  16         self.touch_timer = time + 0.1;
  17
  18         // make particle count and sound volume depend on impact speed
  19         float intensity;
  20         intensity = vlen(self.velocity) + vlen(other.velocity);
  21         if(intensity) // avoid divisions by 0
  22                 intensity /= 2; // average the two velocities
  23         if not(intensity >= autocvar_g_sandbox_object_material_velocity_min)
  24                 return; // impact not strong enough to do anything
  25         // now offset intensity and apply it to the effects
  26         intensity -= autocvar_g_sandbox_object_material_velocity_min; // start from minimum velocity, not actual velocity
  27         intensity = bound(0, intensity * autocvar_g_sandbox_object_material_velocity_factor, 1);
  28
  29         sound(self, CH_TRIGGER, strcat("object/impact_", self.material, "_", ftos(ceil(random() * 5)) , ".ogg"), VOL_BASE * intensity, ATTN_NORM);
  30         pointparticles(particleeffectnum(strcat("impact_", self.material)), self.origin, '0 0 0', ceil(intensity * 10)); // allow a count from 1 to 10
  31 }
  32
  33 entity sandbox_ObjectEdit_Get(float permissions)
  34 {
  35         // returns the traced entity if the player can edit it, and world if not
  36         // if permissions if FALSE, the object is returned regardless of editing rights
  37         // attached objects are SOLID_NOT and don't risk getting traced
  38
  39         makevectors(self.v_angle);
  40         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_edit, MOVE_NORMAL, self);
  41
  42         if(trace_ent.classname != "object")
  43                 return world; // entity is not an object
  44         if(!permissions)
  45                 return trace_ent; // don't check permissions, anyone can edit this object
  46         if(!trace_ent.crypto_idfp)
  47                 return trace_ent; // the player who spawned this object did not have an UID, so anyone can edit it
  48         if not(trace_ent.crypto_idfp != self.crypto_idfp && autocvar_g_sandbox_editor_free < 2)
  49                 return trace_ent; // object does not belong to the player, and players can only edit their own objects on this server
  50         return world;
  51 }
  52
  53 void sandbox_ObjectEdit_Scale(entity e, float f)
  54 {
  55         e.scale = f;
  56         if(e.scale)
  57         {
  58                 e.scale = bound(autocvar_g_sandbox_object_scale_min, e.scale, autocvar_g_sandbox_object_scale_max);
  59                 setsize(e, e.mins * e.scale, e.maxs * e.scale); // adapt bounding box size to model size
  60         }
  61 }
  62
  63 void sandbox_ObjectAttach_Remove(entity e);
  64 void sandbox_ObjectAttach_Set(entity e, entity parent, string s)
  65 {
  66         // attaches e to parent on string s
  67
  68         // we can't attach to an attachment, for obvious reasons
  69         sandbox_ObjectAttach_Remove(e);
  70
  71         e.movetype = MOVETYPE_FOLLOW;
  72         e.solid = SOLID_NOT;
  73         e.takedamage = DAMAGE_NO;
  74
  75         setattachment(e, parent, s);
  76         e.owner = parent;
  77 }
  78
  79 void sandbox_ObjectAttach_Remove(entity e)
  80 {
  81         // detaches any object attached to e
  82
  83         entity head;
  84         for(head = world; (head = find(head, classname, "object")); )
  85         {
  86                 if(head.owner == e)
  87                 {
  88                         head.movetype = MOVETYPE_TOSS; // default
  89                         head.solid = SOLID_BBOX;
  90                         head.takedamage = DAMAGE_AIM;
  91
  92                         setattachment(head, world, "");
  93                         head.owner = world;
  94
  95                         // objects reset origin and angles when detached, so apply the parent's to prevent teleporting
  96                         setorigin(head, e.origin);
  97                         head.angles = e.angles;
  98                 }
  99         }
 100 }
 101
 102 entity sandbox_ObjectSpawn(float database)
 103 {
 104         // spawn a new object with default properties
 105
 106         entity e;
 107         e = spawn();
 108         e.classname = "object";
 109         e.takedamage = DAMAGE_AIM;
 110         e.damageforcescale = 1;
 111         e.solid = SOLID_BBOX; // SOLID_BSP would be best, but can lag the server badly
 112         e.movetype = MOVETYPE_TOSS;
 113         e.frame = 0;
 114         e.skin = 0;
 115         e.material = string_null;
 116         e.touch = sandbox_ObjectFunction_Touch;
 117
 118         if(!database)
 119         {
 120                 // set the object's owner via player UID
 121                 // if the player does not have an UID, the owner cannot be stored and his objects may be edited by anyone
 122                 if(self.crypto_idfp != "")
 123                         e.crypto_idfp = strzone(self.crypto_idfp);
 124                 else
 125                         print_to(self, "^1SANDBOX - WARNING: ^7You spawned an object, but lack a player UID. ^1Your objects are not secured and can be edited by any player!");
 126
 127                 // set origin and direction based on player position and view angle
 128                 makevectors(self.v_angle);
 129                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_spawn, MOVE_NORMAL, self);
 130                 setorigin(e, trace_endpos);
 131                 e.angles_y = self.v_angle_y;
 132         }
 133
 134         object_count += 1;
 135         return e;
 136 }
 137
 138 void sandbox_ObjectRemove(entity e)
 139 {
 140         sandbox_ObjectAttach_Remove(e); // detach child objects
 141         if(e.material)
 142         {
 143                 strunzone(e.material);
 144                 e.material = string_null;
 145         }
 146         if(e.crypto_idfp)
 147         {
 148                 strunzone(e.crypto_idfp);
 149                 e.crypto_idfp = string_null;
 150         }
 151         remove(e);
 152         e = world;
 153
 154         object_count -= 1;
 155 }
 156
 157 string port_string[MAX_STORAGE_ATTACHMENTS]; // fteqcc crashes if this isn't defined as a global
 158
 159 string sandbox_ObjectPort_Save(entity e, float database)
 160 {
 161         // TODO: Store attachement bone for attached objects as well!
 162
 163         // save object properties, and return them as a string
 164         float i;
 165         string s;
 166         entity head;
 167
 168         for(head = world; (head = find(head, classname, "object")); )
 169         {
 170                 // the main object needs to be first in the array [0], with attached objects following
 171                 float slot;
 172                 if(head == e) // this is the main object, make it first
 173                         slot = 0;
 174                 else if(head.owner == e) // child object, list them in order
 175                 {
 176                         i += 1; // children start from 1
 177                         slot = i;
 178                 }
 179                 else
 180                         continue;
 181
 182                 port_string[slot] = strcat(port_string[slot], head.model, " ");
 183                 port_string[slot] = strcat(port_string[slot], ftos(head.skin), " ");
 184                 port_string[slot] = strcat(port_string[slot], ftos(head.alpha), " ");
 185                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.colormod), " ");
 186                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.glowmod), " ");
 187                 port_string[slot] = strcat(port_string[slot], ftos(head.frame), " ");
 188                 port_string[slot] = strcat(port_string[slot], ftos(head.scale), " ");
 189                 port_string[slot] = strcat(port_string[slot], ftos(head.movetype), " ");
 190                 port_string[slot] = strcat(port_string[slot], ftos(head.damageforcescale), " ");
 191                 if(head.material)       port_string[slot] = strcat(port_string[slot], head.material, " ");      else    port_string[slot] = strcat(port_string[slot], "- "); // none
 192                 if(database)
 193                 {
 194                         if(head.crypto_idfp)    port_string[slot] = strcat(port_string[slot], head.crypto_idfp, " ");   else    port_string[slot] = strcat(port_string[slot], "- "); // none
 195                         port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.origin), " ");
 196                         port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.angles), " ");
 197                 }
 198         }
 199
 200         // now apply the array to a simple string, with the ; symbol separating objects
 201         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 202         {
 203                 if(port_string[i])
 204                         s = strcat(s, port_string[i], "; ");
 205                 port_string[i] = string_null; // fully clear the string
 206         }
 207
 208         return s;
 209 }
 210
 211 entity sandbox_ObjectPort_Load(string s, float database)
 212 {
 213         // TODO: Store attachement bone for attached objects as well!
 214
 215         // load object properties, and spawn a new object with them
 216         float n, i;
 217         entity e, parent;
 218
 219         // separate objects between the ; symbols
 220         n = tokenizebyseparator(s, "; ");
 221         for(i = 0; i < n; ++i)
 222                 port_string[i] = argv(i);
 223
 224         // now separate and apply the properties of each object
 225         for(i = 0; i < n; ++i)
 226         {
 227                 tokenize_console(port_string[i]);
 228                 e = sandbox_ObjectSpawn(database);
 229
 230                 setmodel(e, argv(0));
 231                 e.skin = stof(argv(1));
 232                 e.alpha = stof(argv(2));
 233                 e.colormod = stov(argv(3));
 234                 e.glowmod = stov(argv(4));
 235                 e.frame = stof(argv(5));
 236                 sandbox_ObjectEdit_Scale(e, stof(argv(6)));
 237                 e.movetype = stof(argv(7));
 238                 e.damageforcescale = stof(argv(8));
 239                 if(e.material)  strunzone(e.material);  if(argv(9) != "-")      e.material = strzone(argv(9));  else    e.material = string_null;
 240                 if(database)
 241                 {
 242                         if(e.crypto_idfp)       strunzone(e.crypto_idfp);       if(argv(10) != "-")     e.crypto_idfp = strzone(argv(10));      else    e.crypto_idfp = string_null;
 243                         setorigin(e, stov(argv(11)));
 244                         e.angles = stov(argv(12));
 245                 }
 246
 247                 if(!i) // parent object, set it as such and leave it be
 248                         parent = e;
 249                 else // child object, attach it to the parent
 250                         sandbox_ObjectAttach_Set(e, parent, "");
 251         }
 252
 253         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 254                 port_string[i] = string_null; // fully clear the string
 255
 256         return e;
 257 }
 258
 259 void sandbox_Database_Save()
 260 {
 261         // saves all objects to the database file
 262         entity head;
 263         string file_name;
 264         float file_get;
 265
 266         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 267         file_get = fopen(file_name, FILE_WRITE);
 268         fputs(file_get, strcat("// sandbox storage \"", autocvar_g_sandbox_storage_name, "\" for map \"", GetMapname(), "\" last updated ", strftime(TRUE, "%d-%m-%Y %H:%M:%S")));
 269         fputs(file_get, strcat(" containing ", ftos(object_count), " objects\n"));
 270
 271         for(head = world; (head = find(head, classname, "object")); )
 272         {
 273                 // attached objects are persisted separately, ignore them here
 274                 if(head.owner != world)
 275                         continue;
 276
 277                 // use a line of text for each object, listing all properties
 278                 fputs(file_get, strcat(sandbox_ObjectPort_Save(head, TRUE), "\n"));
 279         }
 280         fclose(file_get);
 281 }
 282
 283 void sandbox_Database_Load()
 284 {
 285         // loads all objects from the database file
 286         string file_read, file_name;
 287         float file_get, i;
 288
 289         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 290         file_get = fopen(file_name, FILE_READ);
 291         if(file_get < 0)
 292         {
 293                 if(autocvar_g_sandbox_info > 0)
 294                         print(strcat("^3SANDBOX - SERVER: ^7could not find storage file ^3", file_name, "^7, no objects were loaded\n"));
 295         }
 296         else
 297         {
 298                 for(;;)
 299                 {
 300                         file_read = fgets(file_get);
 301                         if(!file_read)
 302                                 break;
 303                         if(substring(file_read, 0, 2) == "//")
 304                                 continue;
 305                         if(substring(file_read, 0, 1) == "#")
 306                                 continue;
 307
 308                         entity e;
 309                         e = sandbox_ObjectPort_Load(file_read, TRUE);
 310
 311                         if(e.material)
 312                         {
 313                                 // since objects are being loaded for the first time, precache material sounds for each
 314                                 for (i = 1; i <= 5; i++) // 5 sounds in total
 315                                         precache_sound(strcat("object/impact_", e.material, "_", ftos(i), ".ogg"));
 316                         }
 317                 }
 318                 if(autocvar_g_sandbox_info > 0)
 319                         print(strcat("^3SANDBOX - SERVER: ^7successfully loaded storage file ^3", file_name, "\n"));
 320         }
 321 }
 322
 323 MUTATOR_HOOKFUNCTION(sandbox_PlayerCommand)
 324 {
 325         if(MUTATOR_RETURNVALUE) // command was already handled?
 326                 return FALSE;
 327         if(cmd_name == "g_sandbox")
 328         {
 329                 if(cmd_argc < 2)
 330                 {
 331                         print_to(self, "Sandbox mode is active. For usage information, type 'sandbox help'");
 332                         return TRUE;
 333                 }
 334
 335                 switch(argv(1))
 336                 {
 337                         entity e;
 338                         float i;
 339
 340                         // ---------------- COMMAND: HELP ----------------
 341                         case "help":
 342                                 print_to(self, "You can use the following sandbox commands:");
 343                                 print_to(self, "^7\"^2object_spawn ^3models/foo/bar.md3^7\" spawns a new object in front of the player, and gives it the specified model");
 344                                 print_to(self, "^7\"^2object_remove^7\" removes the object the player is looking at. Players can only remove their own objects");
 345                                 print_to(self, "^7\"^2object_duplicate ^3value^7\" duplicates the object. 'copy' copies the object, 'paste' puts it in front of the player");
 346                                 print_to(self, "^7\"^2object_attach ^3property value^7\" attaches one object to another. Players can only attach their own objects");
 347                                 print_to(self, "^7Attachment properties for ^2object_attach^7:");
 348                                 print_to(self, "^3get ^7- selects the object you are facing as the object to be attached");
 349                                 print_to(self, "^3set value ^7- attaches the previously selected object to the object you are facing, on the specified bone");
 350                                 print_to(self, "^3remove ^7- detaches all objects from the object you are facing");
 351                                 print_to(self, "^7\"^2object_edit ^3property value^7\" edits the given property of the object. Players can only edit their own objects");
 352                                 print_to(self, "^7Object properties for ^2object_edit^7:");
 353                                 print_to(self, "^3skin value ^7- changes the skin of the object");
 354                                 print_to(self, "^3alpha value ^7- sets object transparency");
 355                                 print_to(self, "^3colormod \"value_x value_y value_z\" ^7- main object color");
 356                                 print_to(self, "^3glowmod \"value_x value_y value_z\" ^7- glow object color");
 357                                 print_to(self, "^3frame value ^7- object animation frame, for self-animated models");
 358                                 print_to(self, "^3scale value ^7- changes object scale. 0.5 is half size and 2 is double size");
 359                                 print_to(self, "^3physics value ^7- object physics, 0 = static, 1 = movable, 2 = physical");
 360                                 print_to(self, "^3force value ^7- amount of force applied to objects that are shot");
 361                                 print_to(self, "^3material value ^7- sets the material of the object. Default materials are: metal, stone, wood, flesh");
 362                                 print_to(self, "^7\"^2object_claim^7\" sets the player as the owner of the object, if he has the right to edit it");
 363                                 print_to(self, "^7\"^2object_info ^3value^7\" shows public information about the object. 'mesh' shows model information");
 364                                 print_to(self, "^7The ^1drag object ^7key can be used to grab and carry objects. Players can only grab their own objects");
 365                                 return TRUE;
 366
 367                         // ---------------- COMMAND: OBJECT, SPAWN ----------------
 368                         case "object_spawn":
 369                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 370                                 {
 371                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 372                                         return TRUE;
 373                                 }
 374                                 if(cmd_argc < 3)
 375                                 {
 376                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object without specifying a model. Please specify the path to your model file after the 'object_spawn' command");
 377                                         return TRUE;
 378                                 }
 379                                 else if not(fexists(argv(2)))
 380                                 {
 381                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object with a non-existent model. Make sure the path to your model file is correct");
 382                                         return TRUE;
 383                                 }
 384
 385                                 e = sandbox_ObjectSpawn(FALSE);
 386                                 setmodel(e, argv(2));
 387
 388                                 if(autocvar_g_sandbox_info > 0)
 389                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " spawned an object at origin ^3", vtos(e.origin), "\n"));
 390                                 return TRUE;
 391
 392                         // ---------------- COMMAND: OBJECT, REMOVE ----------------
 393                         case "object_remove":
 394                                 e = sandbox_ObjectEdit_Get(TRUE);
 395                                 if(e != world)
 396                                 {
 397                                         if(autocvar_g_sandbox_info > 0)
 398                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " removed an object at origin ^3", vtos(e.origin), "\n"));
 399                                         sandbox_ObjectRemove(e);
 400                                         return TRUE;
 401                                 }
 402
 403                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be removed. Make sure you are facing an object that you have edit rights over");
 404                                 return TRUE;
 405
 406                         // ---------------- COMMAND: OBJECT, DUPLICATE ----------------
 407                         case "object_duplicate":
 408                                 switch(argv(2))
 409                                 {
 410                                         case "copy":
 411                                                 // copies customizable properties of the selected object to the clipboard
 412                                                 e = sandbox_ObjectEdit_Get(autocvar_g_sandbox_editor_free); // can we copy objects we can't edit?
 413                                                 if(e != world)
 414                                                 {
 415                                                         if(self.object_clipboard)
 416                                                                 strunzone(self.object_clipboard);
 417                                                         self.object_clipboard = strzone(sandbox_ObjectPort_Save(e, FALSE));
 418
 419                                                         print_to(self, "^2SANDBOX - INFO: ^7Object copied to clipboard");
 420                                                         return TRUE;
 421                                                 }
 422                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be copied. Make sure you are facing an object that you have copy rights over");
 423                                                 return TRUE;
 424
 425                                         case "paste":
 426                                                 // spawns a new object using the properties in the player's clipboard
 427                                                 if(!self.object_clipboard) // no object in clipboard
 428                                                 {
 429                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object in clipboard. You must copy an object before you can paste it");
 430                                                         return TRUE;
 431                                                 }
 432                                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 433                                                 {
 434                                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 435                                                         return TRUE;
 436                                                 }
 437
 438                                                 e = sandbox_ObjectPort_Load(self.object_clipboard, FALSE);
 439
 440                                                 print_to(self, "^2SANDBOX - INFO: ^7Object pasted successfully");
 441                                                 if(autocvar_g_sandbox_info > 0)
 442                                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " pasted an object at origin ^3", vtos(e.origin), "\n"));
 443                                                 return TRUE;
 444                                 }
 445                                 return TRUE;
 446
 447                         // ---------------- COMMAND: OBJECT, ATTACH ----------------
 448                         case "object_attach":
 449                                 switch(argv(2))
 450                                 {
 451                                         case "get":
 452                                                 // select e as the object as meant to be attached
 453                                                 e = sandbox_ObjectEdit_Get(TRUE);
 454                                                 if(e != world)
 455                                                 {
 456                                                         self.object_attach = e;
 457                                                         print_to(self, "^2SANDBOX - INFO: ^7Object selected for attachment");
 458                                                         return TRUE;
 459                                                 }
 460                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be selected for attachment. Make sure you are facing an object that you have edit rights over");
 461                                                 return TRUE;
 462                                         case "set":
 463                                                 if(self.object_attach == world)
 464                                                 {
 465                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object selected for attachment. Please select an object to be attached first.");
 466                                                         return TRUE;
 467                                                 }
 468
 469                                                 // attaches the previously selected object to e
 470                                                 e = sandbox_ObjectEdit_Get(TRUE);
 471                                                 if(e != world)
 472                                                 {
 473                                                         sandbox_ObjectAttach_Set(self.object_attach, e, argv(3));
 474                                                         self.object_attach = world; // object was attached, no longer keep it scheduled for attachment
 475                                                         print_to(self, "^2SANDBOX - INFO: ^7Object attached successfully");
 476                                                         if(autocvar_g_sandbox_info > 1)
 477                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " attached objects at origin ^3", vtos(e.origin), "\n"));
 478                                                         return TRUE;
 479                                                 }
 480                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be attached to the parent. Make sure you are facing an object that you have edit rights over");
 481                                                 return TRUE;
 482                                         case "remove":
 483                                                 // removes e if it was attached
 484                                                 e = sandbox_ObjectEdit_Get(TRUE);
 485                                                 if(e != world)
 486                                                 {
 487                                                         sandbox_ObjectAttach_Remove(e);
 488                                                         print_to(self, "^2SANDBOX - INFO: ^7Child objects detached successfully");
 489                                                         if(autocvar_g_sandbox_info > 1)
 490                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " detached objects at origin ^3", vtos(e.origin), "\n"));
 491                                                         return TRUE;
 492                                                 }
 493                                                 print_to(self, "^1SANDBOX - WARNING: ^7Child objects could not be detached. Make sure you are facing an object that you have edit rights over");
 494                                                 return TRUE;
 495                                 }
 496                                 return TRUE;
 497
 498                         // ---------------- COMMAND: OBJECT, EDIT ----------------
 499                         case "object_edit":
 500                                 if(!argv(2))
 501                                 {
 502                                         print_to(self, "^1SANDBOX - WARNING: ^7Too few parameters. You must specify a property to edit");
 503                                         return TRUE;
 504                                 }
 505
 506                                 e = sandbox_ObjectEdit_Get(TRUE);
 507                                 if(e != world)
 508                                 {
 509                                         switch(argv(2))
 510                                         {
 511                                                 case "skin":
 512                                                         e.skin = stof(argv(3));
 513                                                         break;
 514                                                 case "alpha":
 515                                                         e.alpha = stof(argv(3));
 516                                                         break;
 517                                                 case "color_main":
 518                                                         e.colormod = stov(argv(3));
 519                                                         break;
 520                                                 case "color_glow":
 521                                                         e.glowmod = stov(argv(3));
 522                                                         break;
 523                                                 case "frame":
 524                                                         e.frame = stof(argv(3));
 525                                                         break;
 526                                                 case "scale":
 527                                                         sandbox_ObjectEdit_Scale(e, stof(argv(3)));
 528                                                         break;
 529                                                 case "physics":
 530                                                         switch(argv(3))
 531                                                         {
 532                                                                 case "0": // static
 533                                                                         e.movetype = MOVETYPE_NONE;
 534                                                                         break;
 535                                                                 case "1": // movable
 536                                                                         e.movetype = MOVETYPE_TOSS;
 537                                                                         break;
 538                                                                 case "2": // physical
 539                                                                         e.movetype = MOVETYPE_PHYSICS;
 540                                                                         break;
 541                                                                 default:
 542                                                                         break;
 543                                                         }
 544                                                         break;
 545                                                 case "force":
 546                                                         e.damageforcescale = stof(argv(3));
 547                                                         break;
 548                                                 case "material":
 549                                                         if(e.material)
 550                                                                 strunzone(e.material);
 551                                                         if(argv(3))
 552                                                         {
 553                                                                 for (i = 1; i <= 5; i++) // precache material sounds, 5 in total
 554                                                                         precache_sound(strcat("object/impact_", argv(3), "_", ftos(i), ".ogg"));
 555                                                                 e.material = strzone(argv(3));
 556                                                         }
 557                                                         else
 558                                                                 e.material = string_null; // no material
 559                                                         break;
 560                                                 default:
 561                                                         print_to(self, "^1SANDBOX - WARNING: ^7Invalid object property. For usage information, type 'sandbox help'");
 562                                                         break;
 563                                         }
 564                                         if(autocvar_g_sandbox_info > 1)
 565                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " edited property ^3", argv(2), " ^7of an object at origin ^3", vtos(e.origin), "\n"));
 566                                         return TRUE;
 567                                 }
 568
 569                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be edited. Make sure you are facing an object that you have edit rights over");
 570                                 return TRUE;
 571
 572                         // ---------------- COMMAND: OBJECT, CLAIM ----------------
 573                         case "object_claim":
 574                                 // if the player can edit an object but is not its owner, this can be used to claim that object
 575                                 if(self.crypto_idfp == "")
 576                                 {
 577                                         print_to(self, "^1SANDBOX - WARNING: ^7You do not have a player UID, and cannot claim objects");
 578                                         return TRUE;
 579                                 }
 580                                 e = sandbox_ObjectEdit_Get(TRUE);
 581                                 if(e != world)
 582                                 {
 583                                         if(e.crypto_idfp == self.crypto_idfp)
 584                                         {
 585                                                 print_to(self, "^2SANDBOX - INFO: ^7Object is already yours, nothing to claim");
 586                                                 return TRUE;
 587                                         }
 588
 589                                         if(e.crypto_idfp)
 590                                                 strunzone(e.crypto_idfp);
 591                                         e.crypto_idfp = self.crypto_idfp;
 592                                         print_to(self, "^2SANDBOX - INFO: ^7Object claimed successfully");
 593                                 }
 594                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be claimed. Make sure you are facing an object that you have edit rights over");
 595                                 return TRUE;
 596
 597                         // ---------------- COMMAND: OBJECT, INFO ----------------
 598                         case "object_info":
 599                                 // prints public information about the object to the player
 600                                 e = sandbox_ObjectEdit_Get(FALSE);
 601                                 if(e != world)
 602                                 {
 603                                         switch(argv(2))
 604                                         {
 605                                                 case "mesh":
 606                                                         string tags;
 607                                                         for(i = 0; gettaginfo(e, i); i++)
 608                                                                 tags = strcat(tags, "^5", gettaginfo_name, "^7, ");
 609                                                         print_to(self, strcat("^2SANDBOX - INFO: ^7Object mesh is ^3", e.model, "^7 at animation frame ^3", ftos(e.frame), " ^7containing the following tags: ", tags));
 610                                                         return TRUE;
 611                                         }
 612                                 }
 613                                 print_to(self, "^1SANDBOX - WARNING: ^7No information could not be found. Make sure you are facing an object");
 614                                 return TRUE;
 615
 616                         // ---------------- COMMAND: DEFAULT ----------------
 617                         default:
 618                                 print_to(self, "Invalid command. For usage information, type 'sandbox help'");
 619                                 return TRUE;
 620                 }
 621         }
 622         return FALSE;
 623 }
 624
 625 MUTATOR_HOOKFUNCTION(sandbox_PlayerPreThink)
 626 {
 627         // if the player is close enough to their object, they can drag it
 628
 629         if(autocvar_sv_cheats)
 630                 return FALSE; // cheat dragging is used instead
 631
 632         // grab is TRUE if the object can be picked up. While an object is being carried, the Drag() function
 633         // must execute for it either way, otherwise it would cause bugs if it went out of the player's trace.
 634         // This also makes sure that an object can only pe picked up if in range, but does not get dropped if
 635         // it goes out of range while slinging it around.
 636
 637         entity e;
 638         float grab;
 639
 640         e = sandbox_ObjectEdit_Get(TRUE);
 641         if(e != world && vlen(e.origin - self.origin) <= autocvar_g_sandbox_editor_distance_edit)
 642                 grab = TRUE;
 643
 644         if(Drag(e, grab)) // execute dragging
 645                 return TRUE;
 646
 647         return FALSE;
 648 }
 649
 650 MUTATOR_HOOKFUNCTION(sandbox_ClientDisconnect)
 651 {
 652         // unzone the player's clipboard if it's not empty
 653         if(self.object_clipboard)
 654         {
 655                 strunzone(self.object_clipboard);
 656                 self.object_clipboard = string_null;
 657         }
 658
 659         return FALSE;
 660 }
 661
 662 float autosave_time;
 663 MUTATOR_HOOKFUNCTION(sandbox_StartFrame)
 664 {
 665         if(!autocvar_g_sandbox_storage_autosave)
 666                 return FALSE;
 667         if(time < autosave_time)
 668                 return FALSE;
 669         autosave_time = time + autocvar_g_sandbox_storage_autosave;
 670
 671         sandbox_Database_Save();
 672
 673         return TRUE;
 674 }
 675
 676 MUTATOR_DEFINITION(sandbox)
 677 {
 678         MUTATOR_HOOK(SV_ParseClientCommand, sandbox_PlayerCommand, CBC_ORDER_ANY);
 679         MUTATOR_HOOK(SV_StartFrame, sandbox_StartFrame, CBC_ORDER_ANY);
 680         MUTATOR_HOOK(PlayerPreThink, sandbox_PlayerPreThink, CBC_ORDER_ANY);
 681         MUTATOR_HOOK(ClientDisconnect, sandbox_ClientDisconnect, CBC_ORDER_ANY);
 682
 683         MUTATOR_ONADD
 684         {
 685                 autosave_time = time + autocvar_g_sandbox_storage_autosave; // don't save the first server frame
 686                 if(autocvar_g_sandbox_storage_autoload)
 687                         sandbox_Database_Load();
 688         }
 689
 690         return FALSE;
 691 }
 692