qcsrc/server/race.qc

   1 #include "race.qh"
   2
   3 #include "client.qh"
   4 #include "portals.qh"
   5 #include "scores.qh"
   6 #include "spawnpoints.qh"
   7 #include "bot/api.qh"
   8 #include "command/getreplies.qh"
   9 #include "../common/deathtypes/all.qh"
  10 #include "../common/notifications/all.qh"
  11 #include "../common/mapinfo.qh"
  12 #include <common/net_linked.qh>
  13 #include "../common/triggers/subs.qh"
  14 #include "../lib/warpzone/util_server.qh"
  15 #include "../lib/warpzone/common.qh"
  16 #include "../common/mutators/mutator/waypoints/waypointsprites.qh"
  17
  18 IntrusiveList g_race_targets;
  19 STATIC_INIT(g_race_targets) { g_race_targets = IL_NEW(); }
  20
  21 void race_InitSpectator()
  22 {
  23         if(g_race_qualifying)
  24                 if(msg_entity.enemy.race_laptime)
  25                         race_SendNextCheckpoint(msg_entity.enemy, 1);
  26 }
  27
  28 void W_Porto_Fail(entity this, float failhard);
  29
  30 float race_readTime(string map, float pos)
  31 {
  32         string rr = ((g_cts) ? CTS_RECORD : ((g_ctf) ? CTF_RECORD : RACE_RECORD));
  33
  34         return stof(db_get(ServerProgsDB, strcat(map, rr, "time", ftos(pos))));
  35 }
  36
  37 string race_readUID(string map, float pos)
  38 {
  39         string rr = ((g_cts) ? CTS_RECORD : ((g_ctf) ? CTF_RECORD : RACE_RECORD));
  40
  41         return db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos)));
  42 }
  43
  44 float race_readPos(string map, float t)
  45 {
  46         for(int i = 1; i <= RANKINGS_CNT; ++i)
  47         {
  48                 int mytime = race_readTime(map, i);
  49                 if(!mytime || mytime > t)
  50                         return i;
  51         }
  52
  53         return 0; // pos is zero if unranked
  54 }
  55
  56 void race_writeTime(string map, float t, string myuid)
  57 {
  58         string rr = ((g_cts) ? CTS_RECORD : ((g_ctf) ? CTF_RECORD : RACE_RECORD));
  59
  60         float newpos;
  61         newpos = race_readPos(map, t);
  62
  63         float i, prevpos = 0;
  64         for(i = 1; i <= RANKINGS_CNT; ++i)
  65         {
  66                 if(race_readUID(map, i) == myuid)
  67                         prevpos = i;
  68         }
  69         if (prevpos)
  70         {
  71                 // player improved his existing record, only have to iterate on ranks between new and old recs
  72                 for (i = prevpos; i > newpos; --i)
  73                 {
  74                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
  75                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
  76                 }
  77         }
  78         else
  79         {
  80                 // player has no ranked record yet
  81                 for (i = RANKINGS_CNT; i > newpos; --i)
  82                 {
  83                         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(i)), ftos(race_readTime(map, i - 1)));
  84                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(i)), race_readUID(map, i - 1));
  85                 }
  86         }
  87
  88         // store new time itself
  89         db_put(ServerProgsDB, strcat(map, rr, "time", ftos(newpos)), ftos(t));
  90         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(newpos)), myuid);
  91 }
  92
  93 string race_readName(string map, float pos)
  94 {
  95         string rr = ((g_cts) ? CTS_RECORD : ((g_ctf) ? CTF_RECORD : RACE_RECORD));
  96
  97         return uid2name(db_get(ServerProgsDB, strcat(map, rr, "crypto_idfp", ftos(pos))));
  98 }
  99
 100
 101 const float MAX_CHECKPOINTS = 255;
 102
 103 spawnfunc(target_checkpoint);
 104
 105 .float race_penalty;
 106 .float race_penalty_accumulator;
 107 .string race_penalty_reason;
 108 .float race_checkpoint; // player: next checkpoint that has to be reached
 109 .entity race_lastpenalty;
 110
 111 .entity sprite;
 112
 113 float race_checkpoint_records[MAX_CHECKPOINTS];
 114 string race_checkpoint_recordholders[MAX_CHECKPOINTS];
 115 float race_checkpoint_lasttimes[MAX_CHECKPOINTS];
 116 float race_checkpoint_lastlaps[MAX_CHECKPOINTS];
 117 entity race_checkpoint_lastplayers[MAX_CHECKPOINTS];
 118
 119 .float race_checkpoint_record[MAX_CHECKPOINTS];
 120
 121 float race_highest_checkpoint;
 122 float race_timed_checkpoint;
 123
 124 float defrag_ents;
 125 float defragcpexists;
 126
 127 float race_NextCheckpoint(float f)
 128 {
 129         if(f >= race_highest_checkpoint)
 130                 return 0;
 131         else
 132                 return f + 1;
 133 }
 134
 135 float race_PreviousCheckpoint(float f)
 136 {
 137         if(f == -1)
 138                 return 0;
 139         else if(f == 0)
 140                 return race_highest_checkpoint;
 141         else
 142                 return f - 1;
 143 }
 144
 145 // encode as:
 146 //   0 = common start/finish
 147 // 254 = start
 148 // 255 = finish
 149 float race_CheckpointNetworkID(float f)
 150 {
 151         if(race_timed_checkpoint)
 152         {
 153                 if(f == 0)
 154                         return 254; // start
 155                 else if(f == race_timed_checkpoint)
 156                         return 255; // finish
 157         }
 158         return f;
 159 }
 160
 161 void race_SendNextCheckpoint(entity e, float spec) // qualifying only
 162 {
 163         if(!e.race_laptime)
 164                 return;
 165
 166         int cp = e.race_checkpoint;
 167         float recordtime = race_checkpoint_records[cp];
 168         float myrecordtime = e.race_checkpoint_record[cp];
 169         string recordholder = race_checkpoint_recordholders[cp];
 170         if(recordholder == e.netname)
 171                 recordholder = "";
 172
 173         if(!IS_REAL_CLIENT(e))
 174                 return;
 175
 176         if(!spec)
 177                 msg_entity = e;
 178         WRITESPECTATABLE_MSG_ONE(msg_entity, {
 179                 WriteHeader(MSG_ONE, TE_CSQC_RACE);
 180                 if(spec)
 181                 {
 182                         WriteByte(MSG_ONE, RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING);
 183                         //WriteCoord(MSG_ONE, e.race_laptime - e.race_penalty_accumulator);
 184                         WriteCoord(MSG_ONE, time - e.race_movetime - e.race_penalty_accumulator);
 185                 }
 186                 else
 187                         WriteByte(MSG_ONE, RACE_NET_CHECKPOINT_NEXT_QUALIFYING);
 188                 WriteByte(MSG_ONE, race_CheckpointNetworkID(cp)); // checkpoint the player will be at next
 189                 WriteInt24_t(MSG_ONE, recordtime);
 190                 if(!spec)
 191                         WriteInt24_t(MSG_ONE, myrecordtime);
 192                 WriteString(MSG_ONE, recordholder);
 193         });
 194 }
 195
 196 void race_send_recordtime(float msg)
 197 {
 198         // send the server best time
 199         WriteHeader(msg, TE_CSQC_RACE);
 200         WriteByte(msg, RACE_NET_SERVER_RECORD);
 201         WriteInt24_t(msg, race_readTime(GetMapname(), 1));
 202 }
 203
 204
 205 void race_send_speedaward(float msg)
 206 {
 207         // send the best speed of the round
 208         WriteHeader(msg, TE_CSQC_RACE);
 209         WriteByte(msg, RACE_NET_SPEED_AWARD);
 210         WriteInt24_t(msg, floor(speedaward_speed+0.5));
 211         WriteString(msg, speedaward_holder);
 212 }
 213
 214 void race_send_speedaward_alltimebest(float msg)
 215 {
 216         // send the best speed
 217         WriteHeader(msg, TE_CSQC_RACE);
 218         WriteByte(msg, RACE_NET_SPEED_AWARD_BEST);
 219         WriteInt24_t(msg, floor(speedaward_alltimebest+0.5));
 220         WriteString(msg, speedaward_alltimebest_holder);
 221 }
 222
 223 void race_SendRankings(float pos, float prevpos, float del, float msg)
 224 {
 225         WriteHeader(msg, TE_CSQC_RACE);
 226         WriteByte(msg, RACE_NET_SERVER_RANKINGS);
 227         WriteShort(msg, pos);
 228         WriteShort(msg, prevpos);
 229         WriteShort(msg, del);
 230         WriteString(msg, race_readName(GetMapname(), pos));
 231         WriteInt24_t(msg, race_readTime(GetMapname(), pos));
 232 }
 233
 234 void race_SendStatus(float id, entity e)
 235 {
 236         if(!IS_REAL_CLIENT(e))
 237                 return;
 238
 239         float msg;
 240         if (id == 0)
 241                 msg = MSG_ONE;
 242         else
 243                 msg = MSG_ALL;
 244         msg_entity = e;
 245         WRITESPECTATABLE_MSG_ONE(msg_entity, {
 246                 WriteHeader(msg, TE_CSQC_RACE);
 247                 WriteByte(msg, RACE_NET_SERVER_STATUS);
 248                 WriteShort(msg, id);
 249                 WriteString(msg, e.netname);
 250         });
 251 }
 252
 253 void race_setTime(string map, float t, string myuid, string mynetname, entity e, bool showmessage)
 254 {
 255         // netname only used TEMPORARILY for printing
 256         int newpos = race_readPos(map, t);
 257
 258         int player_prevpos = 0;
 259         for(int i = 1; i <= RANKINGS_CNT; ++i)
 260         {
 261                 if(race_readUID(map, i) == myuid)
 262                         player_prevpos = i;
 263         }
 264
 265         float oldrec;
 266         string oldrec_holder;
 267         if (player_prevpos && (player_prevpos < newpos || !newpos))
 268         {
 269                 oldrec = race_readTime(GetMapname(), player_prevpos);
 270                 race_SendStatus(0, e); // "fail"
 271                 if(showmessage)
 272                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_FAIL_RANKED, mynetname, player_prevpos, t, oldrec);
 273                 return;
 274         }
 275         else if (!newpos)
 276         {
 277                 // no ranking, time worse than the worst ranked
 278                 oldrec = race_readTime(GetMapname(), RANKINGS_CNT);
 279                 race_SendStatus(0, e); // "fail"
 280                 if(showmessage)
 281                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_FAIL_UNRANKED, mynetname, RANKINGS_CNT, t, oldrec);
 282                 return;
 283         }
 284
 285         // if we didn't hit a return yet, we have a new record!
 286
 287         // if the player does not have a UID we can unfortunately not store the record, as the rankings system relies on UIDs
 288         if(myuid == "")
 289         {
 290                 if(showmessage)
 291                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_NEW_MISSING_UID, mynetname, t);
 292                 return;
 293         }
 294
 295         if(uid2name(myuid) == "^1Unregistered Player")
 296         {
 297                 if(showmessage)
 298                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_NEW_MISSING_NAME, mynetname, t);
 299                 return;
 300         }
 301
 302         oldrec = race_readTime(GetMapname(), newpos);
 303         oldrec_holder = race_readName(GetMapname(), newpos);
 304
 305         // store new ranking
 306         race_writeTime(GetMapname(), t, myuid);
 307
 308         if (newpos == 1 && showmessage)
 309         {
 310                 write_recordmarker(e, time - TIME_DECODE(t), TIME_DECODE(t));
 311                 race_send_recordtime(MSG_ALL);
 312         }
 313
 314         race_SendRankings(newpos, player_prevpos, 0, MSG_ALL);
 315         if(rankings_reply)
 316                 strunzone(rankings_reply);
 317         rankings_reply = strzone(getrankings());
 318
 319         if(newpos == player_prevpos)
 320         {
 321                 if(showmessage)
 322                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_NEW_IMPROVED, mynetname, newpos, t, oldrec);
 323                 if(newpos == 1) { race_SendStatus(3, e); } // "new server record"
 324                 else { race_SendStatus(1, e); } // "new time"
 325         }
 326         else if(oldrec == 0)
 327         {
 328                 if(showmessage)
 329                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_NEW_SET, mynetname, newpos, t);
 330                 if(newpos == 1) { race_SendStatus(3, e); } // "new server record"
 331                 else { race_SendStatus(2, e); } // "new rank"
 332         }
 333         else
 334         {
 335                 if(showmessage)
 336                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_NEW_BROKEN, mynetname, oldrec_holder, newpos, t, oldrec);
 337                 if(newpos == 1) { race_SendStatus(3, e); } // "new server record"
 338                 else { race_SendStatus(2, e); } // "new rank"
 339         }
 340 }
 341
 342 void race_deleteTime(string map, float pos)
 343 {
 344         string rr = ((g_cts) ? CTS_RECORD : ((g_ctf) ? CTF_RECORD : RACE_RECORD));
 345
 346         for(int i = pos; i <= RANKINGS_CNT; ++i)
 347         {
 348                 string therank = ftos(i);
 349                 if (i == RANKINGS_CNT)
 350                 {
 351                         db_remove(ServerProgsDB, strcat(map, rr, "time", therank));
 352                         db_remove(ServerProgsDB, strcat(map, rr, "crypto_idfp", therank));
 353                 }
 354                 else
 355                 {
 356                         db_put(ServerProgsDB, strcat(map, rr, "time", therank), ftos(race_readTime(GetMapname(), i+1)));
 357                         db_put(ServerProgsDB, strcat(map, rr, "crypto_idfp", therank), race_readUID(GetMapname(), i+1));
 358                 }
 359         }
 360
 361         race_SendRankings(pos, 0, 1, MSG_ALL);
 362         if(pos == 1)
 363                 race_send_recordtime(MSG_ALL);
 364
 365         if(rankings_reply)
 366                 strunzone(rankings_reply);
 367         rankings_reply = strzone(getrankings());
 368 }
 369
 370 void race_SendTime(entity e, float cp, float t, float tvalid)
 371 {
 372         float snew, l;
 373
 374         if(g_race_qualifying)
 375                 t += e.race_penalty_accumulator;
 376
 377         t = TIME_ENCODE(t); // make integer
 378
 379         if(tvalid)
 380         if(cp == race_timed_checkpoint) // finish line
 381         if (!e.race_completed)
 382         {
 383                 float s;
 384                 if(g_race_qualifying)
 385                 {
 386                         s = PlayerScore_Add(e, SP_RACE_FASTEST, 0);
 387                         if(!s || t < s)
 388                                 PlayerScore_Add(e, SP_RACE_FASTEST, t - s);
 389                 }
 390                 else
 391                 {
 392                         s = PlayerScore_Add(e, SP_RACE_FASTEST, 0);
 393                         if(!s || t < s)
 394                                 PlayerScore_Add(e, SP_RACE_FASTEST, t - s);
 395
 396                         s = PlayerScore_Add(e, SP_RACE_TIME, 0);
 397                         snew = TIME_ENCODE(time - game_starttime);
 398                         PlayerScore_Add(e, SP_RACE_TIME, snew - s);
 399                         l = PlayerTeamScore_Add(e, SP_RACE_LAPS, ST_RACE_LAPS, 1);
 400
 401                         if(autocvar_fraglimit)
 402                                 if(l >= autocvar_fraglimit)
 403                                         race_StartCompleting();
 404
 405                         if(race_completing)
 406                         {
 407                                 e.race_completed = 1;
 408                                 MAKE_INDEPENDENT_PLAYER(e);
 409                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_FINISHED, e.netname);
 410                                 ClientData_Touch(e);
 411                         }
 412                 }
 413         }
 414
 415         if(g_race_qualifying)
 416         {
 417                 float recordtime;
 418                 string recordholder;
 419
 420                 if(tvalid)
 421                 {
 422                         recordtime = race_checkpoint_records[cp];
 423                         float myrecordtime = e.race_checkpoint_record[cp];
 424                         recordholder = strcat1(race_checkpoint_recordholders[cp]); // make a tempstring copy, as we'll possibly strunzone it!
 425                         if(recordholder == e.netname)
 426                                 recordholder = "";
 427
 428                         if(t != 0)
 429                         {
 430                                 if(cp == race_timed_checkpoint)
 431                                 {
 432                                         race_setTime(GetMapname(), t, e.crypto_idfp, e.netname, e, true);
 433                                         MUTATOR_CALLHOOK(Race_FinalCheckpoint, e);
 434                                 }
 435                                 if(t < recordtime || recordtime == 0)
 436                                 {
 437                                         race_checkpoint_records[cp] = t;
 438                                         if(race_checkpoint_recordholders[cp])
 439                                                 strunzone(race_checkpoint_recordholders[cp]);
 440                                         race_checkpoint_recordholders[cp] = strzone(e.netname);
 441                                         if(g_race_qualifying)
 442                                                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && it.race_checkpoint == cp, LAMBDA(race_SendNextCheckpoint(it, 0)));
 443                                 }
 444
 445                                 if(t < myrecordtime || myrecordtime == 0)
 446                                         e.race_checkpoint_record[cp] = t; // resending done below
 447                         }
 448                 }
 449                 else
 450                 {
 451                         // dummies
 452                         t = 0;
 453                         recordtime = 0;
 454                         recordholder = "";
 455                 }
 456
 457                 if(IS_REAL_CLIENT(e))
 458                 {
 459                         msg_entity = e;
 460                         if(g_race_qualifying)
 461                         {
 462                                 WRITESPECTATABLE_MSG_ONE(e, {
 463                                         WriteHeader(MSG_ONE, TE_CSQC_RACE);
 464                                         WriteByte(MSG_ONE, RACE_NET_CHECKPOINT_HIT_QUALIFYING);
 465                                         WriteByte(MSG_ONE, race_CheckpointNetworkID(cp)); // checkpoint the player now is at
 466                                         WriteInt24_t(MSG_ONE, t); // time to that intermediate
 467                                         WriteInt24_t(MSG_ONE, recordtime); // previously best time
 468                                         WriteInt24_t(MSG_ONE, ((tvalid) ? it.race_checkpoint_record[cp] : 0)); // previously best time
 469                                         WriteString(MSG_ONE, recordholder); // record holder
 470                                 });
 471                         }
 472                 }
 473         }
 474         else // RACE! Not Qualifying
 475         {
 476                 float mylaps, lother, othtime;
 477                 entity oth = race_checkpoint_lastplayers[cp];
 478                 if(oth)
 479                 {
 480                         mylaps = PlayerScore_Add(e, SP_RACE_LAPS, 0);
 481                         lother = race_checkpoint_lastlaps[cp];
 482                         othtime = race_checkpoint_lasttimes[cp];
 483                 }
 484                 else
 485                         mylaps = lother = othtime = 0;
 486
 487                 if(IS_REAL_CLIENT(e))
 488                 {
 489                         msg_entity = e;
 490                         WRITESPECTATABLE_MSG_ONE(msg_entity, {
 491                                 WriteHeader(MSG_ONE, TE_CSQC_RACE);
 492                                 WriteByte(MSG_ONE, RACE_NET_CHECKPOINT_HIT_RACE);
 493                                 WriteByte(MSG_ONE, race_CheckpointNetworkID(cp)); // checkpoint the player now is at
 494                                 if(e == oth)
 495                                 {
 496                                         WriteInt24_t(MSG_ONE, 0);
 497                                         WriteByte(MSG_ONE, 0);
 498                                         WriteByte(MSG_ONE, 0);
 499                                 }
 500                                 else
 501                                 {
 502                                         WriteInt24_t(MSG_ONE, TIME_ENCODE(time - race_checkpoint_lasttimes[cp]));
 503                                         WriteByte(MSG_ONE, mylaps - lother);
 504                                         WriteByte(MSG_ONE, etof(oth)); // record holder
 505                                 }
 506                         });
 507                 }
 508
 509                 race_checkpoint_lastplayers[cp] = e;
 510                 race_checkpoint_lasttimes[cp] = time;
 511                 race_checkpoint_lastlaps[cp] = mylaps;
 512
 513                 if(IS_REAL_CLIENT(oth))
 514                 {
 515                         msg_entity = oth;
 516                         WRITESPECTATABLE_MSG_ONE(msg_entity, {
 517                                 WriteHeader(MSG_ONE, TE_CSQC_RACE);
 518                                 WriteByte(MSG_ONE, RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT);
 519                                 WriteByte(MSG_ONE, race_CheckpointNetworkID(cp)); // checkpoint the player now is at
 520                                 if(e == oth)
 521                                 {
 522                                         WriteInt24_t(MSG_ONE, 0);
 523                                         WriteByte(MSG_ONE, 0);
 524                                         WriteByte(MSG_ONE, 0);
 525                                 }
 526                                 else
 527                                 {
 528                                         WriteInt24_t(MSG_ONE, TIME_ENCODE(time - othtime));
 529                                         WriteByte(MSG_ONE, lother - mylaps);
 530                                         WriteByte(MSG_ONE, etof(e) - 1); // record holder
 531                                 }
 532                         });
 533                 }
 534         }
 535 }
 536
 537 void race_ClearTime(entity e)
 538 {
 539         e.race_checkpoint = 0;
 540         e.race_laptime = 0;
 541         e.race_movetime = e.race_movetime_frac = e.race_movetime_count = 0;
 542         e.race_penalty_accumulator = 0;
 543         e.race_lastpenalty = NULL;
 544
 545         if(!IS_REAL_CLIENT(e))
 546                 return;
 547
 548         msg_entity = e;
 549         WRITESPECTATABLE_MSG_ONE(msg_entity, {
 550                 WriteHeader(MSG_ONE, TE_CSQC_RACE);
 551                 WriteByte(MSG_ONE, RACE_NET_CHECKPOINT_CLEAR); // next
 552         });
 553 }
 554
 555 void checkpoint_passed(entity this, entity player)
 556 {
 557         if(player.personal && autocvar_g_allow_checkpoints)
 558                 return; // practice mode!
 559
 560         if(player.classname == "porto")
 561         {
 562                 // do not allow portalling through checkpoints
 563                 trace_plane_normal = normalize(-1 * player.velocity);
 564                 W_Porto_Fail(player, 0);
 565                 return;
 566         }
 567
 568         string oldmsg; // used twice
 569
 570         /*
 571          * Trigger targets
 572          */
 573         if (!((this.spawnflags & 2) && (IS_PLAYER(player))))
 574         {
 575                 oldmsg = this.message;
 576                 this.message = "";
 577                 SUB_UseTargets(this, player, player);
 578                 this.message = oldmsg;
 579         }
 580
 581         if (!IS_PLAYER(player))
 582                 return;
 583
 584         /*
 585          * Remove unauthorized equipment
 586          */
 587         Portal_ClearAll(player);
 588
 589         player.porto_forbidden = 2; // decreased by 1 each StartFrame
 590
 591         if(defrag_ents)
 592         {
 593                 if(this.race_checkpoint == -2)
 594                 {
 595                         this.race_checkpoint = player.race_checkpoint;
 596                 }
 597
 598                 int cp_amount = 0, largest_cp_id = 0;
 599                 IL_EACH(g_race_targets, it.classname == "target_checkpoint",
 600                 {
 601                         cp_amount += 1;
 602                         if(it.race_checkpoint > largest_cp_id) // update the finish id if someone hit a new checkpoint
 603                         {
 604                                 if(!largest_cp_id)
 605                                 {
 606                                         IL_EACH(g_race_targets, it.classname == "target_checkpoint",
 607                                         {
 608                                                 if(it.race_checkpoint == -2) // set defragcpexists to -1 so that the cp id file will be rewritten when someone finishes
 609                                                         defragcpexists = -1;
 610                                         });
 611                                 }
 612
 613                                 largest_cp_id = it.race_checkpoint;
 614                                 IL_EACH(g_race_targets, it.classname == "target_stopTimer",
 615                                 {
 616                                         it.race_checkpoint = largest_cp_id + 1; // finish line
 617                                 });
 618                                 race_highest_checkpoint = largest_cp_id + 1;
 619                                 race_timed_checkpoint = largest_cp_id + 1;
 620                         }
 621                 });
 622
 623                 if(!cp_amount)
 624                 {
 625                         IL_EACH(g_race_targets, it.classname == "target_stopTimer",
 626                         {
 627                                 it.race_checkpoint = 1;
 628                         });
 629                         race_highest_checkpoint = 1;
 630                         race_timed_checkpoint = 1;
 631                 }
 632         }
 633
 634         if((player.race_checkpoint == -1 && this.race_checkpoint == 0) || (player.race_checkpoint == this.race_checkpoint))
 635         {
 636                 if(this.race_penalty)
 637                 {
 638                         if(player.race_lastpenalty != this)
 639                         {
 640                                 player.race_lastpenalty = this;
 641                                 race_ImposePenaltyTime(player, this.race_penalty, this.race_penalty_reason);
 642                         }
 643                 }
 644
 645                 if(player.race_penalty)
 646                         return;
 647
 648                 /*
 649                  * Trigger targets
 650                  */
 651                 if(this.spawnflags & 2)
 652                 {
 653                         oldmsg = this.message;
 654                         this.message = "";
 655                         SUB_UseTargets(this, player, player); // TODO: should we be using other for the trigger here?
 656                         this.message = oldmsg;
 657                 }
 658
 659                 if(player.race_respawn_checkpoint != this.race_checkpoint || !player.race_started)
 660                         player.race_respawn_spotref = this; // this is not a spot but a CP, but spawnpoint selection will deal with that
 661                 player.race_respawn_checkpoint = this.race_checkpoint;
 662                 player.race_checkpoint = race_NextCheckpoint(this.race_checkpoint);
 663                 player.race_started = 1;
 664
 665                 race_SendTime(player, this.race_checkpoint, player.race_movetime, boolean(player.race_laptime));
 666
 667                 if(!this.race_checkpoint) // start line
 668                 {
 669                         player.race_laptime = time;
 670                         player.race_movetime = player.race_movetime_frac = player.race_movetime_count = 0;
 671                         player.race_penalty_accumulator = 0;
 672                         player.race_lastpenalty = NULL;
 673                 }
 674
 675                 if(g_race_qualifying)
 676                         race_SendNextCheckpoint(player, 0);
 677
 678                 if(defrag_ents && defragcpexists < 0 && this.classname == "target_stopTimer")
 679                 {
 680                         float fh;
 681                         defragcpexists = fh = fopen(strcat("maps/", GetMapname(), ".defragcp"), FILE_WRITE);
 682                         if(fh >= 0)
 683                         {
 684                                 IL_EACH(g_race_targets, it.classname == "target_checkpoint",
 685                                 {
 686                                         fputs(fh, strcat(it.targetname, " ", ftos(it.race_checkpoint), "\n"));
 687                                 });
 688                         }
 689                         fclose(fh);
 690                 }
 691         }
 692         else if(player.race_checkpoint == race_NextCheckpoint(this.race_checkpoint))
 693         {
 694                 // ignored
 695         }
 696         else
 697         {
 698                 if(this.spawnflags & 4)
 699                         Damage (player, this, this, 10000, DEATH_HURTTRIGGER.m_id, player.origin, '0 0 0');
 700         }
 701 }
 702
 703 void checkpoint_touch(entity this, entity toucher)
 704 {
 705         EXACTTRIGGER_TOUCH(this, toucher);
 706         checkpoint_passed(this, toucher);
 707 }
 708
 709 void checkpoint_use(entity this, entity actor, entity trigger)
 710 {
 711         if(trigger.classname == "info_player_deathmatch") // a spawn, a spawn
 712                 return;
 713
 714         checkpoint_passed(this, actor);
 715 }
 716
 717 bool race_waypointsprite_visible_for_player(entity this, entity player, entity view)
 718 {
 719         entity own = this.owner;
 720         if(this.realowner)
 721                 own = this.realowner; // target support
 722
 723         if(view.race_checkpoint == -1 || own.race_checkpoint == -2)
 724                 return true;
 725         else if(view.race_checkpoint == own.race_checkpoint)
 726                 return true;
 727         else
 728                 return false;
 729 }
 730
 731 void trigger_race_checkpoint_verify(entity this)
 732 {
 733     static bool have_verified;
 734         if (have_verified) return;
 735         have_verified = true;
 736
 737         bool qual = g_race_qualifying;
 738
 739         int pl_race_checkpoint = 0;
 740         int pl_race_place = 0;
 741
 742         if (g_race) {
 743                 for (int i = 0; i <= race_highest_checkpoint; ++i) {
 744                         pl_race_checkpoint = race_NextCheckpoint(i);
 745
 746                         // race only (middle of the race)
 747                         g_race_qualifying = false;
 748                         pl_race_place = 0;
 749                         if (!Spawn_FilterOutBadSpots(this, findchain(classname, "info_player_deathmatch"), 0, false)) {
 750                                 error(strcat("Checkpoint ", ftos(i), " misses a spawnpoint with race_place==", ftos(pl_race_place), " (used for respawning in race) - bailing out"));
 751             }
 752
 753                         if (i == 0) {
 754                                 // qualifying only
 755                                 g_race_qualifying = 1;
 756                                 pl_race_place = race_lowest_place_spawn;
 757                                 if (!Spawn_FilterOutBadSpots(this, findchain(classname, "info_player_deathmatch"), 0, false)) {
 758                                         error(strcat("Checkpoint ", ftos(i), " misses a spawnpoint with race_place==", ftos(pl_race_place), " (used for qualifying) - bailing out"));
 759                 }
 760
 761                                 // race only (initial spawn)
 762                                 g_race_qualifying = 0;
 763                                 for (int p = 1; p <= race_highest_place_spawn; ++p) {
 764                                         pl_race_place = p;
 765                                         if (!Spawn_FilterOutBadSpots(this, findchain(classname, "info_player_deathmatch"), 0, false)) {
 766                                                 error(strcat("Checkpoint ", ftos(i), " misses a spawnpoint with race_place==", ftos(pl_race_place), " (used for initially spawning in race) - bailing out"));
 767                     }
 768                                 }
 769                         }
 770                 }
 771         } else if (!defrag_ents) {
 772                 // qualifying only
 773                 pl_race_checkpoint = race_NextCheckpoint(0);
 774                 g_race_qualifying = 1;
 775                 pl_race_place = race_lowest_place_spawn;
 776                 if (!Spawn_FilterOutBadSpots(this, findchain(classname, "info_player_deathmatch"), 0, false)) {
 777                         error(strcat("Checkpoint 0 misses a spawnpoint with race_place==", ftos(pl_race_place), " (used for qualifying) - bailing out"));
 778         }
 779         } else {
 780                 pl_race_checkpoint = race_NextCheckpoint(0);
 781                 g_race_qualifying = 1;
 782                 pl_race_place = 0; // there's only one spawn on defrag maps
 783
 784                 // check if a defragcp file already exists, then read it and apply the checkpoint order
 785                 float fh;
 786                 float len;
 787                 string l;
 788
 789                 defragcpexists = fh = fopen(strcat("maps/", GetMapname(), ".defragcp"), FILE_READ);
 790                 if (fh >= 0) {
 791                         while ((l = fgets(fh))) {
 792                                 len = tokenize_console(l);
 793                                 if (len != 2) {
 794                                         defragcpexists = -1; // something's wrong in the defrag cp file, set defragcpexists to -1 so that it will be rewritten when someone finishes
 795                                         continue;
 796                                 }
 797                                 for (entity cp = NULL; (cp = find(cp, classname, "target_checkpoint"));) {
 798                                         if (argv(0) == cp.targetname) {
 799                                                 cp.race_checkpoint = stof(argv(1));
 800                     }
 801                 }
 802                         }
 803                         fclose(fh);
 804                 }
 805         }
 806
 807         g_race_qualifying = qual;
 808
 809         IL_EACH(g_race_targets, true,
 810         {
 811                 entity cpt = it;
 812                 FOREACH_ENTITY_STRING(target, cpt.targetname,
 813                 {
 814                         vector org = (it.absmin + it.absmax) * 0.5;
 815                         if(cpt.race_checkpoint == 0)
 816                                 WaypointSprite_SpawnFixed(WP_RaceStart, org, it, sprite, RADARICON_NONE);
 817                         else
 818                                 WaypointSprite_SpawnFixed(WP_RaceCheckpoint, org, it, sprite, RADARICON_NONE);
 819
 820                         it.sprite.realowner = cpt;
 821                         it.sprite.waypointsprite_visible_for_player = race_waypointsprite_visible_for_player;
 822                 });
 823         });
 824
 825         if (race_timed_checkpoint) {
 826                 if (defrag_ents) {
 827                         IL_EACH(g_race_targets, true,
 828                         {
 829                                 entity cpt = it;
 830                                 if(it.classname == "target_startTimer" || it.classname == "target_stopTimer") {
 831                                         FOREACH_ENTITY_STRING(target, cpt.targetname, {
 832                                                 WaypointSprite_UpdateSprites(it.sprite, ((cpt.classname == "target_startTimer") ? WP_RaceStart : WP_RaceFinish), WP_Null, WP_Null);
 833                                         });
 834                                 }
 835                                 if(it.classname == "target_checkpoint") {
 836                                         if(it.race_checkpoint == -2)
 837                                                 defragcpexists = -1; // something's wrong with the defrag cp file or it has not been written yet, set defragcpexists to -1 so that it will be rewritten when someone finishes
 838                                 }
 839                         });
 840                         if (defragcpexists != -1) {
 841                                 float largest_cp_id = 0;
 842                                 for (entity cp = NULL; (cp = find(cp, classname, "target_checkpoint"));) {
 843                                         if (cp.race_checkpoint > largest_cp_id) {
 844                                                 largest_cp_id = cp.race_checkpoint;
 845                     }
 846                 }
 847                                 for (entity cp = NULL; (cp = find(cp, classname, "target_stopTimer"));) {
 848                                         cp.race_checkpoint = largest_cp_id + 1; // finish line
 849                 }
 850                                 race_highest_checkpoint = largest_cp_id + 1;
 851                                 race_timed_checkpoint = largest_cp_id + 1;
 852                         } else {
 853                                 for (entity cp = NULL; (cp = find(cp, classname, "target_stopTimer"));) {
 854                                         cp.race_checkpoint = 255; // finish line
 855                 }
 856                                 race_highest_checkpoint = 255;
 857                                 race_timed_checkpoint = 255;
 858                         }
 859                 } else {
 860                         IL_EACH(g_racecheckpoints, it.sprite,
 861                         {
 862                                 if (it.race_checkpoint == 0) {
 863                                         WaypointSprite_UpdateSprites(it.sprite, WP_RaceStart, WP_Null, WP_Null);
 864                 } else if (it.race_checkpoint == race_timed_checkpoint) {
 865                                         WaypointSprite_UpdateSprites(it.sprite, WP_RaceFinish, WP_Null, WP_Null);
 866                                 }
 867             });
 868                 }
 869         }
 870
 871         if (defrag_ents) {
 872                 for (entity trigger = NULL; (trigger = find(trigger, classname, "trigger_multiple")); ) {
 873                         for (entity targ = NULL; (targ = find(targ, targetname, trigger.target)); ) {
 874                                 if (targ.classname == "target_checkpoint" || targ.classname == "target_startTimer" || targ.classname == "target_stopTimer") {
 875                                         trigger.wait = 0;
 876                                         trigger.delay = 0;
 877                                         targ.wait = 0;
 878                                         targ.delay = 0;
 879
 880                     // These just make the game crash on some maps with oddly shaped triggers.
 881                     // (on the other hand they used to fix the case when two players ran through a checkpoint at once,
 882                     // and often one of them just passed through without being registered. Hope it's fixed  in a better way now.
 883                     // (happened on item triggers too)
 884                     //
 885                                         //targ.wait = -2;
 886                                         //targ.delay = 0;
 887
 888                                         //setsize(targ, trigger.mins, trigger.maxs);
 889                                         //setorigin(targ, trigger.origin);
 890                                         //remove(trigger);
 891                                 }
 892             }
 893         }
 894         }
 895 }
 896
 897 vector trigger_race_checkpoint_spawn_evalfunc(entity this, entity player, entity spot, vector current)
 898 {
 899         if(g_race_qualifying)
 900         {
 901                 // spawn at first
 902                 if(this.race_checkpoint != 0)
 903                         return '-1 0 0';
 904                 if(spot.race_place != race_lowest_place_spawn)
 905                         return '-1 0 0';
 906         }
 907         else
 908         {
 909                 if(this.race_checkpoint != player.race_respawn_checkpoint)
 910                         return '-1 0 0';
 911                 // try reusing the previous spawn
 912                 if(this == player.race_respawn_spotref || spot == player.race_respawn_spotref)
 913                         current.x += SPAWN_PRIO_RACE_PREVIOUS_SPAWN;
 914                 if(this.race_checkpoint == 0)
 915                 {
 916                         int pl = player.race_place;
 917                         if(pl > race_highest_place_spawn)
 918                                 pl = 0;
 919                         if(pl == 0 && !player.race_started)
 920                                 pl = race_highest_place_spawn; // use last place if he has not even touched finish yet
 921                         if(spot.race_place != pl)
 922                                 return '-1 0 0';
 923                 }
 924         }
 925         return current;
 926 }
 927
 928 spawnfunc(trigger_race_checkpoint)
 929 {
 930         vector o;
 931         if(!g_race && !g_cts) { delete(this); return; }
 932
 933         EXACTTRIGGER_INIT;
 934
 935         this.use = checkpoint_use;
 936         if (!(this.spawnflags & 1))
 937                 settouch(this, checkpoint_touch);
 938
 939         o = (this.absmin + this.absmax) * 0.5;
 940         tracebox(o, PL_MIN_CONST, PL_MAX_CONST, o - '0 0 1' * (o.z - this.absmin.z), MOVE_NORMAL, this);
 941         waypoint_spawnforitem_force(this, trace_endpos);
 942         this.nearestwaypointtimeout = -1;
 943
 944         if(this.message == "")
 945                 this.message = "went backwards";
 946         if (this.message2 == "")
 947                 this.message2 = "was pushed backwards by";
 948         if (this.race_penalty_reason == "")
 949                 this.race_penalty_reason = "missing a checkpoint";
 950
 951         this.race_checkpoint = this.cnt;
 952
 953         if(this.race_checkpoint > race_highest_checkpoint)
 954         {
 955                 race_highest_checkpoint = this.race_checkpoint;
 956                 if(this.spawnflags & 8)
 957                         race_timed_checkpoint = this.race_checkpoint;
 958                 else
 959                         race_timed_checkpoint = 0;
 960         }
 961
 962         if(!this.race_penalty)
 963         {
 964                 if(this.race_checkpoint)
 965                         WaypointSprite_SpawnFixed(WP_RaceCheckpoint, o, this, sprite, RADARICON_NONE);
 966                 else
 967                         WaypointSprite_SpawnFixed(WP_RaceStartFinish, o, this, sprite, RADARICON_NONE);
 968         }
 969
 970         this.sprite.waypointsprite_visible_for_player = race_waypointsprite_visible_for_player;
 971         this.spawn_evalfunc = trigger_race_checkpoint_spawn_evalfunc;
 972
 973         IL_PUSH(g_racecheckpoints, this);
 974
 975         InitializeEntity(this, trigger_race_checkpoint_verify, INITPRIO_FINDTARGET);
 976 }
 977
 978 spawnfunc(target_checkpoint) // defrag entity
 979 {
 980         if(!g_race && !g_cts) { delete(this); return; }
 981         defrag_ents = 1;
 982
 983         // if this is targeted, then it probably isn't a trigger
 984         bool is_trigger = !boolean(!this.nottargeted && this.targetname != "");
 985
 986         if(is_trigger)
 987                 EXACTTRIGGER_INIT;
 988
 989         this.use = checkpoint_use;
 990         if (is_trigger && !(this.spawnflags & 1))
 991                 settouch(this, checkpoint_touch);
 992
 993         vector org = this.origin;
 994
 995         // bots should only pathfind to this if it is a valid touchable trigger
 996         if(is_trigger)
 997         {
 998                 org = (this.absmin + this.absmax) * 0.5;
 999                 tracebox(org, PL_MIN_CONST, PL_MAX_CONST, org - '0 0 1' * (org.z - this.absmin.z), MOVE_NORMAL, this);
1000                 waypoint_spawnforitem_force(this, trace_endpos);
1001                 this.nearestwaypointtimeout = -1;
1002         }
1003
1004         if(this.message == "")
1005                 this.message = "went backwards";
1006         if (this.message2 == "")
1007                 this.message2 = "was pushed backwards by";
1008         if (this.race_penalty_reason == "")
1009                 this.race_penalty_reason = "missing a checkpoint";
1010
1011         if(this.classname == "target_startTimer")
1012                 this.race_checkpoint = 0;
1013         else
1014                 this.race_checkpoint = -2;
1015
1016         race_timed_checkpoint = 1;
1017
1018         IL_PUSH(g_race_targets, this);
1019
1020         InitializeEntity(this, trigger_race_checkpoint_verify, INITPRIO_FINDTARGET);
1021 }
1022
1023 spawnfunc(target_startTimer) { spawnfunc_target_checkpoint(this); }
1024 spawnfunc(target_stopTimer) { spawnfunc_target_checkpoint(this); }
1025
1026 void race_AbandonRaceCheck(entity p)
1027 {
1028         if(race_completing && !p.race_completed)
1029         {
1030                 p.race_completed = 1;
1031                 MAKE_INDEPENDENT_PLAYER(p);
1032                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_RACE_ABANDONED, p.netname);
1033                 ClientData_Touch(p);
1034         }
1035 }
1036
1037 void race_StartCompleting()
1038 {
1039         race_completing = 1;
1040         FOREACH_CLIENT(IS_PLAYER(it) && IS_DEAD(it), LAMBDA(race_AbandonRaceCheck(it)));
1041 }
1042
1043 void race_PreparePlayer(entity this)
1044 {
1045         race_ClearTime(this);
1046         this.race_place = 0;
1047         this.race_started = 0;
1048         this.race_respawn_checkpoint = 0;
1049         this.race_respawn_spotref = NULL;
1050 }
1051
1052 void race_RetractPlayer(entity this)
1053 {
1054         if(!g_race && !g_cts)
1055                 return;
1056         if(this.race_respawn_checkpoint == 0 || this.race_respawn_checkpoint == race_timed_checkpoint)
1057                 race_ClearTime(this);
1058         this.race_checkpoint = this.race_respawn_checkpoint;
1059 }
1060
1061 spawnfunc(info_player_race)
1062 {
1063         if(!g_race && !g_cts) { delete(this); return; }
1064         ++race_spawns;
1065         spawnfunc_info_player_deathmatch(this);
1066
1067         if(this.race_place > race_highest_place_spawn)
1068                 race_highest_place_spawn = this.race_place;
1069         if(this.race_place < race_lowest_place_spawn)
1070                 race_lowest_place_spawn = this.race_place;
1071 }
1072
1073 void race_ClearRecords()
1074 {
1075         float i;
1076
1077         for(i = 0; i < MAX_CHECKPOINTS; ++i)
1078         {
1079                 race_checkpoint_records[i] = 0;
1080                 if(race_checkpoint_recordholders[i])
1081                         strunzone(race_checkpoint_recordholders[i]);
1082                 race_checkpoint_recordholders[i] = string_null;
1083         }
1084
1085         FOREACH_CLIENT(true, LAMBDA(
1086                 float p = it.race_place;
1087                 race_PreparePlayer(it);
1088                 it.race_place = p;
1089         ));
1090 }
1091
1092 void race_ImposePenaltyTime(entity pl, float penalty, string reason)
1093 {
1094         if(g_race_qualifying)
1095         {
1096                 pl.race_penalty_accumulator += penalty;
1097                 if(IS_REAL_CLIENT(pl))
1098                 {
1099                         msg_entity = pl;
1100                         WRITESPECTATABLE_MSG_ONE(msg_entity, {
1101                                 WriteHeader(MSG_ONE, TE_CSQC_RACE);
1102                                 WriteByte(MSG_ONE, RACE_NET_PENALTY_QUALIFYING);
1103                                 WriteShort(MSG_ONE, TIME_ENCODE(penalty));
1104                                 WriteString(MSG_ONE, reason);
1105                         });
1106                 }
1107         }
1108         else
1109         {
1110                 pl.race_penalty = time + penalty;
1111                 if(IS_REAL_CLIENT(pl))
1112                 {
1113                         msg_entity = pl;
1114                         WRITESPECTATABLE_MSG_ONE(msg_entity, {
1115                                 WriteHeader(MSG_ONE, TE_CSQC_RACE);
1116                                 WriteByte(MSG_ONE, RACE_NET_PENALTY_RACE);
1117                                 WriteShort(MSG_ONE, TIME_ENCODE(penalty));
1118                                 WriteString(MSG_ONE, reason);
1119                         });
1120                 }
1121         }
1122 }
1123
1124 void penalty_touch(entity this, entity toucher)
1125 {
1126         EXACTTRIGGER_TOUCH(this, toucher);
1127         if(toucher.race_lastpenalty != this)
1128         {
1129                 toucher.race_lastpenalty = this;
1130                 race_ImposePenaltyTime(toucher, this.race_penalty, this.race_penalty_reason);
1131         }
1132 }
1133
1134 void penalty_use(entity this, entity actor, entity trigger)
1135 {
1136         race_ImposePenaltyTime(actor, this.race_penalty, this.race_penalty_reason);
1137 }
1138
1139 spawnfunc(trigger_race_penalty)
1140 {
1141         // TODO: find out why this wasnt done:
1142         //if(!g_cts && !g_race) { remove(this); return; }
1143
1144         EXACTTRIGGER_INIT;
1145
1146         this.use = penalty_use;
1147         if (!(this.spawnflags & 1))
1148                 settouch(this, penalty_touch);
1149
1150         if (this.race_penalty_reason == "")
1151                 this.race_penalty_reason = "missing a checkpoint";
1152         if (!this.race_penalty)
1153                 this.race_penalty = 5;
1154 }
1155
1156 float race_GetFractionalLapCount(entity e)
1157 {
1158         // interesting metrics (idea by KrimZon) to maybe sort players in the
1159         // scoreboard, immediately updates when overtaking
1160         //
1161         // requires the track to be built so you never get farther away from the
1162         // next checkpoint, though, and current Xonotic race maps are not built that
1163         // way
1164         //
1165         // also, this code is slow and would need optimization (i.e. "next CP"
1166         // links on CP entities)
1167
1168         float l;
1169         l = PlayerScore_Add(e, SP_RACE_LAPS, 0);
1170         if(e.race_completed)
1171                 return l; // not fractional
1172
1173         vector o0, o1;
1174         float bestfraction, fraction;
1175         entity lastcp;
1176         float nextcpindex, lastcpindex;
1177
1178         nextcpindex = max(e.race_checkpoint, 0);
1179         lastcpindex = e.race_respawn_checkpoint;
1180         lastcp = e.race_respawn_spotref;
1181
1182         if(nextcpindex == lastcpindex)
1183                 return l; // finish
1184
1185         bestfraction = 1;
1186         IL_EACH(g_racecheckpoints, true,
1187         {
1188                 if(it.race_checkpoint != lastcpindex)
1189                         continue;
1190                 if(lastcp)
1191                         if(it != lastcp)
1192                                 continue;
1193                 o0 = (it.absmin + it.absmax) * 0.5;
1194                 IL_EACH(g_racecheckpoints, true,
1195                 {
1196                         if(it.race_checkpoint != nextcpindex)
1197                                 continue;
1198                         o1 = (it.absmin + it.absmax) * 0.5;
1199                         if(o0 == o1)
1200                                 continue;
1201                         fraction = bound(0.0001, vlen(e.origin - o1) / vlen(o0 - o1), 1);
1202                         if(fraction < bestfraction)
1203                                 bestfraction = fraction;
1204                 });
1205         });
1206
1207         // we are at CP "nextcpindex - bestfraction"
1208         // race_timed_checkpoint == 4: then nextcp==4 means 0.9999x, nextcp==0 means 0.0000x
1209         // race_timed_checkpoint == 0: then nextcp==0 means 0.9999x
1210         float c, nc;
1211         nc = race_highest_checkpoint + 1;
1212         c = ((nextcpindex - race_timed_checkpoint + nc + nc - 1) % nc) + 1 - bestfraction;
1213
1214         return l + c / nc;
1215 }