qcsrc/server/mutators/sandbox.qc

   1 const float MAX_STORAGE_ATTACHMENTS = 16;
   2 float object_count;
   3 .string object_clipboard;
   4 .entity object_attach;
   5 .string material;
   6
   7 .float touch_timer;
   8 void sandbox_ObjectFunction_Touch()
   9 {
  10         // apply material impact effects
  11
  12         if(!self.material)
  13                 return;
  14         if(self.touch_timer > time)
  15                 return; // don't execute each frame
  16         self.touch_timer = time + 0.1;
  17
  18         // make particle count and sound volume depend on impact speed
  19         float intensity;
  20         intensity = vlen(self.velocity) + vlen(other.velocity);
  21         if(intensity) // avoid divisions by 0
  22                 intensity /= 2; // average the two velocities
  23         if not(intensity >= autocvar_g_sandbox_object_material_velocity_min)
  24                 return; // impact not strong enough to do anything
  25         // now offset intensity and apply it to the effects
  26         intensity -= autocvar_g_sandbox_object_material_velocity_min; // start from minimum velocity, not actual velocity
  27         intensity = bound(0, intensity * autocvar_g_sandbox_object_material_velocity_factor, 1);
  28
  29         sound(self, CH_TRIGGER, strcat("object/impact_", self.material, "_", ftos(ceil(random() * 5)) , ".ogg"), VOL_BASE * intensity, ATTN_NORM);
  30         pointparticles(particleeffectnum(strcat("impact_", self.material)), self.origin, '0 0 0', ceil(intensity * 10)); // allow a count from 1 to 10
  31 }
  32
  33 entity sandbox_ObjectEdit_Get(float permissions)
  34 {
  35         // returns the traced entity if the player can edit it, and world if not
  36         // if permissions if FALSE, the object is returned regardless of editing rights
  37         // attached objects are SOLID_NOT and don't risk getting traced
  38
  39         makevectors(self.v_angle);
  40         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_edit, MOVE_NORMAL, self);
  41
  42         if(trace_ent.classname != "object")
  43                 return world; // entity is not an object
  44         if(!permissions)
  45                 return trace_ent; // don't check permissions, anyone can edit this object
  46         if(!trace_ent.crypto_idfp)
  47                 return trace_ent; // the player who spawned this object did not have an UID, so anyone can edit it
  48         if not(trace_ent.crypto_idfp != self.crypto_idfp && autocvar_g_sandbox_editor_free < 2)
  49                 return trace_ent; // object does not belong to the player, and players can only edit their own objects on this server
  50         return world;
  51 }
  52
  53 void sandbox_ObjectEdit_Scale(entity e, float f)
  54 {
  55         e.scale = f;
  56         if(e.scale)
  57         {
  58                 e.scale = bound(autocvar_g_sandbox_object_scale_min, e.scale, autocvar_g_sandbox_object_scale_max);
  59                 setsize(e, e.mins * e.scale, e.maxs * e.scale); // adapt bounding box size to model size
  60         }
  61 }
  62
  63 .float old_movetype;
  64 void sandbox_ObjectAttach_Remove(entity e);
  65 void sandbox_ObjectAttach_Set(entity e, entity parent, string s)
  66 {
  67         // attaches e to parent on string s
  68
  69         // we can't attach to an attachment, for obvious reasons
  70         sandbox_ObjectAttach_Remove(e);
  71
  72         e.old_movetype = e.movetype; // persist physics
  73         e.movetype = MOVETYPE_FOLLOW;
  74         e.solid = SOLID_NOT;
  75         e.takedamage = DAMAGE_NO;
  76
  77         setattachment(e, parent, s);
  78         e.owner = parent;
  79 }
  80
  81 void sandbox_ObjectAttach_Remove(entity e)
  82 {
  83         // detaches any object attached to e
  84
  85         entity head;
  86         for(head = world; (head = find(head, classname, "object")); )
  87         {
  88                 if(head.owner == e)
  89                 {
  90                         vector org;
  91                         head.movetype = head.old_movetype; // restore persisted physics
  92                         head.solid = SOLID_BBOX;
  93                         head.takedamage = DAMAGE_AIM;
  94
  95                         org = gettaginfo(head, 0);
  96                         setattachment(head, world, "");
  97                         head.owner = world;
  98
  99                         // objects change origin and angles when detached, so apply previous position
 100                         setorigin(head, org);
 101                         head.angles = e.angles; // don't allow detached objects to spin or roll
 102                 }
 103         }
 104 }
 105
 106 entity sandbox_ObjectSpawn(float database)
 107 {
 108         // spawn a new object with default properties
 109
 110         entity e;
 111         e = spawn();
 112         e.classname = "object";
 113         e.takedamage = DAMAGE_AIM;
 114         e.damageforcescale = 1;
 115         e.solid = SOLID_BBOX; // SOLID_BSP would be best, but can lag the server badly
 116         e.movetype = MOVETYPE_TOSS;
 117         e.frame = 0;
 118         e.skin = 0;
 119         e.material = string_null;
 120         e.touch = sandbox_ObjectFunction_Touch;
 121
 122         if(!database)
 123         {
 124                 // set the object's owner via player UID
 125                 // if the player does not have an UID, the owner cannot be stored and his objects may be edited by anyone
 126                 if(self.crypto_idfp != "")
 127                         e.crypto_idfp = strzone(self.crypto_idfp);
 128                 else
 129                         print_to(self, "^1SANDBOX - WARNING: ^7You spawned an object, but lack a player UID. ^1Your objects are not secured and can be edited by any player!");
 130
 131                 // set origin and direction based on player position and view angle
 132                 makevectors(self.v_angle);
 133                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_spawn, MOVE_NORMAL, self);
 134                 setorigin(e, trace_endpos);
 135                 e.angles_y = self.v_angle_y;
 136         }
 137
 138         object_count += 1;
 139         return e;
 140 }
 141
 142 void sandbox_ObjectRemove(entity e)
 143 {
 144         sandbox_ObjectAttach_Remove(e); // detach child objects
 145         if(e.material)
 146         {
 147                 strunzone(e.material);
 148                 e.material = string_null;
 149         }
 150         if(e.crypto_idfp)
 151         {
 152                 strunzone(e.crypto_idfp);
 153                 e.crypto_idfp = string_null;
 154         }
 155         remove(e);
 156         e = world;
 157
 158         object_count -= 1;
 159 }
 160
 161 string port_string[MAX_STORAGE_ATTACHMENTS]; // fteqcc crashes if this isn't defined as a global
 162
 163 string sandbox_ObjectPort_Save(entity e, float database)
 164 {
 165         // save object properties, and return them as a string
 166         float i;
 167         string s;
 168         entity head;
 169
 170         for(head = world; (head = find(head, classname, "object")); )
 171         {
 172                 // the main object needs to be first in the array [0] with attached objects following
 173                 float slot, physics;
 174                 if(head == e) // this is the main object, place it first
 175                 {
 176                         slot = 0;
 177                         physics = head.movetype; // applied physics are normal physics for parents
 178                 }
 179                 else if(head.owner == e) // child object, list them in order
 180                 {
 181                         i += 1; // children start from 1
 182                         slot = i;
 183                         physics = head.old_movetype; // persisted physics are normal physics for children
 184                         gettaginfo(head.owner, head.tag_index); // get the name of the tag our object is attached to, used further below
 185                 }
 186                 else
 187                         continue;
 188
 189                 // ---------------- OBJECT PROPERTY STORAGE: SAVE ----------------
 190                 if(slot)
 191                 {
 192                         // properties stored only for child objects
 193                         if(gettaginfo_name)     port_string[slot] = strcat(port_string[slot], "\"", gettaginfo_name, "\" ");    else    port_string[slot] = strcat(port_string[slot], "- "); // none
 194                 }
 195                 else
 196                 {
 197                         // properties stored only for parent objects
 198                         if(database)
 199                         {
 200                                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.origin), " ");
 201                                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.angles), " ");
 202                         }
 203                 }
 204                 // properties stored for all objects
 205                 port_string[slot] = strcat(port_string[slot], "\"", head.model, "\" ");
 206                 port_string[slot] = strcat(port_string[slot], ftos(head.skin), " ");
 207                 port_string[slot] = strcat(port_string[slot], ftos(head.alpha), " ");
 208                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.colormod), " ");
 209                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.glowmod), " ");
 210                 port_string[slot] = strcat(port_string[slot], ftos(head.frame), " ");
 211                 port_string[slot] = strcat(port_string[slot], ftos(head.scale), " ");
 212                 port_string[slot] = strcat(port_string[slot], ftos(physics), " ");
 213                 port_string[slot] = strcat(port_string[slot], ftos(head.damageforcescale), " ");
 214                 if(head.material)       port_string[slot] = strcat(port_string[slot], "\"", head.material, "\" ");      else    port_string[slot] = strcat(port_string[slot], "- "); // none
 215                 if(database)
 216                 {
 217                         // properties stored only for the database
 218                         if(head.crypto_idfp)    port_string[slot] = strcat(port_string[slot], "\"", head.crypto_idfp, "\" ");   else    port_string[slot] = strcat(port_string[slot], "- "); // none
 219                 }
 220         }
 221
 222         // now apply the array to a simple string, with the ; symbol separating objects
 223         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 224         {
 225                 if(port_string[i])
 226                         s = strcat(s, port_string[i], "; ");
 227                 port_string[i] = string_null; // fully clear the string
 228         }
 229
 230         return s;
 231 }
 232
 233 entity sandbox_ObjectPort_Load(string s, float database)
 234 {
 235         // load object properties, and spawn a new object with them
 236         float n, i;
 237         entity e, parent;
 238
 239         // separate objects between the ; symbols
 240         n = tokenizebyseparator(s, "; ");
 241         for(i = 0; i < n; ++i)
 242                 port_string[i] = argv(i);
 243
 244         // now separate and apply the properties of each object
 245         for(i = 0; i < n; ++i)
 246         {
 247                 float argv_num;
 248                 string tagname;
 249                 argv_num = 0;
 250                 tokenize_console(port_string[i]);
 251                 e = sandbox_ObjectSpawn(database);
 252
 253                 // ---------------- OBJECT PROPERTY STORAGE: LOAD ----------------
 254                 if(i)
 255                 {
 256                         // properties stored only for child objects
 257                         if(argv(argv_num) != "-")       tagname = argv(argv_num);       else tagname = string_null;     ++argv_num;
 258                 }
 259                 else
 260                 {
 261                         // properties stored only for parent objects
 262                         if(database)
 263                         {
 264                                 setorigin(e, stov(argv(argv_num)));     ++argv_num;
 265                                 e.angles = stov(argv(argv_num));        ++argv_num;
 266                         }
 267                         parent = e; // mark parent objects as such
 268                 }
 269                 // properties stored for all objects
 270                 setmodel(e, argv(argv_num));    ++argv_num;
 271                 e.skin = stof(argv(argv_num));  ++argv_num;
 272                 e.alpha = stof(argv(argv_num)); ++argv_num;
 273                 e.colormod = stov(argv(argv_num));      ++argv_num;
 274                 e.glowmod = stov(argv(argv_num));       ++argv_num;
 275                 e.frame = stof(argv(argv_num)); ++argv_num;
 276                 sandbox_ObjectEdit_Scale(e, stof(argv(argv_num)));      ++argv_num;
 277                 e.movetype = e.old_movetype = stof(argv(argv_num));     ++argv_num;
 278                 e.damageforcescale = stof(argv(argv_num));      ++argv_num;
 279                 if(e.material)  strunzone(e.material);  if(argv(argv_num) != "-")       e.material = strzone(argv(argv_num));   else    e.material = string_null;       ++argv_num;
 280                 if(database)
 281                 {
 282                         // properties stored only for the database
 283                         if(e.crypto_idfp)       strunzone(e.crypto_idfp);       if(argv(argv_num) != "-")       e.crypto_idfp = strzone(argv(argv_num));        else    e.crypto_idfp = string_null;    ++argv_num;
 284                 }
 285
 286                 // attach last
 287                 sandbox_ObjectAttach_Set(e, parent, tagname);
 288         }
 289
 290         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 291                 port_string[i] = string_null; // fully clear the string
 292
 293         return e;
 294 }
 295
 296 void sandbox_Database_Save()
 297 {
 298         // saves all objects to the database file
 299         entity head;
 300         string file_name;
 301         float file_get;
 302
 303         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 304         file_get = fopen(file_name, FILE_WRITE);
 305         fputs(file_get, strcat("// sandbox storage \"", autocvar_g_sandbox_storage_name, "\" for map \"", GetMapname(), "\" last updated ", strftime(TRUE, "%d-%m-%Y %H:%M:%S")));
 306         fputs(file_get, strcat(" containing ", ftos(object_count), " objects\n"));
 307
 308         for(head = world; (head = find(head, classname, "object")); )
 309         {
 310                 // attached objects are persisted separately, ignore them here
 311                 if(head.owner != world)
 312                         continue;
 313
 314                 // use a line of text for each object, listing all properties
 315                 fputs(file_get, strcat(sandbox_ObjectPort_Save(head, TRUE), "\n"));
 316         }
 317         fclose(file_get);
 318 }
 319
 320 void sandbox_Database_Load()
 321 {
 322         // loads all objects from the database file
 323         string file_read, file_name;
 324         float file_get, i;
 325
 326         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 327         file_get = fopen(file_name, FILE_READ);
 328         if(file_get < 0)
 329         {
 330                 if(autocvar_g_sandbox_info > 0)
 331                         print(strcat("^3SANDBOX - SERVER: ^7could not find storage file ^3", file_name, "^7, no objects were loaded\n"));
 332         }
 333         else
 334         {
 335                 for(;;)
 336                 {
 337                         file_read = fgets(file_get);
 338                         if(!file_read)
 339                                 break;
 340                         if(substring(file_read, 0, 2) == "//")
 341                                 continue;
 342                         if(substring(file_read, 0, 1) == "#")
 343                                 continue;
 344
 345                         entity e;
 346                         e = sandbox_ObjectPort_Load(file_read, TRUE);
 347
 348                         if(e.material)
 349                         {
 350                                 // since objects are being loaded for the first time, precache material sounds for each
 351                                 for (i = 1; i <= 5; i++) // 5 sounds in total
 352                                         precache_sound(strcat("object/impact_", e.material, "_", ftos(i), ".ogg"));
 353                         }
 354                 }
 355                 if(autocvar_g_sandbox_info > 0)
 356                         print(strcat("^3SANDBOX - SERVER: ^7successfully loaded storage file ^3", file_name, "\n"));
 357         }
 358 }
 359
 360 MUTATOR_HOOKFUNCTION(sandbox_PlayerCommand)
 361 {
 362         if(MUTATOR_RETURNVALUE) // command was already handled?
 363                 return FALSE;
 364         if(cmd_name == "g_sandbox")
 365         {
 366                 if(cmd_argc < 2)
 367                 {
 368                         print_to(self, "Sandbox mode is active. For usage information, type 'sandbox help'");
 369                         return TRUE;
 370                 }
 371
 372                 switch(argv(1))
 373                 {
 374                         entity e;
 375                         float i;
 376
 377                         // ---------------- COMMAND: HELP ----------------
 378                         case "help":
 379                                 print_to(self, "You can use the following sandbox commands:");
 380                                 print_to(self, "^7\"^2object_spawn ^3models/foo/bar.md3^7\" spawns a new object in front of the player, and gives it the specified model");
 381                                 print_to(self, "^7\"^2object_remove^7\" removes the object the player is looking at. Players can only remove their own objects");
 382                                 print_to(self, "^7\"^2object_duplicate ^3value^7\" duplicates the object. 'copy' copies the object, 'paste' puts it in front of the player");
 383                                 print_to(self, "^7\"^2object_attach ^3property value^7\" attaches one object to another. Players can only attach their own objects");
 384                                 print_to(self, "^7Attachment properties for ^2object_attach^7:");
 385                                 print_to(self, "^3get ^7- selects the object you are facing as the object to be attached");
 386                                 print_to(self, "^3set value ^7- attaches the previously selected object to the object you are facing, on the specified bone");
 387                                 print_to(self, "^3remove ^7- detaches all objects from the object you are facing");
 388                                 print_to(self, "^7\"^2object_edit ^3property value^7\" edits the given property of the object. Players can only edit their own objects");
 389                                 print_to(self, "^7Object properties for ^2object_edit^7:");
 390                                 print_to(self, "^3skin value ^7- changes the skin of the object");
 391                                 print_to(self, "^3alpha value ^7- sets object transparency");
 392                                 print_to(self, "^3colormod \"value_x value_y value_z\" ^7- main object color");
 393                                 print_to(self, "^3glowmod \"value_x value_y value_z\" ^7- glow object color");
 394                                 print_to(self, "^3frame value ^7- object animation frame, for self-animated models");
 395                                 print_to(self, "^3scale value ^7- changes object scale. 0.5 is half size and 2 is double size");
 396                                 print_to(self, "^3physics value ^7- object physics, 0 = static, 1 = movable, 2 = physical");
 397                                 print_to(self, "^3force value ^7- amount of force applied to objects that are shot");
 398                                 print_to(self, "^3material value ^7- sets the material of the object. Default materials are: metal, stone, wood, flesh");
 399                                 print_to(self, "^7\"^2object_claim^7\" sets the player as the owner of the object, if he has the right to edit it");
 400                                 print_to(self, "^7\"^2object_info ^3value^7\" shows public information about the object. 'mesh' shows model information");
 401                                 print_to(self, "^7The ^1drag object ^7key can be used to grab and carry objects. Players can only grab their own objects");
 402                                 return TRUE;
 403
 404                         // ---------------- COMMAND: OBJECT, SPAWN ----------------
 405                         case "object_spawn":
 406                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 407                                 {
 408                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 409                                         return TRUE;
 410                                 }
 411                                 if(cmd_argc < 3)
 412                                 {
 413                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object without specifying a model. Please specify the path to your model file after the 'object_spawn' command");
 414                                         return TRUE;
 415                                 }
 416                                 else if not(fexists(argv(2)))
 417                                 {
 418                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object with a non-existent model. Make sure the path to your model file is correct");
 419                                         return TRUE;
 420                                 }
 421
 422                                 e = sandbox_ObjectSpawn(FALSE);
 423                                 setmodel(e, argv(2));
 424
 425                                 if(autocvar_g_sandbox_info > 0)
 426                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " spawned an object at origin ^3", vtos(e.origin), "\n"));
 427                                 return TRUE;
 428
 429                         // ---------------- COMMAND: OBJECT, REMOVE ----------------
 430                         case "object_remove":
 431                                 e = sandbox_ObjectEdit_Get(TRUE);
 432                                 if(e != world)
 433                                 {
 434                                         if(autocvar_g_sandbox_info > 0)
 435                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " removed an object at origin ^3", vtos(e.origin), "\n"));
 436                                         sandbox_ObjectRemove(e);
 437                                         return TRUE;
 438                                 }
 439
 440                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be removed. Make sure you are facing an object that you have edit rights over");
 441                                 return TRUE;
 442
 443                         // ---------------- COMMAND: OBJECT, DUPLICATE ----------------
 444                         case "object_duplicate":
 445                                 switch(argv(2))
 446                                 {
 447                                         case "copy":
 448                                                 // copies customizable properties of the selected object to the clipboard
 449                                                 e = sandbox_ObjectEdit_Get(autocvar_g_sandbox_editor_free); // can we copy objects we can't edit?
 450                                                 if(e != world)
 451                                                 {
 452                                                         if(self.object_clipboard)
 453                                                                 strunzone(self.object_clipboard);
 454                                                         self.object_clipboard = strzone(sandbox_ObjectPort_Save(e, FALSE));
 455
 456                                                         print_to(self, "^2SANDBOX - INFO: ^7Object copied to clipboard");
 457                                                         return TRUE;
 458                                                 }
 459                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be copied. Make sure you are facing an object that you have copy rights over");
 460                                                 return TRUE;
 461
 462                                         case "paste":
 463                                                 // spawns a new object using the properties in the player's clipboard
 464                                                 if(!self.object_clipboard) // no object in clipboard
 465                                                 {
 466                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object in clipboard. You must copy an object before you can paste it");
 467                                                         return TRUE;
 468                                                 }
 469                                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 470                                                 {
 471                                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 472                                                         return TRUE;
 473                                                 }
 474
 475                                                 e = sandbox_ObjectPort_Load(self.object_clipboard, FALSE);
 476
 477                                                 print_to(self, "^2SANDBOX - INFO: ^7Object pasted successfully");
 478                                                 if(autocvar_g_sandbox_info > 0)
 479                                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " pasted an object at origin ^3", vtos(e.origin), "\n"));
 480                                                 return TRUE;
 481                                 }
 482                                 return TRUE;
 483
 484                         // ---------------- COMMAND: OBJECT, ATTACH ----------------
 485                         case "object_attach":
 486                                 switch(argv(2))
 487                                 {
 488                                         case "get":
 489                                                 // select e as the object as meant to be attached
 490                                                 e = sandbox_ObjectEdit_Get(TRUE);
 491                                                 if(e != world)
 492                                                 {
 493                                                         self.object_attach = e;
 494                                                         print_to(self, "^2SANDBOX - INFO: ^7Object selected for attachment");
 495                                                         return TRUE;
 496                                                 }
 497                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be selected for attachment. Make sure you are facing an object that you have edit rights over");
 498                                                 return TRUE;
 499                                         case "set":
 500                                                 if(self.object_attach == world)
 501                                                 {
 502                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object selected for attachment. Please select an object to be attached first.");
 503                                                         return TRUE;
 504                                                 }
 505
 506                                                 // attaches the previously selected object to e
 507                                                 e = sandbox_ObjectEdit_Get(TRUE);
 508                                                 if(e != world)
 509                                                 {
 510                                                         sandbox_ObjectAttach_Set(self.object_attach, e, argv(3));
 511                                                         self.object_attach = world; // object was attached, no longer keep it scheduled for attachment
 512                                                         print_to(self, "^2SANDBOX - INFO: ^7Object attached successfully");
 513                                                         if(autocvar_g_sandbox_info > 1)
 514                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " attached objects at origin ^3", vtos(e.origin), "\n"));
 515                                                         return TRUE;
 516                                                 }
 517                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be attached to the parent. Make sure you are facing an object that you have edit rights over");
 518                                                 return TRUE;
 519                                         case "remove":
 520                                                 // removes e if it was attached
 521                                                 e = sandbox_ObjectEdit_Get(TRUE);
 522                                                 if(e != world)
 523                                                 {
 524                                                         sandbox_ObjectAttach_Remove(e);
 525                                                         print_to(self, "^2SANDBOX - INFO: ^7Child objects detached successfully");
 526                                                         if(autocvar_g_sandbox_info > 1)
 527                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " detached objects at origin ^3", vtos(e.origin), "\n"));
 528                                                         return TRUE;
 529                                                 }
 530                                                 print_to(self, "^1SANDBOX - WARNING: ^7Child objects could not be detached. Make sure you are facing an object that you have edit rights over");
 531                                                 return TRUE;
 532                                 }
 533                                 return TRUE;
 534
 535                         // ---------------- COMMAND: OBJECT, EDIT ----------------
 536                         case "object_edit":
 537                                 if(!argv(2))
 538                                 {
 539                                         print_to(self, "^1SANDBOX - WARNING: ^7Too few parameters. You must specify a property to edit");
 540                                         return TRUE;
 541                                 }
 542
 543                                 e = sandbox_ObjectEdit_Get(TRUE);
 544                                 if(e != world)
 545                                 {
 546                                         switch(argv(2))
 547                                         {
 548                                                 case "skin":
 549                                                         e.skin = stof(argv(3));
 550                                                         break;
 551                                                 case "alpha":
 552                                                         e.alpha = stof(argv(3));
 553                                                         break;
 554                                                 case "color_main":
 555                                                         e.colormod = stov(argv(3));
 556                                                         break;
 557                                                 case "color_glow":
 558                                                         e.glowmod = stov(argv(3));
 559                                                         break;
 560                                                 case "frame":
 561                                                         e.frame = stof(argv(3));
 562                                                         break;
 563                                                 case "scale":
 564                                                         sandbox_ObjectEdit_Scale(e, stof(argv(3)));
 565                                                         break;
 566                                                 case "physics":
 567                                                         switch(argv(3))
 568                                                         {
 569                                                                 case "0": // static
 570                                                                         e.movetype = MOVETYPE_NONE;
 571                                                                         break;
 572                                                                 case "1": // movable
 573                                                                         e.movetype = MOVETYPE_TOSS;
 574                                                                         break;
 575                                                                 case "2": // physical
 576                                                                         e.movetype = MOVETYPE_PHYSICS;
 577                                                                         break;
 578                                                                 default:
 579                                                                         break;
 580                                                         }
 581                                                         break;
 582                                                 case "force":
 583                                                         e.damageforcescale = stof(argv(3));
 584                                                         break;
 585                                                 case "material":
 586                                                         if(e.material)
 587                                                                 strunzone(e.material);
 588                                                         if(argv(3))
 589                                                         {
 590                                                                 for (i = 1; i <= 5; i++) // precache material sounds, 5 in total
 591                                                                         precache_sound(strcat("object/impact_", argv(3), "_", ftos(i), ".ogg"));
 592                                                                 e.material = strzone(argv(3));
 593                                                         }
 594                                                         else
 595                                                                 e.material = string_null; // no material
 596                                                         break;
 597                                                 default:
 598                                                         print_to(self, "^1SANDBOX - WARNING: ^7Invalid object property. For usage information, type 'sandbox help'");
 599                                                         break;
 600                                         }
 601                                         if(autocvar_g_sandbox_info > 1)
 602                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " edited property ^3", argv(2), " ^7of an object at origin ^3", vtos(e.origin), "\n"));
 603                                         return TRUE;
 604                                 }
 605
 606                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be edited. Make sure you are facing an object that you have edit rights over");
 607                                 return TRUE;
 608
 609                         // ---------------- COMMAND: OBJECT, CLAIM ----------------
 610                         case "object_claim":
 611                                 // if the player can edit an object but is not its owner, this can be used to claim that object
 612                                 if(self.crypto_idfp == "")
 613                                 {
 614                                         print_to(self, "^1SANDBOX - WARNING: ^7You do not have a player UID, and cannot claim objects");
 615                                         return TRUE;
 616                                 }
 617                                 e = sandbox_ObjectEdit_Get(TRUE);
 618                                 if(e != world)
 619                                 {
 620                                         if(e.crypto_idfp == self.crypto_idfp)
 621                                         {
 622                                                 print_to(self, "^2SANDBOX - INFO: ^7Object is already yours, nothing to claim");
 623                                                 return TRUE;
 624                                         }
 625
 626                                         if(e.crypto_idfp)
 627                                                 strunzone(e.crypto_idfp);
 628                                         e.crypto_idfp = self.crypto_idfp;
 629                                         print_to(self, "^2SANDBOX - INFO: ^7Object claimed successfully");
 630                                 }
 631                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be claimed. Make sure you are facing an object that you have edit rights over");
 632                                 return TRUE;
 633
 634                         // ---------------- COMMAND: OBJECT, INFO ----------------
 635                         case "object_info":
 636                                 // prints public information about the object to the player
 637                                 e = sandbox_ObjectEdit_Get(FALSE);
 638                                 if(e != world)
 639                                 {
 640                                         switch(argv(2))
 641                                         {
 642                                                 case "mesh":
 643                                                         string tags;
 644                                                         for(i = 1; gettaginfo(e, i); i++)
 645                                                                 tags = strcat(tags, "^5", gettaginfo_name, "^7, ");
 646                                                         print_to(self, strcat("^2SANDBOX - INFO: ^7Object mesh is ^3", e.model, "^7 at animation frame ^3", ftos(e.frame), " ^7containing the following tags: ", tags));
 647                                                         return TRUE;
 648                                         }
 649                                 }
 650                                 print_to(self, "^1SANDBOX - WARNING: ^7No information could not be found. Make sure you are facing an object");
 651                                 return TRUE;
 652
 653                         // ---------------- COMMAND: DEFAULT ----------------
 654                         default:
 655                                 print_to(self, "Invalid command. For usage information, type 'sandbox help'");
 656                                 return TRUE;
 657                 }
 658         }
 659         return FALSE;
 660 }
 661
 662 MUTATOR_HOOKFUNCTION(sandbox_PlayerPreThink)
 663 {
 664         // if the player is close enough to their object, they can drag it
 665
 666         if(autocvar_sv_cheats)
 667                 return FALSE; // cheat dragging is used instead
 668
 669         // grab is TRUE if the object can be picked up. While an object is being carried, the Drag() function
 670         // must execute for it either way, otherwise it would cause bugs if it went out of the player's trace.
 671         // This also makes sure that an object can only pe picked up if in range, but does not get dropped if
 672         // it goes out of range while slinging it around.
 673
 674         entity e;
 675         float grab;
 676
 677         e = sandbox_ObjectEdit_Get(TRUE);
 678         if(e != world && vlen(e.origin - self.origin) <= autocvar_g_sandbox_editor_distance_edit)
 679                 grab = TRUE;
 680
 681         if(Drag(e, grab)) // execute dragging
 682                 return TRUE;
 683
 684         return FALSE;
 685 }
 686
 687 MUTATOR_HOOKFUNCTION(sandbox_ClientDisconnect)
 688 {
 689         // unzone the player's clipboard if it's not empty
 690         if(self.object_clipboard)
 691         {
 692                 strunzone(self.object_clipboard);
 693                 self.object_clipboard = string_null;
 694         }
 695
 696         return FALSE;
 697 }
 698
 699 float autosave_time;
 700 MUTATOR_HOOKFUNCTION(sandbox_StartFrame)
 701 {
 702         if(!autocvar_g_sandbox_storage_autosave)
 703                 return FALSE;
 704         if(time < autosave_time)
 705                 return FALSE;
 706         autosave_time = time + autocvar_g_sandbox_storage_autosave;
 707
 708         sandbox_Database_Save();
 709
 710         return TRUE;
 711 }
 712
 713 MUTATOR_DEFINITION(sandbox)
 714 {
 715         MUTATOR_HOOK(SV_ParseClientCommand, sandbox_PlayerCommand, CBC_ORDER_ANY);
 716         MUTATOR_HOOK(SV_StartFrame, sandbox_StartFrame, CBC_ORDER_ANY);
 717         MUTATOR_HOOK(PlayerPreThink, sandbox_PlayerPreThink, CBC_ORDER_ANY);
 718         MUTATOR_HOOK(ClientDisconnect, sandbox_ClientDisconnect, CBC_ORDER_ANY);
 719
 720         MUTATOR_ONADD
 721         {
 722                 autosave_time = time + autocvar_g_sandbox_storage_autosave; // don't save the first server frame
 723                 if(autocvar_g_sandbox_storage_autoload)
 724                         sandbox_Database_Load();
 725         }
 726
 727         return FALSE;
 728 }
 729