qcsrc/server/t_items.qc

   1 #define ISF_LOCATION 2
   2 #define ISF_MODEL    4
   3 #define ISF_STATUS   8
   4     #define ITS_STAYWEP   1
   5     #define ITS_ANIMATE1  2
   6     #define ITS_ANIMATE2  4
   7     #define ITS_AVAILABLE 8
   8     #define ITS_ALLOWFB   16
   9     #define ITS_ALLOWSI   32
  10     #define ITS_POWERUP   64
  11 #define ISF_COLORMAP 16
  12 #define ISF_DROP 32
  13 #define ISF_ANGLES 64
  14
  15 .float ItemStatus;
  16
  17 #ifdef CSQC
  18
  19 var float  autocvar_cl_animate_items = 1;
  20 var float  autocvar_cl_ghost_items = 0.45;
  21 var vector autocvar_cl_ghost_items_color = '-1 -1 -1';
  22 var float  autocvar_cl_fullbright_items = 0;
  23 var vector autocvar_cl_weapon_stay_color = '2 0.5 0.5';
  24 var float  autocvar_cl_weapon_stay_alpha = 0.75;
  25 var float  autocvar_cl_simple_items = 0;
  26 var string autocvr_cl_simpleitems_postfix = "_simple";
  27 .float  spawntime;
  28 .float  gravity;
  29 .vector colormod;
  30 void ItemDraw()
  31 {
  32     if(self.gravity)
  33     {
  34         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  35         if(self.move_flags & FL_ONGROUND)
  36         { // For some reason move_avelocity gets set to '0 0 0' here ...
  37             self.oldorigin = self.origin;
  38             self.gravity = 0;
  39
  40             if(autocvar_cl_animate_items)
  41             { // ... so reset it if animations are requested.
  42                 if(self.ItemStatus & ITS_ANIMATE1)
  43                     self.move_avelocity = '0 180 0';
  44
  45                 if(self.ItemStatus & ITS_ANIMATE2)
  46                     self.move_avelocity = '0 -90 0';
  47             }
  48         }
  49     }
  50     else if (autocvar_cl_animate_items)
  51     {
  52         if(self.ItemStatus & ITS_ANIMATE1)
  53         {
  54             self.angles += self.move_avelocity * frametime;
  55             setorigin(self, '0 0 10' + self.oldorigin + '0 0 8' * sin(time * 2));
  56         }
  57
  58         if(self.ItemStatus & ITS_ANIMATE2)
  59         {
  60             self.angles += self.move_avelocity * frametime;
  61             setorigin(self, '0 0 8' + self.oldorigin + '0 0 4' * sin(time * 3));
  62         }
  63     }
  64 }
  65
  66 void ItemDrawSimple()
  67 {
  68     if(self.gravity)
  69     {
  70         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  71
  72         if(self.move_flags & FL_ONGROUND)
  73             self.gravity = 0;
  74     }
  75 }
  76
  77 void ItemRead(float _IsNew)
  78 {
  79     float sf = ReadByte();
  80
  81     if(sf & ISF_LOCATION)
  82     {
  83         self.origin_x = ReadCoord();
  84         self.origin_y = ReadCoord();
  85         self.origin_z = ReadCoord();
  86         setorigin(self, self.origin);
  87         self.oldorigin = self.origin;
  88     }
  89
  90     if(sf & ISF_ANGLES)
  91     {
  92         self.angles_x = ReadCoord();
  93         self.angles_y = ReadCoord();
  94         self.angles_z = ReadCoord();
  95         self.move_angles = self.angles;
  96     }
  97
  98     if(sf & ISF_STATUS) // need to read/write status frist so model can handle simple, fb etc.
  99     {
 100         self.ItemStatus = ReadByte();
 101
 102         if(self.ItemStatus & ITS_AVAILABLE)
 103         {
 104             self.alpha = 1;
 105             self.colormod = self.glowmod = '1 1 1';
 106         }
 107         else
 108         {
 109             if (autocvar_cl_ghost_items_color)
 110             {
 111                 self.alpha = autocvar_cl_ghost_items;
 112                 self.colormod = self.glowmod = autocvar_cl_ghost_items_color;
 113             }
 114             else
 115                 self.alpha = -1;
 116         }
 117
 118         if(autocvar_cl_fullbright_items)
 119             if(self.ItemStatus & ITS_ALLOWFB)
 120                 self.effects |= EF_FULLBRIGHT;
 121
 122         if(self.ItemStatus & ITS_STAYWEP)
 123         {
 124             self.colormod = self.glowmod = autocvar_cl_weapon_stay_color;
 125             self.alpha = autocvar_cl_weapon_stay_alpha;
 126
 127         }
 128
 129         if(self.ItemStatus & ITS_POWERUP)
 130         {
 131             if(self.ItemStatus & ITS_AVAILABLE)
 132                 self.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 133             else
 134                  self.effects &~= (EF_ADDITIVE | EF_FULLBRIGHT);
 135         }
 136     }
 137
 138     if(sf & ISF_MODEL)
 139     {
 140         self.drawmask  = MASK_NORMAL;
 141         self.movetype  = MOVETYPE_NOCLIP;
 142         self.draw       = ItemDraw;
 143
 144         if(self.mdl)
 145             strunzone(self.mdl);
 146
 147         self.mdl = "";
 148         string _fn = ReadString();
 149
 150         if(autocvar_cl_simple_items && (self.ItemStatus & ITS_ALLOWSI))
 151         {
 152             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 153             self.draw = ItemDrawSimple;
 154
 155
 156
 157             if(fexists(sprintf("%s%s.md3", _fn2, autocvr_cl_simpleitems_postfix)))
 158                 self.mdl = strzone(sprintf("%s%s.md3", _fn2, autocvr_cl_simpleitems_postfix));
 159             else if(fexists(sprintf("%s%s.dpm", _fn2, autocvr_cl_simpleitems_postfix)))
 160                 self.mdl = strzone(sprintf("%s%s.dpm", _fn2, autocvr_cl_simpleitems_postfix));
 161             else if(fexists(sprintf("%s%s.iqm", _fn2, autocvr_cl_simpleitems_postfix)))
 162                 self.mdl = strzone(sprintf("%s%s.iqm", _fn2, autocvr_cl_simpleitems_postfix));
 163             else if(fexists(sprintf("%s%s.obj", _fn2, autocvr_cl_simpleitems_postfix)))
 164                 self.mdl = strzone(sprintf("%s%s.obj", _fn2, autocvr_cl_simpleitems_postfix));
 165             else
 166             {
 167                 self.draw = ItemDraw;
 168                 dprint("Simple item requested for ", _fn, " but no model exsist for it\n");
 169             }
 170         }
 171
 172         if(self.draw != ItemDrawSimple)
 173             self.mdl = strzone(_fn);
 174
 175
 176         if(self.mdl == "")
 177             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, " tell tZork aboute this!\n");
 178
 179         precache_model(self.mdl);
 180         setmodel(self, self.mdl);
 181     }
 182
 183     if(sf & ISF_COLORMAP)
 184         self.colormap = ReadShort();
 185
 186     if(sf & ISF_DROP)
 187     {
 188         self.gravity = 1;
 189         self.move_angles = '0 0 0';
 190         self.move_movetype = MOVETYPE_TOSS;
 191         self.move_velocity_x = ReadCoord();
 192         self.move_velocity_y = ReadCoord();
 193         self.move_velocity_z = ReadCoord();
 194         self.velocity = self.move_velocity;
 195         self.move_origin = self.oldorigin;
 196
 197         if(!self.move_time)
 198         {
 199             self.move_time = time;
 200             self.spawntime = time;
 201         }
 202         else
 203             self.move_time = max(self.move_time, time);
 204     }
 205
 206     if(autocvar_cl_animate_items)
 207     {
 208         if(self.ItemStatus & ITS_ANIMATE1)
 209             self.move_avelocity = '0 180 0';
 210
 211         if(self.ItemStatus & ITS_ANIMATE2)
 212             self.move_avelocity = '0 -90 0';
 213     }
 214 }
 215
 216 #endif
 217
 218 #ifdef SVQC
 219 float autocvar_sv_simple_items;
 220 float ItemSend(entity to, float sf)
 221 {
 222     if(self.gravity)
 223         sf |= ISF_DROP;
 224     else
 225         sf &~= ISF_DROP;
 226
 227         WriteByte(MSG_ENTITY, ENT_CLIENT_ITEM);
 228         WriteByte(MSG_ENTITY, sf);
 229
 230         //WriteByte(MSG_ENTITY, self.cnt);
 231     if(sf & ISF_LOCATION)
 232     {
 233         WriteCoord(MSG_ENTITY, self.origin_x);
 234         WriteCoord(MSG_ENTITY, self.origin_y);
 235         WriteCoord(MSG_ENTITY, self.origin_z);
 236     }
 237
 238     if(sf & ISF_ANGLES)
 239     {
 240         WriteCoord(MSG_ENTITY, self.angles_x);
 241         WriteCoord(MSG_ENTITY, self.angles_y);
 242         WriteCoord(MSG_ENTITY, self.angles_z);
 243     }
 244
 245     if(sf & ISF_STATUS)
 246         WriteByte(MSG_ENTITY, self.ItemStatus);
 247
 248     if(sf & ISF_MODEL)
 249     {
 250
 251         if(self.mdl == "")
 252             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, "exspect a crash just aboute now\n");
 253
 254         WriteString(MSG_ENTITY, self.mdl);
 255     }
 256
 257
 258     if(sf & ISF_COLORMAP)
 259         WriteShort(MSG_ENTITY, self.colormap);
 260
 261     if(sf & ISF_DROP)
 262     {
 263         WriteCoord(MSG_ENTITY, self.velocity_x);
 264         WriteCoord(MSG_ENTITY, self.velocity_y);
 265         WriteCoord(MSG_ENTITY, self.velocity_z);
 266     }
 267
 268     return TRUE;
 269 }
 270
 271
 272 float have_pickup_item(void)
 273 {
 274         if(self.flags & FL_POWERUP)
 275         {
 276                 if(autocvar_g_powerups > 0)
 277                         return TRUE;
 278                 if(autocvar_g_powerups == 0)
 279                         return FALSE;
 280                 if(g_ca)
 281                         return FALSE;
 282                 if(g_arena)
 283                         return FALSE;
 284         }
 285         else
 286         {
 287                 if(autocvar_g_pickup_items > 0)
 288                         return TRUE;
 289                 if(autocvar_g_pickup_items == 0)
 290                         return FALSE;
 291                 if(g_ca)
 292                         return FALSE;
 293                 if(g_weaponarena)
 294                         if(!WEPSET_EMPTY_E(self) || (self.items & IT_AMMO))
 295                                 return FALSE;
 296         }
 297         return TRUE;
 298 }
 299
 300 #define ITEM_RESPAWN_TICKS 10
 301
 302 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
 303         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
 304 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
 305         // range: 10 .. respawntime + respawntimejitter
 306
 307 floatfield Item_CounterField(float it)
 308 {
 309         switch(it)
 310         {
 311                 case IT_SHELLS:      return ammo_shells;
 312                 case IT_NAILS:       return ammo_nails;
 313                 case IT_ROCKETS:     return ammo_rockets;
 314                 case IT_CELLS:       return ammo_cells;
 315                 case IT_FUEL:        return ammo_fuel;
 316                 case IT_5HP:         return health;
 317                 case IT_25HP:        return health;
 318                 case IT_HEALTH:      return health;
 319                 case IT_ARMOR_SHARD: return armorvalue;
 320                 case IT_ARMOR:       return armorvalue;
 321                 // add more things here (health, armor)
 322                 default:             error("requested item has no counter field");
 323         }
 324 #ifdef GMQCC
 325         // should never happen
 326         return health;
 327 #endif
 328 }
 329
 330 string Item_CounterFieldName(float it)
 331 {
 332         switch(it)
 333         {
 334                 case IT_SHELLS:      return "shells";
 335                 case IT_NAILS:       return "nails";
 336                 case IT_ROCKETS:     return "rockets";
 337                 case IT_CELLS:       return "cells";
 338                 case IT_FUEL:        return "fuel";
 339
 340                 // add more things here (health, armor)
 341                 default:             error("requested item has no counter field name");
 342         }
 343 #ifdef GMQCC
 344         // should never happen
 345         return string_null;
 346 #endif
 347 }
 348
 349 .float max_armorvalue;
 350 .float pickup_anyway;
 351 /*
 352 float Item_Customize()
 353 {
 354         if(self.spawnshieldtime)
 355                 return TRUE;
 356         if(!WEPSET_CONTAINS_ALL_EE(other, self))
 357         {
 358                 self.colormod = '0 0 0';
 359                 self.glowmod = self.colormod;
 360                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 361                 return TRUE;
 362         }
 363         else
 364         {
 365                 if(g_ghost_items)
 366                 {
 367                         self.colormod = stov(autocvar_g_ghost_items_color);
 368                         self.glowmod = self.colormod;
 369                         self.alpha = g_ghost_items;
 370                         return TRUE;
 371                 }
 372                 else
 373                         return FALSE;
 374         }
 375 }
 376 */
 377
 378 void Item_Show (entity e, float mode)
 379 {
 380         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
 381         e.ItemStatus &~= ITS_STAYWEP;
 382         if (mode > 0)
 383         {
 384                 // make the item look normal, and be touchable
 385                 e.model = e.mdl;
 386                 e.solid = SOLID_TRIGGER;
 387                 e.spawnshieldtime = 1;
 388                 e.ItemStatus |= ITS_AVAILABLE;
 389         }
 390         else if (mode < 0)
 391         {
 392                 // hide the item completely
 393                 e.model = string_null;
 394                 e.solid = SOLID_NOT;
 395                 e.spawnshieldtime = 1;
 396                 e.ItemStatus &~= ITS_AVAILABLE;
 397         }
 398         else if((e.flags & FL_WEAPON) && !(e.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 399         {
 400                 // make the item translucent and not touchable
 401                 e.model = e.mdl;
 402                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 403                 e.effects |= EF_STARDUST;
 404                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 405                 e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 406         }
 407         else
 408         {
 409                 //setmodel(e, "null");
 410                 e.solid = SOLID_NOT;
 411                 e.colormod = '0 0 0';
 412                 e.glowmod = e.colormod;
 413                 e.spawnshieldtime = 1;
 414                 e.ItemStatus &~= ITS_AVAILABLE;
 415         }
 416
 417         if (e.items & IT_STRENGTH || e.items & IT_INVINCIBLE)
 418             e.ItemStatus |= ITS_POWERUP;
 419
 420         if (autocvar_g_nodepthtestitems)
 421                 e.effects |= EF_NODEPTHTEST;
 422
 423
 424     if (autocvar_g_fullbrightitems)
 425                 e.ItemStatus |= ITS_ALLOWFB;
 426
 427         if (autocvar_sv_simple_items)
 428         e.ItemStatus |= ITS_ALLOWSI;
 429
 430         // relink entity (because solid may have changed)
 431         setorigin(e, e.origin);
 432     e.SendFlags |= ISF_STATUS;
 433 }
 434
 435 void Item_Respawn (void)
 436 {
 437         Item_Show(self, 1);
 438         // this is ugly...
 439         if(self.items == IT_STRENGTH)
 440                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
 441         else if(self.items == IT_INVINCIBLE)
 442                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 443         else
 444                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);  // play respawn sound
 445         setorigin (self, self.origin);
 446
 447         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 448         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 449 }
 450
 451 void Item_RespawnCountdown (void)
 452 {
 453         if(self.count >= ITEM_RESPAWN_TICKS)
 454         {
 455                 if(self.waypointsprite_attached)
 456                         WaypointSprite_Kill(self.waypointsprite_attached);
 457                 Item_Respawn();
 458         }
 459         else
 460         {
 461                 self.nextthink = time + 1;
 462                 self.count += 1;
 463                 if(self.count == 1)
 464                 {
 465                         string name;
 466                         vector rgb = '1 0 1';
 467                         name = string_null;
 468                         switch(self.items)
 469                         {
 470                                 case IT_FUEL_REGEN: name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 471                                 case IT_JETPACK:    name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 472                                 case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 473                                 case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 474                         }
 475                         item_name = name;
 476                         item_color = rgb;
 477                         MUTATOR_CALLHOOK(Item_RespawnCountdown);
 478                         name = item_name;
 479                         rgb = item_color;
 480                         if(self.flags & FL_WEAPON)
 481                         {
 482                                 entity wi = get_weaponinfo(self.weapon);
 483                                 if(wi)
 484                                 {
 485                                         name = wi.model2;
 486                                         rgb = '1 0 0';
 487                                 }
 488                         }
 489                         if(name)
 490                         {
 491                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
 492                                 if(self.waypointsprite_attached)
 493                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 494                         }
 495                         else
 496                         {
 497                                 print("Unknown powerup-marked item is wanting to respawn\n");
 498                                 localcmd(sprintf("prvm_edict server %d\n", num_for_edict(self)));
 499                         }
 500                 }
 501                 sound (self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM); // play respawn sound
 502                 if(self.waypointsprite_attached)
 503                 {
 504                         WaypointSprite_Ping(self.waypointsprite_attached);
 505                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 506                 }
 507         }
 508 }
 509
 510 void Item_ScheduleRespawnIn(entity e, float t)
 511 {
 512         if((e.flags & FL_POWERUP) || WEPSET_CONTAINS_ANY_EA(e, WEPBIT_SUPERWEAPONS))
 513         {
 514                 e.think = Item_RespawnCountdown;
 515                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 516                 e.count = 0;
 517         }
 518         else
 519         {
 520                 e.think = Item_Respawn;
 521                 e.nextthink = time + t;
 522         }
 523 }
 524
 525 void Item_ScheduleRespawn(entity e)
 526 {
 527         if(e.respawntime > 0)
 528         {
 529                 Item_Show(e, 0);
 530                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 531         }
 532         else // if respawntime is -1, this item does not respawn
 533                 Item_Show(e, -1);
 534 }
 535
 536 void Item_ScheduleInitialRespawn(entity e)
 537 {
 538         Item_Show(e, 0);
 539         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 540 }
 541
 542 float ITEM_MODE_NONE = 0;
 543 float ITEM_MODE_HEALTH = 1;
 544 float ITEM_MODE_ARMOR = 2;
 545 float ITEM_MODE_FUEL = 3;
 546 float Item_GiveAmmoTo(entity item, entity player, .float ammofield, float ammomax, float mode)
 547 {
 548         if (!item.ammofield)
 549                 return FALSE;
 550
 551         if (item.spawnshieldtime)
 552         {
 553                 if ((player.ammofield < ammomax) || item.pickup_anyway)
 554                 {
 555                         player.ammofield = bound(player.ammofield, ammomax, player.ammofield + item.ammofield);
 556                         goto YEAH;
 557                 }
 558         }
 559         else if(g_weapon_stay == 2)
 560         {
 561                 float mi = min(item.ammofield, ammomax);
 562                 if (player.ammofield < mi)
 563                 {
 564                         player.ammofield = mi;
 565                         goto YEAH;
 566                 }
 567         }
 568
 569         return FALSE;
 570
 571 :YEAH
 572         switch(mode)
 573         {
 574                 case ITEM_MODE_FUEL:
 575                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 576                         break;
 577                 case ITEM_MODE_HEALTH:
 578                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 579                         break;
 580                 case ITEM_MODE_ARMOR:
 581                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 582                         break;
 583                 default:
 584                         break;
 585         }
 586         return TRUE;
 587 }
 588
 589 float Item_GiveTo(entity item, entity player)
 590 {
 591         float _switchweapon;
 592         float pickedup;
 593         float it;
 594         float i;
 595
 596         // if nothing happens to player, just return without taking the item
 597         pickedup = FALSE;
 598         _switchweapon = FALSE;
 599         // in case the player has autoswitch enabled do the following:
 600         // if the player is using their best weapon before items are given, they
 601         // probably want to switch to an even better weapon after items are given
 602         if (player.autoswitch)
 603         if (player.switchweapon == w_getbestweapon(player))
 604                 _switchweapon = TRUE;
 605
 606         if not(WEPSET_CONTAINS_EW(player, player.switchweapon))
 607                 _switchweapon = TRUE;
 608
 609         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 610         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 611         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 612         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 613         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 614         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 615         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 616
 617         if (item.flags & FL_WEAPON)
 618         {
 619                 WEPSET_DECLARE_A(it);
 620                 WEPSET_COPY_AE(it, item);
 621                 WEPSET_ANDNOT_AE(it, player);
 622
 623                 if (!WEPSET_EMPTY_A(it) || (item.spawnshieldtime && item.pickup_anyway))
 624                 {
 625                         pickedup = TRUE;
 626                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 627                         if(WEPSET_CONTAINS_AW(it, i))
 628                                 W_GiveWeapon(player, i);
 629                 }
 630         }
 631
 632         if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 633         {
 634                 pickedup = TRUE;
 635                 player.items |= it;
 636                 sprint (player, strcat("You got the ^2", item.netname, "\n"));
 637         }
 638
 639         if (item.strength_finished)
 640         {
 641                 pickedup = TRUE;
 642                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 643         }
 644         if (item.invincible_finished)
 645         {
 646                 pickedup = TRUE;
 647                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 648         }
 649         if (item.superweapons_finished)
 650         {
 651                 pickedup = TRUE;
 652                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 653         }
 654
 655 :skip
 656
 657         // always eat teamed entities
 658         if(item.team)
 659                 pickedup = TRUE;
 660
 661         if (!pickedup)
 662                 return 0;
 663
 664         if (_switchweapon)
 665                 if (player.switchweapon != w_getbestweapon(player))
 666                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 667
 668         return 1;
 669 }
 670
 671 void Item_Touch (void)
 672 {
 673         entity e, head;
 674
 675         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 676         if(self.classname == "droppedweapon")
 677         {
 678                 if (ITEM_TOUCH_NEEDKILL())
 679                 {
 680                         remove(self);
 681                         return;
 682                 }
 683         }
 684
 685         if not(IS_PLAYER(other))
 686                 return;
 687         if (other.deadflag)
 688                 return;
 689         if (self.solid != SOLID_TRIGGER)
 690                 return;
 691         if (self.owner == other)
 692                 return;
 693
 694         switch(MUTATOR_CALLHOOK(ItemTouch))
 695         {
 696                 case MUT_ITEMTOUCH_RETURN: { return; }
 697                 case MUT_ITEMTOUCH_PICKUP: { goto pickup; }
 698         }
 699
 700         if (self.classname == "droppedweapon")
 701         {
 702                 self.strength_finished = max(0, self.strength_finished - time);
 703                 self.invincible_finished = max(0, self.invincible_finished - time);
 704                 self.superweapons_finished = max(0, self.superweapons_finished - time);
 705         }
 706
 707         if(!Item_GiveTo(self, other))
 708         {
 709                 if (self.classname == "droppedweapon")
 710                 {
 711                         // undo what we did above
 712                         self.strength_finished += time;
 713                         self.invincible_finished += time;
 714                         self.superweapons_finished += time;
 715                 }
 716                 return;
 717         }
 718
 719         :pickup
 720
 721         other.last_pickup = time;
 722
 723         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 724         sound (other, CH_TRIGGER, self.item_pickupsound, VOL_BASE, ATTN_NORM);
 725
 726         if (self.classname == "droppedweapon")
 727                 remove (self);
 728         else if not(self.spawnshieldtime)
 729                 return;
 730         else
 731         {
 732                 if(self.team)
 733                 {
 734                         RandomSelection_Init();
 735                         for(head = world; (head = findfloat(head, team, self.team)); )
 736                         {
 737                                 if(head.flags & FL_ITEM)
 738                                 {
 739                                         Item_Show(head, -1);
 740                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 741                                 }
 742                         }
 743                         e = RandomSelection_chosen_ent;
 744
 745                 }
 746                 else
 747                         e = self;
 748                 Item_ScheduleRespawn(e);
 749         }
 750 }
 751
 752 void Item_Reset()
 753 {
 754         Item_Show(self, !self.state);
 755         setorigin (self, self.origin);
 756
 757         if(self.classname != "droppedweapon")
 758         {
 759                 self.think = func_null;
 760                 self.nextthink = 0;
 761
 762                 if(self.waypointsprite_attached)
 763                         WaypointSprite_Kill(self.waypointsprite_attached);
 764
 765                 if((self.flags & FL_POWERUP) | WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // do not spawn powerups initially!
 766                         Item_ScheduleInitialRespawn(self);
 767         }
 768 }
 769
 770 void Item_FindTeam()
 771 {
 772         entity head, e;
 773
 774         if(self.effects & EF_NODRAW)
 775         {
 776                 // marker for item team search
 777                 dprint("Initializing item team ", ftos(self.team), "\n");
 778                 RandomSelection_Init();
 779                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 780                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 781                 e = RandomSelection_chosen_ent;
 782                 e.state = 0;
 783                 Item_Show(e, 1);
 784
 785                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 786                 {
 787                         if(head != e)
 788                         {
 789                                 // make it a non-spawned item
 790                                 Item_Show(head, -1);
 791                                 head.state = 1; // state 1 = initially hidden item
 792                         }
 793                         head.effects &~= EF_NODRAW;
 794                 }
 795
 796                 Item_Reset();
 797         }
 798 }
 799
 800 // Savage: used for item garbage-collection
 801 // TODO: perhaps nice special effect?
 802 void RemoveItem(void)
 803 {
 804         remove(self);
 805 }
 806
 807 // pickup evaluation functions
 808 // these functions decide how desirable an item is to the bots
 809
 810 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 811
 812 float weapon_pickupevalfunc(entity player, entity item)
 813 {
 814         float c, j, position;
 815
 816         // See if I have it already
 817         if(!WEPSET_CONTAINS_ALL_EE(player, item))
 818         {
 819                 // If I can pick it up
 820                 if(!item.spawnshieldtime)
 821                         c = 0;
 822                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 823                 {
 824                         // Skilled bots will grab more
 825                         c = bound(0, skill / 10, 1) * 0.5;
 826                 }
 827                 else
 828                         c = 0;
 829         }
 830         else
 831                 c = 1;
 832
 833         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 834         if( bot_custom_weapon && c )
 835         {
 836                 // Find the highest position on any range
 837                 position = -1;
 838                 for(j = 0; j < WEP_LAST ; ++j){
 839                         if(
 840                                         bot_weapons_far[j] == item.weapon ||
 841                                         bot_weapons_mid[j] == item.weapon ||
 842                                         bot_weapons_close[j] == item.weapon
 843                           )
 844                         {
 845                                 position = j;
 846                                 break;
 847                         }
 848                 }
 849
 850                 // Rate it
 851                 if (position >= 0 )
 852                 {
 853                         position = WEP_LAST - position;
 854                         // item.bot_pickupbasevalue is overwritten here
 855                         return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 856                 }
 857         }
 858
 859         return item.bot_pickupbasevalue * c;
 860 }
 861
 862 float commodity_pickupevalfunc(entity player, entity item)
 863 {
 864         float c, i;
 865         float need_shells = FALSE, need_nails = FALSE, need_rockets = FALSE, need_cells = FALSE, need_fuel = FALSE;
 866         entity wi;
 867         c = 0;
 868
 869         // Detect needed ammo
 870         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 871         {
 872                 wi = get_weaponinfo(i);
 873
 874                 if not(WEPSET_CONTAINS_EW(player, i))
 875                         continue;
 876
 877                 if(wi.items & IT_SHELLS)
 878                         need_shells = TRUE;
 879                 else if(wi.items & IT_NAILS)
 880                         need_nails = TRUE;
 881                 else if(wi.items & IT_ROCKETS)
 882                         need_rockets = TRUE;
 883                 else if(wi.items & IT_CELLS)
 884                         need_cells = TRUE;
 885                 else if(wi.items & IT_FUEL)
 886                         need_cells = TRUE;
 887         }
 888
 889         // TODO: figure out if the player even has the weapon this ammo is for?
 890         // may not affect strategy much though...
 891         // find out how much more ammo/armor/health the player can hold
 892         if (need_shells)
 893         if (item.ammo_shells)
 894         if (player.ammo_shells < g_pickup_shells_max)
 895                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 896         if (need_nails)
 897         if (item.ammo_nails)
 898         if (player.ammo_nails < g_pickup_nails_max)
 899                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 900         if (need_rockets)
 901         if (item.ammo_rockets)
 902         if (player.ammo_rockets < g_pickup_rockets_max)
 903                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 904         if (need_cells)
 905         if (item.ammo_cells)
 906         if (player.ammo_cells < g_pickup_cells_max)
 907                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 908         if (need_fuel)
 909         if (item.ammo_fuel)
 910         if (player.ammo_fuel < g_pickup_fuel_max)
 911                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
 912         if (item.armorvalue)
 913         if (player.armorvalue < item.max_armorvalue)
 914                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 915         if (item.health)
 916         if (player.health < item.max_health)
 917                 c = c + max(0, 1 - player.health / item.max_health);
 918
 919         return item.bot_pickupbasevalue * c;
 920 }
 921
 922 void Item_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 923 {
 924         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 925                 RemoveItem();
 926 }
 927
 928 .float is_item;
 929 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 930 {
 931         startitem_failed = FALSE;
 932
 933         if(self.model == "")
 934                 self.model = itemmodel;
 935
 936         if(self.model == "")
 937     {
 938         error(strcat("^1Tried to spawn ", itemname, " with no model!\n"));
 939         return;
 940     }
 941
 942         if(self.item_pickupsound == "")
 943                 self.item_pickupsound = pickupsound;
 944
 945         if(!self.respawntime) // both need to be set
 946         {
 947                 self.respawntime = defaultrespawntime;
 948                 self.respawntimejitter = defaultrespawntimejitter;
 949         }
 950
 951         self.items = itemid;
 952         self.weapon = weaponid;
 953
 954         if(weaponid)
 955                 WEPSET_COPY_EW(self, weaponid);
 956
 957         self.flags = FL_ITEM | itemflags;
 958
 959         if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
 960         {
 961                 startitem_failed = TRUE;
 962                 remove(self);
 963                 return;
 964         }
 965
 966         // is it a dropped weapon?
 967         if (self.classname == "droppedweapon")
 968         {
 969                 self.reset = SUB_Remove;
 970                 // it's a dropped weapon
 971                 self.movetype = MOVETYPE_TOSS;
 972
 973                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 974                 self.think = RemoveItem;
 975                 self.nextthink = time + 20;
 976
 977                 self.takedamage = DAMAGE_YES;
 978                 self.event_damage = Item_Damage;
 979
 980                 if(self.strength_finished || self.invincible_finished || self.superweapons_finished)
 981                 /*
 982                 if(self.items == 0)
 983                 if(WEPSET_CONTAINS_ALL_AE(WEPBIT_SUPERWEAPONS, self)) // only superweapons
 984                 if(self.ammo_nails == 0)
 985                 if(self.ammo_cells == 0)
 986                 if(self.ammo_rockets == 0)
 987                 if(self.ammo_shells == 0)
 988                 if(self.ammo_fuel == 0)
 989                 if(self.health == 0)
 990                 if(self.armorvalue == 0)
 991                 */
 992                 {
 993                         // if item is worthless after a timer, have it expire then
 994                         self.nextthink = max(self.strength_finished, self.invincible_finished, self.superweapons_finished);
 995                 }
 996
 997                 // don't drop if in a NODROP zone (such as lava)
 998                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 999                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1000                 {
1001                         startitem_failed = TRUE;
1002                         remove(self);
1003                         return;
1004                 }
1005         }
1006         else
1007         {
1008                 if(!have_pickup_item())
1009                 {
1010                         startitem_failed = TRUE;
1011                         remove (self);
1012                         return;
1013                 }
1014
1015                 if(self.angles != '0 0 0')
1016             self.SendFlags |= ISF_ANGLES;
1017
1018                 self.reset = Item_Reset;
1019                 // it's a level item
1020                 if(self.spawnflags & 1)
1021                         self.noalign = 1;
1022                 if (self.noalign)
1023                         self.movetype = MOVETYPE_NONE;
1024                 else
1025                         self.movetype = MOVETYPE_TOSS;
1026                 // do item filtering according to game mode and other things
1027                 if (!self.noalign)
1028                 {
1029                         // first nudge it off the floor a little bit to avoid math errors
1030                         setorigin(self, self.origin + '0 0 1');
1031                         // set item size before we spawn a spawnfunc_waypoint
1032                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1033                                 setsize (self, '-16 -16 0', '16 16 48');
1034                         else
1035                                 setsize (self, '-16 -16 0', '16 16 32');
1036                         // note droptofloor returns FALSE if stuck/or would fall too far
1037                         droptofloor();
1038                         waypoint_spawnforitem(self);
1039                 }
1040
1041                 /*
1042                  * can't do it that way, as it would break maps
1043                  * TODO make a target_give like entity another way, that perhaps has
1044                  * the weapon name in a key
1045                 if(self.targetname)
1046                 {
1047                         // target_give not yet supported; maybe later
1048                         print("removed targeted ", self.classname, "\n");
1049                         startitem_failed = TRUE;
1050                         remove (self);
1051                         return;
1052                 }
1053                 */
1054
1055                 if(autocvar_spawn_debug >= 2)
1056                 {
1057                         entity otheritem;
1058                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
1059                         {
1060                             // why not flags & fl_item?
1061                                 if(otheritem.is_item)
1062                                 {
1063                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
1064                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
1065                                         error("Mapper sucks.");
1066                                 }
1067                         }
1068                         self.is_item = TRUE;
1069                 }
1070
1071                 WEPSET_OR_AW(weaponsInMap, weaponid);
1072
1073                 precache_model (self.model);
1074                 precache_sound (self.item_pickupsound);
1075
1076                 precache_sound ("misc/itemrespawncountdown.wav");
1077                 if(itemid == IT_STRENGTH)
1078                         precache_sound ("misc/strength_respawn.wav");
1079                 else if(itemid == IT_INVINCIBLE)
1080                         precache_sound ("misc/shield_respawn.wav");
1081                 else
1082                         precache_sound ("misc/itemrespawn.wav");
1083
1084                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
1085                         self.target = "###item###"; // for finding the nearest item using find()
1086         }
1087
1088         self.bot_pickup = TRUE;
1089         self.bot_pickupevalfunc = pickupevalfunc;
1090         self.bot_pickupbasevalue = pickupbasevalue;
1091         self.mdl = self.model;
1092         self.netname = itemname;
1093         self.touch = Item_Touch;
1094         setmodel(self, "null"); // precision set below
1095         //self.effects |= EF_LOWPRECISION;
1096
1097         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1098     {
1099         self.pos1 = '-16 -16 0';
1100         self.pos2 = '16 16 48';
1101     }
1102         else
1103     {
1104         self.pos1 = '-16 -16 0';
1105         self.pos2 = '16 16 32';
1106     }
1107     setsize (self, self.pos1, self.pos2);
1108
1109     if(itemflags & FL_POWERUP)
1110         self.ItemStatus |= ITS_ANIMATE1;
1111
1112         if(self.armorvalue || self.health)
1113         self.ItemStatus |= ITS_ANIMATE2;
1114
1115         if(itemflags & FL_WEAPON)
1116         {
1117                 if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1118             self.colormap = 1024; // color shirt=0 pants=0 grey
1119         else
1120             self.gravity = 1;
1121
1122                 self.ItemStatus |= ITS_ANIMATE1;
1123                 self.ItemStatus |= ISF_COLORMAP;
1124         }
1125
1126         self.state = 0;
1127         if(self.team) // broken, no idea why.
1128         {
1129                 if(!self.cnt)
1130                         self.cnt = 1; // item probability weight
1131
1132                 self.effects |= EF_NODRAW; // marker for item team search
1133                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
1134         }
1135         else
1136                 Item_Reset();
1137
1138     Net_LinkEntity(self, FALSE, 0, ItemSend);
1139
1140         // call this hook after everything else has been done
1141         if(MUTATOR_CALLHOOK(Item_Spawn))
1142         {
1143                 startitem_failed = TRUE;
1144                 remove(self);
1145                 return;
1146         }
1147 }
1148
1149 void spawnfunc_item_rockets (void) {
1150         if(!self.ammo_rockets)
1151                 self.ammo_rockets = g_pickup_rockets;
1152         if(!self.pickup_anyway)
1153                 self.pickup_anyway = g_pickup_ammo_anyway;
1154         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1155 }
1156
1157 void spawnfunc_item_shells (void);
1158 void spawnfunc_item_bullets (void) {
1159         if(!weaponswapping)
1160         if(autocvar_sv_q3acompat_machineshotgunswap)
1161         if(self.classname != "droppedweapon")
1162         {
1163                 weaponswapping = TRUE;
1164                 spawnfunc_item_shells();
1165                 weaponswapping = FALSE;
1166                 return;
1167         }
1168
1169         if(!self.ammo_nails)
1170                 self.ammo_nails = g_pickup_nails;
1171         if(!self.pickup_anyway)
1172                 self.pickup_anyway = g_pickup_ammo_anyway;
1173         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1174 }
1175
1176 void spawnfunc_item_cells (void) {
1177         if(!self.ammo_cells)
1178                 self.ammo_cells = g_pickup_cells;
1179         if(!self.pickup_anyway)
1180                 self.pickup_anyway = g_pickup_ammo_anyway;
1181         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1182 }
1183
1184 void spawnfunc_item_shells (void) {
1185         if(!weaponswapping)
1186         if(autocvar_sv_q3acompat_machineshotgunswap)
1187         if(self.classname != "droppedweapon")
1188         {
1189                 weaponswapping = TRUE;
1190                 spawnfunc_item_bullets();
1191                 weaponswapping = FALSE;
1192                 return;
1193         }
1194
1195         if(!self.ammo_shells)
1196                 self.ammo_shells = g_pickup_shells;
1197         if(!self.pickup_anyway)
1198                 self.pickup_anyway = g_pickup_ammo_anyway;
1199         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1200 }
1201
1202 void spawnfunc_item_armor_small (void) {
1203         if(!self.armorvalue)
1204                 self.armorvalue = g_pickup_armorsmall;
1205         if(!self.max_armorvalue)
1206                 self.max_armorvalue = g_pickup_armorsmall_max;
1207         if(!self.pickup_anyway)
1208                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1209         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1210 }
1211
1212 void spawnfunc_item_armor_medium (void) {
1213         if(!self.armorvalue)
1214                 self.armorvalue = g_pickup_armormedium;
1215         if(!self.max_armorvalue)
1216                 self.max_armorvalue = g_pickup_armormedium_max;
1217         if(!self.pickup_anyway)
1218                 self.pickup_anyway = g_pickup_armormedium_anyway;
1219         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1220 }
1221
1222 void spawnfunc_item_armor_big (void) {
1223         if(!self.armorvalue)
1224                 self.armorvalue = g_pickup_armorbig;
1225         if(!self.max_armorvalue)
1226                 self.max_armorvalue = g_pickup_armorbig_max;
1227         if(!self.pickup_anyway)
1228                 self.pickup_anyway = g_pickup_armorbig_anyway;
1229         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1230 }
1231
1232 void spawnfunc_item_armor_large (void) {
1233         if(!self.armorvalue)
1234                 self.armorvalue = g_pickup_armorlarge;
1235         if(!self.max_armorvalue)
1236                 self.max_armorvalue = g_pickup_armorlarge_max;
1237         if(!self.pickup_anyway)
1238                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1239         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1240 }
1241
1242 void spawnfunc_item_health_small (void) {
1243         if(!self.max_health)
1244                 self.max_health = g_pickup_healthsmall_max;
1245         if(!self.health)
1246                 self.health = g_pickup_healthsmall;
1247         if(!self.pickup_anyway)
1248                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1249         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1250 }
1251
1252 void spawnfunc_item_health_medium (void) {
1253         if(!self.max_health)
1254                 self.max_health = g_pickup_healthmedium_max;
1255         if(!self.health)
1256                 self.health = g_pickup_healthmedium;
1257         if(!self.pickup_anyway)
1258                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1259         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1260 }
1261
1262 void spawnfunc_item_health_large (void) {
1263         if(!self.max_health)
1264                 self.max_health = g_pickup_healthlarge_max;
1265         if(!self.health)
1266                 self.health = g_pickup_healthlarge;
1267         if(!self.pickup_anyway)
1268                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1269         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1270 }
1271
1272 void spawnfunc_item_health_mega (void) {
1273                 if(!self.max_health)
1274                         self.max_health = g_pickup_healthmega_max;
1275                 if(!self.health)
1276                         self.health = g_pickup_healthmega;
1277                 if(!self.pickup_anyway)
1278                         self.pickup_anyway = g_pickup_healthmega_anyway;
1279                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1280 }
1281
1282 // support old misnamed entities
1283 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1284 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1285 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1286 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1287 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1288
1289 void spawnfunc_item_strength (void) {
1290                 precache_sound("weapons/strength_fire.wav");
1291                 if(!self.strength_finished)
1292                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1293                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1294 }
1295
1296 void spawnfunc_item_invincible (void) {
1297                 if(!self.invincible_finished)
1298                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1299                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1300 }
1301
1302 // compatibility:
1303 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1304
1305 float GiveItems(entity e, float beginarg, float endarg);
1306 void target_items_use (void)
1307 {
1308         if(activator.classname == "droppedweapon")
1309         {
1310                 EXACTTRIGGER_TOUCH;
1311                 remove(activator);
1312                 return;
1313         }
1314
1315         if not(IS_PLAYER(activator))
1316                 return;
1317         if(activator.deadflag != DEAD_NO)
1318                 return;
1319         EXACTTRIGGER_TOUCH;
1320
1321         entity e;
1322         for(e = world; (e = find(e, classname, "droppedweapon")); )
1323                 if(e.enemy == activator)
1324                         remove(e);
1325
1326         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1327                 centerprint(activator, self.message);
1328 }
1329
1330 void spawnfunc_target_items (void)
1331 {
1332         float n, i, j;
1333         entity e;
1334
1335         self.use = target_items_use;
1336         if(!self.strength_finished)
1337                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1338         if(!self.invincible_finished)
1339                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1340         if(!self.superweapons_finished)
1341                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1342
1343         precache_sound("misc/itempickup.wav");
1344         precache_sound("misc/megahealth.wav");
1345         precache_sound("misc/armor25.wav");
1346         precache_sound("misc/powerup.wav");
1347         precache_sound("misc/poweroff.wav");
1348         precache_sound("weapons/weaponpickup.wav");
1349
1350         n = tokenize_console(self.netname);
1351         if(argv(0) == "give")
1352         {
1353                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1354         }
1355         else
1356         {
1357                 for(i = 0; i < n; ++i)
1358                 {
1359                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1360                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1361                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1362                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1363                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1364                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1365                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1366                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1367                         else
1368                         {
1369                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1370                                 {
1371                                         e = get_weaponinfo(j);
1372                                         if(argv(i) == e.netname)
1373                                         {
1374                                                 WEPSET_OR_EW(self, j);
1375                                                 if(self.spawnflags == 0 || self.spawnflags == 2)
1376                                                         WEP_ACTION(e.weapon, WR_PRECACHE);
1377                                                 break;
1378                                         }
1379                                 }
1380                                 if(j > WEP_LAST)
1381                                         print("target_items: invalid item ", argv(i), "\n");
1382                         }
1383                 }
1384
1385                 string itemprefix, valueprefix;
1386                 if(self.spawnflags == 0)
1387                 {
1388                         itemprefix = "";
1389                         valueprefix = "";
1390                 }
1391                 else if(self.spawnflags == 1)
1392                 {
1393                         itemprefix = "max ";
1394                         valueprefix = "max ";
1395                 }
1396                 else if(self.spawnflags == 2)
1397                 {
1398                         itemprefix = "min ";
1399                         valueprefix = "min ";
1400                 }
1401                 else if(self.spawnflags == 4)
1402                 {
1403                         itemprefix = "minus ";
1404                         valueprefix = "max ";
1405                 }
1406                 else
1407                 {
1408                         error("invalid spawnflags");
1409 #ifdef GMQCC
1410                         itemprefix = string_null;
1411                         valueprefix = string_null;
1412 #endif
1413                 }
1414
1415                 self.netname = "";
1416                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1417                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1418                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1419                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1420                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * !!(self.items & IT_SUPERWEAPON), "superweapons");
1421                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1422                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1423                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1424                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1425                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1426                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1427                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1428                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1429                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1430                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1431                 {
1432                         e = get_weaponinfo(j);
1433                         if(e.weapon)
1434                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, WEPSET_CONTAINS_EW(self, j), e.netname);
1435                 }
1436         }
1437         self.netname = strzone(self.netname);
1438         //print(self.netname, "\n");
1439
1440         n = tokenize_console(self.netname);
1441         for(i = 0; i < n; ++i)
1442         {
1443                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1444                 {
1445                         e = get_weaponinfo(j);
1446                         if(argv(i) == e.netname)
1447                         {
1448                                 WEP_ACTION(e.weapon, WR_PRECACHE);
1449                                 break;
1450                         }
1451                 }
1452         }
1453 }
1454
1455 void spawnfunc_item_fuel(void)
1456 {
1457         if(!self.ammo_fuel)
1458                 self.ammo_fuel = g_pickup_fuel;
1459         if(!self.pickup_anyway)
1460                 self.pickup_anyway = g_pickup_ammo_anyway;
1461         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1462 }
1463
1464 void spawnfunc_item_fuel_regen(void)
1465 {
1466         if(start_items & IT_FUEL_REGEN)
1467         {
1468                 spawnfunc_item_fuel();
1469                 return;
1470         }
1471         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1472 }
1473
1474 void spawnfunc_item_jetpack(void)
1475 {
1476         if(g_grappling_hook)
1477                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1478         if(!self.ammo_fuel)
1479                 self.ammo_fuel = g_pickup_fuel_jetpack;
1480         if(start_items & IT_JETPACK)
1481         {
1482                 spawnfunc_item_fuel();
1483                 return;
1484         }
1485         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1486 }
1487
1488
1489 #define OP_SET 0
1490 #define OP_MIN 1
1491 #define OP_MAX 2
1492 #define OP_PLUS 3
1493 #define OP_MINUS 4
1494
1495 float GiveWeapon(entity e, float wpn, float op, float val)
1496 {
1497         float v0, v1;
1498         v0 = WEPSET_CONTAINS_EW(e, wpn);
1499         switch(op)
1500         {
1501                 case OP_SET:
1502                         if(val > 0)
1503                                 WEPSET_OR_EW(e, wpn);
1504                         else
1505                                 WEPSET_ANDNOT_EW(e, wpn);
1506                         break;
1507                 case OP_MIN:
1508                 case OP_PLUS:
1509                         if(val > 0)
1510                                 WEPSET_OR_EW(e, wpn);
1511                         break;
1512                 case OP_MAX:
1513                         if(val <= 0)
1514                                 WEPSET_ANDNOT_EW(e, wpn);
1515                         break;
1516                 case OP_MINUS:
1517                         if(val > 0)
1518                                 WEPSET_ANDNOT_EW(e, wpn);
1519                         break;
1520         }
1521         v1 = WEPSET_CONTAINS_EW(e, wpn);
1522         return (v0 != v1);
1523 }
1524
1525 float GiveBit(entity e, .float fld, float bit, float op, float val)
1526 {
1527         float v0, v1;
1528         v0 = (e.fld & bit);
1529         switch(op)
1530         {
1531                 case OP_SET:
1532                         if(val > 0)
1533                                 e.fld |= bit;
1534                         else
1535                                 e.fld &~= bit;
1536                         break;
1537                 case OP_MIN:
1538                 case OP_PLUS:
1539                         if(val > 0)
1540                                 e.fld |= bit;
1541                         break;
1542                 case OP_MAX:
1543                         if(val <= 0)
1544                                 e.fld &~= bit;
1545                         break;
1546                 case OP_MINUS:
1547                         if(val > 0)
1548                                 e.fld &~= bit;
1549                         break;
1550         }
1551         v1 = (e.fld & bit);
1552         return (v0 != v1);
1553 }
1554
1555 float GiveValue(entity e, .float fld, float op, float val)
1556 {
1557         float v0, v1;
1558         v0 = e.fld;
1559         switch(op)
1560         {
1561                 case OP_SET:
1562                         e.fld = val;
1563                         break;
1564                 case OP_MIN:
1565                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1566                         break;
1567                 case OP_MAX:
1568                         e.fld = min(e.fld, val);
1569                         break;
1570                 case OP_PLUS:
1571                         e.fld += val;
1572                         break;
1573                 case OP_MINUS:
1574                         e.fld -= val;
1575                         break;
1576         }
1577         v1 = e.fld;
1578         return (v0 != v1);
1579 }
1580
1581 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1582 {
1583         if(v1 == v0)
1584                 return;
1585         if(v1 <= v0 - t)
1586         {
1587                 if(snd_decr != "")
1588                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTN_NORM);
1589         }
1590         else if(v0 >= v0 + t)
1591         {
1592                 if(snd_incr != "")
1593                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTN_NORM);
1594         }
1595 }
1596
1597 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1598 {
1599         if(v0 < v1)
1600                 e.rotfield = max(e.rotfield, time + rottime);
1601         else if(v0 > v1)
1602                 e.regenfield = max(e.regenfield, time + regentime);
1603 }
1604
1605 #define PREGIVE_WEAPONS(e) WEPSET_DECLARE_A(save_weapons); WEPSET_COPY_AE(save_weapons, e)
1606 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1607 #define POSTGIVE_WEAPON(e,b,snd_incr,snd_decr) GiveSound((e), WEPSET_CONTAINS_AW(save_weapons, b), WEPSET_CONTAINS_EW(e, b), 0, snd_incr, snd_decr)
1608 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1609 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1610 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1611
1612 float GiveItems(entity e, float beginarg, float endarg)
1613 {
1614         float got, i, j, val, op;
1615         float _switchweapon;
1616         entity wi;
1617         string cmd;
1618
1619         val = 999;
1620         op = OP_SET;
1621
1622         got = 0;
1623
1624         _switchweapon = FALSE;
1625         if (e.autoswitch)
1626                 if (e.switchweapon == w_getbestweapon(e))
1627                         _switchweapon = TRUE;
1628
1629         e.strength_finished = max(0, e.strength_finished - time);
1630         e.invincible_finished = max(0, e.invincible_finished - time);
1631         e.superweapons_finished = max(0, e.superweapons_finished - time);
1632
1633         PREGIVE(e, items);
1634         PREGIVE_WEAPONS(e);
1635         PREGIVE(e, strength_finished);
1636         PREGIVE(e, invincible_finished);
1637         PREGIVE(e, superweapons_finished);
1638         PREGIVE(e, ammo_nails);
1639         PREGIVE(e, ammo_cells);
1640         PREGIVE(e, ammo_shells);
1641         PREGIVE(e, ammo_rockets);
1642         PREGIVE(e, ammo_fuel);
1643         PREGIVE(e, armorvalue);
1644         PREGIVE(e, health);
1645
1646         for(i = beginarg; i < endarg; ++i)
1647         {
1648                 cmd = argv(i);
1649
1650                 if(cmd == "0" || stof(cmd))
1651                 {
1652                         val = stof(cmd);
1653                         continue;
1654                 }
1655                 switch(cmd)
1656                 {
1657                         case "no":
1658                                 op = OP_MAX;
1659                                 val = 0;
1660                                 continue;
1661                         case "max":
1662                                 op = OP_MAX;
1663                                 continue;
1664                         case "min":
1665                                 op = OP_MIN;
1666                                 continue;
1667                         case "plus":
1668                                 op = OP_PLUS;
1669                                 continue;
1670                         case "minus":
1671                                 op = OP_MINUS;
1672                                 continue;
1673                         case "ALL":
1674                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1675                                 got += GiveValue(e, strength_finished, op, val);
1676                                 got += GiveValue(e, invincible_finished, op, val);
1677                                 got += GiveValue(e, superweapons_finished, op, val);
1678                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1679                         case "all":
1680                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1681                                 got += GiveValue(e, health, op, val);
1682                                 got += GiveValue(e, armorvalue, op, val);
1683                         case "allweapons":
1684                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1685                                 {
1686                                         wi = get_weaponinfo(j);
1687                                         if(wi.weapon)
1688                                                 if not(wi.spawnflags & WEP_FLAG_MUTATORBLOCKED)
1689                                                         got += GiveWeapon(e, j, op, val);
1690                                 }
1691                         case "allammo":
1692                                 got += GiveValue(e, ammo_cells, op, val);
1693                                 got += GiveValue(e, ammo_shells, op, val);
1694                                 got += GiveValue(e, ammo_nails, op, val);
1695                                 got += GiveValue(e, ammo_rockets, op, val);
1696                                 got += GiveValue(e, ammo_fuel, op, val);
1697                                 break;
1698                         case "unlimited_ammo":
1699                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1700                                 break;
1701                         case "unlimited_weapon_ammo":
1702                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1703                                 break;
1704                         case "unlimited_superweapons":
1705                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1706                                 break;
1707                         case "jetpack":
1708                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1709                                 break;
1710                         case "fuel_regen":
1711                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1712                                 break;
1713                         case "strength":
1714                                 got += GiveValue(e, strength_finished, op, val);
1715                                 break;
1716                         case "invincible":
1717                                 got += GiveValue(e, invincible_finished, op, val);
1718                                 break;
1719                         case "superweapons":
1720                                 got += GiveValue(e, superweapons_finished, op, val);
1721                                 break;
1722                         case "cells":
1723                                 got += GiveValue(e, ammo_cells, op, val);
1724                                 break;
1725                         case "shells":
1726                                 got += GiveValue(e, ammo_shells, op, val);
1727                                 break;
1728                         case "nails":
1729                         case "bullets":
1730                                 got += GiveValue(e, ammo_nails, op, val);
1731                                 break;
1732                         case "rockets":
1733                                 got += GiveValue(e, ammo_rockets, op, val);
1734                                 break;
1735                         case "health":
1736                                 got += GiveValue(e, health, op, val);
1737                                 break;
1738                         case "armor":
1739                                 got += GiveValue(e, armorvalue, op, val);
1740                                 break;
1741                         case "fuel":
1742                                 got += GiveValue(e, ammo_fuel, op, val);
1743                                 break;
1744                         default:
1745                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1746                                 {
1747                                         wi = get_weaponinfo(j);
1748                                         if(cmd == wi.netname)
1749                                         {
1750                                                 got += GiveWeapon(e, j, op, val);
1751                                                 break;
1752                                         }
1753                                 }
1754                                 if(j > WEP_LAST)
1755                                         print("give: invalid item ", cmd, "\n");
1756                                 break;
1757                 }
1758                 val = 999;
1759                 op = OP_SET;
1760         }
1761
1762         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1763         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1764         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1765         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1766         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1767         {
1768                 wi = get_weaponinfo(j);
1769                 if(wi.weapon)
1770                 {
1771                         POSTGIVE_WEAPON(e, j, "weapons/weaponpickup.wav", string_null);
1772                         if not(WEPSET_CONTAINS_AW(save_weapons, j))
1773                                 if(WEPSET_CONTAINS_EW(e, j))
1774                                         WEP_ACTION(wi.weapon, WR_PRECACHE);
1775                 }
1776         }
1777         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1778         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1779         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1780         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1781         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1782         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1783         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
1784         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
1785         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
1786
1787         if(e.superweapons_finished <= 0)
1788                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1789                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1790
1791         if(e.strength_finished <= 0)
1792                 e.strength_finished = 0;
1793         else
1794                 e.strength_finished += time;
1795         if(e.invincible_finished <= 0)
1796                 e.invincible_finished = 0;
1797         else
1798                 e.invincible_finished += time;
1799         if(e.superweapons_finished <= 0)
1800                 e.superweapons_finished = 0;
1801         else
1802                 e.superweapons_finished += time;
1803
1804         if not(WEPSET_CONTAINS_EW(e, e.switchweapon))
1805                 _switchweapon = TRUE;
1806         if(_switchweapon)
1807                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1808
1809         return got;
1810 }
1811 #endif