qcsrc/server/t_items.qc

   1 float have_pickup_item(void)
   2 {
   3         // minstagib: only allow filtered items
   4         if(g_minstagib)
   5                 if(self.classname != "minstagib")
   6                         return FALSE;
   7
   8         if(self.flags & FL_POWERUP)
   9         {
  10                 if(autocvar_g_powerups > 0)
  11                         return TRUE;
  12                 if(autocvar_g_powerups == 0)
  13                         return FALSE;
  14                 if(g_lms)
  15                         return FALSE;
  16                 if(g_ca)
  17                         return FALSE;
  18                 if(g_arena)
  19                         return FALSE;
  20         }
  21         else
  22         {
  23                 if(autocvar_g_pickup_items > 0)
  24                         return TRUE;
  25                 if(autocvar_g_pickup_items == 0)
  26                         return FALSE;
  27                 if(g_lms)
  28                         return FALSE;
  29                 if(g_ca)
  30                         return FALSE;
  31                 if(g_weaponarena)
  32                         if(!WEPSET_EMPTY_E(self) || (self.items & IT_AMMO))
  33                                 return FALSE;
  34         }
  35         return TRUE;
  36 }
  37
  38 #define ITEM_RESPAWN_TICKS 10
  39
  40 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
  41         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
  42 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
  43         // range: 10 .. respawntime + respawntimejitter
  44
  45 floatfield Item_CounterField(float it)
  46 {
  47         switch(it)
  48         {
  49                 case IT_SHELLS:      return ammo_shells;
  50                 case IT_NAILS:       return ammo_nails;
  51                 case IT_ROCKETS:     return ammo_rockets;
  52                 case IT_CELLS:       return ammo_cells;
  53                 case IT_FUEL:        return ammo_fuel;
  54                 case IT_5HP:         return health;
  55                 case IT_25HP:        return health;
  56                 case IT_HEALTH:      return health;
  57                 case IT_ARMOR_SHARD: return armorvalue;
  58                 case IT_ARMOR:       return armorvalue;
  59                 // add more things here (health, armor)
  60                 default:             error("requested item has no counter field");
  61         }
  62 }
  63
  64 string Item_CounterFieldName(float it)
  65 {
  66         switch(it)
  67         {
  68                 case IT_SHELLS:      return "shells";
  69                 case IT_NAILS:       return "nails";
  70                 case IT_ROCKETS:     return "rockets";
  71                 case IT_CELLS:       return "cells";
  72                 case IT_FUEL:        return "fuel";
  73
  74                 // add more things here (health, armor)
  75                 default:             error("requested item has no counter field name");
  76         }
  77 }
  78
  79 .float max_armorvalue;
  80 .float pickup_anyway;
  81
  82 float Item_Customize()
  83 {
  84         if(self.spawnshieldtime)
  85                 return TRUE;
  86         if(!WEPSET_CONTAINS_ALL_EE(other, self))
  87         {
  88                 self.colormod = '0 0 0';
  89                 self.glowmod = self.colormod;
  90                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
  91                 return TRUE;
  92         }
  93         else
  94         {
  95                 if(g_ghost_items)
  96                 {
  97                         self.colormod = stov(autocvar_g_ghost_items_color);
  98                         self.glowmod = self.colormod;
  99                         self.alpha = g_ghost_items;
 100                         return TRUE;
 101                 }
 102                 else
 103                         return FALSE;
 104         }
 105 }
 106
 107 void Item_Show (entity e, float mode)
 108 {
 109         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
 110         if (mode > 0)
 111         {
 112                 // make the item look normal, and be touchable
 113                 e.model = e.mdl;
 114                 e.solid = SOLID_TRIGGER;
 115                 e.colormod = '0 0 0';
 116                 self.glowmod = self.colormod;
 117                 e.alpha = 0;
 118                 e.customizeentityforclient = func_null;
 119
 120                 e.spawnshieldtime = 1;
 121         }
 122         else if (mode < 0)
 123         {
 124                 // hide the item completely
 125                 e.model = string_null;
 126                 e.solid = SOLID_NOT;
 127                 e.colormod = '0 0 0';
 128                 self.glowmod = self.colormod;
 129                 e.alpha = 0;
 130                 e.customizeentityforclient = func_null;
 131
 132                 e.spawnshieldtime = 1;
 133         }
 134         else if((e.flags & FL_WEAPON) && !(e.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 135         {
 136                 // make the item translucent and not touchable
 137                 e.model = e.mdl;
 138                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 139                 e.colormod = '0 0 0';
 140                 self.glowmod = self.colormod;
 141                 e.effects |= EF_STARDUST;
 142                 e.customizeentityforclient = Item_Customize;
 143
 144                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 145         }
 146         else if(g_ghost_items)
 147         {
 148                 // make the item translucent and not touchable
 149                 e.model = e.mdl;
 150                 e.solid = SOLID_NOT;
 151                 e.colormod = stov(autocvar_g_ghost_items_color);
 152                 e.glowmod = e.colormod;
 153                 e.alpha = g_ghost_items;
 154                 e.customizeentityforclient = func_null;
 155
 156                 e.spawnshieldtime = 1;
 157         }
 158         else
 159         {
 160                 // hide the item completely
 161                 e.model = string_null;
 162                 e.solid = SOLID_NOT;
 163                 e.colormod = '0 0 0';
 164                 e.glowmod = e.colormod;
 165                 e.alpha = 0;
 166                 e.customizeentityforclient = func_null;
 167
 168                 e.spawnshieldtime = 1;
 169         }
 170
 171         if (e.items & (IT_STRENGTH | IT_INVINCIBLE))
 172                 e.effects |= EF_ADDITIVE | EF_FULLBRIGHT;
 173         if (autocvar_g_nodepthtestitems)
 174                 e.effects |= EF_NODEPTHTEST;
 175         if (autocvar_g_fullbrightitems)
 176                 e.effects |= EF_FULLBRIGHT;
 177
 178         // relink entity (because solid may have changed)
 179         setorigin(e, e.origin);
 180 }
 181
 182 void Item_Respawn (void)
 183 {
 184         Item_Show(self, 1);
 185         if(!g_minstagib && self.items == IT_STRENGTH)
 186                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
 187         else if(!g_minstagib && self.items == IT_INVINCIBLE)
 188                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 189         else
 190                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);  // play respawn sound
 191         setorigin (self, self.origin);
 192
 193         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 194         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 195 }
 196
 197 void Item_RespawnCountdown (void)
 198 {
 199         if(self.count >= ITEM_RESPAWN_TICKS)
 200         {
 201                 if(self.waypointsprite_attached)
 202                         WaypointSprite_Kill(self.waypointsprite_attached);
 203                 Item_Respawn();
 204         }
 205         else
 206         {
 207                 self.nextthink = time + 1;
 208                 self.count += 1;
 209                 if(self.count == 1)
 210                 {
 211                         string name;
 212                         vector rgb;
 213                         name = string_null;
 214                         if(g_minstagib)
 215                         {
 216                                 switch(self.items)
 217                                 {
 218                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
 219                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
 220                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
 221                                 }
 222                         }
 223                         else
 224                         {
 225                                 switch(self.items)
 226                                 {
 227                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 228                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 229                                 }
 230                         }
 231                         switch(self.items)
 232                         {
 233                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 234                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 235                         }
 236                         if(self.flags & FL_WEAPON)
 237                         {
 238                                 entity wi = get_weaponinfo(self.weapon);
 239                                 if(wi)
 240                                 {
 241                                         name = wi.model2;
 242                                         rgb = '1 0 0';
 243                                 }
 244                         }
 245                         if(!name)
 246                         {
 247                                 print("Unknown powerup-marked item is wanting to respawn\n");
 248                                 localcmd(sprintf("prvm_edict server %d\n", num_for_edict(self)));
 249                         }
 250                         if(name)
 251                         {
 252                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
 253                                 if(self.waypointsprite_attached)
 254                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 255                         }
 256                 }
 257                 sound (self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM); // play respawn sound
 258                 if(self.waypointsprite_attached)
 259                 {
 260                         WaypointSprite_Ping(self.waypointsprite_attached);
 261                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 262                 }
 263         }
 264 }
 265
 266 void Item_ScheduleRespawnIn(entity e, float t)
 267 {
 268         if((e.flags & FL_POWERUP) || WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
 269         {
 270                 e.think = Item_RespawnCountdown;
 271                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 272                 e.count = 0;
 273         }
 274         else
 275         {
 276                 e.think = Item_Respawn;
 277                 e.nextthink = time + t;
 278         }
 279 }
 280
 281 void Item_ScheduleRespawn(entity e)
 282 {
 283         if(e.respawntime > 0)
 284         {
 285                 Item_Show(e, 0);
 286                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 287         }
 288         else // if respawntime is -1, this item does not respawn
 289                 Item_Show(e, -1);
 290 }
 291
 292 void Item_ScheduleInitialRespawn(entity e)
 293 {
 294         Item_Show(e, 0);
 295         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 296 }
 297
 298 float ITEM_MODE_NONE = 0;
 299 float ITEM_MODE_HEALTH = 1;
 300 float ITEM_MODE_ARMOR = 2;
 301 float ITEM_MODE_FUEL = 3;
 302 float Item_GiveAmmoTo(entity item, entity player, .float ammofield, float ammomax, float mode)
 303 {
 304         if (!item.ammofield)
 305                 return FALSE;
 306
 307         if (item.spawnshieldtime)
 308         {
 309                 if ((player.ammofield < ammomax) || item.pickup_anyway)
 310                 {
 311                         player.ammofield = bound(player.ammofield, ammomax, player.ammofield + item.ammofield);
 312                         goto YEAH;
 313                 }
 314         }
 315         else if(g_weapon_stay == 2)
 316         {
 317                 float mi = min(item.ammofield, ammomax);
 318                 if (player.ammofield < mi)
 319                 {
 320                         player.ammofield = mi;
 321                         goto YEAH;
 322                 }
 323         }
 324
 325         return FALSE;
 326
 327 :YEAH
 328         switch(mode)
 329         {
 330                 case ITEM_MODE_FUEL:
 331                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 332                         break;
 333                 case ITEM_MODE_HEALTH:
 334                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 335                         break;
 336                 case ITEM_MODE_ARMOR:
 337                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 338                         break;
 339                 default:
 340                         break;
 341         }
 342         return TRUE;
 343 }
 344
 345 float Item_GiveTo(entity item, entity player)
 346 {
 347         float _switchweapon;
 348         float pickedup;
 349         float it;
 350         float i;
 351
 352         // if nothing happens to player, just return without taking the item
 353         pickedup = FALSE;
 354         _switchweapon = FALSE;
 355
 356         if (g_minstagib)
 357         {
 358                 float prevcells = player.ammo_cells;
 359
 360                 pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 361                 pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, 999, ITEM_MODE_NONE);
 362
 363                 if(player.ammo_cells > prevcells)
 364                 {
 365                         _switchweapon = TRUE;
 366
 367                         // play some cool sounds ;)
 368                         if (clienttype(player) == CLIENTTYPE_REAL)
 369                         {
 370                                 if(player.health <= 5)
 371                                         AnnounceTo(player, "lastsecond");
 372                                 else if(player.health < 50)
 373                                         AnnounceTo(player, "narrowly");
 374                         }
 375                         // sound not available
 376                         // else if(item.items == IT_CELLS)
 377                         //      AnnounceTo(player, "ammo");
 378
 379                         if (WEPSET_CONTAINS_EW(item, WEP_MINSTANEX))
 380                                 W_GiveWeapon (player, WEP_MINSTANEX, item.netname);
 381                         if (item.ammo_cells)
 382                                 player.ammo_cells = bound(player.ammo_cells, 999, player.ammo_cells + autocvar_g_minstagib_ammo_drop);
 383                         player.health = 100;
 384                 }
 385
 386                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 387                 {
 388                         pickedup = TRUE;
 389                         player.items |= it;
 390                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 391                 }
 392
 393                 // extralife powerup
 394                 if (item.max_health)
 395                 {
 396                         pickedup = TRUE;
 397                         // sound not available
 398                         // AnnounceTo(player, "_lives");
 399                         player.armorvalue = bound(player.armorvalue, 999, player.armorvalue + autocvar_g_minstagib_extralives);
 400                         sprint(player, "^3You picked up some extra lives\n");
 401                 }
 402
 403                 // invis powerup
 404                 if (item.strength_finished)
 405                 {
 406                         pickedup = TRUE;
 407                         // sound not available
 408                         // AnnounceTo(player, "invisible");
 409                         player.strength_finished = max(player.strength_finished, time) + autocvar_g_balance_powerup_strength_time;
 410                 }
 411
 412                 // speed powerup
 413                 if (item.invincible_finished)
 414                 {
 415                         pickedup = TRUE;
 416                         // sound not available
 417                         // AnnounceTo(player, "speed");
 418                         player.invincible_finished = max(player.invincible_finished, time) + autocvar_g_balance_powerup_strength_time;
 419                 }
 420         }
 421         else
 422         {
 423                 // in case the player has autoswitch enabled do the following:
 424                 // if the player is using their best weapon before items are given, they
 425                 // probably want to switch to an even better weapon after items are given
 426                 if (player.autoswitch)
 427                 if (player.switchweapon == w_getbestweapon(player))
 428                         _switchweapon = TRUE;
 429
 430                 if not(WEPSET_CONTAINS_EW(player, player.switchweapon))
 431                         _switchweapon = TRUE;
 432
 433                 pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 434                 pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 435                 pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 436                 pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 437                 pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 438                 pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 439                 pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 440
 441                 if (item.flags & FL_WEAPON)
 442                 {
 443                         WEPSET_DECLARE_A(it);
 444                         WEPSET_COPY_AE(it, item);
 445                         WEPSET_ANDNOT_AE(it, player);
 446
 447                         if (!WEPSET_EMPTY_A(it) || (item.spawnshieldtime && self.pickup_anyway))
 448                         {
 449                                 pickedup = TRUE;
 450                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 451                                 {
 452                                         if(WEPSET_CONTAINS_AW(it, i))
 453                                                 W_GiveWeapon (player, i, item.netname);
 454                                 }
 455                         }
 456                 }
 457
 458                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 459                 {
 460                         pickedup = TRUE;
 461                         player.items |= it;
 462                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 463                 }
 464
 465                 if (item.strength_finished)
 466                 {
 467                         pickedup = TRUE;
 468                         player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 469                 }
 470                 if (item.invincible_finished)
 471                 {
 472                         pickedup = TRUE;
 473                         player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 474                 }
 475                 if (item.superweapons_finished)
 476                 {
 477                         pickedup = TRUE;
 478                         player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 479                 }
 480         }
 481
 482 :skip
 483         // always eat teamed entities
 484         if(item.team)
 485                 pickedup = TRUE;
 486
 487         if (!pickedup)
 488                 return 0;
 489
 490         if (_switchweapon)
 491                 if (player.switchweapon != w_getbestweapon(player))
 492                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 493
 494         return 1;
 495 }
 496
 497 void Item_Touch (void)
 498 {
 499         entity e, head;
 500
 501         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 502         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
 503         {
 504                 remove(self);
 505                 return;
 506         }
 507         if (other.classname != "player")
 508                 return;
 509         if (other.deadflag)
 510                 return;
 511         if (self.solid != SOLID_TRIGGER)
 512                 return;
 513         if (self.owner == other)
 514                 return;
 515
 516         if (self.classname == "droppedweapon")
 517         {
 518                 self.strength_finished = max(0, self.strength_finished - time);
 519                 self.invincible_finished = max(0, self.invincible_finished - time);
 520                 self.superweapons_finished = max(0, self.superweapons_finished - time);
 521         }
 522
 523         if(!Item_GiveTo(self, other))
 524         {
 525                 if (self.classname == "droppedweapon")
 526                 {
 527                         // undo what we did above
 528                         self.strength_finished += time;
 529                         self.invincible_finished += time;
 530                         self.superweapons_finished += time;
 531                 }
 532                 return;
 533         }
 534
 535         other.last_pickup = time;
 536
 537         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 538         sound (other, CH_TRIGGER, self.item_pickupsound, VOL_BASE, ATTN_NORM);
 539
 540         if (self.classname == "droppedweapon")
 541                 remove (self);
 542         else if not(self.spawnshieldtime)
 543                 return;
 544         else
 545         {
 546                 if(self.team)
 547                 {
 548                         RandomSelection_Init();
 549                         for(head = world; (head = findfloat(head, team, self.team)); )
 550                         {
 551                                 if(head.flags & FL_ITEM)
 552                                 {
 553                                         Item_Show(head, -1);
 554                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 555                                 }
 556                         }
 557                         e = RandomSelection_chosen_ent;
 558                 }
 559                 else
 560                         e = self;
 561                 Item_ScheduleRespawn(e);
 562         }
 563 }
 564
 565 void Item_Reset()
 566 {
 567         Item_Show(self, !self.state);
 568         setorigin (self, self.origin);
 569
 570         if(self.classname != "droppedweapon")
 571         {
 572                 self.think = SUB_Null;
 573                 self.nextthink = 0;
 574
 575                 if(self.waypointsprite_attached)
 576                         WaypointSprite_Kill(self.waypointsprite_attached);
 577
 578                 if((self.flags & FL_POWERUP) | WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // do not spawn powerups initially!
 579                         Item_ScheduleInitialRespawn(self);
 580         }
 581 }
 582
 583 void Item_FindTeam()
 584 {
 585         entity head, e;
 586
 587         if(self.effects & EF_NODRAW)
 588         {
 589                 // marker for item team search
 590                 dprint("Initializing item team ", ftos(self.team), "\n");
 591                 RandomSelection_Init();
 592                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 593                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 594                 e = RandomSelection_chosen_ent;
 595                 e.state = 0;
 596                 Item_Show(e, 1);
 597
 598                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 599                 {
 600                         if(head != e)
 601                         {
 602                                 // make it a non-spawned item
 603                                 Item_Show(head, -1);
 604                                 head.state = 1; // state 1 = initially hidden item
 605                         }
 606                         head.effects &~= EF_NODRAW;
 607                 }
 608
 609                 Item_Reset();
 610         }
 611 }
 612
 613 // Savage: used for item garbage-collection
 614 // TODO: perhaps nice special effect?
 615 void RemoveItem(void)
 616 {
 617         remove(self);
 618 }
 619
 620 // pickup evaluation functions
 621 // these functions decide how desirable an item is to the bots
 622
 623 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 624
 625 float weapon_pickupevalfunc(entity player, entity item)
 626 {
 627         float c, j, position;
 628
 629         // See if I have it already
 630         if(!WEPSET_CONTAINS_ALL_EE(player, item))
 631         {
 632                 // If I can pick it up
 633                 if(!item.spawnshieldtime)
 634                         c = 0;
 635                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 636                 {
 637                         // Skilled bots will grab more
 638                         c = bound(0, skill / 10, 1) * 0.5;
 639                 }
 640                 else
 641                         c = 0;
 642         }
 643         else
 644                 c = 1;
 645
 646         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 647         if( bot_custom_weapon && c )
 648         {
 649                 // Find the highest position on any range
 650                 position = -1;
 651                 for(j = 0; j < WEP_LAST ; ++j){
 652                         if(
 653                                         bot_weapons_far[j] == item.weapon ||
 654                                         bot_weapons_mid[j] == item.weapon ||
 655                                         bot_weapons_close[j] == item.weapon
 656                           )
 657                         {
 658                                 position = j;
 659                                 break;
 660                         }
 661                 }
 662
 663                 // Rate it
 664                 if (position >= 0 )
 665                 {
 666                         position = WEP_LAST - position;
 667                         // item.bot_pickupbasevalue is overwritten here
 668                         return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 669                 }
 670         }
 671
 672         return item.bot_pickupbasevalue * c;
 673 }
 674
 675 float commodity_pickupevalfunc(entity player, entity item)
 676 {
 677         float c, i, need_shells, need_nails, need_rockets, need_cells, need_fuel;
 678         entity wi;
 679         c = 0;
 680
 681         // Detect needed ammo
 682         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 683         {
 684                 wi = get_weaponinfo(i);
 685
 686                 if not(WEPSET_CONTAINS_EW(player, i))
 687                         continue;
 688
 689                 if(wi.items & IT_SHELLS)
 690                         need_shells = TRUE;
 691                 else if(wi.items & IT_NAILS)
 692                         need_nails = TRUE;
 693                 else if(wi.items & IT_ROCKETS)
 694                         need_rockets = TRUE;
 695                 else if(wi.items & IT_CELLS)
 696                         need_cells = TRUE;
 697                 else if(wi.items & IT_FUEL)
 698                         need_cells = TRUE;
 699         }
 700
 701         // TODO: figure out if the player even has the weapon this ammo is for?
 702         // may not affect strategy much though...
 703         // find out how much more ammo/armor/health the player can hold
 704         if (need_shells)
 705         if (item.ammo_shells)
 706         if (player.ammo_shells < g_pickup_shells_max)
 707                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 708         if (need_nails)
 709         if (item.ammo_nails)
 710         if (player.ammo_nails < g_pickup_nails_max)
 711                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 712         if (need_rockets)
 713         if (item.ammo_rockets)
 714         if (player.ammo_rockets < g_pickup_rockets_max)
 715                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 716         if (need_cells)
 717         if (item.ammo_cells)
 718         if (player.ammo_cells < g_pickup_cells_max)
 719                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 720         if (need_fuel)
 721         if (item.ammo_fuel)
 722         if (player.ammo_fuel < g_pickup_fuel_max)
 723                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
 724         if (item.armorvalue)
 725         if (player.armorvalue < item.max_armorvalue)
 726                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 727         if (item.health)
 728         if (player.health < item.max_health)
 729                 c = c + max(0, 1 - player.health / item.max_health);
 730
 731         return item.bot_pickupbasevalue * c;
 732 }
 733
 734
 735 .float is_item;
 736 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 737 {
 738         startitem_failed = FALSE;
 739
 740         self.items = itemid;
 741         self.weapon = weaponid;
 742         if(weaponid)
 743                 WEPSET_COPY_EW(self, weaponid);
 744         self.flags = FL_ITEM | itemflags;
 745
 746         // is it a dropped weapon?
 747         if (self.classname == "droppedweapon")
 748         {
 749                 self.reset = SUB_Remove;
 750                 // it's a dropped weapon
 751                 self.movetype = MOVETYPE_TOSS;
 752
 753                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 754                 self.think = RemoveItem;
 755                 self.nextthink = time + 20;
 756
 757                 if(self.strength_finished || self.invincible_finished || self.superweapons_finished)
 758                 /*
 759                 if(self.items == 0)
 760                 if(WEPSET_CONTAINS_ALL_AE(WEPBIT_SUPERWEAPONS, self)) // only superweapons
 761                 if(self.ammo_nails == 0)
 762                 if(self.ammo_cells == 0)
 763                 if(self.ammo_rockets == 0)
 764                 if(self.ammo_shells == 0)
 765                 if(self.ammo_fuel == 0)
 766                 if(self.health == 0)
 767                 if(self.armorvalue == 0)
 768                 */
 769                 {
 770                         // if item is worthless after a timer, have it expire then
 771                         self.nextthink = max(self.strength_finished, self.invincible_finished, self.superweapons_finished);
 772                 }
 773
 774                 // don't drop if in a NODROP zone (such as lava)
 775                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 776                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 777                 {
 778                         startitem_failed = TRUE;
 779                         remove(self);
 780                         return;
 781                 }
 782         }
 783         else
 784         {
 785                 if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
 786                 {
 787                         startitem_failed = TRUE;
 788                         remove(self);
 789                         return;
 790                 }
 791
 792                 if(!have_pickup_item())
 793                 {
 794                         startitem_failed = TRUE;
 795                         remove (self);
 796                         return;
 797                 }
 798
 799                 if(self.model != "")
 800                         itemmodel = self.model;
 801                 if(self.item_pickupsound != "")
 802                         pickupsound = self.item_pickupsound;
 803
 804                 self.reset = Item_Reset;
 805                 // it's a level item
 806                 if(self.spawnflags & 1)
 807                         self.noalign = 1;
 808                 if (self.noalign)
 809                         self.movetype = MOVETYPE_NONE;
 810                 else
 811                         self.movetype = MOVETYPE_TOSS;
 812                 // do item filtering according to game mode and other things
 813                 if (!self.noalign)
 814                 {
 815                         // first nudge it off the floor a little bit to avoid math errors
 816                         setorigin(self, self.origin + '0 0 1');
 817                         // set item size before we spawn a spawnfunc_waypoint
 818                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 819                                 setsize (self, '-16 -16 0', '16 16 48');
 820                         else
 821                                 setsize (self, '-16 -16 0', '16 16 32');
 822                         // note droptofloor returns FALSE if stuck/or would fall too far
 823                         droptofloor();
 824                         waypoint_spawnforitem(self);
 825                 }
 826
 827                 /*
 828                  * can't do it that way, as it would break maps
 829                  * TODO make a target_give like entity another way, that perhaps has
 830                  * the weapon name in a key
 831                 if(self.targetname)
 832                 {
 833                         // target_give not yet supported; maybe later
 834                         print("removed targeted ", self.classname, "\n");
 835                         startitem_failed = TRUE;
 836                         remove (self);
 837                         return;
 838                 }
 839                 */
 840
 841                 if(autocvar_spawn_debug >= 2)
 842                 {
 843                         entity otheritem;
 844                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
 845                         {
 846                                 if(otheritem.is_item)
 847                                 {
 848                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 849                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 850                                         error("Mapper sucks.");
 851                                 }
 852                         }
 853                         self.is_item = TRUE;
 854                 }
 855
 856                 WEPSET_OR_AW(weaponsInMap, weaponid);
 857
 858                 precache_model (itemmodel);
 859                 precache_sound (pickupsound);
 860
 861                 precache_sound ("misc/itemrespawncountdown.wav");
 862                 if(!g_minstagib && itemid == IT_STRENGTH)
 863                         precache_sound ("misc/strength_respawn.wav");
 864                 else if(!g_minstagib && itemid == IT_INVINCIBLE)
 865                         precache_sound ("misc/shield_respawn.wav");
 866                 else
 867                         precache_sound ("misc/itemrespawn.wav");
 868
 869                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
 870                         self.target = "###item###"; // for finding the nearest item using find()
 871         }
 872
 873         self.bot_pickup = TRUE;
 874         self.bot_pickupevalfunc = pickupevalfunc;
 875         self.bot_pickupbasevalue = pickupbasevalue;
 876         self.mdl = itemmodel;
 877         self.item_pickupsound = pickupsound;
 878         // let mappers override respawntime
 879         if(!self.respawntime) // both set
 880         {
 881                 self.respawntime = defaultrespawntime;
 882                 self.respawntimejitter = defaultrespawntimejitter;
 883         }
 884         self.netname = itemname;
 885         self.touch = Item_Touch;
 886         setmodel (self, self.mdl); // precision set below
 887         self.effects |= EF_LOWPRECISION;
 888         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 889                 setsize (self, '-16 -16 0', '16 16 48');
 890         else
 891                 setsize (self, '-16 -16 0', '16 16 32');
 892         if(itemflags & FL_WEAPON)
 893                 self.modelflags |= MF_ROTATE;
 894
 895         if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
 896         if (itemflags & FL_WEAPON)
 897         {
 898                 // neutral team color for pickup weapons
 899                 self.colormap = 1024; // color shirt=0 pants=0 grey
 900         }
 901
 902         self.state = 0;
 903         if(self.team)
 904         {
 905                 if(!self.cnt)
 906                         self.cnt = 1; // item probability weight
 907                 self.effects = self.effects | EF_NODRAW; // marker for item team search
 908                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
 909         }
 910         else
 911                 Item_Reset();
 912 }
 913
 914 /* replace items in minstagib
 915  * IT_STRENGTH   = invisibility
 916  * IT_NAILS      = extra lives
 917  * IT_INVINCIBLE = speed
 918  */
 919 void minstagib_items (float itemid)
 920 {
 921         float rnd;
 922         self.classname = "minstagib";
 923
 924         // replace rocket launchers and nex guns with ammo cells
 925         if (itemid == IT_CELLS)
 926         {
 927                 self.ammo_cells = autocvar_g_minstagib_ammo_drop;
 928                 StartItem ("models/items/a_cells.md3",
 929                         "misc/itempickup.wav", 45, 0,
 930                         "MinstaNex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
 931                 return;
 932         }
 933
 934         // randomize
 935         rnd = random() * 3;
 936         if (rnd <= 1)
 937                 itemid = IT_STRENGTH;
 938         else if (rnd <= 2)
 939                 itemid = IT_NAILS;
 940         else
 941                 itemid = IT_INVINCIBLE;
 942
 943         // replace with invis
 944         if (itemid == IT_STRENGTH)
 945         {
 946                 if(!self.strength_finished)
 947                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
 948                 StartItem ("models/items/g_strength.md3",
 949                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 950                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 951         }
 952         // replace with extra lives
 953         if (itemid == IT_NAILS)
 954         {
 955                 self.max_health = 1;
 956                 StartItem ("models/items/g_h100.md3",
 957                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 958                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
 959         }
 960         // replace with speed
 961         if (itemid == IT_INVINCIBLE)
 962         {
 963                 if(!self.invincible_finished)
 964                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
 965                 StartItem ("models/items/g_invincible.md3",
 966                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 967                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 968         }
 969 }
 970
 971 float minst_no_auto_cells;
 972 void minst_remove_item (void) {
 973         if(minst_no_auto_cells)
 974                 remove(self);
 975 }
 976
 977 float weaponswapping;
 978 float internalteam;
 979
 980 void weapon_defaultspawnfunc(float wpn)
 981 {
 982         entity e;
 983         float t;
 984         var .float ammofield;
 985         string s;
 986         entity oldself;
 987         float i, j;
 988         float f;
 989
 990         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
 991         {
 992                 e = get_weaponinfo(wpn);
 993                 s = cvar_string(strcat("g_weaponreplace_", e.netname));
 994                 if(s == "0")
 995                 {
 996                         remove(self);
 997                         startitem_failed = TRUE;
 998                         return;
 999                 }
1000                 t = tokenize_console(s);
1001                 if(t >= 2)
1002                 {
1003                         self.team = --internalteam;
1004                         oldself = self;
1005                         for(i = 1; i < t; ++i)
1006                         {
1007                                 s = argv(i);
1008                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1009                                 {
1010                                         e = get_weaponinfo(j);
1011                                         if(e.netname == s)
1012                                         {
1013                                                 self = spawn();
1014                                                 copyentity(oldself, self);
1015                                                 self.classname = "replacedweapon";
1016                                                 weapon_defaultspawnfunc(j);
1017                                                 break;
1018                                         }
1019                                 }
1020                                 if(j > WEP_LAST)
1021                                 {
1022                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1023                                 }
1024                         }
1025                         self = oldself;
1026                 }
1027                 if(t >= 1)
1028                 {
1029                         s = argv(0);
1030                         wpn = 0;
1031                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1032                         {
1033                                 e = get_weaponinfo(j);
1034                                 if(e.netname == s)
1035                                 {
1036                                         wpn = j;
1037                                         break;
1038                                 }
1039                         }
1040                         if(j > WEP_LAST)
1041                         {
1042                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1043                         }
1044                 }
1045                 if(wpn == 0)
1046                 {
1047                         remove(self);
1048                         startitem_failed = TRUE;
1049                         return;
1050                 }
1051         }
1052
1053         e = get_weaponinfo(wpn);
1054
1055         if(!self.respawntime)
1056         {
1057                 if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1058                 {
1059                         self.respawntime = g_pickup_respawntime_superweapon;
1060                         self.respawntimejitter = g_pickup_respawntimejitter_superweapon;
1061                 }
1062                 else
1063                 {
1064                         self.respawntime = g_pickup_respawntime_weapon;
1065                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
1066                 }
1067         }
1068
1069         if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1070                 if(!self.superweapons_finished)
1071                         self.superweapons_finished = autocvar_g_balance_superweapons_time;
1072
1073         if(e.items)
1074         {
1075                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1076                 {
1077                         if(e.items & j)
1078                         {
1079                                 ammofield = Item_CounterField(j);
1080                                 if(!self.ammofield)
1081                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j), "_weapon"));
1082                         }
1083                 }
1084         }
1085
1086         // pickup anyway
1087         if(g_pickup_weapons_anyway)
1088                 self.pickup_anyway = TRUE;
1089
1090         f = FL_WEAPON;
1091
1092         // no weapon-stay on superweapons
1093         if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1094                 f |= FL_NO_WEAPON_STAY;
1095
1096         // weapon stay isn't supported for teamed weapons
1097         if(self.team)
1098                 f |= FL_NO_WEAPON_STAY;
1099
1100         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapon, f, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1101         if (self.modelindex) // don't precache if self was removed
1102                 weapon_action(e.weapon, WR_PRECACHE);
1103 }
1104
1105 void spawnfunc_weapon_shotgun (void);
1106 void spawnfunc_weapon_uzi (void) {
1107         if(autocvar_sv_q3acompat_machineshotgunswap)
1108         if(self.classname != "droppedweapon")
1109         {
1110                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1111                 return;
1112         }
1113         weapon_defaultspawnfunc(WEP_UZI);
1114 }
1115
1116 void spawnfunc_weapon_shotgun (void) {
1117         if(autocvar_sv_q3acompat_machineshotgunswap)
1118         if(self.classname != "droppedweapon")
1119         {
1120                 weapon_defaultspawnfunc(WEP_UZI);
1121                 return;
1122         }
1123         weapon_defaultspawnfunc(WEP_SHOTGUN);
1124 }
1125
1126 void spawnfunc_weapon_nex (void)
1127 {
1128         if (g_minstagib)
1129         {
1130                 minstagib_items(IT_CELLS);
1131                 self.think = minst_remove_item;
1132                 self.nextthink = time;
1133                 return;
1134         }
1135         weapon_defaultspawnfunc(WEP_NEX);
1136 }
1137
1138 void spawnfunc_weapon_minstanex (void)
1139 {
1140         if (g_minstagib)
1141         {
1142                 minstagib_items(IT_CELLS);
1143                 self.think = minst_remove_item;
1144                 self.nextthink = time;
1145                 return;
1146         }
1147         weapon_defaultspawnfunc(WEP_MINSTANEX);
1148 }
1149
1150 void spawnfunc_weapon_rocketlauncher (void)
1151 {
1152         if (g_minstagib)
1153         {
1154                 minstagib_items(IT_CELLS); // replace rocketlauncher with cells
1155                 self.think = minst_remove_item;
1156                 self.nextthink = time;
1157                 return;
1158         }
1159         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1160 }
1161
1162 void spawnfunc_item_rockets (void) {
1163         if(!self.ammo_rockets)
1164                 self.ammo_rockets = g_pickup_rockets;
1165         if(!self.pickup_anyway)
1166                 self.pickup_anyway = g_pickup_ammo_anyway;
1167         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1168 }
1169
1170 void spawnfunc_item_shells (void);
1171 void spawnfunc_item_bullets (void) {
1172         if(!weaponswapping)
1173         if(autocvar_sv_q3acompat_machineshotgunswap)
1174         if(self.classname != "droppedweapon")
1175         {
1176                 weaponswapping = TRUE;
1177                 spawnfunc_item_shells();
1178                 weaponswapping = FALSE;
1179                 return;
1180         }
1181
1182         if(!self.ammo_nails)
1183                 self.ammo_nails = g_pickup_nails;
1184         if(!self.pickup_anyway)
1185                 self.pickup_anyway = g_pickup_ammo_anyway;
1186         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1187 }
1188
1189 void spawnfunc_item_cells (void) {
1190         if(!self.ammo_cells)
1191                 self.ammo_cells = g_pickup_cells;
1192         if(!self.pickup_anyway)
1193                 self.pickup_anyway = g_pickup_ammo_anyway;
1194         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1195 }
1196
1197 void spawnfunc_item_shells (void) {
1198         if(!weaponswapping)
1199         if(autocvar_sv_q3acompat_machineshotgunswap)
1200         if(self.classname != "droppedweapon")
1201         {
1202                 weaponswapping = TRUE;
1203                 spawnfunc_item_bullets();
1204                 weaponswapping = FALSE;
1205                 return;
1206         }
1207
1208         if(!self.ammo_shells)
1209                 self.ammo_shells = g_pickup_shells;
1210         if(!self.pickup_anyway)
1211                 self.pickup_anyway = g_pickup_ammo_anyway;
1212         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1213 }
1214
1215 void spawnfunc_item_armor_small (void) {
1216         if(!self.armorvalue)
1217                 self.armorvalue = g_pickup_armorsmall;
1218         if(!self.max_armorvalue)
1219                 self.max_armorvalue = g_pickup_armorsmall_max;
1220         if(!self.pickup_anyway)
1221                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1222         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1223 }
1224
1225 void spawnfunc_item_armor_medium (void) {
1226         if(!self.armorvalue)
1227                 self.armorvalue = g_pickup_armormedium;
1228         if(!self.max_armorvalue)
1229                 self.max_armorvalue = g_pickup_armormedium_max;
1230         if(!self.pickup_anyway)
1231                 self.pickup_anyway = g_pickup_armormedium_anyway;
1232         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1233 }
1234
1235 void spawnfunc_item_armor_big (void) {
1236         if(!self.armorvalue)
1237                 self.armorvalue = g_pickup_armorbig;
1238         if(!self.max_armorvalue)
1239                 self.max_armorvalue = g_pickup_armorbig_max;
1240         if(!self.pickup_anyway)
1241                 self.pickup_anyway = g_pickup_armorbig_anyway;
1242         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1243 }
1244
1245 void spawnfunc_item_armor_large (void) {
1246         if(!self.armorvalue)
1247                 self.armorvalue = g_pickup_armorlarge;
1248         if(!self.max_armorvalue)
1249                 self.max_armorvalue = g_pickup_armorlarge_max;
1250         if(!self.pickup_anyway)
1251                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1252         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1253 }
1254
1255 void spawnfunc_item_health_small (void) {
1256         if(!self.max_health)
1257                 self.max_health = g_pickup_healthsmall_max;
1258         if(!self.health)
1259                 self.health = g_pickup_healthsmall;
1260         if(!self.pickup_anyway)
1261                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1262         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1263 }
1264
1265 void spawnfunc_item_health_medium (void) {
1266         if(!self.max_health)
1267                 self.max_health = g_pickup_healthmedium_max;
1268         if(!self.health)
1269                 self.health = g_pickup_healthmedium;
1270         if(!self.pickup_anyway)
1271                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1272         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1273 }
1274
1275 void spawnfunc_item_health_large (void) {
1276         if(!self.max_health)
1277                 self.max_health = g_pickup_healthlarge_max;
1278         if(!self.health)
1279                 self.health = g_pickup_healthlarge;
1280         if(!self.pickup_anyway)
1281                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1282         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1283 }
1284
1285 void spawnfunc_item_health_mega (void) {
1286         if(g_minstagib) {
1287                 minstagib_items(IT_NAILS);
1288         } else {
1289                 if(!self.max_health)
1290                         self.max_health = g_pickup_healthmega_max;
1291                 if(!self.health)
1292                         self.health = g_pickup_healthmega;
1293                 if(!self.pickup_anyway)
1294                         self.pickup_anyway = g_pickup_healthmega_anyway;
1295                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1296         }
1297 }
1298
1299 // support old misnamed entities
1300 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1301 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1302 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1303 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1304 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1305
1306 void spawnfunc_item_strength (void) {
1307         if(g_minstagib) {
1308                 minstagib_items(IT_STRENGTH);
1309         } else {
1310                 precache_sound("weapons/strength_fire.wav");
1311                 if(!self.strength_finished)
1312                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1313                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1314         }
1315 }
1316
1317 void spawnfunc_item_invincible (void) {
1318         if(g_minstagib) {
1319                 minstagib_items(IT_INVINCIBLE);
1320         } else {
1321                 if(!self.invincible_finished)
1322                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1323                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1324         }
1325 }
1326
1327 void spawnfunc_item_minst_cells (void) {
1328         if (g_minstagib)
1329         {
1330                 minst_no_auto_cells = 1;
1331                 minstagib_items(IT_CELLS);
1332         }
1333         else
1334                 remove(self);
1335 }
1336
1337 // compatibility:
1338 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1339
1340 float GiveItems(entity e, float beginarg, float endarg);
1341 void target_items_use (void)
1342 {
1343         if(activator.classname == "droppedweapon")
1344         {
1345                 EXACTTRIGGER_TOUCH;
1346                 remove(activator);
1347                 return;
1348         }
1349
1350         if(activator.classname != "player")
1351                 return;
1352         if(activator.deadflag != DEAD_NO)
1353                 return;
1354         EXACTTRIGGER_TOUCH;
1355
1356         entity e;
1357         for(e = world; (e = find(e, classname, "droppedweapon")); )
1358                 if(e.enemy == activator)
1359                         remove(e);
1360
1361         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1362                 centerprint(activator, self.message);
1363 }
1364
1365 void spawnfunc_target_items (void)
1366 {
1367         float n, i, j;
1368         entity e;
1369
1370         self.use = target_items_use;
1371         if(!self.strength_finished)
1372                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1373         if(!self.invincible_finished)
1374                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1375         if(!self.superweapons_finished)
1376                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1377
1378         precache_sound("misc/itempickup.wav");
1379         precache_sound("misc/megahealth.wav");
1380         precache_sound("misc/armor25.wav");
1381         precache_sound("misc/powerup.wav");
1382         precache_sound("misc/poweroff.wav");
1383         precache_sound("weapons/weaponpickup.wav");
1384
1385         n = tokenize_console(self.netname);
1386         if(argv(0) == "give")
1387         {
1388                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1389         }
1390         else
1391         {
1392                 for(i = 0; i < n; ++i)
1393                 {
1394                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1395                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1396                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1397                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1398                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1399                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1400                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1401                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1402                         else
1403                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1404                         {
1405                                 e = get_weaponinfo(j);
1406                                 if(argv(i) == e.netname)
1407                                 {
1408                                         WEPSET_OR_EW(self, j);
1409                                         if(self.spawnflags == 0 || self.spawnflags == 2)
1410                                                 weapon_action(e.weapon, WR_PRECACHE);
1411                                         break;
1412                                 }
1413                         }
1414                         if(j > WEP_LAST)
1415                                 print("target_items: invalid item ", argv(i), "\n");
1416                 }
1417
1418                 string itemprefix, valueprefix;
1419                 if(self.spawnflags == 0)
1420                 {
1421                         itemprefix = "";
1422                         valueprefix = "";
1423                 }
1424                 else if(self.spawnflags == 1)
1425                 {
1426                         itemprefix = "max ";
1427                         valueprefix = "max ";
1428                 }
1429                 else if(self.spawnflags == 2)
1430                 {
1431                         itemprefix = "min ";
1432                         valueprefix = "min ";
1433                 }
1434                 else if(self.spawnflags == 4)
1435                 {
1436                         itemprefix = "minus ";
1437                         valueprefix = "max ";
1438                 }
1439                 else
1440                         error("invalid spawnflags");
1441
1442                 self.netname = "";
1443                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1444                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1445                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1446                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1447                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * !!(self.items & IT_SUPERWEAPON), "superweapons");
1448                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1449                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1450                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1451                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1452                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1453                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1454                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1455                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1456                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1457                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1458                 {
1459                         e = get_weaponinfo(j);
1460                         if(e.weapon)
1461                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, WEPSET_CONTAINS_EW(self, j), e.netname);
1462                 }
1463         }
1464         self.netname = strzone(self.netname);
1465         //print(self.netname, "\n");
1466
1467         n = tokenize_console(self.netname);
1468         for(i = 0; i < n; ++i)
1469         {
1470                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1471                 {
1472                         e = get_weaponinfo(j);
1473                         if(argv(i) == e.netname)
1474                         {
1475                                 weapon_action(e.weapon, WR_PRECACHE);
1476                                 break;
1477                         }
1478                 }
1479         }
1480 }
1481
1482 void spawnfunc_item_fuel(void)
1483 {
1484         if(!self.ammo_fuel)
1485                 self.ammo_fuel = g_pickup_fuel;
1486         if(!self.pickup_anyway)
1487                 self.pickup_anyway = g_pickup_ammo_anyway;
1488         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1489 }
1490
1491 void spawnfunc_item_fuel_regen(void)
1492 {
1493         if(start_items & IT_FUEL_REGEN)
1494         {
1495                 spawnfunc_item_fuel();
1496                 return;
1497         }
1498         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1499 }
1500
1501 void spawnfunc_item_jetpack(void)
1502 {
1503         if(g_grappling_hook)
1504                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1505         if(!self.ammo_fuel)
1506                 self.ammo_fuel = g_pickup_fuel_jetpack;
1507         if(start_items & IT_JETPACK)
1508         {
1509                 spawnfunc_item_fuel();
1510                 return;
1511         }
1512         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1513 }
1514
1515
1516 #define OP_SET 0
1517 #define OP_MIN 1
1518 #define OP_MAX 2
1519 #define OP_PLUS 3
1520 #define OP_MINUS 4
1521
1522 float GiveBit(entity e, .float fld, float bit, float op, float val)
1523 {
1524         float v0, v1;
1525         v0 = (e.fld & bit);
1526         switch(op)
1527         {
1528                 case OP_SET:
1529                         if(val > 0)
1530                                 e.fld |= bit;
1531                         else
1532                                 e.fld &~= bit;
1533                         break;
1534                 case OP_MIN:
1535                 case OP_PLUS:
1536                         if(val > 0)
1537                                 e.fld |= bit;
1538                         break;
1539                 case OP_MAX:
1540                         if(val <= 0)
1541                                 e.fld &~= bit;
1542                         break;
1543                 case OP_MINUS:
1544                         if(val > 0)
1545                                 e.fld &~= bit;
1546                         break;
1547         }
1548         v1 = (e.fld & bit);
1549         return (v0 != v1);
1550 }
1551
1552 float GiveValue(entity e, .float fld, float op, float val)
1553 {
1554         float v0, v1;
1555         v0 = e.fld;
1556         switch(op)
1557         {
1558                 case OP_SET:
1559                         e.fld = val;
1560                         break;
1561                 case OP_MIN:
1562                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1563                         break;
1564                 case OP_MAX:
1565                         e.fld = min(e.fld, val);
1566                         break;
1567                 case OP_PLUS:
1568                         e.fld += val;
1569                         break;
1570                 case OP_MINUS:
1571                         e.fld -= val;
1572                         break;
1573         }
1574         v1 = e.fld;
1575         return (v0 != v1);
1576 }
1577
1578 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1579 {
1580         if(v1 == v0)
1581                 return;
1582         if(v1 <= v0 - t)
1583         {
1584                 if(snd_decr != "")
1585                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTN_NORM);
1586         }
1587         else if(v0 >= v0 + t)
1588         {
1589                 if(snd_incr != "")
1590                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTN_NORM);
1591         }
1592 }
1593
1594 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1595 {
1596         if(v0 < v1)
1597                 e.rotfield = max(e.rotfield, time + rottime);
1598         else if(v0 > v1)
1599                 e.regenfield = max(e.regenfield, time + regentime);
1600 }
1601
1602 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1603 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1604 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1605 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1606
1607 float GiveItems(entity e, float beginarg, float endarg)
1608 {
1609         float got, i, j, val, op;
1610         float _switchweapon;
1611         entity wi;
1612         string cmd;
1613
1614         val = 999;
1615         op = OP_SET;
1616
1617         got = 0;
1618
1619         _switchweapon = FALSE;
1620         if (e.autoswitch)
1621                 if (e.switchweapon == w_getbestweapon(e))
1622                         _switchweapon = TRUE;
1623
1624         e.strength_finished = max(0, e.strength_finished - time);
1625         e.invincible_finished = max(0, e.invincible_finished - time);
1626         e.superweapons_finished = max(0, e.superweapons_finished - time);
1627
1628         PREGIVE(e, items);
1629         PREGIVE(e, weapons);
1630         PREGIVE(e, strength_finished);
1631         PREGIVE(e, invincible_finished);
1632         PREGIVE(e, superweapons_finished);
1633         PREGIVE(e, ammo_nails);
1634         PREGIVE(e, ammo_cells);
1635         PREGIVE(e, ammo_shells);
1636         PREGIVE(e, ammo_rockets);
1637         PREGIVE(e, ammo_fuel);
1638         PREGIVE(e, armorvalue);
1639         PREGIVE(e, health);
1640
1641         for(i = beginarg; i < endarg; ++i)
1642         {
1643                 cmd = argv(i);
1644
1645                 if(cmd == "0" || stof(cmd))
1646                 {
1647                         val = stof(cmd);
1648                         continue;
1649                 }
1650                 switch(cmd)
1651                 {
1652                         case "no":
1653                                 op = OP_MAX;
1654                                 val = 0;
1655                                 continue;
1656                         case "max":
1657                                 op = OP_MAX;
1658                                 continue;
1659                         case "min":
1660                                 op = OP_MIN;
1661                                 continue;
1662                         case "plus":
1663                                 op = OP_PLUS;
1664                                 continue;
1665                         case "minus":
1666                                 op = OP_MINUS;
1667                                 continue;
1668                         case "ALL":
1669                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1670                                 got += GiveValue(e, strength_finished, op, val);
1671                                 got += GiveValue(e, invincible_finished, op, val);
1672                                 got += GiveValue(e, superweapons_finished, op, val);
1673                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1674                         case "all":
1675                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1676                                 got += GiveValue(e, health, op, val);
1677                                 got += GiveValue(e, armorvalue, op, val);
1678                         case "allweapons":
1679                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1680                                 {
1681                                         wi = get_weaponinfo(j);
1682                                         if(wi.weapon)
1683                                                 got += GiveBit(e, weapons, wi.weapons, op, val); // FIXME
1684                                 }
1685                         case "allammo":
1686                                 got += GiveValue(e, ammo_cells, op, val);
1687                                 got += GiveValue(e, ammo_shells, op, val);
1688                                 got += GiveValue(e, ammo_nails, op, val);
1689                                 got += GiveValue(e, ammo_rockets, op, val);
1690                                 got += GiveValue(e, ammo_fuel, op, val);
1691                                 break;
1692                         case "unlimited_ammo":
1693                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1694                                 break;
1695                         case "unlimited_weapon_ammo":
1696                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1697                                 break;
1698                         case "unlimited_superweapons":
1699                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1700                                 break;
1701                         case "jetpack":
1702                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1703                                 break;
1704                         case "fuel_regen":
1705                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1706                                 break;
1707                         case "strength":
1708                                 got += GiveValue(e, strength_finished, op, val);
1709                                 break;
1710                         case "invincible":
1711                                 got += GiveValue(e, invincible_finished, op, val);
1712                                 break;
1713                         case "superweapons":
1714                                 got += GiveValue(e, superweapons_finished, op, val);
1715                                 break;
1716                         case "cells":
1717                                 got += GiveValue(e, ammo_cells, op, val);
1718                                 break;
1719                         case "shells":
1720                                 got += GiveValue(e, ammo_shells, op, val);
1721                                 break;
1722                         case "nails":
1723                         case "bullets":
1724                                 got += GiveValue(e, ammo_nails, op, val);
1725                                 break;
1726                         case "rockets":
1727                                 got += GiveValue(e, ammo_rockets, op, val);
1728                                 break;
1729                         case "health":
1730                                 got += GiveValue(e, health, op, val);
1731                                 break;
1732                         case "armor":
1733                                 got += GiveValue(e, armorvalue, op, val);
1734                                 break;
1735                         case "fuel":
1736                                 got += GiveValue(e, ammo_fuel, op, val);
1737                                 break;
1738                         default:
1739                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1740                                 {
1741                                         wi = get_weaponinfo(j);
1742                                         if(cmd == wi.netname)
1743                                         {
1744                                                 got += GiveBit(e, weapons, wi.weapons, op, val); // FIXME
1745                                                 break;
1746                                         }
1747                                 }
1748                                 if(j > WEP_LAST)
1749                                         print("give: invalid item ", cmd, "\n");
1750                                 break;
1751                 }
1752                 val = 999;
1753                 op = OP_SET;
1754         }
1755
1756         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1757         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1758         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1759         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1760         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1761         {
1762                 wi = get_weaponinfo(j);
1763                 if(wi.weapon)
1764                 {
1765                         POSTGIVE_BIT(e, weapons, wi.weapons, "weapons/weaponpickup.wav", string_null); // FIXME
1766 #define _WS_save_weapons save_weapons
1767                         if not(WEPSET_CONTAINS_AW(save_weapons, j)) // FIXME
1768                                 if(WEPSET_CONTAINS_EW(e, j))
1769                                         weapon_action(wi.weapon, WR_PRECACHE);
1770                 }
1771         }
1772         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1773         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1774         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1775         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1776         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1777         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1778         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
1779         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
1780         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
1781
1782         if(e.superweapons_finished <= 0)
1783                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1784                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1785
1786         if (g_minstagib)
1787         {
1788                 e.health = bound(0, e.health, 100);
1789                 e.armorvalue = bound(0, e.armorvalue, 999);
1790         }
1791
1792         if(e.strength_finished <= 0)
1793                 e.strength_finished = 0;
1794         else
1795                 e.strength_finished += time;
1796         if(e.invincible_finished <= 0)
1797                 e.invincible_finished = 0;
1798         else
1799                 e.invincible_finished += time;
1800         if(e.superweapons_finished <= 0)
1801                 e.superweapons_finished = 0;
1802         else
1803                 e.superweapons_finished += time;
1804
1805         if not(WEPSET_CONTAINS_EW(e, e.switchweapon))
1806                 _switchweapon = TRUE;
1807         if(_switchweapon)
1808                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1809
1810         return got;
1811 }