qcsrc/server/mutators/sandbox.qc

   1 float object_count;
   2 .string object_clipboard;
   3 .entity object_attach;
   4 .string material;
   5
   6 .float touch_timer;
   7 void sandbox_Object_Touch()
   8 {
   9         // apply material impact effects
  10
  11         if(!self.material)
  12                 return;
  13         if(self.touch_timer > time)
  14                 return; // don't execute each frame
  15         self.touch_timer = time + 0.1;
  16
  17         // make particle count and sound volume depend on impact speed
  18         float intensity;
  19         intensity = vlen(self.velocity) + vlen(other.velocity);
  20         if(intensity) // avoid divisions by 0
  21                 intensity /= 2; // average the two velocities
  22         if not(intensity >= autocvar_g_sandbox_object_material_velocity_min)
  23                 return; // impact not strong enough to do anything
  24         // now offset intensity and apply it to the effects
  25         intensity -= autocvar_g_sandbox_object_material_velocity_min; // start from minimum velocity, not actual velocity
  26         intensity = bound(0, intensity * autocvar_g_sandbox_object_material_velocity_factor, 1);
  27
  28         sound(self, CH_TRIGGER, strcat("object/impact_", self.material, "_", ftos(ceil(random() * 5)) , ".ogg"), VOL_BASE * intensity, ATTN_NORM);
  29         pointparticles(particleeffectnum(strcat("impact_", self.material)), self.origin, '0 0 0', ceil(intensity * 10)); // allow a count from 1 to 10
  30 }
  31
  32 entity sandbox_EditObject_Get()
  33 {
  34         // returns the traced entity if the player can edit it, and world if not
  35         // attached objects are SOLID_NOT and don't risk getting traced
  36
  37         makevectors(self.v_angle);
  38         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_edit, MOVE_NORMAL, self);
  39
  40         if(trace_ent.classname != "object")
  41                 return world; // entity is not an object
  42         if(!trace_ent.crypto_idfp)
  43                 return trace_ent; // the player who spawned this object did not have an UID, so anyone can edit it
  44         else if not(trace_ent.crypto_idfp != self.crypto_idfp && !autocvar_g_sandbox_editor_free)
  45                 return trace_ent; // object does not belong to the player, and players can only edit their own objects on this server
  46         return world;
  47 }
  48
  49 void sandbox_EditObject_Scale(entity e, float f)
  50 {
  51         e.scale = f;
  52         if(e.scale)
  53         {
  54                 e.scale = bound(autocvar_g_sandbox_object_scale_min, e.scale, autocvar_g_sandbox_object_scale_max);
  55                 setsize(e, e.mins * e.scale, e.maxs * e.scale); // adapt bounding box size to model size
  56         }
  57 }
  58
  59 .float old_movetype;
  60 void sandbox_AttachObject_Set(entity e, entity parent, string s)
  61 {
  62         // attaches e to parent on string s
  63
  64         e.old_movetype = e.movetype; // persist this
  65
  66         e.movetype = MOVETYPE_FOLLOW;
  67         e.solid = SOLID_NOT;
  68         e.takedamage = DAMAGE_NO;
  69
  70         setattachment(e, parent, s);
  71         e.owner = parent;
  72 }
  73
  74 void sandbox_AttachObject_Remove(entity e)
  75 {
  76         // detaches any object attached to e
  77
  78         entity head;
  79         for(head = world; (head = find(head, classname, "object")); )
  80         {
  81                 if(head.owner == e)
  82                 {
  83                         head.movetype = head.old_movetype; // revert to previous physics
  84                         head.solid = SOLID_BBOX;
  85                         head.takedamage = DAMAGE_AIM;
  86
  87                         setattachment(head, world, "");
  88                         head.owner = world;
  89
  90                         // objects reset origin and angles when detached, so apply the parent's to prevent teleporting
  91                         setorigin(head, e.origin);
  92                         head.angles = e.angles;
  93                 }
  94         }
  95 }
  96
  97 entity sandbox_SpawnObject(float database)
  98 {
  99         // spawn a new object with default properties
 100
 101         entity e;
 102         e = spawn();
 103         e.classname = "object";
 104         e.takedamage = DAMAGE_AIM;
 105         e.damageforcescale = 1;
 106         e.solid = SOLID_BBOX; // SOLID_BSP would be best, but can lag the server badly
 107         e.movetype = MOVETYPE_TOSS;
 108         e.frame = 0;
 109         e.skin = 0;
 110         e.material = string_null;
 111         e.touch = sandbox_Object_Touch;
 112
 113         if(!database)
 114         {
 115                 // set the object's owner via player UID
 116                 // if the player does not have an UID, the owner cannot be stored and his objects may be edited by anyone
 117                 if(self.crypto_idfp != "")
 118                         e.crypto_idfp = strzone(self.crypto_idfp);
 119                 else
 120                         print_to(self, "^1SANDBOX - WARNING: ^7You spawned an object, but lack a player UID. ^1Your objects are not secured and can be edited by any player!");
 121
 122                 // set origin and direction based on player position and view angle
 123                 makevectors(self.v_angle);
 124                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_spawn, MOVE_NORMAL, self);
 125                 setorigin(e, trace_endpos);
 126                 e.angles_y = self.v_angle_y;
 127         }
 128
 129         object_count += 1;
 130         return e;
 131 }
 132
 133 void sandbox_RemoveObject(entity e)
 134 {
 135         sandbox_AttachObject_Remove(e); // detach child objects
 136         if(e.material)
 137         {
 138                 strunzone(e.material);
 139                 e.material = string_null;
 140         }
 141         if(e.crypto_idfp)
 142         {
 143                 strunzone(e.crypto_idfp);
 144                 e.crypto_idfp = string_null;
 145         }
 146         remove(e);
 147         e = world;
 148
 149         object_count -= 1;
 150 }
 151
 152 string sandbox_Storage_Save(entity e, float database)
 153 {
 154         // save object properties
 155         string s;
 156
 157         s = strcat(e.model, " ");
 158         s = strcat(s, ftos(e.skin), " ");
 159         s = strcat(s, ftos(e.alpha), " ");
 160         s = strcat(s, sprintf("\"%.9v\"", e.colormod), " ");
 161         s = strcat(s, sprintf("\"%.9v\"", e.glowmod), " ");
 162         s = strcat(s, ftos(e.frame), " ");
 163         s = strcat(s, ftos(e.scale), " ");
 164         s = strcat(s, ftos(e.movetype), " ");
 165         s = strcat(s, ftos(e.damageforcescale), " ");
 166         s = strcat(s, e.material, " ");
 167         if(database)
 168         {
 169                 s = strcat(s, e.crypto_idfp, " ");
 170                 s = strcat(s, sprintf("\"%.9v\"", e.origin), " ");
 171                 s = strcat(s, sprintf("\"%.9v\"", e.angles), " ");
 172         }
 173
 174         return s;
 175 }
 176
 177 void sandbox_Storage_Load(entity e, string s, float database)
 178 {
 179         // load object properties
 180         tokenize_console(s);
 181
 182         setmodel(e, argv(0));
 183         e.skin = stof(argv(1));
 184         e.alpha = stof(argv(2));
 185         e.colormod = stov(argv(3));
 186         e.glowmod = stov(argv(4));
 187         e.frame = stof(argv(5));
 188         sandbox_EditObject_Scale(e, stof(argv(6)));
 189         e.movetype = stof(argv(7));
 190         e.damageforcescale = stof(argv(8));
 191         if(e.material)  strunzone(e.material);  if(argv(9))     e.material = strzone(argv(9));  else    e.material = string_null;
 192         if(database)
 193         {
 194                 if(e.crypto_idfp)       strunzone(e.crypto_idfp);       if(argv(10))    e.crypto_idfp = strzone(argv(10));      else    e.crypto_idfp = string_null;
 195                 setorigin(e, stov(argv(11)));
 196                 e.angles = stov(argv(12));
 197         }
 198 }
 199
 200 void sandbox_Storage_DatabaseSave()
 201 {
 202         // saves all objects to the database file
 203         if(!object_count)
 204                 return; // nothing to store
 205
 206         entity head;
 207         string fn;
 208         float fh;
 209
 210         fn = strcat("sandbox/storage_", MapInfo_Map_bspname, ".txt");
 211         fh = fopen(fn, FILE_WRITE);
 212         for(head = world; (head = find(head, classname, "object")); )
 213         {
 214                 // Unfortunately, attached objects cannot be persisted yet. That's because the parent is specified as an entity,
 215                 // but only properties can be saved to this file, leaving no way to identify the owner once all objects are spawned
 216                 // TODO: Find some way to fix this!
 217                 if(head.owner != world)
 218                         continue;
 219
 220                 // a line with the properties of each file
 221                 fputs(fh, strcat(sandbox_Storage_Save(head, TRUE), "\n"));
 222         }
 223         fclose(fh);
 224 }
 225
 226 void sandbox_Storage_DatabaseLoad()
 227 {
 228
 229 }
 230
 231 MUTATOR_HOOKFUNCTION(sandbox_PlayerCommand)
 232 {
 233         if(MUTATOR_RETURNVALUE) // command was already handled?
 234                 return FALSE;
 235         if(cmd_name == "g_sandbox")
 236         {
 237                 if(cmd_argc < 2)
 238                 {
 239                         print_to(self, "Sandbox mode is active. For usage information, type 'sandbox help'");
 240                         return TRUE;
 241                 }
 242
 243                 switch(argv(1))
 244                 {
 245                         entity e;
 246                         float i;
 247
 248                         // ---------------- COMMAND: HELP ----------------
 249                         case "help":
 250                                 print_to(self, "You can use the following sandbox commands:");
 251                                 print_to(self, "^7\"^2object_spawn ^3models/foo/bar.md3^7\" spawns a new object in front of the player, and gives it the specified model");
 252                                 print_to(self, "^7\"^2object_remove^7\" removes the object the player is looking at. Players can only remove their own objects");
 253                                 print_to(self, "^7\"^2object_duplicate ^3value^7\" duplicates the object. 'copy' copies the object, 'paste' puts it in front of the player");
 254                                 print_to(self, "^7\"^2object_claim^7\" sets the player as the owner of the object, if he has the right to edit it");
 255                                 print_to(self, "^7\"^2object_attach ^3property value^7\" attaches one object to another. Players can only attach their own objects");
 256                                 print_to(self, "^7Attachment properties for ^2object_attach^7:");
 257                                 print_to(self, "^3get ^7- selects the object you are facing as the object to be attached");
 258                                 print_to(self, "^3set value ^7- attaches the previously selected object to the object you are facing, on the specified bone");
 259                                 print_to(self, "^3remove ^7- detaches all objects from the object you are facing");
 260                                 print_to(self, "^7\"^2object_edit ^3property value^7\" edits the given property of the object. Players can only edit their own objects");
 261                                 print_to(self, "^7Object properties for ^2object_edit^7:");
 262                                 print_to(self, "^3skin value ^7- changes the skin of the object");
 263                                 print_to(self, "^3alpha value ^7- sets object transparency");
 264                                 print_to(self, "^3colormod \"value_x value_y value_z\" ^7- main object color");
 265                                 print_to(self, "^3glowmod \"value_x value_y value_z\" ^7- glow object color");
 266                                 print_to(self, "^3frame value ^7- object animation frame, for self-animated models");
 267                                 print_to(self, "^3scale value ^7- changes object scale. 0.5 is half size and 2 is double size");
 268                                 print_to(self, "^3physics value ^7- object physics, 0 = static, 1 = movable, 2 = physical");
 269                                 print_to(self, "^3force value ^7- amount of force applied to objects that are shot");
 270                                 print_to(self, "^3material value ^7- sets the material of the object. Default materials are: metal, stone, wood, flesh");
 271                                 print_to(self, "^7The ^1drag object ^7key can be used to grab and carry objects. Players can only grab their own objects");
 272                                 return TRUE;
 273
 274                         // ---------------- COMMAND: SPAWN OBJECT ----------------
 275                         case "object_spawn":
 276                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 277                                 {
 278                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 279                                         return TRUE;
 280                                 }
 281                                 if(cmd_argc < 3)
 282                                 {
 283                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object without specifying a model. Please specify the path to your model file after the 'object_spawn' command");
 284                                         return TRUE;
 285                                 }
 286                                 else if not(fexists(argv(2)))
 287                                 {
 288                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object with a non-existent model. Make sure the path to your model file is correct");
 289                                         return TRUE;
 290                                 }
 291
 292                                 e = sandbox_SpawnObject(FALSE);
 293                                 setmodel(e, argv(2));
 294
 295                                 if(autocvar_g_sandbox_info > 0)
 296                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " spawned an object at origin ^3", vtos(e.origin), "\n"));
 297                                 return TRUE;
 298
 299                         // ---------------- COMMAND: REMOVE OBJECT ----------------
 300                         case "object_remove":
 301                                 e = sandbox_EditObject_Get();
 302                                 if(e != world)
 303                                 {
 304                                         if(autocvar_g_sandbox_info > 0)
 305                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " removed an object at origin ^3", vtos(e.origin), "\n"));
 306                                         sandbox_RemoveObject(e);
 307                                         return TRUE;
 308                                 }
 309
 310                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be removed. Make sure you are facing an object that you have edit rights over");
 311                                 return TRUE;
 312
 313                         // ---------------- COMMAND: DUPLICATE OBJECT ----------------
 314                         case "object_duplicate":
 315                                 switch(argv(2))
 316                                 {
 317                                         case "copy":
 318                                                 // copies customizable properties of the selected object to the clipboard
 319                                                 e = sandbox_EditObject_Get(); // you can only copy objects you can edit, so this works
 320                                                 if(e != world)
 321                                                 {
 322                                                         if(self.object_clipboard)
 323                                                                 strunzone(self.object_clipboard);
 324                                                         self.object_clipboard = strzone(sandbox_Storage_Save(e, FALSE));
 325
 326                                                         print_to(self, "^2SANDBOX - INFO: ^7Object copied to clipboard");
 327                                                         return TRUE;
 328                                                 }
 329                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be copied. Make sure you are facing an object that you have edit rights over");
 330                                                 return TRUE;
 331
 332                                         case "paste":
 333                                                 // spawns a new object using the properties in the player's clipboard
 334                                                 if(!self.object_clipboard) // no object in clipboard
 335                                                 {
 336                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object in clipboard. You must copy an object before you can paste it");
 337                                                         return TRUE;
 338                                                 }
 339                                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 340                                                 {
 341                                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 342                                                         return TRUE;
 343                                                 }
 344
 345                                                 e = sandbox_SpawnObject(FALSE);
 346                                                 sandbox_Storage_Load(e, self.object_clipboard, FALSE);
 347
 348                                                 print_to(self, "^2SANDBOX - INFO: ^7Object pasted successfully");
 349                                                 if(autocvar_g_sandbox_info > 0)
 350                                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " pasted an object at origin ^3", vtos(e.origin), "\n"));
 351                                                 return TRUE;
 352                                 }
 353                                 return TRUE;
 354
 355                         // ---------------- COMMAND: CLAIM OBJECT ----------------
 356                         case "object_claim":
 357                                 // if the player can edit an object but is not its owner, this can be used to claim that object
 358                                 if(self.crypto_idfp == "")
 359                                 {
 360                                         print_to(self, "^1SANDBOX - WARNING: ^7You do not have a player UID, and cannot claim objects");
 361                                         return TRUE;
 362                                 }
 363                                 e = sandbox_EditObject_Get();
 364                                 if(e != world)
 365                                 {
 366                                         if(e.crypto_idfp == self.crypto_idfp)
 367                                         {
 368                                                 print_to(self, "^2SANDBOX - INFO: ^7Object is already yours, nothing to claim");
 369                                                 return TRUE;
 370                                         }
 371
 372                                         if(e.crypto_idfp)
 373                                                 strunzone(e.crypto_idfp);
 374                                         e.crypto_idfp = self.crypto_idfp;
 375                                         print_to(self, "^2SANDBOX - INFO: ^7Object claimed successfully");
 376                                 }
 377                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be claimed. Make sure you are facing an object that you have edit rights over");
 378                                 return TRUE;
 379
 380                         // ---------------- COMMAND: ATTACH OBJECT ----------------
 381                         case "object_attach":
 382                                 switch(argv(2))
 383                                 {
 384                                         case "get":
 385                                                 // select e as the object as meant to be attached
 386                                                 e = sandbox_EditObject_Get();
 387                                                 if(e != world)
 388                                                 {
 389                                                         self.object_attach = e;
 390                                                         print_to(self, "^2SANDBOX - INFO: ^7Object selected for attachment");
 391                                                         return TRUE;
 392                                                 }
 393                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be selected for attachment. Make sure you are facing an object that you have edit rights over");
 394                                                 return TRUE;
 395                                         case "set":
 396                                                 if(self.object_attach == world)
 397                                                 {
 398                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object selected for attachment. Please select an object to be attached first.");
 399                                                         return TRUE;
 400                                                 }
 401
 402                                                 // attaches the previously selected object to e
 403                                                 e = sandbox_EditObject_Get();
 404                                                 if(e != world)
 405                                                 {
 406                                                         sandbox_AttachObject_Set(self.object_attach, e, argv(3));
 407                                                         self.object_attach = world; // object was attached, no longer keep it scheduled for attachment
 408                                                         print_to(self, "^2SANDBOX - INFO: ^7Object attached successfully");
 409                                                         if(autocvar_g_sandbox_info > 1)
 410                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " attached objects at origin ^3", vtos(e.origin), "\n"));
 411                                                         return TRUE;
 412                                                 }
 413                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be attached to the parent. Make sure you are facing an object that you have edit rights over");
 414                                                 return TRUE;
 415                                         case "remove":
 416                                                 // removes e if it was attached
 417                                                 e = sandbox_EditObject_Get();
 418                                                 if(e != world)
 419                                                 {
 420                                                         sandbox_AttachObject_Remove(e);
 421                                                         print_to(self, "^2SANDBOX - INFO: ^7Child objects detached successfully");
 422                                                         if(autocvar_g_sandbox_info > 1)
 423                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " detached objects at origin ^3", vtos(e.origin), "\n"));
 424                                                         return TRUE;
 425                                                 }
 426                                                 print_to(self, "^1SANDBOX - WARNING: ^7Child objects could not be detached. Make sure you are facing an object that you have edit rights over");
 427                                                 return TRUE;
 428                                 }
 429                                 return TRUE;
 430
 431                         // ---------------- COMMAND: EDIT OBJECT ----------------
 432                         case "object_edit":
 433                                 if(!argv(2))
 434                                 {
 435                                         print_to(self, "^1SANDBOX - WARNING: ^7Too few parameters. You must specify a property to edit");
 436                                         return TRUE;
 437                                 }
 438
 439                                 e = sandbox_EditObject_Get();
 440                                 if(e != world)
 441                                 {
 442                                         switch(argv(2))
 443                                         {
 444                                                 case "skin":
 445                                                         e.skin = stof(argv(3));
 446                                                         break;
 447                                                 case "alpha":
 448                                                         e.alpha = stof(argv(3));
 449                                                         break;
 450                                                 case "color_main":
 451                                                         e.colormod = stov(argv(3));
 452                                                         break;
 453                                                 case "color_glow":
 454                                                         e.glowmod = stov(argv(3));
 455                                                         break;
 456                                                 case "frame":
 457                                                         e.frame = stof(argv(3));
 458                                                         break;
 459                                                 case "scale":
 460                                                         sandbox_EditObject_Scale(e, stof(argv(3)));
 461                                                         break;
 462                                                 case "physics":
 463                                                         switch(argv(3))
 464                                                         {
 465                                                                 case "0": // static
 466                                                                         e.movetype = MOVETYPE_NONE;
 467                                                                         break;
 468                                                                 case "1": // movable
 469                                                                         e.movetype = MOVETYPE_TOSS;
 470                                                                         break;
 471                                                                 case "2": // physical
 472                                                                         e.movetype = MOVETYPE_PHYSICS;
 473                                                                         break;
 474                                                                 default:
 475                                                                         break;
 476                                                         }
 477                                                         break;
 478                                                 case "force":
 479                                                         e.damageforcescale = stof(argv(3));
 480                                                         break;
 481                                                 case "material":
 482                                                         if(e.material)
 483                                                                 strunzone(e.material);
 484                                                         if(argv(3))
 485                                                         {
 486                                                                 for (i = 1; i <= 5; i++) // precache material sounds, 5 in total
 487                                                                         precache_sound(strcat("object/impact_", argv(3), "_", ftos(i), ".ogg"));
 488                                                                 e.material = strzone(argv(3));
 489                                                         }
 490                                                         else
 491                                                                 e.material = string_null; // no material
 492                                                         break;
 493                                                 default:
 494                                                         print_to(self, "^1SANDBOX - WARNING: ^7Invalid object property. For usage information, type 'sandbox help'");
 495                                                         break;
 496                                         }
 497                                         if(autocvar_g_sandbox_info > 1)
 498                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " edited property ^3", argv(2), " ^7of an object at origin ^3", vtos(e.origin), "\n"));
 499                                         return TRUE;
 500                                 }
 501
 502                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be edited. Make sure you are facing an object that you have edit rights over");
 503                                 return TRUE;
 504
 505                         // ---------------- COMMAND: DEFAULT ----------------
 506                         default:
 507                                 print_to(self, "Invalid command. For usage information, type 'sandbox help'");
 508                                 return TRUE;
 509                 }
 510         }
 511         return FALSE;
 512 }
 513
 514 MUTATOR_HOOKFUNCTION(sandbox_PlayerPreThink)
 515 {
 516         // if the player is close enough to their object, they can drag it
 517
 518         if(autocvar_sv_cheats)
 519                 return FALSE; // cheat dragging is used instead
 520
 521         // grab is TRUE if the object can be picked up. While an object is being carried, the Drag() function
 522         // must execute for it either way, otherwise it would cause bugs if it went out of the player's trace.
 523         // This also makes sure that an object can only pe picked up if in range, but does not get dropped if
 524         // it goes out of range while slinging it around.
 525
 526         entity e;
 527         float grab;
 528
 529         e = sandbox_EditObject_Get();
 530         if(e != world && vlen(e.origin - self.origin) <= autocvar_g_sandbox_editor_distance_edit)
 531                 grab = TRUE;
 532
 533         if(Drag(e, grab)) // execute dragging
 534                 return TRUE;
 535
 536         return FALSE;
 537 }
 538
 539 MUTATOR_HOOKFUNCTION(sandbox_ClientDisconnect)
 540 {
 541         // unzone the player's clipboard if it's not empty
 542         if(self.object_clipboard)
 543         {
 544                 strunzone(self.object_clipboard);
 545                 self.object_clipboard = string_null;
 546         }
 547
 548         return FALSE;
 549 }
 550
 551 float autosave_time;
 552 MUTATOR_HOOKFUNCTION(sandbox_StartFrame)
 553 {
 554         if(!autocvar_g_sandbox_storage_autosave)
 555                 return FALSE;
 556         if(time < autocvar_g_sandbox_storage_autosave)
 557                 return FALSE;
 558         autosave_time = time + autocvar_g_sandbox_storage_autosave;
 559
 560         sandbox_Storage_DatabaseSave();
 561
 562         return TRUE;
 563 }
 564
 565 MUTATOR_DEFINITION(sandbox)
 566 {
 567         MUTATOR_HOOK(SV_ParseClientCommand, sandbox_PlayerCommand, CBC_ORDER_ANY);
 568         MUTATOR_HOOK(SV_StartFrame, sandbox_StartFrame, CBC_ORDER_ANY);
 569         MUTATOR_HOOK(PlayerPreThink, sandbox_PlayerPreThink, CBC_ORDER_ANY);
 570         MUTATOR_HOOK(ClientDisconnect, sandbox_ClientDisconnect, CBC_ORDER_ANY);
 571
 572         return FALSE;
 573 }
 574