qcsrc/server/teamplay.qc

   1 #include "teamplay.qh"
   2
   3 #include "cl_client.qh"
   4 #include "race.qh"
   5 #include "scores.qh"
   6 #include "scores_rules.qh"
   7
   8 #include "bot/bot.qh"
   9
  10 #include "command/vote.qh"
  11
  12 #include "mutators/all.qh"
  13
  14 #include "../common/deathtypes/all.qh"
  15 #include "../common/gamemodes/all.qh"
  16 #include "../common/teams.qh"
  17
  18 void TeamchangeFrags(entity e)
  19 {
  20         PlayerScore_Clear(e);
  21 }
  22
  23 void LogTeamchange(float player_id, float team_number, float type)
  24 {
  25         if(!autocvar_sv_eventlog)
  26                 return;
  27
  28         if(player_id < 1)
  29                 return;
  30
  31         GameLogEcho(strcat(":team:", ftos(player_id), ":", ftos(team_number), ":", ftos(type)));
  32 }
  33
  34 void default_delayedinit(entity this)
  35 {
  36         if(!scores_initialized)
  37                 ScoreRules_generic();
  38 }
  39
  40 void ActivateTeamplay()
  41 {
  42         serverflags |= SERVERFLAG_TEAMPLAY;
  43         teamplay = 1;
  44         cvar_set("teamplay", "2");  // DP needs this for sending proper getstatus replies.
  45 }
  46
  47 void InitGameplayMode()
  48 {
  49         VoteReset();
  50
  51         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
  52         get_mi_min_max(1);
  53         world.mins = mi_min;
  54         world.maxs = mi_max;
  55
  56         MapInfo_LoadMapSettings(mapname);
  57         serverflags &= ~SERVERFLAG_TEAMPLAY;
  58         teamplay = 0;
  59         cvar_set("teamplay", "0");  // DP needs this for sending proper getstatus replies.
  60
  61         if (!cvar_value_issafe(world.fog))
  62         {
  63                 LOG_INFO("The current map contains a potentially harmful fog setting, ignored\n");
  64                 world.fog = string_null;
  65         }
  66         if(MapInfo_Map_fog != "")
  67                 if(MapInfo_Map_fog == "none")
  68                         world.fog = string_null;
  69                 else
  70                         world.fog = strzone(MapInfo_Map_fog);
  71         clientstuff = strzone(MapInfo_Map_clientstuff);
  72
  73         MapInfo_ClearTemps();
  74
  75         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
  76
  77         cache_mutatormsg = strzone("");
  78         cache_lastmutatormsg = strzone("");
  79
  80         InitializeEntity(NULL, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
  81 }
  82
  83 string GetClientVersionMessage(entity this)
  84 {
  85         string versionmsg;
  86         if (this.version_mismatch) {
  87                 if(this.version < autocvar_gameversion) {
  88                         versionmsg = "^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8";
  89                 } else {
  90                         versionmsg = "^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8";
  91                 }
  92         } else {
  93                 versionmsg = "^2client version and server version are compatible.^8";
  94         }
  95         return versionmsg;
  96 }
  97
  98 string getwelcomemessage(entity this)
  99 {
 100         string s, modifications, motd;
 101
 102         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
 103         modifications = M_ARGV(0, string);
 104
 105         if(g_weaponarena)
 106         {
 107                 if(g_weaponarena_random)
 108                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
 109                 else
 110                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
 111         }
 112         else if(cvar("g_balance_blaster_weaponstart") == 0)
 113                 modifications = strcat(modifications, ", No start weapons");
 114         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
 115                 modifications = strcat(modifications, ", Low gravity");
 116         if(g_weapon_stay && !g_cts)
 117                 modifications = strcat(modifications, ", Weapons stay");
 118         if(g_jetpack)
 119                 modifications = strcat(modifications, ", Jet pack");
 120         if(autocvar_g_powerups == 0)
 121                 modifications = strcat(modifications, ", No powerups");
 122         if(autocvar_g_powerups > 0)
 123                 modifications = strcat(modifications, ", Powerups");
 124         modifications = substring(modifications, 2, strlen(modifications) - 2);
 125
 126         string versionmessage = GetClientVersionMessage(this);
 127
 128         s = strcat("This is Xonotic ", autocvar_g_xonoticversion, "\n", versionmessage);
 129         s = strcat(s, "^8\n\nmatch type is ^1", gamemode_name, "^8\n");
 130
 131         if(modifications != "")
 132                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
 133
 134         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
 135         {
 136                 if(cache_lastmutatormsg)
 137                         strunzone(cache_lastmutatormsg);
 138                 if(cache_mutatormsg)
 139                         strunzone(cache_mutatormsg);
 140                 cache_lastmutatormsg = strzone(autocvar_g_mutatormsg);
 141                 cache_mutatormsg = strzone(cache_lastmutatormsg);
 142         }
 143
 144         if (cache_mutatormsg != "") {
 145                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
 146         }
 147
 148         string mutator_msg = "";
 149         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
 150         mutator_msg = M_ARGV(0, string);
 151
 152         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
 153
 154         motd = autocvar_sv_motd;
 155         if (motd != "") {
 156                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
 157         }
 158         return s;
 159 }
 160
 161 void SetPlayerColors(entity pl, float _color)
 162 {
 163         /*string s;
 164         s = ftos(cl);
 165         stuffcmd(pl, strcat("color ", s, " ", s, "\n")  );
 166         pl.team = cl + 1;
 167         //pl.clientcolors = pl.clientcolors - (pl.clientcolors & 15) + cl;
 168         pl.clientcolors = 16*cl + cl;*/
 169
 170         float pants, shirt;
 171         pants = _color & 0x0F;
 172         shirt = _color & 0xF0;
 173
 174
 175         if(teamplay) {
 176                 setcolor(pl, 16*pants + pants);
 177         } else {
 178                 setcolor(pl, shirt + pants);
 179         }
 180 }
 181
 182 void SetPlayerTeam(entity pl, float t, float s, float noprint)
 183 {
 184         float _color;
 185
 186         if(t == 4)
 187                 _color = NUM_TEAM_4 - 1;
 188         else if(t == 3)
 189                 _color = NUM_TEAM_3 - 1;
 190         else if(t == 2)
 191                 _color = NUM_TEAM_2 - 1;
 192         else
 193                 _color = NUM_TEAM_1 - 1;
 194
 195         SetPlayerColors(pl,_color);
 196
 197         if(t != s) {
 198                 LogTeamchange(pl.playerid, pl.team, 3);  // log manual team join
 199
 200                 if(!noprint)
 201                 bprint(pl.netname, "^7 has changed from ", Team_NumberToColoredFullName(s), "^7 to ", Team_NumberToColoredFullName(t), "\n");
 202         }
 203
 204 }
 205
 206 // set c1...c4 to show what teams are allowed
 207 void CheckAllowedTeams (entity for_whom)
 208 {
 209         int dm = 0;
 210
 211         c1 = c2 = c3 = c4 = -1;
 212         cb1 = cb2 = cb3 = cb4 = 0;
 213
 214         string teament_name = string_null;
 215
 216         bool mutator_returnvalue = MUTATOR_CALLHOOK(GetTeamCount, dm, teament_name);
 217         dm = M_ARGV(0, float);
 218         teament_name = M_ARGV(1, string);
 219
 220         if(!mutator_returnvalue)
 221         {
 222                 if(dm & BIT(0)) c1 = 0;
 223                 if(dm & BIT(1)) c2 = 0;
 224                 if(dm & BIT(2)) c3 = 0;
 225                 if(dm & BIT(3)) c4 = 0;
 226         }
 227
 228         // find out what teams are allowed if necessary
 229         if(teament_name)
 230         {
 231                 entity head = find(NULL, classname, teament_name);
 232                 while(head)
 233                 {
 234                         switch(head.team)
 235                         {
 236                                 case NUM_TEAM_1: c1 = 0; break;
 237                                 case NUM_TEAM_2: c2 = 0; break;
 238                                 case NUM_TEAM_3: c3 = 0; break;
 239                                 case NUM_TEAM_4: c4 = 0; break;
 240                         }
 241
 242                         head = find(head, classname, teament_name);
 243                 }
 244         }
 245
 246         // TODO: Balance quantity of bots across > 2 teams when bot_vs_human is set (and remove next line)
 247         if(c3==-1 && c4==-1)
 248         if(autocvar_bot_vs_human && for_whom)
 249         {
 250                 if(autocvar_bot_vs_human > 0)
 251                 {
 252                         // bots are all blue
 253                         if(IS_BOT_CLIENT(for_whom))
 254                                 c1 = c3 = c4 = -1;
 255                         else
 256                                 c2 = -1;
 257                 }
 258                 else
 259                 {
 260                         // bots are all red
 261                         if(IS_BOT_CLIENT(for_whom))
 262                                 c2 = c3 = c4 = -1;
 263                         else
 264                                 c1 = -1;
 265                 }
 266         }
 267
 268         if(!for_whom)
 269                 return;
 270
 271         // if player has a forced team, ONLY allow that one
 272         if(for_whom.team_forced == NUM_TEAM_1 && c1 >= 0)
 273                 c2 = c3 = c4 = -1;
 274         else if(for_whom.team_forced == NUM_TEAM_2 && c2 >= 0)
 275                 c1 = c3 = c4 = -1;
 276         else if(for_whom.team_forced == NUM_TEAM_3 && c3 >= 0)
 277                 c1 = c2 = c4 = -1;
 278         else if(for_whom.team_forced == NUM_TEAM_4 && c4 >= 0)
 279                 c1 = c2 = c3 = -1;
 280 }
 281
 282 float PlayerValue(entity p)
 283 {
 284         return 1;
 285         // FIXME: it always returns 1...
 286 }
 287
 288 // c1...c4 should be set to -1 (not allowed) or 0 (allowed).
 289 // teams that are allowed will now have their player counts stored in c1...c4
 290 void GetTeamCounts(entity ignore)
 291 {
 292         float value, bvalue;
 293         // now count how many players are on each team already
 294
 295         // FIXME: also find and memorize the lowest-scoring bot on each team (in case players must be shuffled around)
 296         // also remember the lowest-scoring player
 297
 298         FOREACH_CLIENT(true, LAMBDA(
 299                 float t;
 300                 if(IS_PLAYER(it) || it.caplayer)
 301                         t = it.team;
 302                 else if(it.team_forced > 0)
 303                         t = it.team_forced; // reserve the spot
 304                 else
 305                         continue;
 306                 if(it != ignore)// && it.netname != "")
 307                 {
 308                         value = PlayerValue(it);
 309                         if(IS_BOT_CLIENT(it))
 310                                 bvalue = value;
 311                         else
 312                                 bvalue = 0;
 313                         if(t == NUM_TEAM_1)
 314                         {
 315                                 if(c1 >= 0)
 316                                 {
 317                                         c1 = c1 + value;
 318                                         cb1 = cb1 + bvalue;
 319                                 }
 320                         }
 321                         if(t == NUM_TEAM_2)
 322                         {
 323                                 if(c2 >= 0)
 324                                 {
 325                                         c2 = c2 + value;
 326                                         cb2 = cb2 + bvalue;
 327                                 }
 328                         }
 329                         if(t == NUM_TEAM_3)
 330                         {
 331                                 if(c3 >= 0)
 332                                 {
 333                                         c3 = c3 + value;
 334                                         cb3 = cb3 + bvalue;
 335                                 }
 336                         }
 337                         if(t == NUM_TEAM_4)
 338                         {
 339                                 if(c4 >= 0)
 340                                 {
 341                                         c4 = c4 + value;
 342                                         cb4 = cb4 + bvalue;
 343                                 }
 344                         }
 345                 }
 346         ));
 347
 348         // if the player who has a forced team has not joined yet, reserve the spot
 349         if(autocvar_g_campaign)
 350         {
 351                 switch(autocvar_g_campaign_forceteam)
 352                 {
 353                         case 1: if(c1 == cb1) ++c1; break;
 354                         case 2: if(c2 == cb2) ++c2; break;
 355                         case 3: if(c3 == cb3) ++c3; break;
 356                         case 4: if(c4 == cb4) ++c4; break;
 357                 }
 358         }
 359 }
 360
 361 float TeamSmallerEqThanTeam(float ta, float tb, entity e)
 362 {
 363         // we assume that CheckAllowedTeams and GetTeamCounts have already been called
 364         float f;
 365         float ca = -1, cb = -1, cba = 0, cbb = 0, sa = 0, sb = 0;
 366
 367         switch(ta)
 368         {
 369                 case 1: ca = c1; cba = cb1; sa = team1_score; break;
 370                 case 2: ca = c2; cba = cb2; sa = team2_score; break;
 371                 case 3: ca = c3; cba = cb3; sa = team3_score; break;
 372                 case 4: ca = c4; cba = cb4; sa = team4_score; break;
 373         }
 374         switch(tb)
 375         {
 376                 case 1: cb = c1; cbb = cb1; sb = team1_score; break;
 377                 case 2: cb = c2; cbb = cb2; sb = team2_score; break;
 378                 case 3: cb = c3; cbb = cb3; sb = team3_score; break;
 379                 case 4: cb = c4; cbb = cb4; sb = team4_score; break;
 380         }
 381
 382         // invalid
 383         if(ca < 0 || cb < 0)
 384                 return false;
 385
 386         // equal
 387         if(ta == tb)
 388                 return true;
 389
 390         if(IS_REAL_CLIENT(e))
 391         {
 392                 if(bots_would_leave)
 393                 {
 394                         ca -= cba * 0.999;
 395                         cb -= cbb * 0.999;
 396                 }
 397         }
 398
 399         // keep teams alive (teams of size 0 always count as smaller, ignoring score)
 400         if(ca < 1)
 401                 if(cb >= 1)
 402                         return true;
 403         if(ca >= 1)
 404                 if(cb < 1)
 405                         return false;
 406
 407         // first, normalize
 408         f = max(ca, cb, 1);
 409         ca /= f;
 410         cb /= f;
 411         f = max(sa, sb, 1);
 412         sa /= f;
 413         sb /= f;
 414
 415         // the more we're at the end of the match, the more take scores into account
 416         f = bound(0, game_completion_ratio * autocvar_g_balance_teams_scorefactor, 1);
 417         ca += (sa - ca) * f;
 418         cb += (sb - cb) * f;
 419
 420         return ca <= cb;
 421 }
 422
 423 // returns # of smallest team (1, 2, 3, 4)
 424 // NOTE: Assumes CheckAllowedTeams has already been called!
 425 float FindSmallestTeam(entity pl, float ignore_pl)
 426 {
 427         int totalteams = 0;
 428         int t = 1; // initialize with a random team?
 429         if(c4 >= 0) t = 4;
 430         if(c3 >= 0) t = 3;
 431         if(c2 >= 0) t = 2;
 432         if(c1 >= 0) t = 1;
 433
 434         // find out what teams are available
 435         //CheckAllowedTeams();
 436
 437         // make sure there are at least 2 teams to join
 438         if(c1 >= 0)
 439                 totalteams = totalteams + 1;
 440         if(c2 >= 0)
 441                 totalteams = totalteams + 1;
 442         if(c3 >= 0)
 443                 totalteams = totalteams + 1;
 444         if(c4 >= 0)
 445                 totalteams = totalteams + 1;
 446
 447         if((autocvar_bot_vs_human || pl.team_forced > 0) && totalteams == 1)
 448                 totalteams += 1;
 449
 450         if(totalteams <= 1)
 451         {
 452                 if(autocvar_g_campaign && pl && IS_REAL_CLIENT(pl))
 453                         return 1; // special case for campaign and player joining
 454                 else
 455                         error(sprintf("Too few teams available for %s\n", MapInfo_Type_ToString(MapInfo_CurrentGametype())));
 456         }
 457
 458         // count how many players are in each team
 459         if(ignore_pl)
 460                 GetTeamCounts(pl);
 461         else
 462                 GetTeamCounts(NULL);
 463
 464         RandomSelection_Init();
 465
 466         if(TeamSmallerEqThanTeam(1, t, pl))
 467                 t = 1;
 468         if(TeamSmallerEqThanTeam(2, t, pl))
 469                 t = 2;
 470         if(TeamSmallerEqThanTeam(3, t, pl))
 471                 t = 3;
 472         if(TeamSmallerEqThanTeam(4, t, pl))
 473                 t = 4;
 474
 475         // now t is the minimum, or A minimum!
 476         if(t == 1 || TeamSmallerEqThanTeam(1, t, pl))
 477                 RandomSelection_Add(NULL, 1, string_null, 1, 1);
 478         if(t == 2 || TeamSmallerEqThanTeam(2, t, pl))
 479                 RandomSelection_Add(NULL, 2, string_null, 1, 1);
 480         if(t == 3 || TeamSmallerEqThanTeam(3, t, pl))
 481                 RandomSelection_Add(NULL, 3, string_null, 1, 1);
 482         if(t == 4 || TeamSmallerEqThanTeam(4, t, pl))
 483                 RandomSelection_Add(NULL, 4, string_null, 1, 1);
 484
 485         return RandomSelection_chosen_float;
 486 }
 487
 488 int JoinBestTeam(entity this, bool only_return_best, bool forcebestteam)
 489 {
 490         float smallest, selectedteam;
 491
 492         // don't join a team if we're not playing a team game
 493         if(!teamplay)
 494                 return 0;
 495
 496         // find out what teams are available
 497         CheckAllowedTeams(this);
 498
 499         // if we don't care what team he ends up on, put him on whatever team he entered as.
 500         // if he's not on a valid team, then let other code put him on the smallest team
 501         if(!forcebestteam)
 502         {
 503                 if(     c1 >= 0 && this.team == NUM_TEAM_1)
 504                         selectedteam = this.team;
 505                 else if(c2 >= 0 && this.team == NUM_TEAM_2)
 506                         selectedteam = this.team;
 507                 else if(c3 >= 0 && this.team == NUM_TEAM_3)
 508                         selectedteam = this.team;
 509                 else if(c4 >= 0 && this.team == NUM_TEAM_4)
 510                         selectedteam = this.team;
 511                 else
 512                         selectedteam = -1;
 513
 514                 if(selectedteam > 0)
 515                 {
 516                         if(!only_return_best)
 517                         {
 518                                 SetPlayerColors(this, selectedteam - 1);
 519
 520                                 // when JoinBestTeam is called by client.qc/ClientKill_Now_TeamChange the players team is -1 and thus skipped
 521                                 // when JoinBestTeam is called by cl_client.qc/ClientConnect the player_id is 0 the log attempt is rejected
 522                                 LogTeamchange(this.playerid, this.team, 99);
 523                         }
 524                         return selectedteam;
 525                 }
 526                 // otherwise end up on the smallest team (handled below)
 527         }
 528
 529         smallest = FindSmallestTeam(this, true);
 530
 531         if(!only_return_best && !this.bot_forced_team)
 532         {
 533                 TeamchangeFrags(this);
 534                 if(smallest == 1)
 535                 {
 536                         SetPlayerColors(this, NUM_TEAM_1 - 1);
 537                 }
 538                 else if(smallest == 2)
 539                 {
 540                         SetPlayerColors(this, NUM_TEAM_2 - 1);
 541                 }
 542                 else if(smallest == 3)
 543                 {
 544                         SetPlayerColors(this, NUM_TEAM_3 - 1);
 545                 }
 546                 else if(smallest == 4)
 547                 {
 548                         SetPlayerColors(this, NUM_TEAM_4 - 1);
 549                 }
 550                 else
 551                 {
 552                         error("smallest team: invalid team\n");
 553                 }
 554
 555                 LogTeamchange(this.playerid, this.team, 2); // log auto join
 556
 557                 if(!IS_DEAD(this))
 558                         Damage(this, this, this, 100000, DEATH_TEAMCHANGE.m_id, this.origin, '0 0 0');
 559         }
 560
 561         return smallest;
 562 }
 563
 564 //void() ctf_playerchanged;
 565 void SV_ChangeTeam(entity this, float _color)
 566 {
 567         float scolor, dcolor, steam, dteam; //, dbotcount, scount, dcount;
 568
 569         // in normal deathmatch we can just apply the color and we're done
 570         if(!teamplay)
 571                 SetPlayerColors(this, _color);
 572
 573         if(!IS_CLIENT(this))
 574         {
 575                 // since this is an engine function, and gamecode doesn't have any calls earlier than this, do the connecting message here
 576                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_CONNECTING, this.netname);
 577                 return;
 578         }
 579
 580         if(!teamplay)
 581                 return;
 582
 583         scolor = this.clientcolors & 0x0F;
 584         dcolor = _color & 0x0F;
 585
 586         if(scolor == NUM_TEAM_1 - 1)
 587                 steam = 1;
 588         else if(scolor == NUM_TEAM_2 - 1)
 589                 steam = 2;
 590         else if(scolor == NUM_TEAM_3 - 1)
 591                 steam = 3;
 592         else // if(scolor == NUM_TEAM_4 - 1)
 593                 steam = 4;
 594         if(dcolor == NUM_TEAM_1 - 1)
 595                 dteam = 1;
 596         else if(dcolor == NUM_TEAM_2 - 1)
 597                 dteam = 2;
 598         else if(dcolor == NUM_TEAM_3 - 1)
 599                 dteam = 3;
 600         else // if(dcolor == NUM_TEAM_4 - 1)
 601                 dteam = 4;
 602
 603         CheckAllowedTeams(this);
 604
 605         if(dteam == 1 && c1 < 0) dteam = 4;
 606         if(dteam == 4 && c4 < 0) dteam = 3;
 607         if(dteam == 3 && c3 < 0) dteam = 2;
 608         if(dteam == 2 && c2 < 0) dteam = 1;
 609
 610         // not changing teams
 611         if(scolor == dcolor)
 612         {
 613                 //bprint("same team change\n");
 614                 SetPlayerTeam(this, dteam, steam, true);
 615                 return;
 616         }
 617
 618         if((autocvar_g_campaign) || (autocvar_g_changeteam_banned && this.wasplayer)) {
 619                 Send_Notification(NOTIF_ONE, this, MSG_INFO, INFO_TEAMCHANGE_NOTALLOWED);
 620                 return; // changing teams is not allowed
 621         }
 622
 623         // autocvar_g_balance_teams_prevent_imbalance only makes sense if autocvar_g_balance_teams is on, as it makes the team selection dialog pointless
 624         if(autocvar_g_balance_teams && autocvar_g_balance_teams_prevent_imbalance)
 625         {
 626                 GetTeamCounts(this);
 627                 if(!TeamSmallerEqThanTeam(dteam, steam, this))
 628                 {
 629                         Send_Notification(NOTIF_ONE, this, MSG_INFO, INFO_TEAMCHANGE_LARGERTEAM);
 630                         return;
 631                 }
 632         }
 633
 634 //      bprint("allow change teams from ", ftos(steam), " to ", ftos(dteam), "\n");
 635
 636         if(IS_PLAYER(this) && steam != dteam)
 637         {
 638                 // reduce frags during a team change
 639                 TeamchangeFrags(this);
 640         }
 641
 642         MUTATOR_CALLHOOK(Player_ChangeTeam, this, steam, dteam);
 643
 644         SetPlayerTeam(this, dteam, steam, !IS_CLIENT(this));
 645
 646         if(IS_PLAYER(this) && steam != dteam)
 647         {
 648                 // kill player when changing teams
 649                 if(!IS_DEAD(this))
 650                         Damage(this, this, this, 100000, DEATH_TEAMCHANGE.m_id, this.origin, '0 0 0');
 651         }
 652 }
 653
 654 void ShufflePlayerOutOfTeam (float source_team)
 655 {
 656         float smallestteam, smallestteam_count, steam;
 657         float lowest_bot_score, lowest_player_score;
 658         entity lowest_bot, lowest_player, selected;
 659
 660         smallestteam = 0;
 661         smallestteam_count = 999999999;
 662
 663         if(c1 >= 0 && c1 < smallestteam_count)
 664         {
 665                 smallestteam = 1;
 666                 smallestteam_count = c1;
 667         }
 668         if(c2 >= 0 && c2 < smallestteam_count)
 669         {
 670                 smallestteam = 2;
 671                 smallestteam_count = c2;
 672         }
 673         if(c3 >= 0 && c3 < smallestteam_count)
 674         {
 675                 smallestteam = 3;
 676                 smallestteam_count = c3;
 677         }
 678         if(c4 >= 0 && c4 < smallestteam_count)
 679         {
 680                 smallestteam = 4;
 681                 smallestteam_count = c4;
 682         }
 683
 684         if(!smallestteam)
 685         {
 686                 bprint("warning: no smallest team\n");
 687                 return;
 688         }
 689
 690         if(source_team == 1)
 691                 steam = NUM_TEAM_1;
 692         else if(source_team == 2)
 693                 steam = NUM_TEAM_2;
 694         else if(source_team == 3)
 695                 steam = NUM_TEAM_3;
 696         else // if(source_team == 4)
 697                 steam = NUM_TEAM_4;
 698
 699         lowest_bot = NULL;
 700         lowest_bot_score = 999999999;
 701         lowest_player = NULL;
 702         lowest_player_score = 999999999;
 703
 704         // find the lowest-scoring player & bot of that team
 705         FOREACH_CLIENT(IS_PLAYER(it) && it.team == steam, LAMBDA(
 706                 if(it.isbot)
 707                 {
 708                         if(it.totalfrags < lowest_bot_score)
 709                         {
 710                                 lowest_bot = it;
 711                                 lowest_bot_score = it.totalfrags;
 712                         }
 713                 }
 714                 else
 715                 {
 716                         if(it.totalfrags < lowest_player_score)
 717                         {
 718                                 lowest_player = it;
 719                                 lowest_player_score = it.totalfrags;
 720                         }
 721                 }
 722         ));
 723
 724         // prefers to move a bot...
 725         if(lowest_bot != NULL)
 726                 selected = lowest_bot;
 727         // but it will move a player if it has to
 728         else
 729                 selected = lowest_player;
 730         // don't do anything if it couldn't find anyone
 731         if(!selected)
 732         {
 733                 bprint("warning: couldn't find a player to move from team\n");
 734                 return;
 735         }
 736
 737         // smallest team gains a member
 738         if(smallestteam == 1)
 739         {
 740                 c1 = c1 + 1;
 741         }
 742         else if(smallestteam == 2)
 743         {
 744                 c2 = c2 + 1;
 745         }
 746         else if(smallestteam == 3)
 747         {
 748                 c3 = c3 + 1;
 749         }
 750         else if(smallestteam == 4)
 751         {
 752                 c4 = c4 + 1;
 753         }
 754         else
 755         {
 756                 bprint("warning: destination team invalid\n");
 757                 return;
 758         }
 759         // source team loses a member
 760         if(source_team == 1)
 761         {
 762                 c1 = c1 + 1;
 763         }
 764         else if(source_team == 2)
 765         {
 766                 c2 = c2 + 2;
 767         }
 768         else if(source_team == 3)
 769         {
 770                 c3 = c3 + 3;
 771         }
 772         else if(source_team == 4)
 773         {
 774                 c4 = c4 + 4;
 775         }
 776         else
 777         {
 778                 bprint("warning: source team invalid\n");
 779                 return;
 780         }
 781
 782         // move the player to the new team
 783         TeamchangeFrags(selected);
 784         SetPlayerTeam(selected, smallestteam, source_team, false);
 785
 786         if(!IS_DEAD(selected))
 787                 Damage(selected, selected, selected, 100000, DEATH_AUTOTEAMCHANGE.m_id, selected.origin, '0 0 0');
 788         Send_Notification(NOTIF_ONE, selected, MSG_CENTER, CENTER_DEATH_SELF_AUTOTEAMCHANGE, selected.team);
 789 }