qcsrc/server/mutators/sandbox.qc

   1 const float MAX_STORAGE_ATTACHMENTS = 16;
   2 float object_count;
   3 .float object_flood;
   4 .entity object_attach;
   5 .string material;
   6
   7 .float touch_timer;
   8 void sandbox_ObjectFunction_Touch()
   9 {
  10         // apply material impact effects
  11
  12         if(!self.material)
  13                 return;
  14         if(self.touch_timer > time)
  15                 return; // don't execute each frame
  16         self.touch_timer = time + 0.1;
  17
  18         // make particle count and sound volume depend on impact speed
  19         float intensity;
  20         intensity = vlen(self.velocity) + vlen(other.velocity);
  21         if(intensity) // avoid divisions by 0
  22                 intensity /= 2; // average the two velocities
  23         if not(intensity >= autocvar_g_sandbox_object_material_velocity_min)
  24                 return; // impact not strong enough to do anything
  25         // now offset intensity and apply it to the effects
  26         intensity -= autocvar_g_sandbox_object_material_velocity_min; // start from minimum velocity, not actual velocity
  27         intensity = bound(0, intensity * autocvar_g_sandbox_object_material_velocity_factor, 1);
  28
  29         sound(self, CH_TRIGGER, strcat("object/impact_", self.material, "_", ftos(ceil(random() * 5)) , ".ogg"), VOL_BASE * intensity, ATTN_NORM);
  30         pointparticles(particleeffectnum(strcat("impact_", self.material)), self.origin, '0 0 0', ceil(intensity * 10)); // allow a count from 1 to 10
  31 }
  32
  33 void sandbox_ObjectFunction_Think()
  34 {
  35         entity e;
  36
  37         // decide if and how this object can be grabbed
  38         if(autocvar_g_sandbox_readonly)
  39                 self.grab = 0; // no grabbing
  40         else if(autocvar_g_sandbox_editor_free < 2 && self.crypto_idfp)
  41                 self.grab = 1; // owner only
  42         else
  43                 self.grab = 3; // anyone
  44
  45         // Object owner is stored via player UID, but we also need the owner as an entity (if the player is available on the server).
  46         // Therefore, scan for all players, and update the owner as long as the player is present. We must always do this,
  47         // since if the owning player disconnects, the object's owner should also be reset.
  48         FOR_EACH_REALPLAYER(e) // bots can't have objects
  49         {
  50                 if(self.crypto_idfp == e.crypto_idfp)
  51                 {
  52                         self.realowner = e;
  53                         break;
  54                 }
  55                 self.realowner = world;
  56         }
  57
  58         self.nextthink = time;
  59 }
  60
  61 .float old_solid, old_movetype;
  62 entity sandbox_ObjectEdit_Get(float permissions)
  63 {
  64         // returns the traced entity if the player can edit it, and world if not
  65         // if permissions if FALSE, the object is returned regardless of editing rights
  66         // attached objects are SOLID_NOT and don't risk getting traced
  67         entity head;
  68
  69         // Tracing does not work for entities that use SOLID_NOT or SOLID_TRIGGER. Therefore, make all
  70         // objects temporarily solid while doing the trace, then revert them to their initial solidity.
  71         for(head = world; (head = find(head, classname, "object")); )
  72         {
  73                 if(head.owner == world) // skip attached objects
  74                 {
  75                         head.old_solid = head.solid;
  76                         head.solid = SOLID_BBOX;
  77                 }
  78         }
  79         makevectors(self.v_angle);
  80         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_edit, MOVE_NORMAL, self);
  81         for(head = world; (head = find(head, classname, "object")); )
  82         {
  83                 if(head.owner == world) // skip attached objects
  84                         head.solid = head.old_solid;
  85         }
  86
  87         if(trace_ent.classname != "object")
  88                 return world; // entity is not an object
  89         if(!permissions)
  90                 return trace_ent; // don't check permissions, anyone can edit this object
  91         if(!trace_ent.crypto_idfp)
  92                 return trace_ent; // the player who spawned this object did not have an UID, so anyone can edit it
  93         if not(trace_ent.realowner != self && autocvar_g_sandbox_editor_free < 2)
  94                 return trace_ent; // object does not belong to the player, and players can only edit their own objects on this server
  95         return world;
  96 }
  97
  98 void sandbox_ObjectEdit_Scale(entity e, float f)
  99 {
 100         e.scale = f;
 101         if(e.scale)
 102         {
 103                 e.scale = bound(autocvar_g_sandbox_object_scale_min, e.scale, autocvar_g_sandbox_object_scale_max);
 104                 setmodel(e, e.model); // reset mins and maxs based on mesh
 105                 setsize(e, e.mins * e.scale, e.maxs * e.scale); // adapt bounding box size to model size
 106         }
 107 }
 108
 109 void sandbox_ObjectAttach_Remove(entity e);
 110 void sandbox_ObjectAttach_Set(entity e, entity parent, string s)
 111 {
 112         // attaches e to parent on string s
 113
 114         // we can't attach to an attachment, for obvious reasons
 115         sandbox_ObjectAttach_Remove(e);
 116
 117         e.old_solid = e.solid; // persist solidity
 118         e.old_movetype = e.movetype; // persist physics
 119         e.movetype = MOVETYPE_FOLLOW;
 120         e.solid = SOLID_NOT;
 121         e.takedamage = DAMAGE_NO;
 122
 123         setattachment(e, parent, s);
 124         e.owner = parent;
 125 }
 126
 127 void sandbox_ObjectAttach_Remove(entity e)
 128 {
 129         // detaches any object attached to e
 130
 131         entity head;
 132         for(head = world; (head = find(head, classname, "object")); )
 133         {
 134                 if(head.owner == e)
 135                 {
 136                         vector org;
 137                         org = gettaginfo(head, 0);
 138                         setattachment(head, world, "");
 139                         head.owner = world;
 140
 141                         // objects change origin and angles when detached, so apply previous position
 142                         setorigin(head, org);
 143                         head.angles = e.angles; // don't allow detached objects to spin or roll
 144
 145                         head.solid = head.old_solid; // restore persisted solidity
 146                         head.movetype = head.old_movetype; // restore persisted physics
 147                         head.takedamage = DAMAGE_AIM;
 148                 }
 149         }
 150 }
 151
 152 entity sandbox_ObjectSpawn(float database)
 153 {
 154         // spawn a new object with default properties
 155
 156         entity e;
 157         e = spawn();
 158         e.classname = "object";
 159         e.takedamage = DAMAGE_AIM;
 160         e.damageforcescale = 1;
 161         e.solid = SOLID_BBOX; // SOLID_BSP would be best, but can lag the server badly
 162         e.movetype = MOVETYPE_TOSS;
 163         e.frame = 0;
 164         e.skin = 0;
 165         e.material = string_null;
 166         e.touch = sandbox_ObjectFunction_Touch;
 167         e.think = sandbox_ObjectFunction_Think;
 168         e.nextthink = time;
 169         //e.effects |= EF_SELECTABLE; // don't do this all the time, maybe just when editing objects?
 170
 171         if(!database)
 172         {
 173                 // set the object's owner via player UID
 174                 // if the player does not have an UID, the owner cannot be stored and his objects may be edited by anyone
 175                 if(self.crypto_idfp != "")
 176                         e.crypto_idfp = strzone(self.crypto_idfp);
 177                 else
 178                         print_to(self, "^1SANDBOX - WARNING: ^7You spawned an object, but lack a player UID. ^1Your objects are not secured and can be edited by any player!");
 179
 180                 // set public object information
 181                 e.netname = strzone(self.netname); // name of the owner
 182                 e.message = strzone(strftime(TRUE, "%d-%m-%Y %H:%M:%S")); // creation time
 183                 e.message2 = strzone(strftime(TRUE, "%d-%m-%Y %H:%M:%S")); // last editing time
 184
 185                 // set origin and direction based on player position and view angle
 186                 makevectors(self.v_angle);
 187                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_spawn, MOVE_NORMAL, self);
 188                 setorigin(e, trace_endpos);
 189                 e.angles_y = self.v_angle_y;
 190         }
 191
 192         object_count += 1;
 193         return e;
 194 }
 195
 196 void sandbox_ObjectRemove(entity e)
 197 {
 198         sandbox_ObjectAttach_Remove(e); // detach child objects
 199
 200         if(e.material)  {       strunzone(e.material);  e.material = string_null;       }
 201         if(e.crypto_idfp)       {       strunzone(e.crypto_idfp);       e.crypto_idfp = string_null;    }
 202         if(e.netname)   {       strunzone(e.netname);   e.netname = string_null;        }
 203         if(e.message)   {       strunzone(e.message);   e.message = string_null;        }
 204         if(e.message2)  {       strunzone(e.message2);  e.message2 = string_null;       }
 205         remove(e);
 206         e = world;
 207
 208         object_count -= 1;
 209 }
 210
 211 string port_string[MAX_STORAGE_ATTACHMENTS]; // fteqcc crashes if this isn't defined as a global
 212
 213 string sandbox_ObjectPort_Save(entity e, float database)
 214 {
 215         // save object properties, and return them as a string
 216         float i;
 217         string s;
 218         entity head;
 219
 220         for(head = world; (head = find(head, classname, "object")); )
 221         {
 222                 // the main object needs to be first in the array [0] with attached objects following
 223                 float slot, physics, solidity;
 224                 if(head == e) // this is the main object, place it first
 225                 {
 226                         slot = 0;
 227                         solidity = head.solid; // applied solidity is normal solidity for children
 228                         physics = head.movetype; // applied physics are normal physics for parents
 229                 }
 230                 else if(head.owner == e) // child object, list them in order
 231                 {
 232                         i += 1; // children start from 1
 233                         slot = i;
 234                         solidity = head.old_solid; // persisted solidity is normal solidity for children
 235                         physics = head.old_movetype; // persisted physics are normal physics for children
 236                         gettaginfo(head.owner, head.tag_index); // get the name of the tag our object is attached to, used further below
 237                 }
 238                 else
 239                         continue;
 240
 241                 // ---------------- OBJECT PROPERTY STORAGE: SAVE ----------------
 242                 if(slot)
 243                 {
 244                         // properties stored only for child objects
 245                         if(gettaginfo_name)     port_string[slot] = strcat(port_string[slot], "\"", gettaginfo_name, "\" ");    else    port_string[slot] = strcat(port_string[slot], "- "); // none
 246                 }
 247                 else
 248                 {
 249                         // properties stored only for parent objects
 250                         if(database)
 251                         {
 252                                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.origin), " ");
 253                                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.angles), " ");
 254                         }
 255                 }
 256                 // properties stored for all objects
 257                 port_string[slot] = strcat(port_string[slot], "\"", head.model, "\" ");
 258                 port_string[slot] = strcat(port_string[slot], ftos(head.skin), " ");
 259                 port_string[slot] = strcat(port_string[slot], ftos(head.alpha), " ");
 260                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.colormod), " ");
 261                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.glowmod), " ");
 262                 port_string[slot] = strcat(port_string[slot], ftos(head.frame), " ");
 263                 port_string[slot] = strcat(port_string[slot], ftos(head.scale), " ");
 264                 port_string[slot] = strcat(port_string[slot], ftos(solidity), " ");
 265                 port_string[slot] = strcat(port_string[slot], ftos(physics), " ");
 266                 port_string[slot] = strcat(port_string[slot], ftos(head.damageforcescale), " ");
 267                 if(head.material)       port_string[slot] = strcat(port_string[slot], "\"", head.material, "\" ");      else    port_string[slot] = strcat(port_string[slot], "- "); // none
 268                 if(database)
 269                 {
 270                         // properties stored only for the database
 271                         if(head.crypto_idfp)    port_string[slot] = strcat(port_string[slot], "\"", head.crypto_idfp, "\" ");   else    port_string[slot] = strcat(port_string[slot], "- "); // none
 272                         port_string[slot] = strcat(port_string[slot], "\"", e.netname, "\" ");
 273                         port_string[slot] = strcat(port_string[slot], "\"", e.message, "\" ");
 274                         port_string[slot] = strcat(port_string[slot], "\"", e.message2, "\" ");
 275                 }
 276         }
 277
 278         // now apply the array to a simple string, with the ; symbol separating objects
 279         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 280         {
 281                 if(port_string[i])
 282                         s = strcat(s, port_string[i], "; ");
 283                 port_string[i] = string_null; // fully clear the string
 284         }
 285
 286         return s;
 287 }
 288
 289 entity sandbox_ObjectPort_Load(string s, float database)
 290 {
 291         // load object properties, and spawn a new object with them
 292         float n, i;
 293         entity e, parent;
 294
 295         // separate objects between the ; symbols
 296         n = tokenizebyseparator(s, "; ");
 297         for(i = 0; i < n; ++i)
 298                 port_string[i] = argv(i);
 299
 300         // now separate and apply the properties of each object
 301         for(i = 0; i < n; ++i)
 302         {
 303                 float argv_num;
 304                 string tagname;
 305                 argv_num = 0;
 306                 tokenize_console(port_string[i]);
 307                 e = sandbox_ObjectSpawn(database);
 308
 309                 // ---------------- OBJECT PROPERTY STORAGE: LOAD ----------------
 310                 if(i)
 311                 {
 312                         // properties stored only for child objects
 313                         if(argv(argv_num) != "-")       tagname = argv(argv_num);       else tagname = string_null;     ++argv_num;
 314                 }
 315                 else
 316                 {
 317                         // properties stored only for parent objects
 318                         if(database)
 319                         {
 320                                 setorigin(e, stov(argv(argv_num)));     ++argv_num;
 321                                 e.angles = stov(argv(argv_num));        ++argv_num;
 322                         }
 323                         parent = e; // mark parent objects as such
 324                 }
 325                 // properties stored for all objects
 326                 setmodel(e, argv(argv_num));    ++argv_num;
 327                 e.skin = stof(argv(argv_num));  ++argv_num;
 328                 e.alpha = stof(argv(argv_num)); ++argv_num;
 329                 e.colormod = stov(argv(argv_num));      ++argv_num;
 330                 e.glowmod = stov(argv(argv_num));       ++argv_num;
 331                 e.frame = stof(argv(argv_num)); ++argv_num;
 332                 sandbox_ObjectEdit_Scale(e, stof(argv(argv_num)));      ++argv_num;
 333                 e.solid = e.old_solid = stof(argv(argv_num));   ++argv_num;
 334                 e.movetype = e.old_movetype = stof(argv(argv_num));     ++argv_num;
 335                 e.damageforcescale = stof(argv(argv_num));      ++argv_num;
 336                 if(e.material)  strunzone(e.material);  if(argv(argv_num) != "-")       e.material = strzone(argv(argv_num));   else    e.material = string_null;       ++argv_num;
 337                 if(database)
 338                 {
 339                         // properties stored only for the database
 340                         if(e.crypto_idfp)       strunzone(e.crypto_idfp);       if(argv(argv_num) != "-")       e.crypto_idfp = strzone(argv(argv_num));        else    e.crypto_idfp = string_null;    ++argv_num;
 341                         if(e.netname)   strunzone(e.netname);   e.netname = strzone(argv(argv_num));    ++argv_num;
 342                         if(e.message)   strunzone(e.message);   e.message = strzone(argv(argv_num));    ++argv_num;
 343                         if(e.message2)  strunzone(e.message2);  e.message2 = strzone(argv(argv_num));   ++argv_num;
 344                 }
 345
 346                 // attach last
 347                 if(i)
 348                         sandbox_ObjectAttach_Set(e, parent, tagname);
 349         }
 350
 351         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 352                 port_string[i] = string_null; // fully clear the string
 353
 354         return e;
 355 }
 356
 357 void sandbox_Database_Save()
 358 {
 359         // saves all objects to the database file
 360         entity head;
 361         string file_name;
 362         float file_get;
 363
 364         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 365         file_get = fopen(file_name, FILE_WRITE);
 366         fputs(file_get, strcat("// sandbox storage \"", autocvar_g_sandbox_storage_name, "\" for map \"", GetMapname(), "\" last updated ", strftime(TRUE, "%d-%m-%Y %H:%M:%S")));
 367         fputs(file_get, strcat(" containing ", ftos(object_count), " objects\n"));
 368
 369         for(head = world; (head = find(head, classname, "object")); )
 370         {
 371                 // attached objects are persisted separately, ignore them here
 372                 if(head.owner != world)
 373                         continue;
 374
 375                 // use a line of text for each object, listing all properties
 376                 fputs(file_get, strcat(sandbox_ObjectPort_Save(head, TRUE), "\n"));
 377         }
 378         fclose(file_get);
 379 }
 380
 381 void sandbox_Database_Load()
 382 {
 383         // loads all objects from the database file
 384         string file_read, file_name;
 385         float file_get, i;
 386
 387         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 388         file_get = fopen(file_name, FILE_READ);
 389         if(file_get < 0)
 390         {
 391                 if(autocvar_g_sandbox_info > 0)
 392                         print(strcat("^3SANDBOX - SERVER: ^7could not find storage file ^3", file_name, "^7, no objects were loaded\n"));
 393         }
 394         else
 395         {
 396                 for(;;)
 397                 {
 398                         file_read = fgets(file_get);
 399                         if(!file_read)
 400                                 break;
 401                         if(substring(file_read, 0, 2) == "//")
 402                                 continue;
 403                         if(substring(file_read, 0, 1) == "#")
 404                                 continue;
 405
 406                         entity e;
 407                         e = sandbox_ObjectPort_Load(file_read, TRUE);
 408
 409                         if(e.material)
 410                         {
 411                                 // since objects are being loaded for the first time, precache material sounds for each
 412                                 for (i = 1; i <= 5; i++) // 5 sounds in total
 413                                         precache_sound(strcat("object/impact_", e.material, "_", ftos(i), ".ogg"));
 414                         }
 415                 }
 416                 if(autocvar_g_sandbox_info > 0)
 417                         print(strcat("^3SANDBOX - SERVER: ^7successfully loaded storage file ^3", file_name, "\n"));
 418         }
 419         fclose(file_get);
 420 }
 421
 422 MUTATOR_HOOKFUNCTION(sandbox_PlayerCommand)
 423 {
 424         if(MUTATOR_RETURNVALUE) // command was already handled?
 425                 return FALSE;
 426         if(cmd_name == "g_sandbox")
 427         {
 428                 if(autocvar_g_sandbox_readonly)
 429                 {
 430                         print_to(self, "^2SANDBOX - INFO: ^7Sandbox mode is active, but in read-only mode. Sandbox commands cannot be used");
 431                         return TRUE;
 432                 }
 433                 if(cmd_argc < 2)
 434                 {
 435                         print_to(self, "^2SANDBOX - INFO: ^7Sandbox mode is active. For usage information, type 'sandbox help'");
 436                         return TRUE;
 437                 }
 438
 439                 switch(argv(1))
 440                 {
 441                         entity e;
 442                         float i;
 443                         string s;
 444
 445                         // ---------------- COMMAND: HELP ----------------
 446                         case "help":
 447                                 print_to(self, "You can use the following sandbox commands:");
 448                                 print_to(self, "^7\"^2object_spawn ^3models/foo/bar.md3^7\" spawns a new object in front of the player, and gives it the specified model");
 449                                 print_to(self, "^7\"^2object_remove^7\" removes the object the player is looking at. Players can only remove their own objects");
 450                                 print_to(self, "^7\"^2object_duplicate ^3value^7\" duplicates the object, if the player has copying rights over the original");
 451                                 print_to(self, "^3copy value ^7- copies the properties of the object to the specified client cvar");
 452                                 print_to(self, "^3paste value ^7- spawns an object with the given properties. Properties or cvars must be specified as follows; eg1: \"0 1 2 ...\", eg2: \"$cl_cvar\"");
 453                                 print_to(self, "^7\"^2object_attach ^3property value^7\" attaches one object to another. Players can only attach their own objects");
 454                                 print_to(self, "^3get ^7- selects the object you are facing as the object to be attached");
 455                                 print_to(self, "^3set value ^7- attaches the previously selected object to the object you are facing, on the specified bone");
 456                                 print_to(self, "^3remove ^7- detaches all objects from the object you are facing");
 457                                 print_to(self, "^7\"^2object_edit ^3property value^7\" edits the given property of the object. Players can only edit their own objects");
 458                                 print_to(self, "^3skin value ^7- changes the skin of the object");
 459                                 print_to(self, "^3alpha value ^7- sets object transparency");
 460                                 print_to(self, "^3colormod \"value_x value_y value_z\" ^7- main object color");
 461                                 print_to(self, "^3glowmod \"value_x value_y value_z\" ^7- glow object color");
 462                                 print_to(self, "^3frame value ^7- object animation frame, for self-animated models");
 463                                 print_to(self, "^3scale value ^7- changes object scale. 0.5 is half size and 2 is double size");
 464                                 print_to(self, "^3solidity value ^7- object collisions, 0 = non-solid, 1 = solid");
 465                                 print_to(self, "^3physics value ^7- object physics, 0 = static, 1 = movable, 2 = physical");
 466                                 print_to(self, "^3force value ^7- amount of force applied to objects that are shot");
 467                                 print_to(self, "^3material value ^7- sets the material of the object. Default materials are: metal, stone, wood, flesh");
 468                                 print_to(self, "^7\"^2object_claim^7\" sets the player as the owner of the object, if he has the right to edit it");
 469                                 print_to(self, "^7\"^2object_info ^3value^7\" shows public information about the object");
 470                                 print_to(self, "^3object ^7- prints general information about the object, such as owner and creation / editing date");
 471                                 print_to(self, "^3mesh ^7- prints information about the object's mesh, including skeletal bones");
 472                                 print_to(self, "^3attachments ^7- prints information about the object's attachments");
 473                                 print_to(self, "^7The ^1drag object ^7key can be used to grab and carry objects. Players can only grab their own objects");
 474                                 return TRUE;
 475
 476                         // ---------------- COMMAND: OBJECT, SPAWN ----------------
 477                         case "object_spawn":
 478                                 if(time < self.object_flood)
 479                                 {
 480                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Flood protection active. Please wait ^3", ftos(self.object_flood - time), " ^7seconds beofore spawning another object"));
 481                                         return TRUE;
 482                                 }
 483                                 self.object_flood = time + autocvar_g_sandbox_editor_flood;
 484                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 485                                 {
 486                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 487                                         return TRUE;
 488                                 }
 489                                 if(cmd_argc < 3)
 490                                 {
 491                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object without specifying a model. Please specify the path to your model file after the 'object_spawn' command");
 492                                         return TRUE;
 493                                 }
 494                                 if not(fexists(argv(2)))
 495                                 {
 496                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object with a non-existent model. Make sure the path to your model file is correct");
 497                                         return TRUE;
 498                                 }
 499
 500                                 e = sandbox_ObjectSpawn(FALSE);
 501                                 setmodel(e, argv(2));
 502
 503                                 if(autocvar_g_sandbox_info > 0)
 504                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " spawned an object at origin ^3", vtos(e.origin), "\n"));
 505                                 return TRUE;
 506
 507                         // ---------------- COMMAND: OBJECT, REMOVE ----------------
 508                         case "object_remove":
 509                                 e = sandbox_ObjectEdit_Get(TRUE);
 510                                 if(e != world)
 511                                 {
 512                                         if(autocvar_g_sandbox_info > 0)
 513                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " removed an object at origin ^3", vtos(e.origin), "\n"));
 514                                         sandbox_ObjectRemove(e);
 515                                         return TRUE;
 516                                 }
 517
 518                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be removed. Make sure you are facing an object that you have edit rights over");
 519                                 return TRUE;
 520
 521                         // ---------------- COMMAND: OBJECT, DUPLICATE ----------------
 522                         case "object_duplicate":
 523                                 switch(argv(2))
 524                                 {
 525                                         case "copy":
 526                                                 // copies customizable properties of the selected object to the clipboard cvar
 527                                                 e = sandbox_ObjectEdit_Get(autocvar_g_sandbox_editor_free); // can we copy objects we can't edit?
 528                                                 if(e != world)
 529                                                 {
 530                                                         s = sandbox_ObjectPort_Save(e, FALSE);
 531                                                         s = strreplace("\"", "\\\"", s);
 532                                                         stuffcmd(self, strcat("set ", argv(3), " \"", s, "\""));
 533
 534                                                         print_to(self, "^2SANDBOX - INFO: ^7Object copied to clipboard");
 535                                                         return TRUE;
 536                                                 }
 537                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be copied. Make sure you are facing an object that you have copy rights over");
 538                                                 return TRUE;
 539
 540                                         case "paste":
 541                                                 // spawns a new object using the properties in the player's clipboard cvar
 542                                                 if(time < self.object_flood)
 543                                                 {
 544                                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Flood protection active. Please wait ^3", ftos(self.object_flood - time), " ^7seconds beofore spawning another object"));
 545                                                         return TRUE;
 546                                                 }
 547                                                 self.object_flood = time + autocvar_g_sandbox_editor_flood;
 548                                                 if(!argv(3)) // no object in clipboard
 549                                                 {
 550                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object in clipboard. You must copy an object before you can paste it");
 551                                                         return TRUE;
 552                                                 }
 553                                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 554                                                 {
 555                                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 556                                                         return TRUE;
 557                                                 }
 558                                                 e = sandbox_ObjectPort_Load(argv(3), FALSE);
 559
 560                                                 print_to(self, "^2SANDBOX - INFO: ^7Object pasted successfully");
 561                                                 if(autocvar_g_sandbox_info > 0)
 562                                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " pasted an object at origin ^3", vtos(e.origin), "\n"));
 563                                                 return TRUE;
 564                                 }
 565                                 return TRUE;
 566
 567                         // ---------------- COMMAND: OBJECT, ATTACH ----------------
 568                         case "object_attach":
 569                                 switch(argv(2))
 570                                 {
 571                                         case "get":
 572                                                 // select e as the object as meant to be attached
 573                                                 e = sandbox_ObjectEdit_Get(TRUE);
 574                                                 if(e != world)
 575                                                 {
 576                                                         self.object_attach = e;
 577                                                         print_to(self, "^2SANDBOX - INFO: ^7Object selected for attachment");
 578                                                         return TRUE;
 579                                                 }
 580                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be selected for attachment. Make sure you are facing an object that you have edit rights over");
 581                                                 return TRUE;
 582                                         case "set":
 583                                                 if(self.object_attach == world)
 584                                                 {
 585                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object selected for attachment. Please select an object to be attached first.");
 586                                                         return TRUE;
 587                                                 }
 588
 589                                                 // attaches the previously selected object to e
 590                                                 e = sandbox_ObjectEdit_Get(TRUE);
 591                                                 if(e != world)
 592                                                 {
 593                                                         sandbox_ObjectAttach_Set(self.object_attach, e, argv(3));
 594                                                         self.object_attach = world; // object was attached, no longer keep it scheduled for attachment
 595                                                         print_to(self, "^2SANDBOX - INFO: ^7Object attached successfully");
 596                                                         if(autocvar_g_sandbox_info > 1)
 597                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " attached objects at origin ^3", vtos(e.origin), "\n"));
 598                                                         return TRUE;
 599                                                 }
 600                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be attached to the parent. Make sure you are facing an object that you have edit rights over");
 601                                                 return TRUE;
 602                                         case "remove":
 603                                                 // removes e if it was attached
 604                                                 e = sandbox_ObjectEdit_Get(TRUE);
 605                                                 if(e != world)
 606                                                 {
 607                                                         sandbox_ObjectAttach_Remove(e);
 608                                                         print_to(self, "^2SANDBOX - INFO: ^7Child objects detached successfully");
 609                                                         if(autocvar_g_sandbox_info > 1)
 610                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " detached objects at origin ^3", vtos(e.origin), "\n"));
 611                                                         return TRUE;
 612                                                 }
 613                                                 print_to(self, "^1SANDBOX - WARNING: ^7Child objects could not be detached. Make sure you are facing an object that you have edit rights over");
 614                                                 return TRUE;
 615                                 }
 616                                 return TRUE;
 617
 618                         // ---------------- COMMAND: OBJECT, EDIT ----------------
 619                         case "object_edit":
 620                                 if(!argv(2))
 621                                 {
 622                                         print_to(self, "^1SANDBOX - WARNING: ^7Too few parameters. You must specify a property to edit");
 623                                         return TRUE;
 624                                 }
 625
 626                                 e = sandbox_ObjectEdit_Get(TRUE);
 627                                 if(e != world)
 628                                 {
 629                                         switch(argv(2))
 630                                         {
 631                                                 case "skin":
 632                                                         e.skin = stof(argv(3));
 633                                                         break;
 634                                                 case "alpha":
 635                                                         e.alpha = stof(argv(3));
 636                                                         break;
 637                                                 case "color_main":
 638                                                         e.colormod = stov(argv(3));
 639                                                         break;
 640                                                 case "color_glow":
 641                                                         e.glowmod = stov(argv(3));
 642                                                         break;
 643                                                 case "frame":
 644                                                         e.frame = stof(argv(3));
 645                                                         break;
 646                                                 case "scale":
 647                                                         sandbox_ObjectEdit_Scale(e, stof(argv(3)));
 648                                                         break;
 649                                                 case "solidity":
 650                                                         switch(argv(3))
 651                                                         {
 652                                                                 case "0": // non-solid
 653                                                                         e.solid = SOLID_NOT;
 654                                                                         break;
 655                                                                 case "1": // solid
 656                                                                         e.solid = SOLID_BBOX;
 657                                                                         break;
 658                                                                 default:
 659                                                                         break;
 660                                                         }
 661                                                 case "physics":
 662                                                         switch(argv(3))
 663                                                         {
 664                                                                 case "0": // static
 665                                                                         e.movetype = MOVETYPE_NONE;
 666                                                                         break;
 667                                                                 case "1": // movable
 668                                                                         e.movetype = MOVETYPE_TOSS;
 669                                                                         break;
 670                                                                 case "2": // physical
 671                                                                         e.movetype = MOVETYPE_PHYSICS;
 672                                                                         break;
 673                                                                 default:
 674                                                                         break;
 675                                                         }
 676                                                         break;
 677                                                 case "force":
 678                                                         e.damageforcescale = stof(argv(3));
 679                                                         break;
 680                                                 case "material":
 681                                                         if(e.material)  strunzone(e.material);
 682                                                         if(argv(3))
 683                                                         {
 684                                                                 for (i = 1; i <= 5; i++) // precache material sounds, 5 in total
 685                                                                         precache_sound(strcat("object/impact_", argv(3), "_", ftos(i), ".ogg"));
 686                                                                 e.material = strzone(argv(3));
 687                                                         }
 688                                                         else
 689                                                                 e.material = string_null; // no material
 690                                                         break;
 691                                                 default:
 692                                                         print_to(self, "^1SANDBOX - WARNING: ^7Invalid object property. For usage information, type 'sandbox help'");
 693                                                         return TRUE;
 694                                         }
 695
 696                                         // update last editing time
 697                                         if(e.message2)  strunzone(e.message2);
 698                                         e.message2 = strzone(strftime(TRUE, "%d-%m-%Y %H:%M:%S"));
 699
 700                                         if(autocvar_g_sandbox_info > 1)
 701                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " edited property ^3", argv(2), " ^7of an object at origin ^3", vtos(e.origin), "\n"));
 702                                         return TRUE;
 703                                 }
 704
 705                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be edited. Make sure you are facing an object that you have edit rights over");
 706                                 return TRUE;
 707
 708                         // ---------------- COMMAND: OBJECT, CLAIM ----------------
 709                         case "object_claim":
 710                                 // if the player can edit an object but is not its owner, this can be used to claim that object
 711                                 if(self.crypto_idfp == "")
 712                                 {
 713                                         print_to(self, "^1SANDBOX - WARNING: ^7You do not have a player UID, and cannot claim objects");
 714                                         return TRUE;
 715                                 }
 716                                 e = sandbox_ObjectEdit_Get(TRUE);
 717                                 if(e != world)
 718                                 {
 719                                         // update the owner's name
 720                                         // Do this before checking if you're already the owner and skipping if such, so we
 721                                         // also update the player's nickname if he changed it (but has the same player UID)
 722                                         if(e.netname != self.netname)
 723                                         {
 724                                                 if(e.netname)   strunzone(e.netname);
 725                                                 e.netname = strzone(self.netname);
 726                                                 print_to(self, "^2SANDBOX - INFO: ^7Object owner name updated");
 727                                         }
 728
 729                                         if(e.crypto_idfp == self.crypto_idfp)
 730                                         {
 731                                                 print_to(self, "^2SANDBOX - INFO: ^7Object is already yours, nothing to claim");
 732                                                 return TRUE;
 733                                         }
 734
 735                                         if(e.crypto_idfp)       strunzone(e.crypto_idfp);
 736                                         e.crypto_idfp = strzone(self.crypto_idfp);
 737
 738                                         print_to(self, "^2SANDBOX - INFO: ^7Object claimed successfully");
 739                                 }
 740                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be claimed. Make sure you are facing an object that you have edit rights over");
 741                                 return TRUE;
 742
 743                         // ---------------- COMMAND: OBJECT, INFO ----------------
 744                         case "object_info":
 745                                 // prints public information about the object to the player
 746                                 e = sandbox_ObjectEdit_Get(FALSE);
 747                                 if(e != world)
 748                                 {
 749                                         switch(argv(2))
 750                                         {
 751                                                 case "object":
 752                                                         print_to(self, strcat("^2SANDBOX - INFO: ^7Object is owned by \"^7", e.netname, "^7\", created \"^3", e.message, "^7\", last edited \"^3", e.message2, "^7\""));
 753                                                         return TRUE;
 754                                                 case "mesh":
 755                                                         for(i = 1; gettaginfo(e, i); i++)
 756                                                                 s = strcat(s, "^7\"^5", gettaginfo_name, "^7\", ");
 757                                                         print_to(self, strcat("^2SANDBOX - INFO: ^7Object mesh is \"^3", e.model, "^7\" at animation frame ^3", ftos(e.frame), " ^7containing the following tags: ", s));
 758                                                         return TRUE;
 759                                                 case "attachments":
 760                                                         // this should show the same info as 'mesh' but for attachments
 761                                                         entity head;
 762                                                         for(head = world; (head = find(head, classname, "object")); )
 763                                                         {
 764                                                                 if(head.owner == e)
 765                                                                 {
 766                                                                         ++i; // start from 1
 767                                                                         gettaginfo(e, head.tag_index);
 768                                                                         s = strcat(s, "^1attachment ", ftos(i), "^7 has mesh \"^3", head.model, "^7\" at animation frame ^3", ftos(head.frame));
 769                                                                         s = strcat(s, "^7 and is attached to bone \"^5", gettaginfo_name, "^7\", ");
 770                                                                 }
 771                                                         }
 772                                                         if(i) // object contains attachments
 773                                                                 print_to(self, strcat("^2SANDBOX - INFO: ^7Object contains the following ^1", ftos(i), "^7 attachment(s): ", s));
 774                                                         else
 775                                                                 print_to(self, "^2SANDBOX - INFO: ^7Object contains no attachments");
 776                                                         return TRUE;
 777                                         }
 778                                 }
 779                                 print_to(self, "^1SANDBOX - WARNING: ^7No information could be found. Make sure you are facing an object");
 780                                 return TRUE;
 781
 782                         // ---------------- COMMAND: DEFAULT ----------------
 783                         default:
 784                                 print_to(self, "Invalid command. For usage information, type 'sandbox help'");
 785                                 return TRUE;
 786                 }
 787         }
 788         return FALSE;
 789 }
 790
 791 float autosave_time;
 792 MUTATOR_HOOKFUNCTION(sandbox_StartFrame)
 793 {
 794         if(!autocvar_g_sandbox_storage_autosave)
 795                 return FALSE;
 796         if(time < autosave_time)
 797                 return FALSE;
 798         autosave_time = time + autocvar_g_sandbox_storage_autosave;
 799
 800         sandbox_Database_Save();
 801
 802         return TRUE;
 803 }
 804
 805 MUTATOR_DEFINITION(sandbox)
 806 {
 807         MUTATOR_HOOK(SV_ParseClientCommand, sandbox_PlayerCommand, CBC_ORDER_ANY);
 808         MUTATOR_HOOK(SV_StartFrame, sandbox_StartFrame, CBC_ORDER_ANY);
 809
 810         MUTATOR_ONADD
 811         {
 812                 autosave_time = time + autocvar_g_sandbox_storage_autosave; // don't save the first server frame
 813                 if(autocvar_g_sandbox_storage_autoload)
 814                         sandbox_Database_Load();
 815         }
 816
 817         return FALSE;
 818 }
 819