qcsrc/server/nexball.qc

   1 //EF_BRIGHTFIELD|EF_BRIGHTLIGHT|EF_DIMLIGHT|EF_BLUE|EF_RED|EF_FLAME
   2 #define BALL_EFFECTMASK 1229
   3 #define BALL_MINS '-16 -16 -16'  // The model is 24*24*24
   4 #define BALL_MAXS '16 16 16'
   5 #define BALL_ATTACHORG '3 0 16'
   6 #define BALL_SPRITECOLOR '.91 .85 .62'
   7 #define BALL_FOOT   1
   8 #define BALL_BASKET 2
   9 //spawnflags
  10 #define GOAL_TOUCHPLAYER 1
  11 //goal types
  12 #define GOAL_FAULT -1
  13 #define GOAL_OUT -2
  14
  15 #define CVTOV(s) s = cvar( #s )
  16
  17 float g_nexball_football_boost_forward;
  18 float g_nexball_football_boost_up;
  19 float g_nexball_football_physics;
  20 float g_nexball_delay_idle;
  21 float g_nexball_basketball_delay_hold;
  22 float g_nexball_basketball_delay_hold_forteam;
  23 float g_nexball_basketball_effects_default;
  24 float g_nexball_basketball_teamsteal;
  25 float balls;
  26 float ball_scale;
  27 float nb_teams;
  28
  29 .float teamtime;
  30
  31 void nb_delayedinit();
  32 void nb_init() // Called early (worldspawn stage)
  33 {
  34         CVTOV(g_nexball_meter_period); //sent with the client init entity
  35         if (g_nexball_meter_period <= 0)
  36                 g_nexball_meter_period = 2; // avoid division by zero etc. due to silly users
  37         g_nexball_meter_period = rint(g_nexball_meter_period * 32) / 32; //Round to 1/32ths to send as a byte multiplied by 32
  38         addstat(STAT_NB_METERSTART, AS_FLOAT, metertime);
  39
  40         // General settings
  41         CVTOV(g_nexball_football_boost_forward);   //100
  42         CVTOV(g_nexball_football_boost_up);        //200
  43         CVTOV(g_nexball_delay_idle);               //10
  44         CVTOV(g_nexball_football_physics);         //0
  45
  46         radar_showennemies = cvar("g_nexball_radar_showallplayers");
  47
  48         InitializeEntity(world, nb_delayedinit, INITPRIO_GAMETYPE);
  49 }
  50
  51 float OtherTeam(float t)  //works only if there are two teams on the map!
  52 {
  53         entity e;
  54         e = find(world, classname, "nexball_team");
  55         if (e.team == t)
  56                 e = find(e, classname, "nexball_team");
  57         return e.team;
  58 }
  59
  60 void ResetBall();
  61
  62 void LogNB(string mode, entity actor)
  63 {
  64         string s;
  65         if(!cvar("sv_eventlog"))
  66                 return;
  67         s = strcat(":nexball:", mode);
  68         if(actor != world)
  69                 s = strcat(s, ":", ftos(actor.playerid));
  70         GameLogEcho(s);
  71 }
  72
  73 void ball_restart (void)
  74 {
  75         if(self.owner)
  76                 DropBall(self, self.owner.origin, '0 0 0');
  77         ResetBall();
  78 }
  79
  80 void nexball_setstatus (void)
  81 {
  82         local entity oldself;
  83         if (!g_nexball)
  84                 return;
  85         if (self.ballcarried)
  86         {
  87                 if (self.ballcarried.teamtime && (self.ballcarried.teamtime < time))
  88                 {
  89                         bprint("The ", ColoredTeamName(self.team), " held the ball for too long.\n");
  90                         oldself = self;
  91                         self = self.ballcarried;
  92                         DropBall(self, self.owner.origin, '0 0 0');
  93                         ResetBall();
  94                         self = oldself;
  95                 } else
  96                         self.items |= IT_KEY1;
  97         }
  98 }
  99
 100 void relocate_nexball (void)
 101 {
 102         tracebox(self.origin, BALL_MINS, BALL_MAXS, self.origin, TRUE, self);
 103         if (trace_startsolid)
 104         {
 105                 vector o;
 106                 o = self.origin;
 107                 if(!move_out_of_solid(self))
 108                         objerror("could not get out of solid at all!");
 109                 print("^1NOTE: this map needs FIXING. ", self.classname, " at ", vtos(o - '0 0 1'));
 110                 print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 111                 print(" ", ftos(self.origin_y - o_y));
 112                 print(" ", ftos(self.origin_z - o_z), "'\n");
 113                 self.origin = o;
 114         }
 115 }
 116
 117 void basketball_touch();
 118 void football_touch();
 119
 120 void DropOwner (void)
 121 {
 122         local entity ownr;
 123         ownr = self.owner;
 124         DropBall(self, ownr.origin, ownr.velocity);
 125         makevectors(ownr.v_angle_y * '0 1 0');
 126         ownr.velocity += ('0 0 0.75' - v_forward) * 1000;
 127         ownr.flags &~= FL_ONGROUND;
 128 }
 129
 130 void GiveBall (entity plyr, entity ball)
 131 {
 132         local entity ownr;
 133
 134         if ((ownr = ball.owner))
 135         {
 136                 ownr.effects &~= g_nexball_basketball_effects_default;
 137                 ownr.ballcarried = world;
 138                 if (ownr.metertime)
 139                 {
 140                         ownr.metertime = 0;
 141                         ownr.weaponentity.state = WS_READY;
 142                 }
 143                 WaypointSprite_Kill(ownr.waypointsprite_attachedforcarrier);
 144         }
 145         else
 146         {
 147                 WaypointSprite_Kill(ball.waypointsprite_attachedforcarrier);
 148         }
 149
 150         setattachment(ball, plyr, "");
 151         setorigin(ball, BALL_ATTACHORG);
 152
 153         if (ball.team != plyr.team)
 154                 ball.teamtime = time + g_nexball_basketball_delay_hold_forteam;
 155
 156         ball.owner = ball.pusher = plyr; //"owner" is set to the player carrying, "pusher" to the last player who touched it
 157         ball.team = plyr.team;
 158         plyr.ballcarried = ball;
 159         ball.dropperid = plyr.playerid;
 160
 161         plyr.effects |= g_nexball_basketball_effects_default;
 162         ball.effects &~= g_nexball_basketball_effects_default;
 163
 164         ball.velocity = '0 0 0';
 165         ball.movetype = MOVETYPE_NONE;
 166         ball.touch = SUB_Null;
 167         ball.effects |= EF_NOSHADOW;
 168         ball.scale = 1; // scale down.
 169
 170         WaypointSprite_AttachCarrier("nb-ball", plyr);
 171         WaypointSprite_UpdateRule(plyr.waypointsprite_attachedforcarrier, 0, SPRITERULE_DEFAULT);
 172         WaypointSprite_UpdateTeamRadar(plyr.waypointsprite_attachedforcarrier, RADARICON_FLAGCARRIER, BALL_SPRITECOLOR);
 173
 174         if (g_nexball_basketball_delay_hold)
 175         {
 176                 ball.think = DropOwner;
 177                 ball.nextthink = time + g_nexball_basketball_delay_hold;
 178         }
 179 }
 180
 181 void DropBall (entity ball, vector org, vector vel)
 182 {
 183         ball.effects |= g_nexball_basketball_effects_default;
 184         ball.effects &~= EF_NOSHADOW;
 185         ball.owner.effects &~= g_nexball_basketball_effects_default;
 186
 187         setattachment(ball, world, "");
 188         setorigin (ball, org);
 189         ball.movetype = MOVETYPE_BOUNCE;
 190         ball.flags &~= FL_ONGROUND;
 191         ball.scale = ball_scale;
 192         ball.velocity = vel;
 193         ball.ctf_droptime = time;
 194         ball.touch = basketball_touch;
 195         ball.think = ResetBall;
 196         ball.nextthink = min(time + g_nexball_delay_idle, ball.teamtime);
 197
 198         if (ball.owner.metertime)
 199         {
 200                 ball.owner.metertime = 0;
 201                 ball.owner.weaponentity.state = WS_READY;
 202         }
 203
 204         WaypointSprite_Kill(ball.owner.waypointsprite_attachedforcarrier);
 205         //WaypointSprite_AttachCarrier("nb-ball", ball);
 206         WaypointSprite_Spawn("nb-ball", 0, 0, ball, '0 0 64', world, ball.team, ball, waypointsprite_attachedforcarrier, FALSE); // no health bar please
 207         WaypointSprite_UpdateRule(ball.waypointsprite_attachedforcarrier, 0, SPRITERULE_DEFAULT);
 208         WaypointSprite_UpdateTeamRadar(ball.waypointsprite_attachedforcarrier, RADARICON_FLAGCARRIER, BALL_SPRITECOLOR);
 209
 210         ball.owner.ballcarried = world;
 211         ball.owner = world;
 212 }
 213
 214 void InitBall (void)
 215 {
 216         if (gameover) return;
 217         self.flags &~= FL_ONGROUND;
 218         self.movetype = MOVETYPE_BOUNCE;
 219         if (self.classname == "nexball_basketball")
 220                 self.touch = basketball_touch;
 221         else if (self.classname == "nexball_football")
 222                 self.touch = football_touch;
 223         self.cnt = 0;
 224         self.think = ResetBall;
 225         self.nextthink = time + g_nexball_delay_idle + 3;
 226         self.teamtime = 0;
 227         self.pusher = world;
 228         self.team = FALSE;
 229         sound (self, CHAN_PROJECTILE, self.noise1, VOL_BASE, ATTN_NORM);
 230         WaypointSprite_Ping(self.waypointsprite_attachedforcarrier);
 231         LogNB("init", world);
 232 }
 233
 234 void ResetBall (void)
 235 {
 236         if (self.cnt < 2) { // step 1
 237                 if (time == self.teamtime)
 238                         bprint("The ", ColoredTeamName(self.team), " held the ball for too long.\n");
 239                 self.touch = SUB_Null;
 240                 self.movetype = MOVETYPE_NOCLIP;
 241                 self.velocity = '0 0 0'; // just in case?
 242                 if(!self.cnt)
 243                         LogNB("resetidle", world);
 244                 self.cnt = 2;
 245                 self.nextthink = time;
 246         } else if (self.cnt < 4) { // step 2 and 3
 247 //              dprint("Step ", ftos(self.cnt), ": Calculated velocity: ", vtos(self.spawnorigin - self.origin), ", time: ", ftos(time), "\n");
 248                 self.velocity = (self.spawnorigin - self.origin) * (self.cnt - 1); // 1 or 0.5 second movement
 249                 self.nextthink = time + 0.5;
 250                 self.cnt += 1;
 251         } else { // step 4
 252 //              dprint("Step 4: time: ", ftos(time), "\n");
 253                 if (vlen(self.origin - self.spawnorigin) > 10) // should not happen anymore
 254                         dprint("The ball moved too far away from its spawn origin.\nOffset: ",
 255                                vtos(self.origin - self.spawnorigin), " Velocity: ", vtos(self.velocity), "\n");
 256                 self.velocity = '0 0 0';
 257                 setorigin(self, self.spawnorigin); // make sure it's positioned correctly anyway
 258                 self.movetype = MOVETYPE_NONE;
 259                 self.think = InitBall;
 260                 self.nextthink = max(time, game_starttime) + cvar("g_nexball_delay_start");
 261         }
 262 }
 263
 264 void football_touch (void)
 265 {
 266         if (other.solid == SOLID_BSP) {
 267                 if (time > self.lastground + 0.1)
 268                 {
 269                         sound (self, CHAN_PROJECTILE, self.noise, VOL_BASE, ATTN_NORM);
 270                         self.lastground = time;
 271                 }
 272                 if (vlen(self.velocity) && !self.cnt)
 273                         self.nextthink = time + g_nexball_delay_idle;
 274                 return;
 275         }
 276         if (other.classname != "player")
 277                 return;
 278         if (other.health < 1)
 279                 return;
 280         if (!self.cnt)
 281                 self.nextthink = time + g_nexball_delay_idle;
 282
 283         self.pusher = other;
 284         self.team = other.team;
 285
 286         if (g_nexball_football_physics == -1) { // MrBougo try 1, before decompiling Rev's original
 287                 if (vlen(other.velocity))
 288                         self.velocity = other.velocity * 1.5 + '0 0 1' * g_nexball_football_boost_up;
 289         } else if (g_nexball_football_physics == 1) { // MrBougo's modded Rev style: partially independant of the height of the aiming point
 290                 makevectors(other.v_angle);
 291                 self.velocity = other.velocity + v_forward * g_nexball_football_boost_forward + '0 0 1' * g_nexball_football_boost_up;
 292         } else if (g_nexball_football_physics == 2) { // 2nd mod try: totally independant. Really playable!
 293                 makevectors(other.v_angle_y * '0 1 0');
 294                 self.velocity = other.velocity + v_forward * g_nexball_football_boost_forward + v_up * g_nexball_football_boost_up;
 295         } else { // Revenant's original style (from the original mod's disassembly, acknowledged by Revenant)
 296                 makevectors(other.v_angle);
 297                 self.velocity = other.velocity + v_forward * g_nexball_football_boost_forward + v_up * g_nexball_football_boost_up;
 298         }
 299         self.avelocity = -250 * v_forward;  // maybe there is a way to make it look better?
 300 }
 301
 302 void basketball_touch (void)
 303 {
 304         if (other.ballcarried)
 305         {
 306                 football_touch();
 307                 return;
 308         }
 309         if (!self.cnt && other.classname == "player" && (other.playerid != self.dropperid || time > self.ctf_droptime + cvar("g_nexball_delay_collect"))) {
 310                 if (other.health <= 0)
 311                         return;
 312                 LogNB("caught", other);
 313                 GiveBall(other, self);
 314         } else if (other.solid == SOLID_BSP) {
 315                 sound (self, CHAN_PROJECTILE, self.noise, VOL_BASE, ATTN_NORM);
 316                 if (vlen(self.velocity) && !self.cnt)
 317                         self.nextthink = min(time + g_nexball_delay_idle, self.teamtime);
 318         }
 319 }
 320
 321 void GoalTouch (void)
 322 {
 323         entity ball;
 324         float isclient, pscore, otherteam;
 325         string pname;
 326
 327         if (gameover) return;
 328         if ((self.spawnflags & GOAL_TOUCHPLAYER) && other.ballcarried)
 329                 ball = other.ballcarried;
 330         else
 331                 ball = other;
 332         if (ball.classname != "nexball_basketball")
 333         if (ball.classname != "nexball_football")
 334                 return;
 335         if ((!ball.pusher && self.team != GOAL_OUT) || ball.cnt)
 336                 return;
 337         EXACTTRIGGER_TOUCH;
 338
 339
 340         if(nb_teams == 2)
 341                 otherteam = OtherTeam(ball.team);
 342
 343         if((isclient = ball.pusher.flags & FL_CLIENT))
 344                 pname = ball.pusher.netname;
 345         else
 346                 pname = "Someone (?)";
 347
 348         if        (ball.team == self.team) //owngoal (regular goals)
 349         {
 350                 LogNB("owngoal", ball.pusher);
 351                 bprint("Boo! ", pname, "^7 scored a goal against their own team!\n");
 352                 pscore = -1;
 353         } else if (self.team == GOAL_FAULT) {
 354                 LogNB("fault", ball.pusher);
 355                 if (nb_teams == 2)
 356                         bprint(ColoredTeamName(otherteam), " gets a point due to ", pname, "^7's silliness.\n");
 357                 else
 358                         bprint(ColoredTeamName(ball.team), " loses a point due to ", pname, "^7's silliness.\n");
 359                 pscore = -1;
 360         } else if (self.team == GOAL_OUT) {
 361                 LogNB("out", ball.pusher);
 362                 if ((self.spawnflags & GOAL_TOUCHPLAYER) && ball.owner)
 363                         bprint(pname, "^7 went out of bounds.\n");
 364                 else
 365                         bprint("The ball was returned.\n");
 366                 pscore = 0;
 367         } else {                           //score
 368                 LogNB(strcat("goal:", ftos(self.team)), ball.pusher);
 369                 bprint("Goaaaaal! ", pname, "^7 scored a point for the ", ColoredTeamName(ball.team), ".\n");
 370                 pscore = 1;
 371         }
 372
 373         sound (ball, CHAN_AUTO, self.noise, VOL_BASE, ATTN_NONE);
 374
 375         if(ball.team && pscore)
 376         {
 377                 if (nb_teams == 2 && pscore < 0)
 378                         TeamScore_AddToTeam(otherteam, ST_NEXBALL_GOALS, -pscore);
 379                 else
 380                         TeamScore_AddToTeam(ball.team, ST_NEXBALL_GOALS, pscore);
 381         }
 382         if (isclient)
 383         {
 384                 if (pscore > 0)
 385                         PlayerScore_Add(ball.pusher, SP_NEXBALL_GOALS, pscore);
 386                 else if (pscore < 0)
 387                         PlayerScore_Add(ball.pusher, SP_NEXBALL_FAULTS, -pscore);
 388         }
 389
 390         if (ball.owner) // Happens on spawnflag GOAL_TOUCHPLAYER
 391                 DropBall(ball, ball.owner.origin, ball.owner.velocity);
 392
 393         WaypointSprite_Ping(ball.waypointsprite_attachedforcarrier);
 394
 395         ball.cnt = 1;
 396         ball.think = ResetBall;
 397         if (ball.classname == "nexball_basketball")
 398                 ball.touch = football_touch; // better than SUB_Null: football control until the ball gets reset
 399         ball.nextthink = time + cvar("g_nexball_delay_goal") * (self.team != GOAL_OUT);
 400 }
 401
 402 //=======================//
 403 //       team ents       //
 404 //=======================//
 405 void spawnfunc_nexball_team (void)
 406 {
 407         if(!g_nexball) { remove(self); return; }
 408         self.team = self.cnt + 1;
 409 }
 410
 411 void nb_spawnteam (string teamname, float teamcolor)
 412 {
 413         dprint("^2spawned team ", teamname, "\n");
 414         local entity e;
 415         e = spawn();
 416         e.classname = "nexball_team";
 417         e.netname = teamname;
 418         e.cnt = teamcolor;
 419         e.team = e.cnt + 1;
 420         nb_teams += 1;
 421 };
 422
 423 void nb_spawnteams (void)
 424 {
 425         float t_r, t_b, t_y, t_p;
 426         entity e;
 427         for(e = world; (e = find(e, classname, "nexball_goal")); )
 428         {
 429                 switch(e.team)
 430                 {
 431                         case COLOR_TEAM1: if(!t_r) { nb_spawnteam ("Red", e.team-1)   ; t_r = 1; } break;
 432                         case COLOR_TEAM2: if(!t_b) { nb_spawnteam ("Blue", e.team-1)  ; t_b = 1; } break;
 433                         case COLOR_TEAM3: if(!t_y) { nb_spawnteam ("Yellow", e.team-1); t_y = 1; } break;
 434                         case COLOR_TEAM4: if(!t_p) { nb_spawnteam ("Pink", e.team-1)  ; t_p = 1; } break;
 435                 }
 436         }
 437 }
 438
 439 void nb_delayedinit (void)
 440 {
 441         if (find(world, classname, "nexball_team") == world)
 442                 nb_spawnteams();
 443         ScoreRules_nexball(nb_teams);
 444 }
 445
 446
 447 //=======================//
 448 //      spawnfuncs       //
 449 //=======================//
 450
 451 void SpawnBall (void)
 452 {
 453         if(!g_nexball) { remove(self); return; }
 454
 455 //      balls += 4; // using the remaining bits to count balls will leave more than the max edict count, so it's fine
 456
 457         if (!self.model) {
 458                 self.model = "models/nexball/ball.md3";
 459                 self.scale = 1.3;
 460         }
 461
 462         precache_model (self.model);
 463         setmodel (self, self.model);
 464         setsize (self, BALL_MINS, BALL_MAXS);
 465         ball_scale = self.scale;
 466
 467         relocate_nexball();
 468         self.spawnorigin = self.origin;
 469
 470         self.effects = self.effects | EF_LOWPRECISION;
 471
 472         if (cvar(strcat("g_", self.classname, "_trail"))) //nexball_basketball :p
 473         {
 474                 self.glow_color = cvar("g_nexball_trail_color");
 475                 self.glow_trail = TRUE;
 476         }
 477
 478         self.movetype = MOVETYPE_FLY;
 479
 480         if (!cvar("g_nexball_sound_bounce"))
 481                 self.noise = "";
 482         else if (!self.noise)
 483                 self.noise = "sound/nexball/bounce.wav";
 484                 //bounce sound placeholder (FIXME)
 485         if (!self.noise1)
 486                 self.noise1 = "sound/nexball/drop.wav";
 487                 //ball drop sound placeholder (FIXME)
 488         if (!self.noise2)
 489                 self.noise2 = "sound/nexball/steal.wav";
 490                 //stealing sound placeholder (FIXME)
 491         if (self.noise) precache_sound (self.noise);
 492         precache_sound (self.noise1);
 493         precache_sound (self.noise2);
 494
 495         WaypointSprite_AttachCarrier("nb-ball", self); // the ball's team is not set yet, no rule update needed
 496         WaypointSprite_UpdateTeamRadar(self.waypointsprite_attachedforcarrier, RADARICON_FLAGCARRIER, BALL_SPRITECOLOR);
 497
 498         self.reset = ball_restart;
 499         self.think = InitBall;
 500         self.nextthink = game_starttime + cvar("g_nexball_delay_start");
 501 }
 502
 503 void spawnfunc_nexball_basketball (void)
 504 {
 505         self.classname = "nexball_basketball";
 506         if not(balls & BALL_BASKET)
 507         {
 508                 CVTOV(g_nexball_basketball_effects_default);
 509                 CVTOV(g_nexball_basketball_delay_hold);
 510                 CVTOV(g_nexball_basketball_delay_hold_forteam);
 511                 CVTOV(g_nexball_basketball_teamsteal);
 512                 g_nexball_basketball_effects_default = g_nexball_basketball_effects_default & BALL_EFFECTMASK;
 513         }
 514         if (!self.effects)
 515                 self.effects = g_nexball_basketball_effects_default;
 516         self.solid = SOLID_TRIGGER;
 517         balls |= BALL_BASKET;
 518         self.bouncefactor = cvar("g_nexball_basketball_bouncefactor");
 519         self.bouncestop = cvar("g_nexball_basketball_bouncestop");
 520         SpawnBall();
 521 }
 522
 523 void spawnfunc_nexball_football (void)
 524 {
 525         self.classname = "nexball_football";
 526         self.solid = SOLID_TRIGGER;
 527         balls |= BALL_FOOT;
 528         self.bouncefactor = cvar("g_nexball_football_bouncefactor");
 529         self.bouncestop = cvar("g_nexball_football_bouncestop");
 530         SpawnBall();
 531 }
 532
 533 void SpawnGoal (void)
 534 {
 535         if(!g_nexball) { remove(self); return; }
 536         EXACTTRIGGER_INIT;
 537         self.classname = "nexball_goal";
 538         if (!self.noise)
 539                 self.noise = "ctf/respawn.wav";
 540         precache_sound(self.noise);
 541         self.touch = GoalTouch;
 542 }
 543
 544 void spawnfunc_nexball_redgoal (void)
 545 {
 546         self.team = COLOR_TEAM1;
 547         SpawnGoal();
 548 }
 549 void spawnfunc_nexball_bluegoal (void)
 550 {
 551         self.team = COLOR_TEAM2;
 552         SpawnGoal();
 553 }
 554 void spawnfunc_nexball_yellowgoal (void)
 555 {
 556         self.team = COLOR_TEAM3;
 557         SpawnGoal();
 558 }
 559 void spawnfunc_nexball_pinkgoal (void)
 560 {
 561         self.team = COLOR_TEAM4;
 562         SpawnGoal();
 563 }
 564
 565 void spawnfunc_nexball_fault (void)
 566 {
 567         self.team = GOAL_FAULT;
 568         if (!self.noise)
 569                 self.noise = "misc/typehit.wav";
 570         SpawnGoal();
 571 }
 572
 573 void spawnfunc_nexball_out (void)
 574 {
 575         self.team = GOAL_OUT;
 576         if (!self.noise)
 577                 self.noise = "misc/typehit.wav";
 578         SpawnGoal();
 579 }
 580
 581 //
 582 //Spawnfuncs preserved for compatibility
 583 //
 584
 585 void spawnfunc_ball            (void) { spawnfunc_nexball_football(); }
 586 void spawnfunc_ball_football   (void) { spawnfunc_nexball_football(); }
 587 void spawnfunc_ball_basketball (void) { spawnfunc_nexball_basketball(); }
 588 // The "red goal" is defended by blue team. A ball in there counts as a point for red.
 589 void spawnfunc_ball_redgoal    (void) { spawnfunc_nexball_bluegoal(); } // I blame Revenant
 590 void spawnfunc_ball_bluegoal   (void) { spawnfunc_nexball_redgoal(); }  // but he didn't mean to cause trouble :p
 591 void spawnfunc_ball_fault      (void) { spawnfunc_nexball_fault(); }
 592 void spawnfunc_ball_bound      (void) { spawnfunc_nexball_out(); }
 593
 594 //=======================//
 595 //      Weapon code      //
 596 //=======================//
 597
 598 void W_Nexball_Touch (void)
 599 {
 600         local entity ball, attacker;
 601         attacker = self.owner;
 602
 603         PROJECTILE_TOUCH;
 604         if(attacker.team != other.team || g_nexball_basketball_teamsteal)
 605         if((ball = other.ballcarried) && (attacker.classname == "player" || attacker.classname == "gib"))
 606         {
 607                 other.velocity = other.velocity + normalize(self.velocity) * other.damageforcescale * cvar("g_balance_nexball_secondary_force");
 608                 other.flags &~= FL_ONGROUND;
 609                 if(!attacker.ballcarried)
 610                 {
 611                         LogNB("stole", attacker);
 612                         sound (other, CHAN_AUTO, ball.noise2, VOL_BASE, ATTN_NORM);
 613
 614                         if(attacker.team == other.team && time > attacker.teamkill_complain)
 615                         {
 616                                 attacker.teamkill_complain = time + 5;
 617                                 attacker.teamkill_soundtime = time + 0.4;
 618                                 attacker.teamkill_soundsource = other;
 619                         }
 620
 621                         GiveBall(attacker, other.ballcarried);
 622                 }
 623         }
 624         remove(self);
 625 }
 626
 627 void W_Nexball_Attack (float t)
 628 {
 629         local entity ball;
 630         local float mul, mi, ma;
 631         if (!(ball = self.ballcarried))
 632                 return;
 633
 634         W_SetupShot (self, FALSE, 4, "nexball/shoot1.wav",0);
 635         tracebox(w_shotorg, BALL_MINS, BALL_MAXS, w_shotorg, MOVE_WORLDONLY, world);
 636         if(trace_startsolid)
 637         {
 638                 if(self.metertime)
 639                         self.metertime = 0; // Shot failed, hide the power meter
 640                 return;
 641         }
 642
 643         //Calculate multiplier
 644         if (t < 0)
 645                 mul = 1;
 646         else
 647         {
 648                 mi = cvar("g_nexball_basketball_meter_minpower");
 649                 ma = max(mi, cvar("g_nexball_basketball_meter_maxpower")); // avoid confusion
 650                 //One triangle wave period with 1 as max
 651                 mul = 2 * mod(t, g_nexball_meter_period) / g_nexball_meter_period;
 652                 if (mul > 1)
 653                         mul = 2 - mul;
 654                 mul = mi + (ma - mi) * mul; // range from the minimal power to the maximal power
 655         }
 656         DropBall (ball, w_shotorg, W_CalculateProjectileVelocity(self.velocity, w_shotdir * cvar("g_balance_nexball_primary_speed") * mul, FALSE));
 657         //TODO: use the speed_up cvar too ??
 658 }
 659
 660 void W_Nexball_Attack2 (void)
 661 {
 662         local entity missile;
 663         if (!(balls & BALL_BASKET))
 664                 return;
 665         W_SetupShot (self, FALSE, 2, "nexball/shoot2.wav",0);
 666 //      pointparticles(particleeffectnum("grenadelauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 667         missile = spawn ();
 668
 669         missile.owner = self;
 670         missile.classname = "ballstealer";
 671
 672         missile.movetype = MOVETYPE_FLY;
 673         PROJECTILE_MAKETRIGGER(missile);
 674
 675         setmodel (missile, "models/elaser.mdl"); // precision set below
 676         setsize (missile, '0 0 0', '0 0 0');
 677         setorigin (missile, w_shotorg);
 678
 679         W_SetupProjectileVelocity(missile, cvar("g_balance_nexball_secondary_speed"), 0);
 680         missile.angles = vectoangles (missile.velocity);
 681         missile.touch = W_Nexball_Touch;
 682         missile.think = SUB_Remove;
 683         missile.nextthink = time + cvar("g_balance_nexball_secondary_lifetime"); //FIXME: use a distance instead?
 684
 685         missile.effects = EF_BRIGHTFIELD | EF_LOWPRECISION;
 686         missile.flags = FL_PROJECTILE;
 687 }
 688
 689 float w_nexball_weapon(float req)
 690 {
 691         if (req == WR_THINK)
 692         {
 693                 if (self.BUTTON_ATCK)
 694                 if (weapon_prepareattack(0, cvar("g_balance_nexball_primary_refire")))
 695                 if (cvar("g_nexball_basketball_meter"))
 696                 {
 697                         if (self.ballcarried && !self.metertime)
 698                                 self.metertime = time;
 699                         else
 700                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_nexball_primary_animtime"), w_ready);
 701                 }
 702                 else
 703                 {
 704                         W_Nexball_Attack(-1);
 705                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_nexball_primary_animtime"), w_ready);
 706                 }
 707                 if (self.BUTTON_ATCK2)
 708                 if (weapon_prepareattack(1, cvar("g_balance_nexball_secondary_refire")))
 709                 {
 710                         W_Nexball_Attack2();
 711                         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_nexball_secondary_animtime"), w_ready);
 712                 }
 713
 714                 if (!self.BUTTON_ATCK && self.metertime && self.ballcarried)
 715                 {
 716                         W_Nexball_Attack(time - self.metertime);
 717                         // DropBall or stealing will set metertime back to 0
 718                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_nexball_primary_animtime"), w_ready);
 719                 }
 720         }
 721         else if (req == WR_PRECACHE)
 722         {
 723                 precache_model ("models/weapons/g_porto.md3");
 724                 precache_model ("models/weapons/v_porto.md3");
 725                 precache_model ("models/weapons/h_porto.dpm");
 726                 precache_model ("models/elaser.mdl");
 727                 precache_sound ("nexball/shoot1.wav");
 728                 precache_sound ("nexball/shoot2.wav");
 729         }
 730         else if (req == WR_SETUP)
 731                 weapon_setup(WEP_PORTO);
 732         else if (req == WR_SUICIDEMESSAGE)
 733         {
 734                 w_deathtypestring = "is a weirdo";
 735         }
 736         else if (req == WR_KILLMESSAGE)
 737         {
 738                 w_deathtypestring = "got killed by #'s black magic";
 739         }
 740         // No need to check WR_CHECKAMMO* or WR_AIM, it should always return TRUE
 741         return TRUE;
 742 }