qcsrc/server/sv_main.qc

   1 #include "sv_main.qh"
   2
   3 #include "anticheat.qh"
   4 #include "g_hook.qh"
   5 #include "g_world.qh"
   6
   7 #include "bot/bot.qh"
   8 #include "bot/waypoints.qh"
   9
  10 #include "command/common.qh"
  11
  12 #include "mutators/all.qh"
  13 #include "weapons/csqcprojectile.qh"
  14
  15 #include "../common/constants.qh"
  16 #include "../common/deathtypes/all.qh"
  17 #include "../common/debug.qh"
  18 #include "../common/mapinfo.qh"
  19 #include "../common/util.qh"
  20
  21 #include "../common/vehicles/all.qh"
  22 #include "../common/weapons/all.qh"
  23
  24 #include "../lib/csqcmodel/sv_model.qh"
  25
  26 #include "../lib/warpzone/common.qh"
  27 #include "../lib/warpzone/server.qh"
  28
  29 .float lastground;
  30 .int state;
  31
  32 void CreatureFrame_hotliquids(entity this)
  33 {
  34         if (this.dmgtime < time)
  35         {
  36                 this.dmgtime = time + autocvar_g_balance_contents_damagerate;
  37
  38                 if (this.flags & FL_PROJECTILE)
  39                 {
  40                         if (this.watertype == CONTENT_LAVA)
  41                                 Damage (this, world, world, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, this.origin, '0 0 0');
  42                         else if (this.watertype == CONTENT_SLIME)
  43                                 Damage (this, world, world, autocvar_g_balance_contents_projectiledamage * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, this.origin, '0 0 0');
  44                 }
  45                 else
  46                 {
  47                         if (this.watertype == CONTENT_LAVA)
  48                         {
  49                                 if (this.watersound_finished < time)
  50                                 {
  51                                         this.watersound_finished = time + 0.5;
  52                                         sound (this, CH_PLAYER_SINGLE, SND_LAVA, VOL_BASE, ATTEN_NORM);
  53                                 }
  54                                 Damage (this, world, world, autocvar_g_balance_contents_playerdamage_lava * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_LAVA.m_id, this.origin, '0 0 0');
  55                                 if(autocvar_g_balance_contents_playerdamage_lava_burn)
  56                                         Fire_AddDamage(this, world, autocvar_g_balance_contents_playerdamage_lava_burn * this.waterlevel, autocvar_g_balance_contents_playerdamage_lava_burn_time * this.waterlevel, DEATH_LAVA.m_id);
  57                         }
  58                         else if (this.watertype == CONTENT_SLIME)
  59                         {
  60                                 if (this.watersound_finished < time)
  61                                 {
  62                                         this.watersound_finished = time + 0.5;
  63                                         sound (this, CH_PLAYER_SINGLE, SND_SLIME, VOL_BASE, ATTEN_NORM);
  64                                 }
  65                                 Damage (this, world, world, autocvar_g_balance_contents_playerdamage_slime * autocvar_g_balance_contents_damagerate * this.waterlevel, DEATH_SLIME.m_id, this.origin, '0 0 0');
  66                         }
  67                 }
  68         }
  69 }
  70
  71 void CreatureFrame_Liquids(entity this)
  72 {
  73         if (this.watertype <= CONTENT_WATER && this.waterlevel > 0) // workaround a retarded bug made by id software :P (yes, it's that old of a bug)
  74         {
  75                 if (!(this.flags & FL_INWATER))
  76                 {
  77                         this.flags |= FL_INWATER;
  78                         this.dmgtime = 0;
  79                 }
  80
  81                 CreatureFrame_hotliquids(this);
  82         }
  83         else
  84         {
  85                 if (this.flags & FL_INWATER)
  86                 {
  87                         // play leave water sound
  88                         this.flags &= ~FL_INWATER;
  89                         this.dmgtime = 0;
  90                 }
  91                 this.air_finished = time + 12;
  92                 this.dmg = 2;
  93         }
  94 }
  95
  96 void CreatureFrame_FallDamage(entity this)
  97 {
  98         if(!IS_VEHICLE(this) && !(this.flags & FL_PROJECTILE)) // vehicles don't get falling damage
  99         {
 100                 // check for falling damage
 101                 float velocity_len = vlen(this.velocity);
 102                 if(!this.hook.state)
 103                 {
 104                         float dm = vlen(this.oldvelocity) - velocity_len; // dm is now the velocity DECREASE. Velocity INCREASE should never cause a sound or any damage.
 105                         if (IS_DEAD(this))
 106                                 dm = (dm - autocvar_g_balance_falldamage_deadminspeed) * autocvar_g_balance_falldamage_factor;
 107                         else
 108                                 dm = min((dm - autocvar_g_balance_falldamage_minspeed) * autocvar_g_balance_falldamage_factor, autocvar_g_balance_falldamage_maxdamage);
 109                         if (dm > 0)
 110                                 Damage (this, world, world, dm, DEATH_FALL.m_id, this.origin, '0 0 0');
 111                 }
 112
 113                 if(autocvar_g_maxspeed > 0 && velocity_len > autocvar_g_maxspeed)
 114                         Damage (this, world, world, 100000, DEATH_SHOOTING_STAR.m_id, this.origin, '0 0 0');
 115         }
 116 }
 117
 118 void CreatureFrame_All()
 119 {
 120         FOREACH_ENTITY_FLOAT(damagedbycontents, true, LAMBDA(
 121                 if(it.movetype == MOVETYPE_NOCLIP) continue;
 122                 CreatureFrame_Liquids(it);
 123                 CreatureFrame_FallDamage(it);
 124                 it.oldvelocity = it.velocity;
 125         ));
 126 }
 127
 128 void Pause_TryPause(bool ispaused)
 129 {
 130         int n = 0;
 131         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), LAMBDA(
 132                 if (PHYS_INPUT_BUTTON_CHAT(it) != ispaused) return;
 133                 ++n;
 134         ));
 135         if (!n) return;
 136         setpause(ispaused);
 137 }
 138
 139 void SV_PausedTic(float elapsedtime)
 140 {
 141         if (!server_is_dedicated) Pause_TryPause(false);
 142 }
 143
 144 /*
 145 =============
 146 StartFrame
 147
 148 Called before each frame by the server
 149 =============
 150 */
 151
 152 float game_delay;
 153 float game_delay_last;
 154
 155 bool autocvar_sv_autopause = true;
 156 float RedirectionThink();
 157 void StartFrame()
 158 {
 159         execute_next_frame();
 160         if (autocvar_sv_autopause && !server_is_dedicated) Pause_TryPause(true);
 161
 162         remove = remove_unsafely; // not during spawning!
 163         serverprevtime = servertime;
 164         servertime = time;
 165         serverframetime = frametime;
 166
 167 #ifdef PROFILING
 168         if(time > client_cefc_accumulatortime + 1)
 169         {
 170                 float t = client_cefc_accumulator / (time - client_cefc_accumulatortime);
 171                 LOG_INFO("CEFC time: ", ftos(t * 1000), "ms; ");
 172                 int c_seeing = 0;
 173                 int c_seen = 0;
 174                 FOREACH_CLIENT(true, LAMBDA(
 175                         if(IS_REAL_CLIENT(it))
 176                                 ++c_seeing;
 177                         if(IS_PLAYER(it))
 178                                 ++c_seen;
 179                 ));
 180                 LOG_INFO("CEFC calls per second: ", ftos(c_seeing * (c_seen - 1) / t), "; ");
 181                 LOG_INFO("CEFC 100% load at: ", ftos(solve_quadratic(t, -t, -1) * '0 1 0'), "\n");
 182
 183                 client_cefc_accumulatortime = time;
 184                 client_cefc_accumulator = 0;
 185         }
 186 #endif
 187
 188         FOREACH_ENTITY_FLOAT(csqcprojectile_clientanimate, true, LAMBDA(CSQCProjectile_Check(it)));
 189
 190         if(RedirectionThink())
 191                 return;
 192
 193         UncustomizeEntitiesRun();
 194         InitializeEntitiesRun();
 195
 196         WarpZone_StartFrame();
 197
 198         sys_frametime = autocvar_sys_ticrate * autocvar_slowmo;
 199         if(sys_frametime <= 0)
 200                 sys_frametime = 1.0 / 60.0; // somewhat safe fallback
 201
 202         if (timeout_status == TIMEOUT_LEADTIME) // just before the timeout (when timeout_status will be TIMEOUT_ACTIVE)
 203                 orig_slowmo = autocvar_slowmo; // slowmo will be restored after the timeout
 204
 205         skill = autocvar_skill;
 206
 207         // detect when the pre-game countdown (if any) has ended and the game has started
 208         game_delay = (time < game_starttime);
 209
 210         if(autocvar_sv_eventlog && game_delay_last && !game_delay)
 211                 GameLogEcho(":startdelay_ended");
 212
 213         game_delay_last = game_delay;
 214
 215         CreatureFrame_All();
 216         CheckRules_World();
 217
 218         // if in warmup stage and limit for warmup is hit start match
 219         if(warmup_stage)
 220         if(!gameover)
 221         if((g_warmup_limit > 0 && time >= g_warmup_limit)
 222          || (g_warmup_limit == 0 && autocvar_timelimit != 0 && time >= autocvar_timelimit * 60))
 223         {
 224                 ReadyRestart();
 225                 return;
 226         }
 227
 228         bot_serverframe();
 229         anticheat_startframe();
 230         MUTATOR_CALLHOOK(SV_StartFrame);
 231
 232     FOREACH_CLIENT(true, LAMBDA(GlobalStats_update(it)));
 233 }
 234
 235 .vector originjitter;
 236 .vector anglesjitter;
 237 .float anglejitter;
 238 .string gametypefilter;
 239 .string cvarfilter;
 240 float DoesQ3ARemoveThisEntity();
 241 void SV_OnEntityPreSpawnFunction()
 242 {SELFPARAM();
 243         __spawnfunc_expect = this;
 244         if (self)
 245         if (self.gametypefilter != "")
 246         if (!isGametypeInFilter(MapInfo_LoadedGametype, teamplay, have_team_spawns, self.gametypefilter))
 247         {
 248                 remove(self);
 249                 return;
 250         }
 251         if(self.cvarfilter != "")
 252         {
 253                 float n, i, o, inv;
 254                 string s, k, v;
 255                 inv = 0;
 256
 257                 s = self.cvarfilter;
 258                 if(substring(s, 0, 1) == "+")
 259                 {
 260                         s = substring(s, 1, -1);
 261                 }
 262                 else if(substring(s, 0, 1) == "-")
 263                 {
 264                         inv = 1;
 265                         s = substring(s, 1, -1);
 266                 }
 267
 268                 n = tokenize_console(s);
 269                 for(i = 0; i < n; ++i)
 270                 {
 271                         s = argv(i);
 272                         // syntax:
 273                         // var>x
 274                         // var<x
 275                         // var>=x
 276                         // var<=x
 277                         // var==x
 278                         // var!=x
 279                         // var===x
 280                         // var!==x
 281                         if((o = strstrofs(s, ">=", 0)) >= 0)
 282                         {
 283                                 k = substring(s, 0, o);
 284                                 v = substring(s, o+2, -1);
 285                                 if(cvar(k) < stof(v))
 286                                         goto cvar_fail;
 287                         }
 288                         else if((o = strstrofs(s, "<=", 0)) >= 0)
 289                         {
 290                                 k = substring(s, 0, o);
 291                                 v = substring(s, o+2, -1);
 292                                 if(cvar(k) > stof(v))
 293                                         goto cvar_fail;
 294                         }
 295                         else if((o = strstrofs(s, ">", 0)) >= 0)
 296                         {
 297                                 k = substring(s, 0, o);
 298                                 v = substring(s, o+1, -1);
 299                                 if(cvar(k) <= stof(v))
 300                                         goto cvar_fail;
 301                         }
 302                         else if((o = strstrofs(s, "<", 0)) >= 0)
 303                         {
 304                                 k = substring(s, 0, o);
 305                                 v = substring(s, o+1, -1);
 306                                 if(cvar(k) >= stof(v))
 307                                         goto cvar_fail;
 308                         }
 309                         else if((o = strstrofs(s, "==", 0)) >= 0)
 310                         {
 311                                 k = substring(s, 0, o);
 312                                 v = substring(s, o+2, -1);
 313                                 if(cvar(k) != stof(v))
 314                                         goto cvar_fail;
 315                         }
 316                         else if((o = strstrofs(s, "!=", 0)) >= 0)
 317                         {
 318                                 k = substring(s, 0, o);
 319                                 v = substring(s, o+2, -1);
 320                                 if(cvar(k) == stof(v))
 321                                         goto cvar_fail;
 322                         }
 323                         else if((o = strstrofs(s, "===", 0)) >= 0)
 324                         {
 325                                 k = substring(s, 0, o);
 326                                 v = substring(s, o+2, -1);
 327                                 if(cvar_string(k) != v)
 328                                         goto cvar_fail;
 329                         }
 330                         else if((o = strstrofs(s, "!==", 0)) >= 0)
 331                         {
 332                                 k = substring(s, 0, o);
 333                                 v = substring(s, o+2, -1);
 334                                 if(cvar_string(k) == v)
 335                                         goto cvar_fail;
 336                         }
 337                         else if(substring(s, 0, 1) == "!")
 338                         {
 339                                 k = substring(s, 1, -1);
 340                                 if(cvar(k))
 341                                         goto cvar_fail;
 342                         }
 343                         else
 344                         {
 345                                 k = s;
 346                                 if (!cvar(k))
 347                                         goto cvar_fail;
 348                         }
 349                 }
 350                 inv = !inv;
 351 :cvar_fail
 352                 // now inv is 1 if we want to keep the item, and 0 if we want to get rid of it
 353                 if (!inv)
 354                 {
 355                         //print("cvarfilter fail\n");
 356                         remove(self);
 357                         return;
 358                 }
 359         }
 360
 361         if(DoesQ3ARemoveThisEntity())
 362         {
 363                 remove(self);
 364                 return;
 365         }
 366
 367         // support special -1 and -2 angle from radiant
 368         if (self.angles == '0 -1 0')
 369                 self.angles = '-90 0 0';
 370         else if (self.angles == '0 -2 0')
 371                 self.angles = '+90 0 0';
 372
 373         if(self.originjitter.x != 0)
 374                 self.origin_x = self.origin.x + (random() * 2 - 1) * self.originjitter.x;
 375         if(self.originjitter.y != 0)
 376                 self.origin_y = self.origin.y + (random() * 2 - 1) * self.originjitter.y;
 377         if(self.originjitter.z != 0)
 378                 self.origin_z = self.origin.z + (random() * 2 - 1) * self.originjitter.z;
 379         if(self.anglesjitter.x != 0)
 380                 self.angles_x = self.angles.x + (random() * 2 - 1) * self.anglesjitter.x;
 381         if(self.anglesjitter.y != 0)
 382                 self.angles_y = self.angles.y + (random() * 2 - 1) * self.anglesjitter.y;
 383         if(self.anglesjitter.z != 0)
 384                 self.angles_z = self.angles.z + (random() * 2 - 1) * self.anglesjitter.z;
 385         if(self.anglejitter != 0)
 386                 self.angles_y = self.angles.y + (random() * 2 - 1) * self.anglejitter;
 387
 388         if(MUTATOR_CALLHOOK(OnEntityPreSpawn))
 389         {
 390                 remove(self);
 391                 return;
 392         }
 393 }
 394
 395 void WarpZone_PostInitialize_Callback()
 396 {
 397         // create waypoint links for warpzones
 398         entity e;
 399         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
 400         {
 401                 vector src, dst;
 402                 src = (e.absmin + e.absmax) * 0.5;
 403                 makevectors(e.warpzone_angles);
 404                 src = src + ((e.warpzone_origin - src) * v_forward) * v_forward + 16 * v_right;
 405                 dst = (e.enemy.absmin + e.enemy.absmax) * 0.5;
 406                 makevectors(e.enemy.warpzone_angles);
 407                 dst = dst + ((e.enemy.warpzone_origin - dst) * v_forward) * v_forward - 16 * v_right;
 408                 waypoint_spawnforteleporter_v(e, src, dst, 0);
 409         }
 410 }