qcsrc/server/mutators/sandbox.qc

   1 float object_count;
   2 .string object_clipboard;
   3 .entity object_attach;
   4 .string material;
   5
   6 .float touch_timer;
   7 void sandbox_ObjectFunction_Touch()
   8 {
   9         // apply material impact effects
  10
  11         if(!self.material)
  12                 return;
  13         if(self.touch_timer > time)
  14                 return; // don't execute each frame
  15         self.touch_timer = time + 0.1;
  16
  17         // make particle count and sound volume depend on impact speed
  18         float intensity;
  19         intensity = vlen(self.velocity) + vlen(other.velocity);
  20         if(intensity) // avoid divisions by 0
  21                 intensity /= 2; // average the two velocities
  22         if not(intensity >= autocvar_g_sandbox_object_material_velocity_min)
  23                 return; // impact not strong enough to do anything
  24         // now offset intensity and apply it to the effects
  25         intensity -= autocvar_g_sandbox_object_material_velocity_min; // start from minimum velocity, not actual velocity
  26         intensity = bound(0, intensity * autocvar_g_sandbox_object_material_velocity_factor, 1);
  27
  28         sound(self, CH_TRIGGER, strcat("object/impact_", self.material, "_", ftos(ceil(random() * 5)) , ".ogg"), VOL_BASE * intensity, ATTN_NORM);
  29         pointparticles(particleeffectnum(strcat("impact_", self.material)), self.origin, '0 0 0', ceil(intensity * 10)); // allow a count from 1 to 10
  30 }
  31
  32 entity sandbox_ObjectEdit_Get()
  33 {
  34         // returns the traced entity if the player can edit it, and world if not
  35         // attached objects are SOLID_NOT and don't risk getting traced
  36
  37         makevectors(self.v_angle);
  38         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_edit, MOVE_NORMAL, self);
  39
  40         if(trace_ent.classname != "object")
  41                 return world; // entity is not an object
  42         if(!trace_ent.crypto_idfp)
  43                 return trace_ent; // the player who spawned this object did not have an UID, so anyone can edit it
  44         else if not(trace_ent.crypto_idfp != self.crypto_idfp && !autocvar_g_sandbox_editor_free)
  45                 return trace_ent; // object does not belong to the player, and players can only edit their own objects on this server
  46         return world;
  47 }
  48
  49 void sandbox_ObjectEdit_Scale(entity e, float f)
  50 {
  51         e.scale = f;
  52         if(e.scale)
  53         {
  54                 e.scale = bound(autocvar_g_sandbox_object_scale_min, e.scale, autocvar_g_sandbox_object_scale_max);
  55                 setsize(e, e.mins * e.scale, e.maxs * e.scale); // adapt bounding box size to model size
  56         }
  57 }
  58
  59 void sandbox_ObjectAttach_Remove(entity e);
  60 void sandbox_ObjectAttach_Set(entity e, entity parent, string s)
  61 {
  62         // attaches e to parent on string s
  63
  64         // we can't attach to an attachment, for obvious reasons
  65         sandbox_ObjectAttach_Remove(e);
  66
  67         e.movetype = MOVETYPE_FOLLOW;
  68         e.solid = SOLID_NOT;
  69         e.takedamage = DAMAGE_NO;
  70
  71         setattachment(e, parent, s);
  72         e.owner = parent;
  73 }
  74
  75 void sandbox_ObjectAttach_Remove(entity e)
  76 {
  77         // detaches any object attached to e
  78
  79         entity head;
  80         for(head = world; (head = find(head, classname, "object")); )
  81         {
  82                 if(head.owner == e)
  83                 {
  84                         head.movetype = MOVETYPE_TOSS; // default
  85                         head.solid = SOLID_BBOX;
  86                         head.takedamage = DAMAGE_AIM;
  87
  88                         setattachment(head, world, "");
  89                         head.owner = world;
  90
  91                         // objects reset origin and angles when detached, so apply the parent's to prevent teleporting
  92                         setorigin(head, e.origin);
  93                         head.angles = e.angles;
  94                 }
  95         }
  96 }
  97
  98 entity sandbox_ObjectSpawn(float database)
  99 {
 100         // spawn a new object with default properties
 101
 102         entity e;
 103         e = spawn();
 104         e.classname = "object";
 105         e.takedamage = DAMAGE_AIM;
 106         e.damageforcescale = 1;
 107         e.solid = SOLID_BBOX; // SOLID_BSP would be best, but can lag the server badly
 108         e.movetype = MOVETYPE_TOSS;
 109         e.frame = 0;
 110         e.skin = 0;
 111         e.material = string_null;
 112         e.touch = sandbox_ObjectFunction_Touch;
 113
 114         if(!database)
 115         {
 116                 // set the object's owner via player UID
 117                 // if the player does not have an UID, the owner cannot be stored and his objects may be edited by anyone
 118                 if(self.crypto_idfp != "")
 119                         e.crypto_idfp = strzone(self.crypto_idfp);
 120                 else
 121                         print_to(self, "^1SANDBOX - WARNING: ^7You spawned an object, but lack a player UID. ^1Your objects are not secured and can be edited by any player!");
 122
 123                 // set origin and direction based on player position and view angle
 124                 makevectors(self.v_angle);
 125                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_spawn, MOVE_NORMAL, self);
 126                 setorigin(e, trace_endpos);
 127                 e.angles_y = self.v_angle_y;
 128         }
 129
 130         object_count += 1;
 131         return e;
 132 }
 133
 134 void sandbox_ObjectRemove(entity e)
 135 {
 136         sandbox_ObjectAttach_Remove(e); // detach child objects
 137         if(e.material)
 138         {
 139                 strunzone(e.material);
 140                 e.material = string_null;
 141         }
 142         if(e.crypto_idfp)
 143         {
 144                 strunzone(e.crypto_idfp);
 145                 e.crypto_idfp = string_null;
 146         }
 147         remove(e);
 148         e = world;
 149
 150         object_count -= 1;
 151 }
 152
 153 string sandbox_ObjectPort_Save_string(entity e, float database)
 154 {
 155         string s;
 156         s = strcat(s, e.model, " ");
 157         s = strcat(s, ftos(e.skin), " ");
 158         s = strcat(s, ftos(e.alpha), " ");
 159         s = strcat(s, sprintf("\"%.9v\"", e.colormod), " ");
 160         s = strcat(s, sprintf("\"%.9v\"", e.glowmod), " ");
 161         s = strcat(s, ftos(e.frame), " ");
 162         s = strcat(s, ftos(e.scale), " ");
 163         s = strcat(s, ftos(e.movetype), " ");
 164         s = strcat(s, ftos(e.damageforcescale), " ");
 165         if(e.material)  s = strcat(s, e.material, " "); else    s = strcat(s, "- "); // none
 166         if(database)
 167         {
 168                 if(e.crypto_idfp)       s = strcat(s, e.crypto_idfp, " ");      else    s = strcat(s, "- "); // none
 169                 s = strcat(s, sprintf("\"%.9v\"", e.origin), " ");
 170                 s = strcat(s, sprintf("\"%.9v\"", e.angles), " ");
 171         }
 172         s = strcat(s, "; ");
 173         return s;
 174 }
 175 string sandbox_ObjectPort_Save(entity e, float database)
 176 {
 177         // save object properties
 178         string s;
 179         entity head;
 180
 181         // first set the properties of the main object, then those of each child
 182         s = sandbox_ObjectPort_Save_string(e, database);
 183         for(head = world; (head = find(head, classname, "object")); )
 184         {
 185                 if(head.owner == e)
 186                         s = strcat(s, sandbox_ObjectPort_Save_string(head, database));
 187         }
 188
 189         return s;
 190 }
 191
 192 entity sandbox_ObjectPort_Load(string s, float database)
 193 {
 194         // load object properties
 195         float n, i;
 196         entity e, parent;
 197
 198         for(;;)
 199         {
 200                 n = tokenizebyseparator(s, "; ");
 201                 tokenize_console(argv(i));
 202                 e = sandbox_ObjectSpawn(database);
 203
 204                 setmodel(e, argv(0));
 205                 e.skin = stof(argv(1));
 206                 e.alpha = stof(argv(2));
 207                 e.colormod = stov(argv(3));
 208                 e.glowmod = stov(argv(4));
 209                 e.frame = stof(argv(5));
 210                 sandbox_ObjectEdit_Scale(e, stof(argv(6)));
 211                 e.movetype = stof(argv(7));
 212                 e.damageforcescale = stof(argv(8));
 213                 if(e.material)  strunzone(e.material);  if(argv(9) != "-")      e.material = strzone(argv(9));  else    e.material = string_null;
 214                 if(database)
 215                 {
 216                         if(e.crypto_idfp)       strunzone(e.crypto_idfp);       if(argv(10) != "-")     e.crypto_idfp = strzone(argv(10));      else    e.crypto_idfp = string_null;
 217                         setorigin(e, stov(argv(11)));
 218                         e.angles = stov(argv(12));
 219                 }
 220
 221                 if(i > 0) // child object
 222                         sandbox_ObjectAttach_Set(e, parent, "");
 223                 else // parent object
 224                         parent = e;
 225
 226                 i += 1;
 227                 if(i >= n)
 228                         break;
 229         }
 230
 231         return e;
 232 }
 233
 234 void sandbox_Database_Save()
 235 {
 236         // saves all objects to the database file
 237         entity head;
 238         string file_name;
 239         float file_get;
 240
 241         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 242         file_get = fopen(file_name, FILE_WRITE);
 243         fputs(file_get, strcat("// sandbox storage \"", autocvar_g_sandbox_storage_name, "\" for map \"", GetMapname(), "\" last updated ", strftime(TRUE, "%d-%m-%Y %H:%M:%S")));
 244         fputs(file_get, strcat(" containing ", ftos(object_count), " objects\n"));
 245
 246         for(head = world; (head = find(head, classname, "object")); )
 247         {
 248                 // Unfortunately, attached objects cannot be persisted yet. That's because the parent is specified as an entity,
 249                 // but only properties can be saved to this file, leaving no way to identify the owner once all objects are spawned
 250                 // TODO: Find some way to fix this!
 251                 if(head.owner != world)
 252                         continue;
 253
 254                 // use a line for each object, listing all properties
 255                 fputs(file_get, strcat(sandbox_ObjectPort_Save(head, TRUE), "\n"));
 256         }
 257         fclose(file_get);
 258 }
 259
 260 void sandbox_Database_Load()
 261 {
 262         // loads all objects from the database file
 263         string file_read, file_name;
 264         float file_get, i;
 265
 266         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 267         file_get = fopen(file_name, FILE_READ);
 268         if(file_get < 0)
 269         {
 270                 if(autocvar_g_sandbox_info > 0)
 271                         print(strcat("^3SANDBOX - SERVER: ^7could not find storage file ^3", file_name, "^7, no objects were loaded\n"));
 272         }
 273         else
 274         {
 275                 for(;;)
 276                 {
 277                         file_read = fgets(file_get);
 278                         if(!file_read)
 279                                 break;
 280                         if(substring(file_read, 0, 2) == "//")
 281                                 continue;
 282                         if(substring(file_read, 0, 1) == "#")
 283                                 continue;
 284
 285                         entity e;
 286                         e = sandbox_ObjectPort_Load(file_read, TRUE);
 287
 288                         if(e.material)
 289                         {
 290                                 // since objects are being loaded for the first time, precache material sounds for each
 291                                 for (i = 1; i <= 5; i++) // 5 sounds in total
 292                                         precache_sound(strcat("object/impact_", e.material, "_", ftos(i), ".ogg"));
 293                         }
 294                 }
 295                 if(autocvar_g_sandbox_info > 0)
 296                         print(strcat("^3SANDBOX - SERVER: ^7successfully loaded storage file ^3", file_name, "\n"));
 297         }
 298 }
 299
 300 MUTATOR_HOOKFUNCTION(sandbox_PlayerCommand)
 301 {
 302         if(MUTATOR_RETURNVALUE) // command was already handled?
 303                 return FALSE;
 304         if(cmd_name == "g_sandbox")
 305         {
 306                 if(cmd_argc < 2)
 307                 {
 308                         print_to(self, "Sandbox mode is active. For usage information, type 'sandbox help'");
 309                         return TRUE;
 310                 }
 311
 312                 switch(argv(1))
 313                 {
 314                         entity e;
 315                         float i;
 316
 317                         // ---------------- COMMAND: HELP ----------------
 318                         case "help":
 319                                 print_to(self, "You can use the following sandbox commands:");
 320                                 print_to(self, "^7\"^2object_spawn ^3models/foo/bar.md3^7\" spawns a new object in front of the player, and gives it the specified model");
 321                                 print_to(self, "^7\"^2object_remove^7\" removes the object the player is looking at. Players can only remove their own objects");
 322                                 print_to(self, "^7\"^2object_duplicate ^3value^7\" duplicates the object. 'copy' copies the object, 'paste' puts it in front of the player");
 323                                 print_to(self, "^7\"^2object_claim^7\" sets the player as the owner of the object, if he has the right to edit it");
 324                                 print_to(self, "^7\"^2object_attach ^3property value^7\" attaches one object to another. Players can only attach their own objects");
 325                                 print_to(self, "^7Attachment properties for ^2object_attach^7:");
 326                                 print_to(self, "^3get ^7- selects the object you are facing as the object to be attached");
 327                                 print_to(self, "^3set value ^7- attaches the previously selected object to the object you are facing, on the specified bone");
 328                                 print_to(self, "^3remove ^7- detaches all objects from the object you are facing");
 329                                 print_to(self, "^7\"^2object_edit ^3property value^7\" edits the given property of the object. Players can only edit their own objects");
 330                                 print_to(self, "^7Object properties for ^2object_edit^7:");
 331                                 print_to(self, "^3skin value ^7- changes the skin of the object");
 332                                 print_to(self, "^3alpha value ^7- sets object transparency");
 333                                 print_to(self, "^3colormod \"value_x value_y value_z\" ^7- main object color");
 334                                 print_to(self, "^3glowmod \"value_x value_y value_z\" ^7- glow object color");
 335                                 print_to(self, "^3frame value ^7- object animation frame, for self-animated models");
 336                                 print_to(self, "^3scale value ^7- changes object scale. 0.5 is half size and 2 is double size");
 337                                 print_to(self, "^3physics value ^7- object physics, 0 = static, 1 = movable, 2 = physical");
 338                                 print_to(self, "^3force value ^7- amount of force applied to objects that are shot");
 339                                 print_to(self, "^3material value ^7- sets the material of the object. Default materials are: metal, stone, wood, flesh");
 340                                 print_to(self, "^7The ^1drag object ^7key can be used to grab and carry objects. Players can only grab their own objects");
 341                                 return TRUE;
 342
 343                         // ---------------- COMMAND: SPAWN OBJECT ----------------
 344                         case "object_spawn":
 345                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 346                                 {
 347                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 348                                         return TRUE;
 349                                 }
 350                                 if(cmd_argc < 3)
 351                                 {
 352                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object without specifying a model. Please specify the path to your model file after the 'object_spawn' command");
 353                                         return TRUE;
 354                                 }
 355                                 else if not(fexists(argv(2)))
 356                                 {
 357                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object with a non-existent model. Make sure the path to your model file is correct");
 358                                         return TRUE;
 359                                 }
 360
 361                                 e = sandbox_ObjectSpawn(FALSE);
 362                                 setmodel(e, argv(2));
 363
 364                                 if(autocvar_g_sandbox_info > 0)
 365                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " spawned an object at origin ^3", vtos(e.origin), "\n"));
 366                                 return TRUE;
 367
 368                         // ---------------- COMMAND: REMOVE OBJECT ----------------
 369                         case "object_remove":
 370                                 e = sandbox_ObjectEdit_Get();
 371                                 if(e != world)
 372                                 {
 373                                         if(autocvar_g_sandbox_info > 0)
 374                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " removed an object at origin ^3", vtos(e.origin), "\n"));
 375                                         sandbox_ObjectRemove(e);
 376                                         return TRUE;
 377                                 }
 378
 379                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be removed. Make sure you are facing an object that you have edit rights over");
 380                                 return TRUE;
 381
 382                         // ---------------- COMMAND: DUPLICATE OBJECT ----------------
 383                         case "object_duplicate":
 384                                 switch(argv(2))
 385                                 {
 386                                         case "copy":
 387                                                 // copies customizable properties of the selected object to the clipboard
 388                                                 e = sandbox_ObjectEdit_Get(); // you can only copy objects you can edit, so this works
 389                                                 if(e != world)
 390                                                 {
 391                                                         if(self.object_clipboard)
 392                                                                 strunzone(self.object_clipboard);
 393                                                         self.object_clipboard = strzone(sandbox_ObjectPort_Save(e, FALSE));
 394
 395                                                         print_to(self, "^2SANDBOX - INFO: ^7Object copied to clipboard");
 396                                                         return TRUE;
 397                                                 }
 398                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be copied. Make sure you are facing an object that you have edit rights over");
 399                                                 return TRUE;
 400
 401                                         case "paste":
 402                                                 // spawns a new object using the properties in the player's clipboard
 403                                                 if(!self.object_clipboard) // no object in clipboard
 404                                                 {
 405                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object in clipboard. You must copy an object before you can paste it");
 406                                                         return TRUE;
 407                                                 }
 408                                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 409                                                 {
 410                                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 411                                                         return TRUE;
 412                                                 }
 413
 414                                                 e = sandbox_ObjectPort_Load(self.object_clipboard, FALSE);
 415
 416                                                 print_to(self, "^2SANDBOX - INFO: ^7Object pasted successfully");
 417                                                 if(autocvar_g_sandbox_info > 0)
 418                                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " pasted an object at origin ^3", vtos(e.origin), "\n"));
 419                                                 return TRUE;
 420                                 }
 421                                 return TRUE;
 422
 423                         // ---------------- COMMAND: CLAIM OBJECT ----------------
 424                         case "object_claim":
 425                                 // if the player can edit an object but is not its owner, this can be used to claim that object
 426                                 if(self.crypto_idfp == "")
 427                                 {
 428                                         print_to(self, "^1SANDBOX - WARNING: ^7You do not have a player UID, and cannot claim objects");
 429                                         return TRUE;
 430                                 }
 431                                 e = sandbox_ObjectEdit_Get();
 432                                 if(e != world)
 433                                 {
 434                                         if(e.crypto_idfp == self.crypto_idfp)
 435                                         {
 436                                                 print_to(self, "^2SANDBOX - INFO: ^7Object is already yours, nothing to claim");
 437                                                 return TRUE;
 438                                         }
 439
 440                                         if(e.crypto_idfp)
 441                                                 strunzone(e.crypto_idfp);
 442                                         e.crypto_idfp = self.crypto_idfp;
 443                                         print_to(self, "^2SANDBOX - INFO: ^7Object claimed successfully");
 444                                 }
 445                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be claimed. Make sure you are facing an object that you have edit rights over");
 446                                 return TRUE;
 447
 448                         // ---------------- COMMAND: ATTACH OBJECT ----------------
 449                         case "object_attach":
 450                                 switch(argv(2))
 451                                 {
 452                                         case "get":
 453                                                 // select e as the object as meant to be attached
 454                                                 e = sandbox_ObjectEdit_Get();
 455                                                 if(e != world)
 456                                                 {
 457                                                         self.object_attach = e;
 458                                                         print_to(self, "^2SANDBOX - INFO: ^7Object selected for attachment");
 459                                                         return TRUE;
 460                                                 }
 461                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be selected for attachment. Make sure you are facing an object that you have edit rights over");
 462                                                 return TRUE;
 463                                         case "set":
 464                                                 if(self.object_attach == world)
 465                                                 {
 466                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object selected for attachment. Please select an object to be attached first.");
 467                                                         return TRUE;
 468                                                 }
 469
 470                                                 // attaches the previously selected object to e
 471                                                 e = sandbox_ObjectEdit_Get();
 472                                                 if(e != world)
 473                                                 {
 474                                                         sandbox_ObjectAttach_Set(self.object_attach, e, argv(3));
 475                                                         self.object_attach = world; // object was attached, no longer keep it scheduled for attachment
 476                                                         print_to(self, "^2SANDBOX - INFO: ^7Object attached successfully");
 477                                                         if(autocvar_g_sandbox_info > 1)
 478                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " attached objects at origin ^3", vtos(e.origin), "\n"));
 479                                                         return TRUE;
 480                                                 }
 481                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be attached to the parent. Make sure you are facing an object that you have edit rights over");
 482                                                 return TRUE;
 483                                         case "remove":
 484                                                 // removes e if it was attached
 485                                                 e = sandbox_ObjectEdit_Get();
 486                                                 if(e != world)
 487                                                 {
 488                                                         sandbox_ObjectAttach_Remove(e);
 489                                                         print_to(self, "^2SANDBOX - INFO: ^7Child objects detached successfully");
 490                                                         if(autocvar_g_sandbox_info > 1)
 491                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " detached objects at origin ^3", vtos(e.origin), "\n"));
 492                                                         return TRUE;
 493                                                 }
 494                                                 print_to(self, "^1SANDBOX - WARNING: ^7Child objects could not be detached. Make sure you are facing an object that you have edit rights over");
 495                                                 return TRUE;
 496                                 }
 497                                 return TRUE;
 498
 499                         // ---------------- COMMAND: EDIT OBJECT ----------------
 500                         case "object_edit":
 501                                 if(!argv(2))
 502                                 {
 503                                         print_to(self, "^1SANDBOX - WARNING: ^7Too few parameters. You must specify a property to edit");
 504                                         return TRUE;
 505                                 }
 506
 507                                 e = sandbox_ObjectEdit_Get();
 508                                 if(e != world)
 509                                 {
 510                                         switch(argv(2))
 511                                         {
 512                                                 case "skin":
 513                                                         e.skin = stof(argv(3));
 514                                                         break;
 515                                                 case "alpha":
 516                                                         e.alpha = stof(argv(3));
 517                                                         break;
 518                                                 case "color_main":
 519                                                         e.colormod = stov(argv(3));
 520                                                         break;
 521                                                 case "color_glow":
 522                                                         e.glowmod = stov(argv(3));
 523                                                         break;
 524                                                 case "frame":
 525                                                         e.frame = stof(argv(3));
 526                                                         break;
 527                                                 case "scale":
 528                                                         sandbox_ObjectEdit_Scale(e, stof(argv(3)));
 529                                                         break;
 530                                                 case "physics":
 531                                                         switch(argv(3))
 532                                                         {
 533                                                                 case "0": // static
 534                                                                         e.movetype = MOVETYPE_NONE;
 535                                                                         break;
 536                                                                 case "1": // movable
 537                                                                         e.movetype = MOVETYPE_TOSS;
 538                                                                         break;
 539                                                                 case "2": // physical
 540                                                                         e.movetype = MOVETYPE_PHYSICS;
 541                                                                         break;
 542                                                                 default:
 543                                                                         break;
 544                                                         }
 545                                                         break;
 546                                                 case "force":
 547                                                         e.damageforcescale = stof(argv(3));
 548                                                         break;
 549                                                 case "material":
 550                                                         if(e.material)
 551                                                                 strunzone(e.material);
 552                                                         if(argv(3))
 553                                                         {
 554                                                                 for (i = 1; i <= 5; i++) // precache material sounds, 5 in total
 555                                                                         precache_sound(strcat("object/impact_", argv(3), "_", ftos(i), ".ogg"));
 556                                                                 e.material = strzone(argv(3));
 557                                                         }
 558                                                         else
 559                                                                 e.material = string_null; // no material
 560                                                         break;
 561                                                 default:
 562                                                         print_to(self, "^1SANDBOX - WARNING: ^7Invalid object property. For usage information, type 'sandbox help'");
 563                                                         break;
 564                                         }
 565                                         if(autocvar_g_sandbox_info > 1)
 566                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " edited property ^3", argv(2), " ^7of an object at origin ^3", vtos(e.origin), "\n"));
 567                                         return TRUE;
 568                                 }
 569
 570                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be edited. Make sure you are facing an object that you have edit rights over");
 571                                 return TRUE;
 572
 573                         // ---------------- COMMAND: DEFAULT ----------------
 574                         default:
 575                                 print_to(self, "Invalid command. For usage information, type 'sandbox help'");
 576                                 return TRUE;
 577                 }
 578         }
 579         return FALSE;
 580 }
 581
 582 MUTATOR_HOOKFUNCTION(sandbox_PlayerPreThink)
 583 {
 584         // if the player is close enough to their object, they can drag it
 585
 586         if(autocvar_sv_cheats)
 587                 return FALSE; // cheat dragging is used instead
 588
 589         // grab is TRUE if the object can be picked up. While an object is being carried, the Drag() function
 590         // must execute for it either way, otherwise it would cause bugs if it went out of the player's trace.
 591         // This also makes sure that an object can only pe picked up if in range, but does not get dropped if
 592         // it goes out of range while slinging it around.
 593
 594         entity e;
 595         float grab;
 596
 597         e = sandbox_ObjectEdit_Get();
 598         if(e != world && vlen(e.origin - self.origin) <= autocvar_g_sandbox_editor_distance_edit)
 599                 grab = TRUE;
 600
 601         if(Drag(e, grab)) // execute dragging
 602                 return TRUE;
 603
 604         return FALSE;
 605 }
 606
 607 MUTATOR_HOOKFUNCTION(sandbox_ClientDisconnect)
 608 {
 609         // unzone the player's clipboard if it's not empty
 610         if(self.object_clipboard)
 611         {
 612                 strunzone(self.object_clipboard);
 613                 self.object_clipboard = string_null;
 614         }
 615
 616         return FALSE;
 617 }
 618
 619 float autosave_time;
 620 MUTATOR_HOOKFUNCTION(sandbox_StartFrame)
 621 {
 622         if(!autocvar_g_sandbox_storage_autosave)
 623                 return FALSE;
 624         if(time < autocvar_g_sandbox_storage_autosave)
 625                 return FALSE;
 626         autosave_time = time + autocvar_g_sandbox_storage_autosave;
 627
 628         sandbox_Database_Save();
 629
 630         return TRUE;
 631 }
 632
 633 MUTATOR_DEFINITION(sandbox)
 634 {
 635         MUTATOR_HOOK(SV_ParseClientCommand, sandbox_PlayerCommand, CBC_ORDER_ANY);
 636         MUTATOR_HOOK(SV_StartFrame, sandbox_StartFrame, CBC_ORDER_ANY);
 637         MUTATOR_HOOK(PlayerPreThink, sandbox_PlayerPreThink, CBC_ORDER_ANY);
 638         MUTATOR_HOOK(ClientDisconnect, sandbox_ClientDisconnect, CBC_ORDER_ANY);
 639
 640         MUTATOR_ONADD
 641         {
 642                 autosave_time = time + autocvar_g_sandbox_storage_autosave; // don't save the first server frame
 643                 if(autocvar_g_sandbox_storage_autoload)
 644                         sandbox_Database_Load();
 645         }
 646
 647         return FALSE;
 648 }
 649