qcsrc/server/resources.qc

   1 #include "resources.qh"
   2
   3 /// \file
   4 /// \brief Source file that contains implementation of the resource system.
   5 /// \author Lyberta
   6 /// \copyright GNU GPLv2 or any later version.
   7
   8 #include "autocvars.qh"
   9 #include "miscfunctions.qh"
  10
  11 float GetResourceLimit(entity e, int resource_type)
  12 {
  13         float limit;
  14         switch (resource_type)
  15         {
  16                 case RESOURCE_HEALTH:
  17                 {
  18                         limit = autocvar_g_balance_health_limit;
  19                         break;
  20                 }
  21                 case RESOURCE_ARMOR:
  22                 {
  23                         limit = autocvar_g_balance_armor_limit;
  24                         break;
  25                 }
  26                 case RESOURCE_SHELLS:
  27                 {
  28                         limit = g_pickup_shells_max;
  29                         break;
  30                 }
  31                 case RESOURCE_BULLETS:
  32                 {
  33                         limit = g_pickup_nails_max;
  34                         break;
  35                 }
  36                 case RESOURCE_ROCKETS:
  37                 {
  38                         limit = g_pickup_rockets_max;
  39                         break;
  40                 }
  41                 case RESOURCE_CELLS:
  42                 {
  43                         limit = g_pickup_cells_max;
  44                         break;
  45                 }
  46                 case RESOURCE_PLASMA:
  47                 {
  48                         limit = g_pickup_plasma_max;
  49                         break;
  50                 }
  51                 case RESOURCE_FUEL:
  52                 {
  53                         limit = autocvar_g_balance_fuel_limit;
  54                         break;
  55                 }
  56                 default:
  57                 {
  58                         error("GetResourceLimit: Invalid resource type.");
  59                         return 0;
  60                 }
  61         }
  62         MUTATOR_CALLHOOK(GetResourceLimit, e, resource_type, limit);
  63         limit = M_ARGV(2, float);
  64         if (limit > RESOURCE_AMOUNT_HARD_LIMIT)
  65         {
  66                 limit = RESOURCE_AMOUNT_HARD_LIMIT;
  67         }
  68         return limit;
  69 }
  70
  71 float GetResourceAmount(entity e, int resource_type)
  72 {
  73         .float resource_field = GetResourceField(resource_type);
  74         return e.(resource_field);
  75 }
  76
  77 void SetResourceAmount(entity e, int resource_type, float amount)
  78 {
  79         bool forbid = MUTATOR_CALLHOOK(SetResourceAmount, e, resource_type, amount);
  80         if (forbid)
  81         {
  82                 return;
  83         }
  84         resource_type = M_ARGV(1, int);
  85         amount = M_ARGV(2, float);
  86         float max_amount = GetResourceLimit(e, resource_type);
  87         float amount_wasted = 0;
  88         if (amount > max_amount)
  89         {
  90                 amount_wasted = amount - max_amount;
  91                 amount = max_amount;
  92         }
  93         .float resource_field = GetResourceField(resource_type);
  94         if (e.(resource_field) == amount)
  95         {
  96                 return;
  97         }
  98         e.(resource_field) = amount;
  99         MUTATOR_CALLHOOK(ResourceAmountChanged, e, resource_type, amount,
 100                 amount_wasted);
 101 }
 102
 103 void GiveResource(entity receiver, int resource_type, float amount)
 104 {
 105         if (amount == 0)
 106         {
 107                 return;
 108         }
 109         bool forbid = MUTATOR_CALLHOOK(GiveResource, receiver, resource_type,
 110                 amount);
 111         if (forbid)
 112         {
 113                 return;
 114         }
 115         resource_type = M_ARGV(1, int);
 116         amount = M_ARGV(2, float);
 117         if (amount <= 0)
 118         {
 119                 return;
 120         }
 121         SetResourceAmount(receiver, resource_type,
 122                 GetResourceAmount(receiver, resource_type) + amount);
 123         switch (resource_type)
 124         {
 125                 case RESOURCE_HEALTH:
 126                 {
 127                         receiver.pauserothealth_finished =
 128                                 max(receiver.pauserothealth_finished, time +
 129                                 autocvar_g_balance_pause_health_rot);
 130                         return;
 131                 }
 132                 case RESOURCE_ARMOR:
 133                 {
 134                         receiver.pauserotarmor_finished =
 135                                 max(receiver.pauserotarmor_finished, time +
 136                                 autocvar_g_balance_pause_armor_rot);
 137                         return;
 138                 }
 139                 case RESOURCE_FUEL:
 140                 {
 141                         receiver.pauserotfuel_finished = max(receiver.pauserotfuel_finished,
 142                                 time + autocvar_g_balance_pause_fuel_rot);
 143                         return;
 144                 }
 145         }
 146 }
 147
 148 void GiveResourceWithLimit(entity receiver, int resource_type, float amount,
 149         float limit)
 150 {
 151         if (amount == 0)
 152         {
 153                 return;
 154         }
 155         bool forbid = MUTATOR_CALLHOOK(GiveResourceWithLimit, receiver,
 156                 resource_type, amount, limit);
 157         if (forbid)
 158         {
 159                 return;
 160         }
 161         resource_type = M_ARGV(1, int);
 162         amount = M_ARGV(2, float);
 163         limit = M_ARGV(3, float);
 164         if (amount == 0)
 165         {
 166                 return;
 167         }
 168         float current_amount = GetResourceAmount(receiver, resource_type);
 169         if (current_amount + amount > limit)
 170         {
 171                 amount = limit - current_amount;
 172         }
 173         GiveResource(receiver, resource_type, amount);
 174 }
 175
 176 int GetResourceType(.float resource_field)
 177 {
 178         switch (resource_field)
 179         {
 180                 case health: { return RESOURCE_HEALTH; }
 181                 case armorvalue: { return RESOURCE_ARMOR; }
 182                 case ammo_shells: { return RESOURCE_SHELLS; }
 183                 case ammo_nails: { return RESOURCE_BULLETS; }
 184                 case ammo_rockets: { return RESOURCE_ROCKETS; }
 185                 case ammo_cells: { return RESOURCE_CELLS; }
 186                 case ammo_plasma: { return RESOURCE_PLASMA; }
 187                 case ammo_fuel: { return RESOURCE_FUEL; }
 188         }
 189         error("GetResourceType: Invalid field.");
 190         return 0;
 191 }
 192
 193 .float GetResourceField(int resource_type)
 194 {
 195         switch (resource_type)
 196         {
 197                 case RESOURCE_HEALTH: { return health; }
 198                 case RESOURCE_ARMOR: { return armorvalue; }
 199                 case RESOURCE_SHELLS: { return ammo_shells; }
 200                 case RESOURCE_BULLETS: { return ammo_nails; }
 201                 case RESOURCE_ROCKETS: { return ammo_rockets; }
 202                 case RESOURCE_CELLS: { return ammo_cells; }
 203                 case RESOURCE_PLASMA: { return ammo_plasma; }
 204                 case RESOURCE_FUEL: { return ammo_fuel; }
 205         }
 206         error("GetResourceField: Invalid resource type.");
 207         return health;
 208 }