qcsrc/server/mutators/sandbox.qc

   1 const float MAX_STORAGE_ATTACHMENTS = 16;
   2 float object_count;
   3 .float object_flood;
   4 .entity object_attach;
   5 .string material;
   6
   7 .float touch_timer;
   8 void sandbox_ObjectFunction_Touch()
   9 {
  10         // apply material impact effects
  11
  12         if(!self.material)
  13                 return;
  14         if(self.touch_timer > time)
  15                 return; // don't execute each frame
  16         self.touch_timer = time + 0.1;
  17
  18         // make particle count and sound volume depend on impact speed
  19         float intensity;
  20         intensity = vlen(self.velocity) + vlen(other.velocity);
  21         if(intensity) // avoid divisions by 0
  22                 intensity /= 2; // average the two velocities
  23         if not(intensity >= autocvar_g_sandbox_object_material_velocity_min)
  24                 return; // impact not strong enough to do anything
  25         // now offset intensity and apply it to the effects
  26         intensity -= autocvar_g_sandbox_object_material_velocity_min; // start from minimum velocity, not actual velocity
  27         intensity = bound(0, intensity * autocvar_g_sandbox_object_material_velocity_factor, 1);
  28
  29         sound(self, CH_TRIGGER, strcat("object/impact_", self.material, "_", ftos(ceil(random() * 5)) , ".ogg"), VOL_BASE * intensity, ATTN_NORM);
  30         pointparticles(particleeffectnum(strcat("impact_", self.material)), self.origin, '0 0 0', ceil(intensity * 10)); // allow a count from 1 to 10
  31 }
  32
  33 void sandbox_ObjectFunction_Think()
  34 {
  35         entity e;
  36
  37         // decide if and how this object can be grabbed
  38         if(autocvar_g_sandbox_readonly)
  39                 self.grab = 0; // no grabbing
  40         else if(autocvar_g_sandbox_editor_free < 2 && self.crypto_idfp)
  41                 self.grab = 1; // owner only
  42         else
  43                 self.grab = 3; // anyone
  44
  45         // Object owner is stored via player UID, but we also need the owner as an entity (if the player is available on the server).
  46         // Therefore, scan for all players, and update the owner as long as the player is present. We must always do this,
  47         // since if the owning player disconnects, the object's owner should also be reset.
  48         FOR_EACH_REALPLAYER(e) // bots can't have objects
  49         {
  50                 if(self.crypto_idfp == e.crypto_idfp)
  51                 {
  52                         self.realowner = e;
  53                         break;
  54                 }
  55                 self.realowner = world;
  56         }
  57
  58         self.nextthink = time;
  59 }
  60
  61 entity sandbox_ObjectEdit_Get(float permissions)
  62 {
  63         // returns the traced entity if the player can edit it, and world if not
  64         // if permissions if FALSE, the object is returned regardless of editing rights
  65         // attached objects are SOLID_NOT and don't risk getting traced
  66
  67         makevectors(self.v_angle);
  68         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_edit, MOVE_NORMAL, self);
  69
  70         if(trace_ent.classname != "object")
  71                 return world; // entity is not an object
  72         if(!permissions)
  73                 return trace_ent; // don't check permissions, anyone can edit this object
  74         if(!trace_ent.crypto_idfp)
  75                 return trace_ent; // the player who spawned this object did not have an UID, so anyone can edit it
  76         if not(trace_ent.realowner != self && autocvar_g_sandbox_editor_free < 2)
  77                 return trace_ent; // object does not belong to the player, and players can only edit their own objects on this server
  78         return world;
  79 }
  80
  81 void sandbox_ObjectEdit_Scale(entity e, float f)
  82 {
  83         e.scale = f;
  84         if(e.scale)
  85         {
  86                 e.scale = bound(autocvar_g_sandbox_object_scale_min, e.scale, autocvar_g_sandbox_object_scale_max);
  87                 setmodel(e, e.model); // reset mins and maxs based on mesh
  88                 setsize(e, e.mins * e.scale, e.maxs * e.scale); // adapt bounding box size to model size
  89         }
  90 }
  91
  92 .float old_movetype;
  93 void sandbox_ObjectAttach_Remove(entity e);
  94 void sandbox_ObjectAttach_Set(entity e, entity parent, string s)
  95 {
  96         // attaches e to parent on string s
  97
  98         // we can't attach to an attachment, for obvious reasons
  99         sandbox_ObjectAttach_Remove(e);
 100
 101         e.old_movetype = e.movetype; // persist physics
 102         e.movetype = MOVETYPE_FOLLOW;
 103         e.solid = SOLID_NOT;
 104         e.takedamage = DAMAGE_NO;
 105
 106         setattachment(e, parent, s);
 107         e.owner = parent;
 108 }
 109
 110 void sandbox_ObjectAttach_Remove(entity e)
 111 {
 112         // detaches any object attached to e
 113
 114         entity head;
 115         for(head = world; (head = find(head, classname, "object")); )
 116         {
 117                 if(head.owner == e)
 118                 {
 119                         vector org;
 120                         head.movetype = head.old_movetype; // restore persisted physics
 121                         head.solid = SOLID_BBOX;
 122                         head.takedamage = DAMAGE_AIM;
 123
 124                         org = gettaginfo(head, 0);
 125                         setattachment(head, world, "");
 126                         head.owner = world;
 127
 128                         // objects change origin and angles when detached, so apply previous position
 129                         setorigin(head, org);
 130                         head.angles = e.angles; // don't allow detached objects to spin or roll
 131                 }
 132         }
 133 }
 134
 135 entity sandbox_ObjectSpawn(float database)
 136 {
 137         // spawn a new object with default properties
 138
 139         entity e;
 140         e = spawn();
 141         e.classname = "object";
 142         e.takedamage = DAMAGE_AIM;
 143         e.damageforcescale = 1;
 144         e.solid = SOLID_BBOX; // SOLID_BSP would be best, but can lag the server badly
 145         e.movetype = MOVETYPE_TOSS;
 146         e.frame = 0;
 147         e.skin = 0;
 148         e.material = string_null;
 149         e.touch = sandbox_ObjectFunction_Touch;
 150         e.think = sandbox_ObjectFunction_Think;
 151         e.nextthink = time;
 152         //e.effects |= EF_SELECTABLE; // don't do this all the time, maybe just when editing objects?
 153
 154         if(!database)
 155         {
 156                 // set the object's owner via player UID
 157                 // if the player does not have an UID, the owner cannot be stored and his objects may be edited by anyone
 158                 if(self.crypto_idfp != "")
 159                         e.crypto_idfp = strzone(self.crypto_idfp);
 160                 else
 161                         print_to(self, "^1SANDBOX - WARNING: ^7You spawned an object, but lack a player UID. ^1Your objects are not secured and can be edited by any player!");
 162
 163                 // set public object information
 164                 e.netname = strzone(self.netname); // name of the owner
 165                 e.message = strzone(strftime(TRUE, "%d-%m-%Y %H:%M:%S")); // creation time
 166                 e.message2 = strzone(strftime(TRUE, "%d-%m-%Y %H:%M:%S")); // last editing time
 167
 168                 // set origin and direction based on player position and view angle
 169                 makevectors(self.v_angle);
 170                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_spawn, MOVE_NORMAL, self);
 171                 setorigin(e, trace_endpos);
 172                 e.angles_y = self.v_angle_y;
 173         }
 174
 175         object_count += 1;
 176         return e;
 177 }
 178
 179 void sandbox_ObjectRemove(entity e)
 180 {
 181         sandbox_ObjectAttach_Remove(e); // detach child objects
 182
 183         if(e.material)  {       strunzone(e.material);  e.material = string_null;       }
 184         if(e.crypto_idfp)       {       strunzone(e.crypto_idfp);       e.crypto_idfp = string_null;    }
 185         if(e.netname)   {       strunzone(e.netname);   e.netname = string_null;        }
 186         if(e.message)   {       strunzone(e.message);   e.message = string_null;        }
 187         if(e.message2)  {       strunzone(e.message2);  e.message2 = string_null;       }
 188         remove(e);
 189         e = world;
 190
 191         object_count -= 1;
 192 }
 193
 194 string port_string[MAX_STORAGE_ATTACHMENTS]; // fteqcc crashes if this isn't defined as a global
 195
 196 string sandbox_ObjectPort_Save(entity e, float database)
 197 {
 198         // save object properties, and return them as a string
 199         float i;
 200         string s;
 201         entity head;
 202
 203         for(head = world; (head = find(head, classname, "object")); )
 204         {
 205                 // the main object needs to be first in the array [0] with attached objects following
 206                 float slot, physics;
 207                 if(head == e) // this is the main object, place it first
 208                 {
 209                         slot = 0;
 210                         physics = head.movetype; // applied physics are normal physics for parents
 211                 }
 212                 else if(head.owner == e) // child object, list them in order
 213                 {
 214                         i += 1; // children start from 1
 215                         slot = i;
 216                         physics = head.old_movetype; // persisted physics are normal physics for children
 217                         gettaginfo(head.owner, head.tag_index); // get the name of the tag our object is attached to, used further below
 218                 }
 219                 else
 220                         continue;
 221
 222                 // ---------------- OBJECT PROPERTY STORAGE: SAVE ----------------
 223                 if(slot)
 224                 {
 225                         // properties stored only for child objects
 226                         if(gettaginfo_name)     port_string[slot] = strcat(port_string[slot], "\"", gettaginfo_name, "\" ");    else    port_string[slot] = strcat(port_string[slot], "- "); // none
 227                 }
 228                 else
 229                 {
 230                         // properties stored only for parent objects
 231                         if(database)
 232                         {
 233                                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.origin), " ");
 234                                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.angles), " ");
 235                         }
 236                 }
 237                 // properties stored for all objects
 238                 port_string[slot] = strcat(port_string[slot], "\"", head.model, "\" ");
 239                 port_string[slot] = strcat(port_string[slot], ftos(head.skin), " ");
 240                 port_string[slot] = strcat(port_string[slot], ftos(head.alpha), " ");
 241                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.colormod), " ");
 242                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.glowmod), " ");
 243                 port_string[slot] = strcat(port_string[slot], ftos(head.frame), " ");
 244                 port_string[slot] = strcat(port_string[slot], ftos(head.scale), " ");
 245                 port_string[slot] = strcat(port_string[slot], ftos(physics), " ");
 246                 port_string[slot] = strcat(port_string[slot], ftos(head.damageforcescale), " ");
 247                 if(head.material)       port_string[slot] = strcat(port_string[slot], "\"", head.material, "\" ");      else    port_string[slot] = strcat(port_string[slot], "- "); // none
 248                 if(database)
 249                 {
 250                         // properties stored only for the database
 251                         if(head.crypto_idfp)    port_string[slot] = strcat(port_string[slot], "\"", head.crypto_idfp, "\" ");   else    port_string[slot] = strcat(port_string[slot], "- "); // none
 252                         port_string[slot] = strcat(port_string[slot], "\"", e.netname, "\" ");
 253                         port_string[slot] = strcat(port_string[slot], "\"", e.message, "\" ");
 254                         port_string[slot] = strcat(port_string[slot], "\"", e.message2, "\" ");
 255                 }
 256         }
 257
 258         // now apply the array to a simple string, with the ; symbol separating objects
 259         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 260         {
 261                 if(port_string[i])
 262                         s = strcat(s, port_string[i], "; ");
 263                 port_string[i] = string_null; // fully clear the string
 264         }
 265
 266         return s;
 267 }
 268
 269 entity sandbox_ObjectPort_Load(string s, float database)
 270 {
 271         // load object properties, and spawn a new object with them
 272         float n, i;
 273         entity e, parent;
 274
 275         // separate objects between the ; symbols
 276         n = tokenizebyseparator(s, "; ");
 277         for(i = 0; i < n; ++i)
 278                 port_string[i] = argv(i);
 279
 280         // now separate and apply the properties of each object
 281         for(i = 0; i < n; ++i)
 282         {
 283                 float argv_num;
 284                 string tagname;
 285                 argv_num = 0;
 286                 tokenize_console(port_string[i]);
 287                 e = sandbox_ObjectSpawn(database);
 288
 289                 // ---------------- OBJECT PROPERTY STORAGE: LOAD ----------------
 290                 if(i)
 291                 {
 292                         // properties stored only for child objects
 293                         if(argv(argv_num) != "-")       tagname = argv(argv_num);       else tagname = string_null;     ++argv_num;
 294                 }
 295                 else
 296                 {
 297                         // properties stored only for parent objects
 298                         if(database)
 299                         {
 300                                 setorigin(e, stov(argv(argv_num)));     ++argv_num;
 301                                 e.angles = stov(argv(argv_num));        ++argv_num;
 302                         }
 303                         parent = e; // mark parent objects as such
 304                 }
 305                 // properties stored for all objects
 306                 setmodel(e, argv(argv_num));    ++argv_num;
 307                 e.skin = stof(argv(argv_num));  ++argv_num;
 308                 e.alpha = stof(argv(argv_num)); ++argv_num;
 309                 e.colormod = stov(argv(argv_num));      ++argv_num;
 310                 e.glowmod = stov(argv(argv_num));       ++argv_num;
 311                 e.frame = stof(argv(argv_num)); ++argv_num;
 312                 sandbox_ObjectEdit_Scale(e, stof(argv(argv_num)));      ++argv_num;
 313                 e.movetype = e.old_movetype = stof(argv(argv_num));     ++argv_num;
 314                 e.damageforcescale = stof(argv(argv_num));      ++argv_num;
 315                 if(e.material)  strunzone(e.material);  if(argv(argv_num) != "-")       e.material = strzone(argv(argv_num));   else    e.material = string_null;       ++argv_num;
 316                 if(database)
 317                 {
 318                         // properties stored only for the database
 319                         if(e.crypto_idfp)       strunzone(e.crypto_idfp);       if(argv(argv_num) != "-")       e.crypto_idfp = strzone(argv(argv_num));        else    e.crypto_idfp = string_null;    ++argv_num;
 320                         if(e.netname)   strunzone(e.netname);   e.netname = strzone(argv(argv_num));    ++argv_num;
 321                         if(e.message)   strunzone(e.message);   e.message = strzone(argv(argv_num));    ++argv_num;
 322                         if(e.message2)  strunzone(e.message2);  e.message2 = strzone(argv(argv_num));   ++argv_num;
 323                 }
 324
 325                 // attach last
 326                 if(i)
 327                         sandbox_ObjectAttach_Set(e, parent, tagname);
 328         }
 329
 330         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 331                 port_string[i] = string_null; // fully clear the string
 332
 333         return e;
 334 }
 335
 336 void sandbox_Database_Save()
 337 {
 338         // saves all objects to the database file
 339         entity head;
 340         string file_name;
 341         float file_get;
 342
 343         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 344         file_get = fopen(file_name, FILE_WRITE);
 345         fputs(file_get, strcat("// sandbox storage \"", autocvar_g_sandbox_storage_name, "\" for map \"", GetMapname(), "\" last updated ", strftime(TRUE, "%d-%m-%Y %H:%M:%S")));
 346         fputs(file_get, strcat(" containing ", ftos(object_count), " objects\n"));
 347
 348         for(head = world; (head = find(head, classname, "object")); )
 349         {
 350                 // attached objects are persisted separately, ignore them here
 351                 if(head.owner != world)
 352                         continue;
 353
 354                 // use a line of text for each object, listing all properties
 355                 fputs(file_get, strcat(sandbox_ObjectPort_Save(head, TRUE), "\n"));
 356         }
 357         fclose(file_get);
 358 }
 359
 360 void sandbox_Database_Load()
 361 {
 362         // loads all objects from the database file
 363         string file_read, file_name;
 364         float file_get, i;
 365
 366         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 367         file_get = fopen(file_name, FILE_READ);
 368         if(file_get < 0)
 369         {
 370                 if(autocvar_g_sandbox_info > 0)
 371                         print(strcat("^3SANDBOX - SERVER: ^7could not find storage file ^3", file_name, "^7, no objects were loaded\n"));
 372         }
 373         else
 374         {
 375                 for(;;)
 376                 {
 377                         file_read = fgets(file_get);
 378                         if(!file_read)
 379                                 break;
 380                         if(substring(file_read, 0, 2) == "//")
 381                                 continue;
 382                         if(substring(file_read, 0, 1) == "#")
 383                                 continue;
 384
 385                         entity e;
 386                         e = sandbox_ObjectPort_Load(file_read, TRUE);
 387
 388                         if(e.material)
 389                         {
 390                                 // since objects are being loaded for the first time, precache material sounds for each
 391                                 for (i = 1; i <= 5; i++) // 5 sounds in total
 392                                         precache_sound(strcat("object/impact_", e.material, "_", ftos(i), ".ogg"));
 393                         }
 394                 }
 395                 if(autocvar_g_sandbox_info > 0)
 396                         print(strcat("^3SANDBOX - SERVER: ^7successfully loaded storage file ^3", file_name, "\n"));
 397         }
 398         fclose(file_get);
 399 }
 400
 401 MUTATOR_HOOKFUNCTION(sandbox_PlayerCommand)
 402 {
 403         if(MUTATOR_RETURNVALUE) // command was already handled?
 404                 return FALSE;
 405         if(cmd_name == "g_sandbox")
 406         {
 407                 if(autocvar_g_sandbox_readonly)
 408                 {
 409                         print_to(self, "^2SANDBOX - INFO: ^7Sandbox mode is active, but in read-only mode. Sandbox commands cannot be used");
 410                         return TRUE;
 411                 }
 412                 if(cmd_argc < 2)
 413                 {
 414                         print_to(self, "^2SANDBOX - INFO: ^7Sandbox mode is active. For usage information, type 'sandbox help'");
 415                         return TRUE;
 416                 }
 417
 418                 switch(argv(1))
 419                 {
 420                         entity e;
 421                         float i;
 422                         string s;
 423
 424                         // ---------------- COMMAND: HELP ----------------
 425                         case "help":
 426                                 print_to(self, "You can use the following sandbox commands:");
 427                                 print_to(self, "^7\"^2object_spawn ^3models/foo/bar.md3^7\" spawns a new object in front of the player, and gives it the specified model");
 428                                 print_to(self, "^7\"^2object_remove^7\" removes the object the player is looking at. Players can only remove their own objects");
 429                                 print_to(self, "^7\"^2object_duplicate ^3value^7\" duplicates the object, if the player has copying rights over the original");
 430                                 print_to(self, "^3copy value ^7- copies the properties of the object to the specified client cvar");
 431                                 print_to(self, "^3paste value ^7- spawns an object with the given properties. Properties or cvars must be specified as follows; eg1: \"0 1 2 ...\", eg2: \"$cl_cvar\"");
 432                                 print_to(self, "^7\"^2object_attach ^3property value^7\" attaches one object to another. Players can only attach their own objects");
 433                                 print_to(self, "^3get ^7- selects the object you are facing as the object to be attached");
 434                                 print_to(self, "^3set value ^7- attaches the previously selected object to the object you are facing, on the specified bone");
 435                                 print_to(self, "^3remove ^7- detaches all objects from the object you are facing");
 436                                 print_to(self, "^7\"^2object_edit ^3property value^7\" edits the given property of the object. Players can only edit their own objects");
 437                                 print_to(self, "^3skin value ^7- changes the skin of the object");
 438                                 print_to(self, "^3alpha value ^7- sets object transparency");
 439                                 print_to(self, "^3colormod \"value_x value_y value_z\" ^7- main object color");
 440                                 print_to(self, "^3glowmod \"value_x value_y value_z\" ^7- glow object color");
 441                                 print_to(self, "^3frame value ^7- object animation frame, for self-animated models");
 442                                 print_to(self, "^3scale value ^7- changes object scale. 0.5 is half size and 2 is double size");
 443                                 print_to(self, "^3physics value ^7- object physics, 0 = static, 1 = movable, 2 = physical");
 444                                 print_to(self, "^3force value ^7- amount of force applied to objects that are shot");
 445                                 print_to(self, "^3material value ^7- sets the material of the object. Default materials are: metal, stone, wood, flesh");
 446                                 print_to(self, "^7\"^2object_claim^7\" sets the player as the owner of the object, if he has the right to edit it");
 447                                 print_to(self, "^7\"^2object_info ^3value^7\" shows public information about the object");
 448                                 print_to(self, "^3object ^7- prints general information about the object, such as owner and creation / editing date");
 449                                 print_to(self, "^3mesh ^7- prints information about the object's mesh, including skeletal bones");
 450                                 print_to(self, "^3attachments ^7- prints information about the object's attachments");
 451                                 print_to(self, "^7The ^1drag object ^7key can be used to grab and carry objects. Players can only grab their own objects");
 452                                 return TRUE;
 453
 454                         // ---------------- COMMAND: OBJECT, SPAWN ----------------
 455                         case "object_spawn":
 456                                 if(time < self.object_flood)
 457                                 {
 458                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Flood protection active. Please wait ^3", ftos(self.object_flood - time), " ^7seconds beofore spawning another object"));
 459                                         return TRUE;
 460                                 }
 461                                 self.object_flood = time + autocvar_g_sandbox_editor_flood;
 462                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 463                                 {
 464                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 465                                         return TRUE;
 466                                 }
 467                                 if(cmd_argc < 3)
 468                                 {
 469                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object without specifying a model. Please specify the path to your model file after the 'object_spawn' command");
 470                                         return TRUE;
 471                                 }
 472                                 if not(fexists(argv(2)))
 473                                 {
 474                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object with a non-existent model. Make sure the path to your model file is correct");
 475                                         return TRUE;
 476                                 }
 477
 478                                 e = sandbox_ObjectSpawn(FALSE);
 479                                 setmodel(e, argv(2));
 480
 481                                 if(autocvar_g_sandbox_info > 0)
 482                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " spawned an object at origin ^3", vtos(e.origin), "\n"));
 483                                 return TRUE;
 484
 485                         // ---------------- COMMAND: OBJECT, REMOVE ----------------
 486                         case "object_remove":
 487                                 e = sandbox_ObjectEdit_Get(TRUE);
 488                                 if(e != world)
 489                                 {
 490                                         if(autocvar_g_sandbox_info > 0)
 491                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " removed an object at origin ^3", vtos(e.origin), "\n"));
 492                                         sandbox_ObjectRemove(e);
 493                                         return TRUE;
 494                                 }
 495
 496                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be removed. Make sure you are facing an object that you have edit rights over");
 497                                 return TRUE;
 498
 499                         // ---------------- COMMAND: OBJECT, DUPLICATE ----------------
 500                         case "object_duplicate":
 501                                 switch(argv(2))
 502                                 {
 503                                         case "copy":
 504                                                 // copies customizable properties of the selected object to the clipboard cvar
 505                                                 e = sandbox_ObjectEdit_Get(autocvar_g_sandbox_editor_free); // can we copy objects we can't edit?
 506                                                 if(e != world)
 507                                                 {
 508                                                         s = sandbox_ObjectPort_Save(e, FALSE);
 509                                                         s = strreplace("\"", "\\\"", s);
 510                                                         stuffcmd(self, strcat("set ", argv(3), " \"", s, "\""));
 511
 512                                                         print_to(self, "^2SANDBOX - INFO: ^7Object copied to clipboard");
 513                                                         return TRUE;
 514                                                 }
 515                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be copied. Make sure you are facing an object that you have copy rights over");
 516                                                 return TRUE;
 517
 518                                         case "paste":
 519                                                 // spawns a new object using the properties in the player's clipboard cvar
 520                                                 if(time < self.object_flood)
 521                                                 {
 522                                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Flood protection active. Please wait ^3", ftos(self.object_flood - time), " ^7seconds beofore spawning another object"));
 523                                                         return TRUE;
 524                                                 }
 525                                                 self.object_flood = time + autocvar_g_sandbox_editor_flood;
 526                                                 if(!argv(3)) // no object in clipboard
 527                                                 {
 528                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object in clipboard. You must copy an object before you can paste it");
 529                                                         return TRUE;
 530                                                 }
 531                                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 532                                                 {
 533                                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 534                                                         return TRUE;
 535                                                 }
 536                                                 e = sandbox_ObjectPort_Load(argv(3), FALSE);
 537
 538                                                 print_to(self, "^2SANDBOX - INFO: ^7Object pasted successfully");
 539                                                 if(autocvar_g_sandbox_info > 0)
 540                                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " pasted an object at origin ^3", vtos(e.origin), "\n"));
 541                                                 return TRUE;
 542                                 }
 543                                 return TRUE;
 544
 545                         // ---------------- COMMAND: OBJECT, ATTACH ----------------
 546                         case "object_attach":
 547                                 switch(argv(2))
 548                                 {
 549                                         case "get":
 550                                                 // select e as the object as meant to be attached
 551                                                 e = sandbox_ObjectEdit_Get(TRUE);
 552                                                 if(e != world)
 553                                                 {
 554                                                         self.object_attach = e;
 555                                                         print_to(self, "^2SANDBOX - INFO: ^7Object selected for attachment");
 556                                                         return TRUE;
 557                                                 }
 558                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be selected for attachment. Make sure you are facing an object that you have edit rights over");
 559                                                 return TRUE;
 560                                         case "set":
 561                                                 if(self.object_attach == world)
 562                                                 {
 563                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object selected for attachment. Please select an object to be attached first.");
 564                                                         return TRUE;
 565                                                 }
 566
 567                                                 // attaches the previously selected object to e
 568                                                 e = sandbox_ObjectEdit_Get(TRUE);
 569                                                 if(e != world)
 570                                                 {
 571                                                         sandbox_ObjectAttach_Set(self.object_attach, e, argv(3));
 572                                                         self.object_attach = world; // object was attached, no longer keep it scheduled for attachment
 573                                                         print_to(self, "^2SANDBOX - INFO: ^7Object attached successfully");
 574                                                         if(autocvar_g_sandbox_info > 1)
 575                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " attached objects at origin ^3", vtos(e.origin), "\n"));
 576                                                         return TRUE;
 577                                                 }
 578                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be attached to the parent. Make sure you are facing an object that you have edit rights over");
 579                                                 return TRUE;
 580                                         case "remove":
 581                                                 // removes e if it was attached
 582                                                 e = sandbox_ObjectEdit_Get(TRUE);
 583                                                 if(e != world)
 584                                                 {
 585                                                         sandbox_ObjectAttach_Remove(e);
 586                                                         print_to(self, "^2SANDBOX - INFO: ^7Child objects detached successfully");
 587                                                         if(autocvar_g_sandbox_info > 1)
 588                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " detached objects at origin ^3", vtos(e.origin), "\n"));
 589                                                         return TRUE;
 590                                                 }
 591                                                 print_to(self, "^1SANDBOX - WARNING: ^7Child objects could not be detached. Make sure you are facing an object that you have edit rights over");
 592                                                 return TRUE;
 593                                 }
 594                                 return TRUE;
 595
 596                         // ---------------- COMMAND: OBJECT, EDIT ----------------
 597                         case "object_edit":
 598                                 if(!argv(2))
 599                                 {
 600                                         print_to(self, "^1SANDBOX - WARNING: ^7Too few parameters. You must specify a property to edit");
 601                                         return TRUE;
 602                                 }
 603
 604                                 e = sandbox_ObjectEdit_Get(TRUE);
 605                                 if(e != world)
 606                                 {
 607                                         switch(argv(2))
 608                                         {
 609                                                 case "skin":
 610                                                         e.skin = stof(argv(3));
 611                                                         break;
 612                                                 case "alpha":
 613                                                         e.alpha = stof(argv(3));
 614                                                         break;
 615                                                 case "color_main":
 616                                                         e.colormod = stov(argv(3));
 617                                                         break;
 618                                                 case "color_glow":
 619                                                         e.glowmod = stov(argv(3));
 620                                                         break;
 621                                                 case "frame":
 622                                                         e.frame = stof(argv(3));
 623                                                         break;
 624                                                 case "scale":
 625                                                         sandbox_ObjectEdit_Scale(e, stof(argv(3)));
 626                                                         break;
 627                                                 case "physics":
 628                                                         switch(argv(3))
 629                                                         {
 630                                                                 case "0": // static
 631                                                                         e.movetype = MOVETYPE_NONE;
 632                                                                         break;
 633                                                                 case "1": // movable
 634                                                                         e.movetype = MOVETYPE_TOSS;
 635                                                                         break;
 636                                                                 case "2": // physical
 637                                                                         e.movetype = MOVETYPE_PHYSICS;
 638                                                                         break;
 639                                                                 default:
 640                                                                         break;
 641                                                         }
 642                                                         break;
 643                                                 case "force":
 644                                                         e.damageforcescale = stof(argv(3));
 645                                                         break;
 646                                                 case "material":
 647                                                         if(e.material)  strunzone(e.material);
 648                                                         if(argv(3))
 649                                                         {
 650                                                                 for (i = 1; i <= 5; i++) // precache material sounds, 5 in total
 651                                                                         precache_sound(strcat("object/impact_", argv(3), "_", ftos(i), ".ogg"));
 652                                                                 e.material = strzone(argv(3));
 653                                                         }
 654                                                         else
 655                                                                 e.material = string_null; // no material
 656                                                         break;
 657                                                 default:
 658                                                         print_to(self, "^1SANDBOX - WARNING: ^7Invalid object property. For usage information, type 'sandbox help'");
 659                                                         return TRUE;
 660                                         }
 661
 662                                         // update last editing time
 663                                         if(e.message2)  strunzone(e.message2);
 664                                         e.message2 = strzone(strftime(TRUE, "%d-%m-%Y %H:%M:%S"));
 665
 666                                         if(autocvar_g_sandbox_info > 1)
 667                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " edited property ^3", argv(2), " ^7of an object at origin ^3", vtos(e.origin), "\n"));
 668                                         return TRUE;
 669                                 }
 670
 671                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be edited. Make sure you are facing an object that you have edit rights over");
 672                                 return TRUE;
 673
 674                         // ---------------- COMMAND: OBJECT, CLAIM ----------------
 675                         case "object_claim":
 676                                 // if the player can edit an object but is not its owner, this can be used to claim that object
 677                                 if(self.crypto_idfp == "")
 678                                 {
 679                                         print_to(self, "^1SANDBOX - WARNING: ^7You do not have a player UID, and cannot claim objects");
 680                                         return TRUE;
 681                                 }
 682                                 e = sandbox_ObjectEdit_Get(TRUE);
 683                                 if(e != world)
 684                                 {
 685                                         // update the owner's name
 686                                         // Do this before checking if you're already the owner and skipping if such, so we
 687                                         // also update the player's nickname if he changed it (but has the same player UID)
 688                                         if(e.netname != self.netname)
 689                                         {
 690                                                 if(e.netname)   strunzone(e.netname);
 691                                                 e.netname = strzone(self.netname);
 692                                                 print_to(self, "^2SANDBOX - INFO: ^7Object owner name updated");
 693                                         }
 694
 695                                         if(e.crypto_idfp == self.crypto_idfp)
 696                                         {
 697                                                 print_to(self, "^2SANDBOX - INFO: ^7Object is already yours, nothing to claim");
 698                                                 return TRUE;
 699                                         }
 700
 701                                         if(e.crypto_idfp)       strunzone(e.crypto_idfp);
 702                                         e.crypto_idfp = strzone(self.crypto_idfp);
 703
 704                                         print_to(self, "^2SANDBOX - INFO: ^7Object claimed successfully");
 705                                 }
 706                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be claimed. Make sure you are facing an object that you have edit rights over");
 707                                 return TRUE;
 708
 709                         // ---------------- COMMAND: OBJECT, INFO ----------------
 710                         case "object_info":
 711                                 // prints public information about the object to the player
 712                                 e = sandbox_ObjectEdit_Get(FALSE);
 713                                 if(e != world)
 714                                 {
 715                                         switch(argv(2))
 716                                         {
 717                                                 case "object":
 718                                                         print_to(self, strcat("^2SANDBOX - INFO: ^7Object is owned by \"^7", e.netname, "^7\", created \"^3", e.message, "^7\", last edited \"^3", e.message2, "^7\""));
 719                                                         return TRUE;
 720                                                 case "mesh":
 721                                                         for(i = 1; gettaginfo(e, i); i++)
 722                                                                 s = strcat(s, "^7\"^5", gettaginfo_name, "^7\", ");
 723                                                         print_to(self, strcat("^2SANDBOX - INFO: ^7Object mesh is \"^3", e.model, "^7\" at animation frame ^3", ftos(e.frame), " ^7containing the following tags: ", s));
 724                                                         return TRUE;
 725                                                 case "attachments":
 726                                                         // this should show the same info as 'mesh' but for attachments
 727                                                         entity head;
 728                                                         for(head = world; (head = find(head, classname, "object")); )
 729                                                         {
 730                                                                 if(head.owner == e)
 731                                                                 {
 732                                                                         ++i; // start from 1
 733                                                                         gettaginfo(e, head.tag_index);
 734                                                                         s = strcat(s, "^1attachment ", ftos(i), "^7 has mesh \"^3", head.model, "^7\" at animation frame ^3", ftos(head.frame));
 735                                                                         s = strcat(s, "^7 and is attached to bone \"^5", gettaginfo_name, "^7\", ");
 736                                                                 }
 737                                                         }
 738                                                         if(i) // object contains attachments
 739                                                                 print_to(self, strcat("^2SANDBOX - INFO: ^7Object contains the following ^1", ftos(i), "^7 attachment(s): ", s));
 740                                                         else
 741                                                                 print_to(self, "^2SANDBOX - INFO: ^7Object contains no attachments");
 742                                                         return TRUE;
 743                                         }
 744                                 }
 745                                 print_to(self, "^1SANDBOX - WARNING: ^7No information could be found. Make sure you are facing an object");
 746                                 return TRUE;
 747
 748                         // ---------------- COMMAND: DEFAULT ----------------
 749                         default:
 750                                 print_to(self, "Invalid command. For usage information, type 'sandbox help'");
 751                                 return TRUE;
 752                 }
 753         }
 754         return FALSE;
 755 }
 756
 757 float autosave_time;
 758 MUTATOR_HOOKFUNCTION(sandbox_StartFrame)
 759 {
 760         if(!autocvar_g_sandbox_storage_autosave)
 761                 return FALSE;
 762         if(time < autosave_time)
 763                 return FALSE;
 764         autosave_time = time + autocvar_g_sandbox_storage_autosave;
 765
 766         sandbox_Database_Save();
 767
 768         return TRUE;
 769 }
 770
 771 MUTATOR_DEFINITION(sandbox)
 772 {
 773         MUTATOR_HOOK(SV_ParseClientCommand, sandbox_PlayerCommand, CBC_ORDER_ANY);
 774         MUTATOR_HOOK(SV_StartFrame, sandbox_StartFrame, CBC_ORDER_ANY);
 775
 776         MUTATOR_ONADD
 777         {
 778                 autosave_time = time + autocvar_g_sandbox_storage_autosave; // don't save the first server frame
 779                 if(autocvar_g_sandbox_storage_autoload)
 780                         sandbox_Database_Load();
 781         }
 782
 783         return FALSE;
 784 }
 785