qcsrc/server/race.qc

   1 #include "race.qh"
   2
   3 #include "client.qh"
   4 #include "portals.qh"
   5 #include "scores.qh"
   6 #include "spawnpoints.qh"
   7 #include "bot/api.qh"
   8 #include "command/getreplies.qh"
   9 #include "../common/deathtypes/all.qh"
  10 #include "../common/notifications/all.qh"
  11 #include "../common/mapinfo.qh"
  12 #include <common/net_linked.qh>
  13 #include "../common/triggers/subs.qh"
  14 #include "../lib/warpzone/util_server.qh"
  15 #include "../lib/warpzone/common.qh"
  16 #include "../common/mutators/mutator/waypoints/waypointsprites.qh"
  17
  18 IntrusiveList g_race_targets;
  19 STATIC_INIT(g_race_targets) { g_race_targets = IL_NEW(); }
  20
  21 void race_InitSpectator()
  22 {
  23         if(g_race_qualifying)
  24                 if(msg_entity.enemy.race_laptime)
  25                         race_SendNextCheckpoint(msg_entity.enemy, 1);
  26 }
  27
  28 void W_Porto_Fail(entity this, float failhard);
  29
  30 float race_readTime(string map, float pos)
  31 {
  32         string rr = ((g_cts) ? CTS_RECORD : ((g_ctf) ? CTF_RECORD : RACE_RECORD));
  33
  34         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
  35 }
  36
  37 string race_readUID(string map, float pos)
  38 {
  39         string rr = ((g_cts) ? CTS_RECORD : ((g_ctf) ? CTF_RECORD : RACE_RECORD));
  40
  41         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
  42 }
  43
  44 float race_readPos(string map, float t)
  45 {
  46         for(int i = 1; i <= RANKINGS_CNT; ++i)
  47         {
  48                 int mytime = race_readTime(map, i);
  49                 if(!mytime || mytime > t)
  50                         return i;
  51         }
  52
  53         return 0; // pos is zero if unranked
  54 }
  55
  56 void race_writeTime(string map, float t, string myuid)
  57 {
  58         string rr = ((g_cts) ? CTS_RECORD : ((g_ctf) ? CTF_RECORD : RACE_RECORD));
  59
  60         float newpos;
  61         newpos = race_readPos(map, t);
  62
  63         float i, prevpos = 0;
  64         for(i = 1; i <= RANKINGS_CNT; ++i)
  65         {
  66                 if(race_readUID(map, i) == myuid)
  67                         prevpos = i;
  68         }
  69         if (prevpos)
  70         {
  71                 // player improved his existing record, only have to iterate on ranks between new and old recs
  72                 for (i = prevpos; i > newpos; --i)
  73                 {
  74                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
  75                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
  76                 }
  77         }
  78         else
  79         {
  80                 // player has no ranked record yet
  81                 for (i = RANKINGS_CNT; i > newpos; --i)
  82                 {
  83                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
  84                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
  85                 }
  86         }
  87
  88         // store new time itself
  89         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
  90         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
  91 }
  92
  93 string race_readName(string map, float pos)
  94 {
  95         string rr = ((g_cts) ? CTS_RECORD : ((g_ctf) ? CTF_RECORD : RACE_RECORD));
  96
  97         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
  98 }
  99
 100
 101 const float MAX_CHECKPOINTS = 255;
 102
 103 spawnfunc(target_checkpoint);
 104
 105 .float race_penalty;
 106 .float race_penalty_accumulator;
 107 .string race_penalty_reason;
 108 .float race_checkpoint; // player: next checkpoint that has to be reached
 109 .entity race_lastpenalty;
 110
 111 .entity sprite;
 112
 113 float race_checkpoint_records[MAX_CHECKPOINTS];
 114 string race_checkpoint_recordholders[MAX_CHECKPOINTS];
 115 float race_checkpoint_lasttimes[MAX_CHECKPOINTS];
 116 float race_checkpoint_lastlaps[MAX_CHECKPOINTS];
 117 entity race_checkpoint_lastplayers[MAX_CHECKPOINTS];
 118
 119 .float race_checkpoint_record[MAX_CHECKPOINTS];
 120
 121 float race_highest_checkpoint;
 122 float race_timed_checkpoint;
 123
 124 float defrag_ents;
 125 float defragcpexists;
 126
 127 float race_NextCheckpoint(float f)
 128 {
 129         if(f >= race_highest_checkpoint)
 130                 return 0;
 131         else
 132                 return f + 1;
 133 }
 134
 135 float race_PreviousCheckpoint(float f)
 136 {
 137         if(f == -1)
 138                 return 0;
 139         else if(f == 0)
 140                 return race_highest_checkpoint;
 141         else
 142                 return f - 1;
 143 }
 144
 145 // encode as:
 146 //   0 = common start/finish
 147 // 254 = start
 148 // 255 = finish
 149 float race_CheckpointNetworkID(float f)
 150 {
 151         if(race_timed_checkpoint)
 152         {
 153                 if(f == 0)
 154                         return 254; // start
 155                 else if(f == race_timed_checkpoint)
 156                         return 255; // finish
 157         }
 158         return f;
 159 }
 160
 161 void race_SendNextCheckpoint(entity e, float spec) // qualifying only
 162 {
 163         if(!e.race_laptime)
 164                 return;
 165
 166         int cp = e.race_checkpoint;
 167         float recordtime = race_checkpoint_records[cp];
 168         float myrecordtime = e.race_checkpoint_record[cp];
 169         string recordholder = race_checkpoint_recordholders[cp];
 170         if(recordholder == e.netname)
 171                 recordholder = "";
 172
 173         if(!IS_REAL_CLIENT(e))
 174                 return;
 175
 176         if(!spec)
 177                 msg_entity = e;
 178         WRITESPECTATABLE_MSG_ONE(msg_entity, {
 179                 WriteHeader(MSG_ONE, TE_CSQC_RACE);
 180                 if(spec)
 181                 {
 182                         WriteByte(MSG_ONE, RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING);
 183                         //WriteCoord(MSG_ONE, e.race_laptime - e.race_penalty_accumulator);
 184                         WriteCoord(MSG_ONE, time - e.race_movetime - e.race_penalty_accumulator);
 185                 }
 186                 else
 187                         WriteByte(MSG_ONE, RACE_NET_CHECKPOINT_NEXT_QUALIFYING);
 188                 WriteByte(MSG_ONE, race_CheckpointNetworkID(cp)); // checkpoint the player will be at next
 189                 WriteInt24_t(MSG_ONE, recordtime);
 190                 if(!spec)
 191                         WriteInt24_t(MSG_ONE, myrecordtime);
 192                 WriteString(MSG_ONE, recordholder);
 193         });
 194 }
 195
 196 void race_send_recordtime(float msg)
 197 {
 198         // send the server best time
 199         WriteHeader(msg, TE_CSQC_RACE);
 200         WriteByte(msg, RACE_NET_SERVER_RECORD);
 201         WriteInt24_t(msg, race_readTime(GetMapname(), 1));
 202 }
 203
 204
 205 void race_send_speedaward(float msg)
 206 {
 207         // send the best speed of the round
 208         WriteHeader(msg, TE_CSQC_RACE);
 209         WriteByte(msg, RACE_NET_SPEED_AWARD);
 210         WriteInt24_t(msg, floor(speedaward_speed+0.5));
 211         WriteString(msg, speedaward_holder);
 212 }
 213
 214 void race_send_speedaward_alltimebest(float msg)
 215 {
 216         // send the best speed
 217         WriteHeader(msg, TE_CSQC_RACE);
 218         WriteByte(msg, RACE_NET_SPEED_AWARD_BEST);
 219         WriteInt24_t(msg, floor(speedaward_alltimebest+0.5));
 220         WriteString(msg, speedaward_alltimebest_holder);
 221 }
 222
 223 void race_SendRankings(float pos, float prevpos, float del, float msg)
 224 {
 225         WriteHeader(msg, TE_CSQC_RACE);
 226         WriteByte(msg, RACE_NET_SERVER_RANKINGS);
 227         WriteShort(msg, pos);
 228         WriteShort(msg, prevpos);
 229         WriteShort(msg, del);
 230         WriteString(msg, race_readName(GetMapname(), pos));
 231         WriteInt24_t(msg, race_readTime(GetMapname(), pos));
 232 }
 233
 234 void race_SendStatus(float id, entity e)
 235 {
 236         if(!IS_REAL_CLIENT(e))
 237                 return;
 238
 239         float msg;
 240         if (id == 0)
 241                 msg = MSG_ONE;
 242         else
 243                 msg = MSG_ALL;
 244         msg_entity = e;
 245         WRITESPECTATABLE_MSG_ONE(msg_entity, {
 246                 WriteHeader(msg, TE_CSQC_RACE);
 247                 WriteByte(msg, RACE_NET_SERVER_STATUS);
 248                 WriteShort(msg, id);
 249                 WriteString(msg, e.netname);
 250         });
 251 }
 252
 253 void race_setTime(string map, float t, string myuid, string mynetname, entity e, bool showmessage)
 254 {
 255         // netname only used TEMPORARILY for printing
 256         int newpos = race_readPos(map, t);
 257
 258         int player_prevpos = 0;
 259         for(int i = 1; i <= RANKINGS_CNT; ++i)
 260         {
 261                 if(race_readUID(map, i) == myuid)
 262                         player_prevpos = i;
 263         }
 264
 265         float oldrec;
 266         string oldrec_holder;
 267         if (player_prevpos && (player_prevpos < newpos || !newpos))
 268         {
 269                 oldrec = race_readTime(GetMapname(), player_prevpos);
 270                 race_SendStatus(0, e); // "fail"
 271                 if(showmessage)
 272                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_FAIL_RANKED, mynetname, player_prevpos, t, oldrec);
 273                 return;
 274         }
 275         else if (!newpos)
 276         {
 277                 // no ranking, time worse than the worst ranked
 278                 oldrec = race_readTime(GetMapname(), RANKINGS_CNT);
 279                 race_SendStatus(0, e); // "fail"
 280                 if(showmessage)
 281                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_FAIL_UNRANKED, mynetname, RANKINGS_CNT, t, oldrec);
 282                 return;
 283         }
 284
 285         // if we didn't hit a return yet, we have a new record!
 286
 287         // if the player does not have a UID we can unfortunately not store the record, as the rankings system relies on UIDs
 288         if(myuid == "")
 289         {
 290                 if(showmessage)
 291                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_NEW_MISSING_UID, mynetname, t);
 292                 return;
 293         }
 294
 295         if(uid2name(myuid) == "^1Unregistered Player")
 296         {
 297                 if(showmessage)
 298                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_NEW_MISSING_NAME, mynetname, t);
 299                 return;
 300         }
 301
 302         oldrec = race_readTime(GetMapname(), newpos);
 303         oldrec_holder = race_readName(GetMapname(), newpos);
 304
 305         // store new ranking
 306         race_writeTime(GetMapname(), t, myuid);
 307
 308         if (newpos == 1 && showmessage)
 309         {
 310                 write_recordmarker(e, time - TIME_DECODE(t), TIME_DECODE(t));
 311                 race_send_recordtime(MSG_ALL);
 312         }
 313
 314         race_SendRankings(newpos, player_prevpos, 0, MSG_ALL);
 315         if(rankings_reply)
 316                 strunzone(rankings_reply);
 317         rankings_reply = strzone(getrankings());
 318
 319         if(newpos == player_prevpos)
 320         {
 321                 if(showmessage)
 322                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_NEW_IMPROVED, mynetname, newpos, t, oldrec);
 323                 if(newpos == 1) { race_SendStatus(3, e); } // "new server record"
 324                 else { race_SendStatus(1, e); } // "new time"
 325         }
 326         else if(oldrec == 0)
 327         {
 328                 if(showmessage)
 329                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_NEW_SET, mynetname, newpos, t);
 330                 if(newpos == 1) { race_SendStatus(3, e); } // "new server record"
 331                 else { race_SendStatus(2, e); } // "new rank"
 332         }
 333         else
 334         {
 335                 if(showmessage)
 336                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_NEW_BROKEN, mynetname, oldrec_holder, newpos, t, oldrec);
 337                 if(newpos == 1) { race_SendStatus(3, e); } // "new server record"
 338                 else { race_SendStatus(2, e); } // "new rank"
 339         }
 340 }
 341
 342 void race_deleteTime(string map, float pos)
 343 {
 344         string rr = ((g_cts) ? CTS_RECORD : ((g_ctf) ? CTF_RECORD : RACE_RECORD));
 345
 346         for(int i = pos; i <= RANKINGS_CNT; ++i)
 347         {
 348                 string therank = ftos(i);
 349                 if (i == RANKINGS_CNT)
 350                 {
 351                         db_remove(ServerProgsDB, strcat(map, rr, "time", therank));
 352                         db_remove(ServerProgsDB, strcat(map, rr, "crypto_idfp", therank));
 353                 }
 354                 else
 355                 {
 356                         db_put(ServerProgsDB, strcat(map, rr, "time", therank), ftos(race_readTime(GetMapname(), i+1)));
 357                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", therank), race_readUID(GetMapname(), i+1));
 358                 }
 359         }
 360
 361         race_SendRankings(pos, 0, 1, MSG_ALL);
 362         if(pos == 1)
 363                 race_send_recordtime(MSG_ALL);
 364
 365         if(rankings_reply)
 366                 strunzone(rankings_reply);
 367         rankings_reply = strzone(getrankings());
 368 }
 369
 370 void race_SendTime(entity e, float cp, float t, float tvalid)
 371 {
 372         float snew, l;
 373
 374         if(g_race_qualifying)
 375                 t += e.race_penalty_accumulator;
 376
 377         t = TIME_ENCODE(t); // make integer
 378
 379         if(tvalid)
 380         if(cp == race_timed_checkpoint) // finish line
 381         if (!e.race_completed)
 382         {
 383                 float s;
 384                 if(g_race_qualifying)
 385                 {
 386                         s = PlayerScore_Add(e, SP_RACE_FASTEST, 0);
 387                         if(!s || t < s)
 388                                 PlayerScore_Add(e, SP_RACE_FASTEST, t - s);
 389                 }
 390                 else
 391                 {
 392                         s = PlayerScore_Add(e, SP_RACE_FASTEST, 0);
 393                         if(!s || t < s)
 394                                 PlayerScore_Add(e, SP_RACE_FASTEST, t - s);
 395
 396                         s = PlayerScore_Add(e, SP_RACE_TIME, 0);
 397                         snew = TIME_ENCODE(time - game_starttime);
 398                         PlayerScore_Add(e, SP_RACE_TIME, snew - s);
 399                         l = PlayerTeamScore_Add(e, SP_RACE_LAPS, ST_RACE_LAPS, 1);
 400
 401                         if(autocvar_fraglimit)
 402                                 if(l >= autocvar_fraglimit)
 403                                         race_StartCompleting();
 404
 405                         if(race_completing)
 406                         {
 407                                 e.race_completed = 1;
 408                                 MAKE_INDEPENDENT_PLAYER(e);
 409                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_FINISHED, e.netname);
 410                                 ClientData_Touch(e);
 411                         }
 412                 }
 413         }
 414
 415         if(g_race_qualifying)
 416         {
 417                 float recordtime;
 418                 string recordholder;
 419
 420                 if(tvalid)
 421                 {
 422                         recordtime = race_checkpoint_records[cp];
 423                         float myrecordtime = e.race_checkpoint_record[cp];
 424                         recordholder = strcat1(race_checkpoint_recordholders[cp]); // make a tempstring copy, as we'll possibly strunzone it!
 425                         if(recordholder == e.netname)
 426                                 recordholder = "";
 427
 428                         if(t != 0)
 429                         {
 430                                 if(cp == race_timed_checkpoint)
 431                                 {
 432                                         race_setTime(GetMapname(), t, e.crypto_idfp, e.netname, e, true);
 433                                         MUTATOR_CALLHOOK(Race_FinalCheckpoint, e);
 434                                 }
 435                                 if(t < myrecordtime || myrecordtime == 0)
 436                                         e.race_checkpoint_record[cp] = t; // resending done below
 437
 438                                 if(t < recordtime || recordtime == 0)
 439                                 {
 440                                         race_checkpoint_records[cp] = t;
 441                                         if(race_checkpoint_recordholders[cp])
 442                                                 strunzone(race_checkpoint_recordholders[cp]);
 443                                         race_checkpoint_recordholders[cp] = strzone(e.netname);
 444                                         if(g_race_qualifying)
 445                                                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && it.race_checkpoint == cp, LAMBDA(race_SendNextCheckpoint(it, 0)));
 446                                 }
 447
 448                         }
 449                 }
 450                 else
 451                 {
 452                         // dummies
 453                         t = 0;
 454                         recordtime = 0;
 455                         recordholder = "";
 456                 }
 457
 458                 if(IS_REAL_CLIENT(e))
 459                 {
 460                         if(g_race_qualifying)
 461                         {
 462                                 FOREACH_CLIENT(IS_REAL_CLIENT(it),
 463                                 {
 464                                         if(it == e || (IS_SPEC(it) && it.enemy == e))
 465                                         {
 466                                                 msg_entity = it;
 467                                                 WriteHeader(MSG_ONE, TE_CSQC_RACE);
 468                                                 WriteByte(MSG_ONE, RACE_NET_CHECKPOINT_HIT_QUALIFYING);
 469                                                 WriteByte(MSG_ONE, race_CheckpointNetworkID(cp)); // checkpoint the player now is at
 470                                                 WriteInt24_t(MSG_ONE, t); // time to that intermediate
 471                                                 WriteInt24_t(MSG_ONE, recordtime); // previously best time
 472                                                 WriteInt24_t(MSG_ONE, ((tvalid) ? it.race_checkpoint_record[cp] : 0)); // previously best time
 473                                                 WriteString(MSG_ONE, recordholder); // record holder
 474                                         }
 475                                 });
 476                         }
 477                 }
 478         }
 479         else // RACE! Not Qualifying
 480         {
 481                 float mylaps, lother, othtime;
 482                 entity oth = race_checkpoint_lastplayers[cp];
 483                 if(oth)
 484                 {
 485                         mylaps = PlayerScore_Add(e, SP_RACE_LAPS, 0);
 486                         lother = race_checkpoint_lastlaps[cp];
 487                         othtime = race_checkpoint_lasttimes[cp];
 488                 }
 489                 else
 490                         mylaps = lother = othtime = 0;
 491
 492                 if(IS_REAL_CLIENT(e))
 493                 {
 494                         msg_entity = e;
 495                         WRITESPECTATABLE_MSG_ONE(msg_entity, {
 496                                 WriteHeader(MSG_ONE, TE_CSQC_RACE);
 497                                 WriteByte(MSG_ONE, RACE_NET_CHECKPOINT_HIT_RACE);
 498                                 WriteByte(MSG_ONE, race_CheckpointNetworkID(cp)); // checkpoint the player now is at
 499                                 if(e == oth)
 500                                 {
 501                                         WriteInt24_t(MSG_ONE, 0);
 502                                         WriteByte(MSG_ONE, 0);
 503                                         WriteByte(MSG_ONE, 0);
 504                                 }
 505                                 else
 506                                 {
 507                                         WriteInt24_t(MSG_ONE, TIME_ENCODE(time - race_checkpoint_lasttimes[cp]));
 508                                         WriteByte(MSG_ONE, mylaps - lother);
 509                                         WriteByte(MSG_ONE, etof(oth)); // record holder
 510                                 }
 511                         });
 512                 }
 513
 514                 race_checkpoint_lastplayers[cp] = e;
 515                 race_checkpoint_lasttimes[cp] = time;
 516                 race_checkpoint_lastlaps[cp] = mylaps;
 517
 518                 if(IS_REAL_CLIENT(oth))
 519                 {
 520                         msg_entity = oth;
 521                         WRITESPECTATABLE_MSG_ONE(msg_entity, {
 522                                 WriteHeader(MSG_ONE, TE_CSQC_RACE);
 523                                 WriteByte(MSG_ONE, RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT);
 524                                 WriteByte(MSG_ONE, race_CheckpointNetworkID(cp)); // checkpoint the player now is at
 525                                 if(e == oth)
 526                                 {
 527                                         WriteInt24_t(MSG_ONE, 0);
 528                                         WriteByte(MSG_ONE, 0);
 529                                         WriteByte(MSG_ONE, 0);
 530                                 }
 531                                 else
 532                                 {
 533                                         WriteInt24_t(MSG_ONE, TIME_ENCODE(time - othtime));
 534                                         WriteByte(MSG_ONE, lother - mylaps);
 535                                         WriteByte(MSG_ONE, etof(e) - 1); // record holder
 536                                 }
 537                         });
 538                 }
 539         }
 540 }
 541
 542 void race_ClearTime(entity e)
 543 {
 544         e.race_checkpoint = 0;
 545         e.race_laptime = 0;
 546         e.race_movetime = e.race_movetime_frac = e.race_movetime_count = 0;
 547         e.race_penalty_accumulator = 0;
 548         e.race_lastpenalty = NULL;
 549
 550         if(!IS_REAL_CLIENT(e))
 551                 return;
 552
 553         msg_entity = e;
 554         WRITESPECTATABLE_MSG_ONE(msg_entity, {
 555                 WriteHeader(MSG_ONE, TE_CSQC_RACE);
 556                 WriteByte(MSG_ONE, RACE_NET_CHECKPOINT_CLEAR); // next
 557         });
 558 }
 559
 560 void checkpoint_passed(entity this, entity player)
 561 {
 562         if(player.personal && autocvar_g_allow_checkpoints)
 563                 return; // practice mode!
 564
 565         if(player.classname == "porto")
 566         {
 567                 // do not allow portalling through checkpoints
 568                 trace_plane_normal = normalize(-1 * player.velocity);
 569                 W_Porto_Fail(player, 0);
 570                 return;
 571         }
 572
 573         string oldmsg; // used twice
 574
 575         /*
 576          * Trigger targets
 577          */
 578         if (!((this.spawnflags & 2) && (IS_PLAYER(player))))
 579         {
 580                 oldmsg = this.message;
 581                 this.message = "";
 582                 SUB_UseTargets(this, player, player);
 583                 this.message = oldmsg;
 584         }
 585
 586         if (!IS_PLAYER(player))
 587                 return;
 588
 589         /*
 590          * Remove unauthorized equipment
 591          */
 592         Portal_ClearAll(player);
 593
 594         player.porto_forbidden = 2; // decreased by 1 each StartFrame
 595
 596         if(defrag_ents)
 597         {
 598                 if(this.race_checkpoint == -2)
 599                 {
 600                         this.race_checkpoint = player.race_checkpoint;
 601                 }
 602
 603                 int cp_amount = 0, largest_cp_id = 0;
 604                 IL_EACH(g_race_targets, it.classname == "target_checkpoint",
 605                 {
 606                         cp_amount += 1;
 607                         if(it.race_checkpoint > largest_cp_id) // update the finish id if someone hit a new checkpoint
 608                         {
 609                                 if(!largest_cp_id)
 610                                 {
 611                                         IL_EACH(g_race_targets, it.classname == "target_checkpoint",
 612                                         {
 613                                                 if(it.race_checkpoint == -2) // set defragcpexists to -1 so that the cp id file will be rewritten when someone finishes
 614                                                         defragcpexists = -1;
 615                                         });
 616                                 }
 617
 618                                 largest_cp_id = it.race_checkpoint;
 619                                 IL_EACH(g_race_targets, it.classname == "target_stopTimer",
 620                                 {
 621                                         it.race_checkpoint = largest_cp_id + 1; // finish line
 622                                 });
 623                                 race_highest_checkpoint = largest_cp_id + 1;
 624                                 race_timed_checkpoint = largest_cp_id + 1;
 625                         }
 626                 });
 627
 628                 if(!cp_amount)
 629                 {
 630                         IL_EACH(g_race_targets, it.classname == "target_stopTimer",
 631                         {
 632                                 it.race_checkpoint = 1;
 633                         });
 634                         race_highest_checkpoint = 1;
 635                         race_timed_checkpoint = 1;
 636                 }
 637         }
 638
 639         if((player.race_checkpoint == -1 && this.race_checkpoint == 0) || (player.race_checkpoint == this.race_checkpoint))
 640         {
 641                 if(this.race_penalty)
 642                 {
 643                         if(player.race_lastpenalty != this)
 644                         {
 645                                 player.race_lastpenalty = this;
 646                                 race_ImposePenaltyTime(player, this.race_penalty, this.race_penalty_reason);
 647                         }
 648                 }
 649
 650                 if(player.race_penalty)
 651                         return;
 652
 653                 /*
 654                  * Trigger targets
 655                  */
 656                 if(this.spawnflags & 2)
 657                 {
 658                         oldmsg = this.message;
 659                         this.message = "";
 660                         SUB_UseTargets(this, player, player); // TODO: should we be using other for the trigger here?
 661                         this.message = oldmsg;
 662                 }
 663
 664                 if(player.race_respawn_checkpoint != this.race_checkpoint || !player.race_started)
 665                         player.race_respawn_spotref = this; // this is not a spot but a CP, but spawnpoint selection will deal with that
 666                 player.race_respawn_checkpoint = this.race_checkpoint;
 667                 player.race_checkpoint = race_NextCheckpoint(this.race_checkpoint);
 668                 player.race_started = 1;
 669
 670                 race_SendTime(player, this.race_checkpoint, player.race_movetime, boolean(player.race_laptime));
 671
 672                 if(!this.race_checkpoint) // start line
 673                 {
 674                         player.race_laptime = time;
 675                         player.race_movetime = player.race_movetime_frac = player.race_movetime_count = 0;
 676                         player.race_penalty_accumulator = 0;
 677                         player.race_lastpenalty = NULL;
 678                 }
 679
 680                 if(g_race_qualifying)
 681                         race_SendNextCheckpoint(player, 0);
 682
 683                 if(defrag_ents && defragcpexists < 0 && this.classname == "target_stopTimer")
 684                 {
 685                         float fh;
 686                         defragcpexists = fh = fopen(strcat("maps/", GetMapname(), ".defragcp"), FILE_WRITE);
 687                         if(fh >= 0)
 688                         {
 689                                 IL_EACH(g_race_targets, it.classname == "target_checkpoint",
 690                                 {
 691                                         fputs(fh, strcat(it.targetname, " ", ftos(it.race_checkpoint), "\n"));
 692                                 });
 693                         }
 694                         fclose(fh);
 695                 }
 696         }
 697         else if(player.race_checkpoint == race_NextCheckpoint(this.race_checkpoint))
 698         {
 699                 // ignored
 700         }
 701         else
 702         {
 703                 if(this.spawnflags & 4)
 704                         Damage (player, this, this, 10000, DEATH_HURTTRIGGER.m_id, player.origin, '0 0 0');
 705         }
 706 }
 707
 708 void checkpoint_touch(entity this, entity toucher)
 709 {
 710         EXACTTRIGGER_TOUCH(this, toucher);
 711         checkpoint_passed(this, toucher);
 712 }
 713
 714 void checkpoint_use(entity this, entity actor, entity trigger)
 715 {
 716         if(trigger.classname == "info_player_deathmatch") // a spawn, a spawn
 717                 return;
 718
 719         checkpoint_passed(this, actor);
 720 }
 721
 722 bool race_waypointsprite_visible_for_player(entity this, entity player, entity view)
 723 {
 724         entity own = this.owner;
 725         if(this.realowner)
 726                 own = this.realowner; // target support
 727
 728         if(view.race_checkpoint == -1 || own.race_checkpoint == -2)
 729                 return true;
 730         else if(view.race_checkpoint == own.race_checkpoint)
 731                 return true;
 732         else
 733                 return false;
 734 }
 735
 736 void trigger_race_checkpoint_verify(entity this)
 737 {
 738     static bool have_verified;
 739         if (have_verified) return;
 740         have_verified = true;
 741
 742         bool qual = g_race_qualifying;
 743
 744         int pl_race_checkpoint = 0;
 745         int pl_race_place = 0;
 746
 747         if (g_race) {
 748                 for (int i = 0; i <= race_highest_checkpoint; ++i) {
 749                         pl_race_checkpoint = race_NextCheckpoint(i);
 750
 751                         // race only (middle of the race)
 752                         g_race_qualifying = false;
 753                         pl_race_place = 0;
 754                         if (!Spawn_FilterOutBadSpots(this, findchain(classname, "info_player_deathmatch"), 0, false)) {
 755                                 error(strcat("Checkpoint ", ftos(i), " misses a spawnpoint with race_place==", ftos(pl_race_place), " (used for respawning in race) - bailing out"));
 756             }
 757
 758                         if (i == 0) {
 759                                 // qualifying only
 760                                 g_race_qualifying = 1;
 761                                 pl_race_place = race_lowest_place_spawn;
 762                                 if (!Spawn_FilterOutBadSpots(this, findchain(classname, "info_player_deathmatch"), 0, false)) {
 763                                         error(strcat("Checkpoint ", ftos(i), " misses a spawnpoint with race_place==", ftos(pl_race_place), " (used for qualifying) - bailing out"));
 764                 }
 765
 766                                 // race only (initial spawn)
 767                                 g_race_qualifying = 0;
 768                                 for (int p = 1; p <= race_highest_place_spawn; ++p) {
 769                                         pl_race_place = p;
 770                                         if (!Spawn_FilterOutBadSpots(this, findchain(classname, "info_player_deathmatch"), 0, false)) {
 771                                                 error(strcat("Checkpoint ", ftos(i), " misses a spawnpoint with race_place==", ftos(pl_race_place), " (used for initially spawning in race) - bailing out"));
 772                     }
 773                                 }
 774                         }
 775                 }
 776         } else if (!defrag_ents) {
 777                 // qualifying only
 778                 pl_race_checkpoint = race_NextCheckpoint(0);
 779                 g_race_qualifying = 1;
 780                 pl_race_place = race_lowest_place_spawn;
 781                 if (!Spawn_FilterOutBadSpots(this, findchain(classname, "info_player_deathmatch"), 0, false)) {
 782                         error(strcat("Checkpoint 0 misses a spawnpoint with race_place==", ftos(pl_race_place), " (used for qualifying) - bailing out"));
 783         }
 784         } else {
 785                 pl_race_checkpoint = race_NextCheckpoint(0);
 786                 g_race_qualifying = 1;
 787                 pl_race_place = 0; // there's only one spawn on defrag maps
 788
 789                 // check if a defragcp file already exists, then read it and apply the checkpoint order
 790                 float fh;
 791                 float len;
 792                 string l;
 793
 794                 defragcpexists = fh = fopen(strcat("maps/", GetMapname(), ".defragcp"), FILE_READ);
 795                 if (fh >= 0) {
 796                         while ((l = fgets(fh))) {
 797                                 len = tokenize_console(l);
 798                                 if (len != 2) {
 799                                         defragcpexists = -1; // something's wrong in the defrag cp file, set defragcpexists to -1 so that it will be rewritten when someone finishes
 800                                         continue;
 801                                 }
 802                                 for (entity cp = NULL; (cp = find(cp, classname, "target_checkpoint"));) {
 803                                         if (argv(0) == cp.targetname) {
 804                                                 cp.race_checkpoint = stof(argv(1));
 805                     }
 806                 }
 807                         }
 808                         fclose(fh);
 809                 }
 810         }
 811
 812         g_race_qualifying = qual;
 813
 814         IL_EACH(g_race_targets, true,
 815         {
 816                 entity cpt = it;
 817                 FOREACH_ENTITY_STRING(target, cpt.targetname,
 818                 {
 819                         vector org = (it.absmin + it.absmax) * 0.5;
 820                         if(cpt.race_checkpoint == 0)
 821                                 WaypointSprite_SpawnFixed(WP_RaceStart, org, it, sprite, RADARICON_NONE);
 822                         else
 823                                 WaypointSprite_SpawnFixed(WP_RaceCheckpoint, org, it, sprite, RADARICON_NONE);
 824
 825                         it.sprite.realowner = cpt;
 826                         it.sprite.waypointsprite_visible_for_player = race_waypointsprite_visible_for_player;
 827                 });
 828         });
 829
 830         if (race_timed_checkpoint) {
 831                 if (defrag_ents) {
 832                         IL_EACH(g_race_targets, true,
 833                         {
 834                                 entity cpt = it;
 835                                 if(it.classname == "target_startTimer" || it.classname == "target_stopTimer") {
 836                                         FOREACH_ENTITY_STRING(target, cpt.targetname, {
 837                                                 WaypointSprite_UpdateSprites(it.sprite, ((cpt.classname == "target_startTimer") ? WP_RaceStart : WP_RaceFinish), WP_Null, WP_Null);
 838                                         });
 839                                 }
 840                                 if(it.classname == "target_checkpoint") {
 841                                         if(it.race_checkpoint == -2)
 842                                                 defragcpexists = -1; // something's wrong with the defrag cp file or it has not been written yet, set defragcpexists to -1 so that it will be rewritten when someone finishes
 843                                 }
 844                         });
 845                         if (defragcpexists != -1) {
 846                                 float largest_cp_id = 0;
 847                                 for (entity cp = NULL; (cp = find(cp, classname, "target_checkpoint"));) {
 848                                         if (cp.race_checkpoint > largest_cp_id) {
 849                                                 largest_cp_id = cp.race_checkpoint;
 850                     }
 851                 }
 852                                 for (entity cp = NULL; (cp = find(cp, classname, "target_stopTimer"));) {
 853                                         cp.race_checkpoint = largest_cp_id + 1; // finish line
 854                 }
 855                                 race_highest_checkpoint = largest_cp_id + 1;
 856                                 race_timed_checkpoint = largest_cp_id + 1;
 857                         } else {
 858                                 for (entity cp = NULL; (cp = find(cp, classname, "target_stopTimer"));) {
 859                                         cp.race_checkpoint = 255; // finish line
 860                 }
 861                                 race_highest_checkpoint = 255;
 862                                 race_timed_checkpoint = 255;
 863                         }
 864                 } else {
 865                         IL_EACH(g_racecheckpoints, it.sprite,
 866                         {
 867                                 if (it.race_checkpoint == 0) {
 868                                         WaypointSprite_UpdateSprites(it.sprite, WP_RaceStart, WP_Null, WP_Null);
 869                 } else if (it.race_checkpoint == race_timed_checkpoint) {
 870                                         WaypointSprite_UpdateSprites(it.sprite, WP_RaceFinish, WP_Null, WP_Null);
 871                                 }
 872             });
 873                 }
 874         }
 875
 876         if (defrag_ents) {
 877                 for (entity trigger = NULL; (trigger = find(trigger, classname, "trigger_multiple")); ) {
 878                         for (entity targ = NULL; (targ = find(targ, targetname, trigger.target)); ) {
 879                                 if (targ.classname == "target_checkpoint" || targ.classname == "target_startTimer" || targ.classname == "target_stopTimer") {
 880                                         trigger.wait = 0;
 881                                         trigger.delay = 0;
 882                                         targ.wait = 0;
 883                                         targ.delay = 0;
 884
 885                     // These just make the game crash on some maps with oddly shaped triggers.
 886                     // (on the other hand they used to fix the case when two players ran through a checkpoint at once,
 887                     // and often one of them just passed through without being registered. Hope it's fixed  in a better way now.
 888                     // (happened on item triggers too)
 889                     //
 890                                         //targ.wait = -2;
 891                                         //targ.delay = 0;
 892
 893                                         //setsize(targ, trigger.mins, trigger.maxs);
 894                                         //setorigin(targ, trigger.origin);
 895                                         //remove(trigger);
 896                                 }
 897             }
 898         }
 899         }
 900 }
 901
 902 vector trigger_race_checkpoint_spawn_evalfunc(entity this, entity player, entity spot, vector current)
 903 {
 904         if(g_race_qualifying)
 905         {
 906                 // spawn at first
 907                 if(this.race_checkpoint != 0)
 908                         return '-1 0 0';
 909                 if(spot.race_place != race_lowest_place_spawn)
 910                         return '-1 0 0';
 911         }
 912         else
 913         {
 914                 if(this.race_checkpoint != player.race_respawn_checkpoint)
 915                         return '-1 0 0';
 916                 // try reusing the previous spawn
 917                 if(this == player.race_respawn_spotref || spot == player.race_respawn_spotref)
 918                         current.x += SPAWN_PRIO_RACE_PREVIOUS_SPAWN;
 919                 if(this.race_checkpoint == 0)
 920                 {
 921                         int pl = player.race_place;
 922                         if(pl > race_highest_place_spawn)
 923                                 pl = 0;
 924                         if(pl == 0 && !player.race_started)
 925                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 926                         if(spot.race_place != pl)
 927                                 return '-1 0 0';
 928                 }
 929         }
 930         return current;
 931 }
 932
 933 spawnfunc(trigger_race_checkpoint)
 934 {
 935         vector o;
 936         if(!g_race && !g_cts) { delete(this); return; }
 937
 938         EXACTTRIGGER_INIT;
 939
 940         this.use = checkpoint_use;
 941         if (!(this.spawnflags & 1))
 942                 settouch(this, checkpoint_touch);
 943
 944         o = (this.absmin + this.absmax) * 0.5;
 945         tracebox(o, PL_MIN_CONST, PL_MAX_CONST, o - '0 0 1' * (o.z - this.absmin.z), MOVE_NORMAL, this);
 946         waypoint_spawnforitem_force(this, trace_endpos);
 947         this.nearestwaypointtimeout = -1;
 948
 949         if(this.message == "")
 950                 this.message = "went backwards";
 951         if (this.message2 == "")
 952                 this.message2 = "was pushed backwards by";
 953         if (this.race_penalty_reason == "")
 954                 this.race_penalty_reason = "missing a checkpoint";
 955
 956         this.race_checkpoint = this.cnt;
 957
 958         if(this.race_checkpoint > race_highest_checkpoint)
 959         {
 960                 race_highest_checkpoint = this.race_checkpoint;
 961                 if(this.spawnflags & 8)
 962                         race_timed_checkpoint = this.race_checkpoint;
 963                 else
 964                         race_timed_checkpoint = 0;
 965         }
 966
 967         if(!this.race_penalty)
 968         {
 969                 if(this.race_checkpoint)
 970                         WaypointSprite_SpawnFixed(WP_RaceCheckpoint, o, this, sprite, RADARICON_NONE);
 971                 else
 972                         WaypointSprite_SpawnFixed(WP_RaceStartFinish, o, this, sprite, RADARICON_NONE);
 973         }
 974
 975         this.sprite.waypointsprite_visible_for_player = race_waypointsprite_visible_for_player;
 976         this.spawn_evalfunc = trigger_race_checkpoint_spawn_evalfunc;
 977
 978         IL_PUSH(g_racecheckpoints, this);
 979
 980         InitializeEntity(this, trigger_race_checkpoint_verify, INITPRIO_FINDTARGET);
 981 }
 982
 983 spawnfunc(target_checkpoint) // defrag entity
 984 {
 985         if(!g_race && !g_cts) { delete(this); return; }
 986         defrag_ents = 1;
 987
 988         // if this is targeted, then it probably isn't a trigger
 989         bool is_trigger = !boolean(!this.nottargeted && this.targetname != "");
 990
 991         if(is_trigger)
 992                 EXACTTRIGGER_INIT;
 993
 994         this.use = checkpoint_use;
 995         if (is_trigger && !(this.spawnflags & 1))
 996                 settouch(this, checkpoint_touch);
 997
 998         vector org = this.origin;
 999
1000         // bots should only pathfind to this if it is a valid touchable trigger
1001         if(is_trigger)
1002         {
1003                 org = (this.absmin + this.absmax) * 0.5;
1004                 tracebox(org, PL_MIN_CONST, PL_MAX_CONST, org - '0 0 1' * (org.z - this.absmin.z), MOVE_NORMAL, this);
1005                 waypoint_spawnforitem_force(this, trace_endpos);
1006                 this.nearestwaypointtimeout = -1;
1007         }
1008
1009         if(this.message == "")
1010                 this.message = "went backwards";
1011         if (this.message2 == "")
1012                 this.message2 = "was pushed backwards by";
1013         if (this.race_penalty_reason == "")
1014                 this.race_penalty_reason = "missing a checkpoint";
1015
1016         if(this.classname == "target_startTimer")
1017                 this.race_checkpoint = 0;
1018         else
1019                 this.race_checkpoint = -2;
1020
1021         race_timed_checkpoint = 1;
1022
1023         IL_PUSH(g_race_targets, this);
1024
1025         InitializeEntity(this, trigger_race_checkpoint_verify, INITPRIO_FINDTARGET);
1026 }
1027
1028 spawnfunc(target_startTimer) { spawnfunc_target_checkpoint(this); }
1029 spawnfunc(target_stopTimer) { spawnfunc_target_checkpoint(this); }
1030
1031 void race_AbandonRaceCheck(entity p)
1032 {
1033         if(race_completing && !p.race_completed)
1034         {
1035                 p.race_completed = 1;
1036                 MAKE_INDEPENDENT_PLAYER(p);
1037                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_ABANDONED, p.netname);
1038                 ClientData_Touch(p);
1039         }
1040 }
1041
1042 void race_StartCompleting()
1043 {
1044         race_completing = 1;
1045         FOREACH_CLIENT(IS_PLAYER(it) && IS_DEAD(it), LAMBDA(race_AbandonRaceCheck(it)));
1046 }
1047
1048 void race_PreparePlayer(entity this)
1049 {
1050         race_ClearTime(this);
1051         this.race_place = 0;
1052         this.race_started = 0;
1053         this.race_respawn_checkpoint = 0;
1054         this.race_respawn_spotref = NULL;
1055 }
1056
1057 void race_RetractPlayer(entity this)
1058 {
1059         if(!g_race && !g_cts)
1060                 return;
1061         if(this.race_respawn_checkpoint == 0 || this.race_respawn_checkpoint == race_timed_checkpoint)
1062                 race_ClearTime(this);
1063         this.race_checkpoint = this.race_respawn_checkpoint;
1064 }
1065
1066 spawnfunc(info_player_race)
1067 {
1068         if(!g_race && !g_cts) { delete(this); return; }
1069         ++race_spawns;
1070         spawnfunc_info_player_deathmatch(this);
1071
1072         if(this.race_place > race_highest_place_spawn)
1073                 race_highest_place_spawn = this.race_place;
1074         if(this.race_place < race_lowest_place_spawn)
1075                 race_lowest_place_spawn = this.race_place;
1076 }
1077
1078 void race_ClearRecords()
1079 {
1080         for(int j = 0; j < MAX_CHECKPOINTS; ++j)
1081         {
1082                 race_checkpoint_records[j] = 0;
1083                 if(race_checkpoint_recordholders[j])
1084                         strunzone(race_checkpoint_recordholders[j]);
1085                 race_checkpoint_recordholders[j] = string_null;
1086         }
1087
1088         FOREACH_CLIENT(true, LAMBDA(
1089                 float p = it.race_place;
1090                 race_PreparePlayer(it);
1091                 it.race_place = p;
1092         ));
1093 }
1094
1095 void race_ImposePenaltyTime(entity pl, float penalty, string reason)
1096 {
1097         if(g_race_qualifying)
1098         {
1099                 pl.race_penalty_accumulator += penalty;
1100                 if(IS_REAL_CLIENT(pl))
1101                 {
1102                         msg_entity = pl;
1103                         WRITESPECTATABLE_MSG_ONE(msg_entity, {
1104                                 WriteHeader(MSG_ONE, TE_CSQC_RACE);
1105                                 WriteByte(MSG_ONE, RACE_NET_PENALTY_QUALIFYING);
1106                                 WriteShort(MSG_ONE, TIME_ENCODE(penalty));
1107                                 WriteString(MSG_ONE, reason);
1108                         });
1109                 }
1110         }
1111         else
1112         {
1113                 pl.race_penalty = time + penalty;
1114                 if(IS_REAL_CLIENT(pl))
1115                 {
1116                         msg_entity = pl;
1117                         WRITESPECTATABLE_MSG_ONE(msg_entity, {
1118                                 WriteHeader(MSG_ONE, TE_CSQC_RACE);
1119                                 WriteByte(MSG_ONE, RACE_NET_PENALTY_RACE);
1120                                 WriteShort(MSG_ONE, TIME_ENCODE(penalty));
1121                                 WriteString(MSG_ONE, reason);
1122                         });
1123                 }
1124         }
1125 }
1126
1127 void penalty_touch(entity this, entity toucher)
1128 {
1129         EXACTTRIGGER_TOUCH(this, toucher);
1130         if(toucher.race_lastpenalty != this)
1131         {
1132                 toucher.race_lastpenalty = this;
1133                 race_ImposePenaltyTime(toucher, this.race_penalty, this.race_penalty_reason);
1134         }
1135 }
1136
1137 void penalty_use(entity this, entity actor, entity trigger)
1138 {
1139         race_ImposePenaltyTime(actor, this.race_penalty, this.race_penalty_reason);
1140 }
1141
1142 spawnfunc(trigger_race_penalty)
1143 {
1144         // TODO: find out why this wasnt done:
1145         //if(!g_cts && !g_race) { remove(this); return; }
1146
1147         EXACTTRIGGER_INIT;
1148
1149         this.use = penalty_use;
1150         if (!(this.spawnflags & 1))
1151                 settouch(this, penalty_touch);
1152
1153         if (this.race_penalty_reason == "")
1154                 this.race_penalty_reason = "missing a checkpoint";
1155         if (!this.race_penalty)
1156                 this.race_penalty = 5;
1157 }
1158
1159 float race_GetFractionalLapCount(entity e)
1160 {
1161         // interesting metrics (idea by KrimZon) to maybe sort players in the
1162         // scoreboard, immediately updates when overtaking
1163         //
1164         // requires the track to be built so you never get farther away from the
1165         // next checkpoint, though, and current Xonotic race maps are not built that
1166         // way
1167         //
1168         // also, this code is slow and would need optimization (i.e. "next CP"
1169         // links on CP entities)
1170
1171         float l;
1172         l = PlayerScore_Add(e, SP_RACE_LAPS, 0);
1173         if(e.race_completed)
1174                 return l; // not fractional
1175
1176         vector o0, o1;
1177         float bestfraction, fraction;
1178         entity lastcp;
1179         float nextcpindex, lastcpindex;
1180
1181         nextcpindex = max(e.race_checkpoint, 0);
1182         lastcpindex = e.race_respawn_checkpoint;
1183         lastcp = e.race_respawn_spotref;
1184
1185         if(nextcpindex == lastcpindex)
1186                 return l; // finish
1187
1188         bestfraction = 1;
1189         IL_EACH(g_racecheckpoints, true,
1190         {
1191                 if(it.race_checkpoint != lastcpindex)
1192                         continue;
1193                 if(lastcp)
1194                         if(it != lastcp)
1195                                 continue;
1196                 o0 = (it.absmin + it.absmax) * 0.5;
1197                 IL_EACH(g_racecheckpoints, true,
1198                 {
1199                         if(it.race_checkpoint != nextcpindex)
1200                                 continue;
1201                         o1 = (it.absmin + it.absmax) * 0.5;
1202                         if(o0 == o1)
1203                                 continue;
1204                         fraction = bound(0.0001, vlen(e.origin - o1) / vlen(o0 - o1), 1);
1205                         if(fraction < bestfraction)
1206                                 bestfraction = fraction;
1207                 });
1208         });
1209
1210         // we are at CP "nextcpindex - bestfraction"
1211         // race_timed_checkpoint == 4: then nextcp==4 means 0.9999x, nextcp==0 means 0.0000x
1212         // race_timed_checkpoint == 0: then nextcp==0 means 0.9999x
1213         float c, nc;
1214         nc = race_highest_checkpoint + 1;
1215         c = ((nextcpindex - race_timed_checkpoint + nc + nc - 1) % nc) + 1 - bestfraction;
1216
1217         return l + c / nc;
1218 }