qcsrc/server/t_items.qc

   1 #include "t_items.qh"
   2
   3 #include "../common/items/all.qc"
   4
   5 #if defined(SVQC)
   6     #include "_all.qh"
   7
   8     #include "waypointsprites.qh"
   9
  10     #include "bot/bot.qh"
  11     #include "bot/waypoints.qh"
  12
  13     #include "mutators/mutators_include.qh"
  14
  15     #include "weapons/common.qh"
  16     #include "weapons/selection.qh"
  17     #include "weapons/weaponsystem.qh"
  18
  19     #include "../common/constants.qh"
  20     #include "../common/deathtypes.qh"
  21     #include "../common/notifications.qh"
  22         #include "../common/triggers/subs.qh"
  23     #include "../common/util.qh"
  24
  25     #include "../common/monsters/all.qh"
  26
  27     #include "../common/weapons/all.qh"
  28
  29     #include "../warpzonelib/util_server.qh"
  30 #endif
  31
  32 #ifdef CSQC
  33 void ItemDraw()
  34 {
  35     if(self.gravity)
  36     {
  37         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  38         if(self.move_flags & FL_ONGROUND)
  39         { // For some reason move_avelocity gets set to '0 0 0' here ...
  40             self.oldorigin = self.origin;
  41             self.gravity = 0;
  42
  43             if(autocvar_cl_animate_items)
  44             { // ... so reset it if animations are requested.
  45                 if(self.ItemStatus & ITS_ANIMATE1)
  46                     self.move_avelocity = '0 180 0';
  47
  48                 if(self.ItemStatus & ITS_ANIMATE2)
  49                     self.move_avelocity = '0 -90 0';
  50             }
  51         }
  52     }
  53     else if (autocvar_cl_animate_items)
  54     {
  55         if(self.ItemStatus & ITS_ANIMATE1)
  56         {
  57             self.angles += self.move_avelocity * frametime;
  58             setorigin(self, '0 0 10' + self.oldorigin + '0 0 8' * sin(time * 2));
  59         }
  60
  61         if(self.ItemStatus & ITS_ANIMATE2)
  62         {
  63             self.angles += self.move_avelocity * frametime;
  64             setorigin(self, '0 0 8' + self.oldorigin + '0 0 4' * sin(time * 3));
  65         }
  66     }
  67 }
  68
  69 void ItemDrawSimple()
  70 {
  71     if(self.gravity)
  72     {
  73         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  74
  75         if(self.move_flags & FL_ONGROUND)
  76             self.gravity = 0;
  77     }
  78 }
  79
  80 void ItemRead(float _IsNew)
  81 {
  82     int sf = ReadByte();
  83
  84     if(sf & ISF_LOCATION)
  85     {
  86         self.origin_x = ReadCoord();
  87         self.origin_y = ReadCoord();
  88         self.origin_z = ReadCoord();
  89         setorigin(self, self.origin);
  90         self.oldorigin = self.origin;
  91     }
  92
  93     if(sf & ISF_ANGLES)
  94     {
  95         self.angles_x = ReadCoord();
  96         self.angles_y = ReadCoord();
  97         self.angles_z = ReadCoord();
  98         self.move_angles = self.angles;
  99     }
 100
 101     if(sf & ISF_SIZE)
 102     {
 103         self.mins_x = ReadCoord();
 104         self.mins_y = ReadCoord();
 105         self.mins_z = ReadCoord();
 106         self.maxs_x = ReadCoord();
 107         self.maxs_y = ReadCoord();
 108         self.maxs_z = ReadCoord();
 109         setsize(self, self.mins, self.maxs);
 110     }
 111
 112     if(sf & ISF_STATUS) // need to read/write status frist so model can handle simple, fb etc.
 113     {
 114         self.ItemStatus = ReadByte();
 115
 116         if(self.ItemStatus & ITS_AVAILABLE)
 117         {
 118             self.alpha = 1;
 119             self.colormod = self.glowmod = '1 1 1';
 120         }
 121         else
 122         {
 123             if (autocvar_cl_ghost_items_color)
 124             {
 125                 self.alpha = autocvar_cl_ghost_items;
 126                 self.colormod = self.glowmod = autocvar_cl_ghost_items_color;
 127             }
 128             else
 129                 self.alpha = -1;
 130         }
 131
 132         if(autocvar_cl_fullbright_items)
 133             if(self.ItemStatus & ITS_ALLOWFB)
 134                 self.effects |= EF_FULLBRIGHT;
 135
 136         if(self.ItemStatus & ITS_STAYWEP)
 137         {
 138             self.colormod = self.glowmod = autocvar_cl_weapon_stay_color;
 139             self.alpha = autocvar_cl_weapon_stay_alpha;
 140
 141         }
 142
 143         if(self.ItemStatus & ITS_POWERUP)
 144         {
 145             if(self.ItemStatus & ITS_AVAILABLE)
 146                 self.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 147             else
 148                  self.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 149         }
 150     }
 151
 152     if(sf & ISF_MODEL)
 153     {
 154         self.drawmask  = MASK_NORMAL;
 155         self.movetype  = MOVETYPE_TOSS;
 156         self.draw       = ItemDraw;
 157
 158         if(self.mdl)
 159             strunzone(self.mdl);
 160
 161         self.mdl = "";
 162         string _fn = ReadString();
 163
 164         if(autocvar_cl_simple_items && (self.ItemStatus & ITS_ALLOWSI))
 165         {
 166             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 167             self.draw = ItemDrawSimple;
 168
 169
 170
 171             if(fexists(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix)))
 172                 self.mdl = strzone(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix));
 173             else if(fexists(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix)))
 174                 self.mdl = strzone(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix));
 175             else if(fexists(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix)))
 176                 self.mdl = strzone(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix));
 177             else if(fexists(sprintf("%s%s.obj", _fn2, autocvar_cl_simpleitems_postfix)))
 178                 self.mdl = strzone(sprintf("%s%s.obj", _fn2, autocvar_cl_simpleitems_postfix));
 179             else
 180             {
 181                 self.draw = ItemDraw;
 182                 dprint("Simple item requested for ", _fn, " but no model exsist for it\n");
 183             }
 184         }
 185
 186         if(self.draw != ItemDrawSimple)
 187             self.mdl = strzone(_fn);
 188
 189
 190         if(self.mdl == "")
 191             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, " tell tZork aboute this!\n");
 192
 193         precache_model(self.mdl);
 194         setmodel(self, self.mdl);
 195     }
 196
 197     if(sf & ISF_COLORMAP)
 198         self.colormap = ReadShort();
 199
 200     if(sf & ISF_DROP)
 201     {
 202         self.gravity = 1;
 203         //self.move_angles = '0 0 0';
 204         self.move_movetype = MOVETYPE_TOSS;
 205         self.move_velocity_x = ReadCoord();
 206         self.move_velocity_y = ReadCoord();
 207         self.move_velocity_z = ReadCoord();
 208         self.velocity = self.move_velocity;
 209         self.move_origin = self.oldorigin;
 210
 211         if(!self.move_time)
 212         {
 213             self.move_time = time;
 214             self.spawntime = time;
 215         }
 216         else
 217             self.move_time = max(self.move_time, time);
 218     }
 219
 220     if(autocvar_cl_animate_items)
 221     {
 222         if(self.ItemStatus & ITS_ANIMATE1)
 223             self.move_avelocity = '0 180 0';
 224
 225         if(self.ItemStatus & ITS_ANIMATE2)
 226             self.move_avelocity = '0 -90 0';
 227     }
 228 }
 229
 230 #endif
 231
 232 #ifdef SVQC
 233 bool ItemSend(entity to, int sf)
 234 {
 235     if(self.gravity)
 236         sf |= ISF_DROP;
 237     else
 238         sf &= ~ISF_DROP;
 239
 240         WriteByte(MSG_ENTITY, ENT_CLIENT_ITEM);
 241         WriteByte(MSG_ENTITY, sf);
 242
 243         //WriteByte(MSG_ENTITY, self.cnt);
 244     if(sf & ISF_LOCATION)
 245     {
 246         WriteCoord(MSG_ENTITY, self.origin.x);
 247         WriteCoord(MSG_ENTITY, self.origin.y);
 248         WriteCoord(MSG_ENTITY, self.origin.z);
 249     }
 250
 251     if(sf & ISF_ANGLES)
 252     {
 253         WriteCoord(MSG_ENTITY, self.angles.x);
 254         WriteCoord(MSG_ENTITY, self.angles.y);
 255         WriteCoord(MSG_ENTITY, self.angles.z);
 256     }
 257
 258     if(sf & ISF_SIZE)
 259     {
 260         WriteCoord(MSG_ENTITY, self.mins.x);
 261         WriteCoord(MSG_ENTITY, self.mins.y);
 262         WriteCoord(MSG_ENTITY, self.mins.z);
 263         WriteCoord(MSG_ENTITY, self.maxs.x);
 264         WriteCoord(MSG_ENTITY, self.maxs.y);
 265         WriteCoord(MSG_ENTITY, self.maxs.z);
 266     }
 267
 268     if(sf & ISF_STATUS)
 269         WriteByte(MSG_ENTITY, self.ItemStatus);
 270
 271     if(sf & ISF_MODEL)
 272     {
 273
 274         if(self.mdl == "")
 275             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, "exspect a crash just aboute now\n");
 276
 277         WriteString(MSG_ENTITY, self.mdl);
 278     }
 279
 280
 281     if(sf & ISF_COLORMAP)
 282         WriteShort(MSG_ENTITY, self.colormap);
 283
 284     if(sf & ISF_DROP)
 285     {
 286         WriteCoord(MSG_ENTITY, self.velocity.x);
 287         WriteCoord(MSG_ENTITY, self.velocity.y);
 288         WriteCoord(MSG_ENTITY, self.velocity.z);
 289     }
 290
 291     return true;
 292 }
 293
 294 void ItemUpdate(entity item)
 295 {
 296         item.SendFlags |= ISF_LOCATION;
 297 }
 298
 299 float have_pickup_item(void)
 300 {
 301         if(self.flags & FL_POWERUP)
 302         {
 303                 if(autocvar_g_powerups > 0)
 304                         return true;
 305                 if(autocvar_g_powerups == 0)
 306                         return false;
 307         }
 308         else
 309         {
 310                 if(autocvar_g_pickup_items > 0)
 311                         return true;
 312                 if(autocvar_g_pickup_items == 0)
 313                         return false;
 314                 if(g_weaponarena)
 315                         if(self.weapons || (self.items & IT_AMMO)) // no item or ammo pickups in weaponarena
 316                                 return false;
 317         }
 318         return true;
 319 }
 320
 321 /*
 322 float Item_Customize()
 323 {
 324         if(self.spawnshieldtime)
 325                 return true;
 326         if(self.weapons & ~other.weapons)
 327         {
 328                 self.colormod = '0 0 0';
 329                 self.glowmod = self.colormod;
 330                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 331                 return true;
 332         }
 333         else
 334         {
 335                 if(g_ghost_items)
 336                 {
 337                         self.colormod = stov(autocvar_g_ghost_items_color);
 338                         self.glowmod = self.colormod;
 339                         self.alpha = g_ghost_items;
 340                         return true;
 341                 }
 342                 else
 343                         return false;
 344         }
 345 }
 346 */
 347
 348 void Item_Show (entity e, float mode)
 349 {
 350         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 351         e.ItemStatus &= ~ITS_STAYWEP;
 352         if (mode > 0)
 353         {
 354                 // make the item look normal, and be touchable
 355                 e.model = e.mdl;
 356                 e.solid = SOLID_TRIGGER;
 357                 e.spawnshieldtime = 1;
 358                 e.ItemStatus |= ITS_AVAILABLE;
 359         }
 360         else if (mode < 0)
 361         {
 362                 // hide the item completely
 363                 e.model = string_null;
 364                 e.solid = SOLID_NOT;
 365                 e.spawnshieldtime = 1;
 366                 e.ItemStatus &= ~ITS_AVAILABLE;
 367         }
 368         else if((e.flags & FL_WEAPON) && !(e.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 369         {
 370                 // make the item translucent and not touchable
 371                 e.model = e.mdl;
 372                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 373                 e.effects |= EF_STARDUST;
 374                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 375                 e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 376         }
 377         else
 378         {
 379                 //setmodel(e, "null");
 380                 e.solid = SOLID_NOT;
 381                 e.colormod = '0 0 0';
 382                 e.glowmod = e.colormod;
 383                 e.spawnshieldtime = 1;
 384                 e.ItemStatus &= ~ITS_AVAILABLE;
 385         }
 386
 387         if (e.items & IT_STRENGTH || e.items & IT_INVINCIBLE)
 388             e.ItemStatus |= ITS_POWERUP;
 389
 390         if (autocvar_g_nodepthtestitems)
 391                 e.effects |= EF_NODEPTHTEST;
 392
 393
 394     if (autocvar_g_fullbrightitems)
 395                 e.ItemStatus |= ITS_ALLOWFB;
 396
 397         if (autocvar_sv_simple_items)
 398         e.ItemStatus |= ITS_ALLOWSI;
 399
 400         // relink entity (because solid may have changed)
 401         setorigin(e, e.origin);
 402     e.SendFlags |= ISF_STATUS;
 403 }
 404
 405 void Item_Think()
 406 {
 407         self.nextthink = time;
 408         if(self.origin != self.oldorigin)
 409         {
 410                 self.oldorigin = self.origin;
 411                 ItemUpdate(self);
 412         }
 413 }
 414
 415 float it_armor_large_time;
 416 float it_health_mega_time;
 417 float it_invisible_time;
 418 float it_speed_time;
 419 float it_extralife_time;
 420 float it_strength_time;
 421 float it_shield_time;
 422 float it_fuelregen_time;
 423 float it_jetpack_time;
 424 float it_superweapons_time;
 425
 426 void Item_ItemsTime_Init()
 427 {
 428         it_armor_large_time = -1;
 429         it_health_mega_time = -1;
 430         it_invisible_time = -1;
 431         it_speed_time = -1;
 432         it_extralife_time = -1;
 433         it_strength_time = -1;
 434         it_shield_time = -1;
 435         it_fuelregen_time = -1;
 436         it_jetpack_time = -1;
 437         it_superweapons_time = -1;
 438 }
 439 void Item_ItemsTime_Reset()
 440 {
 441         it_armor_large_time = (it_armor_large_time == -1) ? -1 : 0;
 442         it_health_mega_time = (it_health_mega_time == -1) ? -1 : 0;
 443         it_invisible_time   = (it_invisible_time   == -1) ? -1 : 0;
 444         it_speed_time       = (it_speed_time       == -1) ? -1 : 0;
 445         it_extralife_time   = (it_extralife_time   == -1) ? -1 : 0;
 446         it_strength_time    = (it_strength_time    == -1) ? -1 : 0;
 447         it_shield_time      = (it_shield_time      == -1) ? -1 : 0;
 448         it_fuelregen_time   = (it_fuelregen_time   == -1) ? -1 : 0;
 449         it_jetpack_time     = (it_jetpack_time     == -1) ? -1 : 0;
 450         it_superweapons_time= (it_superweapons_time== -1) ? -1 : 0;
 451 }
 452 void Item_ItemsTime_ResetForPlayer(entity e)
 453 {
 454         e.item_armor_large_time = (it_armor_large_time == -1) ? -1 : 0;
 455         e.item_health_mega_time = (it_health_mega_time == -1) ? -1 : 0;
 456         e.item_invisible_time   = (it_invisible_time   == -1) ? -1 : 0;
 457         e.item_speed_time       = (it_speed_time       == -1) ? -1 : 0;
 458         e.item_extralife_time   = (it_extralife_time   == -1) ? -1 : 0;
 459         e.item_strength_time    = (it_strength_time    == -1) ? -1 : 0;
 460         e.item_shield_time      = (it_shield_time      == -1) ? -1 : 0;
 461         e.item_fuelregen_time   = (it_fuelregen_time   == -1) ? -1 : 0;
 462         e.item_jetpack_time     = (it_jetpack_time     == -1) ? -1 : 0;
 463         e.item_superweapons_time= (it_superweapons_time== -1) ? -1 : 0;
 464 }
 465 void Item_ItemsTime_Get(entity e)
 466 {
 467         e.item_armor_large_time = it_armor_large_time;
 468         e.item_health_mega_time = it_health_mega_time;
 469         e.item_invisible_time = it_invisible_time;
 470         e.item_speed_time = it_speed_time;
 471         e.item_extralife_time = it_extralife_time;
 472         e.item_strength_time = it_strength_time;
 473         e.item_shield_time = it_shield_time;
 474         e.item_fuelregen_time = it_fuelregen_time;
 475         e.item_jetpack_time = it_jetpack_time;
 476         e.item_superweapons_time = it_superweapons_time;
 477 }
 478 float Item_ItemsTime_UpdateTime_Check(float item_time, float t)
 479 {
 480         if(t == 0 && item_time == -1)
 481                 return TRUE;
 482         if(time < t && (item_time <= time || t < item_time))
 483                 return TRUE;
 484         return FALSE;
 485 }
 486 void Item_ItemsTime_UpdateTime(entity e, float t)
 487 {
 488         if(g_instagib)
 489         {
 490                 switch(e.items)
 491                 {
 492                         case IT_STRENGTH://"item-invis"
 493                                 if(Item_ItemsTime_UpdateTime_Check(it_invisible_time, t))
 494                                         it_invisible_time = t;
 495                                 break;
 496                         case IT_NAILS://"item-extralife"
 497                                 if(Item_ItemsTime_UpdateTime_Check(it_extralife_time, t))
 498                                         it_extralife_time = t;
 499                                 break;
 500                         case IT_INVINCIBLE://"item-speed"
 501                                 if(Item_ItemsTime_UpdateTime_Check(it_speed_time, t))
 502                                         it_speed_time = t;
 503                                 break;
 504                 }
 505         }
 506         else
 507         {
 508                 switch(e.items)
 509                 {
 510                         case IT_HEALTH:
 511                                 if(!autocvar_sv_itemstime)
 512                                         break;
 513                                 //if (e.classname == "item_health_mega")
 514                                         if(Item_ItemsTime_UpdateTime_Check(it_health_mega_time, t))
 515                                                 it_health_mega_time = t;
 516                                 break;
 517                         case IT_ARMOR:
 518                                 if(!autocvar_sv_itemstime)
 519                                         break;
 520                                 if (e.classname == "item_armor_large")
 521                                         if(Item_ItemsTime_UpdateTime_Check(it_armor_large_time, t))
 522                                                 it_armor_large_time = t;
 523                                 break;
 524                         case IT_STRENGTH://"item-strength"
 525                                 if(Item_ItemsTime_UpdateTime_Check(it_strength_time, t))
 526                                         it_strength_time = t;
 527                                 break;
 528                         case IT_INVINCIBLE://"item-shield"
 529                                 if(Item_ItemsTime_UpdateTime_Check(it_shield_time, t))
 530                                         it_shield_time = t;
 531                                 break;
 532                         default:
 533                                 if(e.weapons & WEPSET_SUPERWEAPONS)
 534                                         if(Item_ItemsTime_UpdateTime_Check(it_superweapons_time, t))
 535                                                         it_superweapons_time = t;
 536                 }
 537         }
 538         switch(e.items)
 539         {
 540                 case IT_FUEL_REGEN://"item-fuelregen"
 541                         if(Item_ItemsTime_UpdateTime_Check(it_fuelregen_time, t))
 542                                 it_fuelregen_time = t;
 543                         break;
 544                 case IT_JETPACK://"item-jetpack"
 545                         if(Item_ItemsTime_UpdateTime_Check(it_jetpack_time, t))
 546                                 it_jetpack_time = t;
 547                         break;
 548         }
 549 }
 550 void Item_ItemsTime_GetForAll()
 551 {
 552         entity e;
 553         if(warmup_stage)
 554         {
 555                 FOR_EACH_REALCLIENT(e)
 556                         Item_ItemsTime_Get(e);
 557         }
 558         else
 559         {
 560                 FOR_EACH_REALCLIENT(e)
 561                 {
 562                         if (e.classname != "player")
 563                                 Item_ItemsTime_Get(e);
 564                 }
 565         }
 566 }
 567
 568 void Item_Respawn (void)
 569 {
 570         Item_Show(self, 1);
 571         // this is ugly...
 572         if(self.items == IT_STRENGTH)
 573                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTEN_NORM);    // play respawn sound
 574         else if(self.items == IT_INVINCIBLE)
 575                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTEN_NORM);      // play respawn sound
 576         else
 577                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTEN_NORM); // play respawn sound
 578         setorigin (self, self.origin);
 579
 580         if(self.flags & FL_POWERUP || self.classname == "item_armor_large" || self.items == IT_HEALTH || (self.weapons & WEPSET_SUPERWEAPONS))
 581         {
 582                 Item_ItemsTime_UpdateTime(self, 0);
 583                 Item_ItemsTime_GetForAll();
 584         }
 585
 586         self.think = Item_Think;
 587         self.nextthink = time;
 588
 589         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 590         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 591 }
 592
 593 void Item_RespawnCountdown (void)
 594 {
 595         if(self.count >= ITEM_RESPAWN_TICKS)
 596         {
 597                 if(self.waypointsprite_attached)
 598                         WaypointSprite_Kill(self.waypointsprite_attached);
 599                 Item_Respawn();
 600         }
 601         else
 602         {
 603                 self.nextthink = time + 1;
 604                 self.count += 1;
 605                 if(self.count == 1)
 606                 {
 607                         string name;
 608                         vector rgb = '1 0 1';
 609                         name = string_null;
 610                         switch(self.items)
 611                         {
 612                                 case IT_FUEL_REGEN: name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 613                                 case IT_JETPACK:    name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 614                                 case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 615                                 case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 616                                 case IT_HEALTH:
 617                                         //if (self.classname == "item_health_mega")
 618                                                 {name = "item_health_mega"; rgb = '1 0 0';}
 619                                         break;
 620                                 case IT_ARMOR:
 621                                         if (self.classname == "item_armor_large")
 622                                                 {name = "item_armor_large"; rgb = '0 1 0';}
 623                                         break;
 624                         }
 625                         item_name = name;
 626                         item_color = rgb;
 627                         MUTATOR_CALLHOOK(Item_RespawnCountdown);
 628                         name = item_name;
 629                         rgb = item_color;
 630                         if(self.flags & FL_WEAPON)
 631                         {
 632                                 entity wi = get_weaponinfo(self.weapon);
 633                                 if(wi)
 634                                 {
 635                                         name = wi.wpmodel;
 636                                         rgb = '1 0 0';
 637                                 }
 638                         }
 639                         if(name)
 640                         {
 641                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, true, RADARICON_POWERUP, rgb);
 642                                 if(self.waypointsprite_attached)
 643                                 {
 644                                         if (self.items == IT_HEALTH || self.items == IT_ARMOR)
 645                                                 WaypointSprite_UpdateRule(self.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 646                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 647                                 }
 648                         }
 649                         else
 650                         {
 651                                 print("Unknown powerup-marked item is wanting to respawn\n");
 652                                 localcmd(sprintf("prvm_edict server %d\n", num_for_edict(self)));
 653                         }
 654                 }
 655                 sound (self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTEN_NORM);        // play respawn sound
 656                 if(self.waypointsprite_attached)
 657                 {
 658                         WaypointSprite_Ping(self.waypointsprite_attached);
 659                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 660                 }
 661         }
 662 }
 663
 664 void Item_RespawnThink()
 665 {
 666         self.nextthink = time;
 667         if(self.origin != self.oldorigin)
 668         {
 669                 self.oldorigin = self.origin;
 670                 ItemUpdate(self);
 671         }
 672
 673         if(time >= self.wait)
 674                 Item_Respawn();
 675 }
 676
 677 void Item_ScheduleRespawnIn(entity e, float t)
 678 {
 679         if((e.flags & FL_POWERUP) || (e.weapons & WEPSET_SUPERWEAPONS) || e.classname == "item_armor_large" || e.items == IT_HEALTH)
 680         {
 681                 entity head;
 682                 e.think = Item_RespawnCountdown;
 683                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 684                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 685                 e.count = 0;
 686                 if(e.weapons & WEPSET_SUPERWEAPONS)
 687                 {
 688                         for(t = e.scheduledrespawntime, head = world; (head = nextent(head)); )
 689                         {
 690                                 if(e == head)
 691                                         continue;
 692                                 if(clienttype(head) == CLIENTTYPE_NOTACLIENT)
 693                                 if(head.weapons & WEPSET_SUPERWEAPONS)
 694                                 if(head.classname != "weapon_info")
 695                                 {
 696                                         if(head.scheduledrespawntime <= time)
 697                                         {
 698                                                 t = 0;
 699                                                 break;
 700                                         }
 701                                         if(head.scheduledrespawntime < t)
 702                                                 t = head.scheduledrespawntime;
 703                                 }
 704                         }
 705                 }
 706                 else
 707                 {
 708                         for(t = e.scheduledrespawntime, head = world; (head = find(head, classname, e.classname)); )
 709                         {
 710                                 // in instagib .classname is "instagib" for every item
 711                                 if(e == head || (g_instagib && e.items != head.items))
 712                                         continue;
 713                                 if(head.scheduledrespawntime <= time)
 714                                 {
 715                                         t = 0;
 716                                         break;
 717                                 }
 718                                 if(head.scheduledrespawntime < t)
 719                                         t = head.scheduledrespawntime;
 720                         }
 721                 }
 722                 Item_ItemsTime_UpdateTime(e, t);
 723                 Item_ItemsTime_GetForAll();
 724         }
 725         else
 726         {
 727                 e.think = Item_RespawnThink;
 728                 e.nextthink = time;
 729                 e.scheduledrespawntime = time + t;
 730                 e.wait = time + t;
 731         }
 732 }
 733
 734 void Item_ScheduleRespawn(entity e)
 735 {
 736         if(e.respawntime > 0)
 737         {
 738                 Item_Show(e, 0);
 739                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 740         }
 741         else // if respawntime is -1, this item does not respawn
 742                 Item_Show(e, -1);
 743 }
 744
 745 void Item_ScheduleInitialRespawn(entity e)
 746 {
 747         Item_Show(e, 0);
 748         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 749 }
 750
 751 float Item_GiveAmmoTo(entity item, entity player, .float ammotype, float ammomax, float mode)
 752 {
 753         if (!item.(ammotype))
 754                 return false;
 755
 756         if (item.spawnshieldtime)
 757         {
 758                 if ((player.(ammotype) < ammomax) || item.pickup_anyway)
 759                 {
 760                         player.(ammotype) = bound(player.(ammotype), ammomax, player.(ammotype) + item.(ammotype));
 761                         goto YEAH;
 762                 }
 763         }
 764         else if(g_weapon_stay == 2)
 765         {
 766                 float mi = min(item.(ammotype), ammomax);
 767                 if (player.(ammotype) < mi)
 768                 {
 769                         player.(ammotype) = mi;
 770                         goto YEAH;
 771                 }
 772         }
 773
 774         return false;
 775
 776 :YEAH
 777         switch(mode)
 778         {
 779                 case ITEM_MODE_FUEL:
 780                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 781                         break;
 782                 case ITEM_MODE_HEALTH:
 783                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 784                         break;
 785                 case ITEM_MODE_ARMOR:
 786                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 787                         break;
 788                 default:
 789                         break;
 790         }
 791         return true;
 792 }
 793
 794 float Item_GiveTo(entity item, entity player)
 795 {
 796         float _switchweapon;
 797         float pickedup;
 798         float it;
 799         float i;
 800
 801         // if nothing happens to player, just return without taking the item
 802         pickedup = false;
 803         _switchweapon = false;
 804         // in case the player has autoswitch enabled do the following:
 805         // if the player is using their best weapon before items are given, they
 806         // probably want to switch to an even better weapon after items are given
 807         if (player.autoswitch)
 808         if (player.switchweapon == w_getbestweapon(player))
 809                 _switchweapon = true;
 810
 811         if (!(player.weapons & WepSet_FromWeapon(player.switchweapon)))
 812                 _switchweapon = true;
 813
 814         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 815         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 816         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 817         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 818         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 819         pickedup |= Item_GiveAmmoTo(item, player, ammo_plasma, g_pickup_plasma_max, ITEM_MODE_NONE);
 820         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 821         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 822
 823         if (item.flags & FL_WEAPON)
 824         {
 825                 WepSet it;
 826                 it = item.weapons;
 827                 it &= ~player.weapons;
 828
 829                 if (it || (item.spawnshieldtime && item.pickup_anyway))
 830                 {
 831                         pickedup = true;
 832                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 833                         if(it & WepSet_FromWeapon(i))
 834                         {
 835                                 W_DropEvent(WR_PICKUP, player, i, item);
 836                                 W_GiveWeapon(player, i);
 837                         }
 838                 }
 839         }
 840
 841         if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 842         {
 843                 pickedup = true;
 844                 player.items |= it;
 845                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 846         }
 847
 848         if (item.strength_finished)
 849         {
 850                 pickedup = true;
 851                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 852         }
 853         if (item.invincible_finished)
 854         {
 855                 pickedup = true;
 856                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 857         }
 858         if (item.superweapons_finished)
 859         {
 860                 pickedup = true;
 861                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 862         }
 863
 864 :skip
 865
 866         // always eat teamed entities
 867         if(item.team)
 868                 pickedup = true;
 869
 870         if (!pickedup)
 871                 return 0;
 872
 873         if (_switchweapon)
 874                 if (player.switchweapon != w_getbestweapon(player))
 875                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 876
 877         return 1;
 878 }
 879
 880 .entity itemdef;
 881
 882 void Item_Touch (void)
 883 {
 884         entity e, head;
 885
 886         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 887         if(self.classname == "droppedweapon")
 888         {
 889                 if (ITEM_TOUCH_NEEDKILL())
 890                 {
 891                         remove(self);
 892                         return;
 893                 }
 894         }
 895
 896         if (!IS_PLAYER(other))
 897                 return;
 898         if (other.frozen)
 899                 return;
 900         if (other.deadflag)
 901                 return;
 902         if (self.solid != SOLID_TRIGGER)
 903                 return;
 904         if (self.owner == other)
 905                 return;
 906         if (time < self.item_spawnshieldtime)
 907                 return;
 908
 909         switch(MUTATOR_CALLHOOK(ItemTouch))
 910         {
 911                 case MUT_ITEMTOUCH_RETURN: { return; }
 912                 case MUT_ITEMTOUCH_PICKUP: { goto pickup; }
 913         }
 914
 915         if (self.classname == "droppedweapon")
 916         {
 917                 self.strength_finished = max(0, self.strength_finished - time);
 918                 self.invincible_finished = max(0, self.invincible_finished - time);
 919                 self.superweapons_finished = max(0, self.superweapons_finished - time);
 920         }
 921         entity it = self.itemdef;
 922         bool gave = (it && it.instanceOfPickup) ? ITEM_HANDLE(Pickup, it, self, other) : Item_GiveTo(self, other);
 923         if (!gave)
 924         {
 925                 if (self.classname == "droppedweapon")
 926                 {
 927                         // undo what we did above
 928                         self.strength_finished += time;
 929                         self.invincible_finished += time;
 930                         self.superweapons_finished += time;
 931                 }
 932                 return;
 933         }
 934
 935         :pickup
 936
 937         other.last_pickup = time;
 938
 939         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 940         sound (other, CH_TRIGGER, self.item_pickupsound, VOL_BASE, ATTEN_NORM);
 941
 942         if (self.classname == "droppedweapon")
 943                 remove (self);
 944         else if (self.spawnshieldtime)
 945         {
 946                 if(self.team)
 947                 {
 948                         RandomSelection_Init();
 949                         for(head = world; (head = findfloat(head, team, self.team)); )
 950                         {
 951                                 if(head.flags & FL_ITEM)
 952                                 {
 953                                         Item_Show(head, -1);
 954                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 955                                 }
 956                         }
 957                         e = RandomSelection_chosen_ent;
 958
 959                 }
 960                 else
 961                         e = self;
 962                 Item_ScheduleRespawn(e);
 963         }
 964 }
 965
 966 void Item_Reset()
 967 {
 968         Item_Show(self, !self.state);
 969         setorigin (self, self.origin);
 970
 971         if(self.classname != "droppedweapon")
 972         {
 973                 self.think = Item_Think;
 974                 self.nextthink = time;
 975
 976                 if(self.waypointsprite_attached)
 977                         WaypointSprite_Kill(self.waypointsprite_attached);
 978
 979                 if((self.flags & FL_POWERUP) || (self.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
 980                         Item_ScheduleInitialRespawn(self);
 981         }
 982 }
 983
 984 void Item_FindTeam()
 985 {
 986         entity head, e;
 987
 988         if(self.effects & EF_NODRAW)
 989         {
 990                 // marker for item team search
 991                 dprint("Initializing item team ", ftos(self.team), "\n");
 992                 RandomSelection_Init();
 993                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 994                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 995                 e = RandomSelection_chosen_ent;
 996                 e.state = 0;
 997                 Item_Show(e, 1);
 998
 999                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
1000                 {
1001                         if(head != e)
1002                         {
1003                                 // make it a non-spawned item
1004                                 Item_Show(head, -1);
1005                                 head.state = 1; // state 1 = initially hidden item
1006                         }
1007                         head.effects &= ~EF_NODRAW;
1008                 }
1009
1010                 Item_Reset();
1011         }
1012 }
1013
1014 // Savage: used for item garbage-collection
1015 // TODO: perhaps nice special effect?
1016 void RemoveItem(void)
1017 {
1018         remove(self);
1019 }
1020
1021 // pickup evaluation functions
1022 // these functions decide how desirable an item is to the bots
1023
1024 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
1025
1026 float weapon_pickupevalfunc(entity player, entity item)
1027 {
1028         float c;
1029
1030         // See if I have it already
1031         if(item.weapons & ~player.weapons)
1032         {
1033                 // If I can pick it up
1034                 if(!item.spawnshieldtime)
1035                         c = 0;
1036                 else if(player.ammo_cells || player.ammo_shells || player.ammo_plasma || player.ammo_nails || player.ammo_rockets)
1037                 {
1038                         // Skilled bots will grab more
1039                         c = bound(0, skill / 10, 1) * 0.5;
1040                 }
1041                 else
1042                         c = 0;
1043         }
1044         else
1045                 c = 1;
1046
1047         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
1048         if( bot_custom_weapon && c )
1049         {
1050                 // Find the highest position on any range
1051                 int position = -1;
1052                 for (int j = 0; j < WEP_LAST ; ++j){
1053                         if(
1054                                         bot_weapons_far[j] == item.weapon ||
1055                                         bot_weapons_mid[j] == item.weapon ||
1056                                         bot_weapons_close[j] == item.weapon
1057                           )
1058                         {
1059                                 position = j;
1060                                 break;
1061                         }
1062                 }
1063
1064                 // Rate it
1065                 if (position >= 0 )
1066                 {
1067                         position = WEP_LAST - position;
1068                         // item.bot_pickupbasevalue is overwritten here
1069                         return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
1070                 }
1071         }
1072
1073         return item.bot_pickupbasevalue * c;
1074 }
1075
1076 float commodity_pickupevalfunc(entity player, entity item)
1077 {
1078         float c, i;
1079         float need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
1080         entity wi;
1081         c = 0;
1082
1083         // Detect needed ammo
1084         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
1085         {
1086                 wi = get_weaponinfo(i);
1087
1088                 if (!(player.weapons & WepSet_FromWeapon(i)))
1089                         continue;
1090
1091                 if(wi.items & IT_SHELLS)
1092                         need_shells = true;
1093                 else if(wi.items & IT_NAILS)
1094                         need_nails = true;
1095                 else if(wi.items & IT_ROCKETS)
1096                         need_rockets = true;
1097                 else if(wi.items & IT_CELLS)
1098                         need_cells = true;
1099                 else if(wi.items & IT_PLASMA)
1100                         need_plasma = true;
1101                 else if(wi.items & IT_FUEL)
1102                         need_fuel = true;
1103         }
1104
1105         // TODO: figure out if the player even has the weapon this ammo is for?
1106         // may not affect strategy much though...
1107         // find out how much more ammo/armor/health the player can hold
1108         if (need_shells)
1109         if (item.ammo_shells)
1110         if (player.ammo_shells < g_pickup_shells_max)
1111                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
1112         if (need_nails)
1113         if (item.ammo_nails)
1114         if (player.ammo_nails < g_pickup_nails_max)
1115                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
1116         if (need_rockets)
1117         if (item.ammo_rockets)
1118         if (player.ammo_rockets < g_pickup_rockets_max)
1119                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
1120         if (need_cells)
1121         if (item.ammo_cells)
1122         if (player.ammo_cells < g_pickup_cells_max)
1123                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
1124         if (need_plasma)
1125         if (item.ammo_plasma)
1126         if (player.ammo_plasma < g_pickup_plasma_max)
1127                 c = c + max(0, 1 - player.ammo_plasma / g_pickup_plasma_max);
1128         if (need_fuel)
1129         if (item.ammo_fuel)
1130         if (player.ammo_fuel < g_pickup_fuel_max)
1131                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
1132         if (item.armorvalue)
1133         if (player.armorvalue < item.max_armorvalue)
1134                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
1135         if (item.health)
1136         if (player.health < item.max_health)
1137                 c = c + max(0, 1 - player.health / item.max_health);
1138
1139         return item.bot_pickupbasevalue * c;
1140 }
1141
1142 void Item_Damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
1143 {
1144         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1145                 RemoveItem();
1146 }
1147
1148 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
1149 {
1150         startitem_failed = false;
1151
1152         if(self.model == "")
1153                 self.model = itemmodel;
1154
1155         if(self.model == "")
1156     {
1157         error(strcat("^1Tried to spawn ", itemname, " with no model!\n"));
1158         return;
1159     }
1160
1161         if(self.item_pickupsound == "")
1162                 self.item_pickupsound = pickupsound;
1163
1164         if(!self.respawntime) // both need to be set
1165         {
1166                 self.respawntime = defaultrespawntime;
1167                 self.respawntimejitter = defaultrespawntimejitter;
1168         }
1169
1170         self.items = itemid;
1171         self.weapon = weaponid;
1172
1173         if(weaponid)
1174                 self.weapons = WepSet_FromWeapon(weaponid);
1175
1176         self.flags = FL_ITEM | itemflags;
1177
1178         if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
1179         {
1180                 startitem_failed = true;
1181                 remove(self);
1182                 return;
1183         }
1184
1185         // is it a dropped weapon?
1186         if (self.classname == "droppedweapon")
1187         {
1188                 self.reset = SUB_Remove;
1189                 // it's a dropped weapon
1190                 self.movetype = MOVETYPE_TOSS;
1191
1192                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1193                 self.think = RemoveItem;
1194                 self.nextthink = time + 20;
1195
1196                 self.takedamage = DAMAGE_YES;
1197                 self.event_damage = Item_Damage;
1198
1199                 if(self.strength_finished || self.invincible_finished || self.superweapons_finished)
1200                 /*
1201                 if(self.items == 0)
1202                 if(!(self.weapons & ~WEPSET_SUPERWEAPONS)) // only superweapons
1203                 if(self.ammo_nails == 0)
1204                 if(self.ammo_cells == 0)
1205                 if(self.ammo_rockets == 0)
1206                 if(self.ammo_shells == 0)
1207                 if(self.ammo_fuel == 0)
1208                 if(self.health == 0)
1209                 if(self.armorvalue == 0)
1210                 */
1211                 {
1212                         // if item is worthless after a timer, have it expire then
1213                         self.nextthink = max(self.strength_finished, self.invincible_finished, self.superweapons_finished);
1214                 }
1215
1216                 // don't drop if in a NODROP zone (such as lava)
1217                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
1218                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1219                 {
1220                         startitem_failed = true;
1221                         remove(self);
1222                         return;
1223                 }
1224         }
1225         else
1226         {
1227                 if(!have_pickup_item())
1228                 {
1229                         startitem_failed = true;
1230                         remove (self);
1231                         return;
1232                 }
1233
1234                 self.reset = Item_Reset;
1235                 // it's a level item
1236                 if(self.spawnflags & 1)
1237                         self.noalign = 1;
1238                 if (self.noalign)
1239                         self.movetype = MOVETYPE_NONE;
1240                 else
1241                         self.movetype = MOVETYPE_TOSS;
1242                 // do item filtering according to game mode and other things
1243                 if (!self.noalign)
1244                 {
1245                         // first nudge it off the floor a little bit to avoid math errors
1246                         setorigin(self, self.origin + '0 0 1');
1247                         // set item size before we spawn a spawnfunc_waypoint
1248                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1249                                 setsize (self, '-16 -16 0', '16 16 48');
1250                         else
1251                                 setsize (self, '-16 -16 0', '16 16 32');
1252
1253                         // note droptofloor returns false if stuck/or would fall too far
1254                         droptofloor();
1255                         waypoint_spawnforitem(self);
1256                 }
1257
1258                 /*
1259                  * can't do it that way, as it would break maps
1260                  * TODO make a target_give like entity another way, that perhaps has
1261                  * the weapon name in a key
1262                 if(self.targetname)
1263                 {
1264                         // target_give not yet supported; maybe later
1265                         print("removed targeted ", self.classname, "\n");
1266                         startitem_failed = true;
1267                         remove (self);
1268                         return;
1269                 }
1270                 */
1271
1272                 if(autocvar_spawn_debug >= 2)
1273                 {
1274                         entity otheritem;
1275                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
1276                         {
1277                             // why not flags & fl_item?
1278                                 if(otheritem.is_item)
1279                                 {
1280                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
1281                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
1282                                         error("Mapper sucks.");
1283                                 }
1284                         }
1285                         self.is_item = true;
1286                 }
1287
1288                 weaponsInMap |= WepSet_FromWeapon(weaponid);
1289
1290                 precache_model (self.model);
1291                 precache_sound (self.item_pickupsound);
1292
1293                 precache_sound ("misc/itemrespawncountdown.wav");
1294                 if(itemid == IT_STRENGTH)
1295                         precache_sound ("misc/strength_respawn.wav");
1296                 else if(itemid == IT_INVINCIBLE)
1297                         precache_sound ("misc/shield_respawn.wav");
1298                 else
1299                         precache_sound ("misc/itemrespawn.wav");
1300
1301                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
1302                         self.target = "###item###"; // for finding the nearest item using find()
1303
1304                 Item_ItemsTime_UpdateTime(self, 0);
1305         }
1306
1307         self.bot_pickup = true;
1308         self.bot_pickupevalfunc = pickupevalfunc;
1309         self.bot_pickupbasevalue = pickupbasevalue;
1310         self.mdl = self.model;
1311         self.netname = itemname;
1312         self.touch = Item_Touch;
1313         setmodel(self, "null"); // precision set below
1314         //self.effects |= EF_LOWPRECISION;
1315
1316         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1317     {
1318         self.pos1 = '-16 -16 0';
1319         self.pos2 = '16 16 48';
1320     }
1321         else
1322     {
1323         self.pos1 = '-16 -16 0';
1324         self.pos2 = '16 16 32';
1325     }
1326     setsize (self, self.pos1, self.pos2);
1327
1328     if(itemflags & FL_POWERUP)
1329         self.ItemStatus |= ITS_ANIMATE1;
1330
1331         if(self.armorvalue || self.health)
1332         self.ItemStatus |= ITS_ANIMATE2;
1333
1334         if(itemflags & FL_WEAPON)
1335         {
1336                 if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1337             self.colormap = 1024; // color shirt=0 pants=0 grey
1338         else
1339             self.gravity = 1;
1340
1341                 self.ItemStatus |= ITS_ANIMATE1;
1342                 self.ItemStatus |= ISF_COLORMAP;
1343         }
1344
1345         self.state = 0;
1346         if(self.team) // broken, no idea why.
1347         {
1348                 if(!self.cnt)
1349                         self.cnt = 1; // item probability weight
1350
1351                 self.effects |= EF_NODRAW; // marker for item team search
1352                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
1353         }
1354         else
1355                 Item_Reset();
1356
1357     Net_LinkEntity(self, false, 0, ItemSend);
1358
1359         self.SendFlags |= ISF_SIZE;
1360         if(self.angles)
1361                 self.SendFlags |= ISF_ANGLES;
1362
1363         // call this hook after everything else has been done
1364         if(MUTATOR_CALLHOOK(Item_Spawn))
1365         {
1366                 startitem_failed = true;
1367                 remove(self);
1368                 return;
1369         }
1370 }
1371
1372 void StartItemA (entity a)
1373 {
1374     self.itemdef = a;
1375     StartItem(a.m_model, a.m_sound, a.m_respawntime(), a.m_respawntimejitter(), a.m_name, a.m_itemid, 0, a.m_itemflags, a.m_pickupevalfunc, a.m_botvalue);
1376 }
1377
1378 void spawnfunc_item_rockets (void) {
1379         if(!self.ammo_rockets)
1380                 self.ammo_rockets = g_pickup_rockets;
1381         if(!self.pickup_anyway)
1382                 self.pickup_anyway = g_pickup_ammo_anyway;
1383     StartItemA (ITEM_Rockets);
1384 }
1385
1386 void spawnfunc_item_bullets (void) {
1387         if(!weaponswapping)
1388         if(autocvar_sv_q3acompat_machineshotgunswap)
1389         if(self.classname != "droppedweapon")
1390         {
1391                 weaponswapping = true;
1392                 spawnfunc_item_shells();
1393                 weaponswapping = false;
1394                 return;
1395         }
1396
1397         if(!self.ammo_nails)
1398                 self.ammo_nails = g_pickup_nails;
1399         if(!self.pickup_anyway)
1400                 self.pickup_anyway = g_pickup_ammo_anyway;
1401     StartItemA (ITEM_Bullets);
1402 }
1403
1404 void spawnfunc_item_cells (void) {
1405         if(!self.ammo_cells)
1406                 self.ammo_cells = g_pickup_cells;
1407         if(!self.pickup_anyway)
1408                 self.pickup_anyway = g_pickup_ammo_anyway;
1409         StartItemA (ITEM_Cells);
1410 }
1411
1412 void spawnfunc_item_plasma()
1413 {
1414         if(!self.ammo_plasma)
1415                 self.ammo_plasma = g_pickup_plasma;
1416         if(!self.pickup_anyway)
1417                 self.pickup_anyway = g_pickup_ammo_anyway;
1418         StartItemA (ITEM_Plasma);
1419 }
1420
1421 void spawnfunc_item_shells (void) {
1422         if(!weaponswapping)
1423         if(autocvar_sv_q3acompat_machineshotgunswap)
1424         if(self.classname != "droppedweapon")
1425         {
1426                 weaponswapping = true;
1427                 spawnfunc_item_bullets();
1428                 weaponswapping = false;
1429                 return;
1430         }
1431
1432         if(!self.ammo_shells)
1433                 self.ammo_shells = g_pickup_shells;
1434         if(!self.pickup_anyway)
1435                 self.pickup_anyway = g_pickup_ammo_anyway;
1436         StartItemA (ITEM_Shells);
1437 }
1438
1439 void spawnfunc_item_armor_small (void) {
1440         if(!self.armorvalue)
1441                 self.armorvalue = g_pickup_armorsmall;
1442         if(!self.max_armorvalue)
1443                 self.max_armorvalue = g_pickup_armorsmall_max;
1444         if(!self.pickup_anyway)
1445                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1446         StartItemA (ITEM_ArmorSmall);
1447 }
1448
1449 void spawnfunc_item_armor_medium (void) {
1450         if(!self.armorvalue)
1451                 self.armorvalue = g_pickup_armormedium;
1452         if(!self.max_armorvalue)
1453                 self.max_armorvalue = g_pickup_armormedium_max;
1454         if(!self.pickup_anyway)
1455                 self.pickup_anyway = g_pickup_armormedium_anyway;
1456         StartItemA (ITEM_ArmorMedium);
1457 }
1458
1459 void spawnfunc_item_armor_big (void) {
1460         if(!self.armorvalue)
1461                 self.armorvalue = g_pickup_armorbig;
1462         if(!self.max_armorvalue)
1463                 self.max_armorvalue = g_pickup_armorbig_max;
1464         if(!self.pickup_anyway)
1465                 self.pickup_anyway = g_pickup_armorbig_anyway;
1466         StartItemA (ITEM_ArmorBig);
1467 }
1468
1469 void spawnfunc_item_armor_large (void) {
1470         if(!self.armorvalue)
1471                 self.armorvalue = g_pickup_armorlarge;
1472         if(!self.max_armorvalue)
1473                 self.max_armorvalue = g_pickup_armorlarge_max;
1474         if(!self.pickup_anyway)
1475                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1476         StartItemA (ITEM_ArmorLarge);
1477 }
1478
1479 void spawnfunc_item_health_small (void) {
1480         if(!self.max_health)
1481                 self.max_health = g_pickup_healthsmall_max;
1482         if(!self.health)
1483                 self.health = g_pickup_healthsmall;
1484         if(!self.pickup_anyway)
1485                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1486         StartItemA (ITEM_HealthSmall);
1487 }
1488
1489 void spawnfunc_item_health_medium (void) {
1490         if(!self.max_health)
1491                 self.max_health = g_pickup_healthmedium_max;
1492         if(!self.health)
1493                 self.health = g_pickup_healthmedium;
1494         if(!self.pickup_anyway)
1495                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1496     StartItemA (ITEM_HealthMedium);
1497 }
1498
1499 void spawnfunc_item_health_large (void) {
1500         if(!self.max_health)
1501                 self.max_health = g_pickup_healthlarge_max;
1502         if(!self.health)
1503                 self.health = g_pickup_healthlarge;
1504         if(!self.pickup_anyway)
1505                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1506         StartItemA (ITEM_HealthLarge);
1507 }
1508
1509 void spawnfunc_item_health_mega (void) {
1510     if(!self.max_health)
1511         self.max_health = g_pickup_healthmega_max;
1512     if(!self.health)
1513         self.health = g_pickup_healthmega;
1514     if(!self.pickup_anyway)
1515         self.pickup_anyway = g_pickup_healthmega_anyway;
1516     StartItemA (ITEM_HealthMega);
1517 }
1518
1519 // support old misnamed entities
1520 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1521 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1522 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1523 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1524 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1525
1526 void spawnfunc_item_strength (void) {
1527                 precache_sound("weapons/strength_fire.wav");
1528                 if(!self.strength_finished)
1529                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1530                 StartItemA (ITEM_Strength);
1531 }
1532
1533 void spawnfunc_item_invincible (void) {
1534                 if(!self.invincible_finished)
1535                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1536                 StartItemA (ITEM_Shield);
1537 }
1538
1539 // compatibility:
1540 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1541
1542 void target_items_use (void)
1543 {
1544         if(activator.classname == "droppedweapon")
1545         {
1546                 EXACTTRIGGER_TOUCH;
1547                 remove(activator);
1548                 return;
1549         }
1550
1551         if (!IS_PLAYER(activator))
1552                 return;
1553         if(activator.deadflag != DEAD_NO)
1554                 return;
1555         EXACTTRIGGER_TOUCH;
1556
1557         entity e;
1558         for(e = world; (e = find(e, classname, "droppedweapon")); )
1559                 if(e.enemy == activator)
1560                         remove(e);
1561
1562         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1563                 centerprint(activator, self.message);
1564 }
1565
1566 void spawnfunc_target_items (void)
1567 {
1568         float n, i, j;
1569         entity e;
1570         string s;
1571
1572         self.use = target_items_use;
1573         if(!self.strength_finished)
1574                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1575         if(!self.invincible_finished)
1576                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1577         if(!self.superweapons_finished)
1578                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1579
1580         precache_sound("misc/itempickup.wav");
1581         precache_sound("misc/megahealth.wav");
1582         precache_sound("misc/armor25.wav");
1583         precache_sound("misc/powerup.wav");
1584         precache_sound("misc/poweroff.wav");
1585         precache_sound("weapons/weaponpickup.wav");
1586
1587         n = tokenize_console(self.netname);
1588         if(argv(0) == "give")
1589         {
1590                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1591         }
1592         else
1593         {
1594                 for(i = 0; i < n; ++i)
1595                 {
1596                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1597                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1598                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1599                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1600                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1601                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1602                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1603                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1604                         else
1605                         {
1606                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1607                                 {
1608                                         e = get_weaponinfo(j);
1609                                         s = W_UndeprecateName(argv(i));
1610                                         if(s == e.netname)
1611                                         {
1612                                                 self.weapons |= WepSet_FromWeapon(j);
1613                                                 if(self.spawnflags == 0 || self.spawnflags == 2)
1614                                                         WEP_ACTION(e.weapon, WR_INIT);
1615                                                 break;
1616                                         }
1617                                 }
1618                                 if(j > WEP_LAST)
1619                                         print("target_items: invalid item ", argv(i), "\n");
1620                         }
1621                 }
1622
1623                 string itemprefix, valueprefix;
1624                 if(self.spawnflags == 0)
1625                 {
1626                         itemprefix = "";
1627                         valueprefix = "";
1628                 }
1629                 else if(self.spawnflags == 1)
1630                 {
1631                         itemprefix = "max ";
1632                         valueprefix = "max ";
1633                 }
1634                 else if(self.spawnflags == 2)
1635                 {
1636                         itemprefix = "min ";
1637                         valueprefix = "min ";
1638                 }
1639                 else if(self.spawnflags == 4)
1640                 {
1641                         itemprefix = "minus ";
1642                         valueprefix = "max ";
1643                 }
1644                 else
1645                 {
1646                         error("invalid spawnflags");
1647                         itemprefix = valueprefix = string_null;
1648                 }
1649
1650                 self.netname = "";
1651                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1652                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1653                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1654                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1655                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * !!(self.items & IT_SUPERWEAPON), "superweapons");
1656                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1657                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1658                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1659                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1660                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1661                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1662                 if(self.ammo_plasma != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_plasma), "plasma");
1663                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1664                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1665                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1666                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1667                 {
1668                         e = get_weaponinfo(j);
1669                         if(e.weapon)
1670                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & WepSet_FromWeapon(j)), e.netname);
1671                 }
1672         }
1673         self.netname = strzone(self.netname);
1674         //print(self.netname, "\n");
1675
1676         n = tokenize_console(self.netname);
1677         for(i = 0; i < n; ++i)
1678         {
1679                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1680                 {
1681                         e = get_weaponinfo(j);
1682                         if(argv(i) == e.netname)
1683                         {
1684                                 WEP_ACTION(e.weapon, WR_INIT);
1685                                 break;
1686                         }
1687                 }
1688         }
1689 }
1690
1691 void spawnfunc_item_fuel(void)
1692 {
1693         if(!self.ammo_fuel)
1694                 self.ammo_fuel = g_pickup_fuel;
1695         if(!self.pickup_anyway)
1696                 self.pickup_anyway = g_pickup_ammo_anyway;
1697         StartItemA (ITEM_JetpackFuel);
1698 }
1699
1700 void spawnfunc_item_fuel_regen(void)
1701 {
1702         if(start_items & IT_FUEL_REGEN)
1703         {
1704                 spawnfunc_item_fuel();
1705                 return;
1706         }
1707         StartItemA (ITEM_JetpackRegen);
1708 }
1709
1710 void spawnfunc_item_jetpack(void)
1711 {
1712         if(!self.ammo_fuel)
1713                 self.ammo_fuel = g_pickup_fuel_jetpack;
1714         if(start_items & IT_JETPACK)
1715         {
1716                 spawnfunc_item_fuel();
1717                 return;
1718         }
1719         StartItemA (ITEM_Jetpack);
1720 }
1721
1722 float GiveWeapon(entity e, float wpn, float op, float val)
1723 {
1724         WepSet v0, v1;
1725         v0 = (e.weapons & WepSet_FromWeapon(wpn));
1726         switch(op)
1727         {
1728                 case OP_SET:
1729                         if(val > 0)
1730                                 e.weapons |= WepSet_FromWeapon(wpn);
1731                         else
1732                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1733                         break;
1734                 case OP_MIN:
1735                 case OP_PLUS:
1736                         if(val > 0)
1737                                 e.weapons |= WepSet_FromWeapon(wpn);
1738                         break;
1739                 case OP_MAX:
1740                         if(val <= 0)
1741                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1742                         break;
1743                 case OP_MINUS:
1744                         if(val > 0)
1745                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1746                         break;
1747         }
1748         v1 = (e.weapons & WepSet_FromWeapon(wpn));
1749         return (v0 != v1);
1750 }
1751
1752 float GiveBit(entity e, .float fld, float bit, float op, float val)
1753 {
1754         float v0, v1;
1755         v0 = (e.(fld) & bit);
1756         switch(op)
1757         {
1758                 case OP_SET:
1759                         if(val > 0)
1760                                 e.(fld) |= bit;
1761                         else
1762                                 e.(fld) &= ~bit;
1763                         break;
1764                 case OP_MIN:
1765                 case OP_PLUS:
1766                         if(val > 0)
1767                                 e.(fld) |= bit;
1768                         break;
1769                 case OP_MAX:
1770                         if(val <= 0)
1771                                 e.(fld) &= ~bit;
1772                         break;
1773                 case OP_MINUS:
1774                         if(val > 0)
1775                                 e.(fld) &= ~bit;
1776                         break;
1777         }
1778         v1 = (e.(fld) & bit);
1779         return (v0 != v1);
1780 }
1781
1782 float GiveValue(entity e, .float fld, float op, float val)
1783 {
1784         float v0, v1;
1785         v0 = e.(fld);
1786         switch(op)
1787         {
1788                 case OP_SET:
1789                         e.(fld) = val;
1790                         break;
1791                 case OP_MIN:
1792                         e.(fld) = max(e.(fld), val); // min 100 cells = at least 100 cells
1793                         break;
1794                 case OP_MAX:
1795                         e.(fld) = min(e.(fld), val);
1796                         break;
1797                 case OP_PLUS:
1798                         e.(fld) += val;
1799                         break;
1800                 case OP_MINUS:
1801                         e.(fld) -= val;
1802                         break;
1803         }
1804         v1 = e.(fld);
1805         return (v0 != v1);
1806 }
1807
1808 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1809 {
1810         if(v1 == v0)
1811                 return;
1812         if(v1 <= v0 - t)
1813         {
1814                 if(snd_decr != "")
1815                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1816         }
1817         else if(v0 >= v0 + t)
1818         {
1819                 if(snd_incr != "")
1820                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1821         }
1822 }
1823
1824 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1825 {
1826         if(v0 < v1)
1827                 e.(rotfield) = max(e.(rotfield), time + rottime);
1828         else if(v0 > v1)
1829                 e.(regenfield) = max(e.(regenfield), time + regentime);
1830 }
1831 float GiveItems(entity e, float beginarg, float endarg)
1832 {
1833         float got, i, j, val, op;
1834         float _switchweapon;
1835         entity wi;
1836         string cmd;
1837
1838         val = 999;
1839         op = OP_SET;
1840
1841         got = 0;
1842
1843         _switchweapon = false;
1844         if (e.autoswitch)
1845                 if (e.switchweapon == w_getbestweapon(e))
1846                         _switchweapon = true;
1847
1848         e.strength_finished = max(0, e.strength_finished - time);
1849         e.invincible_finished = max(0, e.invincible_finished - time);
1850         e.superweapons_finished = max(0, e.superweapons_finished - time);
1851
1852         PREGIVE(e, items);
1853         PREGIVE_WEAPONS(e);
1854         PREGIVE(e, strength_finished);
1855         PREGIVE(e, invincible_finished);
1856         PREGIVE(e, superweapons_finished);
1857         PREGIVE(e, ammo_nails);
1858         PREGIVE(e, ammo_cells);
1859         PREGIVE(e, ammo_plasma);
1860         PREGIVE(e, ammo_shells);
1861         PREGIVE(e, ammo_rockets);
1862         PREGIVE(e, ammo_fuel);
1863         PREGIVE(e, armorvalue);
1864         PREGIVE(e, health);
1865
1866         for(i = beginarg; i < endarg; ++i)
1867         {
1868                 cmd = argv(i);
1869
1870                 if(cmd == "0" || stof(cmd))
1871                 {
1872                         val = stof(cmd);
1873                         continue;
1874                 }
1875                 switch(cmd)
1876                 {
1877                         case "no":
1878                                 op = OP_MAX;
1879                                 val = 0;
1880                                 continue;
1881                         case "max":
1882                                 op = OP_MAX;
1883                                 continue;
1884                         case "min":
1885                                 op = OP_MIN;
1886                                 continue;
1887                         case "plus":
1888                                 op = OP_PLUS;
1889                                 continue;
1890                         case "minus":
1891                                 op = OP_MINUS;
1892                                 continue;
1893                         case "ALL":
1894                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1895                                 got += GiveValue(e, strength_finished, op, val);
1896                                 got += GiveValue(e, invincible_finished, op, val);
1897                                 got += GiveValue(e, superweapons_finished, op, val);
1898                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1899                         case "all":
1900                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1901                                 got += GiveValue(e, health, op, val);
1902                                 got += GiveValue(e, armorvalue, op, val);
1903                         case "allweapons":
1904                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1905                                 {
1906                                         wi = get_weaponinfo(j);
1907                                         if(wi.weapon)
1908                                                 if (!(wi.spawnflags & WEP_FLAG_MUTATORBLOCKED))
1909                                                         got += GiveWeapon(e, j, op, val);
1910                                 }
1911                         case "allammo":
1912                                 got += GiveValue(e, ammo_cells, op, val);
1913                                 got += GiveValue(e, ammo_plasma, op, val);
1914                                 got += GiveValue(e, ammo_shells, op, val);
1915                                 got += GiveValue(e, ammo_nails, op, val);
1916                                 got += GiveValue(e, ammo_rockets, op, val);
1917                                 got += GiveValue(e, ammo_fuel, op, val);
1918                                 break;
1919                         case "unlimited_ammo":
1920                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1921                                 break;
1922                         case "unlimited_weapon_ammo":
1923                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1924                                 break;
1925                         case "unlimited_superweapons":
1926                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1927                                 break;
1928                         case "jetpack":
1929                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1930                                 break;
1931                         case "fuel_regen":
1932                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1933                                 break;
1934                         case "strength":
1935                                 got += GiveValue(e, strength_finished, op, val);
1936                                 break;
1937                         case "invincible":
1938                                 got += GiveValue(e, invincible_finished, op, val);
1939                                 break;
1940                         case "superweapons":
1941                                 got += GiveValue(e, superweapons_finished, op, val);
1942                                 break;
1943                         case "cells":
1944                                 got += GiveValue(e, ammo_cells, op, val);
1945                                 break;
1946                         case "plasma":
1947                                 got += GiveValue(e, ammo_plasma, op, val);
1948                                 break;
1949                         case "shells":
1950                                 got += GiveValue(e, ammo_shells, op, val);
1951                                 break;
1952                         case "nails":
1953                         case "bullets":
1954                                 got += GiveValue(e, ammo_nails, op, val);
1955                                 break;
1956                         case "rockets":
1957                                 got += GiveValue(e, ammo_rockets, op, val);
1958                                 break;
1959                         case "health":
1960                                 got += GiveValue(e, health, op, val);
1961                                 break;
1962                         case "armor":
1963                                 got += GiveValue(e, armorvalue, op, val);
1964                                 break;
1965                         case "fuel":
1966                                 got += GiveValue(e, ammo_fuel, op, val);
1967                                 break;
1968                         default:
1969                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1970                                 {
1971                                         wi = get_weaponinfo(j);
1972                                         if(cmd == wi.netname)
1973                                         {
1974                                                 got += GiveWeapon(e, j, op, val);
1975                                                 break;
1976                                         }
1977                                 }
1978                                 if(j > WEP_LAST)
1979                                         print("give: invalid item ", cmd, "\n");
1980                                 break;
1981                 }
1982                 val = 999;
1983                 op = OP_SET;
1984         }
1985
1986         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1987         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1988         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1989         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1990         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1991         {
1992                 wi = get_weaponinfo(j);
1993                 if(wi.weapon)
1994                 {
1995                         POSTGIVE_WEAPON(e, j, "weapons/weaponpickup.wav", string_null);
1996                         if (!(save_weapons & WepSet_FromWeapon(j)))
1997                                 if(e.weapons & WepSet_FromWeapon(j))
1998                                         WEP_ACTION(wi.weapon, WR_INIT);
1999                 }
2000         }
2001         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
2002         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
2003         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
2004         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
2005         POSTGIVE_VALUE(e, ammo_plasma, 0, "misc/itempickup.wav", string_null);
2006         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
2007         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
2008         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
2009         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
2010         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
2011
2012         if(e.superweapons_finished <= 0)
2013                 if(self.weapons & WEPSET_SUPERWEAPONS)
2014                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
2015
2016         if(e.strength_finished <= 0)
2017                 e.strength_finished = 0;
2018         else
2019                 e.strength_finished += time;
2020         if(e.invincible_finished <= 0)
2021                 e.invincible_finished = 0;
2022         else
2023                 e.invincible_finished += time;
2024         if(e.superweapons_finished <= 0)
2025                 e.superweapons_finished = 0;
2026         else
2027                 e.superweapons_finished += time;
2028
2029         if (!(e.weapons & WepSet_FromWeapon(e.switchweapon)))
2030                 _switchweapon = true;
2031         if(_switchweapon)
2032                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
2033
2034         return got;
2035 }
2036 #endif