qcsrc/server/scores.qc

   1 #include "scores.qh"
   2
   3 #include <common/mapinfo.qh>
   4 #include <common/mutators/base.qh>
   5 #include <common/net_linked.qh>
   6 #include <common/playerstats.qh>
   7 #include <common/scores.qh>
   8 #include <common/state.qh>
   9 #include <common/stats.qh>
  10 #include <common/teams.qh>
  11 #include <common/weapons/_all.qh>
  12 #include <server/client.qh>
  13 #include <server/command/common.qh>
  14 #include <server/intermission.qh>
  15 #include <server/mutators/_mod.qh>
  16 #include <server/round_handler.qh>
  17 #include <server/world.qh>
  18
  19 .entity scorekeeper;
  20 entity teamscorekeepers[16];
  21 float teamscores_entities_count;
  22 var .float scores_primary;
  23 var .float teamscores_primary;
  24 float scores_flags_primary;
  25 float teamscores_flags_primary;
  26 var .float scores_secondary;
  27 float scores_flags_secondary;
  28
  29 // returns cmp value
  30 int ScoreField_Compare(entity t1, entity t2, .float field, float fieldflags, int previous)
  31 {
  32         if(fieldflags & SFL_NOT_SORTABLE) // column does not sort
  33                 return previous;
  34         if (t1.(field) == t2.(field))
  35                 return previous;
  36
  37         if(fieldflags & SFL_ZERO_IS_WORST)
  38         {
  39                 if (t1.(field) == 0)
  40                 {
  41                         previous = -1;
  42                         return previous;
  43                 }
  44                 else if (t2.(field) == 0)
  45                 {
  46                         previous = +1;
  47                         return previous;
  48                 }
  49         }
  50
  51         if (fieldflags & SFL_LOWER_IS_BETTER)
  52                 previous = (t2.(field) - t1.(field));
  53         else
  54                 previous = (t1.(field) - t2.(field));
  55
  56         return previous;
  57 }
  58
  59 /*
  60  * teamscore entities
  61  */
  62
  63 bool TeamScore_SendEntity(entity this, entity to, float sendflags)
  64 {
  65         float i, longflags;
  66
  67         WriteHeader(MSG_ENTITY, ENT_CLIENT_TEAMSCORES);
  68         int t = this.team - 1;
  69         assert(t, eprint(this));
  70         WriteByte(MSG_ENTITY, t);
  71
  72         longflags = 0;
  73         for(i = 0; i < MAX_TEAMSCORE; ++i)
  74                 if(this.(teamscores(i)) > 127 || this.(teamscores(i)) <= -128)
  75                         longflags |= BIT(i);
  76
  77 #if MAX_TEAMSCORE <= 8
  78         WriteByte(MSG_ENTITY, sendflags);
  79         WriteByte(MSG_ENTITY, longflags);
  80 #else
  81         WriteShort(MSG_ENTITY, sendflags);
  82         WriteShort(MSG_ENTITY, longflags);
  83 #endif
  84         for(i = 0; i < MAX_TEAMSCORE; ++i)
  85                 if(sendflags & BIT(i))
  86                 {
  87                         if(longflags & BIT(i))
  88                                 WriteInt24_t(MSG_ENTITY, this.(teamscores(i)));
  89                         else
  90                                 WriteChar(MSG_ENTITY, this.(teamscores(i)));
  91                 }
  92
  93         return true;
  94 }
  95
  96 void TeamScore_Spawn(float t, string name)
  97 {
  98         entity ts = new_pure(csqc_score_team);
  99         ts.netname = name; // not used yet, FIXME
 100         ts.team = t;
 101         Net_LinkEntity(ts, false, 0, TeamScore_SendEntity);
 102         teamscorekeepers[t - 1] = ts;
 103         ++teamscores_entities_count;
 104         PlayerStats_GameReport_AddTeam(t);
 105 }
 106
 107 float TeamScore_AddToTeam(int t, float scorefield, float score)
 108 {
 109         entity s;
 110
 111         if(game_stopped)
 112         {
 113                 score = 0;
 114         }
 115
 116         if(!scores_initialized) return 0; // FIXME remove this when everything uses this system
 117         if(t <= 0 || t >= 16)
 118         {
 119                 if(game_stopped)
 120                         return 0;
 121                 error("Adding score to invalid team!");
 122         }
 123         s = teamscorekeepers[t - 1];
 124         if(!s)
 125         {
 126                 if(game_stopped)
 127                         return 0;
 128                 error("Adding score to unknown team!");
 129         }
 130         if(score)
 131                 if(teamscores_label(scorefield) != "")
 132                         s.SendFlags |= BIT(scorefield);
 133         return (s.(teamscores(scorefield)) += score);
 134 }
 135
 136 float TeamScore_Add(entity player, float scorefield, float score)
 137 {
 138         return TeamScore_AddToTeam(player.team, scorefield, score);
 139 }
 140
 141 // strict: compare others fields too besides primary and secondary
 142 int TeamScore_Compare(entity t1, entity t2, bool strict)
 143 {
 144         if(!t1 || !t2) return (!t2) - !t1;
 145
 146         // supporting MAX_TEAMSCORE > 2 requires keeping track of primary and secondary teamscore
 147         if (MAX_TEAMSCORE > 2)
 148                 error("MAX_TEAMSCORE > 2 not supported");
 149
 150         // first compare primary, then others (don't check secondary flag since there are only 2 teamscores)
 151         int result = 0;
 152         int i = boolean(teamscores_primary && teamscores_primary == teamscores(1));
 153         result = ScoreField_Compare(t1, t2, teamscores(i), teamscores_flags(i), result);
 154         if (result == 0 && strict)
 155         {
 156                 i = (i + 1) % MAX_TEAMSCORE;
 157                 result = ScoreField_Compare(t1, t2, teamscores(i), teamscores_flags(i), result);
 158                 if (result == 0)
 159                         result = t1.team - t2.team;
 160         }
 161
 162         return result;
 163 }
 164
 165 /*
 166  * the scoreinfo entity
 167  */
 168
 169 void ScoreInfo_SetLabel_PlayerScore(PlayerScoreField i, string label, float scoreflags)
 170 {
 171         scores_label(i) = label;
 172         scores_flags(i) = scoreflags;
 173         if((scoreflags & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 174         {
 175                 scores_primary = scores(i);
 176                 scores_flags_primary = scoreflags;
 177         }
 178         else if((scoreflags & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_SECONDARY)
 179         {
 180                 scores_secondary = scores(i);
 181                 scores_flags_secondary = scoreflags;
 182         }
 183         if(label != "")
 184         {
 185                 PlayerStats_GameReport_AddEvent(strcat(PLAYERSTATS_TOTAL, label));
 186                 PlayerStats_GameReport_AddEvent(strcat(PLAYERSTATS_SCOREBOARD, label));
 187         }
 188 }
 189
 190 void ScoreInfo_SetLabel_TeamScore(float i, string label, float scoreflags)
 191 {
 192         teamscores_label(i) = label;
 193         teamscores_flags(i) = scoreflags;
 194         if((scoreflags & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 195         {
 196                 teamscores_primary = teamscores(i);
 197                 teamscores_flags_primary = scoreflags;
 198         }
 199         if(label != "")
 200         {
 201                 PlayerStats_GameReport_AddEvent(strcat(PLAYERSTATS_TOTAL, label));
 202                 PlayerStats_GameReport_AddEvent(strcat(PLAYERSTATS_SCOREBOARD, label));
 203         }
 204 }
 205
 206 bool ScoreInfo_SendEntity(entity this, entity to, int sf)
 207 {
 208         float i;
 209         WriteHeader(MSG_ENTITY, ENT_CLIENT_SCORES_INFO);
 210         WriteRegistered(Gametypes, MSG_ENTITY, MapInfo_LoadedGametype);
 211         FOREACH(Scores, true, {
 212                 WriteString(MSG_ENTITY, scores_label(it));
 213                 WriteByte(MSG_ENTITY, scores_flags(it));
 214         });
 215         for(i = 0; i < MAX_TEAMSCORE; ++i)
 216         {
 217                 WriteString(MSG_ENTITY, teamscores_label(i));
 218                 WriteByte(MSG_ENTITY, teamscores_flags(i));
 219         }
 220         // prevent sending the welcome message again when score types are sent again because the scoring system has changed
 221         // it can happen in some game modes like Race when the qualyfing session ends and the race starts
 222         bool welcome_msg_too = (!CS(to) || time < CS(to).jointime + 5);
 223         WriteByte(MSG_ENTITY, welcome_msg_too);
 224         // welcome message is sent here because it needs to know the gametype
 225         if (welcome_msg_too)
 226                 SendWelcomeMessage(to, MSG_ENTITY);
 227         return true;
 228 }
 229
 230 void ScoreInfo_Init(int teams)
 231 {
 232         if(scores_initialized)
 233         {
 234                 scores_initialized.SendFlags |= 1; // force a resend
 235         }
 236         else
 237         {
 238                 scores_initialized = new_pure(ent_client_scoreinfo);
 239                 Net_LinkEntity(scores_initialized, false, 0, ScoreInfo_SendEntity);
 240         }
 241         if(teams & BIT(0))
 242                 TeamScore_Spawn(NUM_TEAM_1, "Red");
 243         if(teams & BIT(1))
 244                 TeamScore_Spawn(NUM_TEAM_2, "Blue");
 245         if(teams & BIT(2))
 246                 TeamScore_Spawn(NUM_TEAM_3, "Yellow");
 247         if(teams & BIT(3))
 248                 TeamScore_Spawn(NUM_TEAM_4, "Pink");
 249 }
 250
 251 /*
 252  * per-player score entities
 253  */
 254
 255 bool PlayerScore_SendEntity(entity this, entity to, float sendflags)
 256 {
 257         WriteHeader(MSG_ENTITY, ENT_CLIENT_SCORES);
 258         WriteByte(MSG_ENTITY, etof(this.owner));
 259
 260         int longflags = 0;
 261         FOREACH(Scores, true, {
 262             int p = 1 << (i % 16);
 263                 if (this.(scores(it)) > 127 || this.(scores(it)) <= -128)
 264                         longflags |= p;
 265     });
 266
 267         WriteShort(MSG_ENTITY, sendflags);
 268         WriteShort(MSG_ENTITY, longflags);
 269         FOREACH(Scores, true, {
 270             int p = 1 << (i % 16);
 271                 if (sendflags & p)
 272                 {
 273                         if(longflags & p)
 274                                 WriteInt24_t(MSG_ENTITY, this.(scores(it)));
 275                         else
 276                                 WriteChar(MSG_ENTITY, this.(scores(it)));
 277                 }
 278     });
 279
 280         return true;
 281 }
 282
 283 float PlayerScore_Clear(entity player)
 284 {
 285         entity sk;
 286
 287         if(teamscores_entities_count)
 288                 return 0;
 289
 290         if(MUTATOR_CALLHOOK(ForbidPlayerScore_Clear)) return 0;
 291
 292         sk = CS(player).scorekeeper;
 293         FOREACH(Scores, true, {
 294                 if(sk.(scores(it)) != 0)
 295                         if(scores_label(it) != "")
 296                                 sk.SendFlags |= BIT(i % 16);
 297                 if(i != SP_ELO.m_id)
 298                         sk.(scores(it)) = 0;
 299         });
 300
 301         return 1;
 302 }
 303
 304 void Score_ClearAll()
 305 {
 306         entity sk;
 307         float t;
 308         FOREACH_CLIENTSLOT(true, {
 309                 sk = CS(it).scorekeeper;
 310                 if (!sk) continue;
 311                 FOREACH(Scores, true, {
 312                         if(sk.(scores(it)) != 0)
 313                                 if(scores_label(it) != "")
 314                                         sk.SendFlags |= BIT(i % 16);
 315                         if(i != SP_ELO.m_id)
 316                                 sk.(scores(it)) = 0;
 317                 });
 318         });
 319         for(t = 0; t < 16; ++t)
 320         {
 321                 sk = teamscorekeepers[t];
 322                 if(!sk)
 323                         continue;
 324                 for(int j = 0; j < MAX_TEAMSCORE; ++j)
 325                 {
 326                         if(sk.(teamscores(j)) != 0)
 327                                 if(teamscores_label(j) != "")
 328                                         sk.SendFlags |= BIT(j);
 329                         sk.(teamscores(j)) = 0;
 330                 }
 331         }
 332 }
 333
 334 void PlayerScore_Attach(entity player)
 335 {
 336         if(CS(player).scorekeeper)
 337                 error("player already has a scorekeeper");
 338         entity sk = new_pure(scorekeeper);
 339         sk.owner = player;
 340         Net_LinkEntity(sk, false, 0, PlayerScore_SendEntity);
 341         CS(player).scorekeeper = sk;
 342 }
 343
 344 void PlayerScore_Detach(entity player)
 345 {
 346         if(!CS(player).scorekeeper)
 347                 error("player has no scorekeeper");
 348         delete(CS(player).scorekeeper);
 349         CS(player).scorekeeper = NULL;
 350 }
 351
 352 float PlayerScore_Add(entity player, PlayerScoreField scorefield, float score)
 353 {
 354         bool mutator_returnvalue = MUTATOR_CALLHOOK(AddPlayerScore, scorefield, score, player);
 355         score = M_ARGV(1, float);
 356
 357         if(!mutator_returnvalue && game_stopped)
 358         {
 359                 score = 0;
 360         }
 361
 362         if(!scores_initialized) return 0; // FIXME remove this when everything uses this system
 363         entity s = CS(player).scorekeeper;
 364         if(!s)
 365         {
 366                 if(game_stopped)
 367                         return 0;
 368                 LOG_WARN("Adding score to unknown player!");
 369                 return 0;
 370         }
 371         if(!score)
 372         {
 373                 return s.(scores(scorefield));
 374         }
 375         if(scores_label(scorefield) != "")
 376                 s.SendFlags |= BIT(scorefield.m_id % 16);
 377         if(!warmup_stage)
 378                 PlayerStats_GameReport_Event_Player(s.owner, strcat(PLAYERSTATS_TOTAL, scores_label(scorefield)), score);
 379         s.(scores(scorefield)) += score;
 380         MUTATOR_CALLHOOK(AddedPlayerScore, scorefield, score, player);
 381         return s.(scores(scorefield));
 382 }
 383
 384 float PlayerScore_Set(entity player, PlayerScoreField scorefield, float score)
 385 {
 386         if(!scores_initialized) return 0; // FIXME remove this when everything uses this system
 387         entity s = CS(player).scorekeeper;
 388         if(!s)
 389         {
 390                 if(game_stopped)
 391                         return 0;
 392                 LOG_WARN("Setting score of unknown player!");
 393                 return 0;
 394         }
 395
 396         float oldscore = s.(scores(scorefield));
 397         if(oldscore == score)
 398                 return oldscore;
 399
 400         if(scores_label(scorefield) != "")
 401                 s.SendFlags |= BIT(scorefield.m_id % 16);
 402         s.(scores(scorefield)) = score;
 403         return s.(scores(scorefield));
 404 }
 405
 406 float PlayerTeamScore_Add(entity player, PlayerScoreField pscorefield, float tscorefield, float score)
 407 {
 408         float r;
 409         r = PlayerScore_Add(player, pscorefield, score);
 410         if(teamscores_entities_count) // only for teamplay
 411                 r = TeamScore_Add(player, tscorefield, score);
 412         return r;
 413 }
 414
 415 // strict: compare others fields too besides primary and secondary
 416 float PlayerScore_Compare(entity t1, entity t2, bool strict)
 417 {
 418         if(!t1 || !t2) return (!t2) - !t1;
 419
 420         int result = 0;
 421         result = ScoreField_Compare(t1, t2, scores_primary, scores_flags_primary, result);
 422         // NOTE: if (scores_secondary) doesn't work because it's a field pointer
 423         if (result == 0 && scores_flags_secondary)
 424                 result = ScoreField_Compare(t1, t2, scores_secondary, scores_flags_secondary, result);
 425
 426         if (result == 0 && strict)
 427         {
 428                 FOREACH(Scores, true, {
 429                         if (scores_flags(it) & SFL_SORT_PRIO_MASK)
 430                                 continue;
 431                         if (scores_label(it) == "")
 432                                 continue;
 433                         var .float f = scores(it);
 434                         result = ScoreField_Compare(t1, t2, f, scores_flags(it), result);
 435                         if (result) break;
 436                 });
 437                 if (result == 0)
 438                         result = t1.owner.playerid - t2.owner.playerid;
 439         }
 440
 441         return result;
 442 }
 443
 444 void WinningConditionHelper(entity this)
 445 {
 446         float c;
 447         string s;
 448         float fullstatus;
 449         entity winnerscorekeeper;
 450         entity secondscorekeeper;
 451         entity sk;
 452
 453         // format:
 454         // gametype:P<pure>:S<slots>::plabel,plabel:tlabel,tlabel:teamid:tscore,tscore:teamid:tscore,tscore
 455         // score labels always start with a symbol or with lower case
 456         // so to match pure, match for :P0:
 457         // to match full, match for :S0:
 458
 459         fullstatus = autocvar_g_full_getstatus_responses;
 460
 461         s = GetGametype();
 462         s = strcat(s, ":", autocvar_g_xonoticversion);
 463         s = strcat(s, ":P", ftos(cvar_purechanges_count));
 464         s = strcat(s, ":S", ftos(nJoinAllowed(this, NULL)));
 465         s = strcat(s, ":F", ftos(serverflags));
 466         s = strcat(s, ":T", sv_termsofservice_url_escaped);
 467         s = strcat(s, ":M", modname);
 468         s = strcat(s, "::", GetPlayerScoreString(NULL, (fullstatus ? 1 : 2)));
 469
 470         if(teamscores_entities_count)
 471         {
 472                 float t;
 473
 474                 s = strcat(s, ":", GetTeamScoreString(0, 1));
 475                 for(t = 0; t < 16; ++t)
 476                         if(teamscorekeepers[t])
 477                                 s = strcat(s, ":", ftos(t+1), ":", GetTeamScoreString(t+1, 1));
 478
 479                 WinningConditionHelper_winnerteam = -1;
 480                 WinningConditionHelper_secondteam = -1;
 481                 winnerscorekeeper = NULL;
 482                 secondscorekeeper = NULL;
 483                 for(t = 0; t < 16; ++t)
 484                 {
 485                         sk = teamscorekeepers[t];
 486                         c = TeamScore_Compare(winnerscorekeeper, sk, true);
 487                         if(c < 0)
 488                         {
 489                                 WinningConditionHelper_secondteam = WinningConditionHelper_winnerteam;
 490                                 WinningConditionHelper_winnerteam = t + 1;
 491                                 secondscorekeeper = winnerscorekeeper;
 492                                 winnerscorekeeper = sk;
 493                         }
 494                         else
 495                         {
 496                                 c = TeamScore_Compare(secondscorekeeper, sk, true);
 497                                 if(c < 0)
 498                                 {
 499                                         WinningConditionHelper_secondteam = t + 1;
 500                                         secondscorekeeper = sk;
 501                                 }
 502                         }
 503                 }
 504
 505                 WinningConditionHelper_equality = (TeamScore_Compare(winnerscorekeeper, secondscorekeeper, false) == 0);
 506                 if(WinningConditionHelper_equality)
 507                         WinningConditionHelper_winnerteam = WinningConditionHelper_secondteam = -1;
 508
 509                 WinningConditionHelper_topscore = winnerscorekeeper.teamscores_primary;
 510                 WinningConditionHelper_secondscore = secondscorekeeper.teamscores_primary;
 511                 WinningConditionHelper_lowerisbetter = (teamscores_flags_primary & SFL_LOWER_IS_BETTER);
 512                 WinningConditionHelper_zeroisworst = (teamscores_flags_primary & SFL_ZERO_IS_WORST);
 513
 514                 WinningConditionHelper_winner = NULL; // not supported in teamplay
 515                 WinningConditionHelper_second = NULL; // not supported in teamplay
 516         }
 517         else
 518         {
 519                 WinningConditionHelper_winner = NULL;
 520                 WinningConditionHelper_second = NULL;
 521                 winnerscorekeeper = NULL;
 522                 secondscorekeeper = NULL;
 523                 FOREACH_CLIENT(IS_PLAYER(it), {
 524                         sk = CS(it).scorekeeper;
 525                         c = PlayerScore_Compare(winnerscorekeeper, sk, true);
 526                         if(c < 0)
 527                         {
 528                                 WinningConditionHelper_second = WinningConditionHelper_winner;
 529                                 WinningConditionHelper_winner = it;
 530                                 secondscorekeeper = winnerscorekeeper;
 531                                 winnerscorekeeper = sk;
 532                         }
 533                         else
 534                         {
 535                                 c = PlayerScore_Compare(secondscorekeeper, sk, true);
 536                                 if(c < 0)
 537                                 {
 538                                         WinningConditionHelper_second = it;
 539                                         secondscorekeeper = sk;
 540                                 }
 541                         }
 542                 });
 543
 544                 WinningConditionHelper_equality = (PlayerScore_Compare(winnerscorekeeper, secondscorekeeper, false) == 0);
 545                 if(WinningConditionHelper_equality)
 546                         WinningConditionHelper_winner = WinningConditionHelper_second = NULL;
 547
 548                 WinningConditionHelper_topscore = winnerscorekeeper.scores_primary;
 549                 WinningConditionHelper_secondscore = secondscorekeeper.scores_primary;
 550                 WinningConditionHelper_lowerisbetter = (scores_flags_primary & SFL_LOWER_IS_BETTER);
 551                 WinningConditionHelper_zeroisworst = (scores_flags_primary & SFL_ZERO_IS_WORST);
 552
 553                 WinningConditionHelper_winnerteam = -1; // no teamplay
 554                 WinningConditionHelper_secondteam = -1; // no teamplay
 555         }
 556
 557         if(WinningConditionHelper_topscore == 0)
 558         {
 559                 if(scores_flags_primary & SFL_ZERO_IS_WORST)
 560                 {
 561                         if(WinningConditionHelper_lowerisbetter)
 562                                 WinningConditionHelper_topscore = 999999999;
 563                         else
 564                                 WinningConditionHelper_topscore = -999999999;
 565                 }
 566                 if(player_count == 0) // special case: empty servers DO end the match at a 0:0 tie
 567                         WinningConditionHelper_equality = 0;
 568         }
 569
 570         if(WinningConditionHelper_secondscore == 0)
 571         {
 572                 if(scores_flags_primary & SFL_ZERO_IS_WORST)
 573                 {
 574                         if(WinningConditionHelper_lowerisbetter)
 575                                 WinningConditionHelper_secondscore = 999999999;
 576                         else
 577                                 WinningConditionHelper_secondscore = -999999999;
 578                 }
 579         }
 580
 581         strcpy(worldstatus, s);
 582
 583         FOREACH_CLIENT(true, {
 584                 string s = "";
 585                 if(fullstatus)
 586                 {
 587                         s = GetPlayerScoreString(it, 1);
 588                         s = strcat(s, IS_REAL_CLIENT(it) ? ":human" : ":bot");
 589                         if(!(IS_PLAYER(it) || INGAME_JOINED(it)))
 590                                 s = strcat(s, ":spectator");
 591                 }
 592                 else
 593                 {
 594                         if (IS_PLAYER(it) || INGAME_JOINED(it))
 595                                 s = GetPlayerScoreString(it, 2);
 596                         else
 597                                 s = "-666";
 598                 }
 599
 600                 strcpy(it.clientstatus, s);
 601         });
 602 }
 603
 604 string GetScoreLogLabel(string label, float fl)
 605 {
 606         if(fl & SFL_LOWER_IS_BETTER)
 607                 label = strcat(label, "<");
 608         if((fl & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 609                 label = strcat(label, "!!");
 610         else if((fl & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_SECONDARY)
 611                 label = strcat(label, "!");
 612         return label;
 613 }
 614
 615 string GetPlayerScoreString(entity pl, float shortString)
 616 {
 617         string out;
 618         entity sk;
 619         float f;
 620         string l;
 621
 622         out = "";
 623         if(!pl)
 624         {
 625                 // label
 626                 FOREACH(Scores, true, {
 627                         if ((scores_flags(it) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 628                         {
 629                                 f = scores_flags(it);
 630                                 l = scores_label(it);
 631                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 632                         }
 633         });
 634                 if(shortString < 2)
 635                 FOREACH(Scores, true, {
 636                         if((scores_flags(it) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_SECONDARY)
 637                         {
 638                                 f = scores_flags(it);
 639                                 l = scores_label(it);
 640                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 641                         }
 642         });
 643                 if(shortString < 1)
 644                 FOREACH(Scores, true, {
 645                         if((scores_flags(it) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_PRIMARY)
 646                         if((scores_flags(it) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_SECONDARY)
 647                         {
 648                                 f = scores_flags(it);
 649                                 l = scores_label(it);
 650                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 651                         }
 652         });
 653                 out = substring(out, 0, strlen(out) - 1);
 654         }
 655         else if((sk = CS(pl).scorekeeper))
 656         {
 657                 FOREACH(Scores, true, {
 658                         if ((scores_flags(it) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 659                                 out = strcat(out, ftos(sk.(scores(it))), ",");
 660         });
 661                 if(shortString < 2)
 662                 FOREACH(Scores, true, {
 663                         if ((scores_flags(it) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_SECONDARY)
 664                                 out = strcat(out, ftos(sk.(scores(it))), ",");
 665         });
 666                 if(shortString < 1)
 667                 FOREACH(Scores, true, {
 668                         if((scores_flags(it) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_PRIMARY)
 669                         if((scores_flags(it) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_SECONDARY)
 670                                 out = strcat(out, ftos(sk.(scores(it))), ",");
 671         });
 672                 out = substring(out, 0, strlen(out) - 1);
 673         }
 674         return out;
 675 }
 676
 677 string GetTeamScoreString(float tm, float shortString)
 678 {
 679         string out;
 680         entity sk;
 681         float i, f;
 682         string l;
 683
 684         out = "";
 685         if(tm == 0)
 686         {
 687                 // label
 688                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 689                         if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 690                         {
 691                                 f = teamscores_flags(i);
 692                                 l = teamscores_label(i);
 693                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 694                         }
 695                 if(shortString < 2)
 696                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 697                         if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_SECONDARY)
 698                         {
 699                                 f = teamscores_flags(i);
 700                                 l = teamscores_label(i);
 701                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 702                         }
 703                 if(shortString < 1)
 704                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 705                         if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_PRIMARY)
 706                         if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_SECONDARY)
 707                         {
 708                                 f = teamscores_flags(i);
 709                                 l = teamscores_label(i);
 710                                 out = strcat(out, GetScoreLogLabel(l, f), ",");
 711                         }
 712                 out = substring(out, 0, strlen(out) - 1);
 713         }
 714         else if((sk = teamscorekeepers[tm - 1]))
 715         {
 716                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 717                         if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_PRIMARY)
 718                                 out = strcat(out, ftos(sk.(teamscores(i))), ",");
 719                 if(shortString < 2)
 720                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 721                         if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) == SFL_SORT_PRIO_SECONDARY)
 722                                 out = strcat(out, ftos(sk.(teamscores(i))), ",");
 723                 if(shortString < 1)
 724                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 725                         if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_PRIMARY)
 726                         if((teamscores_flags(i) & SFL_SORT_PRIO_MASK) != SFL_SORT_PRIO_SECONDARY)
 727                                 out = strcat(out, ftos(sk.(teamscores(i))), ",");
 728                 out = substring(out, 0, strlen(out) - 1);
 729         }
 730         return out;
 731 }
 732
 733 // strict: compare others fields too besides primary and secondary
 734 int PlayerTeamScore_Compare(entity p1, entity p2, float teams, bool strict)
 735 {
 736         if(teams && teamscores_entities_count)
 737         {
 738                 if(p1.team != p2.team)
 739                 {
 740                         entity t1, t2;
 741                         float r;
 742                         t1 = teamscorekeepers[p1.team - 1];
 743                         t2 = teamscorekeepers[p2.team - 1];
 744                         r = TeamScore_Compare(t1, t2, ((teams >= 0) ? 1 : strict));
 745                         return r;
 746                 }
 747                 if(teams < 0)
 748                         return 0;
 749         }
 750
 751         return PlayerScore_Compare(CS(p1).scorekeeper, CS(p2).scorekeeper, strict);
 752 }
 753
 754 entity PlayerScore_Sort(.float field, int teams, bool strict, bool nospectators)
 755 {
 756         entity p, plist, pprev, pbest, pbestprev, pfirst, plast;
 757         float i, j;
 758
 759         plist = NULL;
 760
 761         FOREACH_CLIENT(true, { it.(field) = 0; });
 762
 763         FOREACH_CLIENT(CS(it).scorekeeper,
 764         {
 765                 if(nospectators)
 766                         if(it.frags == FRAGS_SPECTATOR)
 767                                 continue;
 768
 769                 it.chain = plist;
 770                 plist = it;
 771         });
 772         // Now plist points to the whole list.
 773
 774         pfirst = plast = NULL;
 775
 776         i = j = 0;
 777         while(plist)
 778         {
 779                 pprev = pbestprev = NULL;
 780                 pbest = plist;
 781                 for(p = plist; (pprev = p), (p = p.chain); )
 782                 {
 783                         if(PlayerTeamScore_Compare(p, pbest, teams, strict) > 0)
 784                         {
 785                                 pbest = p;
 786                                 pbestprev = pprev;
 787                         }
 788                 }
 789
 790                 // remove pbest out of the chain
 791                 if(pbestprev == NULL)
 792                         plist = pbest.chain;
 793                 else
 794                         pbestprev.chain = pbest.chain;
 795                 pbest.chain = NULL;
 796
 797                 ++i;
 798                 if(!plast || PlayerTeamScore_Compare(plast, pbest, teams, strict))
 799                         j = i;
 800
 801                 pbest.(field) = j;
 802
 803                 if (!pfirst)
 804                         pfirst = pbest;
 805                 if(plast)
 806                         plast.chain = pbest;
 807                 plast = pbest;
 808         }
 809
 810         return pfirst;
 811 }
 812
 813 float TeamScore_GetCompareValue(float t)
 814 {
 815         float s;
 816         entity sk;
 817
 818         if(t <= 0 || t >= 16)
 819         {
 820                 if(game_stopped)
 821                         return 0;
 822                 error("Reading score of invalid team!");
 823         }
 824
 825         sk = teamscorekeepers[t - 1];
 826         if (!sk)
 827                 return -999999999;
 828         s = sk.teamscores_primary;
 829         if(teamscores_flags_primary & SFL_ZERO_IS_WORST)
 830                 if(!s)
 831                         return -999999999;
 832         if(teamscores_flags_primary & SFL_LOWER_IS_BETTER)
 833                 s = -s;
 834         return s;
 835 }
 836
 837 const float NAMEWIDTH = 22;
 838 const float SCORESWIDTH = 58;
 839 // TODO put this somewhere in common?
 840 string Score_NicePrint_ItemColor(float vflags)
 841 {
 842         if(vflags & SFL_SORT_PRIO_PRIMARY)
 843                 return "^3";
 844         else if(vflags & SFL_SORT_PRIO_SECONDARY)
 845                 return "^5";
 846         else
 847                 return "^7";
 848 }
 849
 850 void Score_NicePrint_Team(entity to, float t, float w)
 851 {
 852         string s, s2;
 853         float i;
 854         entity sk;
 855         float fl, sc;
 856         s = "";
 857
 858         sk = teamscorekeepers[t - 1];
 859         if(sk)
 860         {
 861                 s = strcat(s, Team_ColoredFullName(t));
 862                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 863                         if(teamscores_label(i) != "")
 864                         {
 865                                 fl = teamscores_flags(i);
 866                                 sc = sk.(teamscores(i));
 867                                 s = strcat(s, " ", Score_NicePrint_ItemColor(fl), ScoreString(fl, sc, 0));
 868                         }
 869         }
 870         else
 871                 s = "Scores:";
 872
 873         s = strcat(s, strpad(max(0, NAMEWIDTH - strlennocol(s)), ""));
 874
 875         FOREACH(Scores, true, {
 876                 if(scores_label(it) != "")
 877                 {
 878                         fl = scores_flags(it);
 879                         s2 = scores_label(it);
 880                         s = strcat(s, " ", Score_NicePrint_ItemColor(fl), strpad(-w, substring(s2, 0, w)));
 881                 }
 882     });
 883
 884         print_to(to, s);
 885 }
 886
 887 void Score_NicePrint_Player(entity to, entity p, float w)
 888 {
 889         string s;
 890         float i;
 891         entity sk;
 892         float fl, sc;
 893         s = "  ";
 894
 895         sk = CS(p).scorekeeper;
 896
 897         s = strcat(s, playername(p.netname, p.team, false));
 898         for (;;)
 899         {
 900                 i = strlennocol(s) - NAMEWIDTH;
 901                 if(i > 0)
 902                         s = substring(s, 0, strlen(s) - i);
 903                 else
 904                 {
 905                         s = strcat(s, strpad(i, ""));
 906                         break;
 907                 }
 908         }
 909
 910         FOREACH(Scores, true, {
 911                 if(scores_label(it) != "")
 912                 {
 913                         fl = scores_flags(it);
 914                         sc = sk.(scores(it));
 915                         s = strcat(s, " ", Score_NicePrint_ItemColor(fl), strpad(-w, ScoreString(fl, sc, 0)));
 916                 }
 917     });
 918
 919         print_to(to, s);
 920 }
 921
 922 void Score_NicePrint_Spectators(entity to)
 923 {
 924         print_to(to, "Spectators:");
 925 }
 926
 927 void Score_NicePrint_Spectator(entity to, entity p)
 928 {
 929         print_to(to, strcat("  ", playername(p.netname, p.team, false)));
 930 }
 931
 932 .float score_dummyfield;
 933 void Score_NicePrint(entity to)
 934 {
 935         entity p;
 936         float w;
 937
 938         int t = 0;
 939         FOREACH(Scores, true, {
 940                 if(scores_label(it) != "")
 941                         ++t;
 942     });
 943         w = bound(6, floor(SCORESWIDTH / t - 1), 9);
 944
 945         p = PlayerScore_Sort(score_dummyfield, 1, true, false);
 946         t = -1;
 947
 948         if(!teamscores_entities_count)
 949                 Score_NicePrint_Team(to, t, w);
 950         while(p)
 951         {
 952                 if(teamscores_entities_count)
 953                         if(t != p.team)
 954                                 Score_NicePrint_Team(to, p.team, w);
 955                 Score_NicePrint_Player(to, p, w);
 956                 t = p.team;
 957                 p = p.chain;
 958         }
 959
 960         t = 0;
 961         FOREACH_CLIENT(!IS_PLAYER(it), {
 962                 if (!t)
 963                         Score_NicePrint_Spectators(to);
 964                 Score_NicePrint_Spectator(to, it);
 965                 t = 1;
 966         });
 967 }
 968
 969 void PlayerScore_PlayerStats(entity p)
 970 {
 971         entity s = CS(p).scorekeeper;
 972         FOREACH(Scores, true, {
 973                 if(s.(scores(it)) != 0 && scores_label(it) != "")
 974                         PlayerStats_GameReport_Event_Player(s.owner,
 975                                 strcat(PLAYERSTATS_SCOREBOARD, scores_label(it)), s.(scores(it)));
 976         });
 977 }
 978
 979 void PlayerScore_TeamStats()
 980 {
 981         entity sk;
 982         float t, i;
 983         for(t = 0; t < 16; ++t)
 984         {
 985                 sk = teamscorekeepers[t];
 986                 if(!sk)
 987                         continue;
 988                 for(i = 0; i < MAX_TEAMSCORE; ++i)
 989                         if(sk.(teamscores(i)) != 0 && teamscores_label(i) != "")
 990                                 // the +1 is important here!
 991                                 PlayerStats_GameReport_Event_Team(t+1,
 992                                         strcat(PLAYERSTATS_SCOREBOARD, teamscores_label(i)), sk.(teamscores(i)));
 993         }
 994 }