qcsrc/server/playerstats.qc

   1 float playerstats_db;
   2 string teamstats_last;
   3 string playerstats_last;
   4 string events_last;
   5 .float playerstats_addedglobalinfo;
   6 .string playerstats_id;
   7
   8 void PlayerStats_Init() // initiated before InitGameplayMode so that scores are added properly
   9 {
  10         string uri;
  11         playerstats_db = -1;
  12         playerstats_waitforme = TRUE;
  13         uri = autocvar_g_playerstats_uri;
  14         if(uri == "")
  15                 return;
  16         playerstats_db = db_create();
  17         if(playerstats_db >= 0)
  18                 playerstats_waitforme = FALSE; // must wait for it at match end
  19
  20         serverflags |= SERVERFLAG_PLAYERSTATS;
  21
  22         PlayerStats_AddEvent(PLAYERSTATS_ALIVETIME);
  23         PlayerStats_AddEvent(PLAYERSTATS_AVGLATENCY);
  24         PlayerStats_AddEvent(PLAYERSTATS_WINS);
  25         PlayerStats_AddEvent(PLAYERSTATS_MATCHES);
  26         PlayerStats_AddEvent(PLAYERSTATS_JOINS);
  27         PlayerStats_AddEvent(PLAYERSTATS_SCOREBOARD_VALID);
  28         PlayerStats_AddEvent(PLAYERSTATS_SCOREBOARD_POS);
  29         PlayerStats_AddEvent(PLAYERSTATS_RANK);
  30
  31     // accuracy stats
  32     entity w;
  33     float i;
  34     for(i = WEP_FIRST; i <= WEP_LAST; ++i)
  35     {
  36         w = get_weaponinfo(i);
  37
  38         PlayerStats_AddEvent(strcat("acc-", w.netname, "-hit"));
  39         PlayerStats_AddEvent(strcat("acc-", w.netname, "-fired"));
  40
  41         PlayerStats_AddEvent(strcat("acc-", w.netname, "-cnt-hit"));
  42         PlayerStats_AddEvent(strcat("acc-", w.netname, "-cnt-fired"));
  43
  44         PlayerStats_AddEvent(strcat("acc-", w.netname, "-frags"));
  45     }
  46
  47         PlayerStats_AddEvent(PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_3);
  48         PlayerStats_AddEvent(PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_5);
  49         PlayerStats_AddEvent(PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_10);
  50         PlayerStats_AddEvent(PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_15);
  51         PlayerStats_AddEvent(PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_20);
  52         PlayerStats_AddEvent(PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_25);
  53         PlayerStats_AddEvent(PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_30);
  54         PlayerStats_AddEvent(PLAYERSTATS_ACHIEVEMENT_BOTLIKE);
  55         PlayerStats_AddEvent(PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD);
  56         PlayerStats_AddEvent(PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM);
  57 }
  58
  59 void PlayerStats_AddPlayer(entity e)
  60 {
  61         string s;
  62
  63         if(playerstats_db < 0)
  64                 return;
  65         if(e.playerstats_id)
  66                 return;
  67
  68         s = string_null;
  69         if(e.crypto_idfp != "" && e.cvar_cl_allow_uidtracking == 1)
  70                 s = e.crypto_idfp;
  71         else if(clienttype(e) == CLIENTTYPE_BOT)
  72                 s = sprintf("bot#%g#%s", skill, e.cleanname);
  73
  74         if((s == "") || find(world, playerstats_id, s)) // already have one of the ID - next one can't be tracked then!
  75         {
  76                 if(clienttype(e) == CLIENTTYPE_BOT)
  77                         s = sprintf("bot#%d", e.playerid);
  78                 else
  79                         s = sprintf("player#%d", e.playerid);
  80         }
  81
  82         e.playerstats_id = strzone(s);
  83
  84         string key;
  85         key = sprintf("%s:*", e.playerstats_id);
  86
  87         string p;
  88         p = db_get(playerstats_db, key);
  89         if(p == "")
  90         {
  91                 if(playerstats_last)
  92                 {
  93                         db_put(playerstats_db, key, playerstats_last);
  94                         strunzone(playerstats_last);
  95                 }
  96                 else
  97                         db_put(playerstats_db, key, "#");
  98                 playerstats_last = strzone(e.playerstats_id);
  99         }
 100 }
 101
 102 void PlayerStats_AddTeam(float t) // TODO: doesn't this remain unused?
 103 {
 104         if(playerstats_db < 0)
 105                 return;
 106
 107         string key;
 108         key = sprintf("%d", t);
 109
 110         string p;
 111         p = db_get(playerstats_db, key);
 112         if(p == "")
 113         {
 114                 if(teamstats_last)
 115                 {
 116                         db_put(playerstats_db, key, teamstats_last);
 117                         strunzone(teamstats_last);
 118                 }
 119                 else
 120                         db_put(playerstats_db, key, "#");
 121                 teamstats_last = strzone(key);
 122         }
 123 }
 124
 125 void PlayerStats_AddEvent(string event_id)
 126 {
 127         if(playerstats_db < 0)
 128                 return;
 129
 130         string key;
 131         key = sprintf("*:%s", event_id);
 132
 133         string p;
 134         p = db_get(playerstats_db, key);
 135         if(p == "")
 136         {
 137                 if(events_last)
 138                 {
 139                         db_put(playerstats_db, key, events_last);
 140                         strunzone(events_last);
 141                 }
 142                 else
 143                         db_put(playerstats_db, key, "#");
 144                 events_last = strzone(event_id);
 145         }
 146 }
 147
 148 void PlayerStats_Event(entity e, string event_id, float value)
 149 {
 150         if((e.playerstats_id == "") || playerstats_db < 0)
 151                 return;
 152
 153         string key;
 154         float val;
 155         key = sprintf("%s:%s", e.playerstats_id, event_id);
 156         val = stof(db_get(playerstats_db, key));
 157         val += value;
 158         db_put(playerstats_db, key, ftos(val));
 159 }
 160
 161 void PlayerStats_TeamScore(float t, string event_id, float value) // TODO: doesn't this remain unused?
 162 {
 163         string key;
 164         float val;
 165         key = sprintf("team#%d:%s", t, event_id);
 166         val = stof(db_get(playerstats_db, key));
 167         val += value;
 168         db_put(playerstats_db, key, ftos(val));
 169 }
 170
 171 /*
 172         format spec:
 173
 174         A collection of lines of the format <key> SPACE <value> NEWLINE, where
 175         <key> is always a single character.
 176
 177         The following keys are defined:
 178
 179         V: format version (always a fixed number) - this MUST be the first line!
 180         #: comment (MUST be ignored by any parser)
 181         R: release information on the server
 182         T: time at which the game ended
 183         G: game type
 184         O: mod name (icon request) as in server browser
 185         M: map name
 186         I: match ID (see "matchid" in g_world.qc
 187         S: "hostname" of the server
 188         C: number of "unpure" cvar changes
 189         U: UDP port number of the server
 190         D: duration of the match
 191         P: player ID of an existing player; this also sets the owner for all following "n", "e" and "t" lines (lower case!)
 192         n: nickname of the player (optional)
 193         t: team ID
 194         i: player index
 195         e: followed by an event name, a space, and the event count/score
 196                 event names can be:
 197                         alivetime: total playing time of the player
 198                         avglatency: average network latency compounded throughout the match
 199                         wins: number of games won (can only be set if matches is set)
 200                         matches: number of matches played to the end (not aborted by map switch)
 201                         joins: number of matches joined (always 1 unless player never played during the match)
 202                         scoreboardvalid: set to 1 if the player was there at the end of the match
 203                         total-<scoreboardname>: total score of that scoreboard item
 204                         scoreboard-<scoreboardname>: end-of-game score of that scoreboard item (can differ in non-team games)
 205                         achievement-<achievementname>: achievement counters (their "count" is usually 1 if nonzero at all)
 206                         kills-<index>: number of kills against the indexed player
 207                         rank <number>: rank of player
 208                         acc-<weapon netname>-hit: total damage dealt
 209                         acc-<weapon netname>-fired: total damage that all fired projectiles *could* have dealt
 210                         acc-<weapon netname>-cnt-hit: amount of shots that actually hit
 211                         acc-<weapon netname>-cnt-fired: amount of fired shots
 212                         acc-<weapon netname>-frags: amount of frags dealt by weapon
 213
 214         Response format (not used yet): see https://gist.github.com/4284222
 215 */
 216
 217 void PlayerStats_ready(entity fh, entity pass, float status)
 218 {
 219         string p, pn;
 220         string e, en;
 221         string nn, tt;
 222         string s;
 223
 224         switch(status)
 225         {
 226                 case URL_READY_CANWRITE:
 227                         url_fputs(fh, "V 6\n");
 228 #ifdef WATERMARK
 229                         url_fputs(fh, sprintf("R %s\n", WATERMARK));
 230 #endif
 231                         url_fputs(fh, sprintf("T %s.%06d\n", strftime(FALSE, "%s"), floor(random() * 1000000)));
 232                         url_fputs(fh, sprintf("G %s\n", GetGametype()));
 233                         url_fputs(fh, sprintf("O %s\n", modname));
 234                         url_fputs(fh, sprintf("M %s\n", GetMapname()));
 235                         url_fputs(fh, sprintf("I %s\n", matchid));
 236                         url_fputs(fh, sprintf("S %s\n", cvar_string("hostname")));
 237                         url_fputs(fh, sprintf("C %d\n", cvar_purechanges_count));
 238                         url_fputs(fh, sprintf("U %d\n", cvar("port")));
 239                         url_fputs(fh, sprintf("D %f\n", max(0, time - game_starttime)));
 240                         for(p = playerstats_last; (pn = db_get(playerstats_db, sprintf("%s:*", p))) != ""; p = pn)
 241                         {
 242                                 url_fputs(fh, sprintf("P %s\n", p));
 243                                 nn = db_get(playerstats_db, sprintf("%s:_playerid", p));
 244                                 if(nn != "")
 245                                         url_fputs(fh, sprintf("i %s\n", nn));
 246                                 nn = db_get(playerstats_db, sprintf("%s:_netname", p));
 247                                 if(nn != "")
 248                                         url_fputs(fh, sprintf("n %s\n", nn));
 249                                 if(teamplay)
 250                                 {
 251                                         tt = db_get(playerstats_db, sprintf("%s:_team", p));
 252                                         url_fputs(fh, sprintf("t %s\n", tt));
 253                                 }
 254                                 for(e = events_last; (en = db_get(playerstats_db, sprintf("*:%s", e))) != ""; e = en)
 255                                 {
 256                                         float v;
 257                                         v = stof(db_get(playerstats_db, sprintf("%s:%s", p, e)));
 258                                         if(v != 0)
 259                                                 url_fputs(fh, sprintf("e %s %g\n", e, v));
 260                                 }
 261                         }
 262                         url_fputs(fh, "\n");
 263                         url_fclose(fh);
 264                         break;
 265                 case URL_READY_CANREAD:
 266                         // url_fclose is processing, we got a response for writing the data
 267                         // this must come from HTTP
 268                         print("Got response from player stats server:\n");
 269                         while((s = url_fgets(fh)))
 270                                 print("  ", s, "\n");
 271                         print("End of response.\n");
 272                         url_fclose(fh);
 273                         break;
 274                 case URL_READY_CLOSED:
 275                         // url_fclose has finished
 276                         print("Player stats written\n");
 277                         playerstats_waitforme = TRUE;
 278                         db_close(playerstats_db);
 279                         playerstats_db = -1;
 280                         break;
 281                 case URL_READY_ERROR:
 282                 default:
 283                         print("Player stats writing failed: ", ftos(status), "\n");
 284                         playerstats_waitforme = TRUE;
 285                         if(playerstats_db >= 0)
 286                         {
 287                                 db_close(playerstats_db);
 288                                 playerstats_db = -1;
 289                         }
 290                         break;
 291         }
 292 }
 293
 294 //#NO AUTOCVARS START
 295 void PlayerStats_Shutdown()
 296 {
 297         string uri;
 298
 299         if(playerstats_db < 0)
 300                 return;
 301
 302         uri = autocvar_g_playerstats_uri;
 303         if(uri != "")
 304         {
 305                 playerstats_waitforme = FALSE;
 306                 url_multi_fopen(uri, FILE_APPEND, PlayerStats_ready, world);
 307         }
 308         else
 309         {
 310                 playerstats_waitforme = TRUE;
 311                 db_close(playerstats_db);
 312                 playerstats_db = -1;
 313         }
 314 }
 315 //#NO AUTOCVARS END
 316
 317 void PlayerStats_Accuracy(entity p)
 318 {
 319     entity a, w;
 320     a = p.accuracy;
 321     float i;
 322
 323     for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 324     {
 325         w = get_weaponinfo(i);
 326
 327         PlayerStats_Event(p, strcat("acc-", w.netname, "-hit"), a.(accuracy_hit[i-1]));
 328         PlayerStats_Event(p, strcat("acc-", w.netname, "-fired"), a.(accuracy_fired[i-1]));
 329
 330         PlayerStats_Event(p, strcat("acc-", w.netname, "-cnt-hit"), a.(accuracy_cnt_hit[i-1]));
 331         PlayerStats_Event(p, strcat("acc-", w.netname, "-cnt-fired"), a.(accuracy_cnt_fired[i-1]));
 332
 333         PlayerStats_Event(p, strcat("acc-", w.netname, "-frags"), a.(accuracy_frags[i-1]));
 334     }
 335     //backtrace(strcat("adding player stat accuracy for ", p.netname, ".\n"));
 336 }
 337
 338 void PlayerStats_AddGlobalInfo(entity p)
 339 {
 340         if(playerstats_db < 0)
 341                 return;
 342         if((p.playerstats_id == "") || playerstats_db < 0)
 343                 return;
 344         p.playerstats_addedglobalinfo = TRUE;
 345
 346         // add global info!
 347         if(p.alivetime)
 348         {
 349                 PlayerStats_Event(p, PLAYERSTATS_ALIVETIME, time - p.alivetime);
 350                 p.alivetime = 0;
 351         }
 352
 353         db_put(playerstats_db, sprintf("%s:_playerid", p.playerstats_id), ftos(p.playerid));
 354
 355         if(p.cvar_cl_allow_uid2name == 1 || clienttype(p) == CLIENTTYPE_BOT)
 356                 db_put(playerstats_db, sprintf("%s:_netname", p.playerstats_id), p.netname);
 357
 358         if(teamplay)
 359                 db_put(playerstats_db, sprintf("%s:_team", p.playerstats_id), ftos(p.team));
 360
 361         if(stof(db_get(playerstats_db, sprintf("%d:%s", p.playerstats_id, PLAYERSTATS_ALIVETIME))) > 0)
 362                 PlayerStats_Event(p, PLAYERSTATS_JOINS, 1);
 363
 364         PlayerStats_Accuracy(p);
 365
 366         if(clienttype(p) == CLIENTTYPE_REAL)
 367         {
 368                 if(p.latency_cnt)
 369                 {
 370                         float latency = (p.latency_sum / p.latency_cnt);
 371                         if(latency) { PlayerStats_Event(p, PLAYERSTATS_AVGLATENCY, latency); }
 372                 }
 373         }
 374
 375         strunzone(p.playerstats_id);
 376         p.playerstats_id = string_null;
 377 }
 378
 379 .float scoreboard_pos;
 380 void PlayerStats_EndMatch(float finished)
 381 {
 382         entity p;
 383         PlayerScore_Sort(score_dummyfield, 0, 0, 0);
 384         PlayerScore_Sort(scoreboard_pos, 1, 1, 1);
 385         FOR_EACH_CLIENT(p)
 386         {
 387                 // add personal score rank
 388                 PlayerStats_Event(p, PLAYERSTATS_RANK, p.score_dummyfield);
 389
 390                 if(!p.scoreboard_pos)
 391                         continue;
 392
 393                 // scoreboard is valid!
 394                 PlayerStats_Event(p, PLAYERSTATS_SCOREBOARD_VALID, 1);
 395
 396                 // add scoreboard position
 397                 PlayerStats_Event(p, PLAYERSTATS_SCOREBOARD_POS, p.scoreboard_pos);
 398
 399                 // add scoreboard data
 400                 PlayerScore_PlayerStats(p);
 401
 402                 // if the match ended normally, add winning info
 403                 if(finished)
 404                 {
 405                         PlayerStats_Event(p, PLAYERSTATS_WINS, p.winning);
 406                         PlayerStats_Event(p, PLAYERSTATS_MATCHES, 1);
 407                 }
 408         }
 409 }