qcsrc/server/mutators/sandbox.qc

   1 float object_count;
   2 .string object_clipboard;
   3 .entity object_attach;
   4 .string material;
   5
   6 .float touch_timer;
   7 void sandbox_Object_Touch()
   8 {
   9         // apply material impact effects
  10
  11         if(!self.material)
  12                 return;
  13         if(self.touch_timer > time)
  14                 return; // don't execute each frame
  15         self.touch_timer = time + 0.1;
  16
  17         // make particle count and sound volume depend on impact speed
  18         float intensity;
  19         intensity = vlen(self.velocity) + vlen(other.velocity);
  20         if(intensity) // avoid divisions by 0
  21                 intensity /= 2; // average the two velocities
  22         if not(intensity >= autocvar_g_sandbox_object_material_velocity_min)
  23                 return; // impact not strong enough to do anything
  24         // now offset intensity and apply it to the effects
  25         intensity -= autocvar_g_sandbox_object_material_velocity_min; // start from minimum velocity, not actual velocity
  26         intensity = bound(0, intensity * autocvar_g_sandbox_object_material_velocity_factor, 1);
  27
  28         sound(self, CH_TRIGGER, strcat("object/impact_", self.material, "_", ftos(ceil(random() * 5)) , ".ogg"), VOL_BASE * intensity, ATTN_NORM);
  29         pointparticles(particleeffectnum(strcat("impact_", self.material)), self.origin, '0 0 0', ceil(intensity * 10)); // allow a count from 1 to 10
  30 }
  31
  32 entity sandbox_EditObject_Get()
  33 {
  34         // returns the traced entity if the player can edit it, and world if not
  35         // attached objects are SOLID_NOT and don't risk getting traced
  36
  37         makevectors(self.v_angle);
  38         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_edit, MOVE_NORMAL, self);
  39
  40         if(trace_ent.classname != "object")
  41                 return world; // entity is not an object
  42         if(!trace_ent.crypto_idfp)
  43                 return trace_ent; // the player who spawned this object did not have an UID, so anyone can edit it
  44         else if not(trace_ent.crypto_idfp != self.crypto_idfp && !autocvar_g_sandbox_editor_free)
  45                 return trace_ent; // object does not belong to the player, and players can only edit their own objects on this server
  46         return world;
  47 }
  48
  49 void sandbox_EditObject_Scale(entity e, float f)
  50 {
  51         e.scale = f;
  52         if(e.scale)
  53         {
  54                 e.scale = bound(autocvar_g_sandbox_object_scale_min, e.scale, autocvar_g_sandbox_object_scale_max);
  55                 setsize(e, e.mins * e.scale, e.maxs * e.scale); // adapt bounding box size to model size
  56         }
  57 }
  58
  59 .float old_movetype;
  60 void sandbox_AttachObject_Set(entity e, entity parent, string s)
  61 {
  62         // attaches e to parent on string s
  63
  64         e.old_movetype = e.movetype; // persist this
  65
  66         e.movetype = MOVETYPE_FOLLOW;
  67         e.solid = SOLID_NOT;
  68         e.takedamage = DAMAGE_NO;
  69
  70         setattachment(e, parent, s);
  71         e.owner = parent;
  72 }
  73
  74 void sandbox_AttachObject_Remove(entity e)
  75 {
  76         // detaches any object attached to e
  77
  78         entity head;
  79         for(head = world; (head = find(head, classname, "object")); )
  80         {
  81                 if(head.owner == e)
  82                 {
  83                         head.movetype = head.old_movetype; // revert to previous physics
  84                         head.solid = SOLID_BBOX;
  85                         head.takedamage = DAMAGE_AIM;
  86
  87                         setattachment(head, world, "");
  88                         head.owner = world;
  89
  90                         // objects reset origin and angles when detached, so apply the parent's to prevent teleporting
  91                         setorigin(head, e.origin);
  92                         head.angles = e.angles;
  93                 }
  94         }
  95 }
  96
  97 entity sandbox_SpawnObject(float database)
  98 {
  99         // spawn a new object with default properties
 100
 101         entity e;
 102         e = spawn();
 103         e.classname = "object";
 104         e.takedamage = DAMAGE_AIM;
 105         e.damageforcescale = 1;
 106         e.solid = SOLID_BBOX; // SOLID_BSP would be best, but can lag the server badly
 107         e.movetype = MOVETYPE_TOSS;
 108         e.frame = 0;
 109         e.skin = 0;
 110         e.material = string_null;
 111         e.touch = sandbox_Object_Touch;
 112
 113         if(!database)
 114         {
 115                 // set the object's owner via player UID
 116                 // if the player does not have an UID, the owner cannot be stored and his objects may be edited by anyone
 117                 if(self.crypto_idfp != "")
 118                         e.crypto_idfp = strzone(self.crypto_idfp);
 119                 else
 120                         print_to(self, "^1SANDBOX - WARNING: ^7You spawned an object, but lack a player UID. ^1Your objects are not secured and can be edited by any player!");
 121
 122                 // set origin and direction based on player position and view angle
 123                 makevectors(self.v_angle);
 124                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_spawn, MOVE_NORMAL, self);
 125                 setorigin(e, trace_endpos);
 126                 e.angles_y = self.v_angle_y;
 127         }
 128
 129         object_count += 1;
 130         return e;
 131 }
 132
 133 void sandbox_RemoveObject(entity e)
 134 {
 135         sandbox_AttachObject_Remove(e); // detach child objects
 136         if(e.material)
 137         {
 138                 strunzone(e.material);
 139                 e.material = string_null;
 140         }
 141         if(e.crypto_idfp)
 142         {
 143                 strunzone(e.crypto_idfp);
 144                 e.crypto_idfp = string_null;
 145         }
 146         remove(e);
 147         e = world;
 148
 149         object_count -= 1;
 150 }
 151
 152 string sandbox_Storage_Save(entity e, float database)
 153 {
 154         // save object properties
 155         string s;
 156
 157         s = strcat(e.model, " ");
 158         s = strcat(s, ftos(e.skin), " ");
 159         s = strcat(s, ftos(e.alpha), " ");
 160         s = strcat(s, sprintf("\"%.9v\"", e.colormod), " ");
 161         s = strcat(s, sprintf("\"%.9v\"", e.glowmod), " ");
 162         s = strcat(s, ftos(e.frame), " ");
 163         s = strcat(s, ftos(e.scale), " ");
 164         s = strcat(s, ftos(e.movetype), " ");
 165         s = strcat(s, ftos(e.damageforcescale), " ");
 166         s = strcat(s, e.material, " ");
 167         if(database)
 168         {
 169                 s = strcat(s, e.crypto_idfp, " ");
 170                 s = strcat(s, sprintf("\"%.9v\"", e.origin), " ");
 171                 s = strcat(s, sprintf("\"%.9v\"", e.angles), " ");
 172         }
 173
 174         return s;
 175 }
 176
 177 void sandbox_Storage_Load(entity e, string s, float database)
 178 {
 179         // load object properties
 180         tokenize_console(s);
 181
 182         setmodel(e, argv(0));
 183         e.skin = stof(argv(1));
 184         e.alpha = stof(argv(2));
 185         e.colormod = stov(argv(3));
 186         e.glowmod = stov(argv(4));
 187         e.frame = stof(argv(5));
 188         sandbox_EditObject_Scale(e, stof(argv(6)));
 189         e.movetype = stof(argv(7));
 190         e.damageforcescale = stof(argv(8));
 191         if(e.material)  strunzone(e.material);  if(argv(9))     e.material = strzone(argv(9));  else    e.material = string_null;
 192         if(database)
 193         {
 194                 if(e.crypto_idfp)       strunzone(e.crypto_idfp);       if(argv(10))    e.crypto_idfp = strzone(argv(10));      else    e.crypto_idfp = string_null;
 195                 setorigin(e, stov(argv(11)));
 196                 e.angles = stov(argv(12));
 197         }
 198 }
 199
 200 void sandbox_Storage_DatabaseSave()
 201 {
 202         // saves all objects to the database file
 203         if(!object_count)
 204                 return; // nothing to store
 205
 206         entity head;
 207         string fn;
 208         float fh, i;
 209
 210         fn = strcat("sandbox/storage_", GetMapname(), ".txt");
 211         fh = fopen(fn, FILE_WRITE);
 212         fputs(fh, strcat("// sandbox storage for map ", GetMapname(), ", containing a total of ", ftos(object_count), " objects\n"));
 213         i = 1;
 214         for(head = world; (head = find(head, classname, "object")); )
 215         {
 216                 // Unfortunately, attached objects cannot be persisted yet. That's because the parent is specified as an entity,
 217                 // but only properties can be saved to this file, leaving no way to identify the owner once all objects are spawned
 218                 // TODO: Find some way to fix this!
 219                 if(head.owner != world)
 220                         continue;
 221
 222                 // use a line for each object, listing all properties
 223                 fputs(fh, strcat(sandbox_Storage_Save(head, TRUE), "\n"));
 224                 i++;
 225         }
 226         fclose(fh);
 227 }
 228
 229 void sandbox_Storage_DatabaseLoad()
 230 {
 231         // loads all objects from the database file
 232         string fn, rf;
 233         float fh, n;
 234
 235         fn = strcat("sandbox/storage_", GetMapname(), ".txt");
 236         fh = fopen(fn, FILE_READ);
 237         if(fh < 0)
 238                 { } // message comes here
 239         else
 240         {
 241                 for(;;)
 242                 {
 243                         rf = fgets(fh);
 244                         if(!rf)
 245                                 break;
 246                         if(substring(rf, 0, 2) == "//")
 247                                 continue;
 248                         if(substring(rf, 0, 1) == "#")
 249                                 continue;
 250                         dprint(strcat(rf, " --------\n"));
 251                 }
 252         }
 253 }
 254
 255 MUTATOR_HOOKFUNCTION(sandbox_PlayerCommand)
 256 {
 257         if(MUTATOR_RETURNVALUE) // command was already handled?
 258                 return FALSE;
 259         if(cmd_name == "g_sandbox")
 260         {
 261 sandbox_Storage_DatabaseLoad();
 262                 if(cmd_argc < 2)
 263                 {
 264                         print_to(self, "Sandbox mode is active. For usage information, type 'sandbox help'");
 265                         return TRUE;
 266                 }
 267
 268                 switch(argv(1))
 269                 {
 270                         entity e;
 271                         float i;
 272
 273                         // ---------------- COMMAND: HELP ----------------
 274                         case "help":
 275                                 print_to(self, "You can use the following sandbox commands:");
 276                                 print_to(self, "^7\"^2object_spawn ^3models/foo/bar.md3^7\" spawns a new object in front of the player, and gives it the specified model");
 277                                 print_to(self, "^7\"^2object_remove^7\" removes the object the player is looking at. Players can only remove their own objects");
 278                                 print_to(self, "^7\"^2object_duplicate ^3value^7\" duplicates the object. 'copy' copies the object, 'paste' puts it in front of the player");
 279                                 print_to(self, "^7\"^2object_claim^7\" sets the player as the owner of the object, if he has the right to edit it");
 280                                 print_to(self, "^7\"^2object_attach ^3property value^7\" attaches one object to another. Players can only attach their own objects");
 281                                 print_to(self, "^7Attachment properties for ^2object_attach^7:");
 282                                 print_to(self, "^3get ^7- selects the object you are facing as the object to be attached");
 283                                 print_to(self, "^3set value ^7- attaches the previously selected object to the object you are facing, on the specified bone");
 284                                 print_to(self, "^3remove ^7- detaches all objects from the object you are facing");
 285                                 print_to(self, "^7\"^2object_edit ^3property value^7\" edits the given property of the object. Players can only edit their own objects");
 286                                 print_to(self, "^7Object properties for ^2object_edit^7:");
 287                                 print_to(self, "^3skin value ^7- changes the skin of the object");
 288                                 print_to(self, "^3alpha value ^7- sets object transparency");
 289                                 print_to(self, "^3colormod \"value_x value_y value_z\" ^7- main object color");
 290                                 print_to(self, "^3glowmod \"value_x value_y value_z\" ^7- glow object color");
 291                                 print_to(self, "^3frame value ^7- object animation frame, for self-animated models");
 292                                 print_to(self, "^3scale value ^7- changes object scale. 0.5 is half size and 2 is double size");
 293                                 print_to(self, "^3physics value ^7- object physics, 0 = static, 1 = movable, 2 = physical");
 294                                 print_to(self, "^3force value ^7- amount of force applied to objects that are shot");
 295                                 print_to(self, "^3material value ^7- sets the material of the object. Default materials are: metal, stone, wood, flesh");
 296                                 print_to(self, "^7The ^1drag object ^7key can be used to grab and carry objects. Players can only grab their own objects");
 297                                 return TRUE;
 298
 299                         // ---------------- COMMAND: SPAWN OBJECT ----------------
 300                         case "object_spawn":
 301                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 302                                 {
 303                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 304                                         return TRUE;
 305                                 }
 306                                 if(cmd_argc < 3)
 307                                 {
 308                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object without specifying a model. Please specify the path to your model file after the 'object_spawn' command");
 309                                         return TRUE;
 310                                 }
 311                                 else if not(fexists(argv(2)))
 312                                 {
 313                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object with a non-existent model. Make sure the path to your model file is correct");
 314                                         return TRUE;
 315                                 }
 316
 317                                 e = sandbox_SpawnObject(FALSE);
 318                                 setmodel(e, argv(2));
 319
 320                                 if(autocvar_g_sandbox_info > 0)
 321                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " spawned an object at origin ^3", vtos(e.origin), "\n"));
 322                                 return TRUE;
 323
 324                         // ---------------- COMMAND: REMOVE OBJECT ----------------
 325                         case "object_remove":
 326                                 e = sandbox_EditObject_Get();
 327                                 if(e != world)
 328                                 {
 329                                         if(autocvar_g_sandbox_info > 0)
 330                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " removed an object at origin ^3", vtos(e.origin), "\n"));
 331                                         sandbox_RemoveObject(e);
 332                                         return TRUE;
 333                                 }
 334
 335                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be removed. Make sure you are facing an object that you have edit rights over");
 336                                 return TRUE;
 337
 338                         // ---------------- COMMAND: DUPLICATE OBJECT ----------------
 339                         case "object_duplicate":
 340                                 switch(argv(2))
 341                                 {
 342                                         case "copy":
 343                                                 // copies customizable properties of the selected object to the clipboard
 344                                                 e = sandbox_EditObject_Get(); // you can only copy objects you can edit, so this works
 345                                                 if(e != world)
 346                                                 {
 347                                                         if(self.object_clipboard)
 348                                                                 strunzone(self.object_clipboard);
 349                                                         self.object_clipboard = strzone(sandbox_Storage_Save(e, FALSE));
 350
 351                                                         print_to(self, "^2SANDBOX - INFO: ^7Object copied to clipboard");
 352                                                         return TRUE;
 353                                                 }
 354                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be copied. Make sure you are facing an object that you have edit rights over");
 355                                                 return TRUE;
 356
 357                                         case "paste":
 358                                                 // spawns a new object using the properties in the player's clipboard
 359                                                 if(!self.object_clipboard) // no object in clipboard
 360                                                 {
 361                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object in clipboard. You must copy an object before you can paste it");
 362                                                         return TRUE;
 363                                                 }
 364                                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 365                                                 {
 366                                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 367                                                         return TRUE;
 368                                                 }
 369
 370                                                 e = sandbox_SpawnObject(FALSE);
 371                                                 sandbox_Storage_Load(e, self.object_clipboard, FALSE);
 372
 373                                                 print_to(self, "^2SANDBOX - INFO: ^7Object pasted successfully");
 374                                                 if(autocvar_g_sandbox_info > 0)
 375                                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " pasted an object at origin ^3", vtos(e.origin), "\n"));
 376                                                 return TRUE;
 377                                 }
 378                                 return TRUE;
 379
 380                         // ---------------- COMMAND: CLAIM OBJECT ----------------
 381                         case "object_claim":
 382                                 // if the player can edit an object but is not its owner, this can be used to claim that object
 383                                 if(self.crypto_idfp == "")
 384                                 {
 385                                         print_to(self, "^1SANDBOX - WARNING: ^7You do not have a player UID, and cannot claim objects");
 386                                         return TRUE;
 387                                 }
 388                                 e = sandbox_EditObject_Get();
 389                                 if(e != world)
 390                                 {
 391                                         if(e.crypto_idfp == self.crypto_idfp)
 392                                         {
 393                                                 print_to(self, "^2SANDBOX - INFO: ^7Object is already yours, nothing to claim");
 394                                                 return TRUE;
 395                                         }
 396
 397                                         if(e.crypto_idfp)
 398                                                 strunzone(e.crypto_idfp);
 399                                         e.crypto_idfp = self.crypto_idfp;
 400                                         print_to(self, "^2SANDBOX - INFO: ^7Object claimed successfully");
 401                                 }
 402                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be claimed. Make sure you are facing an object that you have edit rights over");
 403                                 return TRUE;
 404
 405                         // ---------------- COMMAND: ATTACH OBJECT ----------------
 406                         case "object_attach":
 407                                 switch(argv(2))
 408                                 {
 409                                         case "get":
 410                                                 // select e as the object as meant to be attached
 411                                                 e = sandbox_EditObject_Get();
 412                                                 if(e != world)
 413                                                 {
 414                                                         self.object_attach = e;
 415                                                         print_to(self, "^2SANDBOX - INFO: ^7Object selected for attachment");
 416                                                         return TRUE;
 417                                                 }
 418                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be selected for attachment. Make sure you are facing an object that you have edit rights over");
 419                                                 return TRUE;
 420                                         case "set":
 421                                                 if(self.object_attach == world)
 422                                                 {
 423                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object selected for attachment. Please select an object to be attached first.");
 424                                                         return TRUE;
 425                                                 }
 426
 427                                                 // attaches the previously selected object to e
 428                                                 e = sandbox_EditObject_Get();
 429                                                 if(e != world)
 430                                                 {
 431                                                         sandbox_AttachObject_Set(self.object_attach, e, argv(3));
 432                                                         self.object_attach = world; // object was attached, no longer keep it scheduled for attachment
 433                                                         print_to(self, "^2SANDBOX - INFO: ^7Object attached successfully");
 434                                                         if(autocvar_g_sandbox_info > 1)
 435                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " attached objects at origin ^3", vtos(e.origin), "\n"));
 436                                                         return TRUE;
 437                                                 }
 438                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be attached to the parent. Make sure you are facing an object that you have edit rights over");
 439                                                 return TRUE;
 440                                         case "remove":
 441                                                 // removes e if it was attached
 442                                                 e = sandbox_EditObject_Get();
 443                                                 if(e != world)
 444                                                 {
 445                                                         sandbox_AttachObject_Remove(e);
 446                                                         print_to(self, "^2SANDBOX - INFO: ^7Child objects detached successfully");
 447                                                         if(autocvar_g_sandbox_info > 1)
 448                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " detached objects at origin ^3", vtos(e.origin), "\n"));
 449                                                         return TRUE;
 450                                                 }
 451                                                 print_to(self, "^1SANDBOX - WARNING: ^7Child objects could not be detached. Make sure you are facing an object that you have edit rights over");
 452                                                 return TRUE;
 453                                 }
 454                                 return TRUE;
 455
 456                         // ---------------- COMMAND: EDIT OBJECT ----------------
 457                         case "object_edit":
 458                                 if(!argv(2))
 459                                 {
 460                                         print_to(self, "^1SANDBOX - WARNING: ^7Too few parameters. You must specify a property to edit");
 461                                         return TRUE;
 462                                 }
 463
 464                                 e = sandbox_EditObject_Get();
 465                                 if(e != world)
 466                                 {
 467                                         switch(argv(2))
 468                                         {
 469                                                 case "skin":
 470                                                         e.skin = stof(argv(3));
 471                                                         break;
 472                                                 case "alpha":
 473                                                         e.alpha = stof(argv(3));
 474                                                         break;
 475                                                 case "color_main":
 476                                                         e.colormod = stov(argv(3));
 477                                                         break;
 478                                                 case "color_glow":
 479                                                         e.glowmod = stov(argv(3));
 480                                                         break;
 481                                                 case "frame":
 482                                                         e.frame = stof(argv(3));
 483                                                         break;
 484                                                 case "scale":
 485                                                         sandbox_EditObject_Scale(e, stof(argv(3)));
 486                                                         break;
 487                                                 case "physics":
 488                                                         switch(argv(3))
 489                                                         {
 490                                                                 case "0": // static
 491                                                                         e.movetype = MOVETYPE_NONE;
 492                                                                         break;
 493                                                                 case "1": // movable
 494                                                                         e.movetype = MOVETYPE_TOSS;
 495                                                                         break;
 496                                                                 case "2": // physical
 497                                                                         e.movetype = MOVETYPE_PHYSICS;
 498                                                                         break;
 499                                                                 default:
 500                                                                         break;
 501                                                         }
 502                                                         break;
 503                                                 case "force":
 504                                                         e.damageforcescale = stof(argv(3));
 505                                                         break;
 506                                                 case "material":
 507                                                         if(e.material)
 508                                                                 strunzone(e.material);
 509                                                         if(argv(3))
 510                                                         {
 511                                                                 for (i = 1; i <= 5; i++) // precache material sounds, 5 in total
 512                                                                         precache_sound(strcat("object/impact_", argv(3), "_", ftos(i), ".ogg"));
 513                                                                 e.material = strzone(argv(3));
 514                                                         }
 515                                                         else
 516                                                                 e.material = string_null; // no material
 517                                                         break;
 518                                                 default:
 519                                                         print_to(self, "^1SANDBOX - WARNING: ^7Invalid object property. For usage information, type 'sandbox help'");
 520                                                         break;
 521                                         }
 522                                         if(autocvar_g_sandbox_info > 1)
 523                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " edited property ^3", argv(2), " ^7of an object at origin ^3", vtos(e.origin), "\n"));
 524                                         return TRUE;
 525                                 }
 526
 527                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be edited. Make sure you are facing an object that you have edit rights over");
 528                                 return TRUE;
 529
 530                         // ---------------- COMMAND: DEFAULT ----------------
 531                         default:
 532                                 print_to(self, "Invalid command. For usage information, type 'sandbox help'");
 533                                 return TRUE;
 534                 }
 535         }
 536         return FALSE;
 537 }
 538
 539 MUTATOR_HOOKFUNCTION(sandbox_PlayerPreThink)
 540 {
 541         // if the player is close enough to their object, they can drag it
 542
 543         if(autocvar_sv_cheats)
 544                 return FALSE; // cheat dragging is used instead
 545
 546         // grab is TRUE if the object can be picked up. While an object is being carried, the Drag() function
 547         // must execute for it either way, otherwise it would cause bugs if it went out of the player's trace.
 548         // This also makes sure that an object can only pe picked up if in range, but does not get dropped if
 549         // it goes out of range while slinging it around.
 550
 551         entity e;
 552         float grab;
 553
 554         e = sandbox_EditObject_Get();
 555         if(e != world && vlen(e.origin - self.origin) <= autocvar_g_sandbox_editor_distance_edit)
 556                 grab = TRUE;
 557
 558         if(Drag(e, grab)) // execute dragging
 559                 return TRUE;
 560
 561         return FALSE;
 562 }
 563
 564 MUTATOR_HOOKFUNCTION(sandbox_ClientDisconnect)
 565 {
 566         // unzone the player's clipboard if it's not empty
 567         if(self.object_clipboard)
 568         {
 569                 strunzone(self.object_clipboard);
 570                 self.object_clipboard = string_null;
 571         }
 572
 573         return FALSE;
 574 }
 575
 576 float autosave_time;
 577 MUTATOR_HOOKFUNCTION(sandbox_StartFrame)
 578 {
 579         if(!autocvar_g_sandbox_storage_autosave)
 580                 return FALSE;
 581         if(time < autocvar_g_sandbox_storage_autosave)
 582                 return FALSE;
 583         autosave_time = time + autocvar_g_sandbox_storage_autosave;
 584
 585         sandbox_Storage_DatabaseSave();
 586
 587         return TRUE;
 588 }
 589
 590 MUTATOR_DEFINITION(sandbox)
 591 {
 592         MUTATOR_HOOK(SV_ParseClientCommand, sandbox_PlayerCommand, CBC_ORDER_ANY);
 593         MUTATOR_HOOK(SV_StartFrame, sandbox_StartFrame, CBC_ORDER_ANY);
 594         MUTATOR_HOOK(PlayerPreThink, sandbox_PlayerPreThink, CBC_ORDER_ANY);
 595         MUTATOR_HOOK(ClientDisconnect, sandbox_ClientDisconnect, CBC_ORDER_ANY);
 596
 597         MUTATOR_ONADD
 598         {
 599                 if(autocvar_g_sandbox_storage_autoload)
 600                         sandbox_Storage_DatabaseLoad();
 601         }
 602
 603         return FALSE;
 604 }
 605