qcsrc/server/t_jumppads.qc

   1 float PUSH_ONCE                 = 1;
   2 float PUSH_SILENT               = 2;
   3
   4 .float pushltime;
   5 .float height;
   6
   7 void() SUB_UseTargets;
   8
   9 float trigger_push_calculatevelocity_flighttime;
  10
  11 void trigger_push_use()
  12 {
  13         if(teamplay)
  14                 self.team = activator.team;
  15 }
  16
  17 /*
  18         trigger_push_calculatevelocity
  19
  20         Arguments:
  21           org - origin of the object which is to be pushed
  22           tgt - target entity (can be either a point or a model entity; if it is
  23                 the latter, its midpoint is used)
  24           ht  - jump height, measured from the higher one of org and tgt's midpoint
  25
  26         Returns: velocity for the jump
  27         the global trigger_push_calculatevelocity_flighttime is set to the total
  28         jump time
  29  */
  30
  31 vector trigger_push_calculatevelocity(vector org, entity tgt, float ht)
  32 {
  33         local float grav, sdist, zdist, vs, vz, jumpheight;
  34         local vector sdir, torg;
  35
  36         torg = tgt.origin + (tgt.mins + tgt.maxs) * 0.5;
  37
  38         grav = autocvar_sv_gravity;
  39
  40         zdist = torg_z - org_z;
  41         sdist = vlen(torg - org - zdist * '0 0 1');
  42         sdir = normalize(torg - org - zdist * '0 0 1');
  43
  44         // how high do we need to push the player?
  45         jumpheight = fabs(ht);
  46         if(zdist > 0)
  47                 jumpheight = jumpheight + zdist;
  48
  49         /*
  50                 STOP.
  51
  52                 You will not understand the following equations anyway...
  53                 But here is what I did to get them.
  54
  55                 I used the functions
  56
  57                   s(t) = t * vs
  58                   z(t) = t * vz - 1/2 grav t^2
  59
  60                 and solved for:
  61
  62                   s(ti) = sdist
  63                   z(ti) = zdist
  64                   max(z, ti) = jumpheight
  65
  66                 From these three equations, you will find the three parameters vs, vz
  67                 and ti.
  68          */
  69
  70         // push him so high...
  71         vz = sqrt(2 * grav * jumpheight); // NOTE: sqrt(positive)!
  72
  73         // we start with downwards velocity only if it's a downjump and the jump apex should be outside the jump!
  74         if(ht < 0)
  75                 if(zdist < 0)
  76                         vz = -vz;
  77
  78         vector solution;
  79         solution = solve_quadratic(0.5 * grav, -vz, zdist); // equation "z(ti) = zdist"
  80         // ALWAYS solvable because jumpheight >= zdist
  81         if(!solution_z)
  82                 solution_y = solution_x; // just in case it is not solvable due to roundoff errors, assume two equal solutions at their center (this is mainly for the usual case with ht == 0)
  83         if(zdist == 0)
  84                 solution_x = solution_y; // solution_x is 0 in this case, so don't use it, but rather use solution_y (which will be sqrt(0.5 * jumpheight / grav), actually)
  85
  86         if(zdist < 0)
  87         {
  88                 // down-jump
  89                 if(ht < 0)
  90                 {
  91                         // almost straight line type
  92                         // jump apex is before the jump
  93                         // we must take the larger one
  94                         trigger_push_calculatevelocity_flighttime = solution_y;
  95                 }
  96                 else
  97                 {
  98                         // regular jump
  99                         // jump apex is during the jump
 100                         // we must take the larger one too
 101                         trigger_push_calculatevelocity_flighttime = solution_y;
 102                 }
 103         }
 104         else
 105         {
 106                 // up-jump
 107                 if(ht < 0)
 108                 {
 109                         // almost straight line type
 110                         // jump apex is after the jump
 111                         // we must take the smaller one
 112                         trigger_push_calculatevelocity_flighttime = solution_x;
 113                 }
 114                 else
 115                 {
 116                         // regular jump
 117                         // jump apex is during the jump
 118                         // we must take the larger one
 119                         trigger_push_calculatevelocity_flighttime = solution_y;
 120                 }
 121         }
 122         vs = sdist / trigger_push_calculatevelocity_flighttime;
 123
 124         // finally calculate the velocity
 125         return sdir * vs + '0 0 1' * vz;
 126 }
 127
 128 void trigger_push_touch()
 129 {
 130         vector move;
 131
 132         if (self.active == ACTIVE_NOT)
 133                 return;
 134
 135         if (!isPushable(other))
 136                 return;
 137
 138         if(self.team)
 139                 if((self.spawnflags & 4 == 0) == (self.team != other.team))
 140                         return;
 141
 142         EXACTTRIGGER_TOUCH;
 143
 144         if(self.enemy)
 145         {
 146                 other.velocity = trigger_push_calculatevelocity(other.origin, self.enemy, self.height);
 147         }
 148         else if(self.target)
 149         {
 150                 entity e;
 151                 RandomSelection_Init();
 152                 for(e = world; (e = find(e, targetname, self.target)); )
 153                 {
 154                         if(e.cnt)
 155                                 RandomSelection_Add(e, 0, string_null, e.cnt, 1);
 156                         else
 157                                 RandomSelection_Add(e, 0, string_null, 1, 1);
 158                 }
 159                 other.velocity = trigger_push_calculatevelocity(other.origin, RandomSelection_chosen_ent, self.height);
 160         }
 161         else
 162         {
 163                 other.velocity = self.movedir;
 164         }
 165
 166         other.flags &~= FL_ONGROUND;
 167
 168         if (other.classname == "player")
 169         {
 170                 // reset tracking of oldvelocity for impact damage (sudden velocity changes)
 171                 other.oldvelocity = other.velocity;
 172
 173                 if(self.pushltime < time)  // prevent "snorring" sound when a player hits the jumppad more than once
 174                 {
 175                         // flash when activated
 176                         pointparticles(particleeffectnum("jumppad_activate"), other.origin, other.velocity, 1);
 177                         sound (other, CH_TRIGGER, self.noise, VOL_BASE, ATTN_NORM);
 178                         self.pushltime = time + 0.2;
 179                 }
 180                 local float ct;
 181                 ct = clienttype(other);
 182                 if( ct == CLIENTTYPE_REAL || ct == CLIENTTYPE_BOT)
 183                 {
 184                         local float i;
 185                         local float found;
 186                         found = FALSE;
 187                         for(i = 0; i < other.jumppadcount && i < NUM_JUMPPADSUSED; ++i)
 188                                 if(other.(jumppadsused[i]) == self)
 189                                         found = TRUE;
 190                         if(!found)
 191                         {
 192                                 other.(jumppadsused[mod(other.jumppadcount, NUM_JUMPPADSUSED)]) = self;
 193                                 other.jumppadcount = other.jumppadcount + 1;
 194                         }
 195
 196                         if(ct == CLIENTTYPE_REAL)
 197                         {
 198                                 if(self.message)
 199                                         centerprint(other, self.message);
 200                         }
 201                         else
 202                                 other.lastteleporttime = time;
 203
 204                         if (!other.animstate_override)
 205                         {
 206                                 if (other.crouch)
 207                                         setanim(other, other.anim_duckjump, FALSE, TRUE, TRUE);
 208                                 else
 209                                         setanim(other, other.anim_jump, FALSE, TRUE, TRUE);
 210                         }
 211                 }
 212                 else
 213                         other.jumppadcount = TRUE;
 214
 215                 // reset tracking of who pushed you into a hazard (for kill credit)
 216                 other.pushltime = 0;
 217         }
 218
 219         if(self.enemy.target)
 220         {
 221                 entity oldself;
 222                 oldself = self;
 223                 activator = other;
 224                 self = self.enemy;
 225                 SUB_UseTargets();
 226                 self = oldself;
 227         }
 228
 229         if (other.flags & FL_PROJECTILE)
 230         {
 231                 other.angles = vectoangles (other.velocity);
 232                 switch(other.movetype)
 233                 {
 234                         case MOVETYPE_FLY:
 235                                 other.movetype = MOVETYPE_TOSS;
 236                                 other.gravity = 1;
 237                                 break;
 238                         case MOVETYPE_BOUNCEMISSILE:
 239                                 other.movetype = MOVETYPE_BOUNCE;
 240                                 other.gravity = 1;
 241                                 break;
 242                 }
 243                 UpdateCSQCProjectile(other);
 244         }
 245
 246         if (self.spawnflags & PUSH_ONCE)
 247         {
 248                 self.touch = SUB_Null;
 249                 self.think = SUB_Remove;
 250                 self.nextthink = time;
 251         }
 252 };
 253
 254 .vector dest;
 255 void trigger_push_findtarget()
 256 {
 257         local entity e, t;
 258         local vector org;
 259         local float flighttime;
 260
 261         // first calculate a typical start point for the jump
 262         org = (self.absmin + self.absmax) * 0.5;
 263         org_z = self.absmax_z - PL_MIN_z;
 264
 265         if (self.target)
 266         {
 267                 float n;
 268                 n = 0;
 269                 for(t = world; (t = find(t, targetname, self.target)); )
 270                 {
 271                         ++n;
 272                         e = spawn();
 273                         setorigin(e, org);
 274                         setsize(e, PL_MIN, PL_MAX);
 275                         e.velocity = trigger_push_calculatevelocity(org, t, self.height);
 276                         tracetoss(e, e);
 277                         if(e.movetype == MOVETYPE_NONE)
 278                                 waypoint_spawnforteleporter(self, trace_endpos, vlen(trace_endpos - org) / vlen(e.velocity));
 279                         remove(e);
 280                 }
 281
 282                 if(n == 0)
 283                 {
 284                         // no dest!
 285                         objerror ("Jumppad with nonexistant target");
 286                         return;
 287                 }
 288                 else if(n == 1)
 289                 {
 290                         // exactly one dest - bots love that
 291                         self.enemy = find(e, targetname, self.target);
 292                 }
 293                 else
 294                 {
 295                         // have to use random selection every single time
 296                         self.enemy = world;
 297                 }
 298         }
 299         else
 300         {
 301                 e = spawn();
 302                 setorigin(e, org);
 303                 setsize(e, PL_MIN, PL_MAX);
 304                 e.velocity = self.movedir;
 305                 tracetoss(e, e);
 306                 waypoint_spawnforteleporter(self, trace_endpos, vlen(trace_endpos - org) / vlen(e.velocity));
 307                 remove(e);
 308         }
 309 };
 310
 311 /*
 312  * ENTITY PARAMETERS:
 313  *
 314  *   target:  target of jump
 315  *   height:  the absolute value is the height of the highest point of the jump
 316  *            trajectory above the higher one of the player and the target.
 317  *            the sign indicates whether the highest point is INSIDE (positive)
 318  *            or OUTSIDE (negative) of the jump trajectory. General rule: use
 319  *            positive values for targets mounted on the floor, and use negative
 320  *            values to target a point on the ceiling.
 321  *   movedir: if target is not set, this * speed * 10 is the velocity to be reached.
 322  */
 323 void spawnfunc_trigger_push()
 324 {
 325         SetMovedir ();
 326
 327         EXACTTRIGGER_INIT;
 328
 329         self.active = ACTIVE_ACTIVE;
 330         self.use = trigger_push_use;
 331         self.touch = trigger_push_touch;
 332
 333         // normal push setup
 334         if (!self.speed)
 335                 self.speed = 1000;
 336         self.movedir = self.movedir * self.speed * 10;
 337
 338         if not(self.noise)
 339                 self.noise = "misc/jumppad.wav";
 340         precache_sound (self.noise);
 341
 342         // this must be called to spawn the teleport waypoints for bots
 343         InitializeEntity(self, trigger_push_findtarget, INITPRIO_FINDTARGET);
 344 };
 345
 346 void spawnfunc_target_push() {};
 347 void spawnfunc_info_notnull() {};
 348 void spawnfunc_target_position() {};