qcsrc/server/tturrets/units/unit_fusionreactor.qc

   1 void spawnfunc_turret_fusionreactor();
   2 void turret_fusionreactor_dinit();
   3 void turret_fusionreactor_fire();
   4
   5 void turret_fusionreactor_fire()
   6 {
   7     vector fl_org;
   8
   9     self.enemy.ammo = min(self.enemy.ammo + self.shot_dmg,self.enemy.ammo_max);
  10     if(g_td) // auto repair?
  11         {
  12         self.enemy.health = min(self.enemy.health + self.shot_dmg,self.enemy.max_health);
  13                 self.enemy.tur_health = min(self.enemy.tur_health + self.shot_dmg,self.enemy.max_health);
  14         }
  15         if(g_rts) // monster healing
  16         {
  17                 self.enemy.heal_delay = time + 0.5;
  18                 self.enemy.health = min(self.enemy.health + self.shot_dmg,self.enemy.max_health);
  19                 WaypointSprite_UpdateHealth(self.enemy.sprite, self.enemy.health);
  20         }
  21     fl_org = 0.5 * (self.enemy.absmin + self.enemy.absmax);
  22     te_smallflash(fl_org);
  23 }
  24
  25 void turret_fusionreactor_postthink()
  26 {
  27     self.tur_head.avelocity = '0 250 0' * (self.ammo / self.ammo_max);
  28 }
  29
  30 /*
  31 void turret_fusionreactor_respawnhook()
  32 {
  33     self.tur_head.avelocity = '0 50 0';
  34 }
  35 */
  36
  37 /**
  38 ** Preforms pre-fire checks for fusionreactor
  39 **/
  40 float turret_fusionreactor_firecheck()
  41 {
  42         if (self.attack_finished_single > time)
  43                 return 0;
  44
  45         if (self.enemy.deadflag != DEAD_NO)
  46                 return 0;
  47
  48         if (self.enemy == world)
  49                 return 0;
  50
  51         if (self.ammo < self.shot_dmg)
  52                 return 0;
  53
  54         if (vlen(self.enemy.origin - self.origin) > self.target_range)
  55                 return 0;
  56
  57     if(g_td)
  58     {
  59         if(self.realowner != self.enemy.realowner)
  60             return 0;
  61
  62                 if(self.enemy.turrcaps_flags & TFL_TURRCAPS_AMMOSOURCE)
  63                         return 0;
  64
  65         if(self.enemy.health >= self.enemy.max_health)
  66             return 0;
  67     }
  68         if(g_rts)
  69         {
  70                 if(IsDifferentTeam(self, self.enemy))
  71                         return 0;
  72
  73                 if not(self.enemy.flags & FL_MONSTER)
  74                         return 0;
  75
  76                 if(self.enemy.health >= self.enemy.max_health)
  77                         return 0;
  78
  79                 if(time < self.enemy.heal_delay)
  80                         return 0;
  81
  82                 return 1; // this is for monsters, so don't do the other checks
  83         }
  84
  85         if (self.enemy.ammo >= self.enemy.ammo_max)
  86                 return 0;
  87
  88         if(teamplay && self.team != self.enemy.team)
  89                 return 0;
  90
  91         if not (self.enemy.ammo_flags & TFL_AMMO_ENERGY)
  92                 return 0;
  93
  94         return 1;
  95 }
  96
  97 void turret_fusionreactor_dinit()
  98 {
  99     if (self.netname == "")      self.netname     = "Fusionreactor";
 100
 101     self.turrcaps_flags      = TFL_TURRCAPS_SUPPORT | TFL_TURRCAPS_AMMOSOURCE;
 102     self.ammo_flags          = TFL_AMMO_ENERGY | TFL_AMMO_RECHARGE;
 103     self.target_select_flags = TFL_TARGETSELECT_TEAMCHECK | TFL_TARGETSELECT_OWNTEAM | TFL_TARGETSELECT_RANGELIMTS;
 104     self.firecheck_flags     = TFL_FIRECHECK_OWM_AMMO | TFL_FIRECHECK_OTHER_AMMO | TFL_FIRECHECK_DISTANCES | TFL_FIRECHECK_DEAD;
 105     self.shoot_flags         = TFL_SHOOT_HITALLVALID;
 106     self.aim_flags           = TFL_AIM_NO;
 107     self.track_flags         = TFL_TRACK_NO;
 108     // self.turret_respawnhook  = turret_fusionreactor_respawnhook;
 109
 110     if (turret_stdproc_init("fusreac_std", "models/turrets/base.md3", "models/turrets/reactor.md3", TID_FUSION) == 0)
 111     {
 112         remove(self);
 113         return;
 114     }
 115     self.tur_head.scale = 0.75;
 116     self.tur_head.avelocity = '0 50 0';
 117     setsize(self,'-34 -34 0','34 34 90');
 118
 119     self.turret_firecheckfunc   = turret_fusionreactor_firecheck;
 120     self.turret_firefunc        = turret_fusionreactor_fire;
 121     self.turret_postthink       = turret_fusionreactor_postthink;
 122 }
 123
 124 /*QUAKED turret_fusionreactor (0 .5 .8) ?
 125 */
 126 void spawnfunc_turret_fusionreactor()
 127 {
 128     precache_model ("models/turrets/reactor.md3");
 129     precache_model ("models/turrets/base.md3");
 130
 131     self.think = turret_fusionreactor_dinit;
 132     self.nextthink = time + 0.5;
 133 }