qcsrc/server/tturrets/units/unit_hk.qc

   1 //#define TURRET_DEBUG_HK
   2
   3 #ifdef TURRET_DEBUG_HK
   4 .float atime;
   5 #endif
   6
   7 void spawnfunc_turret_hk();
   8 void turret_hk_dinit();
   9 void turret_hk_attack();
  10
  11
  12 float hk_is_valid_target(entity e_target)
  13 {
  14     if (e_target == world)
  15         return 0;
  16
  17     // If only this was used more..
  18     if (e_target.flags & FL_NOTARGET)
  19         return 0;
  20
  21     // Cant touch this
  22     if ((e_target.takedamage == DAMAGE_NO) || (e_target.health < 0))
  23         return 0;
  24
  25     // player
  26     if (e_target.flags & FL_CLIENT)
  27     {
  28         if (self.owner.target_select_playerbias < 0)
  29             return 0;
  30
  31         if (e_target.deadflag != DEAD_NO)
  32             return 0;
  33     }
  34
  35     // Missile
  36     if ((e_target.flags & FL_PROJECTILE) && (self.owner.target_select_missilebias < 0))
  37         return 0;
  38
  39     // Team check
  40     if ((e_target.team == self.owner.team) || (self.owner.team == e_target.owner.team))
  41         return 0;
  42
  43     return 1;
  44 }
  45 void turret_hk_missile_think()
  46 {
  47     vector vu, vd, vf, vl, vr, ve;  // Vector (direction)
  48     float  fu, fd, ff, fl, fr, fe;  // Fraction to solid
  49     vector olddir,wishdir,newdir;   // Final direction
  50     float lt_for;   // Length of Trace FORwrad
  51     float lt_seek;  // Length of Trace SEEK (left, right, up down)
  52     float pt_seek;  // Pitch of Trace SEEK (How mutch to angele left, right up, down trace towards v_forward)
  53     vector pre_pos;
  54     float myspeed;
  55     entity e;
  56     float ad,edist;
  57
  58     self.nextthink = time + self.ticrate;
  59
  60     //if (self.cnt < time)
  61     //    turret_hk_missile_explode();
  62
  63     if (self.enemy.deadflag != DEAD_NO)
  64         self.enemy = world;
  65
  66     // Pick the closest valid target.
  67     if (!self.enemy)
  68     {
  69         e = findradius(self.origin, 5000);
  70         while (e)
  71         {
  72             if (hk_is_valid_target(e))
  73             {
  74                 if (!self.enemy)
  75                     self.enemy = e;
  76                 else
  77                     if (vlen(self.origin - e.origin) < vlen(self.origin - self.enemy.origin))
  78                         self.enemy = e;
  79             }
  80             e = e.chain;
  81         }
  82     }
  83
  84     self.angles = vectoangles(self.velocity);
  85     self.angles_x = self.angles_x * -1;
  86     makevectors(self.angles);
  87     self.angles_x = self.angles_x * -1;
  88
  89     if (self.enemy)
  90     {
  91         edist = vlen(self.origin - self.enemy.origin);
  92         // Close enougth to do decent damage?
  93         if ( edist <= (self.owner.shot_radius * 0.25) )
  94         {
  95             turret_projectile_explode();
  96             return;
  97         }
  98
  99         // Get data on enemy position
 100         pre_pos = self.enemy.origin +
 101                   self.enemy.velocity *
 102                   min((vlen(self.enemy.origin - self.origin) / vlen(self.velocity)),0.5);
 103
 104         traceline(self.origin, pre_pos,TRUE,self.enemy);
 105         ve = normalize(pre_pos - self.origin);
 106         fe = trace_fraction;
 107
 108     }
 109     else
 110     {
 111         fe = 0;
 112     }
 113
 114     if ((fe != 1) || (self.enemy == world) || (edist > 1000))
 115     {
 116         myspeed = vlen(self.velocity);
 117
 118         lt_for  = myspeed * 3;
 119         lt_seek = myspeed * 2.95;
 120
 121         // Trace forward
 122         traceline(self.origin, self.origin + v_forward * lt_for,FALSE,self);
 123         vf = trace_endpos;
 124         ff = trace_fraction;
 125
 126         // Find angular offset
 127         ad = vlen(vectoangles(normalize(self.enemy.origin - self.origin)) - self.angles);
 128
 129         // To close to something, Slow down!
 130         if ( ((ff < 0.7) || (ad > 4)) && (myspeed > autocvar_g_turrets_unit_hk_std_shot_speed) )
 131             myspeed = max(myspeed * autocvar_g_turrets_unit_hk_std_shot_speed_decel, autocvar_g_turrets_unit_hk_std_shot_speed);
 132
 133         // Failry clear, accelerate.
 134         if ( (ff > 0.7) && (myspeed < autocvar_g_turrets_unit_hk_std_shot_speed_max) )
 135             myspeed = min(myspeed * autocvar_g_turrets_unit_hk_std_shot_speed_accel, autocvar_g_turrets_unit_hk_std_shot_speed_max);
 136
 137         // Setup trace pitch
 138         pt_seek = 1 - ff;
 139         pt_seek = bound(0.15,pt_seek,0.8);
 140         if (ff < 0.5) pt_seek = 1;
 141
 142         // Trace left
 143         traceline(self.origin, self.origin + (-1 * (v_right * pt_seek) + (v_forward * ff)) * lt_seek,FALSE,self);
 144         vl = trace_endpos;
 145         fl = trace_fraction;
 146
 147         // Trace right
 148         traceline(self.origin,  self.origin + ((v_right * pt_seek) + (v_forward * ff)) * lt_seek ,FALSE,self);
 149         vr = trace_endpos;
 150         fr = trace_fraction;
 151
 152         // Trace up
 153         traceline(self.origin,  self.origin + ((v_up * pt_seek) + (v_forward * ff)) * lt_seek ,FALSE,self);
 154         vu = trace_endpos;
 155         fu = trace_fraction;
 156
 157         // Trace down
 158         traceline(self.origin,  self.origin + (-1 * (v_up * pt_seek) + (v_forward * ff)) * lt_seek ,FALSE,self);
 159         vd = trace_endpos;
 160         fd = trace_fraction;
 161
 162         vl = normalize(vl - self.origin);
 163         vr = normalize(vr - self.origin);
 164         vu = normalize(vu - self.origin);
 165         vd = normalize(vd - self.origin);
 166
 167         // Panic tresh passed, find a single direction and turn as hard as we can
 168         if (pt_seek == 1)
 169         {
 170             wishdir = v_right;
 171             if (fl > fr) wishdir = -1 * v_right;
 172             if (fu > fl) wishdir = v_up;
 173             if (fd > fu) wishdir = -1 * v_up;
 174         }
 175         else
 176         {
 177             // Normalize our trace vectors to make a smooth path
 178             wishdir = normalize( (vl * fl) + (vr * fr) +  (vu * fu) +  (vd * fd) );
 179         }
 180
 181         if (self.enemy)
 182         {
 183             if (fe < 0.1) fe = 0.1; // Make sure we always try to move sligtly towards our target
 184             wishdir = (wishdir * (1 - fe)) + (ve * fe);
 185         }
 186     }
 187     else
 188     {
 189         // Got a clear path to target, speed up fast (if not at full speed) and go straight for it.
 190         myspeed = vlen(self.velocity);
 191         if (myspeed < autocvar_g_turrets_unit_hk_std_shot_speed_max)
 192             myspeed = min(myspeed * autocvar_g_turrets_unit_hk_std_shot_speed_accel2,autocvar_g_turrets_unit_hk_std_shot_speed_max);
 193
 194         wishdir = ve;
 195     }
 196
 197     if ((myspeed > autocvar_g_turrets_unit_hk_std_shot_speed) && (self.cnt > time))
 198         myspeed = min(myspeed * autocvar_g_turrets_unit_hk_std_shot_speed_accel2,autocvar_g_turrets_unit_hk_std_shot_speed_max);
 199
 200     // Ranoutagazfish?
 201     if (self.cnt < time)
 202     {
 203         self.cnt = time + 0.25;
 204         self.nextthink = 0;
 205         self.movetype         = MOVETYPE_BOUNCE;
 206         return;
 207     }
 208
 209     // Calculate new heading
 210     olddir = normalize(self.velocity);
 211     newdir = normalize(olddir + wishdir * autocvar_g_turrets_unit_hk_std_shot_speed_turnrate);
 212
 213     // Set heading & speed
 214     self.velocity = newdir * myspeed;
 215
 216     // Align model with new heading
 217     self.angles = vectoangles(self.velocity);
 218
 219
 220 #ifdef TURRET_DEBUG_HK
 221     //if(self.atime < time) {
 222     if ((fe <= 0.99)||(edist > 1000))
 223     {
 224         te_lightning2(world,self.origin, self.origin + vr * lt_seek);
 225         te_lightning2(world,self.origin, self.origin + vl * lt_seek);
 226         te_lightning2(world,self.origin, self.origin + vu * lt_seek);
 227         te_lightning2(world,self.origin, self.origin + vd * lt_seek);
 228         te_lightning2(world,self.origin, vf);
 229     }
 230     else
 231     {
 232         te_lightning2(world,self.origin, self.enemy.origin);
 233     }
 234     bprint("Speed: ", ftos(rint(myspeed)), "\n");
 235     bprint("Trace to solid: ", ftos(rint(ff * 100)), "%\n");
 236     bprint("Trace to target:", ftos(rint(fe * 100)), "%\n");
 237     self.atime = time + 0.2;
 238     //}
 239 #endif
 240
 241         UpdateCSQCProjectile(self);
 242 }
 243
 244 void turret_hk_attack()
 245 {
 246     entity missile;
 247
 248     missile = turret_projectile("weapons/rocket_fire.wav", 6, 10, DEATH_TURRET_HK, PROJECTILE_ROCKET, FALSE, FALSE);
 249     te_explosion (missile.origin);
 250
 251     missile.think            = turret_hk_missile_think;
 252     missile.nextthink        = time + 0.25;
 253     missile.movetype         = MOVETYPE_BOUNCEMISSILE;
 254     missile.velocity         = self.tur_shotdir_updated * (self.shot_speed * 0.75);
 255     missile.angles           = vectoangles(missile.velocity);
 256     missile.cnt              = time + 30;
 257     missile.ticrate          = max(autocvar_sys_ticrate, 0.05);
 258
 259     if (self.tur_head.frame == 0)
 260         self.tur_head.frame = self.tur_head.frame + 1;
 261
 262 }
 263
 264 void turret_hk_postthink()
 265 {
 266     if (self.tur_head.frame != 0)
 267         self.tur_head.frame = self.tur_head.frame + 1;
 268
 269     if (self.tur_head.frame > 5)
 270         self.tur_head.frame = 0;
 271 }
 272
 273 float turret_hk_addtarget(entity e_target,entity e_sender)
 274 {
 275     if (e_target)
 276     {
 277         if (turret_validate_target(self,e_target,self.target_validate_flags) > 0)
 278         {
 279             self.enemy = e_target;
 280             return 1;
 281         }
 282     }
 283
 284     return 0;
 285 }
 286
 287 void turret_hk_dinit()
 288 {
 289     if (self.netname == "")
 290         self.netname  = "Hunter-killer turret";
 291
 292     self.turrcaps_flags = TFL_TURRCAPS_RADIUSDMG | TFL_TURRCAPS_MEDPROJ | TFL_TURRCAPS_PLAYERKILL | TFL_TURRCAPS_RECIVETARGETS;
 293     self.ammo_flags = TFL_AMMO_ROCKETS | TFL_AMMO_RECHARGE;
 294     self.aim_flags = TFL_AIM_SIMPLE;
 295     self.target_select_flags = TFL_TARGETSELECT_LOS | TFL_TARGETSELECT_PLAYERS | TFL_TARGETSELECT_TRIGGERTARGET | TFL_TARGETSELECT_RANGELIMTS | TFL_TARGETSELECT_TEAMCHECK;
 296     self.firecheck_flags = TFL_FIRECHECK_DEAD | TFL_FIRECHECK_TEAMCECK  | TFL_FIRECHECK_REFIRE | TFL_FIRECHECK_AFF;
 297     self.shoot_flags = TFL_SHOOT_CLEARTARGET;
 298
 299     if (turret_stdproc_init("hk_std", "models/turrets/base.md3", "models/turrets/hk.md3", TID_HK) == 0)
 300     {
 301         remove(self);
 302         return;
 303     }
 304
 305     self.target_validate_flags = TFL_TARGETSELECT_PLAYERS | TFL_TARGETSELECT_TEAMCHECK;
 306
 307     // Our fire routine
 308     self.turret_firefunc  = turret_hk_attack;
 309
 310     // re-color badge & handle recoil effect
 311     self.turret_postthink = turret_hk_postthink;
 312
 313     // What to do when reciveing foreign target data
 314     self.turret_addtarget = turret_hk_addtarget;
 315 }
 316
 317
 318 /*QUAKED turret_hk (0 .5 .8) ?
 319 * Turret that fires Hunter-killer missiles.
 320 * Missiles seek their target and try to avoid obstacles. If target dies early, they
 321 * pick a new one on their own.
 322 */
 323
 324 void spawnfunc_turret_hk()
 325 {
 326     precache_model ("models/turrets/base.md3");
 327     precache_model ("models/turrets/hk.md3");
 328
 329     self.think = turret_hk_dinit;
 330     self.nextthink = time + 0.5;
 331 }
 332
 333