qcsrc/server/mutators/sandbox.qc

   1 const float MAX_STORAGE_ATTACHMENTS = 16;
   2 float object_count;
   3 .float object_flood;
   4 .entity object_attach;
   5 .string material;
   6
   7 .float touch_timer;
   8 void sandbox_ObjectFunction_Touch()
   9 {
  10         // apply material impact effects
  11
  12         if(!self.material)
  13                 return;
  14         if(self.touch_timer > time)
  15                 return; // don't execute each frame
  16         self.touch_timer = time + 0.1;
  17
  18         // make particle count and sound volume depend on impact speed
  19         float intensity;
  20         intensity = vlen(self.velocity) + vlen(other.velocity);
  21         if(intensity) // avoid divisions by 0
  22                 intensity /= 2; // average the two velocities
  23         if not(intensity >= autocvar_g_sandbox_object_material_velocity_min)
  24                 return; // impact not strong enough to do anything
  25         // now offset intensity and apply it to the effects
  26         intensity -= autocvar_g_sandbox_object_material_velocity_min; // start from minimum velocity, not actual velocity
  27         intensity = bound(0, intensity * autocvar_g_sandbox_object_material_velocity_factor, 1);
  28
  29         sound(self, CH_TRIGGER, strcat("object/impact_", self.material, "_", ftos(ceil(random() * 5)) , ".ogg"), VOL_BASE * intensity, ATTN_NORM);
  30         pointparticles(particleeffectnum(strcat("impact_", self.material)), self.origin, '0 0 0', ceil(intensity * 10)); // allow a count from 1 to 10
  31 }
  32
  33 void sandbox_ObjectFunction_Think()
  34 {
  35         entity e;
  36
  37         // decide if and how this object can be grabbed
  38         if(autocvar_g_sandbox_readonly)
  39                 self.grab = 0; // no grabbing
  40         else if(autocvar_g_sandbox_editor_free < 2 && self.crypto_idfp)
  41                 self.grab = 1; // owner only
  42         else
  43                 self.grab = 3; // anyone
  44
  45         // Object owner is stored via player UID, but we also need the owner as an entity (if the player is available on the server).
  46         // Therefore, scan for all players, and update the owner as long as the player is present. We must always do this,
  47         // since if the owning player disconnects, the object's owner should also be reset.
  48         FOR_EACH_REALPLAYER(e) // bots can't have objects
  49         {
  50                 if(self.crypto_idfp == e.crypto_idfp)
  51                 {
  52                         self.realowner = e;
  53                         break;
  54                 }
  55                 self.realowner = world;
  56         }
  57
  58         self.nextthink = time;
  59 }
  60
  61 .float old_solid, old_movetype;
  62 entity sandbox_ObjectEdit_Get(float permissions)
  63 {
  64         // returns the traced entity if the player can edit it, and world if not
  65         // if permissions if FALSE, the object is returned regardless of editing rights
  66
  67         // Tracing does not work for entities that use SOLID_NOT or SOLID_TRIGGER. Therefore, make all
  68         // objects temporarily solid while doing the trace, then revert them to their initial solidity.
  69         entity head;
  70         for(head = world; (head = find(head, classname, "object")); )
  71         {
  72                 if(head.owner == world) // skip attached objects
  73                 {
  74                         head.old_solid = head.solid;
  75                         head.solid = SOLID_BBOX;
  76                 }
  77         }
  78         makevectors(self.v_angle);
  79         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_edit, MOVE_NORMAL, self);
  80         for(head = world; (head = find(head, classname, "object")); )
  81         {
  82                 if(head.owner == world) // skip attached objects
  83                         head.solid = head.old_solid;
  84         }
  85
  86         if(trace_ent.classname != "object")
  87                 return world; // entity is not an object
  88         if(trace_ent.owner != world)
  89                 return world; // entity is an attached object
  90         if(!permissions)
  91                 return trace_ent; // don't check permissions, anyone can edit this object
  92         if(!trace_ent.crypto_idfp)
  93                 return trace_ent; // the player who spawned this object did not have an UID, so anyone can edit it
  94         if not(trace_ent.realowner != self && autocvar_g_sandbox_editor_free < 2)
  95                 return trace_ent; // object does not belong to the player, and players can only edit their own objects on this server
  96         return world;
  97 }
  98
  99 void sandbox_ObjectEdit_Scale(entity e, float f)
 100 {
 101         e.scale = f;
 102         if(e.scale)
 103         {
 104                 e.scale = bound(autocvar_g_sandbox_object_scale_min, e.scale, autocvar_g_sandbox_object_scale_max);
 105                 setmodel(e, e.model); // reset mins and maxs based on mesh
 106                 setsize(e, e.mins * e.scale, e.maxs * e.scale); // adapt bounding box size to model size
 107         }
 108 }
 109
 110 void sandbox_ObjectAttach_Remove(entity e);
 111 void sandbox_ObjectAttach_Set(entity e, entity parent, string s)
 112 {
 113         // attaches e to parent on string s
 114
 115         // we can't attach to an attachment, for obvious reasons
 116         sandbox_ObjectAttach_Remove(e);
 117
 118         e.old_solid = e.solid; // persist solidity
 119         e.old_movetype = e.movetype; // persist physics
 120         e.movetype = MOVETYPE_FOLLOW;
 121         e.solid = SOLID_NOT;
 122         e.takedamage = DAMAGE_NO;
 123
 124         setattachment(e, parent, s);
 125         e.owner = parent;
 126 }
 127
 128 void sandbox_ObjectAttach_Remove(entity e)
 129 {
 130         // detaches any object attached to e
 131
 132         entity head;
 133         for(head = world; (head = find(head, classname, "object")); )
 134         {
 135                 if(head.owner == e)
 136                 {
 137                         vector org;
 138                         org = gettaginfo(head, 0);
 139                         setattachment(head, world, "");
 140                         head.owner = world;
 141
 142                         // objects change origin and angles when detached, so apply previous position
 143                         setorigin(head, org);
 144                         head.angles = e.angles; // don't allow detached objects to spin or roll
 145
 146                         head.solid = head.old_solid; // restore persisted solidity
 147                         head.movetype = head.old_movetype; // restore persisted physics
 148                         head.takedamage = DAMAGE_AIM;
 149                 }
 150         }
 151 }
 152
 153 entity sandbox_ObjectSpawn(float database)
 154 {
 155         // spawn a new object with default properties
 156
 157         entity e;
 158         e = spawn();
 159         e.classname = "object";
 160         e.takedamage = DAMAGE_AIM;
 161         e.damageforcescale = 1;
 162         e.solid = SOLID_BBOX; // SOLID_BSP would be best, but can lag the server badly
 163         e.movetype = MOVETYPE_TOSS;
 164         e.frame = 0;
 165         e.skin = 0;
 166         e.material = string_null;
 167         e.touch = sandbox_ObjectFunction_Touch;
 168         e.think = sandbox_ObjectFunction_Think;
 169         e.nextthink = time;
 170         //e.effects |= EF_SELECTABLE; // don't do this all the time, maybe just when editing objects?
 171
 172         if(!database)
 173         {
 174                 // set the object's owner via player UID
 175                 // if the player does not have an UID, the owner cannot be stored and his objects may be edited by anyone
 176                 if(self.crypto_idfp != "")
 177                         e.crypto_idfp = strzone(self.crypto_idfp);
 178                 else
 179                         print_to(self, "^1SANDBOX - WARNING: ^7You spawned an object, but lack a player UID. ^1Your objects are not secured and can be edited by any player!");
 180
 181                 // set public object information
 182                 e.netname = strzone(self.netname); // name of the owner
 183                 e.message = strzone(strftime(TRUE, "%d-%m-%Y %H:%M:%S")); // creation time
 184                 e.message2 = strzone(strftime(TRUE, "%d-%m-%Y %H:%M:%S")); // last editing time
 185
 186                 // set origin and direction based on player position and view angle
 187                 makevectors(self.v_angle);
 188                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_spawn, MOVE_NORMAL, self);
 189                 setorigin(e, trace_endpos);
 190                 e.angles_y = self.v_angle_y;
 191         }
 192
 193         object_count += 1;
 194         return e;
 195 }
 196
 197 void sandbox_ObjectRemove(entity e)
 198 {
 199         sandbox_ObjectAttach_Remove(e); // detach child objects
 200
 201         if(e.material)  {       strunzone(e.material);  e.material = string_null;       }
 202         if(e.crypto_idfp)       {       strunzone(e.crypto_idfp);       e.crypto_idfp = string_null;    }
 203         if(e.netname)   {       strunzone(e.netname);   e.netname = string_null;        }
 204         if(e.message)   {       strunzone(e.message);   e.message = string_null;        }
 205         if(e.message2)  {       strunzone(e.message2);  e.message2 = string_null;       }
 206         remove(e);
 207         e = world;
 208
 209         object_count -= 1;
 210 }
 211
 212 string port_string[MAX_STORAGE_ATTACHMENTS]; // fteqcc crashes if this isn't defined as a global
 213
 214 string sandbox_ObjectPort_Save(entity e, float database)
 215 {
 216         // save object properties, and return them as a string
 217         float i;
 218         string s;
 219         entity head;
 220
 221         for(head = world; (head = find(head, classname, "object")); )
 222         {
 223                 // the main object needs to be first in the array [0] with attached objects following
 224                 float slot, physics, solidity;
 225                 if(head == e) // this is the main object, place it first
 226                 {
 227                         slot = 0;
 228                         solidity = head.solid; // applied solidity is normal solidity for children
 229                         physics = head.movetype; // applied physics are normal physics for parents
 230                 }
 231                 else if(head.owner == e) // child object, list them in order
 232                 {
 233                         i += 1; // children start from 1
 234                         slot = i;
 235                         solidity = head.old_solid; // persisted solidity is normal solidity for children
 236                         physics = head.old_movetype; // persisted physics are normal physics for children
 237                         gettaginfo(head.owner, head.tag_index); // get the name of the tag our object is attached to, used further below
 238                 }
 239                 else
 240                         continue;
 241
 242                 // ---------------- OBJECT PROPERTY STORAGE: SAVE ----------------
 243                 if(slot)
 244                 {
 245                         // properties stored only for child objects
 246                         if(gettaginfo_name)     port_string[slot] = strcat(port_string[slot], "\"", gettaginfo_name, "\" ");    else    port_string[slot] = strcat(port_string[slot], "- "); // none
 247                 }
 248                 else
 249                 {
 250                         // properties stored only for parent objects
 251                         if(database)
 252                         {
 253                                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.origin), " ");
 254                                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.angles), " ");
 255                         }
 256                 }
 257                 // properties stored for all objects
 258                 port_string[slot] = strcat(port_string[slot], "\"", head.model, "\" ");
 259                 port_string[slot] = strcat(port_string[slot], ftos(head.skin), " ");
 260                 port_string[slot] = strcat(port_string[slot], ftos(head.alpha), " ");
 261                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.colormod), " ");
 262                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.glowmod), " ");
 263                 port_string[slot] = strcat(port_string[slot], ftos(head.frame), " ");
 264                 port_string[slot] = strcat(port_string[slot], ftos(head.scale), " ");
 265                 port_string[slot] = strcat(port_string[slot], ftos(solidity), " ");
 266                 port_string[slot] = strcat(port_string[slot], ftos(physics), " ");
 267                 port_string[slot] = strcat(port_string[slot], ftos(head.damageforcescale), " ");
 268                 if(head.material)       port_string[slot] = strcat(port_string[slot], "\"", head.material, "\" ");      else    port_string[slot] = strcat(port_string[slot], "- "); // none
 269                 if(database)
 270                 {
 271                         // properties stored only for the database
 272                         if(head.crypto_idfp)    port_string[slot] = strcat(port_string[slot], "\"", head.crypto_idfp, "\" ");   else    port_string[slot] = strcat(port_string[slot], "- "); // none
 273                         port_string[slot] = strcat(port_string[slot], "\"", e.netname, "\" ");
 274                         port_string[slot] = strcat(port_string[slot], "\"", e.message, "\" ");
 275                         port_string[slot] = strcat(port_string[slot], "\"", e.message2, "\" ");
 276                 }
 277         }
 278
 279         // now apply the array to a simple string, with the ; symbol separating objects
 280         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 281         {
 282                 if(port_string[i])
 283                         s = strcat(s, port_string[i], "; ");
 284                 port_string[i] = string_null; // fully clear the string
 285         }
 286
 287         return s;
 288 }
 289
 290 entity sandbox_ObjectPort_Load(string s, float database)
 291 {
 292         // load object properties, and spawn a new object with them
 293         float n, i;
 294         entity e, parent;
 295
 296         // separate objects between the ; symbols
 297         n = tokenizebyseparator(s, "; ");
 298         for(i = 0; i < n; ++i)
 299                 port_string[i] = argv(i);
 300
 301         // now separate and apply the properties of each object
 302         for(i = 0; i < n; ++i)
 303         {
 304                 float argv_num;
 305                 string tagname;
 306                 argv_num = 0;
 307                 tokenize_console(port_string[i]);
 308                 e = sandbox_ObjectSpawn(database);
 309
 310                 // ---------------- OBJECT PROPERTY STORAGE: LOAD ----------------
 311                 if(i)
 312                 {
 313                         // properties stored only for child objects
 314                         if(argv(argv_num) != "-")       tagname = argv(argv_num);       else tagname = string_null;     ++argv_num;
 315                 }
 316                 else
 317                 {
 318                         // properties stored only for parent objects
 319                         if(database)
 320                         {
 321                                 setorigin(e, stov(argv(argv_num)));     ++argv_num;
 322                                 e.angles = stov(argv(argv_num));        ++argv_num;
 323                         }
 324                         parent = e; // mark parent objects as such
 325                 }
 326                 // properties stored for all objects
 327                 setmodel(e, argv(argv_num));    ++argv_num;
 328                 e.skin = stof(argv(argv_num));  ++argv_num;
 329                 e.alpha = stof(argv(argv_num)); ++argv_num;
 330                 e.colormod = stov(argv(argv_num));      ++argv_num;
 331                 e.glowmod = stov(argv(argv_num));       ++argv_num;
 332                 e.frame = stof(argv(argv_num)); ++argv_num;
 333                 sandbox_ObjectEdit_Scale(e, stof(argv(argv_num)));      ++argv_num;
 334                 e.solid = e.old_solid = stof(argv(argv_num));   ++argv_num;
 335                 e.movetype = e.old_movetype = stof(argv(argv_num));     ++argv_num;
 336                 e.damageforcescale = stof(argv(argv_num));      ++argv_num;
 337                 if(e.material)  strunzone(e.material);  if(argv(argv_num) != "-")       e.material = strzone(argv(argv_num));   else    e.material = string_null;       ++argv_num;
 338                 if(database)
 339                 {
 340                         // properties stored only for the database
 341                         if(e.crypto_idfp)       strunzone(e.crypto_idfp);       if(argv(argv_num) != "-")       e.crypto_idfp = strzone(argv(argv_num));        else    e.crypto_idfp = string_null;    ++argv_num;
 342                         if(e.netname)   strunzone(e.netname);   e.netname = strzone(argv(argv_num));    ++argv_num;
 343                         if(e.message)   strunzone(e.message);   e.message = strzone(argv(argv_num));    ++argv_num;
 344                         if(e.message2)  strunzone(e.message2);  e.message2 = strzone(argv(argv_num));   ++argv_num;
 345                 }
 346
 347                 // attach last
 348                 if(i)
 349                         sandbox_ObjectAttach_Set(e, parent, tagname);
 350         }
 351
 352         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 353                 port_string[i] = string_null; // fully clear the string
 354
 355         return e;
 356 }
 357
 358 void sandbox_Database_Save()
 359 {
 360         // saves all objects to the database file
 361         entity head;
 362         string file_name;
 363         float file_get;
 364
 365         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 366         file_get = fopen(file_name, FILE_WRITE);
 367         fputs(file_get, strcat("// sandbox storage \"", autocvar_g_sandbox_storage_name, "\" for map \"", GetMapname(), "\" last updated ", strftime(TRUE, "%d-%m-%Y %H:%M:%S")));
 368         fputs(file_get, strcat(" containing ", ftos(object_count), " objects\n"));
 369
 370         for(head = world; (head = find(head, classname, "object")); )
 371         {
 372                 // attached objects are persisted separately, ignore them here
 373                 if(head.owner != world)
 374                         continue;
 375
 376                 // use a line of text for each object, listing all properties
 377                 fputs(file_get, strcat(sandbox_ObjectPort_Save(head, TRUE), "\n"));
 378         }
 379         fclose(file_get);
 380 }
 381
 382 void sandbox_Database_Load()
 383 {
 384         // loads all objects from the database file
 385         string file_read, file_name;
 386         float file_get, i;
 387
 388         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 389         file_get = fopen(file_name, FILE_READ);
 390         if(file_get < 0)
 391         {
 392                 if(autocvar_g_sandbox_info > 0)
 393                         print(strcat("^3SANDBOX - SERVER: ^7could not find storage file ^3", file_name, "^7, no objects were loaded\n"));
 394         }
 395         else
 396         {
 397                 for(;;)
 398                 {
 399                         file_read = fgets(file_get);
 400                         if(!file_read)
 401                                 break;
 402                         if(substring(file_read, 0, 2) == "//")
 403                                 continue;
 404                         if(substring(file_read, 0, 1) == "#")
 405                                 continue;
 406
 407                         entity e;
 408                         e = sandbox_ObjectPort_Load(file_read, TRUE);
 409
 410                         if(e.material)
 411                         {
 412                                 // since objects are being loaded for the first time, precache material sounds for each
 413                                 for (i = 1; i <= 5; i++) // 5 sounds in total
 414                                         precache_sound(strcat("object/impact_", e.material, "_", ftos(i), ".ogg"));
 415                         }
 416                 }
 417                 if(autocvar_g_sandbox_info > 0)
 418                         print(strcat("^3SANDBOX - SERVER: ^7successfully loaded storage file ^3", file_name, "\n"));
 419         }
 420         fclose(file_get);
 421 }
 422
 423 MUTATOR_HOOKFUNCTION(sandbox_PlayerCommand)
 424 {
 425         if(MUTATOR_RETURNVALUE) // command was already handled?
 426                 return FALSE;
 427         if(cmd_name == "g_sandbox")
 428         {
 429                 if(autocvar_g_sandbox_readonly)
 430                 {
 431                         print_to(self, "^2SANDBOX - INFO: ^7Sandbox mode is active, but in read-only mode. Sandbox commands cannot be used");
 432                         return TRUE;
 433                 }
 434                 if(cmd_argc < 2)
 435                 {
 436                         print_to(self, "^2SANDBOX - INFO: ^7Sandbox mode is active. For usage information, type 'sandbox help'");
 437                         return TRUE;
 438                 }
 439
 440                 switch(argv(1))
 441                 {
 442                         entity e;
 443                         float i;
 444                         string s;
 445
 446                         // ---------------- COMMAND: HELP ----------------
 447                         case "help":
 448                                 print_to(self, "You can use the following sandbox commands:");
 449                                 print_to(self, "^7\"^2object_spawn ^3models/foo/bar.md3^7\" spawns a new object in front of the player, and gives it the specified model");
 450                                 print_to(self, "^7\"^2object_remove^7\" removes the object the player is looking at. Players can only remove their own objects");
 451                                 print_to(self, "^7\"^2object_duplicate ^3value^7\" duplicates the object, if the player has copying rights over the original");
 452                                 print_to(self, "^3copy value ^7- copies the properties of the object to the specified client cvar");
 453                                 print_to(self, "^3paste value ^7- spawns an object with the given properties. Properties or cvars must be specified as follows; eg1: \"0 1 2 ...\", eg2: \"$cl_cvar\"");
 454                                 print_to(self, "^7\"^2object_attach ^3property value^7\" attaches one object to another. Players can only attach their own objects");
 455                                 print_to(self, "^3get ^7- selects the object you are facing as the object to be attached");
 456                                 print_to(self, "^3set value ^7- attaches the previously selected object to the object you are facing, on the specified bone");
 457                                 print_to(self, "^3remove ^7- detaches all objects from the object you are facing");
 458                                 print_to(self, "^7\"^2object_edit ^3property value^7\" edits the given property of the object. Players can only edit their own objects");
 459                                 print_to(self, "^3skin value ^7- changes the skin of the object");
 460                                 print_to(self, "^3alpha value ^7- sets object transparency");
 461                                 print_to(self, "^3colormod \"value_x value_y value_z\" ^7- main object color");
 462                                 print_to(self, "^3glowmod \"value_x value_y value_z\" ^7- glow object color");
 463                                 print_to(self, "^3frame value ^7- object animation frame, for self-animated models");
 464                                 print_to(self, "^3scale value ^7- changes object scale. 0.5 is half size and 2 is double size");
 465                                 print_to(self, "^3solidity value ^7- object collisions, 0 = non-solid, 1 = solid");
 466                                 print_to(self, "^3physics value ^7- object physics, 0 = static, 1 = movable, 2 = physical");
 467                                 print_to(self, "^3force value ^7- amount of force applied to objects that are shot");
 468                                 print_to(self, "^3material value ^7- sets the material of the object. Default materials are: metal, stone, wood, flesh");
 469                                 print_to(self, "^7\"^2object_claim^7\" sets the player as the owner of the object, if he has the right to edit it");
 470                                 print_to(self, "^7\"^2object_info ^3value^7\" shows public information about the object");
 471                                 print_to(self, "^3object ^7- prints general information about the object, such as owner and creation / editing date");
 472                                 print_to(self, "^3mesh ^7- prints information about the object's mesh, including skeletal bones");
 473                                 print_to(self, "^3attachments ^7- prints information about the object's attachments");
 474                                 print_to(self, "^7The ^1drag object ^7key can be used to grab and carry objects. Players can only grab their own objects");
 475                                 return TRUE;
 476
 477                         // ---------------- COMMAND: OBJECT, SPAWN ----------------
 478                         case "object_spawn":
 479                                 if(time < self.object_flood)
 480                                 {
 481                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Flood protection active. Please wait ^3", ftos(self.object_flood - time), " ^7seconds beofore spawning another object"));
 482                                         return TRUE;
 483                                 }
 484                                 self.object_flood = time + autocvar_g_sandbox_editor_flood;
 485                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 486                                 {
 487                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 488                                         return TRUE;
 489                                 }
 490                                 if(cmd_argc < 3)
 491                                 {
 492                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object without specifying a model. Please specify the path to your model file after the 'object_spawn' command");
 493                                         return TRUE;
 494                                 }
 495                                 if not(fexists(argv(2)))
 496                                 {
 497                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object with a non-existent model. Make sure the path to your model file is correct");
 498                                         return TRUE;
 499                                 }
 500
 501                                 e = sandbox_ObjectSpawn(FALSE);
 502                                 setmodel(e, argv(2));
 503
 504                                 if(autocvar_g_sandbox_info > 0)
 505                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " spawned an object at origin ^3", vtos(e.origin), "\n"));
 506                                 return TRUE;
 507
 508                         // ---------------- COMMAND: OBJECT, REMOVE ----------------
 509                         case "object_remove":
 510                                 e = sandbox_ObjectEdit_Get(TRUE);
 511                                 if(e != world)
 512                                 {
 513                                         if(autocvar_g_sandbox_info > 0)
 514                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " removed an object at origin ^3", vtos(e.origin), "\n"));
 515                                         sandbox_ObjectRemove(e);
 516                                         return TRUE;
 517                                 }
 518
 519                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be removed. Make sure you are facing an object that you have edit rights over");
 520                                 return TRUE;
 521
 522                         // ---------------- COMMAND: OBJECT, DUPLICATE ----------------
 523                         case "object_duplicate":
 524                                 switch(argv(2))
 525                                 {
 526                                         case "copy":
 527                                                 // copies customizable properties of the selected object to the clipboard cvar
 528                                                 e = sandbox_ObjectEdit_Get(autocvar_g_sandbox_editor_free); // can we copy objects we can't edit?
 529                                                 if(e != world)
 530                                                 {
 531                                                         s = sandbox_ObjectPort_Save(e, FALSE);
 532                                                         s = strreplace("\"", "\\\"", s);
 533                                                         stuffcmd(self, strcat("set ", argv(3), " \"", s, "\""));
 534
 535                                                         print_to(self, "^2SANDBOX - INFO: ^7Object copied to clipboard");
 536                                                         return TRUE;
 537                                                 }
 538                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be copied. Make sure you are facing an object that you have copy rights over");
 539                                                 return TRUE;
 540
 541                                         case "paste":
 542                                                 // spawns a new object using the properties in the player's clipboard cvar
 543                                                 if(time < self.object_flood)
 544                                                 {
 545                                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Flood protection active. Please wait ^3", ftos(self.object_flood - time), " ^7seconds beofore spawning another object"));
 546                                                         return TRUE;
 547                                                 }
 548                                                 self.object_flood = time + autocvar_g_sandbox_editor_flood;
 549                                                 if(!argv(3)) // no object in clipboard
 550                                                 {
 551                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object in clipboard. You must copy an object before you can paste it");
 552                                                         return TRUE;
 553                                                 }
 554                                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 555                                                 {
 556                                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 557                                                         return TRUE;
 558                                                 }
 559                                                 e = sandbox_ObjectPort_Load(argv(3), FALSE);
 560
 561                                                 print_to(self, "^2SANDBOX - INFO: ^7Object pasted successfully");
 562                                                 if(autocvar_g_sandbox_info > 0)
 563                                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " pasted an object at origin ^3", vtos(e.origin), "\n"));
 564                                                 return TRUE;
 565                                 }
 566                                 return TRUE;
 567
 568                         // ---------------- COMMAND: OBJECT, ATTACH ----------------
 569                         case "object_attach":
 570                                 switch(argv(2))
 571                                 {
 572                                         case "get":
 573                                                 // select e as the object as meant to be attached
 574                                                 e = sandbox_ObjectEdit_Get(TRUE);
 575                                                 if(e != world)
 576                                                 {
 577                                                         self.object_attach = e;
 578                                                         print_to(self, "^2SANDBOX - INFO: ^7Object selected for attachment");
 579                                                         return TRUE;
 580                                                 }
 581                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be selected for attachment. Make sure you are facing an object that you have edit rights over");
 582                                                 return TRUE;
 583                                         case "set":
 584                                                 if(self.object_attach == world)
 585                                                 {
 586                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object selected for attachment. Please select an object to be attached first.");
 587                                                         return TRUE;
 588                                                 }
 589
 590                                                 // attaches the previously selected object to e
 591                                                 e = sandbox_ObjectEdit_Get(TRUE);
 592                                                 if(e != world)
 593                                                 {
 594                                                         sandbox_ObjectAttach_Set(self.object_attach, e, argv(3));
 595                                                         self.object_attach = world; // object was attached, no longer keep it scheduled for attachment
 596                                                         print_to(self, "^2SANDBOX - INFO: ^7Object attached successfully");
 597                                                         if(autocvar_g_sandbox_info > 1)
 598                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " attached objects at origin ^3", vtos(e.origin), "\n"));
 599                                                         return TRUE;
 600                                                 }
 601                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be attached to the parent. Make sure you are facing an object that you have edit rights over");
 602                                                 return TRUE;
 603                                         case "remove":
 604                                                 // removes e if it was attached
 605                                                 e = sandbox_ObjectEdit_Get(TRUE);
 606                                                 if(e != world)
 607                                                 {
 608                                                         sandbox_ObjectAttach_Remove(e);
 609                                                         print_to(self, "^2SANDBOX - INFO: ^7Child objects detached successfully");
 610                                                         if(autocvar_g_sandbox_info > 1)
 611                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " detached objects at origin ^3", vtos(e.origin), "\n"));
 612                                                         return TRUE;
 613                                                 }
 614                                                 print_to(self, "^1SANDBOX - WARNING: ^7Child objects could not be detached. Make sure you are facing an object that you have edit rights over");
 615                                                 return TRUE;
 616                                 }
 617                                 return TRUE;
 618
 619                         // ---------------- COMMAND: OBJECT, EDIT ----------------
 620                         case "object_edit":
 621                                 if(!argv(2))
 622                                 {
 623                                         print_to(self, "^1SANDBOX - WARNING: ^7Too few parameters. You must specify a property to edit");
 624                                         return TRUE;
 625                                 }
 626
 627                                 e = sandbox_ObjectEdit_Get(TRUE);
 628                                 if(e != world)
 629                                 {
 630                                         switch(argv(2))
 631                                         {
 632                                                 case "skin":
 633                                                         e.skin = stof(argv(3));
 634                                                         break;
 635                                                 case "alpha":
 636                                                         e.alpha = stof(argv(3));
 637                                                         break;
 638                                                 case "color_main":
 639                                                         e.colormod = stov(argv(3));
 640                                                         break;
 641                                                 case "color_glow":
 642                                                         e.glowmod = stov(argv(3));
 643                                                         break;
 644                                                 case "frame":
 645                                                         e.frame = stof(argv(3));
 646                                                         break;
 647                                                 case "scale":
 648                                                         sandbox_ObjectEdit_Scale(e, stof(argv(3)));
 649                                                         break;
 650                                                 case "solidity":
 651                                                         switch(argv(3))
 652                                                         {
 653                                                                 case "0": // non-solid
 654                                                                         e.solid = SOLID_TRIGGER;
 655                                                                         break;
 656                                                                 case "1": // solid
 657                                                                         e.solid = SOLID_BBOX;
 658                                                                         break;
 659                                                                 default:
 660                                                                         break;
 661                                                         }
 662                                                 case "physics":
 663                                                         switch(argv(3))
 664                                                         {
 665                                                                 case "0": // static
 666                                                                         e.movetype = MOVETYPE_NONE;
 667                                                                         break;
 668                                                                 case "1": // movable
 669                                                                         e.movetype = MOVETYPE_TOSS;
 670                                                                         break;
 671                                                                 case "2": // physical
 672                                                                         e.movetype = MOVETYPE_PHYSICS;
 673                                                                         break;
 674                                                                 default:
 675                                                                         break;
 676                                                         }
 677                                                         break;
 678                                                 case "force":
 679                                                         e.damageforcescale = stof(argv(3));
 680                                                         break;
 681                                                 case "material":
 682                                                         if(e.material)  strunzone(e.material);
 683                                                         if(argv(3))
 684                                                         {
 685                                                                 for (i = 1; i <= 5; i++) // precache material sounds, 5 in total
 686                                                                         precache_sound(strcat("object/impact_", argv(3), "_", ftos(i), ".ogg"));
 687                                                                 e.material = strzone(argv(3));
 688                                                         }
 689                                                         else
 690                                                                 e.material = string_null; // no material
 691                                                         break;
 692                                                 default:
 693                                                         print_to(self, "^1SANDBOX - WARNING: ^7Invalid object property. For usage information, type 'sandbox help'");
 694                                                         return TRUE;
 695                                         }
 696
 697                                         // update last editing time
 698                                         if(e.message2)  strunzone(e.message2);
 699                                         e.message2 = strzone(strftime(TRUE, "%d-%m-%Y %H:%M:%S"));
 700
 701                                         if(autocvar_g_sandbox_info > 1)
 702                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " edited property ^3", argv(2), " ^7of an object at origin ^3", vtos(e.origin), "\n"));
 703                                         return TRUE;
 704                                 }
 705
 706                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be edited. Make sure you are facing an object that you have edit rights over");
 707                                 return TRUE;
 708
 709                         // ---------------- COMMAND: OBJECT, CLAIM ----------------
 710                         case "object_claim":
 711                                 // if the player can edit an object but is not its owner, this can be used to claim that object
 712                                 if(self.crypto_idfp == "")
 713                                 {
 714                                         print_to(self, "^1SANDBOX - WARNING: ^7You do not have a player UID, and cannot claim objects");
 715                                         return TRUE;
 716                                 }
 717                                 e = sandbox_ObjectEdit_Get(TRUE);
 718                                 if(e != world)
 719                                 {
 720                                         // update the owner's name
 721                                         // Do this before checking if you're already the owner and skipping if such, so we
 722                                         // also update the player's nickname if he changed it (but has the same player UID)
 723                                         if(e.netname != self.netname)
 724                                         {
 725                                                 if(e.netname)   strunzone(e.netname);
 726                                                 e.netname = strzone(self.netname);
 727                                                 print_to(self, "^2SANDBOX - INFO: ^7Object owner name updated");
 728                                         }
 729
 730                                         if(e.crypto_idfp == self.crypto_idfp)
 731                                         {
 732                                                 print_to(self, "^2SANDBOX - INFO: ^7Object is already yours, nothing to claim");
 733                                                 return TRUE;
 734                                         }
 735
 736                                         if(e.crypto_idfp)       strunzone(e.crypto_idfp);
 737                                         e.crypto_idfp = strzone(self.crypto_idfp);
 738
 739                                         print_to(self, "^2SANDBOX - INFO: ^7Object claimed successfully");
 740                                 }
 741                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be claimed. Make sure you are facing an object that you have edit rights over");
 742                                 return TRUE;
 743
 744                         // ---------------- COMMAND: OBJECT, INFO ----------------
 745                         case "object_info":
 746                                 // prints public information about the object to the player
 747                                 e = sandbox_ObjectEdit_Get(FALSE);
 748                                 if(e != world)
 749                                 {
 750                                         switch(argv(2))
 751                                         {
 752                                                 case "object":
 753                                                         print_to(self, strcat("^2SANDBOX - INFO: ^7Object is owned by \"^7", e.netname, "^7\", created \"^3", e.message, "^7\", last edited \"^3", e.message2, "^7\""));
 754                                                         return TRUE;
 755                                                 case "mesh":
 756                                                         for(i = 1; gettaginfo(e, i); i++)
 757                                                                 s = strcat(s, "^7\"^5", gettaginfo_name, "^7\", ");
 758                                                         print_to(self, strcat("^2SANDBOX - INFO: ^7Object mesh is \"^3", e.model, "^7\" at animation frame ^3", ftos(e.frame), " ^7containing the following tags: ", s));
 759                                                         return TRUE;
 760                                                 case "attachments":
 761                                                         // this should show the same info as 'mesh' but for attachments
 762                                                         entity head;
 763                                                         for(head = world; (head = find(head, classname, "object")); )
 764                                                         {
 765                                                                 if(head.owner == e)
 766                                                                 {
 767                                                                         ++i; // start from 1
 768                                                                         gettaginfo(e, head.tag_index);
 769                                                                         s = strcat(s, "^1attachment ", ftos(i), "^7 has mesh \"^3", head.model, "^7\" at animation frame ^3", ftos(head.frame));
 770                                                                         s = strcat(s, "^7 and is attached to bone \"^5", gettaginfo_name, "^7\", ");
 771                                                                 }
 772                                                         }
 773                                                         if(i) // object contains attachments
 774                                                                 print_to(self, strcat("^2SANDBOX - INFO: ^7Object contains the following ^1", ftos(i), "^7 attachment(s): ", s));
 775                                                         else
 776                                                                 print_to(self, "^2SANDBOX - INFO: ^7Object contains no attachments");
 777                                                         return TRUE;
 778                                         }
 779                                 }
 780                                 print_to(self, "^1SANDBOX - WARNING: ^7No information could be found. Make sure you are facing an object");
 781                                 return TRUE;
 782
 783                         // ---------------- COMMAND: DEFAULT ----------------
 784                         default:
 785                                 print_to(self, "Invalid command. For usage information, type 'sandbox help'");
 786                                 return TRUE;
 787                 }
 788         }
 789         return FALSE;
 790 }
 791
 792 float autosave_time;
 793 MUTATOR_HOOKFUNCTION(sandbox_StartFrame)
 794 {
 795         if(!autocvar_g_sandbox_storage_autosave)
 796                 return FALSE;
 797         if(time < autosave_time)
 798                 return FALSE;
 799         autosave_time = time + autocvar_g_sandbox_storage_autosave;
 800
 801         sandbox_Database_Save();
 802
 803         return TRUE;
 804 }
 805
 806 MUTATOR_DEFINITION(sandbox)
 807 {
 808         MUTATOR_HOOK(SV_ParseClientCommand, sandbox_PlayerCommand, CBC_ORDER_ANY);
 809         MUTATOR_HOOK(SV_StartFrame, sandbox_StartFrame, CBC_ORDER_ANY);
 810
 811         MUTATOR_ONADD
 812         {
 813                 autosave_time = time + autocvar_g_sandbox_storage_autosave; // don't save the first server frame
 814                 if(autocvar_g_sandbox_storage_autoload)
 815                         sandbox_Database_Load();
 816         }
 817
 818         return FALSE;
 819 }
 820