qcsrc/server/race.qc

   1 #include "race.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include "client.qh"
   6 #include "portals.qh"
   7 #include "scores.qh"
   8 #include "spawnpoints.qh"
   9 #include "bot/api.qh"
  10 #include "command/getreplies.qh"
  11 #include "../common/deathtypes/all.qh"
  12 #include "../common/notifications/all.qh"
  13 #include "../common/mapinfo.qh"
  14 #include <common/gamemodes/rules.qh>
  15 #include <common/net_linked.qh>
  16 #include <common/state.qh>
  17 #include <common/weapons/weapon/porto.qh>
  18 #include "../common/mapobjects/subs.qh"
  19 #include <common/mapobjects/triggers.qh>
  20 #include "../lib/warpzone/util_server.qh"
  21 #include "../lib/warpzone/common.qh"
  22 #include "../common/mutators/mutator/waypoints/waypointsprites.qh"
  23
  24 IntrusiveList g_race_targets;
  25 STATIC_INIT(g_race_targets) { g_race_targets = IL_NEW(); }
  26
  27 void race_InitSpectator()
  28 {
  29         if(g_race_qualifying)
  30                 if(msg_entity.enemy.race_laptime)
  31                         race_SendNextCheckpoint(msg_entity.enemy, 1);
  32 }
  33
  34 float race_readTime(string map, float pos)
  35 {
  36         string rr = ((g_cts) ? CTS_RECORD : ((g_ctf) ? CTF_RECORD : RACE_RECORD));
  37
  38         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
  39 }
  40
  41 string race_readUID(string map, float pos)
  42 {
  43         string rr = ((g_cts) ? CTS_RECORD : ((g_ctf) ? CTF_RECORD : RACE_RECORD));
  44
  45         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
  46 }
  47
  48 float race_readPos(string map, float t)
  49 {
  50         for(int i = 1; i <= RANKINGS_CNT; ++i)
  51         {
  52                 int mytime = race_readTime(map, i);
  53                 if(!mytime || mytime > t)
  54                         return i;
  55         }
  56
  57         return 0; // pos is zero if unranked
  58 }
  59
  60 void race_writeTime(string map, float t, string myuid)
  61 {
  62         string rr = ((g_cts) ? CTS_RECORD : ((g_ctf) ? CTF_RECORD : RACE_RECORD));
  63
  64         float newpos;
  65         newpos = race_readPos(map, t);
  66
  67         float i, prevpos = 0;
  68         for(i = 1; i <= RANKINGS_CNT; ++i)
  69         {
  70                 if(race_readUID(map, i) == myuid)
  71                         prevpos = i;
  72         }
  73         if (prevpos)
  74         {
  75                 // player improved his existing record, only have to iterate on ranks between new and old recs
  76                 for (i = prevpos; i > newpos; --i)
  77                 {
  78                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
  79                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
  80                 }
  81         }
  82         else
  83         {
  84                 // player has no ranked record yet
  85                 for (i = RANKINGS_CNT; i > newpos; --i)
  86                 {
  87                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
  88                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
  89                 }
  90         }
  91
  92         // store new time itself
  93         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
  94         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
  95 }
  96
  97 string race_readName(string map, float pos)
  98 {
  99         string rr = ((g_cts) ? CTS_RECORD : ((g_ctf) ? CTF_RECORD : RACE_RECORD));
 100
 101         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
 102 }
 103
 104
 105 const float MAX_CHECKPOINTS = 255;
 106
 107 .float race_penalty;
 108 .float race_penalty_accumulator;
 109 .string race_penalty_reason;
 110 .float race_checkpoint; // player: next checkpoint that has to be reached
 111 .entity race_lastpenalty;
 112
 113 .entity sprite;
 114
 115 float race_checkpoint_records[MAX_CHECKPOINTS];
 116 string race_checkpoint_recordholders[MAX_CHECKPOINTS];
 117 float race_checkpoint_lasttimes[MAX_CHECKPOINTS];
 118 float race_checkpoint_lastlaps[MAX_CHECKPOINTS];
 119 entity race_checkpoint_lastplayers[MAX_CHECKPOINTS];
 120
 121 .float race_checkpoint_record[MAX_CHECKPOINTS];
 122
 123 float race_highest_checkpoint;
 124 float race_timed_checkpoint;
 125
 126 float defrag_ents;
 127 float defragcpexists;
 128
 129 float race_NextCheckpoint(float f)
 130 {
 131         if(f >= race_highest_checkpoint)
 132                 return 0;
 133         else
 134                 return f + 1;
 135 }
 136
 137 float race_PreviousCheckpoint(float f)
 138 {
 139         if(f == -1)
 140                 return 0;
 141         else if(f == 0)
 142                 return race_highest_checkpoint;
 143         else
 144                 return f - 1;
 145 }
 146
 147 // encode as:
 148 //   0 = common start/finish
 149 // 254 = start
 150 // 255 = finish
 151 float race_CheckpointNetworkID(float f)
 152 {
 153         if(race_timed_checkpoint)
 154         {
 155                 if(f == 0)
 156                         return 254; // start
 157                 else if(f == race_timed_checkpoint)
 158                         return 255; // finish
 159         }
 160         return f;
 161 }
 162
 163 void race_SendNextCheckpoint(entity e, float spec) // qualifying only
 164 {
 165         if(!e.race_laptime)
 166                 return;
 167
 168         int cp = e.race_checkpoint;
 169         float recordtime = race_checkpoint_records[cp];
 170         float myrecordtime = e.race_checkpoint_record[cp];
 171         string recordholder = race_checkpoint_recordholders[cp];
 172         if(recordholder == e.netname)
 173                 recordholder = "";
 174
 175         if(!IS_REAL_CLIENT(e))
 176                 return;
 177
 178         if(!spec)
 179                 msg_entity = e;
 180         WRITESPECTATABLE_MSG_ONE(msg_entity, {
 181                 WriteHeader(MSG_ONE, TE_CSQC_RACE);
 182                 if(spec)
 183                 {
 184                         WriteByte(MSG_ONE, RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING);
 185                         //WriteCoord(MSG_ONE, e.race_laptime - e.race_penalty_accumulator);
 186                         WriteCoord(MSG_ONE, time - e.race_movetime - e.race_penalty_accumulator);
 187                 }
 188                 else
 189                         WriteByte(MSG_ONE, RACE_NET_CHECKPOINT_NEXT_QUALIFYING);
 190                 WriteByte(MSG_ONE, race_CheckpointNetworkID(cp)); // checkpoint the player will be at next
 191                 WriteInt24_t(MSG_ONE, recordtime);
 192                 if(!spec)
 193                         WriteInt24_t(MSG_ONE, myrecordtime);
 194                 WriteString(MSG_ONE, recordholder);
 195         });
 196 }
 197
 198 void race_send_recordtime(float msg)
 199 {
 200         // send the server best time
 201         WriteHeader(msg, TE_CSQC_RACE);
 202         WriteByte(msg, RACE_NET_SERVER_RECORD);
 203         WriteInt24_t(msg, race_readTime(GetMapname(), 1));
 204 }
 205
 206
 207 void race_send_speedaward(float msg)
 208 {
 209         // send the best speed of the round
 210         WriteHeader(msg, TE_CSQC_RACE);
 211         WriteByte(msg, RACE_NET_SPEED_AWARD);
 212         WriteInt24_t(msg, floor(speedaward_speed+0.5));
 213         WriteString(msg, speedaward_holder);
 214 }
 215
 216 void race_send_speedaward_alltimebest(float msg)
 217 {
 218         // send the best speed
 219         WriteHeader(msg, TE_CSQC_RACE);
 220         WriteByte(msg, RACE_NET_SPEED_AWARD_BEST);
 221         WriteInt24_t(msg, floor(speedaward_alltimebest+0.5));
 222         WriteString(msg, speedaward_alltimebest_holder);
 223 }
 224
 225 void race_send_rankings_cnt(float msg)
 226 {
 227         WriteHeader(msg, TE_CSQC_RACE);
 228         WriteByte(msg, RACE_NET_RANKINGS_CNT);
 229         int m = min(RANKINGS_CNT, autocvar_g_cts_send_rankings_cnt);
 230         WriteByte(msg, m);
 231 }
 232
 233 void race_SendRankings(float pos, float prevpos, float del, float msg)
 234 {
 235         WriteHeader(msg, TE_CSQC_RACE);
 236         WriteByte(msg, RACE_NET_SERVER_RANKINGS);
 237         WriteShort(msg, pos);
 238         WriteShort(msg, prevpos);
 239         WriteShort(msg, del);
 240         WriteString(msg, race_readName(GetMapname(), pos));
 241         WriteInt24_t(msg, race_readTime(GetMapname(), pos));
 242 }
 243
 244 void race_SendStatus(float id, entity e)
 245 {
 246         if(!IS_REAL_CLIENT(e))
 247                 return;
 248
 249         float msg;
 250         if (id == 0)
 251                 msg = MSG_ONE;
 252         else
 253                 msg = MSG_ALL;
 254         msg_entity = e;
 255         WRITESPECTATABLE_MSG_ONE(msg_entity, {
 256                 WriteHeader(msg, TE_CSQC_RACE);
 257                 WriteByte(msg, RACE_NET_SERVER_STATUS);
 258                 WriteShort(msg, id);
 259                 WriteString(msg, e.netname);
 260         });
 261 }
 262
 263 void race_setTime(string map, float t, string myuid, string mynetname, entity e, bool showmessage)
 264 {
 265         // netname only used TEMPORARILY for printing
 266         int newpos = race_readPos(map, t);
 267
 268         int player_prevpos = 0;
 269         for(int i = 1; i <= RANKINGS_CNT; ++i)
 270         {
 271                 if(race_readUID(map, i) == myuid)
 272                         player_prevpos = i;
 273         }
 274
 275         float oldrec;
 276         string oldrec_holder;
 277         if (player_prevpos && (player_prevpos < newpos || !newpos))
 278         {
 279                 oldrec = race_readTime(GetMapname(), player_prevpos);
 280                 race_SendStatus(0, e); // "fail"
 281                 if(showmessage)
 282                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_FAIL_RANKED, mynetname, player_prevpos, t, oldrec);
 283                 return;
 284         }
 285         else if (!newpos)
 286         {
 287                 // no ranking, time worse than the worst ranked
 288                 oldrec = race_readTime(GetMapname(), RANKINGS_CNT);
 289                 race_SendStatus(0, e); // "fail"
 290                 if(showmessage)
 291                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_FAIL_UNRANKED, mynetname, RANKINGS_CNT, t, oldrec);
 292                 return;
 293         }
 294
 295         // if we didn't hit a return yet, we have a new record!
 296
 297         // if the player does not have a UID we can unfortunately not store the record, as the rankings system relies on UIDs
 298         if(myuid == "")
 299         {
 300                 if(showmessage)
 301                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_NEW_MISSING_UID, mynetname, t);
 302                 return;
 303         }
 304
 305         if(uid2name(myuid) == "^1Unregistered Player")
 306         {
 307                 if(showmessage)
 308                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_NEW_MISSING_NAME, mynetname, t);
 309                 return;
 310         }
 311
 312         oldrec = race_readTime(GetMapname(), newpos);
 313         oldrec_holder = race_readName(GetMapname(), newpos);
 314
 315         // store new ranking
 316         race_writeTime(GetMapname(), t, myuid);
 317
 318         if (newpos == 1 && showmessage)
 319         {
 320                 write_recordmarker(e, time - TIME_DECODE(t), TIME_DECODE(t));
 321                 race_send_recordtime(MSG_ALL);
 322         }
 323
 324         race_SendRankings(newpos, player_prevpos, 0, MSG_ALL);
 325         strcpy(rankings_reply, getrankings());
 326
 327         if(newpos == player_prevpos)
 328         {
 329                 if(showmessage)
 330                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_NEW_IMPROVED, mynetname, newpos, t, oldrec);
 331                 if(newpos == 1) { race_SendStatus(3, e); } // "new server record"
 332                 else { race_SendStatus(1, e); } // "new time"
 333         }
 334         else if(oldrec == 0)
 335         {
 336                 if(showmessage)
 337                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_NEW_SET, mynetname, newpos, t);
 338                 if(newpos == 1) { race_SendStatus(3, e); } // "new server record"
 339                 else { race_SendStatus(2, e); } // "new rank"
 340         }
 341         else
 342         {
 343                 if(showmessage)
 344                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_NEW_BROKEN, mynetname, oldrec_holder, newpos, t, oldrec);
 345                 if(newpos == 1) { race_SendStatus(3, e); } // "new server record"
 346                 else { race_SendStatus(2, e); } // "new rank"
 347         }
 348 }
 349
 350 void race_deleteTime(string map, float pos)
 351 {
 352         string rr = ((g_cts) ? CTS_RECORD : ((g_ctf) ? CTF_RECORD : RACE_RECORD));
 353
 354         for(int i = pos; i <= RANKINGS_CNT; ++i)
 355         {
 356                 string therank = ftos(i);
 357                 if (i == RANKINGS_CNT)
 358                 {
 359                         db_remove(ServerProgsDB, strcat(map, rr, "time", therank));
 360                         db_remove(ServerProgsDB, strcat(map, rr, "crypto_idfp", therank));
 361                 }
 362                 else
 363                 {
 364                         db_put(ServerProgsDB, strcat(map, rr, "time", therank), ftos(race_readTime(GetMapname(), i+1)));
 365                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", therank), race_readUID(GetMapname(), i+1));
 366                 }
 367         }
 368
 369         race_SendRankings(pos, 0, 1, MSG_ALL);
 370         if(pos == 1)
 371                 race_send_recordtime(MSG_ALL);
 372
 373         strcpy(rankings_reply, getrankings());
 374 }
 375
 376 void race_SendTime(entity e, float cp, float t, float tvalid)
 377 {
 378         float snew, l;
 379
 380         if(g_race_qualifying)
 381                 t += e.race_penalty_accumulator;
 382
 383         t = TIME_ENCODE(t); // make integer
 384
 385         if(tvalid)
 386         if(cp == race_timed_checkpoint) // finish line
 387         if (!CS(e).race_completed)
 388         {
 389                 float s;
 390                 if(g_race_qualifying)
 391                 {
 392                         s = GameRules_scoring_add(e, RACE_FASTEST, 0);
 393                         if(!s || t < s)
 394                                 GameRules_scoring_add(e, RACE_FASTEST, t - s);
 395                 }
 396                 else
 397                 {
 398                         s = GameRules_scoring_add(e, RACE_FASTEST, 0);
 399                         if(!s || t < s)
 400                                 GameRules_scoring_add(e, RACE_FASTEST, t - s);
 401
 402                         s = GameRules_scoring_add(e, RACE_TIME, 0);
 403                         snew = TIME_ENCODE(time - game_starttime);
 404                         GameRules_scoring_add(e, RACE_TIME, snew - s);
 405                         l = GameRules_scoring_add_team(e, RACE_LAPS, 1);
 406
 407                         if(autocvar_fraglimit)
 408                                 if(l >= autocvar_fraglimit)
 409                                         race_StartCompleting();
 410
 411                         if(race_completing)
 412                         {
 413                                 CS(e).race_completed = 1;
 414                                 MAKE_INDEPENDENT_PLAYER(e);
 415                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_FINISHED, e.netname);
 416                                 ClientData_Touch(e);
 417                         }
 418                 }
 419         }
 420
 421         if(g_race_qualifying)
 422         {
 423                 float recordtime;
 424                 string recordholder;
 425
 426                 if(tvalid)
 427                 {
 428                         recordtime = race_checkpoint_records[cp];
 429                         float myrecordtime = e.race_checkpoint_record[cp];
 430                         recordholder = strcat1(race_checkpoint_recordholders[cp]); // make a tempstring copy, as we'll possibly strunzone it!
 431                         if(recordholder == e.netname)
 432                                 recordholder = "";
 433
 434                         if(t != 0)
 435                         {
 436                                 if(cp == race_timed_checkpoint)
 437                                 {
 438                                         race_setTime(GetMapname(), t, e.crypto_idfp, e.netname, e, true);
 439                                         MUTATOR_CALLHOOK(Race_FinalCheckpoint, e);
 440                                 }
 441                                 if(t < myrecordtime || myrecordtime == 0)
 442                                         e.race_checkpoint_record[cp] = t; // resending done below
 443
 444                                 if(t < recordtime || recordtime == 0)
 445                                 {
 446                                         race_checkpoint_records[cp] = t;
 447                                         strcpy(race_checkpoint_recordholders[cp], e.netname);
 448                                         if(g_race_qualifying)
 449                                                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && it.race_checkpoint == cp, { race_SendNextCheckpoint(it, 0); });
 450                                 }
 451
 452                         }
 453                 }
 454                 else
 455                 {
 456                         // dummies
 457                         t = 0;
 458                         recordtime = 0;
 459                         recordholder = "";
 460                 }
 461
 462                 if(IS_REAL_CLIENT(e))
 463                 {
 464                         if(g_race_qualifying)
 465                         {
 466                                 FOREACH_CLIENT(IS_REAL_CLIENT(it),
 467                                 {
 468                                         if(it == e || (IS_SPEC(it) && it.enemy == e))
 469                                         {
 470                                                 msg_entity = it;
 471                                                 WriteHeader(MSG_ONE, TE_CSQC_RACE);
 472                                                 WriteByte(MSG_ONE, RACE_NET_CHECKPOINT_HIT_QUALIFYING);
 473                                                 WriteByte(MSG_ONE, race_CheckpointNetworkID(cp)); // checkpoint the player now is at
 474                                                 WriteInt24_t(MSG_ONE, t); // time to that intermediate
 475                                                 WriteInt24_t(MSG_ONE, recordtime); // previously best time
 476                                                 WriteInt24_t(MSG_ONE, ((tvalid) ? it.race_checkpoint_record[cp] : 0)); // previously best time
 477                                                 WriteString(MSG_ONE, recordholder); // record holder
 478                                         }
 479                                 });
 480                         }
 481                 }
 482         }
 483         else // RACE! Not Qualifying
 484         {
 485                 float mylaps, lother, othtime;
 486                 entity oth = race_checkpoint_lastplayers[cp];
 487                 if(oth)
 488                 {
 489                         mylaps = GameRules_scoring_add(e, RACE_LAPS, 0);
 490                         lother = race_checkpoint_lastlaps[cp];
 491                         othtime = race_checkpoint_lasttimes[cp];
 492                 }
 493                 else
 494                         mylaps = lother = othtime = 0;
 495
 496                 if(IS_REAL_CLIENT(e))
 497                 {
 498                         msg_entity = e;
 499                         WRITESPECTATABLE_MSG_ONE(msg_entity, {
 500                                 WriteHeader(MSG_ONE, TE_CSQC_RACE);
 501                                 WriteByte(MSG_ONE, RACE_NET_CHECKPOINT_HIT_RACE);
 502                                 WriteByte(MSG_ONE, race_CheckpointNetworkID(cp)); // checkpoint the player now is at
 503                                 if(e == oth)
 504                                 {
 505                                         WriteInt24_t(MSG_ONE, 0);
 506                                         WriteByte(MSG_ONE, 0);
 507                                         WriteByte(MSG_ONE, 0);
 508                                 }
 509                                 else
 510                                 {
 511                                         WriteInt24_t(MSG_ONE, TIME_ENCODE(time - race_checkpoint_lasttimes[cp]));
 512                                         WriteByte(MSG_ONE, mylaps - lother);
 513                                         WriteByte(MSG_ONE, etof(oth)); // record holder
 514                                 }
 515                         });
 516                 }
 517
 518                 race_checkpoint_lastplayers[cp] = e;
 519                 race_checkpoint_lasttimes[cp] = time;
 520                 race_checkpoint_lastlaps[cp] = mylaps;
 521
 522                 if(IS_REAL_CLIENT(oth))
 523                 {
 524                         msg_entity = oth;
 525                         WRITESPECTATABLE_MSG_ONE(msg_entity, {
 526                                 WriteHeader(MSG_ONE, TE_CSQC_RACE);
 527                                 WriteByte(MSG_ONE, RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT);
 528                                 WriteByte(MSG_ONE, race_CheckpointNetworkID(cp)); // checkpoint the player now is at
 529                                 if(e == oth)
 530                                 {
 531                                         WriteInt24_t(MSG_ONE, 0);
 532                                         WriteByte(MSG_ONE, 0);
 533                                         WriteByte(MSG_ONE, 0);
 534                                 }
 535                                 else
 536                                 {
 537                                         WriteInt24_t(MSG_ONE, TIME_ENCODE(time - othtime));
 538                                         WriteByte(MSG_ONE, lother - mylaps);
 539                                         WriteByte(MSG_ONE, etof(e) - 1); // record holder
 540                                 }
 541                         });
 542                 }
 543         }
 544 }
 545
 546 void race_ClearTime(entity e)
 547 {
 548         e.race_checkpoint = 0;
 549         e.race_laptime = 0;
 550         e.race_movetime = e.race_movetime_frac = e.race_movetime_count = 0;
 551         e.race_penalty_accumulator = 0;
 552         e.race_lastpenalty = NULL;
 553
 554         if(!IS_REAL_CLIENT(e))
 555                 return;
 556
 557         msg_entity = e;
 558         WRITESPECTATABLE_MSG_ONE(msg_entity, {
 559                 WriteHeader(MSG_ONE, TE_CSQC_RACE);
 560                 WriteByte(MSG_ONE, RACE_NET_CHECKPOINT_CLEAR); // next
 561         });
 562 }
 563
 564 void checkpoint_passed(entity this, entity player)
 565 {
 566         if(player.personal && autocvar_g_allow_checkpoints)
 567                 return; // practice mode!
 568
 569         if(player.classname == "porto")
 570         {
 571                 // do not allow portalling through checkpoints
 572                 trace_plane_normal = normalize(-1 * player.velocity);
 573                 W_Porto_Fail(player, 0);
 574                 return;
 575         }
 576
 577         string oldmsg; // used twice
 578
 579         /*
 580          * Trigger targets
 581          */
 582         if (!((this.spawnflags & 2) && (IS_PLAYER(player))))
 583         {
 584                 oldmsg = this.message;
 585                 this.message = "";
 586                 SUB_UseTargets(this, player, player);
 587                 this.message = oldmsg;
 588         }
 589
 590         if (!IS_PLAYER(player))
 591                 return;
 592
 593         /*
 594          * Remove unauthorized equipment
 595          */
 596         Portal_ClearAll(player);
 597
 598         player.porto_forbidden = 2; // decreased by 1 each StartFrame
 599
 600         if(defrag_ents)
 601         {
 602                 if(this.race_checkpoint == -2)
 603                 {
 604                         this.race_checkpoint = player.race_checkpoint;
 605                 }
 606
 607                 int cp_amount = 0, largest_cp_id = 0;
 608                 IL_EACH(g_race_targets, it.classname == "target_checkpoint",
 609                 {
 610                         cp_amount += 1;
 611                         if(it.race_checkpoint > largest_cp_id) // update the finish id if someone hit a new checkpoint
 612                         {
 613                                 if(!largest_cp_id)
 614                                 {
 615                                         IL_EACH(g_race_targets, it.classname == "target_checkpoint",
 616                                         {
 617                                                 if(it.race_checkpoint == -2) // set defragcpexists to -1 so that the cp id file will be rewritten when someone finishes
 618                                                         defragcpexists = -1;
 619                                         });
 620                                 }
 621
 622                                 largest_cp_id = it.race_checkpoint;
 623                                 IL_EACH(g_race_targets, it.classname == "target_stopTimer",
 624                                 {
 625                                         it.race_checkpoint = largest_cp_id + 1; // finish line
 626                                 });
 627                                 race_highest_checkpoint = largest_cp_id + 1;
 628                                 race_timed_checkpoint = largest_cp_id + 1;
 629                         }
 630                 });
 631
 632                 if(!cp_amount)
 633                 {
 634                         IL_EACH(g_race_targets, it.classname == "target_stopTimer",
 635                         {
 636                                 it.race_checkpoint = 1;
 637                         });
 638                         race_highest_checkpoint = 1;
 639                         race_timed_checkpoint = 1;
 640                 }
 641         }
 642
 643         if((player.race_checkpoint == -1 && this.race_checkpoint == 0) || (player.race_checkpoint == this.race_checkpoint))
 644         {
 645                 if(this.race_penalty)
 646                 {
 647                         if(player.race_lastpenalty != this)
 648                         {
 649                                 player.race_lastpenalty = this;
 650                                 race_ImposePenaltyTime(player, this.race_penalty, this.race_penalty_reason);
 651                         }
 652                 }
 653
 654                 if(player.race_penalty)
 655                         return;
 656
 657                 /*
 658                  * Trigger targets
 659                  */
 660                 if(this.spawnflags & 2)
 661                 {
 662                         oldmsg = this.message;
 663                         this.message = "";
 664                         SUB_UseTargets(this, player, player); // TODO: should we be using other for the trigger here?
 665                         this.message = oldmsg;
 666                 }
 667
 668                 if(player.race_respawn_checkpoint != this.race_checkpoint || !player.race_started)
 669                         player.race_respawn_spotref = this; // this is not a spot but a CP, but spawnpoint selection will deal with that
 670                 player.race_respawn_checkpoint = this.race_checkpoint;
 671                 player.race_checkpoint = race_NextCheckpoint(this.race_checkpoint);
 672                 player.race_started = 1;
 673
 674                 race_SendTime(player, this.race_checkpoint, player.race_movetime, boolean(player.race_laptime));
 675
 676                 if(!this.race_checkpoint) // start line
 677                 {
 678                         player.race_laptime = time;
 679                         player.race_movetime = player.race_movetime_frac = player.race_movetime_count = 0;
 680                         player.race_penalty_accumulator = 0;
 681                         player.race_lastpenalty = NULL;
 682                 }
 683
 684                 if(g_race_qualifying)
 685                         race_SendNextCheckpoint(player, 0);
 686
 687                 if(defrag_ents && defragcpexists < 0 && this.classname == "target_stopTimer")
 688                 {
 689                         float fh;
 690                         defragcpexists = fh = fopen(strcat("maps/", GetMapname(), ".defragcp"), FILE_WRITE);
 691                         if(fh >= 0)
 692                         {
 693                                 IL_EACH(g_race_targets, it.classname == "target_checkpoint",
 694                                 {
 695                                         fputs(fh, strcat(it.targetname, " ", ftos(it.race_checkpoint), "\n"));
 696                                 });
 697                         }
 698                         fclose(fh);
 699                 }
 700         }
 701         else if(player.race_checkpoint == race_NextCheckpoint(this.race_checkpoint))
 702         {
 703                 // ignored
 704         }
 705         else
 706         {
 707                 if(this.spawnflags & 4)
 708                         Damage (player, this, this, 10000, DEATH_HURTTRIGGER.m_id, DMG_NOWEP, player.origin, '0 0 0');
 709         }
 710 }
 711
 712 void checkpoint_touch(entity this, entity toucher)
 713 {
 714         EXACTTRIGGER_TOUCH(this, toucher);
 715         checkpoint_passed(this, toucher);
 716 }
 717
 718 void checkpoint_use(entity this, entity actor, entity trigger)
 719 {
 720         if(trigger.classname == "info_player_deathmatch") // a spawn, a spawn
 721                 return;
 722
 723         checkpoint_passed(this, actor);
 724 }
 725
 726 bool race_waypointsprite_visible_for_player(entity this, entity player, entity view)
 727 {
 728         entity own = this.owner;
 729         if(this.realowner)
 730                 own = this.realowner; // target support
 731
 732         if(view.race_checkpoint == -1 || own.race_checkpoint == -2)
 733                 return true;
 734         else if(view.race_checkpoint == own.race_checkpoint)
 735                 return true;
 736         else
 737                 return false;
 738 }
 739
 740 void trigger_race_checkpoint_verify(entity this)
 741 {
 742     static bool have_verified;
 743         if (have_verified) return;
 744         have_verified = true;
 745
 746         bool qual = g_race_qualifying;
 747
 748         int pl_race_checkpoint = 0;
 749         int pl_race_place = 0;
 750
 751         if (g_race) {
 752                 for (int i = 0; i <= race_highest_checkpoint; ++i) {
 753                         pl_race_checkpoint = race_NextCheckpoint(i);
 754
 755                         // race only (middle of the race)
 756                         g_race_qualifying = false;
 757                         pl_race_place = 0;
 758                         if (!Spawn_FilterOutBadSpots(this, findchain(classname, "info_player_deathmatch"), 0, false)) {
 759                                 error(strcat("Checkpoint ", ftos(i), " misses a spawnpoint with race_place==", ftos(pl_race_place), " (used for respawning in race) - bailing out"));
 760             }
 761
 762                         if (i == 0) {
 763                                 // qualifying only
 764                                 g_race_qualifying = 1;
 765                                 pl_race_place = race_lowest_place_spawn;
 766                                 if (!Spawn_FilterOutBadSpots(this, findchain(classname, "info_player_deathmatch"), 0, false)) {
 767                                         error(strcat("Checkpoint ", ftos(i), " misses a spawnpoint with race_place==", ftos(pl_race_place), " (used for qualifying) - bailing out"));
 768                 }
 769
 770                                 // race only (initial spawn)
 771                                 g_race_qualifying = 0;
 772                                 for (int p = 1; p <= race_highest_place_spawn; ++p) {
 773                                         pl_race_place = p;
 774                                         if (!Spawn_FilterOutBadSpots(this, findchain(classname, "info_player_deathmatch"), 0, false)) {
 775                                                 error(strcat("Checkpoint ", ftos(i), " misses a spawnpoint with race_place==", ftos(pl_race_place), " (used for initially spawning in race) - bailing out"));
 776                     }
 777                                 }
 778                         }
 779                 }
 780         } else if (!defrag_ents) {
 781                 // qualifying only
 782                 pl_race_checkpoint = race_NextCheckpoint(0);
 783                 g_race_qualifying = 1;
 784                 pl_race_place = race_lowest_place_spawn;
 785                 if (!Spawn_FilterOutBadSpots(this, findchain(classname, "info_player_deathmatch"), 0, false)) {
 786                         error(strcat("Checkpoint 0 misses a spawnpoint with race_place==", ftos(pl_race_place), " (used for qualifying) - bailing out"));
 787         }
 788         } else {
 789                 pl_race_checkpoint = race_NextCheckpoint(0);
 790                 g_race_qualifying = 1;
 791                 pl_race_place = 0; // there's only one spawn on defrag maps
 792
 793                 // check if a defragcp file already exists, then read it and apply the checkpoint order
 794                 float fh;
 795                 float len;
 796                 string l;
 797
 798                 defragcpexists = fh = fopen(strcat("maps/", GetMapname(), ".defragcp"), FILE_READ);
 799                 if (fh >= 0) {
 800                         while ((l = fgets(fh))) {
 801                                 len = tokenize_console(l);
 802                                 if (len != 2) {
 803                                         defragcpexists = -1; // something's wrong in the defrag cp file, set defragcpexists to -1 so that it will be rewritten when someone finishes
 804                                         continue;
 805                                 }
 806                                 for (entity cp = NULL; (cp = find(cp, classname, "target_checkpoint"));) {
 807                                         if (argv(0) == cp.targetname) {
 808                                                 cp.race_checkpoint = stof(argv(1));
 809                     }
 810                 }
 811                         }
 812                         fclose(fh);
 813                 }
 814         }
 815
 816         g_race_qualifying = qual;
 817
 818         IL_EACH(g_race_targets, it.classname == "target_checkpoint" || it.classname == "target_startTimer" || it.classname == "target_stopTimer",
 819         {
 820                 if(it.targetname == "" || !it.targetname) // somehow this is a case...
 821                         continue;
 822                 entity cpt = it;
 823                 FOREACH_ENTITY_STRING(target, cpt.targetname,
 824                 {
 825                         vector org = (it.absmin + it.absmax) * 0.5;
 826                         if(cpt.race_checkpoint == 0)
 827                                 WaypointSprite_SpawnFixed(WP_RaceStart, org, it, sprite, RADARICON_NONE);
 828                         else
 829                                 WaypointSprite_SpawnFixed(WP_RaceCheckpoint, org, it, sprite, RADARICON_NONE);
 830
 831                         it.sprite.realowner = cpt;
 832                         it.sprite.waypointsprite_visible_for_player = race_waypointsprite_visible_for_player;
 833                 });
 834         });
 835
 836         if (race_timed_checkpoint) {
 837                 if (defrag_ents) {
 838                         IL_EACH(g_race_targets, it.classname == "target_checkpoint" || it.classname == "target_startTimer" || it.classname == "target_stopTimer",
 839                         {
 840                                 entity cpt = it;
 841                                 if(it.classname == "target_startTimer" || it.classname == "target_stopTimer") {
 842                                         if(it.targetname == "" || !it.targetname) // somehow this is a case...
 843                                                 continue;
 844                                         FOREACH_ENTITY_STRING(target, cpt.targetname, {
 845                                                 if(it.sprite)
 846                                                         WaypointSprite_UpdateSprites(it.sprite, ((cpt.classname == "target_startTimer") ? WP_RaceStart : WP_RaceFinish), WP_Null, WP_Null);
 847                                         });
 848                                 }
 849                                 if(it.classname == "target_checkpoint") {
 850                                         if(it.race_checkpoint == -2)
 851                                                 defragcpexists = -1; // something's wrong with the defrag cp file or it has not been written yet, set defragcpexists to -1 so that it will be rewritten when someone finishes
 852                                 }
 853                         });
 854                         if (defragcpexists != -1) {
 855                                 float largest_cp_id = 0;
 856                                 for (entity cp = NULL; (cp = find(cp, classname, "target_checkpoint"));) {
 857                                         if (cp.race_checkpoint > largest_cp_id) {
 858                                                 largest_cp_id = cp.race_checkpoint;
 859                     }
 860                 }
 861                                 for (entity cp = NULL; (cp = find(cp, classname, "target_stopTimer"));) {
 862                                         cp.race_checkpoint = largest_cp_id + 1; // finish line
 863                 }
 864                                 race_highest_checkpoint = largest_cp_id + 1;
 865                                 race_timed_checkpoint = largest_cp_id + 1;
 866                         } else {
 867                                 for (entity cp = NULL; (cp = find(cp, classname, "target_stopTimer"));) {
 868                                         cp.race_checkpoint = 255; // finish line
 869                 }
 870                                 race_highest_checkpoint = 255;
 871                                 race_timed_checkpoint = 255;
 872                         }
 873                 } else {
 874                         IL_EACH(g_racecheckpoints, it.sprite,
 875                         {
 876                                 if (it.race_checkpoint == 0) {
 877                                         WaypointSprite_UpdateSprites(it.sprite, WP_RaceStart, WP_Null, WP_Null);
 878                 } else if (it.race_checkpoint == race_timed_checkpoint) {
 879                                         WaypointSprite_UpdateSprites(it.sprite, WP_RaceFinish, WP_Null, WP_Null);
 880                                 }
 881             });
 882                 }
 883         }
 884
 885         if (defrag_ents) {
 886                 for (entity trigger = NULL; (trigger = find(trigger, classname, "trigger_multiple")); ) {
 887                         for (entity targ = NULL; (targ = find(targ, targetname, trigger.target)); ) {
 888                                 if (targ.classname == "target_checkpoint" || targ.classname == "target_startTimer" || targ.classname == "target_stopTimer") {
 889                                         trigger.wait = 0;
 890                                         trigger.delay = 0;
 891                                         targ.wait = 0;
 892                                         targ.delay = 0;
 893
 894                     // These just make the game crash on some maps with oddly shaped triggers.
 895                     // (on the other hand they used to fix the case when two players ran through a checkpoint at once,
 896                     // and often one of them just passed through without being registered. Hope it's fixed  in a better way now.
 897                     // (happened on item triggers too)
 898                     //
 899                                         //targ.wait = -2;
 900                                         //targ.delay = 0;
 901
 902                                         //setsize(targ, trigger.mins, trigger.maxs);
 903                                         //setorigin(targ, trigger.origin);
 904                                         //remove(trigger);
 905                                 }
 906             }
 907         }
 908         }
 909 }
 910
 911 vector trigger_race_checkpoint_spawn_evalfunc(entity this, entity player, entity spot, vector current)
 912 {
 913         if(g_race_qualifying)
 914         {
 915                 // spawn at first
 916                 if(this.race_checkpoint != 0)
 917                         return '-1 0 0';
 918                 if(spot.race_place != race_lowest_place_spawn)
 919                         return '-1 0 0';
 920         }
 921         else
 922         {
 923                 if(this.race_checkpoint != player.race_respawn_checkpoint)
 924                         return '-1 0 0';
 925                 // try reusing the previous spawn
 926                 if(this == player.race_respawn_spotref || spot == player.race_respawn_spotref)
 927                         current.x += SPAWN_PRIO_RACE_PREVIOUS_SPAWN;
 928                 if(this.race_checkpoint == 0)
 929                 {
 930                         int pl = player.race_place;
 931                         if(pl > race_highest_place_spawn)
 932                                 pl = 0;
 933                         if(pl == 0 && !player.race_started)
 934                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 935                         if(spot.race_place != pl)
 936                                 return '-1 0 0';
 937                 }
 938         }
 939         return current;
 940 }
 941
 942 spawnfunc(trigger_race_checkpoint)
 943 {
 944         vector o;
 945         if(!g_race && !g_cts) { delete(this); return; }
 946
 947         EXACTTRIGGER_INIT;
 948
 949         this.use = checkpoint_use;
 950         if (!(this.spawnflags & 1))
 951                 settouch(this, checkpoint_touch);
 952
 953         o = (this.absmin + this.absmax) * 0.5;
 954         tracebox(o, PL_MIN_CONST, PL_MAX_CONST, o - '0 0 1' * (o.z - this.absmin.z), MOVE_NORMAL, this);
 955         waypoint_spawnforitem_force(this, trace_endpos);
 956         this.nearestwaypointtimeout = -1;
 957
 958         if(this.message == "")
 959                 this.message = "went backwards";
 960         if (this.message2 == "")
 961                 this.message2 = "was pushed backwards by";
 962         if (this.race_penalty_reason == "")
 963                 this.race_penalty_reason = "missing a checkpoint";
 964
 965         this.race_checkpoint = this.cnt;
 966
 967         if(this.race_checkpoint > race_highest_checkpoint)
 968         {
 969                 race_highest_checkpoint = this.race_checkpoint;
 970                 if(this.spawnflags & 8)
 971                         race_timed_checkpoint = this.race_checkpoint;
 972                 else
 973                         race_timed_checkpoint = 0;
 974         }
 975
 976         if(!this.race_penalty)
 977         {
 978                 if(this.race_checkpoint)
 979                         WaypointSprite_SpawnFixed(WP_RaceCheckpoint, o, this, sprite, RADARICON_NONE);
 980                 else
 981                         WaypointSprite_SpawnFixed(WP_RaceStartFinish, o, this, sprite, RADARICON_NONE);
 982         }
 983
 984         this.sprite.waypointsprite_visible_for_player = race_waypointsprite_visible_for_player;
 985         this.spawn_evalfunc = trigger_race_checkpoint_spawn_evalfunc;
 986
 987         IL_PUSH(g_racecheckpoints, this);
 988
 989         InitializeEntity(this, trigger_race_checkpoint_verify, INITPRIO_FINDTARGET);
 990 }
 991
 992 spawnfunc(target_checkpoint) // defrag entity
 993 {
 994         if(!g_race && !g_cts) { delete(this); return; }
 995         defrag_ents = 1;
 996
 997         // if this is targeted, then it probably isn't a trigger
 998         bool is_trigger = this.targetname == "";
 999
1000         if(is_trigger)
1001                 EXACTTRIGGER_INIT;
1002
1003         this.use = checkpoint_use;
1004         if (is_trigger && !(this.spawnflags & 1))
1005                 settouch(this, checkpoint_touch);
1006
1007         vector org = this.origin;
1008
1009         // bots should only pathfind to this if it is a valid touchable trigger
1010         if(is_trigger)
1011         {
1012                 org = (this.absmin + this.absmax) * 0.5;
1013                 tracebox(org, PL_MIN_CONST, PL_MAX_CONST, org - '0 0 1' * (org.z - this.absmin.z), MOVE_NORMAL, this);
1014                 waypoint_spawnforitem_force(this, trace_endpos);
1015                 this.nearestwaypointtimeout = -1;
1016         }
1017
1018         if(this.message == "")
1019                 this.message = "went backwards";
1020         if (this.message2 == "")
1021                 this.message2 = "was pushed backwards by";
1022         if (this.race_penalty_reason == "")
1023                 this.race_penalty_reason = "missing a checkpoint";
1024
1025         if(this.classname == "target_startTimer")
1026                 this.race_checkpoint = 0;
1027         else
1028                 this.race_checkpoint = -2;
1029
1030         race_timed_checkpoint = 1;
1031
1032         IL_PUSH(g_race_targets, this);
1033
1034         InitializeEntity(this, trigger_race_checkpoint_verify, INITPRIO_FINDTARGET);
1035 }
1036
1037 spawnfunc(target_startTimer) { spawnfunc_target_checkpoint(this); }
1038 spawnfunc(target_stopTimer) { spawnfunc_target_checkpoint(this); }
1039
1040 void race_AbandonRaceCheck(entity p)
1041 {
1042         if(race_completing && !CS(p).race_completed)
1043         {
1044                 CS(p).race_completed = 1;
1045                 MAKE_INDEPENDENT_PLAYER(p);
1046                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_ABANDONED, p.netname);
1047                 ClientData_Touch(p);
1048         }
1049 }
1050
1051 void race_StartCompleting()
1052 {
1053         race_completing = 1;
1054         FOREACH_CLIENT(IS_PLAYER(it) && IS_DEAD(it), { race_AbandonRaceCheck(it); });
1055 }
1056
1057 void race_PreparePlayer(entity this)
1058 {
1059         race_ClearTime(this);
1060         this.race_place = 0;
1061         this.race_started = 0;
1062         this.race_respawn_checkpoint = 0;
1063         this.race_respawn_spotref = NULL;
1064 }
1065
1066 void race_RetractPlayer(entity this)
1067 {
1068         if(!g_race && !g_cts)
1069                 return;
1070         if(this.race_respawn_checkpoint == 0 || this.race_respawn_checkpoint == race_timed_checkpoint)
1071                 race_ClearTime(this);
1072         this.race_checkpoint = this.race_respawn_checkpoint;
1073 }
1074
1075 spawnfunc(info_player_race)
1076 {
1077         if(!g_race && !g_cts) { delete(this); return; }
1078         ++race_spawns;
1079         spawnfunc_info_player_deathmatch(this);
1080
1081         if(this.race_place > race_highest_place_spawn)
1082                 race_highest_place_spawn = this.race_place;
1083         if(this.race_place < race_lowest_place_spawn)
1084                 race_lowest_place_spawn = this.race_place;
1085 }
1086
1087 void race_ClearRecords()
1088 {
1089         for(int j = 0; j < MAX_CHECKPOINTS; ++j)
1090         {
1091                 race_checkpoint_records[j] = 0;
1092                 strfree(race_checkpoint_recordholders[j]);
1093         }
1094
1095         FOREACH_CLIENT(true, {
1096                 float p = it.race_place;
1097                 race_PreparePlayer(it);
1098                 it.race_place = p;
1099         });
1100 }
1101
1102 void race_ImposePenaltyTime(entity pl, float penalty, string reason)
1103 {
1104         if(g_race_qualifying)
1105         {
1106                 pl.race_penalty_accumulator += penalty;
1107                 if(IS_REAL_CLIENT(pl))
1108                 {
1109                         msg_entity = pl;
1110                         WRITESPECTATABLE_MSG_ONE(msg_entity, {
1111                                 WriteHeader(MSG_ONE, TE_CSQC_RACE);
1112                                 WriteByte(MSG_ONE, RACE_NET_PENALTY_QUALIFYING);
1113                                 WriteShort(MSG_ONE, TIME_ENCODE(penalty));
1114                                 WriteString(MSG_ONE, reason);
1115                         });
1116                 }
1117         }
1118         else
1119         {
1120                 pl.race_penalty = time + penalty;
1121                 if(IS_REAL_CLIENT(pl))
1122                 {
1123                         msg_entity = pl;
1124                         WRITESPECTATABLE_MSG_ONE(msg_entity, {
1125                                 WriteHeader(MSG_ONE, TE_CSQC_RACE);
1126                                 WriteByte(MSG_ONE, RACE_NET_PENALTY_RACE);
1127                                 WriteShort(MSG_ONE, TIME_ENCODE(penalty));
1128                                 WriteString(MSG_ONE, reason);
1129                         });
1130                 }
1131         }
1132 }
1133
1134 void penalty_touch(entity this, entity toucher)
1135 {
1136         EXACTTRIGGER_TOUCH(this, toucher);
1137         if(toucher.race_lastpenalty != this)
1138         {
1139                 toucher.race_lastpenalty = this;
1140                 race_ImposePenaltyTime(toucher, this.race_penalty, this.race_penalty_reason);
1141         }
1142 }
1143
1144 void penalty_use(entity this, entity actor, entity trigger)
1145 {
1146         race_ImposePenaltyTime(actor, this.race_penalty, this.race_penalty_reason);
1147 }
1148
1149 spawnfunc(trigger_race_penalty)
1150 {
1151         // TODO: find out why this wasnt done:
1152         //if(!g_cts && !g_race) { remove(this); return; }
1153
1154         EXACTTRIGGER_INIT;
1155
1156         this.use = penalty_use;
1157         if (!(this.spawnflags & 1))
1158                 settouch(this, penalty_touch);
1159
1160         if (this.race_penalty_reason == "")
1161                 this.race_penalty_reason = "missing a checkpoint";
1162         if (!this.race_penalty)
1163                 this.race_penalty = 5;
1164 }
1165
1166 float race_GetFractionalLapCount(entity e)
1167 {
1168         // interesting metrics (idea by KrimZon) to maybe sort players in the
1169         // scoreboard, immediately updates when overtaking
1170         //
1171         // requires the track to be built so you never get farther away from the
1172         // next checkpoint, though, and current Xonotic race maps are not built that
1173         // way
1174         //
1175         // also, this code is slow and would need optimization (i.e. "next CP"
1176         // links on CP entities)
1177
1178         float l;
1179         l = GameRules_scoring_add(e, RACE_LAPS, 0);
1180         if(CS(e).race_completed)
1181                 return l; // not fractional
1182
1183         vector o0, o1;
1184         float bestfraction, fraction;
1185         entity lastcp;
1186         float nextcpindex, lastcpindex;
1187
1188         nextcpindex = max(e.race_checkpoint, 0);
1189         lastcpindex = e.race_respawn_checkpoint;
1190         lastcp = e.race_respawn_spotref;
1191
1192         if(nextcpindex == lastcpindex)
1193                 return l; // finish
1194
1195         bestfraction = 1;
1196         IL_EACH(g_racecheckpoints, true,
1197         {
1198                 if(it.race_checkpoint != lastcpindex)
1199                         continue;
1200                 if(lastcp)
1201                         if(it != lastcp)
1202                                 continue;
1203                 o0 = (it.absmin + it.absmax) * 0.5;
1204                 IL_EACH(g_racecheckpoints, true,
1205                 {
1206                         if(it.race_checkpoint != nextcpindex)
1207                                 continue;
1208                         o1 = (it.absmin + it.absmax) * 0.5;
1209                         if(o0 == o1)
1210                                 continue;
1211                         fraction = bound(0.0001, vlen(e.origin - o1) / vlen(o0 - o1), 1);
1212                         if(fraction < bestfraction)
1213                                 bestfraction = fraction;
1214                 });
1215         });
1216
1217         // we are at CP "nextcpindex - bestfraction"
1218         // race_timed_checkpoint == 4: then nextcp==4 means 0.9999x, nextcp==0 means 0.0000x
1219         // race_timed_checkpoint == 0: then nextcp==0 means 0.9999x
1220         float c, nc;
1221         nc = race_highest_checkpoint + 1;
1222         c = ((nextcpindex - race_timed_checkpoint + nc + nc - 1) % nc) + 1 - bestfraction;
1223
1224         return l + c / nc;
1225 }