qcsrc/server/vehicles/racer.qc

   1 #include "racer.qh"
   2
   3 #ifdef SVQC
   4 void racer_exit(float eject);
   5 void racer_enter();
   6
   7 // Auto cvars
   8 float autocvar_g_vehicle_racer;
   9
  10 float autocvar_g_vehicle_racer_speed_afterburn;
  11 float autocvar_g_vehicle_racer_afterburn_cost;
  12
  13 float autocvar_g_vehicle_racer_anglestabilizer;
  14 float autocvar_g_vehicle_racer_downforce;
  15
  16 float autocvar_g_vehicle_racer_speed_forward;
  17 float autocvar_g_vehicle_racer_speed_strafe;
  18 float autocvar_g_vehicle_racer_springlength;
  19 float autocvar_g_vehicle_racer_upforcedamper;
  20 float autocvar_g_vehicle_racer_friction;
  21
  22 float autocvar_g_vehicle_racer_hovertype;
  23 float autocvar_g_vehicle_racer_hoverpower;
  24
  25 float autocvar_g_vehicle_racer_turnroll;
  26 float autocvar_g_vehicle_racer_turnspeed;
  27 float autocvar_g_vehicle_racer_pitchspeed;
  28
  29 float autocvar_g_vehicle_racer_energy;
  30 float autocvar_g_vehicle_racer_energy_regen;
  31 float autocvar_g_vehicle_racer_energy_regen_pause;
  32
  33 float autocvar_g_vehicle_racer_health;
  34 float autocvar_g_vehicle_racer_health_regen;
  35 float autocvar_g_vehicle_racer_health_regen_pause;
  36
  37 float autocvar_g_vehicle_racer_shield;
  38 float autocvar_g_vehicle_racer_shield_regen;
  39 float autocvar_g_vehicle_racer_shield_regen_pause;
  40
  41 float autocvar_g_vehicle_racer_cannon_cost;
  42 float autocvar_g_vehicle_racer_cannon_damage;
  43 float autocvar_g_vehicle_racer_cannon_radius;
  44 float autocvar_g_vehicle_racer_cannon_refire;
  45 float autocvar_g_vehicle_racer_cannon_speed;
  46 float autocvar_g_vehicle_racer_cannon_spread;
  47 float autocvar_g_vehicle_racer_cannon_force;
  48
  49 float autocvar_g_vehicle_racer_rocket_accel;
  50 float autocvar_g_vehicle_racer_rocket_damage;
  51 float autocvar_g_vehicle_racer_rocket_radius;
  52 float autocvar_g_vehicle_racer_rocket_force;
  53 float autocvar_g_vehicle_racer_rocket_refire;
  54 float autocvar_g_vehicle_racer_rocket_speed;
  55 float autocvar_g_vehicle_racer_rocket_turnrate;
  56
  57 float autocvar_g_vehicle_racer_rocket_locktarget;
  58 float autocvar_g_vehicle_racer_rocket_locking_time;
  59 float autocvar_g_vehicle_racer_rocket_locking_releasetime;
  60 float autocvar_g_vehicle_racer_rocket_locked_time;
  61 float autocvar_g_vehicle_racer_rocket_locked_maxangle;
  62 float autocvar_g_vehicle_racer_rocket_climbspeed;
  63
  64 float autocvar_g_vehicle_racer_respawntime;
  65
  66 float autocvar_g_vehicle_racer_blowup_radius;
  67 float autocvar_g_vehicle_racer_blowup_coredamage;
  68 float autocvar_g_vehicle_racer_blowup_edgedamage;
  69 float autocvar_g_vehicle_racer_blowup_forceintensity;
  70
  71 float autocvar_g_vehicle_racer_bouncefactor;
  72 float autocvar_g_vehicle_racer_bouncestop;
  73 vector autocvar_g_vehicle_racer_bouncepain;
  74
  75 var vector racer_force_from_tag(string tag_name, float spring_length, float max_power);
  76
  77 void racer_align4point(float _delta)
  78 {
  79     vector push_vector;
  80     float fl_push, fr_push, bl_push, br_push;
  81
  82     push_vector  = racer_force_from_tag("tag_engine_fr", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  83     fr_push      = force_fromtag_normpower;
  84     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  85
  86     push_vector += racer_force_from_tag("tag_engine_fl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  87     fl_push      = force_fromtag_normpower;
  88     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  89
  90     push_vector += racer_force_from_tag("tag_engine_br", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  91     br_push      = force_fromtag_normpower;
  92     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  93
  94     push_vector += racer_force_from_tag("tag_engine_bl", autocvar_g_vehicle_racer_springlength, autocvar_g_vehicle_racer_hoverpower);
  95     bl_push      = force_fromtag_normpower;
  96     //vehicles_sweap_collision(force_fromtag_origin, self.velocity, _delta, v_add, autocvar_g_vehicle_racer_collision_multiplier);
  97
  98    self.velocity += push_vector * _delta;
  99
 100     // Anti ocilation
 101     if(self.velocity.z > 0)
 102         self.velocity_z *= 1 - autocvar_g_vehicle_racer_upforcedamper * _delta;
 103
 104     push_vector.x =  (fl_push - bl_push);
 105     push_vector_x += (fr_push - br_push);
 106     push_vector_x *= 360;
 107
 108     push_vector.z = (fr_push - fl_push);
 109     push_vector_z += (br_push - bl_push);
 110     push_vector_z *= 360;
 111
 112     // Apply angle diffrance
 113     self.angles_z += push_vector.z * _delta;
 114     self.angles_x += push_vector.x * _delta;
 115
 116     // Apply stabilizer
 117     self.angles_x *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * _delta);
 118     self.angles_z *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * _delta);
 119 }
 120
 121 void racer_fire_cannon(string tagname)
 122 {
 123     vector v;
 124     entity bolt;
 125
 126     v = gettaginfo(self, gettagindex(self, tagname));
 127     bolt = vehicles_projectile("wakizashi_gun_muzzleflash", "weapons/lasergun_fire.wav",
 128                            v, normalize(v_forward + randomvec() * autocvar_g_vehicle_racer_cannon_spread) * autocvar_g_vehicle_racer_cannon_speed,
 129                            autocvar_g_vehicle_racer_cannon_damage, autocvar_g_vehicle_racer_cannon_radius, autocvar_g_vehicle_racer_cannon_force,  0,
 130                            DEATH_VH_WAKI_GUN, PROJECTILE_WAKICANNON, 0, true, true, self.owner);
 131
 132         // Fix z-aim (for chase mode)
 133     v = normalize(trace_endpos - bolt.origin);
 134     v_forward.z = v.z * 0.5;
 135     bolt.velocity = v_forward * autocvar_g_vehicle_racer_cannon_speed;
 136 }
 137
 138 void racer_rocket_groundhugger()
 139 {
 140     vector olddir, newdir;
 141     float oldvel, newvel;
 142
 143     self.nextthink  = time;
 144
 145     if(self.owner.deadflag != DEAD_NO || self.cnt < time)
 146     {
 147         self.use();
 148         return;
 149     }
 150
 151     if (!self.realowner.vehicle)
 152     {
 153         UpdateCSQCProjectile(self);
 154         return;
 155     }
 156
 157     olddir = normalize(self.velocity);
 158     oldvel = vlen(self.velocity);
 159     newvel = oldvel + self.lip;
 160
 161     tracebox(self.origin, self.mins, self.maxs, self.origin + olddir * 64, MOVE_WORLDONLY,self);
 162     if(trace_fraction <= 0.5)
 163     {
 164         // Hitting somethign soon, just speed ahead
 165         self.velocity = olddir * newvel;
 166         UpdateCSQCProjectile(self);
 167         return;
 168     }
 169
 170     traceline(trace_endpos, trace_endpos - '0 0 64', MOVE_NORMAL, self);
 171     if(trace_fraction != 1.0)
 172     {
 173         newdir = normalize(trace_endpos + '0 0 64' - self.origin) * autocvar_g_vehicle_racer_rocket_turnrate;
 174         self.velocity = normalize(olddir + newdir) * newvel;
 175     }
 176     else
 177     {
 178         self.velocity = olddir * newvel;
 179         self.velocity_z -= 1600 * sys_frametime; // 2x grav looks better for this one
 180     }
 181
 182     UpdateCSQCProjectile(self);
 183     return;
 184 }
 185
 186 void racer_rocket_tracker()
 187 {
 188     vector olddir, newdir;
 189     float oldvel, newvel;
 190
 191     self.nextthink  = time;
 192
 193     if (self.owner.deadflag != DEAD_NO || self.cnt < time)
 194     {
 195         self.use();
 196         return;
 197     }
 198
 199     if (!self.realowner.vehicle)
 200     {
 201         UpdateCSQCProjectile(self);
 202         return;
 203     }
 204
 205     olddir = normalize(self.velocity);
 206     oldvel = vlen(self.velocity);
 207     newvel = oldvel + self.lip;
 208     makevectors(vectoangles(olddir));
 209
 210         float time_to_impact = min(vlen(self.enemy.origin - self.origin) / vlen(self.velocity), 1);
 211         vector predicted_origin = self.enemy.origin + self.enemy.velocity * time_to_impact;
 212
 213     traceline(self.origin, self.origin + v_forward * 64 - '0 0 32', MOVE_NORMAL, self);
 214     newdir = normalize(predicted_origin - self.origin);
 215
 216     //vector
 217         float height_diff = predicted_origin.z - self.origin.z;
 218
 219     if(vlen(newdir - v_forward) > autocvar_g_vehicle_racer_rocket_locked_maxangle)
 220     {
 221         //bprint("Target lost!\n");
 222         //dprint("OF:", ftos(vlen(newdir - v_forward)), "\n");
 223         self.think = racer_rocket_groundhugger;
 224         return;
 225     }
 226
 227     if(trace_fraction != 1.0 && trace_ent != self.enemy)
 228         newdir.z += 16 * sys_frametime;
 229
 230     self.velocity = normalize(olddir + newdir * autocvar_g_vehicle_racer_rocket_turnrate) * newvel;
 231     self.velocity_z -= 800 * sys_frametime;
 232     self.velocity_z += max(height_diff, autocvar_g_vehicle_racer_rocket_climbspeed) * sys_frametime ;
 233
 234     UpdateCSQCProjectile(self);
 235     return;
 236 }
 237
 238 void racer_fire_rocket(string tagname, entity trg)
 239 {
 240     vector v = gettaginfo(self, gettagindex(self, tagname));
 241     entity rocket = vehicles_projectile("wakizashi_rocket_launch", "weapons/rocket_fire.wav",
 242                            v, v_forward * autocvar_g_vehicle_racer_rocket_speed,
 243                            autocvar_g_vehicle_racer_rocket_damage, autocvar_g_vehicle_racer_rocket_radius, autocvar_g_vehicle_racer_rocket_force, 3,
 244                            DEATH_VH_WAKI_ROCKET, PROJECTILE_WAKIROCKET, 20, false, false, self.owner);
 245
 246     rocket.lip              = autocvar_g_vehicle_racer_rocket_accel * sys_frametime;
 247     rocket.wait             = autocvar_g_vehicle_racer_rocket_turnrate;
 248     rocket.nextthink        = time;
 249     rocket.enemy            = trg;
 250     rocket.cnt              = time + 15;
 251
 252     if(trg)
 253         rocket.think            = racer_rocket_tracker;
 254     else
 255         rocket.think            = racer_rocket_groundhugger;
 256 }
 257
 258 float racer_frame()
 259 {
 260     entity player, racer;
 261     vector df;
 262     float ftmp;
 263
 264         if(intermission_running)
 265                 return 1;
 266
 267     player  = self;
 268     racer   = self.vehicle;
 269     self    = racer;
 270
 271     player.BUTTON_ZOOM = player.BUTTON_CROUCH = 0;
 272
 273     vehicles_painframe();
 274
 275     if(racer.deadflag != DEAD_NO)
 276     {
 277         self = player;
 278         player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 279         return 1;
 280     }
 281
 282     racer_align4point(frametime);
 283
 284     crosshair_trace(player);
 285
 286     racer.angles_x *= -1;
 287
 288     // Yaw
 289     ftmp = autocvar_g_vehicle_racer_turnspeed * frametime;
 290     ftmp = bound(-ftmp, shortangle_f(player.v_angle.y - racer.angles.y, racer.angles.y), ftmp);
 291     racer.angles_y = anglemods(racer.angles.y + ftmp);
 292
 293     // Roll
 294     racer.angles_z += -ftmp * autocvar_g_vehicle_racer_turnroll * frametime;
 295
 296     // Pitch
 297     ftmp = autocvar_g_vehicle_racer_pitchspeed  * frametime;
 298     ftmp = bound(-ftmp, shortangle_f(player.v_angle.x - racer.angles.x, racer.angles.x), ftmp);
 299     racer.angles_x = bound(-30, anglemods(racer.angles.x + ftmp), 30);
 300
 301     makevectors(racer.angles);
 302     racer.angles_x *= -1;
 303
 304     //ftmp = racer.velocity_z;
 305     df = racer.velocity * -autocvar_g_vehicle_racer_friction;
 306     //racer.velocity_z = ftmp;
 307
 308     if(vlen(player.movement) != 0)
 309     {
 310         if(player.movement_x)
 311             df += v_forward * ((player.movement.x > 0) ? autocvar_g_vehicle_racer_speed_forward : -autocvar_g_vehicle_racer_speed_forward);
 312
 313         if(player.movement_y)
 314             df += v_right * ((player.movement.y > 0) ? autocvar_g_vehicle_racer_speed_strafe : -autocvar_g_vehicle_racer_speed_strafe);
 315
 316         if(self.sound_nexttime < time || self.sounds != 1)
 317         {
 318             self.sounds = 1;
 319             self.sound_nexttime = time + 10.922667; //soundlength("vehicles/racer_move.wav");
 320             sound (self, CH_TRIGGER_SINGLE, "vehicles/racer_move.wav", VOL_VEHICLEENGINE, ATTEN_NORM);
 321         }
 322     }
 323     else
 324     {
 325         if(self.sound_nexttime < time || self.sounds != 0)
 326         {
 327             self.sounds = 0;
 328             self.sound_nexttime = time + 11.888604; //soundlength("vehicles/racer_idle.wav");
 329             sound (self, CH_TRIGGER_SINGLE, "vehicles/racer_idle.wav", VOL_VEHICLEENGINE, ATTEN_NORM);
 330         }
 331     }
 332
 333     // Afterburn
 334     if (player.BUTTON_JUMP && racer.vehicle_energy >= (autocvar_g_vehicle_racer_afterburn_cost * frametime))
 335     {
 336         if(time - racer.wait > 0.2)
 337             pointparticles(particleeffectnum("wakizashi_booster_smoke"), self.origin - v_forward * 32, v_forward  * vlen(self.velocity), 1);
 338
 339         racer.wait = time;
 340         racer.vehicle_energy -= autocvar_g_vehicle_racer_afterburn_cost * frametime;
 341         df += (v_forward * autocvar_g_vehicle_racer_speed_afterburn);
 342
 343         if(racer.invincible_finished < time)
 344         {
 345             traceline(racer.origin, racer.origin - '0 0 256', MOVE_NORMAL, self);
 346             if(trace_fraction != 1.0)
 347                 pointparticles(particleeffectnum("smoke_small"), trace_endpos, '0 0 0', 1);
 348
 349             racer.invincible_finished = time + 0.1 + (random() * 0.1);
 350         }
 351
 352         if(racer.strength_finished < time)
 353         {
 354             racer.strength_finished = time + 10.922667; //soundlength("vehicles/racer_boost.wav");
 355             sound (racer.tur_head, CH_TRIGGER_SINGLE, "vehicles/racer_boost.wav", VOL_VEHICLEENGINE, ATTEN_NORM);
 356         }
 357     }
 358     else
 359     {
 360         racer.strength_finished = 0;
 361         sound (racer.tur_head, CH_TRIGGER_SINGLE, "misc/null.wav", VOL_VEHICLEENGINE, ATTEN_NORM);
 362     }
 363
 364         df -= v_up * (vlen(racer.velocity) * autocvar_g_vehicle_racer_downforce);
 365     player.movement = racer.velocity += df * frametime;
 366
 367     if(player.BUTTON_ATCK)
 368     if(time > racer.attack_finished_single)
 369     if(racer.vehicle_energy >= autocvar_g_vehicle_racer_cannon_cost)
 370     {
 371         racer.vehicle_energy -= autocvar_g_vehicle_racer_cannon_cost;
 372         racer.wait = time;
 373
 374         crosshair_trace(player);
 375         if(racer.cnt)
 376         {
 377             racer_fire_cannon("tag_fire1");
 378             racer.cnt = 0;
 379         }
 380         else
 381         {
 382             racer_fire_cannon("tag_fire2");
 383             racer.cnt = 1;
 384         }
 385         racer.attack_finished_single = time + autocvar_g_vehicle_racer_cannon_refire;
 386     }
 387
 388     if(autocvar_g_vehicle_racer_rocket_locktarget)
 389     {
 390         vehicles_locktarget((1 / autocvar_g_vehicle_racer_rocket_locking_time) * frametime,
 391                          (1 / autocvar_g_vehicle_racer_rocket_locking_releasetime) * frametime,
 392                          autocvar_g_vehicle_racer_rocket_locked_time);
 393
 394         if(self.lock_target)
 395         {
 396             if(racer.lock_strength == 1)
 397                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '1 0 0', 0);
 398             else if(self.lock_strength > 0.5)
 399                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '0 1 0', 0);
 400             else if(self.lock_strength < 0.5)
 401                 UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '0 0 1', 0);
 402         }
 403     }
 404
 405     if(time > racer.delay)
 406     if(player.BUTTON_ATCK2)
 407     {
 408         racer.misc_bulletcounter += 1;
 409         racer.delay = time + 0.3;
 410
 411         if(racer.misc_bulletcounter == 1)
 412             racer_fire_rocket("tag_rocket_r", (racer.lock_strength == 1 && racer.lock_target) ? racer.lock_target : world);
 413         else if(racer.misc_bulletcounter == 2)
 414         {
 415             racer_fire_rocket("tag_rocket_l", (racer.lock_strength == 1 && racer.lock_target) ? racer.lock_target : world);
 416             racer.lock_strength  = 0;
 417             racer.lock_target    = world;
 418             racer.misc_bulletcounter = 0;
 419
 420             racer.delay = time + autocvar_g_vehicle_racer_rocket_refire;
 421             racer.lip = time;
 422         }
 423     }
 424     player.vehicle_reload1 = bound(0, 100 * ((time - racer.lip) / (racer.delay - racer.lip)), 100);
 425
 426     if(racer.vehicle_flags  & VHF_SHIELDREGEN)
 427         vehicles_regen(racer.dmg_time, vehicle_shield, autocvar_g_vehicle_racer_shield, autocvar_g_vehicle_racer_shield_regen_pause, autocvar_g_vehicle_racer_shield_regen, frametime, true);
 428
 429     if(racer.vehicle_flags  & VHF_HEALTHREGEN)
 430         vehicles_regen(racer.dmg_time, vehicle_health, autocvar_g_vehicle_racer_health, autocvar_g_vehicle_racer_health_regen_pause, autocvar_g_vehicle_racer_health_regen, frametime, false);
 431
 432     if(racer.vehicle_flags  & VHF_ENERGYREGEN)
 433         vehicles_regen(racer.wait, vehicle_energy, autocvar_g_vehicle_racer_energy, autocvar_g_vehicle_racer_energy_regen_pause, autocvar_g_vehicle_racer_energy_regen, frametime, false);
 434
 435
 436     VEHICLE_UPDATE_PLAYER(player, health, racer);
 437     VEHICLE_UPDATE_PLAYER(player, energy, racer);
 438
 439     if(racer.vehicle_flags & VHF_HASSHIELD)
 440         VEHICLE_UPDATE_PLAYER(player, shield, racer);
 441
 442     player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 443     setorigin(player,racer.origin + '0 0 32');
 444     player.velocity = racer.velocity;
 445
 446     self = player;
 447     return 1;
 448 }
 449
 450 void racer_think()
 451 {
 452     self.nextthink = time;
 453
 454     float pushdeltatime = time - self.lastpushtime;
 455     if (pushdeltatime > 0.15) pushdeltatime = 0;
 456     self.lastpushtime = time;
 457     if(!pushdeltatime) return;
 458
 459     tracebox(self.origin, self.mins, self.maxs, self.origin - ('0 0 1' * autocvar_g_vehicle_racer_springlength), MOVE_NORMAL, self);
 460
 461     vector df = self.velocity * -autocvar_g_vehicle_racer_friction;
 462         df.z += (1 - trace_fraction) * autocvar_g_vehicle_racer_hoverpower + sin(time * 2) * (autocvar_g_vehicle_racer_springlength * 2);
 463
 464         self.velocity += df * pushdeltatime;
 465     if(self.velocity.z > 0)
 466         self.velocity_z *= 1 - autocvar_g_vehicle_racer_upforcedamper * pushdeltatime;
 467
 468     self.angles_x *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * pushdeltatime);
 469     self.angles_z *= 1 - (autocvar_g_vehicle_racer_anglestabilizer * pushdeltatime);
 470 }
 471
 472 void racer_enter()
 473 {
 474     self.movetype = MOVETYPE_BOUNCE;
 475     self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_racer_health)  * 100;
 476     self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_racer_shield)  * 100;
 477
 478     if(self.owner.flagcarried)
 479        setorigin(self.owner.flagcarried, '-190 0 96');
 480
 481         //targetdrone_spawn(self.origin + '0 0 512' + randomvec() * 256, 1);
 482 }
 483
 484 void racer_exit(float eject)
 485 {
 486     vector spot;
 487
 488     self.think      = racer_think;
 489     self.nextthink  = time;
 490     self.movetype   = MOVETYPE_BOUNCE;
 491     sound (self.tur_head, CH_TRIGGER_SINGLE, "misc/null.wav", VOL_VEHICLEENGINE, ATTEN_NORM);
 492
 493     if (!self.owner)
 494         return;
 495
 496         makevectors(self.angles);
 497         if(eject)
 498         {
 499             spot = self.origin + v_forward * 100 + '0 0 64';
 500             spot = vehicles_findgoodexit(spot);
 501             setorigin(self.owner , spot);
 502             self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 503             self.owner.oldvelocity = self.owner.velocity;
 504         }
 505         else
 506         {
 507                 if(vlen(self.velocity) > 2 * autocvar_sv_maxairspeed)
 508                 {
 509                         self.owner.velocity = normalize(self.velocity) * autocvar_sv_maxairspeed * 2;
 510                         self.owner.velocity_z += 200;
 511                         spot = self.origin + v_forward * 32 + '0 0 32';
 512                         spot = vehicles_findgoodexit(spot);
 513                 }
 514                 else
 515                 {
 516                         self.owner.velocity = self.velocity * 0.5;
 517                         self.owner.velocity_z += 10;
 518                         spot = self.origin - v_forward * 200 + '0 0 32';
 519                         spot = vehicles_findgoodexit(spot);
 520                 }
 521             self.owner.oldvelocity = self.owner.velocity;
 522             setorigin(self.owner , spot);
 523         }
 524         antilag_clear(self.owner);
 525     self.owner = world;
 526 }
 527
 528 void racer_impact()
 529 {
 530         if(autocvar_g_vehicle_racer_bouncepain.x)
 531                 vehicles_impact(autocvar_g_vehicle_racer_bouncepain.x, autocvar_g_vehicle_racer_bouncepain.y, autocvar_g_vehicle_racer_bouncepain.z);
 532 }
 533
 534 void racer_blowup()
 535 {
 536     self.deadflag    = DEAD_DEAD;
 537     self.vehicle_exit(VHEF_NORMAL);
 538
 539     RadiusDamage (self, self.enemy, autocvar_g_vehicle_racer_blowup_coredamage,
 540                                         autocvar_g_vehicle_racer_blowup_edgedamage,
 541                                         autocvar_g_vehicle_racer_blowup_radius, world, world,
 542                                         autocvar_g_vehicle_racer_blowup_forceintensity,
 543                                         DEATH_VH_WAKI_DEATH, world);
 544
 545         self.alpha      = -1;
 546     self.movetype   = MOVETYPE_NONE;
 547     self.effects    = EF_NODRAW;
 548     self.colormod  = '0 0 0';
 549     self.avelocity = '0 0 0';
 550     self.velocity  = '0 0 0';
 551
 552     setorigin(self, self.pos1);
 553         self.touch = func_null;
 554         self.nextthink = 0;
 555 }
 556
 557 void racer_deadtouch()
 558 {
 559     self.avelocity_x *= 0.7;
 560     self.cnt -= 1;
 561     if(self.cnt <= 0)
 562         racer_blowup();
 563 }
 564
 565 void racer_die()
 566 {
 567     self.health       = 0;
 568     self.event_damage = func_null;
 569     self.solid        = SOLID_CORPSE;
 570     self.takedamage   = DAMAGE_NO;
 571     self.deadflag     = DEAD_DYING;
 572     self.movetype     = MOVETYPE_BOUNCE;
 573     self.wait         = time;
 574     self.cnt          = 1 + random() * 2;
 575     self.touch        = racer_deadtouch;
 576
 577     pointparticles(particleeffectnum("explosion_medium"), self.origin, '0 0 0', 1);
 578
 579     if(random() < 0.5)
 580         self.avelocity_z = 32;
 581     else
 582         self.avelocity_z = -32;
 583
 584     self.avelocity_x = -vlen(self.velocity) * 0.2;
 585     self.velocity   += '0 0 700';
 586     self.colormod    = '-0.5 -0.5 -0.5';
 587
 588         self.think     = racer_blowup;
 589         self.nextthink = 2 + time + random() * 3;
 590 }
 591 void racer_spawn(float _spawnflag)
 592 {
 593     if(self.scale != 0.5)
 594     {
 595         if(autocvar_g_vehicle_racer_hovertype != 0)
 596             racer_force_from_tag = vehicles_force_fromtag_maglev;
 597         else
 598             racer_force_from_tag = vehicles_force_fromtag_hover;
 599
 600         // FIXME: this be hakkz, fix the models insted (scale body, add tag_viewport to the hudmodel).
 601         self.scale = 0.5;
 602         setattachment(self.vehicle_hudmodel, self, "");
 603         setattachment(self.vehicle_viewport, self, "tag_viewport");
 604
 605         self.mass               = 900;
 606     }
 607
 608     self.think          = racer_think;
 609     self.nextthink      = time;
 610     self.vehicle_health = autocvar_g_vehicle_racer_health;
 611     self.vehicle_shield = autocvar_g_vehicle_racer_shield;
 612
 613     self.movetype       = MOVETYPE_TOSS;
 614     self.solid          = SOLID_SLIDEBOX;
 615     self.delay          = time;
 616     self.scale          = 0.5;
 617
 618     setsize(self, RACER_MIN * 0.5, RACER_MAX * 0.5);
 619     self.bouncefactor = autocvar_g_vehicle_racer_bouncefactor;
 620     self.bouncestop = autocvar_g_vehicle_racer_bouncestop;
 621     self.vehicle_impact = racer_impact;
 622     self.damageforcescale = 0.5;
 623     //self.destvec = autocvar_g_vehicle_racer_bouncepain;
 624 }
 625
 626 void spawnfunc_vehicle_racer()
 627 {
 628     if(!autocvar_g_vehicle_racer)
 629     {
 630         remove(self);
 631         return;
 632     }
 633
 634     self.vehicle_flags |= VHF_DMGSHAKE;
 635     self.vehicle_flags |= VHF_DMGROLL;
 636
 637     precache_sound ("weapons/lasergun_fire.wav");
 638     precache_sound ("weapons/rocket_fire.wav");
 639
 640     precache_sound ("vehicles/racer_idle.wav");
 641     precache_sound ("vehicles/racer_move.wav");
 642     precache_sound ("vehicles/racer_boost.wav");
 643
 644     precache_model ("models/vhshield.md3");
 645     precache_model ("models/vehicles/wakizashi.dpm");
 646     precache_model ("models/vehicles/wakizashi_cockpit.dpm");
 647
 648     if(autocvar_g_vehicle_racer_energy)
 649         if(autocvar_g_vehicle_racer_energy_regen)
 650             self.vehicle_flags |= VHF_ENERGYREGEN;
 651
 652     if(autocvar_g_vehicle_racer_shield)
 653         self.vehicle_flags |= VHF_HASSHIELD;
 654
 655     if(autocvar_g_vehicle_racer_shield_regen)
 656         self.vehicle_flags |= VHF_SHIELDREGEN;
 657
 658     if(autocvar_g_vehicle_racer_health_regen)
 659         self.vehicle_flags |= VHF_HEALTHREGEN;
 660
 661     if(!vehicle_initialize(
 662              "Wakizashi",
 663              "models/vehicles/wakizashi.dpm",
 664              "null", // we need this so tur_head is networked and usable for sounds
 665              "models/vehicles/wakizashi_cockpit.dpm",
 666              "", "", "tag_viewport",
 667              HUD_WAKIZASHI,
 668              0.5 * RACER_MIN, 0.5 * RACER_MAX,
 669              false,
 670              racer_spawn, autocvar_g_vehicle_racer_respawntime,
 671              racer_frame,
 672              racer_enter, racer_exit,
 673              racer_die,   racer_think,
 674              true,
 675              autocvar_g_vehicle_racer_health,
 676              autocvar_g_vehicle_racer_shield))
 677     {
 678         remove(self);
 679         return;
 680     }
 681 }
 682 #endif // SVQC