qcsrc/server/tturrets/system/system_main.qc

   1 #define cvar_base "g_turrets_unit_"
   2 .float clientframe;
   3 void turrets_setframe(float _frame, float client_only)
   4 {
   5     if((client_only ? self.clientframe : self.frame ) != _frame)
   6     {
   7         self.SendFlags |= TNSF_ANIM;
   8         self.anim_start_time = time;
   9     }
  10
  11      if(client_only)
  12         self.clientframe = _frame;
  13     else
  14         self.frame = _frame;
  15
  16 }
  17
  18 float turret_send(entity to, float sf)
  19 {
  20
  21         WriteByte(MSG_ENTITY, ENT_CLIENT_TURRET);
  22         WriteByte(MSG_ENTITY, sf);
  23         if(sf & TNSF_SETUP)
  24         {
  25             WriteByte(MSG_ENTITY, self.turret_type);
  26
  27             WriteCoord(MSG_ENTITY, self.origin_x);
  28             WriteCoord(MSG_ENTITY, self.origin_y);
  29             WriteCoord(MSG_ENTITY, self.origin_z);
  30
  31             WriteAngle(MSG_ENTITY, self.angles_x);
  32             WriteAngle(MSG_ENTITY, self.angles_y);
  33     }
  34
  35     if(sf & TNSF_ANG)
  36     {
  37         WriteShort(MSG_ENTITY, rint(self.tur_head.angles_x));
  38         WriteShort(MSG_ENTITY, rint(self.tur_head.angles_y));
  39     }
  40
  41     if(sf & TNSF_AVEL)
  42     {
  43         WriteShort(MSG_ENTITY, rint(self.tur_head.avelocity_x));
  44         WriteShort(MSG_ENTITY, rint(self.tur_head.avelocity_y));
  45     }
  46
  47     if(sf & TNSF_MOVE)
  48     {
  49         WriteShort(MSG_ENTITY, rint(self.origin_x));
  50         WriteShort(MSG_ENTITY, rint(self.origin_y));
  51         WriteShort(MSG_ENTITY, rint(self.origin_z));
  52
  53         WriteShort(MSG_ENTITY, rint(self.velocity_x));
  54         WriteShort(MSG_ENTITY, rint(self.velocity_y));
  55         WriteShort(MSG_ENTITY, rint(self.velocity_z));
  56
  57         WriteShort(MSG_ENTITY, rint(self.angles_y));
  58     }
  59
  60     if(sf & TNSF_ANIM)
  61     {
  62         WriteCoord(MSG_ENTITY, self.anim_start_time);
  63         WriteByte(MSG_ENTITY, self.frame);
  64     }
  65
  66     if(sf & TNSF_STATUS)
  67     {
  68         WriteByte(MSG_ENTITY, self.team);
  69
  70         if(self.health <= 0)
  71             WriteByte(MSG_ENTITY, 0);
  72         else
  73             WriteByte(MSG_ENTITY, ceil((self.health / self.tur_health) * 255));
  74     }
  75
  76         return TRUE;
  77 }
  78
  79 void load_unit_settings(entity ent, string unitname, float is_reload)
  80 {
  81     string sbase;
  82
  83     if (ent == world)
  84         return;
  85
  86     if not (ent.turret_scale_damage)    ent.turret_scale_damage  = 1;
  87     if not (ent.turret_scale_range)     ent.turret_scale_range   = 1;
  88     if not (ent.turret_scale_refire)    ent.turret_scale_refire  = 1;
  89     if not (ent.turret_scale_ammo)      ent.turret_scale_ammo    = 1;
  90     if not (ent.turret_scale_aim)       ent.turret_scale_aim     = 1;
  91     if not (ent.turret_scale_health)    ent.turret_scale_health  = 1;
  92     if not (ent.turret_scale_respawn)   ent.turret_scale_respawn = 1;
  93
  94     sbase = strcat(cvar_base,unitname);
  95     if (is_reload)
  96     {
  97         ent.enemy = world;
  98         ent.tur_head.avelocity = '0 0 0';
  99
 100         ent.tur_head.angles = '0 0 0';
 101     }
 102
 103     ent.health      = cvar(strcat(sbase,"_health")) * ent.turret_scale_health;
 104     ent.respawntime = cvar(strcat(sbase,"_respawntime")) * ent.turret_scale_respawn;
 105
 106     ent.shot_dmg          = cvar(strcat(sbase,"_shot_dmg")) * ent.turret_scale_damage;
 107     ent.shot_refire       = cvar(strcat(sbase,"_shot_refire")) * ent.turret_scale_refire;
 108     ent.shot_radius       = cvar(strcat(sbase,"_shot_radius")) * ent.turret_scale_damage;
 109     ent.shot_speed        = cvar(strcat(sbase,"_shot_speed"));
 110     ent.shot_spread       = cvar(strcat(sbase,"_shot_spread"));
 111     ent.shot_force        = cvar(strcat(sbase,"_shot_force")) * ent.turret_scale_damage;
 112     ent.shot_volly        = cvar(strcat(sbase,"_shot_volly"));
 113     ent.shot_volly_refire = cvar(strcat(sbase,"_shot_volly_refire")) * ent.turret_scale_refire;
 114
 115     ent.target_range         = cvar(strcat(sbase,"_target_range")) * ent.turret_scale_range;
 116     ent.target_range_min     = cvar(strcat(sbase,"_target_range_min")) * ent.turret_scale_range;
 117     ent.target_range_optimal = cvar(strcat(sbase,"_target_range_optimal")) * ent.turret_scale_range;
 118     //ent.target_range_fire    = cvar(strcat(sbase,"_target_range_fire")) * ent.turret_scale_range;
 119
 120     ent.target_select_rangebias  = cvar(strcat(sbase,"_target_select_rangebias"));
 121     ent.target_select_samebias   = cvar(strcat(sbase,"_target_select_samebias"));
 122     ent.target_select_anglebias  = cvar(strcat(sbase,"_target_select_anglebias"));
 123     ent.target_select_playerbias = cvar(strcat(sbase,"_target_select_playerbias"));
 124     //ent.target_select_fov = cvar(cvar_gets(sbase,"_target_select_fov"));
 125
 126     ent.ammo_max      = cvar(strcat(sbase,"_ammo_max")) * ent.turret_scale_ammo;
 127     ent.ammo_recharge = cvar(strcat(sbase,"_ammo_recharge")) * ent.turret_scale_ammo;
 128
 129     ent.aim_firetolerance_dist = cvar(strcat(sbase,"_aim_firetolerance_dist"));
 130     ent.aim_speed    = cvar(strcat(sbase,"_aim_speed")) * ent.turret_scale_aim;
 131     ent.aim_maxrot   = cvar(strcat(sbase,"_aim_maxrot"));
 132     ent.aim_maxpitch = cvar(strcat(sbase,"_aim_maxpitch"));
 133
 134     ent.track_type        = cvar(strcat(sbase,"_track_type"));
 135     ent.track_accel_pitch = cvar(strcat(sbase,"_track_accel_pitch"));
 136     ent.track_accel_rot   = cvar(strcat(sbase,"_track_accel_rot"));
 137     ent.track_blendrate   = cvar(strcat(sbase,"_track_blendrate"));
 138
 139     if(is_reload)
 140         if(ent.turret_respawnhook)
 141             ent.turret_respawnhook();
 142 }
 143
 144 void turret_projectile_explode()
 145 {
 146
 147     self.takedamage = DAMAGE_NO;
 148     self.event_damage = func_null;
 149 #ifdef TURRET_DEBUG
 150     float d;
 151     d = RadiusDamage (self, self.owner, self.owner.shot_dmg, 0, self.owner.shot_radius, self, self.owner.shot_force, self.totalfrags, world);
 152     self.owner.tur_dbg_dmg_t_h = self.owner.tur_dbg_dmg_t_h + d;
 153     self.owner.tur_dbg_dmg_t_f = self.owner.tur_dbg_dmg_t_f + self.owner.shot_dmg;
 154 #else
 155     RadiusDamage (self, self.realowner, self.owner.shot_dmg, 0, self.owner.shot_radius, self, self.owner.shot_force, self.totalfrags, world);
 156 #endif
 157     remove(self);
 158 }
 159
 160 void turret_projectile_touch()
 161 {
 162     PROJECTILE_TOUCH;
 163     turret_projectile_explode();
 164 }
 165
 166 void turret_projectile_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector vforce)
 167 {
 168     self.velocity  += vforce;
 169     self.health    -= damage;
 170     //self.realowner  = attacker; // Dont change realowner, it does not make much sense for turrets
 171     if(self.health <= 0)
 172         W_PrepareExplosionByDamage(self.owner, turret_projectile_explode);
 173 }
 174
 175 entity turret_projectile(string _snd, float _size, float _health, float _death, float _proj_type, float _cull, float _cli_anim)
 176 {
 177     entity proj;
 178
 179     sound (self, CH_WEAPON_A, _snd, VOL_BASE, ATTN_NORM);
 180     proj                 = spawn ();
 181     setorigin(proj, self.tur_shotorg);
 182     setsize(proj, '-0.5 -0.5 -0.5' * _size, '0.5 0.5 0.5' * _size);
 183     proj.owner           = self;
 184     proj.realowner       = self;
 185     proj.bot_dodge       = TRUE;
 186     proj.bot_dodgerating = self.shot_dmg;
 187     proj.think           = turret_projectile_explode;
 188     proj.touch           = turret_projectile_touch;
 189     proj.nextthink       = time + 9;
 190     proj.movetype        = MOVETYPE_FLYMISSILE;
 191     proj.velocity        = normalize(self.tur_shotdir_updated + randomvec() * self.shot_spread) * self.shot_speed;
 192     proj.flags           = FL_PROJECTILE;
 193     proj.enemy           = self.enemy;
 194     proj.totalfrags      = _death;
 195     PROJECTILE_MAKETRIGGER(proj);
 196     if(_health)
 197     {
 198         proj.health         = _health;
 199         proj.takedamage     = DAMAGE_YES;
 200         proj.event_damage   = turret_projectile_damage;
 201     }
 202     else
 203         proj.flags |= FL_NOTARGET;
 204
 205     CSQCProjectile(proj, _cli_anim, _proj_type, _cull);
 206
 207     return proj;
 208 }
 209
 210 /**
 211 ** updates enemy distances, predicted impact point/time
 212 ** and updated aim<->predict impact distance.
 213 **/
 214 void turret_do_updates(entity t_turret)
 215 {
 216     vector enemy_pos;
 217     entity oldself;
 218
 219     oldself = self;
 220     self = t_turret;
 221
 222     enemy_pos = real_origin(self.enemy);
 223
 224     turret_tag_fire_update();
 225
 226     self.tur_shotdir_updated = v_forward;
 227     self.tur_dist_enemy  = vlen(self.tur_shotorg - enemy_pos);
 228     self.tur_dist_aimpos = vlen(self.tur_shotorg - self.tur_aimpos);
 229
 230     /*if((self.firecheck_flags & TFL_FIRECHECK_VERIFIED) && (self.enemy))
 231     {
 232         oldpos = self.enemy.origin;
 233         setorigin(self.enemy, self.tur_aimpos);
 234         tracebox(self.tur_shotorg, '-1 -1 -1', '1 1 1', self.tur_shotorg + (self.tur_shotdir_updated * self.tur_dist_aimpos), MOVE_NORMAL,self);
 235         setorigin(self.enemy, oldpos);
 236
 237         if(trace_ent == self.enemy)
 238             self.tur_dist_impact_to_aimpos = 0;
 239         else
 240             self.tur_dist_impact_to_aimpos = vlen(trace_endpos - self.tur_aimpos);
 241     }
 242     else*/
 243         tracebox(self.tur_shotorg, '-1 -1 -1','1 1 1', self.tur_shotorg + (self.tur_shotdir_updated * self.tur_dist_aimpos), MOVE_NORMAL,self);
 244
 245         self.tur_dist_impact_to_aimpos = vlen(trace_endpos - self.tur_aimpos) - (vlen(self.enemy.maxs - self.enemy.mins) * 0.5);
 246         self.tur_impactent             = trace_ent;
 247         self.tur_impacttime            = vlen(self.tur_shotorg - trace_endpos) / self.shot_speed;
 248
 249     self = oldself;
 250 }
 251
 252 /*
 253 vector turret_fovsearch_pingpong()
 254 {
 255     vector wish_angle;
 256     if(self.phase < time)
 257     {
 258         if( self.tur_head.phase )
 259             self.tur_head.phase = 0;
 260         else
 261             self.tur_head.phase = 1;
 262         self.phase = time + 5;
 263     }
 264
 265     if( self.tur_head.phase)
 266         wish_angle = self.idle_aim + '0 1 0' * (self.aim_maxrot * (self.target_select_fov / 360));
 267     else
 268         wish_angle = self.idle_aim - '0 1 0' * (self.aim_maxrot * (self.target_select_fov / 360));
 269
 270     return wish_angle;
 271 }
 272
 273 vector turret_fovsearch_steprot()
 274 {
 275     vector wish_angle;
 276     //float rot_add;
 277
 278     wish_angle   = self.tur_head.angles;
 279     wish_angle_x = self.idle_aim_x;
 280
 281     if (self.phase < time)
 282     {
 283         //rot_add = self.aim_maxrot / self.target_select_fov;
 284         wish_angle_y += (self.target_select_fov * 2);
 285
 286         if(wish_angle_y > 360)
 287             wish_angle_y = wish_angle_y - 360;
 288
 289          self.phase = time + 1.5;
 290     }
 291
 292     return wish_angle;
 293 }
 294
 295 vector turret_fovsearch_random()
 296 {
 297     vector wish_angle;
 298
 299     if (self.phase < time)
 300     {
 301         wish_angle_y = random() * self.aim_maxrot;
 302         if(random() < 0.5)
 303             wish_angle_y *= -1;
 304
 305         wish_angle_x = random() * self.aim_maxpitch;
 306         if(random() < 0.5)
 307             wish_angle_x *= -1;
 308
 309         self.phase = time + 5;
 310
 311         self.tur_aimpos = wish_angle;
 312     }
 313
 314     return self.idle_aim + self.tur_aimpos;
 315 }
 316 */
 317
 318 /**
 319 ** Handles head rotation according to
 320 ** the units .track_type and .track_flags
 321 **/
 322 .float turret_framecounter;
 323 void turret_stdproc_track()
 324 {
 325     vector target_angle; // This is where we want to aim
 326     vector move_angle;   // This is where we can aim
 327     float f_tmp;
 328     vector v1, v2;
 329     v1 = self.tur_head.angles;
 330     v2 = self.tur_head.avelocity;
 331
 332     if (self.track_flags == TFL_TRACK_NO)
 333         return;
 334
 335     if not (self.active)
 336         target_angle = self.idle_aim - ('1 0 0' * self.aim_maxpitch);
 337     else if (self.enemy == world)
 338     {
 339         if(time > self.lip)
 340             target_angle = self.idle_aim + self.angles;
 341         else
 342             target_angle = vectoangles(normalize(self.tur_aimpos - self.tur_shotorg));
 343     }
 344     else
 345     {
 346         target_angle = vectoangles(normalize(self.tur_aimpos - self.tur_shotorg));
 347     }
 348
 349     self.tur_head.angles_x = anglemods(self.tur_head.angles_x);
 350     self.tur_head.angles_y = anglemods(self.tur_head.angles_y);
 351
 352     // Find the diffrence between where we currently aim and where we want to aim
 353     //move_angle = target_angle - (self.angles + self.tur_head.angles);
 354     //move_angle = shortangle_vxy(move_angle,(self.angles + self.tur_head.angles));
 355
 356     move_angle = AnglesTransform_ToAngles(AnglesTransform_LeftDivide(AnglesTransform_FromAngles(self.angles), AnglesTransform_FromAngles(target_angle))) - self.tur_head.angles;
 357     move_angle = shortangle_vxy(move_angle, self.tur_head.angles);
 358
 359     switch(self.track_type)
 360     {
 361         case TFL_TRACKTYPE_STEPMOTOR:
 362             f_tmp = self.aim_speed * self.ticrate; // dgr/sec -> dgr/tic
 363             if (self.track_flags & TFL_TRACK_PITCH)
 364             {
 365                 self.tur_head.angles_x += bound(-f_tmp,move_angle_x, f_tmp);
 366                 if(self.tur_head.angles_x > self.aim_maxpitch)
 367                     self.tur_head.angles_x = self.aim_maxpitch;
 368
 369                 if(self.tur_head.angles_x  < -self.aim_maxpitch)
 370                     self.tur_head.angles_x = self.aim_maxpitch;
 371             }
 372
 373             if (self.track_flags & TFL_TRACK_ROT)
 374             {
 375                 self.tur_head.angles_y += bound(-f_tmp, move_angle_y, f_tmp);
 376                 if(self.tur_head.angles_y > self.aim_maxrot)
 377                     self.tur_head.angles_y = self.aim_maxrot;
 378
 379                 if(self.tur_head.angles_y  < -self.aim_maxrot)
 380                     self.tur_head.angles_y = self.aim_maxrot;
 381             }
 382
 383             // CSQC
 384             self.SendFlags  |= TNSF_ANG;
 385
 386             return;
 387
 388         case TFL_TRACKTYPE_FLUIDINERTIA:
 389             f_tmp = self.aim_speed * self.ticrate; // dgr/sec -> dgr/tic
 390             move_angle_x = bound(-self.aim_speed, move_angle_x * self.track_accel_pitch * f_tmp, self.aim_speed);
 391             move_angle_y = bound(-self.aim_speed, move_angle_y * self.track_accel_rot * f_tmp, self.aim_speed);
 392             move_angle = (self.tur_head.avelocity * self.track_blendrate) + (move_angle * (1 - self.track_blendrate));
 393             break;
 394
 395         case TFL_TRACKTYPE_FLUIDPRECISE:
 396
 397             move_angle_y = bound(-self.aim_speed, move_angle_y, self.aim_speed);
 398             move_angle_x = bound(-self.aim_speed, move_angle_x, self.aim_speed);
 399
 400             break;
 401     }
 402
 403     //  pitch
 404     if (self.track_flags & TFL_TRACK_PITCH)
 405     {
 406         self.tur_head.avelocity_x = move_angle_x;
 407         if((self.tur_head.angles_x + self.tur_head.avelocity_x * self.ticrate) > self.aim_maxpitch)
 408         {
 409             self.tur_head.avelocity_x = 0;
 410             self.tur_head.angles_x = self.aim_maxpitch;
 411
 412             self.SendFlags  |= TNSF_ANG;
 413         }
 414
 415         if((self.tur_head.angles_x + self.tur_head.avelocity_x * self.ticrate) < -self.aim_maxpitch)
 416         {
 417             self.tur_head.avelocity_x = 0;
 418             self.tur_head.angles_x = -self.aim_maxpitch;
 419
 420             self.SendFlags  |= TNSF_ANG;
 421         }
 422     }
 423
 424     //  rot
 425     if (self.track_flags & TFL_TRACK_ROT)
 426     {
 427         self.tur_head.avelocity_y = move_angle_y;
 428
 429         if((self.tur_head.angles_y + self.tur_head.avelocity_y * self.ticrate) > self.aim_maxrot)
 430         {
 431             self.tur_head.avelocity_y = 0;
 432             self.tur_head.angles_y = self.aim_maxrot;
 433
 434             self.SendFlags  |= TNSF_ANG;
 435         }
 436
 437         if((self.tur_head.angles_y + self.tur_head.avelocity_y * self.ticrate) < -self.aim_maxrot)
 438         {
 439             self.tur_head.avelocity_y = 0;
 440             self.tur_head.angles_y = -self.aim_maxrot;
 441
 442             self.SendFlags  |= TNSF_ANG;
 443         }
 444     }
 445
 446     self.SendFlags  |= TNSF_AVEL;
 447
 448     // Force a angle update every 10'th frame
 449     self.turret_framecounter += 1;
 450     if(self.turret_framecounter >= 10)
 451     {
 452         self.SendFlags |= TNSF_ANG;
 453         self.turret_framecounter = 0;
 454     }
 455 }
 456
 457
 458 /*
 459  + = implemented
 460  - = not implemented
 461
 462  + TFL_FIRECHECK_NO
 463  + TFL_FIRECHECK_WORLD
 464  + TFL_FIRECHECK_DEAD
 465  + TFL_FIRECHECK_DISTANCES
 466  - TFL_FIRECHECK_LOS
 467  + TFL_FIRECHECK_AIMDIST
 468  + TFL_FIRECHECK_REALDIST
 469  - TFL_FIRECHECK_ANGLEDIST
 470  - TFL_FIRECHECK_TEAMCECK
 471  + TFL_FIRECHECK_AFF
 472  + TFL_FIRECHECK_OWM_AMMO
 473  + TFL_FIRECHECK_OTHER_AMMO
 474  + TFL_FIRECHECK_REFIRE
 475 */
 476
 477 /**
 478 ** Preforms pre-fire checks based on the uints firecheck_flags
 479 **/
 480 float turret_stdproc_firecheck()
 481 {
 482     // This one just dont care =)
 483     if (self.firecheck_flags & TFL_FIRECHECK_NO)
 484         return 1;
 485
 486     if (self.enemy == world)
 487         return 0;
 488
 489     // Ready?
 490     if (self.firecheck_flags & TFL_FIRECHECK_REFIRE)
 491         if (self.attack_finished_single > time) return 0;
 492
 493     // Special case: volly fire turret that has to fire a full volly if a shot was fired.
 494     if (self.shoot_flags & TFL_SHOOT_VOLLYALWAYS)
 495         if (self.volly_counter != self.shot_volly)
 496                         if(self.ammo >= self.shot_dmg)
 497                                 return 1;
 498
 499     // Lack of zombies makes shooting dead things unnecessary :P
 500     if (self.firecheck_flags & TFL_FIRECHECK_DEAD)
 501         if (self.enemy.deadflag != DEAD_NO)
 502             return 0;
 503
 504     // Own ammo?
 505     if (self.firecheck_flags & TFL_FIRECHECK_OWM_AMMO)
 506         if (self.ammo < self.shot_dmg)
 507             return 0;
 508
 509     // Other's ammo? (support-supply units)
 510     if (self.firecheck_flags & TFL_FIRECHECK_OTHER_AMMO)
 511         if (self.enemy.ammo >= self.enemy.ammo_max)
 512             return 0;
 513
 514         // Target of opertunity?
 515         if(turret_validate_target(self, self.tur_impactent, self.target_validate_flags) > 0)
 516         {
 517                 self.enemy = self.tur_impactent;
 518                 return 1;
 519         }
 520
 521     if (self.firecheck_flags & TFL_FIRECHECK_DISTANCES)
 522     {
 523         // To close?
 524         if (self.tur_dist_aimpos < self.target_range_min)
 525                         if(turret_validate_target(self, self.tur_impactent, self.target_validate_flags) > 0)
 526                                 return 1; // Target of opertunity?
 527                         else
 528                                 return 0;
 529     }
 530
 531     // Try to avoid FF?
 532     if (self.firecheck_flags & TFL_FIRECHECK_AFF)
 533         if (self.tur_impactent.team == self.team)
 534             return 0;
 535
 536     // aim<->predicted impact
 537     if (self.firecheck_flags & TFL_FIRECHECK_AIMDIST)
 538         if (self.tur_dist_impact_to_aimpos > self.aim_firetolerance_dist)
 539             return 0;
 540
 541     // Volly status
 542     if (self.shot_volly > 1)
 543         if (self.volly_counter == self.shot_volly)
 544             if (self.ammo < (self.shot_dmg * self.shot_volly))
 545                 return 0;
 546
 547     /*if(self.firecheck_flags & TFL_FIRECHECK_VERIFIED)
 548         if(self.tur_impactent != self.enemy)
 549             return 0;*/
 550
 551     return 1;
 552 }
 553
 554 /*
 555  + TFL_TARGETSELECT_NO
 556  + TFL_TARGETSELECT_LOS
 557  + TFL_TARGETSELECT_PLAYERS
 558  + TFL_TARGETSELECT_MISSILES
 559  - TFL_TARGETSELECT_TRIGGERTARGET
 560  + TFL_TARGETSELECT_ANGLELIMITS
 561  + TFL_TARGETSELECT_RANGELIMTS
 562  + TFL_TARGETSELECT_TEAMCHECK
 563  - TFL_TARGETSELECT_NOBUILTIN
 564  + TFL_TARGETSELECT_OWNTEAM
 565 */
 566
 567 /**
 568 ** Evaluate a entity for target valitity based on validate_flags
 569 ** NOTE: the caller must check takedamage before calling this, to inline this check.
 570 **/
 571 float turret_validate_target(entity e_turret, entity e_target, float validate_flags)
 572 {
 573     vector v_tmp;
 574
 575         turret_target = e_target;
 576         turret = e_turret;
 577         if(MUTATOR_CALLHOOK(TurretValidateTarget))
 578                 return 1;
 579         e_target = turret_target;
 580         e_turret = turret;
 581
 582     //if(!validate_flags & TFL_TARGETSELECT_NOBUILTIN)
 583     //    return -0.5;
 584
 585     if(e_target.owner == e_turret)
 586         return -0.5;
 587
 588     if not(checkpvs(e_target.origin, e_turret))
 589         return -1;
 590
 591     if not (e_target)
 592         return -2;
 593
 594         if(g_onslaught)
 595                 if (substring(e_target.classname, 0, 10) == "onslaught_") // don't attack onslaught targets, that's the player's job!
 596                         return - 3;
 597
 598     if (validate_flags & TFL_TARGETSELECT_NO)
 599         return -4;
 600
 601     // If only this was used more..
 602     if (e_target.flags & FL_NOTARGET)
 603         return -5;
 604
 605     // Cant touch this
 606     if(e_target.vehicle_flags & VHF_ISVEHICLE)
 607     {
 608         if (e_target.vehicle_health <= 0)
 609             return -6;
 610     }
 611     else if (e_target.health <= 0)
 612         return -6;
 613
 614     // player
 615     if (e_target.flags & FL_CLIENT)
 616     {
 617         if not (validate_flags & TFL_TARGETSELECT_PLAYERS)
 618             return -7;
 619
 620         if (e_target.deadflag != DEAD_NO)
 621             return -8;
 622     }
 623
 624         // enemy turrets
 625         if (validate_flags & TFL_TARGETSELECT_NOTURRETS)
 626         if (e_target.turret_firefunc || e_target.owner.tur_head == e_target)
 627             if(e_target.team != e_turret.team) // Dont break support units.
 628                 return -9;
 629
 630     // Missile
 631     if (e_target.flags & FL_PROJECTILE)
 632         if not (validate_flags & TFL_TARGETSELECT_MISSILES)
 633             return -10;
 634
 635     if (validate_flags & TFL_TARGETSELECT_MISSILESONLY)
 636         if not (e_target.flags & FL_PROJECTILE)
 637             return -10.5;
 638
 639     // Team check
 640     if (validate_flags & TFL_TARGETSELECT_TEAMCHECK)
 641     {
 642         if (validate_flags & TFL_TARGETSELECT_OWNTEAM)
 643         {
 644             if (e_target.team != e_turret.team)
 645                 return -11;
 646
 647             if (e_turret.team != e_target.owner.team)
 648                 return -12;
 649         }
 650         else
 651         {
 652             if (e_target.team == e_turret.team)
 653                 return -13;
 654
 655             if (e_turret.team == e_target.owner.team)
 656                 return -14;
 657         }
 658     }
 659
 660     // Range limits?
 661     tvt_dist = vlen(e_turret.origin - real_origin(e_target));
 662     if (validate_flags & TFL_TARGETSELECT_RANGELIMTS)
 663     {
 664         if (tvt_dist < e_turret.target_range_min)
 665             return -15;
 666
 667         if (tvt_dist > e_turret.target_range)
 668             return -16;
 669     }
 670
 671     // Can we even aim this thing?
 672     tvt_thadv = angleofs3(e_turret.tur_head.origin, e_turret.angles + e_turret.tur_head.angles, e_target);
 673     tvt_tadv  = shortangle_vxy(angleofs(e_turret, e_target), e_turret.angles);
 674     tvt_thadf = vlen(tvt_thadv);
 675     tvt_tadf  = vlen(tvt_tadv);
 676
 677     /*
 678     if(validate_flags & TFL_TARGETSELECT_FOV)
 679     {
 680         if(e_turret.target_select_fov < tvt_thadf)
 681             return -21;
 682     }
 683     */
 684
 685     if (validate_flags & TFL_TARGETSELECT_ANGLELIMITS)
 686     {
 687         if (fabs(tvt_tadv_x) > e_turret.aim_maxpitch)
 688             return -17;
 689
 690         if (fabs(tvt_tadv_y) > e_turret.aim_maxrot)
 691             return -18;
 692     }
 693
 694     // Line of sight?
 695     if (validate_flags & TFL_TARGETSELECT_LOS)
 696     {
 697         v_tmp = real_origin(e_target) + ((e_target.mins + e_target.maxs) * 0.5);
 698
 699         traceline(e_turret.origin + '0 0 16', v_tmp, 0, e_turret);
 700
 701         if (e_turret.aim_firetolerance_dist < vlen(v_tmp - trace_endpos))
 702             return -19;
 703     }
 704
 705     if (e_target.classname == "grapplinghook")
 706         return -20;
 707
 708     /*
 709     if (e_target.classname == "func_button")
 710         return -21;
 711     */
 712
 713 #ifdef TURRET_DEBUG_TARGETSELECT
 714     dprint("Target:",e_target.netname," is a valid target for ",e_turret.netname,"\n");
 715 #endif
 716
 717     return 1;
 718 }
 719
 720 entity turret_select_target()
 721 {
 722     entity e;        // target looper entity
 723     float  score;    // target looper entity score
 724     entity e_enemy;  // currently best scoreing target
 725     float  m_score;  // currently best scoreing target's score
 726
 727     m_score = 0;
 728     if(self.enemy && self.enemy.takedamage && turret_validate_target(self,self.enemy,self.target_validate_flags) > 0)
 729     {
 730         e_enemy = self.enemy;
 731         m_score = self.turret_score_target(self,e_enemy) * self.target_select_samebias;
 732     }
 733     else
 734         e_enemy = self.enemy = world;
 735
 736     e = findradius(self.origin, self.target_range);
 737
 738     // Nothing to aim at?
 739     if (!e)
 740                 return world;
 741
 742     while (e)
 743     {
 744                 if(e.takedamage)
 745                 {
 746                     float f = turret_validate_target(self, e, self.target_select_flags);
 747                     //dprint("F is: ", ftos(f), "\n");
 748                         if ( f > 0)
 749                         {
 750                                 score = self.turret_score_target(self,e);
 751                                 if ((score > m_score) && (score > 0))
 752                                 {
 753                                         e_enemy = e;
 754                                         m_score = score;
 755                                 }
 756                         }
 757                 }
 758         e = e.chain;
 759     }
 760
 761     return e_enemy;
 762 }
 763
 764 void turret_think()
 765 {
 766     entity e;
 767
 768     self.nextthink = time + self.ticrate;
 769
 770     // ONS uses somewhat backwards linking.
 771     if (teamplay)
 772     {
 773         if (g_onslaught)
 774             if (self.target)
 775             {
 776                 e = find(world, targetname,self.target);
 777                 if (e != world)
 778                     self.team = e.team;
 779             }
 780
 781         if (self.team != self.tur_head.team)
 782             turret_stdproc_respawn();
 783     }
 784
 785 #ifdef TURRET_DEBUG
 786     if (self.tur_dbg_tmr1 < time)
 787     {
 788         if (self.enemy) paint_target (self.enemy,128,self.tur_dbg_rvec,0.9);
 789         paint_target(self,256,self.tur_dbg_rvec,0.9);
 790         self.tur_dbg_tmr1 = time + 1;
 791     }
 792 #endif
 793
 794     // Handle ammo
 795     if not (self.spawnflags & TSF_NO_AMMO_REGEN)
 796     if (self.ammo < self.ammo_max)
 797         self.ammo = min(self.ammo + self.ammo_recharge, self.ammo_max);
 798
 799     // Inactive turrets needs to run the think loop,
 800     // So they can handle animation and wake up if need be.
 801     if not (self.active)
 802     {
 803         turret_stdproc_track();
 804         return;
 805     }
 806
 807     // This is typicaly used for zaping every target in range
 808     // turret_fusionreactor uses this to recharge friendlys.
 809     if (self.shoot_flags & TFL_SHOOT_HITALLVALID)
 810     {
 811         // Do a self.turret_fire for every valid target.
 812         e = findradius(self.origin,self.target_range);
 813         while (e)
 814         {
 815                         if(e.takedamage)
 816                         {
 817                                 if (turret_validate_target(self,e,self.target_validate_flags))
 818                                 {
 819                                         self.enemy = e;
 820
 821                                         turret_do_updates(self);
 822
 823                                         if (self.turret_firecheckfunc())
 824                                                 turret_fire();
 825                                 }
 826                         }
 827
 828             e = e.chain;
 829         }
 830         self.enemy = world;
 831     }
 832     else if(self.shoot_flags & TFL_SHOOT_CUSTOM)
 833     {
 834         // This one is doing something.. oddball. assume its handles what needs to be handled.
 835
 836         // Predict?
 837         if not(self.aim_flags & TFL_AIM_NO)
 838             self.tur_aimpos = turret_stdproc_aim_generic();
 839
 840         // Turn & pitch?
 841         if not(self.track_flags & TFL_TRACK_NO)
 842             turret_stdproc_track();
 843
 844         turret_do_updates(self);
 845
 846         // Fire?
 847         if (self.turret_firecheckfunc())
 848             turret_fire();
 849     }
 850     else
 851     {
 852         // Special case for volly always. if it fired once it must compleate the volly.
 853         if(self.shoot_flags & TFL_SHOOT_VOLLYALWAYS)
 854             if(self.volly_counter != self.shot_volly)
 855             {
 856                 // Predict or whatnot
 857                 if not(self.aim_flags & TFL_AIM_NO)
 858                     self.tur_aimpos = turret_stdproc_aim_generic();
 859
 860                 // Turn & pitch
 861                 if not(self.track_flags & TFL_TRACK_NO)
 862                     turret_stdproc_track();
 863
 864                 turret_do_updates(self);
 865
 866                 // Fire!
 867                 if (self.turret_firecheckfunc() != 0)
 868                     turret_fire();
 869
 870                 if(self.turret_postthink)
 871                     self.turret_postthink();
 872
 873                 return;
 874             }
 875
 876         // Check if we have a vailid enemy, and try to find one if we dont.
 877
 878         // g_turrets_targetscan_maxdelay forces a target re-scan at least this often
 879         float do_target_scan = 0;
 880         if((self.target_select_time + autocvar_g_turrets_targetscan_maxdelay) < time)
 881             do_target_scan = 1;
 882
 883         // Old target (if any) invalid?
 884         if(self.target_validate_time < time)
 885         if (turret_validate_target(self, self.enemy, self.target_validate_flags) <= 0)
 886         {
 887                 self.enemy = world;
 888                 self.target_validate_time = time + 0.5;
 889                 do_target_scan = 1;
 890         }
 891
 892         // But never more often then g_turrets_targetscan_mindelay!
 893         if (self.target_select_time + autocvar_g_turrets_targetscan_mindelay > time)
 894             do_target_scan = 0;
 895
 896         if(do_target_scan)
 897         {
 898             self.enemy = turret_select_target();
 899             self.target_select_time = time;
 900         }
 901
 902         // No target, just go to idle, do any custom stuff and bail.
 903         if (self.enemy == world)
 904         {
 905             // Turn & pitch
 906             if not(self.track_flags & TFL_TRACK_NO)
 907                 turret_stdproc_track();
 908
 909             // do any per-turret stuff
 910             if(self.turret_postthink)
 911                 self.turret_postthink();
 912
 913             // And bail.
 914             return;
 915         }
 916         else
 917             self.lip = time + autocvar_g_turrets_aimidle_delay; // Keep track of the last time we had a target.
 918
 919         // Predict?
 920         if not(self.aim_flags & TFL_AIM_NO)
 921             self.tur_aimpos = turret_stdproc_aim_generic();
 922
 923         // Turn & pitch?
 924         if not(self.track_flags & TFL_TRACK_NO)
 925             turret_stdproc_track();
 926
 927         turret_do_updates(self);
 928
 929         // Fire?
 930         if (self.turret_firecheckfunc())
 931             turret_fire();
 932     }
 933
 934     // do any custom per-turret stuff
 935     if(self.turret_postthink)
 936         self.turret_postthink();
 937 }
 938
 939 void turret_fire()
 940 {
 941     if (autocvar_g_turrets_nofire != 0)
 942         return;
 943
 944     self.turret_firefunc();
 945
 946     self.attack_finished_single = time + self.shot_refire;
 947     self.ammo -= self.shot_dmg;
 948     self.volly_counter = self.volly_counter - 1;
 949
 950     if (self.volly_counter <= 0)
 951     {
 952         self.volly_counter = self.shot_volly;
 953
 954         if (self.shoot_flags & TFL_SHOOT_CLEARTARGET)
 955             self.enemy = world;
 956
 957         if (self.shot_volly > 1)
 958             self.attack_finished_single = time + self.shot_volly_refire;
 959     }
 960
 961 #ifdef TURRET_DEBUG
 962     if (self.enemy) paint_target3(self.tur_aimpos, 64, self.tur_dbg_rvec, self.tur_impacttime + 0.25);
 963 #endif
 964 }
 965
 966 void turret_stdproc_fire()
 967 {
 968     dprint("^1Bang, ^3your dead^7 ",self.enemy.netname,"! ^1(turret with no real firefunc)\n");
 969 }
 970
 971 /*
 972     When .used a turret switch team to activator.team.
 973     If activator is world, the turret go inactive.
 974 */
 975 void turret_stdproc_use()
 976 {
 977     dprint("Turret ",self.netname, " used by ", activator.classname, "\n");
 978
 979     self.team = activator.team;
 980
 981     if(self.team == 0)
 982         self.active = ACTIVE_NOT;
 983     else
 984         self.active = ACTIVE_ACTIVE;
 985
 986 }
 987
 988 void turret_link()
 989 {
 990     Net_LinkEntity(self, TRUE, 0, turret_send);
 991     self.think      = turret_think;
 992     self.nextthink  = time;
 993     self.tur_head.effects = EF_NODRAW;
 994 }
 995
 996 void turrets_manager_think()
 997 {
 998     self.nextthink = time + 1;
 999
1000     entity e;
1001     if (autocvar_g_turrets_reloadcvars == 1)
1002     {
1003         e = nextent(world);
1004         while (e)
1005         {
1006             if (e.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
1007             {
1008                 load_unit_settings(e,e.cvar_basename,1);
1009                 if(e.turret_postthink)
1010                     e.turret_postthink();
1011             }
1012
1013             e = nextent(e);
1014         }
1015         cvar_set("g_turrets_reloadcvars","0");
1016     }
1017 }
1018
1019 /*
1020 * Standard turret initialization. use this!
1021 * (unless you have a very good reason not to)
1022 * if the return value is 0, the turret should be removed.
1023 */
1024 float turret_stdproc_init (string cvar_base_name, string base, string head, float _turret_type)
1025 {
1026         entity e, ee = world;
1027
1028     // Are turrets allowed?
1029     if (autocvar_g_turrets == 0)
1030         return 0;
1031
1032     if(_turret_type < 1 || _turret_type > TID_LAST)
1033     {
1034         dprint("Invalid / Unkown turret type\"", ftos(_turret_type), "\", aborting!\n");
1035         return 0;
1036     }
1037     self.turret_type = _turret_type;
1038
1039     e = find(world, classname, "turret_manager");
1040     if not (e)
1041     {
1042         e = spawn();
1043         e.classname = "turret_manager";
1044         e.think = turrets_manager_think;
1045         e.nextthink = time + 2;
1046     }
1047
1048     if not (self.spawnflags & TSF_SUSPENDED)
1049         builtin_droptofloor(); // why can't we use regular droptofloor here?
1050
1051     // Terrainbase spawnflag. This puts a enlongated model
1052     // under the turret, so it looks ok on uneaven surfaces.
1053     /*  TODO: Handle this with CSQC
1054     if (self.spawnflags & TSF_TERRAINBASE)
1055     {
1056         entity tb;
1057         tb = spawn();
1058         setmodel(tb,"models/turrets/terrainbase.md3");
1059         setorigin(tb,self.origin);
1060         tb.solid = SOLID_BBOX;
1061     }
1062     */
1063
1064     self.cvar_basename = cvar_base_name;
1065     load_unit_settings(self, self.cvar_basename, 0);
1066
1067     self.effects = EF_NODRAW;
1068
1069     // Handle turret teams.
1070     if (autocvar_g_assault != 0)
1071     {
1072         if not (self.team)
1073             self.team = 14; // Assume turrets are on the defending side if not explicitly set otehrwize
1074     }
1075     else if not (teamplay)
1076                 self.team = MAX_SHOT_DISTANCE; // Group all turrets into the same team, so they dont kill eachother.
1077         else if(g_onslaught && self.targetname)
1078         {
1079                 e = find(world,target,self.targetname);
1080                 if(e != world)
1081                 {
1082                         self.team = e.team;
1083                         ee = e;
1084                 }
1085         }
1086         else if(!self.team)
1087                 self.team = MAX_SHOT_DISTANCE; // Group all turrets into the same team, so they dont kill eachother.
1088
1089     /*
1090     * Try to guess some reasonaly defaults
1091     * for missing params and do sanety checks
1092     * thise checks could produce some "interesting" results
1093     * if it hits a glitch in my logic :P so try to set as mutch
1094     * as possible beforehand.
1095     */
1096     if not(self.ticrate)
1097     {
1098         if (self.turrcaps_flags & TFL_TURRCAPS_SUPPORT)
1099             self.ticrate = 0.2;     // Support units generaly dont need to have a high speed ai-loop
1100         else
1101             self.ticrate = 0.1;     // 10 fps for normal turrets
1102     }
1103
1104     self.ticrate = bound(sys_frametime, self.ticrate, 60);  // keep it sane
1105
1106 // General stuff
1107     if (self.netname == "")
1108         self.netname = self.classname;
1109
1110     if not (self.respawntime)
1111         self.respawntime = 60;
1112     self.respawntime = max(-1, self.respawntime);
1113
1114     if not (self.health)
1115         self.health = 1000;
1116     self.tur_health = max(1, self.health);
1117         self.max_health = self.tur_health;
1118         self.bot_attack = TRUE;
1119     self.monster_attack = TRUE;
1120
1121     if not (self.turrcaps_flags)
1122         self.turrcaps_flags = TFL_TURRCAPS_RADIUSDMG | TFL_TURRCAPS_MEDPROJ | TFL_TURRCAPS_PLAYERKILL;
1123
1124     if not (self.damage_flags)
1125         self.damage_flags = TFL_DMG_YES | TFL_DMG_RETALIATE | TFL_DMG_AIMSHAKE;
1126
1127 // Shot stuff.
1128     if not (self.shot_refire)
1129         self.shot_refire = 1;
1130     self.shot_refire = bound(0.01, self.shot_refire, 9999);
1131
1132     if not (self.shot_dmg)
1133         self.shot_dmg  = self.shot_refire * 50;
1134     self.shot_dmg = max(1, self.shot_dmg);
1135
1136     if not (self.shot_radius)
1137         self.shot_radius = self.shot_dmg * 0.5;
1138     self.shot_radius = max(1, self.shot_radius);
1139
1140     if not (self.shot_speed)
1141         self.shot_speed = 2500;
1142     self.shot_speed = max(1, self.shot_speed);
1143
1144     if not (self.shot_spread)
1145         self.shot_spread = 0.0125;
1146     self.shot_spread = bound(0.0001, self.shot_spread, 500);
1147
1148     if not (self.shot_force)
1149         self.shot_force = self.shot_dmg * 0.5 + self.shot_radius * 0.5;
1150     self.shot_force = bound(0.001, self.shot_force, 5000);
1151
1152     if not (self.shot_volly)
1153         self.shot_volly = 1;
1154     self.shot_volly = bound(1, self.shot_volly, floor(self.ammo_max / self.shot_dmg));
1155
1156     if not (self.shot_volly_refire)
1157         self.shot_volly_refire = self.shot_refire * self.shot_volly;
1158     self.shot_volly_refire = bound(self.shot_refire, self.shot_volly_refire, 60);
1159
1160     if not (self.firecheck_flags)
1161         self.firecheck_flags = TFL_FIRECHECK_DEAD | TFL_FIRECHECK_DISTANCES |
1162                                TFL_FIRECHECK_LOS | TFL_FIRECHECK_AIMDIST | TFL_FIRECHECK_TEAMCECK |
1163                                TFL_FIRECHECK_OWM_AMMO | TFL_FIRECHECK_REFIRE;
1164
1165 // Range stuff.
1166     if not (self.target_range)
1167         self.target_range = self.shot_speed * 0.5;
1168     self.target_range = bound(0, self.target_range, MAX_SHOT_DISTANCE);
1169
1170     if not (self.target_range_min)
1171         self.target_range_min = self.shot_radius * 2;
1172     self.target_range_min = bound(0, self.target_range_min, MAX_SHOT_DISTANCE);
1173
1174     if not (self.target_range_optimal)
1175         self.target_range_optimal = self.target_range * 0.5;
1176     self.target_range_optimal = bound(0, self.target_range_optimal, MAX_SHOT_DISTANCE);
1177
1178
1179 // Aim stuff.
1180     if not (self.aim_maxrot)
1181         self.aim_maxrot = 90;
1182     self.aim_maxrot = bound(0, self.aim_maxrot, 360);
1183
1184     if not (self.aim_maxpitch)
1185         self.aim_maxpitch = 20;
1186     self.aim_maxpitch = bound(0, self.aim_maxpitch, 90);
1187
1188     if not (self.aim_speed)
1189         self.aim_speed = 36;
1190     self.aim_speed  = bound(0.1, self.aim_speed, 1000);
1191
1192     if not (self.aim_firetolerance_dist)
1193         self.aim_firetolerance_dist  = 5 + (self.shot_radius * 2);
1194     self.aim_firetolerance_dist = bound(0.1, self.aim_firetolerance_dist, MAX_SHOT_DISTANCE);
1195
1196     if not (self.aim_flags)
1197     {
1198         self.aim_flags = TFL_AIM_LEAD | TFL_AIM_SHOTTIMECOMPENSATE;
1199         if(self.turrcaps_flags & TFL_TURRCAPS_RADIUSDMG)
1200             self.aim_flags |= TFL_AIM_GROUNDGROUND;
1201     }
1202
1203     if not (self.track_type)
1204         self.track_type = TFL_TRACKTYPE_STEPMOTOR;
1205
1206     if (self.track_type != TFL_TRACKTYPE_STEPMOTOR)
1207     {
1208         // Fluid / Ineria mode. Looks mutch nicer.
1209         // Can reduce aim preformance alot, needs a bit diffrent aimspeed
1210
1211         if not (self.aim_speed)
1212             self.aim_speed = 180;
1213         self.aim_speed = bound(0.1, self.aim_speed, 1000);
1214
1215         if not (self.track_accel_pitch)
1216             self.track_accel_pitch = 0.5;
1217
1218         if not (self.track_accel_rot)
1219             self.track_accel_rot   = 0.5;
1220
1221         if not (self.track_blendrate)
1222             self.track_blendrate   = 0.35;
1223     }
1224
1225     if (!self.track_flags)
1226         self.track_flags = TFL_TRACK_PITCH | TFL_TRACK_ROT;
1227
1228
1229 // Target selection stuff.
1230     if not (self.target_select_rangebias)
1231         self.target_select_rangebias = 1;
1232     self.target_select_rangebias = bound(-10, self.target_select_rangebias, 10);
1233
1234     if not (self.target_select_samebias)
1235         self.target_select_samebias = 1;
1236     self.target_select_samebias = bound(-10, self.target_select_samebias, 10);
1237
1238     if not (self.target_select_anglebias)
1239         self.target_select_anglebias = 1;
1240     self.target_select_anglebias = bound(-10, self.target_select_anglebias, 10);
1241
1242     if not (self.target_select_missilebias)
1243         self.target_select_missilebias = -10;
1244
1245     self.target_select_missilebias = bound(-10, self.target_select_missilebias, 10);
1246     self.target_select_playerbias = bound(-10, self.target_select_playerbias, 10);
1247
1248     if not (self.target_select_flags)
1249     {
1250             self.target_select_flags = TFL_TARGETSELECT_LOS | TFL_TARGETSELECT_TEAMCHECK
1251                                      | TFL_TARGETSELECT_RANGELIMTS | TFL_TARGETSELECT_ANGLELIMITS;
1252
1253         if (self.turrcaps_flags & TFL_TURRCAPS_MISSILEKILL)
1254             self.target_select_flags |= TFL_TARGETSELECT_MISSILES;
1255
1256         if (self.turrcaps_flags & TFL_TURRCAPS_PLAYERKILL)
1257             self.target_select_flags |= TFL_TARGETSELECT_PLAYERS;
1258         //else
1259         //    self.target_select_flags = TFL_TARGETSELECT_NO;
1260     }
1261
1262     self.target_validate_flags = self.target_select_flags;
1263
1264 // Ammo stuff
1265     if not (self.ammo_max)
1266         self.ammo_max = self.shot_dmg * 10;
1267     self.ammo_max = max(self.shot_dmg, self.ammo_max);
1268
1269     if not (self.ammo)
1270         self.ammo = self.shot_dmg * 5;
1271     self.ammo = bound(0,self.ammo, self.ammo_max);
1272
1273     if not (self.ammo_recharge)
1274         self.ammo_recharge = self.shot_dmg * 0.5;
1275     self.ammo_recharge = max(0 ,self.ammo_recharge);
1276
1277     // Convert the recharge from X per sec to X per ticrate
1278     self.ammo_recharge = self.ammo_recharge * self.ticrate;
1279
1280     if not (self.ammo_flags)
1281         self.ammo_flags = TFL_AMMO_ENERGY | TFL_AMMO_RECHARGE;
1282
1283 // Damage stuff
1284     if(self.spawnflags & TSL_NO_RESPAWN)
1285         if not (self.damage_flags & TFL_DMG_DEATH_NORESPAWN)
1286             self.damage_flags |= TFL_DMG_DEATH_NORESPAWN;
1287
1288 // Offsets & origins
1289     if (!self.tur_shotorg)   self.tur_shotorg = '50 0 50';
1290
1291     if (!self.health)
1292         self.health = 150;
1293
1294 // Game hooks
1295         if(MUTATOR_CALLHOOK(TurretSpawn))
1296                 return 0;
1297
1298 // End of default & sanety checks, start building the turret.
1299
1300 // Spawn extra bits
1301     self.tur_head         = spawn();
1302     self.tur_head.netname = self.tur_head.classname = "turret_head";
1303     self.tur_head.team    = self.team;
1304     self.tur_head.owner   = self;
1305
1306     setmodel(self, base);
1307     setmodel(self.tur_head, head);
1308
1309     setsize(self, '-32 -32 0', '32 32 64');
1310     setsize(self.tur_head, '0 0 0', '0 0 0');
1311
1312     setorigin(self.tur_head, '0 0 0');
1313     setattachment(self.tur_head, self, "tag_head");
1314
1315     self.tur_health          = self.health;
1316     self.solid               = SOLID_BBOX;
1317     self.tur_head.solid      = SOLID_NOT;
1318     self.takedamage          = DAMAGE_AIM;
1319     self.tur_head.takedamage = DAMAGE_NO;
1320     self.movetype            = MOVETYPE_NOCLIP;
1321     self.tur_head.movetype   = MOVETYPE_NOCLIP;
1322
1323     // Defend mode?
1324     if not (self.tur_defend)
1325     if (self.target != "")
1326     {
1327         self.tur_defend = find(world, targetname, self.target);
1328         if (self.tur_defend == world)
1329         {
1330             self.target = "";
1331             dprint("Turret has invalid defendpoint!\n");
1332         }
1333     }
1334
1335     // In target defend mode, aim on the spot to defend when idle.
1336     if (self.tur_defend)
1337         self.idle_aim  = self.tur_head.angles + angleofs(self.tur_head, self.tur_defend);
1338     else
1339         self.idle_aim  = '0 0 0';
1340
1341     // Attach stdprocs. override when and what needed
1342     self.turret_firecheckfunc   = turret_stdproc_firecheck;
1343     self.turret_firefunc        = turret_stdproc_fire;
1344     self.event_damage           = turret_stdproc_damage;
1345
1346     if (self.turrcaps_flags & TFL_TURRCAPS_SUPPORT)
1347         self.turret_score_target    = turret_stdproc_targetscore_support;
1348     else
1349         self.turret_score_target    = turret_stdproc_targetscore_generic;
1350
1351     self.use = turret_stdproc_use;
1352
1353     ++turret_count;
1354     self.nextthink = time + 1;
1355     self.nextthink +=  turret_count * sys_frametime;
1356
1357     self.tur_head.team = self.team;
1358     self.view_ofs = '0 0 0';
1359
1360 #ifdef TURRET_DEBUG
1361     self.tur_dbg_start = self.nextthink;
1362     while (vlen(self.tur_dbg_rvec) < 2)
1363         self.tur_dbg_rvec  = randomvec() * 4;
1364
1365     self.tur_dbg_rvec_x = fabs(self.tur_dbg_rvec_x);
1366     self.tur_dbg_rvec_y = fabs(self.tur_dbg_rvec_y);
1367     self.tur_dbg_rvec_z = fabs(self.tur_dbg_rvec_z);
1368 #endif
1369
1370     // Its all good.
1371     self.turrcaps_flags |= TFL_TURRCAPS_ISTURRET;
1372
1373     self.classname = "turret_main";
1374
1375     self.active = ACTIVE_ACTIVE;
1376
1377     // In ONS mode, and linked to a ONS ent. need to call the use to set team.
1378     if (g_onslaught && ee)
1379     {
1380         activator = ee;
1381         self.use();
1382     }
1383
1384         turret_link();
1385         turret_stdproc_respawn();
1386     turret_tag_fire_update();
1387
1388     return 1;
1389 }
1390
1391