qcsrc/server/sv_main.qc

   1 void CreatureFrame (void)
   2 {
   3         entity oldself;
   4         float dm;
   5
   6         oldself = self;
   7         for(self = world; (self = findfloat(self, damagedbycontents, TRUE)); )
   8         {
   9                 if (self.movetype == MOVETYPE_NOCLIP) { continue; }
  10
  11                 float vehic = (self.vehicle_flags & VHF_ISVEHICLE);
  12                 float projectile = (self.flags & FL_PROJECTILE);
  13                 float monster = (self.flags & FL_MONSTER);
  14
  15                 if (self.watertype <= CONTENT_WATER && self.waterlevel > 0) // workaround a retarded bug made by id software :P (yes, it's that old of a bug)
  16                 {
  17                         if (!(self.flags & FL_INWATER))
  18                         {
  19                                 self.flags |= FL_INWATER;
  20                                 self.dmgtime = 0;
  21                         }
  22
  23                         if(!vehic && !projectile && !monster) // vehicles, monsters and projectiles don't drown
  24                         {
  25                                 if (self.waterlevel != WATERLEVEL_SUBMERGED)
  26                                 {
  27                                         if(self.air_finished < time)
  28                                                 PlayerSound(playersound_gasp, CH_PLAYER, VOICETYPE_PLAYERSOUND);
  29                                         self.air_finished = time + autocvar_g_balance_contents_drowndelay;
  30                                         self.dmg = 2;
  31                                 }
  32                                 else if (self.air_finished < time)
  33                                 {       // drown!
  34                                         if (!self.deadflag)
  35                                         if (self.pain_finished < time)
  36                                         {
  37                                                 Damage (self, world, world, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN, self.origin, '0 0 0');
  38                                                 self.pain_finished = time + 0.5;
  39                                         }
  40                                 }
  41                         }
  42
  43                         if (self.dmgtime < time)
  44                         {
  45                                 self.dmgtime = time + autocvar_g_balance_contents_damagerate;
  46
  47                                 if (projectile)
  48                                 {
  49                                         if (self.watertype == CONTENT_LAVA)
  50                                         {
  51                                                 Damage (self, world, world, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * self.waterlevel, DEATH_LAVA, self.origin, '0 0 0');
  52                                         }
  53                                         else if (self.watertype == CONTENT_SLIME)
  54                                         {
  55                                                 Damage (self, world, world, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * self.waterlevel, DEATH_SLIME, self.origin, '0 0 0');
  56                                         }
  57                                 }
  58                                 else
  59                                 {
  60                                         if (self.watertype == CONTENT_LAVA)
  61                                         {
  62                                                 if (self.watersound_finished < time)
  63                                                 {
  64                                                         self.watersound_finished = time + 0.5;
  65                                                         sound (self, CH_PLAYER, "player/lava.wav", VOL_BASE, ATTN_NORM);
  66                                                 }
  67                                                 Damage (self, world, world, autocvar_g_balance_contents_playerdamage_lava * autocvar_g_balance_contents_damagerate * self.waterlevel, DEATH_LAVA, self.origin, '0 0 0');
  68                                         }
  69                                         else if (self.watertype == CONTENT_SLIME)
  70                                         {
  71                                                 if (self.watersound_finished < time)
  72                                                 {
  73                                                         self.watersound_finished = time + 0.5;
  74                                                         sound (self, CH_PLAYER, "player/slime.wav", VOL_BASE, ATTN_NORM);
  75                                                 }
  76                                                 Damage (self, world, world, autocvar_g_balance_contents_playerdamage_slime * autocvar_g_balance_contents_damagerate * self.waterlevel, DEATH_SLIME, self.origin, '0 0 0');
  77                                         }
  78                                 }
  79                         }
  80                 }
  81                 else
  82                 {
  83                         if (self.flags & FL_INWATER)
  84                         {
  85                                 // play leave water sound
  86                                 self.flags &~= FL_INWATER;
  87                                 self.dmgtime = 0;
  88                         }
  89                         self.air_finished = time + 12;
  90                         self.dmg = 2;
  91                 }
  92
  93                 if(!vehic && !projectile) // vehicles don't get falling damage
  94                 {
  95                         // check for falling damage
  96                         float velocity_len = vlen(self.velocity);
  97                         if(!self.hook.state && !g_ca && !(g_cts && !autocvar_g_cts_selfdamage))
  98                         {
  99                                 dm = vlen(self.oldvelocity) - velocity_len; // dm is now the velocity DECREASE. Velocity INCREASE should never cause a sound or any damage.
 100                                 if (self.deadflag)
 101                                         dm = (dm - autocvar_g_balance_falldamage_deadminspeed) * autocvar_g_balance_falldamage_factor;
 102                                 else
 103                                         dm = min((dm - autocvar_g_balance_falldamage_minspeed) * autocvar_g_balance_falldamage_factor, autocvar_g_balance_falldamage_maxdamage);
 104                                 if (dm > 0)
 105                                         Damage (self, world, world, dm, DEATH_FALL, self.origin, '0 0 0');
 106                         }
 107
 108                         if(autocvar_g_maxspeed > 0 && velocity_len > autocvar_g_maxspeed)
 109                                 Damage (self, world, world, 100000, DEATH_SHOOTING_STAR, self.origin, '0 0 0');
 110                         // play stupid sounds
 111                         if (g_footsteps)
 112                         if (!gameover)
 113                         if (self.flags & FL_ONGROUND)
 114                         if (velocity_len > autocvar_sv_maxspeed * 0.6)
 115                         if (!self.deadflag)
 116                         if (time < self.lastground + 0.2)
 117                         {
 118                                 if((time > self.nextstep) || (time < (self.nextstep - 10.0)))
 119                                 {
 120                                         self.nextstep = time + 0.3 + random() * 0.1;
 121                                         trace_dphitq3surfaceflags = 0;
 122                                         tracebox(self.origin, self.mins, self.maxs, self.origin - '0 0 1', MOVE_NOMONSTERS, self);
 123                                         /*
 124                                         if(trace_fraction == 1)
 125                                                 dprint("nohit\n");
 126                                         else
 127                                                 dprint(ftos(trace_dphitq3surfaceflags), "\n");
 128                                         */
 129                                         if not(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOSTEPS)
 130                                         {
 131                                                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_METALSTEPS)
 132                                                         GlobalSound(globalsound_metalstep, CH_PLAYER, VOICETYPE_PLAYERSOUND);
 133                                                 else
 134                                                         GlobalSound(globalsound_step, CH_PLAYER, VOICETYPE_PLAYERSOUND);
 135                                         }
 136                                 }
 137                         }
 138                 }
 139
 140         self.oldvelocity = self.velocity;
 141         }
 142         self = oldself;
 143 }
 144
 145
 146 /*
 147 =============
 148 StartFrame
 149
 150 Called before each frame by the server
 151 =============
 152 */
 153
 154 float game_delay;
 155 float game_delay_last;
 156
 157 void RuneMatchGivePoints();
 158 float RedirectionThink();
 159 entity SelectSpawnPoint (float anypoint);
 160 void StartFrame (void)
 161 {
 162         execute_next_frame();
 163
 164         remove = remove_unsafely; // not during spawning!
 165         serverprevtime = servertime;
 166         servertime = time;
 167         serverframetime = frametime;
 168
 169 #ifdef PROFILING
 170         if(time > client_cefc_accumulatortime + 1)
 171         {
 172                 float t, pp, c_seeing, c_seen;
 173                 entity cl;
 174                 t = client_cefc_accumulator / (time - client_cefc_accumulatortime);
 175                 print("CEFC time: ", ftos(t * 1000), "ms; ");
 176                 c_seeing = 0;
 177                 c_seen = 0;
 178                 FOR_EACH_CLIENT(cl)
 179                 {
 180                         if(clienttype(cl) == CLIENTTYPE_REAL)
 181                                 ++c_seeing;
 182                         if(cl.classname == "player")
 183                                 ++c_seen;
 184                 }
 185                 print("CEFC calls per second: ", ftos(c_seeing * (c_seen - 1) / t), "; ");
 186                 print("CEFC 100% load at: ", ftos(solve_quadratic(t, -t, -1) * '0 1 0'), "\n");
 187
 188                 client_cefc_accumulatortime = time;
 189                 client_cefc_accumulator = 0;
 190         }
 191 #endif
 192
 193         entity e;
 194         for(e = world; (e = findfloat(e, csqcprojectile_clientanimate, 1)); )
 195                 CSQCProjectile_Check(e);
 196
 197         if(RedirectionThink())
 198                 return;
 199
 200         UncustomizeEntitiesRun();
 201         InitializeEntitiesRun();
 202
 203         WarpZone_StartFrame();
 204
 205         sys_frametime = autocvar_sys_ticrate * autocvar_slowmo;
 206         if(sys_frametime <= 0)
 207                 sys_frametime = 1.0 / 60.0; // somewhat safe fallback
 208
 209         if (timeout_status == TIMEOUT_LEADTIME) // just before the timeout (when timeout_status will be TIMEOUT_ACTIVE)
 210                 orig_slowmo = autocvar_slowmo; // slowmo will be restored after the timeout
 211
 212         skill = autocvar_skill;
 213
 214         count_players();
 215         if(g_ca || g_freezetag)
 216                 count_alive_players();
 217         Arena_Warmup();
 218         Spawnqueue_Check();
 219
 220         // detect when the pre-game countdown (if any) has ended and the game has started
 221         game_delay = (time < game_starttime) ? TRUE : FALSE;
 222
 223         if(game_delay_last == TRUE)
 224         if(game_delay == FALSE)
 225         if(autocvar_sv_eventlog)
 226                         GameLogEcho(":startdelay_ended");
 227
 228         game_delay_last = game_delay;
 229
 230         // if in warmup stage and limit for warmup is hit start match
 231         if (inWarmupStage)
 232         if ((g_warmup_limit > 0 && time >= g_warmup_limit)
 233          || (g_warmup_limit == 0 && autocvar_timelimit != 0 && time >= autocvar_timelimit * 60))
 234         {
 235                 ReadyRestart();
 236                 return;
 237         }
 238
 239         CreatureFrame ();
 240         CheckRules_World ();
 241
 242         RuneMatchGivePoints();
 243         bot_serverframe();
 244
 245         FOR_EACH_PLAYER(self)
 246                 self.porto_forbidden = max(0, self.porto_forbidden - 1);
 247
 248         MUTATOR_CALLHOOK(SV_StartFrame);
 249 }
 250
 251 .vector originjitter;
 252 .vector anglesjitter;
 253 .float anglejitter;
 254 .string gametypefilter;
 255 .string cvarfilter;
 256 float DoesQ3ARemoveThisEntity();
 257 void SV_OnEntityPreSpawnFunction()
 258 {
 259         if (self)
 260         if (self.gametypefilter != "")
 261         if not(isGametypeInFilter(MapInfo_LoadedGametype, teamplay, have_team_spawns, self.gametypefilter))
 262         {
 263                 remove(self);
 264                 return;
 265         }
 266         if(self.cvarfilter != "")
 267         {
 268                 float n, i, o, inv;
 269                 string s, k, v;
 270                 inv = 0;
 271
 272                 s = self.cvarfilter;
 273                 if(substring(s, 0, 1) == "+")
 274                 {
 275                         s = substring(s, 1, -1);
 276                 }
 277                 else if(substring(s, 0, 1) == "-")
 278                 {
 279                         inv = 1;
 280                         s = substring(s, 1, -1);
 281                 }
 282
 283                 n = tokenize_console(s);
 284                 for(i = 0; i < n; ++i)
 285                 {
 286                         s = argv(i);
 287                         // syntax:
 288                         // var>x
 289                         // var<x
 290                         // var>=x
 291                         // var<=x
 292                         // var==x
 293                         // var!=x
 294                         // var===x
 295                         // var!==x
 296                         if((o = strstrofs(s, ">=", 0)) >= 0)
 297                         {
 298                                 k = substring(s, 0, o);
 299                                 v = substring(s, o+2, -1);
 300                                 if(cvar(k) < stof(v))
 301                                         goto cvar_fail;
 302                         }
 303                         else if((o = strstrofs(s, "<=", 0)) >= 0)
 304                         {
 305                                 k = substring(s, 0, o);
 306                                 v = substring(s, o+2, -1);
 307                                 if(cvar(k) > stof(v))
 308                                         goto cvar_fail;
 309                         }
 310                         else if((o = strstrofs(s, ">", 0)) >= 0)
 311                         {
 312                                 k = substring(s, 0, o);
 313                                 v = substring(s, o+1, -1);
 314                                 if(cvar(k) <= stof(v))
 315                                         goto cvar_fail;
 316                         }
 317                         else if((o = strstrofs(s, "<", 0)) >= 0)
 318                         {
 319                                 k = substring(s, 0, o);
 320                                 v = substring(s, o+1, -1);
 321                                 if(cvar(k) >= stof(v))
 322                                         goto cvar_fail;
 323                         }
 324                         else if((o = strstrofs(s, "==", 0)) >= 0)
 325                         {
 326                                 k = substring(s, 0, o);
 327                                 v = substring(s, o+2, -1);
 328                                 if(cvar(k) != stof(v))
 329                                         goto cvar_fail;
 330                         }
 331                         else if((o = strstrofs(s, "!=", 0)) >= 0)
 332                         {
 333                                 k = substring(s, 0, o);
 334                                 v = substring(s, o+2, -1);
 335                                 if(cvar(k) == stof(v))
 336                                         goto cvar_fail;
 337                         }
 338                         else if((o = strstrofs(s, "===", 0)) >= 0)
 339                         {
 340                                 k = substring(s, 0, o);
 341                                 v = substring(s, o+2, -1);
 342                                 if(cvar_string(k) != v)
 343                                         goto cvar_fail;
 344                         }
 345                         else if((o = strstrofs(s, "!==", 0)) >= 0)
 346                         {
 347                                 k = substring(s, 0, o);
 348                                 v = substring(s, o+2, -1);
 349                                 if(cvar_string(k) == v)
 350                                         goto cvar_fail;
 351                         }
 352                         else if(substring(s, 0, 1) == "!")
 353                         {
 354                                 k = substring(s, 1, -1);
 355                                 if(cvar(k))
 356                                         goto cvar_fail;
 357                         }
 358                         else
 359                         {
 360                                 k = s;
 361                                 if not(cvar(k))
 362                                         goto cvar_fail;
 363                         }
 364                 }
 365                 inv = !inv;
 366 :cvar_fail
 367                 // now inv is 1 if we want to keep the item, and 0 if we want to get rid of it
 368                 if not(inv)
 369                 {
 370                         //print("cvarfilter fail\n");
 371                         remove(self);
 372                         return;
 373                 }
 374         }
 375
 376         if(DoesQ3ARemoveThisEntity())
 377         {
 378                 remove(self);
 379                 return;
 380         }
 381
 382         // support special -1 and -2 angle from radiant
 383         if (self.angles == '0 -1 0')
 384                 self.angles = '-90 0 0';
 385         else if (self.angles == '0 -2 0')
 386                 self.angles = '+90 0 0';
 387
 388         if(self.originjitter_x != 0)
 389                 self.origin_x = self.origin_x + (random() * 2 - 1) * self.originjitter_x;
 390         if(self.originjitter_y != 0)
 391                 self.origin_y = self.origin_y + (random() * 2 - 1) * self.originjitter_y;
 392         if(self.originjitter_z != 0)
 393                 self.origin_z = self.origin_z + (random() * 2 - 1) * self.originjitter_z;
 394         if(self.anglesjitter_x != 0)
 395                 self.angles_x = self.angles_x + (random() * 2 - 1) * self.anglesjitter_x;
 396         if(self.anglesjitter_y != 0)
 397                 self.angles_y = self.angles_y + (random() * 2 - 1) * self.anglesjitter_y;
 398         if(self.anglesjitter_z != 0)
 399                 self.angles_z = self.angles_z + (random() * 2 - 1) * self.anglesjitter_z;
 400         if(self.anglejitter != 0)
 401                 self.angles_y = self.angles_y + (random() * 2 - 1) * self.anglejitter;
 402
 403         if(MUTATOR_CALLHOOK(OnEntityPreSpawn))
 404         {
 405                 remove(self);
 406                 return;
 407         }
 408 }
 409
 410 void WarpZone_PostInitialize_Callback(void)
 411 {
 412         // create waypoint links for warpzones
 413         entity e;
 414         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
 415         {
 416                 vector src, dst;
 417                 src = (e.absmin + e.absmax) * 0.5;
 418                 makevectors(e.warpzone_angles);
 419                 src = src + ((e.warpzone_origin - src) * v_forward) * v_forward + 16 * v_right;
 420                 dst = (e.enemy.absmin + e.enemy.absmax) * 0.5;
 421                 makevectors(e.enemy.warpzone_angles);
 422                 dst = dst + ((e.enemy.warpzone_origin - dst) * v_forward) * v_forward - 16 * v_right;
 423                 waypoint_spawnforteleporter_v(e, src, dst, 0);
 424         }
 425 }