qcsrc/server/mutators/sandbox.qc

   1 const float MAX_STORAGE_ATTACHMENTS = 16;
   2 float object_count;
   3 .float object_flood;
   4 .entity object_attach;
   5 .string material;
   6
   7 .float touch_timer;
   8 void sandbox_ObjectFunction_Touch()
   9 {
  10         // apply material impact effects
  11
  12         if(!self.material)
  13                 return;
  14         if(self.touch_timer > time)
  15                 return; // don't execute each frame
  16         self.touch_timer = time + 0.1;
  17
  18         // make particle count and sound volume depend on impact speed
  19         float intensity;
  20         intensity = vlen(self.velocity) + vlen(other.velocity);
  21         if(intensity) // avoid divisions by 0
  22                 intensity /= 2; // average the two velocities
  23         if not(intensity >= autocvar_g_sandbox_object_material_velocity_min)
  24                 return; // impact not strong enough to do anything
  25         // now offset intensity and apply it to the effects
  26         intensity -= autocvar_g_sandbox_object_material_velocity_min; // start from minimum velocity, not actual velocity
  27         intensity = bound(0, intensity * autocvar_g_sandbox_object_material_velocity_factor, 1);
  28
  29         sound(self, CH_TRIGGER, strcat("object/impact_", self.material, "_", ftos(ceil(random() * 5)) , ".ogg"), VOL_BASE * intensity, ATTN_NORM);
  30         pointparticles(particleeffectnum(strcat("impact_", self.material)), self.origin, '0 0 0', ceil(intensity * 10)); // allow a count from 1 to 10
  31 }
  32
  33 void sandbox_ObjectFunction_Think()
  34 {
  35         entity e;
  36
  37         // decide if and how this object can be grabbed
  38         if(autocvar_g_sandbox_readonly)
  39                 self.grab = 0; // no grabbing
  40         else if(autocvar_g_sandbox_editor_free < 2 && self.crypto_idfp)
  41                 self.grab = 1; // owner only
  42         else
  43                 self.grab = 3; // anyone
  44
  45         // Object owner is stored via player UID, but we also need the owner as an entity (if the player is available on the server).
  46         // Therefore, scan for all players, and update the owner as long as the player is present. We must always do this,
  47         // since if the owning player disconnects, the object's owner should also be reset.
  48         FOR_EACH_REALPLAYER(e) // bots can't have objects
  49         {
  50                 if(self.crypto_idfp == e.crypto_idfp)
  51                 {
  52                         self.realowner = e;
  53                         break;
  54                 }
  55                 self.realowner = world;
  56         }
  57
  58         self.nextthink = time;
  59 }
  60
  61 .float old_solid, old_movetype;
  62 entity sandbox_ObjectEdit_Get(float permissions)
  63 {
  64         // Returns the traced entity if the player can edit it, and world if not.
  65         // If permissions if FALSE, the object is returned regardless of editing rights.
  66         // Attached objects are SOLID_NOT and do not get traced.
  67
  68         crosshair_trace_plusvisibletriggers(self);
  69         if(vlen(self.origin - trace_ent.origin) > autocvar_g_sandbox_editor_distance_edit)
  70                 return world; // out of trace range
  71         if(trace_ent.classname != "object")
  72                 return world; // entity is not an object
  73         if(!permissions)
  74                 return trace_ent; // don't check permissions, anyone can edit this object
  75         if(!trace_ent.crypto_idfp)
  76                 return trace_ent; // the player who spawned this object did not have an UID, so anyone can edit it
  77         if not(trace_ent.realowner != self && autocvar_g_sandbox_editor_free < 2)
  78                 return trace_ent; // object does not belong to the player, and players can only edit their own objects on this server
  79         return world;
  80 }
  81
  82 void sandbox_ObjectEdit_Scale(entity e, float f)
  83 {
  84         e.scale = f;
  85         if(e.scale)
  86         {
  87                 e.scale = bound(autocvar_g_sandbox_object_scale_min, e.scale, autocvar_g_sandbox_object_scale_max);
  88                 setmodel(e, e.model); // reset mins and maxs based on mesh
  89                 setsize(e, e.mins * e.scale, e.maxs * e.scale); // adapt bounding box size to model size
  90         }
  91 }
  92
  93 void sandbox_ObjectAttach_Remove(entity e);
  94 void sandbox_ObjectAttach_Set(entity e, entity parent, string s)
  95 {
  96         // attaches e to parent on string s
  97
  98         // we can't attach to an attachment, for obvious reasons
  99         sandbox_ObjectAttach_Remove(e);
 100
 101         e.old_solid = e.solid; // persist solidity
 102         e.old_movetype = e.movetype; // persist physics
 103         e.movetype = MOVETYPE_FOLLOW;
 104         e.solid = SOLID_NOT;
 105         e.takedamage = DAMAGE_NO;
 106
 107         setattachment(e, parent, s);
 108         e.owner = parent;
 109 }
 110
 111 void sandbox_ObjectAttach_Remove(entity e)
 112 {
 113         // detaches any object attached to e
 114
 115         entity head;
 116         for(head = world; (head = find(head, classname, "object")); )
 117         {
 118                 if(head.owner == e)
 119                 {
 120                         vector org;
 121                         org = gettaginfo(head, 0);
 122                         setattachment(head, world, "");
 123                         head.owner = world;
 124
 125                         // objects change origin and angles when detached, so apply previous position
 126                         setorigin(head, org);
 127                         head.angles = e.angles; // don't allow detached objects to spin or roll
 128
 129                         head.solid = head.old_solid; // restore persisted solidity
 130                         head.movetype = head.old_movetype; // restore persisted physics
 131                         head.takedamage = DAMAGE_AIM;
 132                 }
 133         }
 134 }
 135
 136 entity sandbox_ObjectSpawn(float database)
 137 {
 138         // spawn a new object with default properties
 139
 140         entity e;
 141         e = spawn();
 142         e.classname = "object";
 143         e.takedamage = DAMAGE_AIM;
 144         e.damageforcescale = 1;
 145         e.solid = SOLID_BBOX; // SOLID_BSP would be best, but can lag the server badly
 146         e.movetype = MOVETYPE_TOSS;
 147         e.frame = 0;
 148         e.skin = 0;
 149         e.material = string_null;
 150         e.touch = sandbox_ObjectFunction_Touch;
 151         e.think = sandbox_ObjectFunction_Think;
 152         e.nextthink = time;
 153         //e.effects |= EF_SELECTABLE; // don't do this all the time, maybe just when editing objects?
 154
 155         if(!database)
 156         {
 157                 // set the object's owner via player UID
 158                 // if the player does not have an UID, the owner cannot be stored and his objects may be edited by anyone
 159                 if(self.crypto_idfp != "")
 160                         e.crypto_idfp = strzone(self.crypto_idfp);
 161                 else
 162                         print_to(self, "^1SANDBOX - WARNING: ^7You spawned an object, but lack a player UID. ^1Your objects are not secured and can be edited by any player!");
 163
 164                 // set public object information
 165                 e.netname = strzone(self.netname); // name of the owner
 166                 e.message = strzone(strftime(TRUE, "%d-%m-%Y %H:%M:%S")); // creation time
 167                 e.message2 = strzone(strftime(TRUE, "%d-%m-%Y %H:%M:%S")); // last editing time
 168
 169                 // set origin and direction based on player position and view angle
 170                 makevectors(self.v_angle);
 171                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_spawn, MOVE_NORMAL, self);
 172                 setorigin(e, trace_endpos);
 173                 e.angles_y = self.v_angle_y;
 174         }
 175
 176         object_count += 1;
 177         return e;
 178 }
 179
 180 void sandbox_ObjectRemove(entity e)
 181 {
 182         sandbox_ObjectAttach_Remove(e); // detach child objects
 183
 184         if(e.material)  {       strunzone(e.material);  e.material = string_null;       }
 185         if(e.crypto_idfp)       {       strunzone(e.crypto_idfp);       e.crypto_idfp = string_null;    }
 186         if(e.netname)   {       strunzone(e.netname);   e.netname = string_null;        }
 187         if(e.message)   {       strunzone(e.message);   e.message = string_null;        }
 188         if(e.message2)  {       strunzone(e.message2);  e.message2 = string_null;       }
 189         remove(e);
 190         e = world;
 191
 192         object_count -= 1;
 193 }
 194
 195 string port_string[MAX_STORAGE_ATTACHMENTS]; // fteqcc crashes if this isn't defined as a global
 196
 197 string sandbox_ObjectPort_Save(entity e, float database)
 198 {
 199         // save object properties, and return them as a string
 200         float i;
 201         string s;
 202         entity head;
 203
 204         for(head = world; (head = find(head, classname, "object")); )
 205         {
 206                 // the main object needs to be first in the array [0] with attached objects following
 207                 float slot, physics, solidity;
 208                 if(head == e) // this is the main object, place it first
 209                 {
 210                         slot = 0;
 211                         solidity = head.solid; // applied solidity is normal solidity for children
 212                         physics = head.movetype; // applied physics are normal physics for parents
 213                 }
 214                 else if(head.owner == e) // child object, list them in order
 215                 {
 216                         i += 1; // children start from 1
 217                         slot = i;
 218                         solidity = head.old_solid; // persisted solidity is normal solidity for children
 219                         physics = head.old_movetype; // persisted physics are normal physics for children
 220                         gettaginfo(head.owner, head.tag_index); // get the name of the tag our object is attached to, used further below
 221                 }
 222                 else
 223                         continue;
 224
 225                 // ---------------- OBJECT PROPERTY STORAGE: SAVE ----------------
 226                 if(slot)
 227                 {
 228                         // properties stored only for child objects
 229                         if(gettaginfo_name)     port_string[slot] = strcat(port_string[slot], "\"", gettaginfo_name, "\" ");    else    port_string[slot] = strcat(port_string[slot], "- "); // none
 230                 }
 231                 else
 232                 {
 233                         // properties stored only for parent objects
 234                         if(database)
 235                         {
 236                                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.origin), " ");
 237                                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.angles), " ");
 238                         }
 239                 }
 240                 // properties stored for all objects
 241                 port_string[slot] = strcat(port_string[slot], "\"", head.model, "\" ");
 242                 port_string[slot] = strcat(port_string[slot], ftos(head.skin), " ");
 243                 port_string[slot] = strcat(port_string[slot], ftos(head.alpha), " ");
 244                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.colormod), " ");
 245                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.glowmod), " ");
 246                 port_string[slot] = strcat(port_string[slot], ftos(head.frame), " ");
 247                 port_string[slot] = strcat(port_string[slot], ftos(head.scale), " ");
 248                 port_string[slot] = strcat(port_string[slot], ftos(solidity), " ");
 249                 port_string[slot] = strcat(port_string[slot], ftos(physics), " ");
 250                 port_string[slot] = strcat(port_string[slot], ftos(head.damageforcescale), " ");
 251                 if(head.material)       port_string[slot] = strcat(port_string[slot], "\"", head.material, "\" ");      else    port_string[slot] = strcat(port_string[slot], "- "); // none
 252                 if(database)
 253                 {
 254                         // properties stored only for the database
 255                         if(head.crypto_idfp)    port_string[slot] = strcat(port_string[slot], "\"", head.crypto_idfp, "\" ");   else    port_string[slot] = strcat(port_string[slot], "- "); // none
 256                         port_string[slot] = strcat(port_string[slot], "\"", e.netname, "\" ");
 257                         port_string[slot] = strcat(port_string[slot], "\"", e.message, "\" ");
 258                         port_string[slot] = strcat(port_string[slot], "\"", e.message2, "\" ");
 259                 }
 260         }
 261
 262         // now apply the array to a simple string, with the ; symbol separating objects
 263         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 264         {
 265                 if(port_string[i])
 266                         s = strcat(s, port_string[i], "; ");
 267                 port_string[i] = string_null; // fully clear the string
 268         }
 269
 270         return s;
 271 }
 272
 273 entity sandbox_ObjectPort_Load(string s, float database)
 274 {
 275         // load object properties, and spawn a new object with them
 276         float n, i;
 277         entity e, parent;
 278
 279         // separate objects between the ; symbols
 280         n = tokenizebyseparator(s, "; ");
 281         for(i = 0; i < n; ++i)
 282                 port_string[i] = argv(i);
 283
 284         // now separate and apply the properties of each object
 285         for(i = 0; i < n; ++i)
 286         {
 287                 float argv_num;
 288                 string tagname;
 289                 argv_num = 0;
 290                 tokenize_console(port_string[i]);
 291                 e = sandbox_ObjectSpawn(database);
 292
 293                 // ---------------- OBJECT PROPERTY STORAGE: LOAD ----------------
 294                 if(i)
 295                 {
 296                         // properties stored only for child objects
 297                         if(argv(argv_num) != "-")       tagname = argv(argv_num);       else tagname = string_null;     ++argv_num;
 298                 }
 299                 else
 300                 {
 301                         // properties stored only for parent objects
 302                         if(database)
 303                         {
 304                                 setorigin(e, stov(argv(argv_num)));     ++argv_num;
 305                                 e.angles = stov(argv(argv_num));        ++argv_num;
 306                         }
 307                         parent = e; // mark parent objects as such
 308                 }
 309                 // properties stored for all objects
 310                 setmodel(e, argv(argv_num));    ++argv_num;
 311                 e.skin = stof(argv(argv_num));  ++argv_num;
 312                 e.alpha = stof(argv(argv_num)); ++argv_num;
 313                 e.colormod = stov(argv(argv_num));      ++argv_num;
 314                 e.glowmod = stov(argv(argv_num));       ++argv_num;
 315                 e.frame = stof(argv(argv_num)); ++argv_num;
 316                 sandbox_ObjectEdit_Scale(e, stof(argv(argv_num)));      ++argv_num;
 317                 e.solid = e.old_solid = stof(argv(argv_num));   ++argv_num;
 318                 e.movetype = e.old_movetype = stof(argv(argv_num));     ++argv_num;
 319                 e.damageforcescale = stof(argv(argv_num));      ++argv_num;
 320                 if(e.material)  strunzone(e.material);  if(argv(argv_num) != "-")       e.material = strzone(argv(argv_num));   else    e.material = string_null;       ++argv_num;
 321                 if(database)
 322                 {
 323                         // properties stored only for the database
 324                         if(e.crypto_idfp)       strunzone(e.crypto_idfp);       if(argv(argv_num) != "-")       e.crypto_idfp = strzone(argv(argv_num));        else    e.crypto_idfp = string_null;    ++argv_num;
 325                         if(e.netname)   strunzone(e.netname);   e.netname = strzone(argv(argv_num));    ++argv_num;
 326                         if(e.message)   strunzone(e.message);   e.message = strzone(argv(argv_num));    ++argv_num;
 327                         if(e.message2)  strunzone(e.message2);  e.message2 = strzone(argv(argv_num));   ++argv_num;
 328                 }
 329
 330                 // attach last
 331                 if(i)
 332                         sandbox_ObjectAttach_Set(e, parent, tagname);
 333         }
 334
 335         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 336                 port_string[i] = string_null; // fully clear the string
 337
 338         return e;
 339 }
 340
 341 void sandbox_Database_Save()
 342 {
 343         // saves all objects to the database file
 344         entity head;
 345         string file_name;
 346         float file_get;
 347
 348         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 349         file_get = fopen(file_name, FILE_WRITE);
 350         fputs(file_get, strcat("// sandbox storage \"", autocvar_g_sandbox_storage_name, "\" for map \"", GetMapname(), "\" last updated ", strftime(TRUE, "%d-%m-%Y %H:%M:%S")));
 351         fputs(file_get, strcat(" containing ", ftos(object_count), " objects\n"));
 352
 353         for(head = world; (head = find(head, classname, "object")); )
 354         {
 355                 // attached objects are persisted separately, ignore them here
 356                 if(head.owner != world)
 357                         continue;
 358
 359                 // use a line of text for each object, listing all properties
 360                 fputs(file_get, strcat(sandbox_ObjectPort_Save(head, TRUE), "\n"));
 361         }
 362         fclose(file_get);
 363 }
 364
 365 void sandbox_Database_Load()
 366 {
 367         // loads all objects from the database file
 368         string file_read, file_name;
 369         float file_get, i;
 370
 371         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 372         file_get = fopen(file_name, FILE_READ);
 373         if(file_get < 0)
 374         {
 375                 if(autocvar_g_sandbox_info > 0)
 376                         print(strcat("^3SANDBOX - SERVER: ^7could not find storage file ^3", file_name, "^7, no objects were loaded\n"));
 377         }
 378         else
 379         {
 380                 for(;;)
 381                 {
 382                         file_read = fgets(file_get);
 383                         if(!file_read)
 384                                 break;
 385                         if(substring(file_read, 0, 2) == "//")
 386                                 continue;
 387                         if(substring(file_read, 0, 1) == "#")
 388                                 continue;
 389
 390                         entity e;
 391                         e = sandbox_ObjectPort_Load(file_read, TRUE);
 392
 393                         if(e.material)
 394                         {
 395                                 // since objects are being loaded for the first time, precache material sounds for each
 396                                 for (i = 1; i <= 5; i++) // 5 sounds in total
 397                                         precache_sound(strcat("object/impact_", e.material, "_", ftos(i), ".ogg"));
 398                         }
 399                 }
 400                 if(autocvar_g_sandbox_info > 0)
 401                         print(strcat("^3SANDBOX - SERVER: ^7successfully loaded storage file ^3", file_name, "\n"));
 402         }
 403         fclose(file_get);
 404 }
 405
 406 MUTATOR_HOOKFUNCTION(sandbox_PlayerCommand)
 407 {
 408         if(MUTATOR_RETURNVALUE) // command was already handled?
 409                 return FALSE;
 410         if(cmd_name == "g_sandbox")
 411         {
 412                 if(autocvar_g_sandbox_readonly)
 413                 {
 414                         print_to(self, "^2SANDBOX - INFO: ^7Sandbox mode is active, but in read-only mode. Sandbox commands cannot be used");
 415                         return TRUE;
 416                 }
 417                 if(cmd_argc < 2)
 418                 {
 419                         print_to(self, "^2SANDBOX - INFO: ^7Sandbox mode is active. For usage information, type 'sandbox help'");
 420                         return TRUE;
 421                 }
 422
 423                 switch(argv(1))
 424                 {
 425                         entity e;
 426                         float i;
 427                         string s;
 428
 429                         // ---------------- COMMAND: HELP ----------------
 430                         case "help":
 431                                 print_to(self, "You can use the following sandbox commands:");
 432                                 print_to(self, "^7\"^2object_spawn ^3models/foo/bar.md3^7\" spawns a new object in front of the player, and gives it the specified model");
 433                                 print_to(self, "^7\"^2object_remove^7\" removes the object the player is looking at. Players can only remove their own objects");
 434                                 print_to(self, "^7\"^2object_duplicate ^3value^7\" duplicates the object, if the player has copying rights over the original");
 435                                 print_to(self, "^3copy value ^7- copies the properties of the object to the specified client cvar");
 436                                 print_to(self, "^3paste value ^7- spawns an object with the given properties. Properties or cvars must be specified as follows; eg1: \"0 1 2 ...\", eg2: \"$cl_cvar\"");
 437                                 print_to(self, "^7\"^2object_attach ^3property value^7\" attaches one object to another. Players can only attach their own objects");
 438                                 print_to(self, "^3get ^7- selects the object you are facing as the object to be attached");
 439                                 print_to(self, "^3set value ^7- attaches the previously selected object to the object you are facing, on the specified bone");
 440                                 print_to(self, "^3remove ^7- detaches all objects from the object you are facing");
 441                                 print_to(self, "^7\"^2object_edit ^3property value^7\" edits the given property of the object. Players can only edit their own objects");
 442                                 print_to(self, "^3skin value ^7- changes the skin of the object");
 443                                 print_to(self, "^3alpha value ^7- sets object transparency");
 444                                 print_to(self, "^3colormod \"value_x value_y value_z\" ^7- main object color");
 445                                 print_to(self, "^3glowmod \"value_x value_y value_z\" ^7- glow object color");
 446                                 print_to(self, "^3frame value ^7- object animation frame, for self-animated models");
 447                                 print_to(self, "^3scale value ^7- changes object scale. 0.5 is half size and 2 is double size");
 448                                 print_to(self, "^3solidity value ^7- object collisions, 0 = non-solid, 1 = solid");
 449                                 print_to(self, "^3physics value ^7- object physics, 0 = static, 1 = movable, 2 = physical");
 450                                 print_to(self, "^3force value ^7- amount of force applied to objects that are shot");
 451                                 print_to(self, "^3material value ^7- sets the material of the object. Default materials are: metal, stone, wood, flesh");
 452                                 print_to(self, "^7\"^2object_claim^7\" sets the player as the owner of the object, if he has the right to edit it");
 453                                 print_to(self, "^7\"^2object_info ^3value^7\" shows public information about the object");
 454                                 print_to(self, "^3object ^7- prints general information about the object, such as owner and creation / editing date");
 455                                 print_to(self, "^3mesh ^7- prints information about the object's mesh, including skeletal bones");
 456                                 print_to(self, "^3attachments ^7- prints information about the object's attachments");
 457                                 print_to(self, "^7The ^1drag object ^7key can be used to grab and carry objects. Players can only grab their own objects");
 458                                 return TRUE;
 459
 460                         // ---------------- COMMAND: OBJECT, SPAWN ----------------
 461                         case "object_spawn":
 462                                 if(time < self.object_flood)
 463                                 {
 464                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Flood protection active. Please wait ^3", ftos(self.object_flood - time), " ^7seconds beofore spawning another object"));
 465                                         return TRUE;
 466                                 }
 467                                 self.object_flood = time + autocvar_g_sandbox_editor_flood;
 468                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 469                                 {
 470                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 471                                         return TRUE;
 472                                 }
 473                                 if(cmd_argc < 3)
 474                                 {
 475                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object without specifying a model. Please specify the path to your model file after the 'object_spawn' command");
 476                                         return TRUE;
 477                                 }
 478                                 if not(fexists(argv(2)))
 479                                 {
 480                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object with a non-existent model. Make sure the path to your model file is correct");
 481                                         return TRUE;
 482                                 }
 483
 484                                 e = sandbox_ObjectSpawn(FALSE);
 485                                 setmodel(e, argv(2));
 486
 487                                 if(autocvar_g_sandbox_info > 0)
 488                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " spawned an object at origin ^3", vtos(e.origin), "\n"));
 489                                 return TRUE;
 490
 491                         // ---------------- COMMAND: OBJECT, REMOVE ----------------
 492                         case "object_remove":
 493                                 e = sandbox_ObjectEdit_Get(TRUE);
 494                                 if(e != world)
 495                                 {
 496                                         if(autocvar_g_sandbox_info > 0)
 497                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " removed an object at origin ^3", vtos(e.origin), "\n"));
 498                                         sandbox_ObjectRemove(e);
 499                                         return TRUE;
 500                                 }
 501
 502                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be removed. Make sure you are facing an object that you have edit rights over");
 503                                 return TRUE;
 504
 505                         // ---------------- COMMAND: OBJECT, DUPLICATE ----------------
 506                         case "object_duplicate":
 507                                 switch(argv(2))
 508                                 {
 509                                         case "copy":
 510                                                 // copies customizable properties of the selected object to the clipboard cvar
 511                                                 e = sandbox_ObjectEdit_Get(autocvar_g_sandbox_editor_free); // can we copy objects we can't edit?
 512                                                 if(e != world)
 513                                                 {
 514                                                         s = sandbox_ObjectPort_Save(e, FALSE);
 515                                                         s = strreplace("\"", "\\\"", s);
 516                                                         stuffcmd(self, strcat("set ", argv(3), " \"", s, "\""));
 517
 518                                                         print_to(self, "^2SANDBOX - INFO: ^7Object copied to clipboard");
 519                                                         return TRUE;
 520                                                 }
 521                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be copied. Make sure you are facing an object that you have copy rights over");
 522                                                 return TRUE;
 523
 524                                         case "paste":
 525                                                 // spawns a new object using the properties in the player's clipboard cvar
 526                                                 if(time < self.object_flood)
 527                                                 {
 528                                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Flood protection active. Please wait ^3", ftos(self.object_flood - time), " ^7seconds beofore spawning another object"));
 529                                                         return TRUE;
 530                                                 }
 531                                                 self.object_flood = time + autocvar_g_sandbox_editor_flood;
 532                                                 if(!argv(3)) // no object in clipboard
 533                                                 {
 534                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object in clipboard. You must copy an object before you can paste it");
 535                                                         return TRUE;
 536                                                 }
 537                                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 538                                                 {
 539                                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 540                                                         return TRUE;
 541                                                 }
 542                                                 e = sandbox_ObjectPort_Load(argv(3), FALSE);
 543
 544                                                 print_to(self, "^2SANDBOX - INFO: ^7Object pasted successfully");
 545                                                 if(autocvar_g_sandbox_info > 0)
 546                                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " pasted an object at origin ^3", vtos(e.origin), "\n"));
 547                                                 return TRUE;
 548                                 }
 549                                 return TRUE;
 550
 551                         // ---------------- COMMAND: OBJECT, ATTACH ----------------
 552                         case "object_attach":
 553                                 switch(argv(2))
 554                                 {
 555                                         case "get":
 556                                                 // select e as the object as meant to be attached
 557                                                 e = sandbox_ObjectEdit_Get(TRUE);
 558                                                 if(e != world)
 559                                                 {
 560                                                         self.object_attach = e;
 561                                                         print_to(self, "^2SANDBOX - INFO: ^7Object selected for attachment");
 562                                                         return TRUE;
 563                                                 }
 564                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be selected for attachment. Make sure you are facing an object that you have edit rights over");
 565                                                 return TRUE;
 566                                         case "set":
 567                                                 if(self.object_attach == world)
 568                                                 {
 569                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object selected for attachment. Please select an object to be attached first.");
 570                                                         return TRUE;
 571                                                 }
 572
 573                                                 // attaches the previously selected object to e
 574                                                 e = sandbox_ObjectEdit_Get(TRUE);
 575                                                 if(e != world)
 576                                                 {
 577                                                         sandbox_ObjectAttach_Set(self.object_attach, e, argv(3));
 578                                                         self.object_attach = world; // object was attached, no longer keep it scheduled for attachment
 579                                                         print_to(self, "^2SANDBOX - INFO: ^7Object attached successfully");
 580                                                         if(autocvar_g_sandbox_info > 1)
 581                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " attached objects at origin ^3", vtos(e.origin), "\n"));
 582                                                         return TRUE;
 583                                                 }
 584                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be attached to the parent. Make sure you are facing an object that you have edit rights over");
 585                                                 return TRUE;
 586                                         case "remove":
 587                                                 // removes e if it was attached
 588                                                 e = sandbox_ObjectEdit_Get(TRUE);
 589                                                 if(e != world)
 590                                                 {
 591                                                         sandbox_ObjectAttach_Remove(e);
 592                                                         print_to(self, "^2SANDBOX - INFO: ^7Child objects detached successfully");
 593                                                         if(autocvar_g_sandbox_info > 1)
 594                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " detached objects at origin ^3", vtos(e.origin), "\n"));
 595                                                         return TRUE;
 596                                                 }
 597                                                 print_to(self, "^1SANDBOX - WARNING: ^7Child objects could not be detached. Make sure you are facing an object that you have edit rights over");
 598                                                 return TRUE;
 599                                 }
 600                                 return TRUE;
 601
 602                         // ---------------- COMMAND: OBJECT, EDIT ----------------
 603                         case "object_edit":
 604                                 if(!argv(2))
 605                                 {
 606                                         print_to(self, "^1SANDBOX - WARNING: ^7Too few parameters. You must specify a property to edit");
 607                                         return TRUE;
 608                                 }
 609
 610                                 e = sandbox_ObjectEdit_Get(TRUE);
 611                                 if(e != world)
 612                                 {
 613                                         switch(argv(2))
 614                                         {
 615                                                 case "skin":
 616                                                         e.skin = stof(argv(3));
 617                                                         break;
 618                                                 case "alpha":
 619                                                         e.alpha = stof(argv(3));
 620                                                         break;
 621                                                 case "color_main":
 622                                                         e.colormod = stov(argv(3));
 623                                                         break;
 624                                                 case "color_glow":
 625                                                         e.glowmod = stov(argv(3));
 626                                                         break;
 627                                                 case "frame":
 628                                                         e.frame = stof(argv(3));
 629                                                         break;
 630                                                 case "scale":
 631                                                         sandbox_ObjectEdit_Scale(e, stof(argv(3)));
 632                                                         break;
 633                                                 case "solidity":
 634                                                         switch(argv(3))
 635                                                         {
 636                                                                 case "0": // non-solid
 637                                                                         e.solid = SOLID_TRIGGER;
 638                                                                         break;
 639                                                                 case "1": // solid
 640                                                                         e.solid = SOLID_BBOX;
 641                                                                         break;
 642                                                                 default:
 643                                                                         break;
 644                                                         }
 645                                                 case "physics":
 646                                                         switch(argv(3))
 647                                                         {
 648                                                                 case "0": // static
 649                                                                         e.movetype = MOVETYPE_NONE;
 650                                                                         break;
 651                                                                 case "1": // movable
 652                                                                         e.movetype = MOVETYPE_TOSS;
 653                                                                         break;
 654                                                                 case "2": // physical
 655                                                                         e.movetype = MOVETYPE_PHYSICS;
 656                                                                         break;
 657                                                                 default:
 658                                                                         break;
 659                                                         }
 660                                                         break;
 661                                                 case "force":
 662                                                         e.damageforcescale = stof(argv(3));
 663                                                         break;
 664                                                 case "material":
 665                                                         if(e.material)  strunzone(e.material);
 666                                                         if(argv(3))
 667                                                         {
 668                                                                 for (i = 1; i <= 5; i++) // precache material sounds, 5 in total
 669                                                                         precache_sound(strcat("object/impact_", argv(3), "_", ftos(i), ".ogg"));
 670                                                                 e.material = strzone(argv(3));
 671                                                         }
 672                                                         else
 673                                                                 e.material = string_null; // no material
 674                                                         break;
 675                                                 default:
 676                                                         print_to(self, "^1SANDBOX - WARNING: ^7Invalid object property. For usage information, type 'sandbox help'");
 677                                                         return TRUE;
 678                                         }
 679
 680                                         // update last editing time
 681                                         if(e.message2)  strunzone(e.message2);
 682                                         e.message2 = strzone(strftime(TRUE, "%d-%m-%Y %H:%M:%S"));
 683
 684                                         if(autocvar_g_sandbox_info > 1)
 685                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " edited property ^3", argv(2), " ^7of an object at origin ^3", vtos(e.origin), "\n"));
 686                                         return TRUE;
 687                                 }
 688
 689                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be edited. Make sure you are facing an object that you have edit rights over");
 690                                 return TRUE;
 691
 692                         // ---------------- COMMAND: OBJECT, CLAIM ----------------
 693                         case "object_claim":
 694                                 // if the player can edit an object but is not its owner, this can be used to claim that object
 695                                 if(self.crypto_idfp == "")
 696                                 {
 697                                         print_to(self, "^1SANDBOX - WARNING: ^7You do not have a player UID, and cannot claim objects");
 698                                         return TRUE;
 699                                 }
 700                                 e = sandbox_ObjectEdit_Get(TRUE);
 701                                 if(e != world)
 702                                 {
 703                                         // update the owner's name
 704                                         // Do this before checking if you're already the owner and skipping if such, so we
 705                                         // also update the player's nickname if he changed it (but has the same player UID)
 706                                         if(e.netname != self.netname)
 707                                         {
 708                                                 if(e.netname)   strunzone(e.netname);
 709                                                 e.netname = strzone(self.netname);
 710                                                 print_to(self, "^2SANDBOX - INFO: ^7Object owner name updated");
 711                                         }
 712
 713                                         if(e.crypto_idfp == self.crypto_idfp)
 714                                         {
 715                                                 print_to(self, "^2SANDBOX - INFO: ^7Object is already yours, nothing to claim");
 716                                                 return TRUE;
 717                                         }
 718
 719                                         if(e.crypto_idfp)       strunzone(e.crypto_idfp);
 720                                         e.crypto_idfp = strzone(self.crypto_idfp);
 721
 722                                         print_to(self, "^2SANDBOX - INFO: ^7Object claimed successfully");
 723                                 }
 724                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be claimed. Make sure you are facing an object that you have edit rights over");
 725                                 return TRUE;
 726
 727                         // ---------------- COMMAND: OBJECT, INFO ----------------
 728                         case "object_info":
 729                                 // prints public information about the object to the player
 730                                 e = sandbox_ObjectEdit_Get(FALSE);
 731                                 if(e != world)
 732                                 {
 733                                         switch(argv(2))
 734                                         {
 735                                                 case "object":
 736                                                         print_to(self, strcat("^2SANDBOX - INFO: ^7Object is owned by \"^7", e.netname, "^7\", created \"^3", e.message, "^7\", last edited \"^3", e.message2, "^7\""));
 737                                                         return TRUE;
 738                                                 case "mesh":
 739                                                         for(i = 1; gettaginfo(e, i); i++)
 740                                                                 s = strcat(s, "^7\"^5", gettaginfo_name, "^7\", ");
 741                                                         print_to(self, strcat("^2SANDBOX - INFO: ^7Object mesh is \"^3", e.model, "^7\" at animation frame ^3", ftos(e.frame), " ^7containing the following tags: ", s));
 742                                                         return TRUE;
 743                                                 case "attachments":
 744                                                         // this should show the same info as 'mesh' but for attachments
 745                                                         entity head;
 746                                                         for(head = world; (head = find(head, classname, "object")); )
 747                                                         {
 748                                                                 if(head.owner == e)
 749                                                                 {
 750                                                                         ++i; // start from 1
 751                                                                         gettaginfo(e, head.tag_index);
 752                                                                         s = strcat(s, "^1attachment ", ftos(i), "^7 has mesh \"^3", head.model, "^7\" at animation frame ^3", ftos(head.frame));
 753                                                                         s = strcat(s, "^7 and is attached to bone \"^5", gettaginfo_name, "^7\", ");
 754                                                                 }
 755                                                         }
 756                                                         if(i) // object contains attachments
 757                                                                 print_to(self, strcat("^2SANDBOX - INFO: ^7Object contains the following ^1", ftos(i), "^7 attachment(s): ", s));
 758                                                         else
 759                                                                 print_to(self, "^2SANDBOX - INFO: ^7Object contains no attachments");
 760                                                         return TRUE;
 761                                         }
 762                                 }
 763                                 print_to(self, "^1SANDBOX - WARNING: ^7No information could be found. Make sure you are facing an object");
 764                                 return TRUE;
 765
 766                         // ---------------- COMMAND: DEFAULT ----------------
 767                         default:
 768                                 print_to(self, "Invalid command. For usage information, type 'sandbox help'");
 769                                 return TRUE;
 770                 }
 771         }
 772         return FALSE;
 773 }
 774
 775 float autosave_time;
 776 MUTATOR_HOOKFUNCTION(sandbox_StartFrame)
 777 {
 778         if(!autocvar_g_sandbox_storage_autosave)
 779                 return FALSE;
 780         if(time < autosave_time)
 781                 return FALSE;
 782         autosave_time = time + autocvar_g_sandbox_storage_autosave;
 783
 784         sandbox_Database_Save();
 785
 786         return TRUE;
 787 }
 788
 789 MUTATOR_DEFINITION(sandbox)
 790 {
 791         MUTATOR_HOOK(SV_ParseClientCommand, sandbox_PlayerCommand, CBC_ORDER_ANY);
 792         MUTATOR_HOOK(SV_StartFrame, sandbox_StartFrame, CBC_ORDER_ANY);
 793
 794         MUTATOR_ONADD
 795         {
 796                 autosave_time = time + autocvar_g_sandbox_storage_autosave; // don't save the first server frame
 797                 if(autocvar_g_sandbox_storage_autoload)
 798                         sandbox_Database_Load();
 799         }
 800
 801         return FALSE;
 802 }
 803