qcsrc/server/t_items.qc

   1 float have_pickup_item(void)
   2 {
   3         // minstagib: only allow filtered items
   4         if(g_minstagib)
   5                 if(self.classname != "minstagib")
   6                         return FALSE;
   7
   8         if(self.flags & FL_POWERUP)
   9         {
  10                 if(autocvar_g_powerups > 0)
  11                         return TRUE;
  12                 if(autocvar_g_powerups == 0)
  13                         return FALSE;
  14                 if(g_lms)
  15                         return FALSE;
  16                 if(g_ca)
  17                         return FALSE;
  18                 if(g_arena)
  19                         return FALSE;
  20         }
  21         else
  22         {
  23                 if(autocvar_g_pickup_items > 0)
  24                         return TRUE;
  25                 if(autocvar_g_pickup_items == 0)
  26                         return FALSE;
  27                 if(g_lms)
  28                         return FALSE;
  29                 if(g_ca)
  30                         return FALSE;
  31                 if(g_weaponarena)
  32                         if(!WEPSET_EMPTY_E(self) || (self.items & IT_AMMO))
  33                                 return FALSE;
  34         }
  35         return TRUE;
  36 }
  37
  38 #define ITEM_RESPAWN_TICKS 10
  39
  40 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
  41         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
  42 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
  43         // range: 10 .. respawntime + respawntimejitter
  44
  45 floatfield Item_CounterField(float it)
  46 {
  47         switch(it)
  48         {
  49                 case IT_SHELLS:      return ammo_shells;
  50                 case IT_NAILS:       return ammo_nails;
  51                 case IT_ROCKETS:     return ammo_rockets;
  52                 case IT_CELLS:       return ammo_cells;
  53                 case IT_FUEL:        return ammo_fuel;
  54                 case IT_5HP:         return health;
  55                 case IT_25HP:        return health;
  56                 case IT_HEALTH:      return health;
  57                 case IT_ARMOR_SHARD: return armorvalue;
  58                 case IT_ARMOR:       return armorvalue;
  59                 // add more things here (health, armor)
  60                 default:             error("requested item has no counter field");
  61         }
  62 }
  63
  64 string Item_CounterFieldName(float it)
  65 {
  66         switch(it)
  67         {
  68                 case IT_SHELLS:      return "shells";
  69                 case IT_NAILS:       return "nails";
  70                 case IT_ROCKETS:     return "rockets";
  71                 case IT_CELLS:       return "cells";
  72                 case IT_FUEL:        return "fuel";
  73
  74                 // add more things here (health, armor)
  75                 default:             error("requested item has no counter field name");
  76         }
  77 }
  78
  79 .float max_armorvalue;
  80 .float pickup_anyway;
  81
  82 float Item_Customize()
  83 {
  84         if(self.spawnshieldtime)
  85                 return TRUE;
  86         if(!WEPSET_CONTAINS_ALL_EE(other, self))
  87         {
  88                 self.colormod = '0 0 0';
  89                 self.glowmod = self.colormod;
  90                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
  91                 return TRUE;
  92         }
  93         else
  94         {
  95                 if(g_ghost_items)
  96                 {
  97                         self.colormod = stov(autocvar_g_ghost_items_color);
  98                         self.glowmod = self.colormod;
  99                         self.alpha = g_ghost_items;
 100                         return TRUE;
 101                 }
 102                 else
 103                         return FALSE;
 104         }
 105 }
 106
 107 void Item_Show (entity e, float mode)
 108 {
 109         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
 110         if (mode > 0)
 111         {
 112                 // make the item look normal, and be touchable
 113                 e.model = e.mdl;
 114                 e.solid = SOLID_TRIGGER;
 115                 e.colormod = '0 0 0';
 116                 self.glowmod = self.colormod;
 117                 e.alpha = 0;
 118                 e.customizeentityforclient = func_null;
 119
 120                 e.spawnshieldtime = 1;
 121         }
 122         else if (mode < 0)
 123         {
 124                 // hide the item completely
 125                 e.model = string_null;
 126                 e.solid = SOLID_NOT;
 127                 e.colormod = '0 0 0';
 128                 self.glowmod = self.colormod;
 129                 e.alpha = 0;
 130                 e.customizeentityforclient = func_null;
 131
 132                 e.spawnshieldtime = 1;
 133         }
 134         else if((e.flags & FL_WEAPON) && !(e.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 135         {
 136                 // make the item translucent and not touchable
 137                 e.model = e.mdl;
 138                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 139                 e.colormod = '0 0 0';
 140                 self.glowmod = self.colormod;
 141                 e.effects |= EF_STARDUST;
 142                 e.customizeentityforclient = Item_Customize;
 143
 144                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 145         }
 146         else if(g_ghost_items)
 147         {
 148                 // make the item translucent and not touchable
 149                 e.model = e.mdl;
 150                 e.solid = SOLID_NOT;
 151                 e.colormod = stov(autocvar_g_ghost_items_color);
 152                 e.glowmod = e.colormod;
 153                 e.alpha = g_ghost_items;
 154                 e.customizeentityforclient = func_null;
 155
 156                 e.spawnshieldtime = 1;
 157         }
 158         else
 159         {
 160                 // hide the item completely
 161                 e.model = string_null;
 162                 e.solid = SOLID_NOT;
 163                 e.colormod = '0 0 0';
 164                 e.glowmod = e.colormod;
 165                 e.alpha = 0;
 166                 e.customizeentityforclient = func_null;
 167
 168                 e.spawnshieldtime = 1;
 169         }
 170
 171         if (e.items & (IT_STRENGTH | IT_INVINCIBLE))
 172                 e.effects |= EF_ADDITIVE | EF_FULLBRIGHT;
 173         if (autocvar_g_nodepthtestitems)
 174                 e.effects |= EF_NODEPTHTEST;
 175         if (autocvar_g_fullbrightitems)
 176                 e.effects |= EF_FULLBRIGHT;
 177
 178         // relink entity (because solid may have changed)
 179         setorigin(e, e.origin);
 180 }
 181
 182 void Item_Respawn (void)
 183 {
 184         Item_Show(self, 1);
 185         if(!g_minstagib && self.items == IT_STRENGTH)
 186                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
 187         else if(!g_minstagib && self.items == IT_INVINCIBLE)
 188                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 189         else
 190                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);  // play respawn sound
 191         setorigin (self, self.origin);
 192
 193         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 194         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 195 }
 196
 197 void Item_RespawnCountdown (void)
 198 {
 199         if(self.count >= ITEM_RESPAWN_TICKS)
 200         {
 201                 if(self.waypointsprite_attached)
 202                         WaypointSprite_Kill(self.waypointsprite_attached);
 203                 Item_Respawn();
 204         }
 205         else
 206         {
 207                 self.nextthink = time + 1;
 208                 self.count += 1;
 209                 if(self.count == 1)
 210                 {
 211                         string name;
 212                         vector rgb = '1 0 1';
 213                         name = string_null;
 214                         if(g_minstagib)
 215                         {
 216                                 switch(self.items)
 217                                 {
 218                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
 219                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
 220                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
 221                                 }
 222                         }
 223                         else
 224                         {
 225                                 switch(self.items)
 226                                 {
 227                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 228                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 229                                 }
 230                         }
 231                         switch(self.items)
 232                         {
 233                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 234                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 235                         }
 236                         if(self.flags & FL_WEAPON)
 237                         {
 238                                 entity wi = get_weaponinfo(self.weapon);
 239                                 if(wi)
 240                                 {
 241                                         name = wi.model2;
 242                                         rgb = '1 0 0';
 243                                 }
 244                         }
 245                         if(!name)
 246                         {
 247                                 print("Unknown powerup-marked item is wanting to respawn\n");
 248                                 localcmd(sprintf("prvm_edict server %d\n", num_for_edict(self)));
 249                         }
 250                         if(name)
 251                         {
 252                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
 253                                 if(self.waypointsprite_attached)
 254                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 255                         }
 256                 }
 257                 sound (self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM); // play respawn sound
 258                 if(self.waypointsprite_attached)
 259                 {
 260                         WaypointSprite_Ping(self.waypointsprite_attached);
 261                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 262                 }
 263         }
 264 }
 265
 266 void Item_ScheduleRespawnIn(entity e, float t)
 267 {
 268         if((e.flags & FL_POWERUP) || WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
 269         {
 270                 e.think = Item_RespawnCountdown;
 271                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 272                 e.count = 0;
 273         }
 274         else
 275         {
 276                 e.think = Item_Respawn;
 277                 e.nextthink = time + t;
 278         }
 279 }
 280
 281 void Item_ScheduleRespawn(entity e)
 282 {
 283         if(e.respawntime > 0)
 284         {
 285                 Item_Show(e, 0);
 286                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 287         }
 288         else // if respawntime is -1, this item does not respawn
 289                 Item_Show(e, -1);
 290 }
 291
 292 void Item_ScheduleInitialRespawn(entity e)
 293 {
 294         Item_Show(e, 0);
 295         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 296 }
 297
 298 float ITEM_MODE_NONE = 0;
 299 float ITEM_MODE_HEALTH = 1;
 300 float ITEM_MODE_ARMOR = 2;
 301 float ITEM_MODE_FUEL = 3;
 302 float Item_GiveAmmoTo(entity item, entity player, .float ammofield, float ammomax, float mode)
 303 {
 304         if (!item.ammofield)
 305                 return FALSE;
 306
 307         if (item.spawnshieldtime)
 308         {
 309                 if ((player.ammofield < ammomax) || item.pickup_anyway)
 310                 {
 311                         player.ammofield = bound(player.ammofield, ammomax, player.ammofield + item.ammofield);
 312                         goto YEAH;
 313                 }
 314         }
 315         else if(g_weapon_stay == 2)
 316         {
 317                 float mi = min(item.ammofield, ammomax);
 318                 if (player.ammofield < mi)
 319                 {
 320                         player.ammofield = mi;
 321                         goto YEAH;
 322                 }
 323         }
 324
 325         return FALSE;
 326
 327 :YEAH
 328         switch(mode)
 329         {
 330                 case ITEM_MODE_FUEL:
 331                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 332                         break;
 333                 case ITEM_MODE_HEALTH:
 334                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 335                         break;
 336                 case ITEM_MODE_ARMOR:
 337                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 338                         break;
 339                 default:
 340                         break;
 341         }
 342         return TRUE;
 343 }
 344
 345 float Item_GiveTo(entity item, entity player)
 346 {
 347         float _switchweapon;
 348         float pickedup;
 349         float it;
 350         float i;
 351
 352         // if nothing happens to player, just return without taking the item
 353         pickedup = FALSE;
 354         _switchweapon = FALSE;
 355
 356         if (g_minstagib)
 357         {
 358                 float prevcells = player.ammo_cells;
 359
 360                 pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 361                 pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, 999, ITEM_MODE_NONE);
 362
 363                 if(player.ammo_cells > prevcells)
 364                 {
 365                         _switchweapon = TRUE;
 366
 367                         // play some cool sounds ;)
 368                         if (clienttype(player) == CLIENTTYPE_REAL)
 369                         {
 370                                 if(player.health <= 5)
 371                                         AnnounceTo(player, "lastsecond");
 372                                 else if(player.health < 50)
 373                                         AnnounceTo(player, "narrowly");
 374                         }
 375                         // sound not available
 376                         // else if(item.items == IT_CELLS)
 377                         //      AnnounceTo(player, "ammo");
 378
 379                         if (WEPSET_CONTAINS_EW(item, WEP_MINSTANEX))
 380                                 W_GiveWeapon (player, WEP_MINSTANEX, item.netname);
 381                         player.health = 100;
 382                 }
 383
 384                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 385                 {
 386                         pickedup = TRUE;
 387                         player.items |= it;
 388                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 389                 }
 390
 391                 // extralife powerup
 392                 if (item.max_health)
 393                 {
 394                         pickedup = TRUE;
 395                         // sound not available
 396                         // AnnounceTo(player, "_lives");
 397                         player.armorvalue = bound(player.armorvalue, 999, player.armorvalue + autocvar_g_minstagib_extralives);
 398                         sprint(player, "^3You picked up some extra lives\n");
 399                 }
 400
 401                 // invis powerup
 402                 if (item.strength_finished)
 403                 {
 404                         pickedup = TRUE;
 405                         // sound not available
 406                         // AnnounceTo(player, "invisible");
 407                         player.strength_finished = max(player.strength_finished, time) + autocvar_g_balance_powerup_strength_time;
 408                 }
 409
 410                 // speed powerup
 411                 if (item.invincible_finished)
 412                 {
 413                         pickedup = TRUE;
 414                         // sound not available
 415                         // AnnounceTo(player, "speed");
 416                         player.invincible_finished = max(player.invincible_finished, time) + autocvar_g_balance_powerup_strength_time;
 417                 }
 418         }
 419         else
 420         {
 421                 // in case the player has autoswitch enabled do the following:
 422                 // if the player is using their best weapon before items are given, they
 423                 // probably want to switch to an even better weapon after items are given
 424                 if (player.autoswitch)
 425                 if (player.switchweapon == w_getbestweapon(player))
 426                         _switchweapon = TRUE;
 427
 428                 if not(WEPSET_CONTAINS_EW(player, player.switchweapon))
 429                         _switchweapon = TRUE;
 430
 431                 pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 432                 pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 433                 pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 434                 pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 435                 pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 436                 pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 437                 pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 438
 439                 if (item.flags & FL_WEAPON)
 440                 {
 441                         WEPSET_DECLARE_A(it);
 442                         WEPSET_COPY_AE(it, item);
 443                         WEPSET_ANDNOT_AE(it, player);
 444
 445                         if (!WEPSET_EMPTY_A(it) || (item.spawnshieldtime && self.pickup_anyway))
 446                         {
 447                                 pickedup = TRUE;
 448                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 449                                         if(WEPSET_CONTAINS_AW(it, i))
 450                                                 W_GiveWeapon (player, i, item.netname);
 451                         }
 452                 }
 453
 454                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 455                 {
 456                         pickedup = TRUE;
 457                         player.items |= it;
 458                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 459                 }
 460
 461                 if (item.strength_finished)
 462                 {
 463                         pickedup = TRUE;
 464                         player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 465                 }
 466                 if (item.invincible_finished)
 467                 {
 468                         pickedup = TRUE;
 469                         player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 470                 }
 471                 if (item.superweapons_finished)
 472                 {
 473                         pickedup = TRUE;
 474                         player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 475                 }
 476         }
 477
 478 :skip
 479         // always eat teamed entities
 480         if(item.team)
 481                 pickedup = TRUE;
 482
 483         if (!pickedup)
 484                 return 0;
 485
 486         if (_switchweapon)
 487                 if (player.switchweapon != w_getbestweapon(player))
 488                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 489
 490         return 1;
 491 }
 492
 493 void Item_Touch (void)
 494 {
 495         entity e, head;
 496
 497         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 498         if(self.classname == "droppedweapon")
 499         {
 500                 if (ITEM_TOUCH_NEEDKILL())
 501                 {
 502                         remove(self);
 503                         return;
 504                 }
 505         }
 506
 507         if (other.classname != "player")
 508                 return;
 509         if (other.deadflag)
 510                 return;
 511         if (self.solid != SOLID_TRIGGER)
 512                 return;
 513         if (self.owner == other)
 514                 return;
 515
 516         if (self.classname == "droppedweapon")
 517         {
 518                 self.strength_finished = max(0, self.strength_finished - time);
 519                 self.invincible_finished = max(0, self.invincible_finished - time);
 520                 self.superweapons_finished = max(0, self.superweapons_finished - time);
 521         }
 522
 523         if(!Item_GiveTo(self, other))
 524         {
 525                 if (self.classname == "droppedweapon")
 526                 {
 527                         // undo what we did above
 528                         self.strength_finished += time;
 529                         self.invincible_finished += time;
 530                         self.superweapons_finished += time;
 531                 }
 532                 return;
 533         }
 534
 535         other.last_pickup = time;
 536
 537         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 538         sound (other, CH_TRIGGER, self.item_pickupsound, VOL_BASE, ATTN_NORM);
 539
 540         if (self.classname == "droppedweapon")
 541                 remove (self);
 542         else if not(self.spawnshieldtime)
 543                 return;
 544         else
 545         {
 546                 if(self.team)
 547                 {
 548                         RandomSelection_Init();
 549                         for(head = world; (head = findfloat(head, team, self.team)); )
 550                         {
 551                                 if(head.flags & FL_ITEM)
 552                                 {
 553                                         Item_Show(head, -1);
 554                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 555                                 }
 556                         }
 557                         e = RandomSelection_chosen_ent;
 558                 }
 559                 else
 560                         e = self;
 561                 Item_ScheduleRespawn(e);
 562         }
 563 }
 564
 565 void Item_Reset()
 566 {
 567         Item_Show(self, !self.state);
 568         setorigin (self, self.origin);
 569
 570         if(self.classname != "droppedweapon")
 571         {
 572                 self.think = SUB_Null;
 573                 self.nextthink = 0;
 574
 575                 if(self.waypointsprite_attached)
 576                         WaypointSprite_Kill(self.waypointsprite_attached);
 577
 578                 if((self.flags & FL_POWERUP) | WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // do not spawn powerups initially!
 579                         Item_ScheduleInitialRespawn(self);
 580         }
 581 }
 582
 583 void Item_FindTeam()
 584 {
 585         entity head, e;
 586
 587         if(self.effects & EF_NODRAW)
 588         {
 589                 // marker for item team search
 590                 dprint("Initializing item team ", ftos(self.team), "\n");
 591                 RandomSelection_Init();
 592                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 593                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 594                 e = RandomSelection_chosen_ent;
 595                 e.state = 0;
 596                 Item_Show(e, 1);
 597
 598                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 599                 {
 600                         if(head != e)
 601                         {
 602                                 // make it a non-spawned item
 603                                 Item_Show(head, -1);
 604                                 head.state = 1; // state 1 = initially hidden item
 605                         }
 606                         head.effects &~= EF_NODRAW;
 607                 }
 608
 609                 Item_Reset();
 610         }
 611 }
 612
 613 // Savage: used for item garbage-collection
 614 // TODO: perhaps nice special effect?
 615 void RemoveItem(void)
 616 {
 617         remove(self);
 618 }
 619
 620 // pickup evaluation functions
 621 // these functions decide how desirable an item is to the bots
 622
 623 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 624
 625 float weapon_pickupevalfunc(entity player, entity item)
 626 {
 627         float c, j, position;
 628
 629         // See if I have it already
 630         if(!WEPSET_CONTAINS_ALL_EE(player, item))
 631         {
 632                 // If I can pick it up
 633                 if(!item.spawnshieldtime)
 634                         c = 0;
 635                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 636                 {
 637                         // Skilled bots will grab more
 638                         c = bound(0, skill / 10, 1) * 0.5;
 639                 }
 640                 else
 641                         c = 0;
 642         }
 643         else
 644                 c = 1;
 645
 646         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 647         if( bot_custom_weapon && c )
 648         {
 649                 // Find the highest position on any range
 650                 position = -1;
 651                 for(j = 0; j < WEP_LAST ; ++j){
 652                         if(
 653                                         bot_weapons_far[j] == item.weapon ||
 654                                         bot_weapons_mid[j] == item.weapon ||
 655                                         bot_weapons_close[j] == item.weapon
 656                           )
 657                         {
 658                                 position = j;
 659                                 break;
 660                         }
 661                 }
 662
 663                 // Rate it
 664                 if (position >= 0 )
 665                 {
 666                         position = WEP_LAST - position;
 667                         // item.bot_pickupbasevalue is overwritten here
 668                         return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 669                 }
 670         }
 671
 672         return item.bot_pickupbasevalue * c;
 673 }
 674
 675 float commodity_pickupevalfunc(entity player, entity item)
 676 {
 677         float c, i;
 678         float need_shells = FALSE, need_nails = FALSE, need_rockets = FALSE, need_cells = FALSE, need_fuel = FALSE;
 679         entity wi;
 680         c = 0;
 681
 682         // Detect needed ammo
 683         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 684         {
 685                 wi = get_weaponinfo(i);
 686
 687                 if not(WEPSET_CONTAINS_EW(player, i))
 688                         continue;
 689
 690                 if(wi.items & IT_SHELLS)
 691                         need_shells = TRUE;
 692                 else if(wi.items & IT_NAILS)
 693                         need_nails = TRUE;
 694                 else if(wi.items & IT_ROCKETS)
 695                         need_rockets = TRUE;
 696                 else if(wi.items & IT_CELLS)
 697                         need_cells = TRUE;
 698                 else if(wi.items & IT_FUEL)
 699                         need_cells = TRUE;
 700         }
 701
 702         // TODO: figure out if the player even has the weapon this ammo is for?
 703         // may not affect strategy much though...
 704         // find out how much more ammo/armor/health the player can hold
 705         if (need_shells)
 706         if (item.ammo_shells)
 707         if (player.ammo_shells < g_pickup_shells_max)
 708                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 709         if (need_nails)
 710         if (item.ammo_nails)
 711         if (player.ammo_nails < g_pickup_nails_max)
 712                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 713         if (need_rockets)
 714         if (item.ammo_rockets)
 715         if (player.ammo_rockets < g_pickup_rockets_max)
 716                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 717         if (need_cells)
 718         if (item.ammo_cells)
 719         if (player.ammo_cells < g_pickup_cells_max)
 720                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 721         if (need_fuel)
 722         if (item.ammo_fuel)
 723         if (player.ammo_fuel < g_pickup_fuel_max)
 724                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
 725         if (item.armorvalue)
 726         if (player.armorvalue < item.max_armorvalue)
 727                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 728         if (item.health)
 729         if (player.health < item.max_health)
 730                 c = c + max(0, 1 - player.health / item.max_health);
 731
 732         return item.bot_pickupbasevalue * c;
 733 }
 734
 735 void Item_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 736 {
 737         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 738                 RemoveItem();
 739 }
 740
 741 .float is_item;
 742 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 743 {
 744         startitem_failed = FALSE;
 745
 746         if(self.model == "")
 747                 self.model = itemmodel;
 748         if(self.item_pickupsound == "")
 749                 self.item_pickupsound = pickupsound;
 750         if(!self.respawntime) // both need to be set
 751         {
 752                 self.respawntime = defaultrespawntime;
 753                 self.respawntimejitter = defaultrespawntimejitter;
 754         }
 755
 756         self.items = itemid;
 757         self.weapon = weaponid;
 758
 759         if(weaponid)
 760                 WEPSET_COPY_EW(self, weaponid);
 761         self.flags = FL_ITEM | itemflags;
 762
 763         if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
 764         {
 765                 startitem_failed = TRUE;
 766                 remove(self);
 767                 return;
 768         }
 769
 770         // is it a dropped weapon?
 771         if (self.classname == "droppedweapon")
 772         {
 773                 self.reset = SUB_Remove;
 774                 // it's a dropped weapon
 775                 self.movetype = MOVETYPE_TOSS;
 776
 777                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 778                 self.think = RemoveItem;
 779                 self.nextthink = time + 20;
 780
 781                 self.takedamage = DAMAGE_YES;
 782                 self.event_damage = Item_Damage;
 783
 784                 if(self.strength_finished || self.invincible_finished || self.superweapons_finished)
 785                 /*
 786                 if(self.items == 0)
 787                 if(WEPSET_CONTAINS_ALL_AE(WEPBIT_SUPERWEAPONS, self)) // only superweapons
 788                 if(self.ammo_nails == 0)
 789                 if(self.ammo_cells == 0)
 790                 if(self.ammo_rockets == 0)
 791                 if(self.ammo_shells == 0)
 792                 if(self.ammo_fuel == 0)
 793                 if(self.health == 0)
 794                 if(self.armorvalue == 0)
 795                 */
 796                 {
 797                         // if item is worthless after a timer, have it expire then
 798                         self.nextthink = max(self.strength_finished, self.invincible_finished, self.superweapons_finished);
 799                 }
 800
 801                 // don't drop if in a NODROP zone (such as lava)
 802                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 803                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 804                 {
 805                         startitem_failed = TRUE;
 806                         remove(self);
 807                         return;
 808                 }
 809         }
 810         else
 811         {
 812                 if(!have_pickup_item())
 813                 {
 814                         startitem_failed = TRUE;
 815                         remove (self);
 816                         return;
 817                 }
 818
 819                 self.reset = Item_Reset;
 820                 // it's a level item
 821                 if(self.spawnflags & 1)
 822                         self.noalign = 1;
 823                 if (self.noalign)
 824                         self.movetype = MOVETYPE_NONE;
 825                 else
 826                         self.movetype = MOVETYPE_TOSS;
 827                 // do item filtering according to game mode and other things
 828                 if (!self.noalign)
 829                 {
 830                         // first nudge it off the floor a little bit to avoid math errors
 831                         setorigin(self, self.origin + '0 0 1');
 832                         // set item size before we spawn a spawnfunc_waypoint
 833                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 834                                 setsize (self, '-16 -16 0', '16 16 48');
 835                         else
 836                                 setsize (self, '-16 -16 0', '16 16 32');
 837                         // note droptofloor returns FALSE if stuck/or would fall too far
 838                         droptofloor();
 839                         waypoint_spawnforitem(self);
 840                 }
 841
 842                 /*
 843                  * can't do it that way, as it would break maps
 844                  * TODO make a target_give like entity another way, that perhaps has
 845                  * the weapon name in a key
 846                 if(self.targetname)
 847                 {
 848                         // target_give not yet supported; maybe later
 849                         print("removed targeted ", self.classname, "\n");
 850                         startitem_failed = TRUE;
 851                         remove (self);
 852                         return;
 853                 }
 854                 */
 855
 856                 if(autocvar_spawn_debug >= 2)
 857                 {
 858                         entity otheritem;
 859                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
 860                         {
 861                                 if(otheritem.is_item)
 862                                 {
 863                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 864                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 865                                         error("Mapper sucks.");
 866                                 }
 867                         }
 868                         self.is_item = TRUE;
 869                 }
 870
 871                 WEPSET_OR_AW(weaponsInMap, weaponid);
 872
 873                 precache_model (self.model);
 874                 precache_sound (self.item_pickupsound);
 875
 876                 precache_sound ("misc/itemrespawncountdown.wav");
 877                 if(!g_minstagib && itemid == IT_STRENGTH)
 878                         precache_sound ("misc/strength_respawn.wav");
 879                 else if(!g_minstagib && itemid == IT_INVINCIBLE)
 880                         precache_sound ("misc/shield_respawn.wav");
 881                 else
 882                         precache_sound ("misc/itemrespawn.wav");
 883
 884                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
 885                         self.target = "###item###"; // for finding the nearest item using find()
 886         }
 887
 888         self.bot_pickup = TRUE;
 889         self.bot_pickupevalfunc = pickupevalfunc;
 890         self.bot_pickupbasevalue = pickupbasevalue;
 891         self.mdl = self.model;
 892         self.netname = itemname;
 893         self.touch = Item_Touch;
 894         setmodel (self, self.mdl); // precision set below
 895         self.effects |= EF_LOWPRECISION;
 896         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 897                 setsize (self, '-16 -16 0', '16 16 48');
 898         else
 899                 setsize (self, '-16 -16 0', '16 16 32');
 900         if(itemflags & FL_WEAPON)
 901                 self.modelflags |= MF_ROTATE;
 902
 903         if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
 904         if (itemflags & FL_WEAPON)
 905         {
 906                 // neutral team color for pickup weapons
 907                 self.colormap = 1024; // color shirt=0 pants=0 grey
 908         }
 909
 910         self.state = 0;
 911         if(self.team)
 912         {
 913                 if(!self.cnt)
 914                         self.cnt = 1; // item probability weight
 915                 self.effects = self.effects | EF_NODRAW; // marker for item team search
 916                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
 917         }
 918         else
 919                 Item_Reset();
 920 }
 921
 922 /* replace items in minstagib
 923  * IT_STRENGTH   = invisibility
 924  * IT_NAILS      = extra lives
 925  * IT_INVINCIBLE = speed
 926  */
 927 void minstagib_items (float itemid)
 928 {
 929         float rnd;
 930         self.classname = "minstagib";
 931
 932         // replace rocket launchers and nex guns with ammo cells
 933         if (itemid == IT_CELLS)
 934         {
 935                 self.ammo_cells = autocvar_g_minstagib_ammo_drop;
 936                 StartItem ("models/items/a_cells.md3",
 937                         "misc/itempickup.wav", 45, 0,
 938                         "MinstaNex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
 939                 return;
 940         }
 941
 942         // randomize
 943         rnd = random() * 3;
 944         if (rnd <= 1)
 945                 itemid = IT_STRENGTH;
 946         else if (rnd <= 2)
 947                 itemid = IT_NAILS;
 948         else
 949                 itemid = IT_INVINCIBLE;
 950
 951         // replace with invis
 952         if (itemid == IT_STRENGTH)
 953         {
 954                 if(!self.strength_finished)
 955                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
 956                 StartItem ("models/items/g_strength.md3",
 957                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 958                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 959         }
 960         // replace with extra lives
 961         if (itemid == IT_NAILS)
 962         {
 963                 self.max_health = 1;
 964                 StartItem ("models/items/g_h100.md3",
 965                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 966                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
 967         }
 968         // replace with speed
 969         if (itemid == IT_INVINCIBLE)
 970         {
 971                 if(!self.invincible_finished)
 972                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
 973                 StartItem ("models/items/g_invincible.md3",
 974                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 975                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 976         }
 977 }
 978
 979 float minst_no_auto_cells;
 980 void minst_remove_item (void) {
 981         if(minst_no_auto_cells)
 982                 remove(self);
 983 }
 984
 985 float weaponswapping;
 986 float internalteam;
 987
 988 void weapon_defaultspawnfunc(float wpn)
 989 {
 990         entity e;
 991         float t;
 992         var .float ammofield;
 993         string s;
 994         entity oldself;
 995         float i, j;
 996         float f;
 997
 998         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
 999         {
1000                 e = get_weaponinfo(wpn);
1001
1002                 if(e.spawnflags & WEP_FLAG_MUTATORBLOCKED)
1003                 {
1004                         print("Attempted to spawn a mutator-blocked weapon; these guns will in the future require a mutator\n");
1005                         /*
1006                         objerror("Attempted to spawn a mutator-blocked weapon rejected");
1007                         startitem_failed = TRUE;
1008                         return;
1009                         */
1010                 }
1011
1012                 s = W_Apply_Weaponreplace(e.netname);
1013                 ret_string = s;
1014                 other = e;
1015                 MUTATOR_CALLHOOK(SetWeaponreplace);
1016                 s = ret_string;
1017                 if(s == "")
1018                 {
1019                         remove(self);
1020                         startitem_failed = TRUE;
1021                         return;
1022                 }
1023                 t = tokenize_console(s);
1024                 if(t >= 2)
1025                 {
1026                         self.team = --internalteam;
1027                         oldself = self;
1028                         for(i = 1; i < t; ++i)
1029                         {
1030                                 s = argv(i);
1031                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1032                                 {
1033                                         e = get_weaponinfo(j);
1034                                         if(e.netname == s)
1035                                         {
1036                                                 self = spawn();
1037                                                 copyentity(oldself, self);
1038                                                 self.classname = "replacedweapon";
1039                                                 weapon_defaultspawnfunc(j);
1040                                                 break;
1041                                         }
1042                                 }
1043                                 if(j > WEP_LAST)
1044                                 {
1045                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1046                                 }
1047                         }
1048                         self = oldself;
1049                 }
1050                 if(t >= 1) // always the case!
1051                 {
1052                         s = argv(0);
1053                         wpn = 0;
1054                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1055                         {
1056                                 e = get_weaponinfo(j);
1057                                 if(e.netname == s)
1058                                 {
1059                                         wpn = j;
1060                                         break;
1061                                 }
1062                         }
1063                         if(j > WEP_LAST)
1064                         {
1065                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1066                         }
1067                 }
1068                 if(wpn == 0)
1069                 {
1070                         remove(self);
1071                         startitem_failed = TRUE;
1072                         return;
1073                 }
1074         }
1075
1076         e = get_weaponinfo(wpn);
1077
1078         if(!self.respawntime)
1079         {
1080                 if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1081                 {
1082                         self.respawntime = g_pickup_respawntime_superweapon;
1083                         self.respawntimejitter = g_pickup_respawntimejitter_superweapon;
1084                 }
1085                 else
1086                 {
1087                         self.respawntime = g_pickup_respawntime_weapon;
1088                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
1089                 }
1090         }
1091
1092         if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1093                 if(!self.superweapons_finished)
1094                         self.superweapons_finished = autocvar_g_balance_superweapons_time;
1095
1096         if(e.items)
1097         {
1098                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1099                 {
1100                         if(e.items & j)
1101                         {
1102                                 ammofield = Item_CounterField(j);
1103                                 if(!self.ammofield)
1104                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j), "_weapon"));
1105                         }
1106                 }
1107         }
1108
1109         // pickup anyway
1110         if(g_pickup_weapons_anyway)
1111                 self.pickup_anyway = TRUE;
1112
1113         f = FL_WEAPON;
1114
1115         // no weapon-stay on superweapons
1116         if(WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
1117                 f |= FL_NO_WEAPON_STAY;
1118
1119         // weapon stay isn't supported for teamed weapons
1120         if(self.team)
1121                 f |= FL_NO_WEAPON_STAY;
1122
1123         // stupid minstagib hack, don't ask
1124         if(g_minstagib)
1125                 if(self.ammo_cells)
1126                         self.ammo_cells = autocvar_g_minstagib_ammo_drop;
1127
1128         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapon, f, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1129         if (self.modelindex) // don't precache if self was removed
1130                 weapon_action(e.weapon, WR_PRECACHE);
1131 }
1132
1133 void spawnfunc_weapon_shotgun (void);
1134 void spawnfunc_weapon_uzi (void) {
1135         if(autocvar_sv_q3acompat_machineshotgunswap)
1136         if(self.classname != "droppedweapon")
1137         {
1138                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1139                 return;
1140         }
1141         weapon_defaultspawnfunc(WEP_UZI);
1142 }
1143
1144 void spawnfunc_weapon_shotgun (void) {
1145         if(autocvar_sv_q3acompat_machineshotgunswap)
1146         if(self.classname != "droppedweapon")
1147         {
1148                 weapon_defaultspawnfunc(WEP_UZI);
1149                 return;
1150         }
1151         weapon_defaultspawnfunc(WEP_SHOTGUN);
1152 }
1153
1154 void spawnfunc_weapon_nex (void)
1155 {
1156         if (g_minstagib)
1157         {
1158                 minstagib_items(IT_CELLS);
1159                 self.think = minst_remove_item;
1160                 self.nextthink = time;
1161                 return;
1162         }
1163         weapon_defaultspawnfunc(WEP_NEX);
1164 }
1165
1166 void spawnfunc_weapon_minstanex (void)
1167 {
1168         if (g_minstagib)
1169         {
1170                 minstagib_items(IT_CELLS);
1171                 self.think = minst_remove_item;
1172                 self.nextthink = time;
1173                 return;
1174         }
1175         weapon_defaultspawnfunc(WEP_MINSTANEX);
1176 }
1177
1178 void spawnfunc_weapon_rocketlauncher (void)
1179 {
1180         if (g_minstagib)
1181         {
1182                 minstagib_items(IT_CELLS); // replace rocketlauncher with cells
1183                 self.think = minst_remove_item;
1184                 self.nextthink = time;
1185                 return;
1186         }
1187         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1188 }
1189
1190 void spawnfunc_item_rockets (void) {
1191         if(!self.ammo_rockets)
1192                 self.ammo_rockets = g_pickup_rockets;
1193         if(!self.pickup_anyway)
1194                 self.pickup_anyway = g_pickup_ammo_anyway;
1195         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1196 }
1197
1198 void spawnfunc_item_shells (void);
1199 void spawnfunc_item_bullets (void) {
1200         if(!weaponswapping)
1201         if(autocvar_sv_q3acompat_machineshotgunswap)
1202         if(self.classname != "droppedweapon")
1203         {
1204                 weaponswapping = TRUE;
1205                 spawnfunc_item_shells();
1206                 weaponswapping = FALSE;
1207                 return;
1208         }
1209
1210         if(!self.ammo_nails)
1211                 self.ammo_nails = g_pickup_nails;
1212         if(!self.pickup_anyway)
1213                 self.pickup_anyway = g_pickup_ammo_anyway;
1214         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1215 }
1216
1217 void spawnfunc_item_cells (void) {
1218         if(!self.ammo_cells)
1219                 self.ammo_cells = g_pickup_cells;
1220         if(!self.pickup_anyway)
1221                 self.pickup_anyway = g_pickup_ammo_anyway;
1222         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1223 }
1224
1225 void spawnfunc_item_shells (void) {
1226         if(!weaponswapping)
1227         if(autocvar_sv_q3acompat_machineshotgunswap)
1228         if(self.classname != "droppedweapon")
1229         {
1230                 weaponswapping = TRUE;
1231                 spawnfunc_item_bullets();
1232                 weaponswapping = FALSE;
1233                 return;
1234         }
1235
1236         if(!self.ammo_shells)
1237                 self.ammo_shells = g_pickup_shells;
1238         if(!self.pickup_anyway)
1239                 self.pickup_anyway = g_pickup_ammo_anyway;
1240         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1241 }
1242
1243 void spawnfunc_item_armor_small (void) {
1244         if(!self.armorvalue)
1245                 self.armorvalue = g_pickup_armorsmall;
1246         if(!self.max_armorvalue)
1247                 self.max_armorvalue = g_pickup_armorsmall_max;
1248         if(!self.pickup_anyway)
1249                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1250         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1251 }
1252
1253 void spawnfunc_item_armor_medium (void) {
1254         if(!self.armorvalue)
1255                 self.armorvalue = g_pickup_armormedium;
1256         if(!self.max_armorvalue)
1257                 self.max_armorvalue = g_pickup_armormedium_max;
1258         if(!self.pickup_anyway)
1259                 self.pickup_anyway = g_pickup_armormedium_anyway;
1260         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1261 }
1262
1263 void spawnfunc_item_armor_big (void) {
1264         if(!self.armorvalue)
1265                 self.armorvalue = g_pickup_armorbig;
1266         if(!self.max_armorvalue)
1267                 self.max_armorvalue = g_pickup_armorbig_max;
1268         if(!self.pickup_anyway)
1269                 self.pickup_anyway = g_pickup_armorbig_anyway;
1270         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1271 }
1272
1273 void spawnfunc_item_armor_large (void) {
1274         if(!self.armorvalue)
1275                 self.armorvalue = g_pickup_armorlarge;
1276         if(!self.max_armorvalue)
1277                 self.max_armorvalue = g_pickup_armorlarge_max;
1278         if(!self.pickup_anyway)
1279                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1280         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1281 }
1282
1283 void spawnfunc_item_health_small (void) {
1284         if(!self.max_health)
1285                 self.max_health = g_pickup_healthsmall_max;
1286         if(!self.health)
1287                 self.health = g_pickup_healthsmall;
1288         if(!self.pickup_anyway)
1289                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1290         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1291 }
1292
1293 void spawnfunc_item_health_medium (void) {
1294         if(!self.max_health)
1295                 self.max_health = g_pickup_healthmedium_max;
1296         if(!self.health)
1297                 self.health = g_pickup_healthmedium;
1298         if(!self.pickup_anyway)
1299                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1300         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1301 }
1302
1303 void spawnfunc_item_health_large (void) {
1304         if(!self.max_health)
1305                 self.max_health = g_pickup_healthlarge_max;
1306         if(!self.health)
1307                 self.health = g_pickup_healthlarge;
1308         if(!self.pickup_anyway)
1309                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1310         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1311 }
1312
1313 void spawnfunc_item_health_mega (void) {
1314         if(g_minstagib) {
1315                 minstagib_items(IT_NAILS);
1316         } else {
1317                 if(!self.max_health)
1318                         self.max_health = g_pickup_healthmega_max;
1319                 if(!self.health)
1320                         self.health = g_pickup_healthmega;
1321                 if(!self.pickup_anyway)
1322                         self.pickup_anyway = g_pickup_healthmega_anyway;
1323                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1324         }
1325 }
1326
1327 // support old misnamed entities
1328 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1329 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1330 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1331 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1332 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1333
1334 void spawnfunc_item_strength (void) {
1335         if(g_minstagib) {
1336                 minstagib_items(IT_STRENGTH);
1337         } else {
1338                 precache_sound("weapons/strength_fire.wav");
1339                 if(!self.strength_finished)
1340                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1341                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1342         }
1343 }
1344
1345 void spawnfunc_item_invincible (void) {
1346         if(g_minstagib) {
1347                 minstagib_items(IT_INVINCIBLE);
1348         } else {
1349                 if(!self.invincible_finished)
1350                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1351                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1352         }
1353 }
1354
1355 void spawnfunc_item_minst_cells (void) {
1356         if (g_minstagib)
1357         {
1358                 minst_no_auto_cells = 1;
1359                 minstagib_items(IT_CELLS);
1360         }
1361         else
1362                 remove(self);
1363 }
1364
1365 // compatibility:
1366 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1367
1368 float GiveItems(entity e, float beginarg, float endarg);
1369 void target_items_use (void)
1370 {
1371         if(activator.classname == "droppedweapon")
1372         {
1373                 EXACTTRIGGER_TOUCH;
1374                 remove(activator);
1375                 return;
1376         }
1377
1378         if(activator.classname != "player")
1379                 return;
1380         if(activator.deadflag != DEAD_NO)
1381                 return;
1382         EXACTTRIGGER_TOUCH;
1383
1384         entity e;
1385         for(e = world; (e = find(e, classname, "droppedweapon")); )
1386                 if(e.enemy == activator)
1387                         remove(e);
1388
1389         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1390                 centerprint(activator, self.message);
1391 }
1392
1393 void spawnfunc_target_items (void)
1394 {
1395         float n, i, j;
1396         entity e;
1397
1398         self.use = target_items_use;
1399         if(!self.strength_finished)
1400                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1401         if(!self.invincible_finished)
1402                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1403         if(!self.superweapons_finished)
1404                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1405
1406         precache_sound("misc/itempickup.wav");
1407         precache_sound("misc/megahealth.wav");
1408         precache_sound("misc/armor25.wav");
1409         precache_sound("misc/powerup.wav");
1410         precache_sound("misc/poweroff.wav");
1411         precache_sound("weapons/weaponpickup.wav");
1412
1413         n = tokenize_console(self.netname);
1414         if(argv(0) == "give")
1415         {
1416                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1417         }
1418         else
1419         {
1420                 for(i = 0; i < n; ++i)
1421                 {
1422                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1423                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1424                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1425                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1426                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1427                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1428                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1429                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1430                         else
1431                         {
1432                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1433                                 {
1434                                         e = get_weaponinfo(j);
1435                                         if(argv(i) == e.netname)
1436                                         {
1437                                                 WEPSET_OR_EW(self, j);
1438                                                 if(self.spawnflags == 0 || self.spawnflags == 2)
1439                                                         weapon_action(e.weapon, WR_PRECACHE);
1440                                                 break;
1441                                         }
1442                                 }
1443                                 if(j > WEP_LAST)
1444                                         print("target_items: invalid item ", argv(i), "\n");
1445                         }
1446                 }
1447
1448                 string itemprefix, valueprefix;
1449                 if(self.spawnflags == 0)
1450                 {
1451                         itemprefix = "";
1452                         valueprefix = "";
1453                 }
1454                 else if(self.spawnflags == 1)
1455                 {
1456                         itemprefix = "max ";
1457                         valueprefix = "max ";
1458                 }
1459                 else if(self.spawnflags == 2)
1460                 {
1461                         itemprefix = "min ";
1462                         valueprefix = "min ";
1463                 }
1464                 else if(self.spawnflags == 4)
1465                 {
1466                         itemprefix = "minus ";
1467                         valueprefix = "max ";
1468                 }
1469                 else
1470                         error("invalid spawnflags");
1471
1472                 self.netname = "";
1473                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1474                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1475                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1476                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1477                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * !!(self.items & IT_SUPERWEAPON), "superweapons");
1478                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1479                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1480                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1481                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1482                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1483                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1484                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1485                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1486                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1487                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1488                 {
1489                         e = get_weaponinfo(j);
1490                         if(e.weapon)
1491                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, WEPSET_CONTAINS_EW(self, j), e.netname);
1492                 }
1493         }
1494         self.netname = strzone(self.netname);
1495         //print(self.netname, "\n");
1496
1497         n = tokenize_console(self.netname);
1498         for(i = 0; i < n; ++i)
1499         {
1500                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1501                 {
1502                         e = get_weaponinfo(j);
1503                         if(argv(i) == e.netname)
1504                         {
1505                                 weapon_action(e.weapon, WR_PRECACHE);
1506                                 break;
1507                         }
1508                 }
1509         }
1510 }
1511
1512 void spawnfunc_item_fuel(void)
1513 {
1514         if(!self.ammo_fuel)
1515                 self.ammo_fuel = g_pickup_fuel;
1516         if(!self.pickup_anyway)
1517                 self.pickup_anyway = g_pickup_ammo_anyway;
1518         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1519 }
1520
1521 void spawnfunc_item_fuel_regen(void)
1522 {
1523         if(start_items & IT_FUEL_REGEN)
1524         {
1525                 spawnfunc_item_fuel();
1526                 return;
1527         }
1528         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1529 }
1530
1531 void spawnfunc_item_jetpack(void)
1532 {
1533         if(g_grappling_hook)
1534                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1535         if(!self.ammo_fuel)
1536                 self.ammo_fuel = g_pickup_fuel_jetpack;
1537         if(start_items & IT_JETPACK)
1538         {
1539                 spawnfunc_item_fuel();
1540                 return;
1541         }
1542         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1543 }
1544
1545
1546 #define OP_SET 0
1547 #define OP_MIN 1
1548 #define OP_MAX 2
1549 #define OP_PLUS 3
1550 #define OP_MINUS 4
1551
1552 float GiveWeapon(entity e, float wpn, float op, float val)
1553 {
1554         float v0, v1;
1555         v0 = WEPSET_CONTAINS_EW(e, wpn);
1556         switch(op)
1557         {
1558                 case OP_SET:
1559                         if(val > 0)
1560                                 WEPSET_OR_EW(e, wpn);
1561                         else
1562                                 WEPSET_ANDNOT_EW(e, wpn);
1563                         break;
1564                 case OP_MIN:
1565                 case OP_PLUS:
1566                         if(val > 0)
1567                                 WEPSET_OR_EW(e, wpn);
1568                         break;
1569                 case OP_MAX:
1570                         if(val <= 0)
1571                                 WEPSET_ANDNOT_EW(e, wpn);
1572                         break;
1573                 case OP_MINUS:
1574                         if(val > 0)
1575                                 WEPSET_ANDNOT_EW(e, wpn);
1576                         break;
1577         }
1578         v1 = WEPSET_CONTAINS_EW(e, wpn);
1579         return (v0 != v1);
1580 }
1581
1582 float GiveBit(entity e, .float fld, float bit, float op, float val)
1583 {
1584         float v0, v1;
1585         v0 = (e.fld & bit);
1586         switch(op)
1587         {
1588                 case OP_SET:
1589                         if(val > 0)
1590                                 e.fld |= bit;
1591                         else
1592                                 e.fld &~= bit;
1593                         break;
1594                 case OP_MIN:
1595                 case OP_PLUS:
1596                         if(val > 0)
1597                                 e.fld |= bit;
1598                         break;
1599                 case OP_MAX:
1600                         if(val <= 0)
1601                                 e.fld &~= bit;
1602                         break;
1603                 case OP_MINUS:
1604                         if(val > 0)
1605                                 e.fld &~= bit;
1606                         break;
1607         }
1608         v1 = (e.fld & bit);
1609         return (v0 != v1);
1610 }
1611
1612 float GiveValue(entity e, .float fld, float op, float val)
1613 {
1614         float v0, v1;
1615         v0 = e.fld;
1616         switch(op)
1617         {
1618                 case OP_SET:
1619                         e.fld = val;
1620                         break;
1621                 case OP_MIN:
1622                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1623                         break;
1624                 case OP_MAX:
1625                         e.fld = min(e.fld, val);
1626                         break;
1627                 case OP_PLUS:
1628                         e.fld += val;
1629                         break;
1630                 case OP_MINUS:
1631                         e.fld -= val;
1632                         break;
1633         }
1634         v1 = e.fld;
1635         return (v0 != v1);
1636 }
1637
1638 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1639 {
1640         if(v1 == v0)
1641                 return;
1642         if(v1 <= v0 - t)
1643         {
1644                 if(snd_decr != "")
1645                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTN_NORM);
1646         }
1647         else if(v0 >= v0 + t)
1648         {
1649                 if(snd_incr != "")
1650                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTN_NORM);
1651         }
1652 }
1653
1654 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1655 {
1656         if(v0 < v1)
1657                 e.rotfield = max(e.rotfield, time + rottime);
1658         else if(v0 > v1)
1659                 e.regenfield = max(e.regenfield, time + regentime);
1660 }
1661
1662 #define PREGIVE_WEAPONS(e) WEPSET_DECLARE_A(save_weapons); WEPSET_COPY_AE(save_weapons, e)
1663 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1664 #define POSTGIVE_WEAPON(e,b,snd_incr,snd_decr) GiveSound((e), WEPSET_CONTAINS_AW(save_weapons, b), WEPSET_CONTAINS_EW(e, b), 0, snd_incr, snd_decr)
1665 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1666 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1667 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1668
1669 float GiveItems(entity e, float beginarg, float endarg)
1670 {
1671         float got, i, j, val, op;
1672         float _switchweapon;
1673         entity wi;
1674         string cmd;
1675
1676         val = 999;
1677         op = OP_SET;
1678
1679         got = 0;
1680
1681         _switchweapon = FALSE;
1682         if (e.autoswitch)
1683                 if (e.switchweapon == w_getbestweapon(e))
1684                         _switchweapon = TRUE;
1685
1686         e.strength_finished = max(0, e.strength_finished - time);
1687         e.invincible_finished = max(0, e.invincible_finished - time);
1688         e.superweapons_finished = max(0, e.superweapons_finished - time);
1689
1690         PREGIVE(e, items);
1691         PREGIVE_WEAPONS(e);
1692         PREGIVE(e, strength_finished);
1693         PREGIVE(e, invincible_finished);
1694         PREGIVE(e, superweapons_finished);
1695         PREGIVE(e, ammo_nails);
1696         PREGIVE(e, ammo_cells);
1697         PREGIVE(e, ammo_shells);
1698         PREGIVE(e, ammo_rockets);
1699         PREGIVE(e, ammo_fuel);
1700         PREGIVE(e, armorvalue);
1701         PREGIVE(e, health);
1702
1703         for(i = beginarg; i < endarg; ++i)
1704         {
1705                 cmd = argv(i);
1706
1707                 if(cmd == "0" || stof(cmd))
1708                 {
1709                         val = stof(cmd);
1710                         continue;
1711                 }
1712                 switch(cmd)
1713                 {
1714                         case "no":
1715                                 op = OP_MAX;
1716                                 val = 0;
1717                                 continue;
1718                         case "max":
1719                                 op = OP_MAX;
1720                                 continue;
1721                         case "min":
1722                                 op = OP_MIN;
1723                                 continue;
1724                         case "plus":
1725                                 op = OP_PLUS;
1726                                 continue;
1727                         case "minus":
1728                                 op = OP_MINUS;
1729                                 continue;
1730                         case "ALL":
1731                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1732                                 got += GiveValue(e, strength_finished, op, val);
1733                                 got += GiveValue(e, invincible_finished, op, val);
1734                                 got += GiveValue(e, superweapons_finished, op, val);
1735                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1736                         case "all":
1737                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1738                                 got += GiveValue(e, health, op, val);
1739                                 got += GiveValue(e, armorvalue, op, val);
1740                         case "allweapons":
1741                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1742                                 {
1743                                         wi = get_weaponinfo(j);
1744                                         if(wi.weapon)
1745                                                 if not(wi.spawnflags & WEP_FLAG_MUTATORBLOCKED)
1746                                                         got += GiveWeapon(e, j, op, val);
1747                                 }
1748                         case "allammo":
1749                                 got += GiveValue(e, ammo_cells, op, val);
1750                                 got += GiveValue(e, ammo_shells, op, val);
1751                                 got += GiveValue(e, ammo_nails, op, val);
1752                                 got += GiveValue(e, ammo_rockets, op, val);
1753                                 got += GiveValue(e, ammo_fuel, op, val);
1754                                 break;
1755                         case "unlimited_ammo":
1756                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1757                                 break;
1758                         case "unlimited_weapon_ammo":
1759                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1760                                 break;
1761                         case "unlimited_superweapons":
1762                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1763                                 break;
1764                         case "jetpack":
1765                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1766                                 break;
1767                         case "fuel_regen":
1768                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1769                                 break;
1770                         case "strength":
1771                                 got += GiveValue(e, strength_finished, op, val);
1772                                 break;
1773                         case "invincible":
1774                                 got += GiveValue(e, invincible_finished, op, val);
1775                                 break;
1776                         case "superweapons":
1777                                 got += GiveValue(e, superweapons_finished, op, val);
1778                                 break;
1779                         case "cells":
1780                                 got += GiveValue(e, ammo_cells, op, val);
1781                                 break;
1782                         case "shells":
1783                                 got += GiveValue(e, ammo_shells, op, val);
1784                                 break;
1785                         case "nails":
1786                         case "bullets":
1787                                 got += GiveValue(e, ammo_nails, op, val);
1788                                 break;
1789                         case "rockets":
1790                                 got += GiveValue(e, ammo_rockets, op, val);
1791                                 break;
1792                         case "health":
1793                                 got += GiveValue(e, health, op, val);
1794                                 break;
1795                         case "armor":
1796                                 got += GiveValue(e, armorvalue, op, val);
1797                                 break;
1798                         case "fuel":
1799                                 got += GiveValue(e, ammo_fuel, op, val);
1800                                 break;
1801                         default:
1802                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1803                                 {
1804                                         wi = get_weaponinfo(j);
1805                                         if(cmd == wi.netname)
1806                                         {
1807                                                 got += GiveWeapon(e, j, op, val);
1808                                                 break;
1809                                         }
1810                                 }
1811                                 if(j > WEP_LAST)
1812                                         print("give: invalid item ", cmd, "\n");
1813                                 break;
1814                 }
1815                 val = 999;
1816                 op = OP_SET;
1817         }
1818
1819         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1820         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1821         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1822         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1823         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1824         {
1825                 wi = get_weaponinfo(j);
1826                 if(wi.weapon)
1827                 {
1828                         POSTGIVE_WEAPON(e, j, "weapons/weaponpickup.wav", string_null);
1829                         if not(WEPSET_CONTAINS_AW(save_weapons, j))
1830                                 if(WEPSET_CONTAINS_EW(e, j))
1831                                         weapon_action(wi.weapon, WR_PRECACHE);
1832                 }
1833         }
1834         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1835         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1836         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1837         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1838         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1839         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1840         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
1841         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
1842         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
1843
1844         if(e.superweapons_finished <= 0)
1845                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1846                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1847
1848         if (g_minstagib)
1849         {
1850                 e.health = bound(0, e.health, 100);
1851                 e.armorvalue = bound(0, e.armorvalue, 999);
1852         }
1853
1854         if(e.strength_finished <= 0)
1855                 e.strength_finished = 0;
1856         else
1857                 e.strength_finished += time;
1858         if(e.invincible_finished <= 0)
1859                 e.invincible_finished = 0;
1860         else
1861                 e.invincible_finished += time;
1862         if(e.superweapons_finished <= 0)
1863                 e.superweapons_finished = 0;
1864         else
1865                 e.superweapons_finished += time;
1866
1867         if not(WEPSET_CONTAINS_EW(e, e.switchweapon))
1868                 _switchweapon = TRUE;
1869         if(_switchweapon)
1870                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1871
1872         return got;
1873 }