qcsrc/server/teamplay.qc

   1 #include "teamplay.qh"
   2 #include "_all.qh"
   3
   4 #include "cl_client.qh"
   5 #include "race.qh"
   6 #include "scores.qh"
   7 #include "scores_rules.qh"
   8
   9 #include "bot/bot.qh"
  10
  11 #include "command/vote.qh"
  12
  13 #include "mutators/mutators_include.qh"
  14
  15 #include "../common/deathtypes.qh"
  16 #include "../common/teams.qh"
  17
  18 void TeamchangeFrags(entity e)
  19 {
  20         PlayerScore_Clear(e);
  21 }
  22
  23 void LogTeamchange(float player_id, float team_number, float type)
  24 {
  25         if(!autocvar_sv_eventlog)
  26                 return;
  27
  28         if(player_id < 1)
  29                 return;
  30
  31         GameLogEcho(strcat(":team:", ftos(player_id), ":", ftos(team_number), ":", ftos(type)));
  32 }
  33
  34 void default_delayedinit()
  35 {
  36         if(!scores_initialized)
  37                 ScoreRules_generic();
  38 }
  39
  40 void ActivateTeamplay()
  41 {
  42         serverflags |= SERVERFLAG_TEAMPLAY;
  43         teamplay = 1;
  44         cvar_set("teamplay", "2");  // DP needs this for sending proper getstatus replies.
  45 }
  46
  47 void InitGameplayMode()
  48 {
  49         float fraglimit_override, timelimit_override, leadlimit_override, qualifying_override;
  50
  51         qualifying_override = -1;
  52
  53         VoteReset();
  54
  55         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
  56         get_mi_min_max(1);
  57         world.mins = mi_min;
  58         world.maxs = mi_max;
  59
  60         MapInfo_LoadMapSettings(mapname);
  61         serverflags &= ~SERVERFLAG_TEAMPLAY;
  62         teamplay = 0;
  63         cvar_set("teamplay", "0");  // DP needs this for sending proper getstatus replies.
  64
  65         if (!cvar_value_issafe(world.fog))
  66         {
  67                 LOG_INFO("The current map contains a potentially harmful fog setting, ignored\n");
  68                 world.fog = string_null;
  69         }
  70         if(MapInfo_Map_fog != "")
  71                 if(MapInfo_Map_fog == "none")
  72                         world.fog = string_null;
  73                 else
  74                         world.fog = strzone(MapInfo_Map_fog);
  75         clientstuff = strzone(MapInfo_Map_clientstuff);
  76
  77         MapInfo_ClearTemps();
  78
  79         // set both here, gamemode can override it later
  80         timelimit_override = autocvar_timelimit_override;
  81         fraglimit_override = autocvar_fraglimit_override;
  82         leadlimit_override = autocvar_leadlimit_override;
  83         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
  84
  85         if(g_dm)
  86         {
  87                 MUTATOR_ADD(gamemode_deathmatch);
  88         }
  89
  90         if(g_tdm)
  91         {
  92                 ActivateTeamplay();
  93                 fraglimit_override = autocvar_g_tdm_point_limit;
  94                 leadlimit_override = autocvar_g_tdm_point_leadlimit;
  95                 if(autocvar_g_tdm_team_spawns)
  96                         have_team_spawns = -1; // request team spawns
  97                 MUTATOR_ADD(gamemode_tdm);
  98         }
  99
 100         if(g_domination)
 101         {
 102                 ActivateTeamplay();
 103                 fraglimit_override = autocvar_g_domination_point_limit;
 104                 leadlimit_override = autocvar_g_domination_point_leadlimit;
 105                 if(autocvar_g_domination_roundbased && autocvar_g_domination_roundbased_point_limit)
 106                         fraglimit_override = autocvar_g_domination_roundbased_point_limit;
 107                 have_team_spawns = -1; // request team spawns
 108                 MUTATOR_ADD(gamemode_domination);
 109         }
 110
 111         if(g_ctf)
 112         {
 113                 ActivateTeamplay();
 114                 fraglimit_override = autocvar_capturelimit_override;
 115                 leadlimit_override = autocvar_captureleadlimit_override;
 116                 have_team_spawns = -1; // request team spawns
 117                 MUTATOR_ADD(gamemode_ctf);
 118         }
 119
 120         if(g_lms)
 121         {
 122                 fraglimit_override = autocvar_g_lms_lives_override;
 123                 leadlimit_override = 0; // not supported by LMS
 124                 if(fraglimit_override == 0)
 125                         fraglimit_override = -1;
 126                 MUTATOR_ADD(gamemode_lms);
 127         }
 128
 129         if(g_ca)
 130         {
 131                 ActivateTeamplay();
 132                 fraglimit_override = autocvar_g_ca_point_limit;
 133                 leadlimit_override = autocvar_g_ca_point_leadlimit;
 134                 if(autocvar_g_ca_team_spawns)
 135                         have_team_spawns = -1; // request team spawns
 136                 MUTATOR_ADD(gamemode_ca);
 137         }
 138
 139         if(g_keyhunt)
 140         {
 141                 ActivateTeamplay();
 142                 fraglimit_override = autocvar_g_keyhunt_point_limit;
 143                 leadlimit_override = autocvar_g_keyhunt_point_leadlimit;
 144                 MUTATOR_ADD(gamemode_keyhunt);
 145         }
 146
 147         if(g_freezetag)
 148         {
 149                 ActivateTeamplay();
 150                 fraglimit_override = autocvar_g_freezetag_point_limit;
 151                 leadlimit_override = autocvar_g_freezetag_point_leadlimit;
 152                 if(autocvar_g_freezetag_team_spawns)
 153                         have_team_spawns = -1; // request team spawns
 154                 MUTATOR_ADD(gamemode_freezetag);
 155         }
 156
 157         if(g_assault)
 158         {
 159                 ActivateTeamplay();
 160                 have_team_spawns = -1; // request team spawns
 161                 MUTATOR_ADD(gamemode_assault);
 162         }
 163
 164         if(g_onslaught)
 165         {
 166                 ActivateTeamplay();
 167                 fraglimit_override = autocvar_g_onslaught_point_limit;
 168                 have_team_spawns = -1; // request team spawns
 169                 MUTATOR_ADD(gamemode_onslaught);
 170         }
 171
 172         if(g_race)
 173         {
 174                 if(autocvar_g_race_teams)
 175                 {
 176                         ActivateTeamplay();
 177                         race_teams = bound(2, autocvar_g_race_teams, 4);
 178                         have_team_spawns = -1; // request team spawns
 179                 }
 180                 else
 181                         race_teams = 0;
 182                 qualifying_override = autocvar_g_race_qualifying_timelimit_override;
 183                 fraglimit_override = autocvar_g_race_laps_limit;
 184                 leadlimit_override = 0; // currently not supported by race
 185
 186                 // we need to find out the correct value for g_race_qualifying
 187                 float want_qualifying = ((qualifying_override >= 0) ? qualifying_override : autocvar_g_race_qualifying_timelimit) > 0;
 188
 189                 if(autocvar_g_campaign)
 190                 {
 191                         g_race_qualifying = 1;
 192                         independent_players = 1;
 193                 }
 194                 else if(!autocvar_g_campaign && want_qualifying)
 195                 {
 196                         g_race_qualifying = 2;
 197                         independent_players = 1;
 198                         race_fraglimit = (race_fraglimit >= 0) ? fraglimit_override : autocvar_fraglimit;
 199                         race_leadlimit = (race_leadlimit >= 0) ? leadlimit_override : autocvar_leadlimit;
 200                         race_timelimit = (race_timelimit >= 0) ? timelimit_override : autocvar_timelimit;
 201                         fraglimit_override = 0;
 202                         leadlimit_override = 0;
 203                         timelimit_override = autocvar_g_race_qualifying_timelimit;
 204                 }
 205                 else
 206                 {
 207                         g_race_qualifying = 0;
 208                 }
 209
 210                 MUTATOR_ADD(gamemode_race);
 211         }
 212
 213         if(g_cts)
 214         {
 215                 g_race_qualifying = 1;
 216                 fraglimit_override = 0;
 217                 leadlimit_override = 0;
 218                 independent_players = 1;
 219                 MUTATOR_ADD(gamemode_cts);
 220         }
 221
 222         if(g_nexball)
 223         {
 224                 fraglimit_override = autocvar_g_nexball_goallimit;
 225                 leadlimit_override = autocvar_g_nexball_goalleadlimit;
 226                 ActivateTeamplay();
 227                 have_team_spawns = -1; // request team spawns
 228                 MUTATOR_ADD(gamemode_nexball);
 229         }
 230
 231         if(g_keepaway)
 232         {
 233                 MUTATOR_ADD(gamemode_keepaway);
 234         }
 235
 236         if(g_invasion)
 237         {
 238                 fraglimit_override = autocvar_g_invasion_point_limit;
 239                 if(autocvar_g_invasion_teams >= 2)
 240                 {
 241                         ActivateTeamplay();
 242                         if(autocvar_g_invasion_team_spawns)
 243                                 have_team_spawns = -1; // request team spawns
 244                 }
 245                 MUTATOR_ADD(gamemode_invasion);
 246         }
 247
 248         if(teamplay)
 249                 entcs_init();
 250
 251         cache_mutatormsg = strzone("");
 252         cache_lastmutatormsg = strzone("");
 253
 254         // enforce the server's universal frag/time limits
 255         if(!autocvar_g_campaign)
 256         {
 257                 if(fraglimit_override >= 0)
 258                         cvar_set("fraglimit", ftos(fraglimit_override));
 259                 if(timelimit_override >= 0)
 260                         cvar_set("timelimit", ftos(timelimit_override));
 261                 if(leadlimit_override >= 0)
 262                         cvar_set("leadlimit", ftos(leadlimit_override));
 263                 if(qualifying_override >= 0)
 264                         cvar_set("g_race_qualifying_timelimit", ftos(qualifying_override));
 265         }
 266
 267         InitializeEntity(world, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 268 }
 269
 270 string GetClientVersionMessage() {
 271         string versionmsg;
 272         if (self.version_mismatch) {
 273                 if(self.version < autocvar_gameversion) {
 274                         versionmsg = "^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8";
 275                 } else {
 276                         versionmsg = "^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8";
 277                 }
 278         } else {
 279                 versionmsg = "^2client version and server version are compatible.^8";
 280         }
 281         return versionmsg;
 282 }
 283
 284 string getwelcomemessage(void)
 285 {
 286         string s, modifications, motd;
 287
 288         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
 289         modifications = ret_string;
 290
 291         if(g_weaponarena)
 292         {
 293                 if(g_weaponarena_random)
 294                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
 295                 else
 296                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
 297         }
 298         if(cvar("g_balance_blaster_weaponstart") == 0)
 299                 modifications = strcat(modifications, ", No start weapons");
 300         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
 301                 modifications = strcat(modifications, ", Low gravity");
 302         if(g_cloaked && !g_cts)
 303                 modifications = strcat(modifications, ", Cloaked");
 304         if(g_grappling_hook)
 305                 modifications = strcat(modifications, ", Hook");
 306         if(g_weapon_stay && !g_cts)
 307                 modifications = strcat(modifications, ", Weapons stay");
 308         if(g_jetpack)
 309                 modifications = strcat(modifications, ", Jet pack");
 310         if(autocvar_g_powerups == 0)
 311                 modifications = strcat(modifications, ", No powerups");
 312         if(autocvar_g_powerups > 0)
 313                 modifications = strcat(modifications, ", Powerups");
 314         modifications = substring(modifications, 2, strlen(modifications) - 2);
 315
 316         string versionmessage;
 317         versionmessage = GetClientVersionMessage();
 318
 319         s = strcat("This is Xonotic ", autocvar_g_xonoticversion, "\n", versionmessage);
 320         s = strcat(s, "^8\n\nmatch type is ^1", gamemode_name, "^8\n");
 321
 322         if(modifications != "")
 323                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
 324
 325         if (g_grappling_hook)
 326                 s = strcat(s, "\n\n^3grappling hook^8 is enabled, press 'e' to use it\n");
 327
 328         if (cvar("g_nades"))
 329                 s = strcat(s, "\n\n^3nades^8 are enabled, press 'g' to use them\n");
 330
 331         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
 332         {
 333                 if(cache_lastmutatormsg)
 334                         strunzone(cache_lastmutatormsg);
 335                 if(cache_mutatormsg)
 336                         strunzone(cache_mutatormsg);
 337                 cache_lastmutatormsg = strzone(autocvar_g_mutatormsg);
 338                 cache_mutatormsg = strzone(cache_lastmutatormsg);
 339         }
 340
 341         if (cache_mutatormsg != "") {
 342                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
 343         }
 344
 345         motd = autocvar_sv_motd;
 346         if (motd != "") {
 347                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
 348         }
 349         return s;
 350 }
 351
 352 void SetPlayerColors(entity pl, float _color)
 353 {
 354         /*string s;
 355         s = ftos(cl);
 356         stuffcmd(pl, strcat("color ", s, " ", s, "\n")  );
 357         pl.team = cl + 1;
 358         //pl.clientcolors = pl.clientcolors - (pl.clientcolors & 15) + cl;
 359         pl.clientcolors = 16*cl + cl;*/
 360
 361         float pants, shirt;
 362         pants = _color & 0x0F;
 363         shirt = _color & 0xF0;
 364
 365
 366         if(teamplay) {
 367                 setcolor(pl, 16*pants + pants);
 368         } else {
 369                 setcolor(pl, shirt + pants);
 370         }
 371 }
 372
 373 void SetPlayerTeam(entity pl, float t, float s, float noprint)
 374 {
 375         float _color;
 376
 377         if(t == 4)
 378                 _color = NUM_TEAM_4 - 1;
 379         else if(t == 3)
 380                 _color = NUM_TEAM_3 - 1;
 381         else if(t == 2)
 382                 _color = NUM_TEAM_2 - 1;
 383         else
 384                 _color = NUM_TEAM_1 - 1;
 385
 386         SetPlayerColors(pl,_color);
 387
 388         if(t != s) {
 389                 LogTeamchange(pl.playerid, pl.team, 3);  // log manual team join
 390
 391                 if(!noprint)
 392                 bprint(pl.netname, "^7 has changed from ", Team_NumberToColoredFullName(s), "^7 to ", Team_NumberToColoredFullName(t), "\n");
 393         }
 394
 395 }
 396
 397 // set c1...c4 to show what teams are allowed
 398 void CheckAllowedTeams (entity for_whom)
 399 {
 400         float dm;
 401         entity head;
 402         string teament_name;
 403
 404         c1 = c2 = c3 = c4 = -1;
 405         cb1 = cb2 = cb3 = cb4 = 0;
 406
 407         teament_name = string_null;
 408         if(g_onslaught)
 409         {
 410                 // onslaught is special
 411                 head = findchain(classname, "onslaught_generator");
 412                 while (head)
 413                 {
 414                         if (head.team == NUM_TEAM_1) c1 = 0;
 415                         if (head.team == NUM_TEAM_2) c2 = 0;
 416                         if (head.team == NUM_TEAM_3) c3 = 0;
 417                         if (head.team == NUM_TEAM_4) c4 = 0;
 418                         head = head.chain;
 419                 }
 420         }
 421         else if(g_domination)
 422                 teament_name = "dom_team";
 423         else if(g_ctf)
 424                 teament_name = "ctf_team";
 425         else if(g_tdm)
 426                 teament_name = "tdm_team";
 427         else if(g_nexball)
 428                 teament_name = "nexball_team";
 429         else if(g_assault)
 430                 c1 = c2 = 0; // Assault always has 2 teams
 431         else
 432         {
 433                 // cover anything else by treating it like tdm with no teams spawned
 434                 dm = 2;
 435
 436                 MUTATOR_CALLHOOK(GetTeamCount, dm);
 437                 dm = ret_float;
 438
 439                 if(dm >= 4)
 440                         c1 = c2 = c3 = c4 = 0;
 441                 else if(dm >= 3)
 442                         c1 = c2 = c3 = 0;
 443                 else
 444                         c1 = c2 = 0;
 445         }
 446
 447         // find out what teams are allowed if necessary
 448         if(teament_name)
 449         {
 450                 head = find(world, classname, teament_name);
 451                 while(head)
 452                 {
 453                         if(!(g_domination && head.netname == ""))
 454                         {
 455                                 if(head.team == NUM_TEAM_1)
 456                                         c1 = 0;
 457                                 else if(head.team == NUM_TEAM_2)
 458                                         c2 = 0;
 459                                 else if(head.team == NUM_TEAM_3)
 460                                         c3 = 0;
 461                                 else if(head.team == NUM_TEAM_4)
 462                                         c4 = 0;
 463                         }
 464                         head = find(head, classname, teament_name);
 465                 }
 466         }
 467
 468         // TODO: Balance quantity of bots across > 2 teams when bot_vs_human is set (and remove next line)
 469         if(c3==-1 && c4==-1)
 470         if(autocvar_bot_vs_human && for_whom)
 471         {
 472                 if(autocvar_bot_vs_human > 0)
 473                 {
 474                         // bots are all blue
 475                         if(IS_BOT_CLIENT(for_whom))
 476                                 c1 = c3 = c4 = -1;
 477                         else
 478                                 c2 = -1;
 479                 }
 480                 else
 481                 {
 482                         // bots are all red
 483                         if(IS_BOT_CLIENT(for_whom))
 484                                 c2 = c3 = c4 = -1;
 485                         else
 486                                 c1 = -1;
 487                 }
 488         }
 489
 490         // if player has a forced team, ONLY allow that one
 491         if(self.team_forced == NUM_TEAM_1 && c1 >= 0)
 492                 c2 = c3 = c4 = -1;
 493         else if(self.team_forced == NUM_TEAM_2 && c2 >= 0)
 494                 c1 = c3 = c4 = -1;
 495         else if(self.team_forced == NUM_TEAM_3 && c3 >= 0)
 496                 c1 = c2 = c4 = -1;
 497         else if(self.team_forced == NUM_TEAM_4 && c4 >= 0)
 498                 c1 = c2 = c3 = -1;
 499 }
 500
 501 float PlayerValue(entity p)
 502 {
 503         return 1;
 504         // FIXME: it always returns 1...
 505 }
 506
 507 // c1...c4 should be set to -1 (not allowed) or 0 (allowed).
 508 // teams that are allowed will now have their player counts stored in c1...c4
 509 void GetTeamCounts(entity ignore)
 510 {
 511         entity head;
 512         float value, bvalue;
 513         // now count how many players are on each team already
 514
 515         // FIXME: also find and memorize the lowest-scoring bot on each team (in case players must be shuffled around)
 516         // also remember the lowest-scoring player
 517
 518         FOR_EACH_CLIENT(head)
 519         {
 520                 float t;
 521                 if(IS_PLAYER(head) || head.caplayer)
 522                         t = head.team;
 523                 else if(head.team_forced > 0)
 524                         t = head.team_forced; // reserve the spot
 525                 else
 526                         continue;
 527                 if(head != ignore)// && head.netname != "")
 528                 {
 529                         value = PlayerValue(head);
 530                         if(IS_BOT_CLIENT(head))
 531                                 bvalue = value;
 532                         else
 533                                 bvalue = 0;
 534                         if(t == NUM_TEAM_1)
 535                         {
 536                                 if(c1 >= 0)
 537                                 {
 538                                         c1 = c1 + value;
 539                                         cb1 = cb1 + bvalue;
 540                                 }
 541                         }
 542                         if(t == NUM_TEAM_2)
 543                         {
 544                                 if(c2 >= 0)
 545                                 {
 546                                         c2 = c2 + value;
 547                                         cb2 = cb2 + bvalue;
 548                                 }
 549                         }
 550                         if(t == NUM_TEAM_3)
 551                         {
 552                                 if(c3 >= 0)
 553                                 {
 554                                         c3 = c3 + value;
 555                                         cb3 = cb3 + bvalue;
 556                                 }
 557                         }
 558                         if(t == NUM_TEAM_4)
 559                         {
 560                                 if(c4 >= 0)
 561                                 {
 562                                         c4 = c4 + value;
 563                                         cb4 = cb4 + bvalue;
 564                                 }
 565                         }
 566                 }
 567         }
 568
 569         // if the player who has a forced team has not joined yet, reserve the spot
 570         if(autocvar_g_campaign)
 571         {
 572                 switch(autocvar_g_campaign_forceteam)
 573                 {
 574                         case 1: if(c1 == cb1) ++c1; break;
 575                         case 2: if(c2 == cb2) ++c2; break;
 576                         case 3: if(c3 == cb3) ++c3; break;
 577                         case 4: if(c4 == cb4) ++c4; break;
 578                 }
 579         }
 580 }
 581
 582 float TeamSmallerEqThanTeam(float ta, float tb, entity e)
 583 {
 584         // we assume that CheckAllowedTeams and GetTeamCounts have already been called
 585         float f;
 586         float ca = -1, cb = -1, cba = 0, cbb = 0, sa = 0, sb = 0;
 587
 588         switch(ta)
 589         {
 590                 case 1: ca = c1; cba = cb1; sa = team1_score; break;
 591                 case 2: ca = c2; cba = cb2; sa = team2_score; break;
 592                 case 3: ca = c3; cba = cb3; sa = team3_score; break;
 593                 case 4: ca = c4; cba = cb4; sa = team4_score; break;
 594         }
 595         switch(tb)
 596         {
 597                 case 1: cb = c1; cbb = cb1; sb = team1_score; break;
 598                 case 2: cb = c2; cbb = cb2; sb = team2_score; break;
 599                 case 3: cb = c3; cbb = cb3; sb = team3_score; break;
 600                 case 4: cb = c4; cbb = cb4; sb = team4_score; break;
 601         }
 602
 603         // invalid
 604         if(ca < 0 || cb < 0)
 605                 return false;
 606
 607         // equal
 608         if(ta == tb)
 609                 return true;
 610
 611         if(IS_REAL_CLIENT(e))
 612         {
 613                 if(bots_would_leave)
 614                 {
 615                         ca -= cba * 0.999;
 616                         cb -= cbb * 0.999;
 617                 }
 618         }
 619
 620         // keep teams alive (teams of size 0 always count as smaller, ignoring score)
 621         if(ca < 1)
 622                 if(cb >= 1)
 623                         return true;
 624         if(ca >= 1)
 625                 if(cb < 1)
 626                         return false;
 627
 628         // first, normalize
 629         f = max(ca, cb, 1);
 630         ca /= f;
 631         cb /= f;
 632         f = max(sa, sb, 1);
 633         sa /= f;
 634         sb /= f;
 635
 636         // the more we're at the end of the match, the more take scores into account
 637         f = bound(0, game_completion_ratio * autocvar_g_balance_teams_scorefactor, 1);
 638         ca += (sa - ca) * f;
 639         cb += (sb - cb) * f;
 640
 641         return ca <= cb;
 642 }
 643
 644 // returns # of smallest team (1, 2, 3, 4)
 645 // NOTE: Assumes CheckAllowedTeams has already been called!
 646 float FindSmallestTeam(entity pl, float ignore_pl)
 647 {
 648         float totalteams, t;
 649         totalteams = 0;
 650
 651         // find out what teams are available
 652         //CheckAllowedTeams();
 653
 654         // make sure there are at least 2 teams to join
 655         if(c1 >= 0)
 656                 totalteams = totalteams + 1;
 657         if(c2 >= 0)
 658                 totalteams = totalteams + 1;
 659         if(c3 >= 0)
 660                 totalteams = totalteams + 1;
 661         if(c4 >= 0)
 662                 totalteams = totalteams + 1;
 663
 664         if((autocvar_bot_vs_human || pl.team_forced > 0) && totalteams == 1)
 665                 totalteams += 1;
 666
 667         if(totalteams <= 1)
 668         {
 669                 if(autocvar_g_campaign && pl && IS_REAL_CLIENT(pl))
 670                         return 1; // special case for campaign and player joining
 671                 else
 672                         error(sprintf("Too few teams available for %s\n", MapInfo_Type_ToString(MapInfo_CurrentGametype())));
 673         }
 674
 675         // count how many players are in each team
 676         if(ignore_pl)
 677                 GetTeamCounts(pl);
 678         else
 679                 GetTeamCounts(world);
 680
 681         RandomSelection_Init();
 682
 683         t = 1;
 684         if(TeamSmallerEqThanTeam(2, t, pl))
 685                 t = 2;
 686         if(TeamSmallerEqThanTeam(3, t, pl))
 687                 t = 3;
 688         if(TeamSmallerEqThanTeam(4, t, pl))
 689                 t = 4;
 690
 691         // now t is the minimum, or A minimum!
 692         if(t == 1 || TeamSmallerEqThanTeam(1, t, pl))
 693                 RandomSelection_Add(world, 1, string_null, 1, 1);
 694         if(t == 2 || TeamSmallerEqThanTeam(2, t, pl))
 695                 RandomSelection_Add(world, 2, string_null, 1, 1);
 696         if(t == 3 || TeamSmallerEqThanTeam(3, t, pl))
 697                 RandomSelection_Add(world, 3, string_null, 1, 1);
 698         if(t == 4 || TeamSmallerEqThanTeam(4, t, pl))
 699                 RandomSelection_Add(world, 4, string_null, 1, 1);
 700
 701         return RandomSelection_chosen_float;
 702 }
 703
 704 float JoinBestTeam(entity pl, float only_return_best, float forcebestteam)
 705 {
 706         float smallest, selectedteam;
 707
 708         // don't join a team if we're not playing a team game
 709         if(!teamplay)
 710                 return 0;
 711
 712         // find out what teams are available
 713         CheckAllowedTeams(pl);
 714
 715         // if we don't care what team he ends up on, put him on whatever team he entered as.
 716         // if he's not on a valid team, then let other code put him on the smallest team
 717         if(!forcebestteam)
 718         {
 719                 if(     c1 >= 0 && pl.team == NUM_TEAM_1)
 720                         selectedteam = pl.team;
 721                 else if(c2 >= 0 && pl.team == NUM_TEAM_2)
 722                         selectedteam = pl.team;
 723                 else if(c3 >= 0 && pl.team == NUM_TEAM_3)
 724                         selectedteam = pl.team;
 725                 else if(c4 >= 0 && pl.team == NUM_TEAM_4)
 726                         selectedteam = pl.team;
 727                 else
 728                         selectedteam = -1;
 729
 730                 if(selectedteam > 0)
 731                 {
 732                         if(!only_return_best)
 733                         {
 734                                 SetPlayerColors(pl, selectedteam - 1);
 735
 736                                 // when JoinBestTeam is called by client.qc/ClientKill_Now_TeamChange the players team is -1 and thus skipped
 737                                 // when JoinBestTeam is called by cl_client.qc/ClientConnect the player_id is 0 the log attempt is rejected
 738                                 LogTeamchange(pl.playerid, pl.team, 99);
 739                         }
 740                         return selectedteam;
 741                 }
 742                 // otherwise end up on the smallest team (handled below)
 743         }
 744
 745         smallest = FindSmallestTeam(pl, true);
 746
 747         if(!only_return_best && !pl.bot_forced_team)
 748         {
 749                 TeamchangeFrags(self);
 750                 if(smallest == 1)
 751                 {
 752                         SetPlayerColors(pl, NUM_TEAM_1 - 1);
 753                 }
 754                 else if(smallest == 2)
 755                 {
 756                         SetPlayerColors(pl, NUM_TEAM_2 - 1);
 757                 }
 758                 else if(smallest == 3)
 759                 {
 760                         SetPlayerColors(pl, NUM_TEAM_3 - 1);
 761                 }
 762                 else if(smallest == 4)
 763                 {
 764                         SetPlayerColors(pl, NUM_TEAM_4 - 1);
 765                 }
 766                 else
 767                 {
 768                         error("smallest team: invalid team\n");
 769                 }
 770
 771                 LogTeamchange(pl.playerid, pl.team, 2); // log auto join
 772
 773                 if(pl.deadflag == DEAD_NO)
 774                         Damage(pl, pl, pl, 100000, DEATH_TEAMCHANGE, pl.origin, '0 0 0');
 775         }
 776
 777         return smallest;
 778 }
 779
 780 //void() ctf_playerchanged;
 781 void SV_ChangeTeam(float _color)
 782 {
 783         float scolor, dcolor, steam, dteam; //, dbotcount, scount, dcount;
 784
 785         // in normal deathmatch we can just apply the color and we're done
 786         if(!teamplay) {
 787                 SetPlayerColors(self, _color);
 788                 return;
 789         }
 790
 791         scolor = self.clientcolors & 0x0F;
 792         dcolor = _color & 0x0F;
 793
 794         if(scolor == NUM_TEAM_1 - 1)
 795                 steam = 1;
 796         else if(scolor == NUM_TEAM_2 - 1)
 797                 steam = 2;
 798         else if(scolor == NUM_TEAM_3 - 1)
 799                 steam = 3;
 800         else // if(scolor == NUM_TEAM_4 - 1)
 801                 steam = 4;
 802         if(dcolor == NUM_TEAM_1 - 1)
 803                 dteam = 1;
 804         else if(dcolor == NUM_TEAM_2 - 1)
 805                 dteam = 2;
 806         else if(dcolor == NUM_TEAM_3 - 1)
 807                 dteam = 3;
 808         else // if(dcolor == NUM_TEAM_4 - 1)
 809                 dteam = 4;
 810
 811         CheckAllowedTeams(self);
 812
 813         if(dteam == 1 && c1 < 0) dteam = 4;
 814         if(dteam == 4 && c4 < 0) dteam = 3;
 815         if(dteam == 3 && c3 < 0) dteam = 2;
 816         if(dteam == 2 && c2 < 0) dteam = 1;
 817
 818         // not changing teams
 819         if(scolor == dcolor)
 820         {
 821                 //bprint("same team change\n");
 822                 SetPlayerTeam(self, dteam, steam, true);
 823                 return;
 824         }
 825
 826         if((autocvar_g_campaign) || (autocvar_g_changeteam_banned && self.wasplayer)) {
 827                 Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_TEAMCHANGE_NOTALLOWED);
 828                 return; // changing teams is not allowed
 829         }
 830
 831         // autocvar_g_balance_teams_prevent_imbalance only makes sense if autocvar_g_balance_teams is on, as it makes the team selection dialog pointless
 832         if(autocvar_g_balance_teams && autocvar_g_balance_teams_prevent_imbalance)
 833         {
 834                 GetTeamCounts(self);
 835                 if(!TeamSmallerEqThanTeam(dteam, steam, self))
 836                 {
 837                         Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_TEAMCHANGE_LARGERTEAM);
 838                         return;
 839                 }
 840         }
 841
 842 //      bprint("allow change teams from ", ftos(steam), " to ", ftos(dteam), "\n");
 843
 844         if(IS_PLAYER(self) && steam != dteam)
 845         {
 846                 // reduce frags during a team change
 847                 TeamchangeFrags(self);
 848         }
 849
 850         // since this is an engine function, and gamecode doesn't have any calls earlier than this, do the connecting message here
 851         if(!IS_CLIENT(self))
 852                 Send_Notification(NOTIF_ONE, self, MSG_INFO, INFO_CONNECTING, self.netname);
 853
 854         SetPlayerTeam(self, dteam, steam, !IS_CLIENT(self));
 855
 856         if(IS_PLAYER(self) && steam != dteam)
 857         {
 858                 // kill player when changing teams
 859                 if(self.deadflag == DEAD_NO)
 860                         Damage(self, self, self, 100000, DEATH_TEAMCHANGE, self.origin, '0 0 0');
 861         }
 862 }
 863
 864 void ShufflePlayerOutOfTeam (float source_team)
 865 {
 866         float smallestteam, smallestteam_count, steam;
 867         float lowest_bot_score, lowest_player_score;
 868         entity head, lowest_bot, lowest_player, selected;
 869
 870         smallestteam = 0;
 871         smallestteam_count = 999999999;
 872
 873         if(c1 >= 0 && c1 < smallestteam_count)
 874         {
 875                 smallestteam = 1;
 876                 smallestteam_count = c1;
 877         }
 878         if(c2 >= 0 && c2 < smallestteam_count)
 879         {
 880                 smallestteam = 2;
 881                 smallestteam_count = c2;
 882         }
 883         if(c3 >= 0 && c3 < smallestteam_count)
 884         {
 885                 smallestteam = 3;
 886                 smallestteam_count = c3;
 887         }
 888         if(c4 >= 0 && c4 < smallestteam_count)
 889         {
 890                 smallestteam = 4;
 891                 smallestteam_count = c4;
 892         }
 893
 894         if(!smallestteam)
 895         {
 896                 bprint("warning: no smallest team\n");
 897                 return;
 898         }
 899
 900         if(source_team == 1)
 901                 steam = NUM_TEAM_1;
 902         else if(source_team == 2)
 903                 steam = NUM_TEAM_2;
 904         else if(source_team == 3)
 905                 steam = NUM_TEAM_3;
 906         else // if(source_team == 4)
 907                 steam = NUM_TEAM_4;
 908
 909         lowest_bot = world;
 910         lowest_bot_score = 999999999;
 911         lowest_player = world;
 912         lowest_player_score = 999999999;
 913
 914         // find the lowest-scoring player & bot of that team
 915         FOR_EACH_PLAYER(head)
 916         {
 917                 if(head.team == steam)
 918                 {
 919                         if(head.isbot)
 920                         {
 921                                 if(head.totalfrags < lowest_bot_score)
 922                                 {
 923                                         lowest_bot = head;
 924                                         lowest_bot_score = head.totalfrags;
 925                                 }
 926                         }
 927                         else
 928                         {
 929                                 if(head.totalfrags < lowest_player_score)
 930                                 {
 931                                         lowest_player = head;
 932                                         lowest_player_score = head.totalfrags;
 933                                 }
 934                         }
 935                 }
 936         }
 937
 938         // prefers to move a bot...
 939         if(lowest_bot != world)
 940                 selected = lowest_bot;
 941         // but it will move a player if it has to
 942         else
 943                 selected = lowest_player;
 944         // don't do anything if it couldn't find anyone
 945         if(!selected)
 946         {
 947                 bprint("warning: couldn't find a player to move from team\n");
 948                 return;
 949         }
 950
 951         // smallest team gains a member
 952         if(smallestteam == 1)
 953         {
 954                 c1 = c1 + 1;
 955         }
 956         else if(smallestteam == 2)
 957         {
 958                 c2 = c2 + 1;
 959         }
 960         else if(smallestteam == 3)
 961         {
 962                 c3 = c3 + 1;
 963         }
 964         else if(smallestteam == 4)
 965         {
 966                 c4 = c4 + 1;
 967         }
 968         else
 969         {
 970                 bprint("warning: destination team invalid\n");
 971                 return;
 972         }
 973         // source team loses a member
 974         if(source_team == 1)
 975         {
 976                 c1 = c1 + 1;
 977         }
 978         else if(source_team == 2)
 979         {
 980                 c2 = c2 + 2;
 981         }
 982         else if(source_team == 3)
 983         {
 984                 c3 = c3 + 3;
 985         }
 986         else if(source_team == 4)
 987         {
 988                 c4 = c4 + 4;
 989         }
 990         else
 991         {
 992                 bprint("warning: source team invalid\n");
 993                 return;
 994         }
 995
 996         // move the player to the new team
 997         TeamchangeFrags(selected);
 998         SetPlayerTeam(selected, smallestteam, source_team, false);
 999
1000         if(selected.deadflag == DEAD_NO)
1001                 Damage(selected, selected, selected, 100000, DEATH_AUTOTEAMCHANGE, selected.origin, '0 0 0');
1002         Send_Notification(NOTIF_ONE, selected, MSG_CENTER, CENTER_DEATH_SELF_AUTOTEAMCHANGE, selected.team);
1003 }