qcsrc/server/teamplay.qc

   1 string cache_mutatormsg;
   2 string cache_lastmutatormsg;
   3
   4 // client counts for each team
   5 float c1, c2, c3, c4;
   6 // # of bots on those teams
   7 float cb1, cb2, cb3, cb4;
   8
   9 //float audit_teams_time;
  10
  11 void TeamchangeFrags(entity e)
  12 {
  13         PlayerScore_Clear(e);
  14 }
  15
  16 void tdm_init();
  17 void entcs_init();
  18
  19 void LogTeamchange(float player_id, float team_number, float type)
  20 {
  21         if(!autocvar_sv_eventlog)
  22                 return;
  23
  24         if(player_id < 1)
  25                 return;
  26
  27         GameLogEcho(strcat(":team:", ftos(player_id), ":", ftos(team_number), ":", ftos(type)));
  28 }
  29
  30 void default_delayedinit()
  31 {
  32         if(!scores_initialized)
  33                 ScoreRules_generic();
  34 }
  35
  36 void ActivateTeamplay()
  37 {
  38         serverflags |= SERVERFLAG_TEAMPLAY;
  39         teamplay = 1;
  40 }
  41
  42 void InitGameplayMode()
  43 {
  44         float fraglimit_override, timelimit_override, leadlimit_override, qualifying_override;
  45
  46         qualifying_override = -1;
  47
  48         VoteReset();
  49
  50         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
  51         get_mi_min_max(1);
  52         world.mins = mi_min;
  53         world.maxs = mi_max;
  54
  55         MapInfo_LoadMapSettings(mapname);
  56         teamplay = 0;
  57         serverflags &= ~SERVERFLAG_TEAMPLAY;
  58
  59         if (!cvar_value_issafe(world.fog))
  60         {
  61                 print("The current map contains a potentially harmful fog setting, ignored\n");
  62                 world.fog = string_null;
  63         }
  64         if(MapInfo_Map_fog != "")
  65                 if(MapInfo_Map_fog == "none")
  66                         world.fog = string_null;
  67                 else
  68                         world.fog = strzone(MapInfo_Map_fog);
  69         clientstuff = strzone(MapInfo_Map_clientstuff);
  70
  71         MapInfo_ClearTemps();
  72
  73         // set both here, gamemode can override it later
  74         timelimit_override = autocvar_timelimit_override;
  75         fraglimit_override = autocvar_fraglimit_override;
  76         leadlimit_override = autocvar_leadlimit_override;
  77         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
  78
  79         if(g_dm)
  80         {
  81         }
  82
  83         if(g_tdm)
  84         {
  85                 ActivateTeamplay();
  86                 tdm_init();
  87                 if(autocvar_g_tdm_team_spawns)
  88                         have_team_spawns = -1; // request team spawns
  89         }
  90
  91         if(g_domination)
  92         {
  93                 ActivateTeamplay();
  94                 fraglimit_override = autocvar_g_domination_point_limit;
  95                 leadlimit_override = autocvar_g_domination_point_leadlimit;
  96                 MUTATOR_ADD(gamemode_domination);
  97                 have_team_spawns = -1; // request team spawns
  98         }
  99
 100         if(g_ctf)
 101         {
 102                 ActivateTeamplay();
 103                 fraglimit_override = autocvar_capturelimit_override;
 104                 leadlimit_override = autocvar_captureleadlimit_override;
 105                 MUTATOR_ADD(gamemode_ctf);
 106                 have_team_spawns = -1; // request team spawns
 107         }
 108
 109         if(g_lms)
 110         {
 111                 fraglimit_override = autocvar_g_lms_lives_override;
 112                 leadlimit_override = 0; // not supported by LMS
 113                 if(fraglimit_override == 0)
 114                         fraglimit_override = -1;
 115                 MUTATOR_ADD(gamemode_lms);
 116         }
 117
 118         if(g_ca)
 119         {
 120                 ActivateTeamplay();
 121                 fraglimit_override = autocvar_g_ca_point_limit;
 122                 leadlimit_override = autocvar_g_ca_point_leadlimit;
 123                 MUTATOR_ADD(gamemode_ca);
 124                 if(autocvar_g_ca_team_spawns)
 125                         have_team_spawns = -1; // request team spawns
 126         }
 127
 128         if(g_keyhunt)
 129         {
 130                 ActivateTeamplay();
 131                 fraglimit_override = autocvar_g_keyhunt_point_limit;
 132                 leadlimit_override = autocvar_g_keyhunt_point_leadlimit;
 133                 MUTATOR_ADD(gamemode_keyhunt);
 134         }
 135
 136         if(g_freezetag)
 137         {
 138                 ActivateTeamplay();
 139                 fraglimit_override = autocvar_g_freezetag_point_limit;
 140                 leadlimit_override = autocvar_g_freezetag_point_leadlimit;
 141                 MUTATOR_ADD(gamemode_freezetag);
 142                 if(autocvar_g_freezetag_team_spawns)
 143                         have_team_spawns = -1; // request team spawns
 144         }
 145
 146         if(g_assault)
 147         {
 148                 ActivateTeamplay();
 149                 MUTATOR_ADD(gamemode_assault);
 150                 have_team_spawns = -1; // request team spawns
 151         }
 152
 153         if(g_onslaught)
 154         {
 155                 ActivateTeamplay();
 156                 have_team_spawns = -1; // request team spawns
 157                 MUTATOR_ADD(gamemode_onslaught);
 158         }
 159
 160         if(g_race)
 161         {
 162
 163                 if(autocvar_g_race_teams)
 164                 {
 165                         ActivateTeamplay();
 166                         race_teams = bound(2, autocvar_g_race_teams, 4);
 167                         have_team_spawns = -1; // request team spawns
 168                 }
 169                 else
 170                         race_teams = 0;
 171
 172                 qualifying_override = autocvar_g_race_qualifying_timelimit_override;
 173                 fraglimit_override = autocvar_g_race_laps_limit;
 174                 leadlimit_override = 0; // currently not supported by race
 175         }
 176
 177         if(g_cts)
 178         {
 179                 g_race_qualifying = 1;
 180                 fraglimit_override = 0;
 181                 leadlimit_override = 0;
 182         }
 183
 184         if(g_nexball)
 185         {
 186         fraglimit_override = autocvar_g_nexball_goallimit;
 187         leadlimit_override = autocvar_g_nexball_goalleadlimit;
 188         ActivateTeamplay();
 189         have_team_spawns = -1; // request team spawns
 190             MUTATOR_ADD(gamemode_nexball);
 191         }
 192
 193         if(g_keepaway)
 194         {
 195                 MUTATOR_ADD(gamemode_keepaway);
 196         }
 197
 198         if(g_invasion)
 199         {
 200                 fraglimit_override = autocvar_g_invasion_point_limit;
 201                 MUTATOR_ADD(gamemode_invasion);
 202         }
 203
 204         if(teamplay)
 205                 entcs_init();
 206
 207         cache_mutatormsg = strzone("");
 208         cache_lastmutatormsg = strzone("");
 209
 210         // enforce the server's universal frag/time limits
 211         if(!autocvar_g_campaign)
 212         {
 213                 if(fraglimit_override >= 0)
 214                         cvar_set("fraglimit", ftos(fraglimit_override));
 215                 if(timelimit_override >= 0)
 216                         cvar_set("timelimit", ftos(timelimit_override));
 217                 if(leadlimit_override >= 0)
 218                         cvar_set("leadlimit", ftos(leadlimit_override));
 219                 if(qualifying_override >= 0)
 220                         cvar_set("g_race_qualifying_timelimit", ftos(qualifying_override));
 221         }
 222
 223         if(g_race)
 224         {
 225                 // we need to find out the correct value for g_race_qualifying
 226                 if(autocvar_g_campaign)
 227                 {
 228                         g_race_qualifying = 1;
 229                 }
 230                 else if(!autocvar_g_campaign && autocvar_g_race_qualifying_timelimit > 0)
 231                 {
 232                         g_race_qualifying = 2;
 233                         race_fraglimit = autocvar_fraglimit;
 234                         race_leadlimit = autocvar_leadlimit;
 235                         race_timelimit = autocvar_timelimit;
 236                         cvar_set("fraglimit", "0");
 237                         cvar_set("leadlimit", "0");
 238                         cvar_set("timelimit", ftos(autocvar_g_race_qualifying_timelimit));
 239                 }
 240                 else
 241                         g_race_qualifying = 0;
 242         }
 243
 244         if(g_race || g_cts)
 245         {
 246                 if(g_race_qualifying)
 247                         independent_players = 1;
 248
 249                 ScoreRules_race();
 250         }
 251
 252         InitializeEntity(world, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 253 }
 254
 255 string GetClientVersionMessage() {
 256         string versionmsg;
 257         if (self.version_mismatch) {
 258                 if(self.version < autocvar_gameversion) {
 259                         versionmsg = "^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8";
 260                 } else {
 261                         versionmsg = "^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8";
 262                 }
 263         } else {
 264                 versionmsg = "^2client version and server version are compatible.^8";
 265         }
 266         return versionmsg;
 267 }
 268
 269 string getwelcomemessage(void)
 270 {
 271         string s, modifications, motd;
 272
 273         ret_string = "";
 274         MUTATOR_CALLHOOK(BuildMutatorsPrettyString);
 275         modifications = ret_string;
 276
 277         if(g_weaponarena)
 278         {
 279                 if(g_weaponarena_random)
 280                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
 281                 else
 282                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
 283         }
 284         if(autocvar_g_start_weapon_laser == 0)
 285                 modifications = strcat(modifications, ", No start weapons");
 286         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
 287                 modifications = strcat(modifications, ", Low gravity");
 288         if(g_cloaked && !g_cts)
 289                 modifications = strcat(modifications, ", Cloaked");
 290         if(g_grappling_hook)
 291                 modifications = strcat(modifications, ", Hook");
 292         if(g_weapon_stay && !g_cts)
 293                 modifications = strcat(modifications, ", Weapons stay");
 294         if(g_jetpack)
 295                 modifications = strcat(modifications, ", Jet pack");
 296         if(autocvar_g_powerups == 0)
 297                 modifications = strcat(modifications, ", No powerups");
 298         if(autocvar_g_powerups > 0)
 299                 modifications = strcat(modifications, ", Powerups");
 300         modifications = substring(modifications, 2, strlen(modifications) - 2);
 301
 302         string versionmessage;
 303         versionmessage = GetClientVersionMessage();
 304
 305         s = strcat("This is Xonotic ", autocvar_g_xonoticversion, "\n", versionmessage);
 306         s = strcat(s, "^8\n\nmatch type is ^1", gamemode_name, "^8\n");
 307
 308         if(modifications != "")
 309                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
 310
 311         if (g_grappling_hook)
 312                 s = strcat(s, "\n\n^3grappling hook^8 is enabled, press 'e' to use it\n");
 313
 314         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
 315         {
 316                 if(cache_lastmutatormsg)
 317                         strunzone(cache_lastmutatormsg);
 318                 if(cache_mutatormsg)
 319                         strunzone(cache_mutatormsg);
 320                 cache_lastmutatormsg = strzone(autocvar_g_mutatormsg);
 321                 cache_mutatormsg = strzone(cache_lastmutatormsg);
 322         }
 323
 324         if (cache_mutatormsg != "") {
 325                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
 326         }
 327
 328         motd = autocvar_sv_motd;
 329         if (motd != "") {
 330                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
 331         }
 332         return s;
 333 }
 334
 335 void SetPlayerColors(entity pl, float _color)
 336 {
 337         /*string s;
 338         s = ftos(cl);
 339         stuffcmd(pl, strcat("color ", s, " ", s, "\n")  );
 340         pl.team = cl + 1;
 341         //pl.clientcolors = pl.clientcolors - (pl.clientcolors & 15) + cl;
 342         pl.clientcolors = 16*cl + cl;*/
 343
 344         float pants, shirt;
 345         pants = _color & 0x0F;
 346         shirt = _color & 0xF0;
 347
 348
 349         if(teamplay) {
 350                 setcolor(pl, 16*pants + pants);
 351         } else {
 352                 setcolor(pl, shirt + pants);
 353         }
 354 }
 355
 356 void SetPlayerTeam(entity pl, float t, float s, float noprint)
 357 {
 358         float _color;
 359
 360         if(t == 4)
 361                 _color = NUM_TEAM_4 - 1;
 362         else if(t == 3)
 363                 _color = NUM_TEAM_3 - 1;
 364         else if(t == 2)
 365                 _color = NUM_TEAM_2 - 1;
 366         else
 367                 _color = NUM_TEAM_1 - 1;
 368
 369         SetPlayerColors(pl,_color);
 370
 371         if(t != s) {
 372                 LogTeamchange(pl.playerid, pl.team, 3);  // log manual team join
 373
 374                 if(!noprint)
 375                 bprint(pl.netname, "^7 has changed from ", Team_NumberToColoredFullName(s), "^7 to ", Team_NumberToColoredFullName(t), "\n");
 376         }
 377
 378 }
 379
 380 // set c1...c4 to show what teams are allowed
 381 void CheckAllowedTeams (entity for_whom)
 382 {
 383         float dm;
 384         entity head;
 385         string teament_name;
 386
 387         c1 = c2 = c3 = c4 = -1;
 388         cb1 = cb2 = cb3 = cb4 = 0;
 389
 390         teament_name = string_null;
 391         if(g_onslaught)
 392         {
 393                 // onslaught is special
 394                 head = findchain(classname, "onslaught_generator");
 395                 while (head)
 396                 {
 397                         if (head.team == NUM_TEAM_1) c1 = 0;
 398                         if (head.team == NUM_TEAM_2) c2 = 0;
 399                         if (head.team == NUM_TEAM_3) c3 = 0;
 400                         if (head.team == NUM_TEAM_4) c4 = 0;
 401                         head = head.chain;
 402                 }
 403         }
 404         else if(g_domination)
 405                 teament_name = "dom_team";
 406         else if(g_ctf)
 407                 teament_name = "ctf_team";
 408         else if(g_tdm)
 409                 teament_name = "tdm_team";
 410         else if(g_nexball)
 411                 teament_name = "nexball_team";
 412         else if(g_assault)
 413                 c1 = c2 = 0; // Assault always has 2 teams
 414         else
 415         {
 416                 // cover anything else by treating it like tdm with no teams spawned
 417                 if(g_race)
 418                         dm = race_teams;
 419                 else
 420                         dm = 2;
 421
 422                 ret_float = dm;
 423                 MUTATOR_CALLHOOK(GetTeamCount);
 424                 dm = ret_float;
 425
 426                 if(dm >= 4)
 427                         c1 = c2 = c3 = c4 = 0;
 428                 else if(dm >= 3)
 429                         c1 = c2 = c3 = 0;
 430                 else
 431                         c1 = c2 = 0;
 432         }
 433
 434         // find out what teams are allowed if necessary
 435         if(teament_name)
 436         {
 437                 head = find(world, classname, teament_name);
 438                 while(head)
 439                 {
 440                         if(!(g_domination && head.netname == ""))
 441                         {
 442                                 if(head.team == NUM_TEAM_1)
 443                                         c1 = 0;
 444                                 else if(head.team == NUM_TEAM_2)
 445                                         c2 = 0;
 446                                 else if(head.team == NUM_TEAM_3)
 447                                         c3 = 0;
 448                                 else if(head.team == NUM_TEAM_4)
 449                                         c4 = 0;
 450                         }
 451                         head = find(head, classname, teament_name);
 452                 }
 453         }
 454
 455         // TODO: Balance quantity of bots across > 2 teams when bot_vs_human is set (and remove next line)
 456         if(c3==-1 && c4==-1)
 457         if(autocvar_bot_vs_human && for_whom)
 458         {
 459                 if(autocvar_bot_vs_human > 0)
 460                 {
 461                         // bots are all blue
 462                         if(IS_BOT_CLIENT(for_whom))
 463                                 c1 = c3 = c4 = -1;
 464                         else
 465                                 c2 = -1;
 466                 }
 467                 else
 468                 {
 469                         // bots are all red
 470                         if(IS_BOT_CLIENT(for_whom))
 471                                 c2 = c3 = c4 = -1;
 472                         else
 473                                 c1 = -1;
 474                 }
 475         }
 476
 477         // if player has a forced team, ONLY allow that one
 478         if(self.team_forced == NUM_TEAM_1 && c1 >= 0)
 479                 c2 = c3 = c4 = -1;
 480         else if(self.team_forced == NUM_TEAM_2 && c2 >= 0)
 481                 c1 = c3 = c4 = -1;
 482         else if(self.team_forced == NUM_TEAM_3 && c3 >= 0)
 483                 c1 = c2 = c4 = -1;
 484         else if(self.team_forced == NUM_TEAM_4 && c4 >= 0)
 485                 c1 = c2 = c3 = -1;
 486 }
 487
 488 float PlayerValue(entity p)
 489 {
 490         return 1;
 491         // FIXME: it always returns 1...
 492 }
 493
 494 // c1...c4 should be set to -1 (not allowed) or 0 (allowed).
 495 // teams that are allowed will now have their player counts stored in c1...c4
 496 void GetTeamCounts(entity ignore)
 497 {
 498         entity head;
 499         float value, bvalue;
 500         // now count how many players are on each team already
 501
 502         // FIXME: also find and memorize the lowest-scoring bot on each team (in case players must be shuffled around)
 503         // also remember the lowest-scoring player
 504
 505         FOR_EACH_CLIENT(head)
 506         {
 507                 float t;
 508                 if(IS_PLAYER(head))
 509                         t = head.team;
 510                 else if(head.team_forced > 0)
 511                         t = head.team_forced; // reserve the spot
 512                 else
 513                         continue;
 514                 if(head != ignore)// && head.netname != "")
 515                 {
 516                         value = PlayerValue(head);
 517                         if(IS_BOT_CLIENT(head))
 518                                 bvalue = value;
 519                         else
 520                                 bvalue = 0;
 521                         if(t == NUM_TEAM_1)
 522                         {
 523                                 if(c1 >= 0)
 524                                 {
 525                                         c1 = c1 + value;
 526                                         cb1 = cb1 + bvalue;
 527                                 }
 528                         }
 529                         if(t == NUM_TEAM_2)
 530                         {
 531                                 if(c2 >= 0)
 532                                 {
 533                                         c2 = c2 + value;
 534                                         cb2 = cb2 + bvalue;
 535                                 }
 536                         }
 537                         if(t == NUM_TEAM_3)
 538                         {
 539                                 if(c3 >= 0)
 540                                 {
 541                                         c3 = c3 + value;
 542                                         cb3 = cb3 + bvalue;
 543                                 }
 544                         }
 545                         if(t == NUM_TEAM_4)
 546                         {
 547                                 if(c4 >= 0)
 548                                 {
 549                                         c4 = c4 + value;
 550                                         cb4 = cb4 + bvalue;
 551                                 }
 552                         }
 553                 }
 554         }
 555
 556         // if the player who has a forced team has not joined yet, reserve the spot
 557         if(autocvar_g_campaign)
 558         {
 559                 switch(autocvar_g_campaign_forceteam)
 560                 {
 561                         case 1: if(c1 == cb1) ++c1; break;
 562                         case 2: if(c2 == cb2) ++c2; break;
 563                         case 3: if(c3 == cb3) ++c3; break;
 564                         case 4: if(c4 == cb4) ++c4; break;
 565                 }
 566         }
 567 }
 568
 569 float TeamSmallerEqThanTeam(float ta, float tb, entity e)
 570 {
 571         // we assume that CheckAllowedTeams and GetTeamCounts have already been called
 572         float f;
 573         float ca = -1, cb = -1, cba = 0, cbb = 0, sa = 0, sb = 0;
 574
 575         switch(ta)
 576         {
 577                 case 1: ca = c1; cba = cb1; sa = team1_score; break;
 578                 case 2: ca = c2; cba = cb2; sa = team2_score; break;
 579                 case 3: ca = c3; cba = cb3; sa = team3_score; break;
 580                 case 4: ca = c4; cba = cb4; sa = team4_score; break;
 581         }
 582         switch(tb)
 583         {
 584                 case 1: cb = c1; cbb = cb1; sb = team1_score; break;
 585                 case 2: cb = c2; cbb = cb2; sb = team2_score; break;
 586                 case 3: cb = c3; cbb = cb3; sb = team3_score; break;
 587                 case 4: cb = c4; cbb = cb4; sb = team4_score; break;
 588         }
 589
 590         // invalid
 591         if(ca < 0 || cb < 0)
 592                 return FALSE;
 593
 594         // equal
 595         if(ta == tb)
 596                 return TRUE;
 597
 598         if(IS_REAL_CLIENT(e))
 599         {
 600                 if(bots_would_leave)
 601                 {
 602                         ca -= cba * 0.999;
 603                         cb -= cbb * 0.999;
 604                 }
 605         }
 606
 607         // keep teams alive (teams of size 0 always count as smaller, ignoring score)
 608         if(ca < 1)
 609                 if(cb >= 1)
 610                         return TRUE;
 611         if(ca >= 1)
 612                 if(cb < 1)
 613                         return FALSE;
 614
 615         // first, normalize
 616         f = max(ca, cb, 1);
 617         ca /= f;
 618         cb /= f;
 619         f = max(sa, sb, 1);
 620         sa /= f;
 621         sb /= f;
 622
 623         // the more we're at the end of the match, the more take scores into account
 624         f = bound(0, game_completion_ratio * autocvar_g_balance_teams_scorefactor, 1);
 625         ca += (sa - ca) * f;
 626         cb += (sb - cb) * f;
 627
 628         return ca <= cb;
 629 }
 630
 631 // returns # of smallest team (1, 2, 3, 4)
 632 // NOTE: Assumes CheckAllowedTeams has already been called!
 633 float FindSmallestTeam(entity pl, float ignore_pl)
 634 {
 635         float totalteams, t;
 636         totalteams = 0;
 637
 638         // find out what teams are available
 639         //CheckAllowedTeams();
 640
 641         // make sure there are at least 2 teams to join
 642         if(c1 >= 0)
 643                 totalteams = totalteams + 1;
 644         if(c2 >= 0)
 645                 totalteams = totalteams + 1;
 646         if(c3 >= 0)
 647                 totalteams = totalteams + 1;
 648         if(c4 >= 0)
 649                 totalteams = totalteams + 1;
 650
 651         if((autocvar_bot_vs_human || pl.team_forced > 0) && totalteams == 1)
 652                 totalteams += 1;
 653
 654         if(totalteams <= 1)
 655         {
 656                 if(autocvar_g_campaign && pl && IS_REAL_CLIENT(pl))
 657                         return 1; // special case for campaign and player joining
 658                 else if(g_domination)
 659                         error("Too few teams available for domination\n");
 660                 else if(g_ctf)
 661                         error("Too few teams available for ctf\n");
 662                 else if(g_keyhunt)
 663                         error("Too few teams available for key hunt\n");
 664                 else if(g_freezetag)
 665                         error("Too few teams available for freeze tag\n");
 666                 else
 667                         error("Too few teams available for team deathmatch\n");
 668         }
 669
 670         // count how many players are in each team
 671         if(ignore_pl)
 672                 GetTeamCounts(pl);
 673         else
 674                 GetTeamCounts(world);
 675
 676         RandomSelection_Init();
 677
 678         t = 1;
 679         if(TeamSmallerEqThanTeam(2, t, pl))
 680                 t = 2;
 681         if(TeamSmallerEqThanTeam(3, t, pl))
 682                 t = 3;
 683         if(TeamSmallerEqThanTeam(4, t, pl))
 684                 t = 4;
 685
 686         // now t is the minimum, or A minimum!
 687         if(t == 1 || TeamSmallerEqThanTeam(1, t, pl))
 688                 RandomSelection_Add(world, 1, string_null, 1, 1);
 689         if(t == 2 || TeamSmallerEqThanTeam(2, t, pl))
 690                 RandomSelection_Add(world, 2, string_null, 1, 1);
 691         if(t == 3 || TeamSmallerEqThanTeam(3, t, pl))
 692                 RandomSelection_Add(world, 3, string_null, 1, 1);
 693         if(t == 4 || TeamSmallerEqThanTeam(4, t, pl))
 694                 RandomSelection_Add(world, 4, string_null, 1, 1);
 695
 696         return RandomSelection_chosen_float;
 697 }
 698
 699 float JoinBestTeam(entity pl, float only_return_best, float forcebestteam)
 700 {
 701         float smallest, selectedteam;
 702
 703         // don't join a team if we're not playing a team game
 704         if(!teamplay)
 705                 return 0;
 706
 707         // find out what teams are available
 708         CheckAllowedTeams(pl);
 709
 710         // if we don't care what team he ends up on, put him on whatever team he entered as.
 711         // if he's not on a valid team, then let other code put him on the smallest team
 712         if(!forcebestteam)
 713         {
 714                 if(     c1 >= 0 && pl.team == NUM_TEAM_1)
 715                         selectedteam = pl.team;
 716                 else if(c2 >= 0 && pl.team == NUM_TEAM_2)
 717                         selectedteam = pl.team;
 718                 else if(c3 >= 0 && pl.team == NUM_TEAM_3)
 719                         selectedteam = pl.team;
 720                 else if(c4 >= 0 && pl.team == NUM_TEAM_4)
 721                         selectedteam = pl.team;
 722                 else
 723                         selectedteam = -1;
 724
 725                 if(selectedteam > 0)
 726                 {
 727                         if(!only_return_best)
 728                         {
 729                                 SetPlayerColors(pl, selectedteam - 1);
 730
 731                                 // when JoinBestTeam is called by client.qc/ClientKill_Now_TeamChange the players team is -1 and thus skipped
 732                                 // when JoinBestTeam is called by cl_client.qc/ClientConnect the player_id is 0 the log attempt is rejected
 733                                 LogTeamchange(pl.playerid, pl.team, 99);
 734                         }
 735                         return selectedteam;
 736                 }
 737                 // otherwise end up on the smallest team (handled below)
 738         }
 739
 740         smallest = FindSmallestTeam(pl, TRUE);
 741
 742         if(!only_return_best && !pl.bot_forced_team)
 743         {
 744                 TeamchangeFrags(self);
 745                 if(smallest == 1)
 746                 {
 747                         SetPlayerColors(pl, NUM_TEAM_1 - 1);
 748                 }
 749                 else if(smallest == 2)
 750                 {
 751                         SetPlayerColors(pl, NUM_TEAM_2 - 1);
 752                 }
 753                 else if(smallest == 3)
 754                 {
 755                         SetPlayerColors(pl, NUM_TEAM_3 - 1);
 756                 }
 757                 else if(smallest == 4)
 758                 {
 759                         SetPlayerColors(pl, NUM_TEAM_4 - 1);
 760                 }
 761                 else
 762                 {
 763                         error("smallest team: invalid team\n");
 764                 }
 765
 766                 LogTeamchange(pl.playerid, pl.team, 2); // log auto join
 767
 768                 if(pl.deadflag == DEAD_NO)
 769                         Damage(pl, pl, pl, 100000, DEATH_TEAMCHANGE, pl.origin, '0 0 0');
 770         }
 771
 772         return smallest;
 773 }
 774
 775 //void() ctf_playerchanged;
 776 void SV_ChangeTeam(float _color)
 777 {
 778         float scolor, dcolor, steam, dteam; //, dbotcount, scount, dcount;
 779
 780         // in normal deathmatch we can just apply the color and we're done
 781         if(!teamplay) {
 782                 SetPlayerColors(self, _color);
 783                 return;
 784         }
 785
 786         scolor = self.clientcolors & 0x0F;
 787         dcolor = _color & 0x0F;
 788
 789         if(scolor == NUM_TEAM_1 - 1)
 790                 steam = 1;
 791         else if(scolor == NUM_TEAM_2 - 1)
 792                 steam = 2;
 793         else if(scolor == NUM_TEAM_3 - 1)
 794                 steam = 3;
 795         else // if(scolor == NUM_TEAM_4 - 1)
 796                 steam = 4;
 797         if(dcolor == NUM_TEAM_1 - 1)
 798                 dteam = 1;
 799         else if(dcolor == NUM_TEAM_2 - 1)
 800                 dteam = 2;
 801         else if(dcolor == NUM_TEAM_3 - 1)
 802                 dteam = 3;
 803         else // if(dcolor == NUM_TEAM_4 - 1)
 804                 dteam = 4;
 805
 806         CheckAllowedTeams(self);
 807
 808         if(dteam == 1 && c1 < 0) dteam = 4;
 809         if(dteam == 4 && c4 < 0) dteam = 3;
 810         if(dteam == 3 && c3 < 0) dteam = 2;
 811         if(dteam == 2 && c2 < 0) dteam = 1;
 812
 813         // not changing teams
 814         if(scolor == dcolor)
 815         {
 816                 //bprint("same team change\n");
 817                 SetPlayerTeam(self, dteam, steam, TRUE);
 818                 return;
 819         }
 820
 821         if((autocvar_g_campaign) || (autocvar_g_changeteam_banned && self.wasplayer)) {
 822                 sprint(self, "Team changes not allowed\n");
 823                 return; // changing teams is not allowed
 824         }
 825
 826         // autocvar_g_balance_teams_prevent_imbalance only makes sense if autocvar_g_balance_teams is on, as it makes the team selection dialog pointless
 827         if(autocvar_g_balance_teams && autocvar_g_balance_teams_prevent_imbalance)
 828         {
 829                 GetTeamCounts(self);
 830                 if(!TeamSmallerEqThanTeam(dteam, steam, self))
 831                 {
 832                         sprint(self, "Cannot change to a larger/better/shinier team\n");
 833                         return;
 834                 }
 835         }
 836
 837 //      bprint("allow change teams from ", ftos(steam), " to ", ftos(dteam), "\n");
 838
 839         if(IS_PLAYER(self) && steam != dteam)
 840         {
 841                 // reduce frags during a team change
 842                 TeamchangeFrags(self);
 843         }
 844
 845         SetPlayerTeam(self, dteam, steam, FALSE);
 846
 847         if(IS_PLAYER(self) && steam != dteam)
 848         {
 849                 // kill player when changing teams
 850                 if(self.deadflag == DEAD_NO)
 851                         Damage(self, self, self, 100000, DEATH_TEAMCHANGE, self.origin, '0 0 0');
 852         }
 853 }
 854
 855 void ShufflePlayerOutOfTeam (float source_team)
 856 {
 857         float smallestteam, smallestteam_count, steam;
 858         float lowest_bot_score, lowest_player_score;
 859         entity head, lowest_bot, lowest_player, selected;
 860
 861         smallestteam = 0;
 862         smallestteam_count = 999999999;
 863
 864         if(c1 >= 0 && c1 < smallestteam_count)
 865         {
 866                 smallestteam = 1;
 867                 smallestteam_count = c1;
 868         }
 869         if(c2 >= 0 && c2 < smallestteam_count)
 870         {
 871                 smallestteam = 2;
 872                 smallestteam_count = c2;
 873         }
 874         if(c3 >= 0 && c3 < smallestteam_count)
 875         {
 876                 smallestteam = 3;
 877                 smallestteam_count = c3;
 878         }
 879         if(c4 >= 0 && c4 < smallestteam_count)
 880         {
 881                 smallestteam = 4;
 882                 smallestteam_count = c4;
 883         }
 884
 885         if(!smallestteam)
 886         {
 887                 bprint("warning: no smallest team\n");
 888                 return;
 889         }
 890
 891         if(source_team == 1)
 892                 steam = NUM_TEAM_1;
 893         else if(source_team == 2)
 894                 steam = NUM_TEAM_2;
 895         else if(source_team == 3)
 896                 steam = NUM_TEAM_3;
 897         else // if(source_team == 4)
 898                 steam = NUM_TEAM_4;
 899
 900         lowest_bot = world;
 901         lowest_bot_score = 999999999;
 902         lowest_player = world;
 903         lowest_player_score = 999999999;
 904
 905         // find the lowest-scoring player & bot of that team
 906         FOR_EACH_PLAYER(head)
 907         {
 908                 if(head.team == steam)
 909                 {
 910                         if(head.isbot)
 911                         {
 912                                 if(head.totalfrags < lowest_bot_score)
 913                                 {
 914                                         lowest_bot = head;
 915                                         lowest_bot_score = head.totalfrags;
 916                                 }
 917                         }
 918                         else
 919                         {
 920                                 if(head.totalfrags < lowest_player_score)
 921                                 {
 922                                         lowest_player = head;
 923                                         lowest_player_score = head.totalfrags;
 924                                 }
 925                         }
 926                 }
 927         }
 928
 929         // prefers to move a bot...
 930         if(lowest_bot != world)
 931                 selected = lowest_bot;
 932         // but it will move a player if it has to
 933         else
 934                 selected = lowest_player;
 935         // don't do anything if it couldn't find anyone
 936         if(!selected)
 937         {
 938                 bprint("warning: couldn't find a player to move from team\n");
 939                 return;
 940         }
 941
 942         // smallest team gains a member
 943         if(smallestteam == 1)
 944         {
 945                 c1 = c1 + 1;
 946         }
 947         else if(smallestteam == 2)
 948         {
 949                 c2 = c2 + 1;
 950         }
 951         else if(smallestteam == 3)
 952         {
 953                 c3 = c3 + 1;
 954         }
 955         else if(smallestteam == 4)
 956         {
 957                 c4 = c4 + 1;
 958         }
 959         else
 960         {
 961                 bprint("warning: destination team invalid\n");
 962                 return;
 963         }
 964         // source team loses a member
 965         if(source_team == 1)
 966         {
 967                 c1 = c1 + 1;
 968         }
 969         else if(source_team == 2)
 970         {
 971                 c2 = c2 + 2;
 972         }
 973         else if(source_team == 3)
 974         {
 975                 c3 = c3 + 3;
 976         }
 977         else if(source_team == 4)
 978         {
 979                 c4 = c4 + 4;
 980         }
 981         else
 982         {
 983                 bprint("warning: source team invalid\n");
 984                 return;
 985         }
 986
 987         // move the player to the new team
 988         TeamchangeFrags(selected);
 989         SetPlayerTeam(selected, smallestteam, source_team, FALSE);
 990
 991         if(selected.deadflag == DEAD_NO)
 992                 Damage(selected, selected, selected, 100000, DEATH_AUTOTEAMCHANGE, selected.origin, '0 0 0');
 993         centerprint(selected, strcat("You have been moved into a different team to improve team balance\nYou are now on: ", Team_ColoredFullName(selected.team)));
 994 }
 995
 996 // code from here on is just to support maps that don't have team entities
 997 void tdm_spawnteam (string teamname, float teamcolor)
 998 {
 999         entity e;
1000         e = spawn();
1001         e.classname = "tdm_team";
1002         e.netname = teamname;
1003         e.cnt = teamcolor;
1004         e.team = e.cnt + 1;
1005 }
1006
1007 // spawn some default teams if the map is not set up for tdm
1008 void tdm_spawnteams()
1009 {
1010         float numteams;
1011
1012         numteams = autocvar_g_tdm_teams_override;
1013         if(numteams < 2)
1014                 numteams = autocvar_g_tdm_teams;
1015         numteams = bound(2, numteams, 4);
1016
1017         tdm_spawnteam("Red", NUM_TEAM_1-1);
1018         tdm_spawnteam("Blue", NUM_TEAM_2-1);
1019         if(numteams >= 3)
1020                 tdm_spawnteam("Yellow", NUM_TEAM_3-1);
1021         if(numteams >= 4)
1022                 tdm_spawnteam("Pink", NUM_TEAM_4-1);
1023 }
1024
1025 void tdm_delayedinit()
1026 {
1027         // if no teams are found, spawn defaults
1028         if (find(world, classname, "tdm_team") == world)
1029                 tdm_spawnteams();
1030 }
1031
1032 void tdm_init()
1033 {
1034         InitializeEntity(world, tdm_delayedinit, INITPRIO_GAMETYPE);
1035 }