qcsrc/server/vehicles/raptor.qc

   1 #ifdef SVQC
   2 #define RAPTOR_MIN '-80 -80 0'
   3 #define RAPTOR_MAX '80 80 70'
   4 //#define RAPTOR_ENGINE "sound/vehicles/raptor.wav"
   5 float autocvar_g_vehicle_raptor_respawntime;
   6
   7 float autocvar_g_vehicle_raptor_movestyle;
   8 float autocvar_g_vehicle_raptor_turnspeed;
   9 float autocvar_g_vehicle_raptor_pitchspeed;
  10 float autocvar_g_vehicle_raptor_pitchlimit;
  11
  12 float autocvar_g_vehicle_raptor_speed_forward;
  13 float autocvar_g_vehicle_raptor_speed_strafe;
  14 float autocvar_g_vehicle_raptor_speed_up;
  15 float autocvar_g_vehicle_raptor_speed_down;
  16 float autocvar_g_vehicle_raptor_friction;
  17
  18 float autocvar_g_vehicle_raptor_bomblets;
  19 float autocvar_g_vehicle_raptor_bomblet_alt;
  20 float autocvar_g_vehicle_raptor_bomblet_time;
  21 float autocvar_g_vehicle_raptor_bomblet_damage;
  22 float autocvar_g_vehicle_raptor_bomblet_spread;
  23 float autocvar_g_vehicle_raptor_bomblet_edgedamage;
  24 float autocvar_g_vehicle_raptor_bomblet_radius;
  25 float autocvar_g_vehicle_raptor_bomblet_force;
  26 float autocvar_g_vehicle_raptor_bomblet_explode_delay;
  27 float autocvar_g_vehicle_raptor_bombs_refire;
  28
  29 float autocvar_g_vehicle_raptor_cannon_turnspeed;
  30 float autocvar_g_vehicle_raptor_cannon_turnlimit;
  31 float autocvar_g_vehicle_raptor_cannon_pitchlimit_up;
  32 float autocvar_g_vehicle_raptor_cannon_pitchlimit_down;
  33
  34 float autocvar_g_vehicle_raptor_cannon_locktarget;
  35 float autocvar_g_vehicle_raptor_cannon_locking_time;
  36 float autocvar_g_vehicle_raptor_cannon_locking_releasetime;
  37 float autocvar_g_vehicle_raptor_cannon_locked_time;
  38 float autocvar_g_vehicle_raptor_cannon_predicttarget;
  39
  40 float autocvar_g_vehicle_raptor_cannon_cost;
  41 float autocvar_g_vehicle_raptor_cannon_damage;
  42 float autocvar_g_vehicle_raptor_cannon_radius;
  43 float autocvar_g_vehicle_raptor_cannon_refire;
  44 float autocvar_g_vehicle_raptor_cannon_speed;
  45 float autocvar_g_vehicle_raptor_cannon_spread;
  46 float autocvar_g_vehicle_raptor_cannon_force;
  47
  48 float autocvar_g_vehicle_raptor_energy;
  49 float autocvar_g_vehicle_raptor_energy_regen;
  50 float autocvar_g_vehicle_raptor_energy_regen_pause;
  51
  52 float autocvar_g_vehicle_raptor_health;
  53 float autocvar_g_vehicle_raptor_health_regen;
  54 float autocvar_g_vehicle_raptor_health_regen_pause;
  55
  56 float autocvar_g_vehicle_raptor_shield;
  57 float autocvar_g_vehicle_raptor_shield_regen;
  58 float autocvar_g_vehicle_raptor_shield_regen_pause;
  59
  60 void raptor_spawn();
  61 float raptor_frame();
  62 float raptor_takeoff();
  63
  64 .entity bomb1;
  65 .entity bomb2;
  66
  67 float raptor_altitude(float amax)
  68 {
  69         tracebox(self.origin, self.mins, self.maxs, self.origin - ('0 0 1' * amax), TRUE, self);
  70     return vlen(self.origin - trace_endpos);
  71 }
  72
  73
  74 void raptor_bomblet_boom()
  75 {
  76     RadiusDamage (self, self.realowner, autocvar_g_vehicle_raptor_bomblet_damage,
  77                                     autocvar_g_vehicle_raptor_bomblet_edgedamage,
  78                                     autocvar_g_vehicle_raptor_bomblet_radius, world,
  79                                     autocvar_g_vehicle_raptor_bomblet_force, DEATH_RAPTOR_BOMB, world);
  80     remove(self);
  81 }
  82
  83 void raptor_bomblet_touch()
  84 {
  85     if(other == self.owner)
  86         return;
  87
  88     PROJECTILE_TOUCH;
  89     self.think = raptor_bomblet_boom;
  90     self.nextthink = time + random() * autocvar_g_vehicle_raptor_bomblet_explode_delay;
  91 }
  92
  93 void raptor_bomb_burst()
  94 {
  95     if(self.cnt > time)
  96     if(autocvar_g_vehicle_raptor_bomblet_alt)
  97     {
  98         self.nextthink = time;
  99         traceline(self.origin, self.origin + (normalize(self.velocity) * autocvar_g_vehicle_raptor_bomblet_alt), MOVE_NORMAL, self);
 100         if((trace_fraction == 1.0) || (vlen(self.origin - self.owner.origin) < autocvar_g_vehicle_raptor_bomblet_radius))
 101         {
 102             UpdateCSQCProjectile(self);
 103             return;
 104         }
 105     }
 106
 107     entity bomblet;
 108     float i;
 109
 110     Damage_DamageInfo(self.origin, 0, 0, 0, '0 0 0', DEATH_RAPTOR_BOMB_SPLIT, self);
 111
 112     for(i = 0; i < autocvar_g_vehicle_raptor_bomblets; ++i)
 113     {
 114         bomblet = spawn();
 115         setorigin(bomblet, self.origin);
 116
 117         bomblet.movetype    = MOVETYPE_TOSS;
 118         bomblet.touch       = raptor_bomblet_touch;
 119         bomblet.think       = raptor_bomblet_boom;
 120         bomblet.nextthink   = time + 5;
 121         bomblet.owner       = self.owner;
 122         bomblet.realowner   = self.realowner;
 123         bomblet.velocity    = normalize(normalize(self.velocity) + (randomvec() * autocvar_g_vehicle_raptor_bomblet_spread)) * vlen(self.velocity);
 124
 125         PROJECTILE_MAKETRIGGER(bomblet);
 126         CSQCProjectile(bomblet, TRUE, PROJECTILE_RAPTORBOMBLET, TRUE);
 127     }
 128
 129     remove(self);
 130 }
 131
 132 void raptor_bomb_touch()
 133 {
 134     raptor_bomb_burst();
 135 }
 136
 137 void raptor_bombdrop()
 138 {
 139     entity bomb_1, bomb_2;
 140
 141     bomb_1 = spawn();
 142     bomb_2 = spawn();
 143
 144     setorigin(bomb_1, gettaginfo(self, gettagindex(self, "bombmount_left")));
 145     setorigin(bomb_2, gettaginfo(self, gettagindex(self, "bombmount_right")));
 146
 147     bomb_1.movetype     = bomb_2.movetype   = MOVETYPE_BOUNCE;
 148     bomb_1.velocity     = bomb_2.velocity   = self.velocity;
 149     bomb_1.touch        = bomb_2.touch      = raptor_bomb_touch;
 150     bomb_1.think        = bomb_2.think      = raptor_bomb_burst;
 151     bomb_1.cnt          = bomb_2.cnt        = time + 10;
 152
 153     if(autocvar_g_vehicle_raptor_bomblet_alt)
 154         bomb_1.nextthink = bomb_2.nextthink  = time;
 155     else
 156         bomb_1.nextthink = bomb_2.nextthink  = time + autocvar_g_vehicle_raptor_bomblet_time;
 157
 158     bomb_1.owner     = bomb_2.owner      = self;
 159     bomb_1.realowner = bomb_2.realowner  = self.owner;
 160     bomb_1.solid     = bomb_2.solid      = SOLID_BBOX;
 161     bomb_1.gravity   = bomb_2.gravity    = 1;
 162
 163     PROJECTILE_MAKETRIGGER(bomb_1);
 164     PROJECTILE_MAKETRIGGER(bomb_2);
 165
 166     CSQCProjectile(bomb_1, TRUE, PROJECTILE_RAPTORBOMB, TRUE);
 167     CSQCProjectile(bomb_2, TRUE, PROJECTILE_RAPTORBOMB, TRUE);
 168
 169 }
 170
 171
 172 void raptor_fire_cannon(entity gun, string tagname)
 173 {
 174     entity bolt;
 175     vector b_org;
 176     b_org = gettaginfo(gun, gettagindex(gun, tagname));
 177     bolt = vehicles_projectile("raptor_cannon_muzzleflash", "weapons/lasergun_fire.wav",
 178                            b_org, normalize(v_forward + randomvec() * autocvar_g_vehicle_raptor_cannon_spread) * autocvar_g_vehicle_raptor_cannon_speed,
 179                            autocvar_g_vehicle_raptor_cannon_damage, autocvar_g_vehicle_raptor_cannon_radius, autocvar_g_vehicle_raptor_cannon_force,  0,
 180                            DEATH_RAPTOR_CANNON, PROJECTILE_RAPTORCANNON, 0, TRUE, TRUE);
 181 }
 182
 183 void raptor_think()
 184 {
 185 }
 186
 187 void raptor_enter()
 188 {
 189     self.owner.PlayerPhysplug = raptor_takeoff;
 190     self.movetype       = MOVETYPE_BOUNCEMISSILE;
 191     self.solid          = SOLID_SLIDEBOX;
 192     self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_raptor_health);
 193     self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_raptor_shield);
 194     self.velocity_z = 1; // Nudge upwards to takeoff sequense can work.
 195     self.tur_head.exteriormodeltoclient = self.owner;
 196
 197     self.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 198     self.lip   = time;
 199
 200 }
 201
 202 void raptor_land()
 203 {
 204     float hgt;
 205
 206     hgt = raptor_altitude(512);
 207     self.velocity = (self.velocity * 0.9) + ('0 0 -1800' * (hgt / 256) * sys_frametime);
 208     self.angles_x *= 0.95;
 209     self.angles_z *= 0.95;
 210
 211     if(hgt < 128)
 212         if(self.frame != 0)
 213             self.frame = max(self.frame - 0.25, 0);
 214
 215     self.bomb1.gun1.avelocity_y = 90 + ((self.frame / 25) * 2000);
 216     self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 217
 218     if(hgt < 16)
 219     {
 220         self.movetype   = MOVETYPE_TOSS;
 221         self.think      = raptor_think;
 222     }
 223
 224     self.nextthink  = time;
 225 }
 226
 227 void raptor_exit(float eject)
 228 {
 229     vector spot;
 230     self.tur_head.exteriormodeltoclient = world;
 231
 232     if(self.deadflag == DEAD_NO)
 233     {
 234         self.think      = raptor_land;
 235         self.nextthink  = time;
 236     }
 237
 238     if not (self.owner)
 239         return;
 240
 241         makevectors(self.angles);
 242         if(eject)
 243         {
 244             spot = self.origin + v_forward * 100 + '0 0 64';
 245             spot = vehicles_findgoodexit(spot);
 246             setorigin(self.owner , spot);
 247             self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 248         }
 249         else
 250         {
 251             spot = self.origin - v_forward * 200 + '0 0 64';
 252             spot = vehicles_findgoodexit(spot);
 253             setorigin(self.owner , spot);
 254         }
 255
 256     self.owner = world;
 257 }
 258
 259 float raptor_takeoff()
 260 {
 261     entity player, raptor;
 262
 263     player = self;
 264     raptor = self.vehicle;
 265     self   = raptor;
 266
 267     if(self.sound_nexttime < time)
 268     {
 269         self.sound_nexttime = time + 7.955812; //soundlength("vehicles/raptor_fly.wav");
 270         sound (self, CHAN_TRIGGER, "vehicles/raptor_speed.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 271     }
 272
 273     // Takeoff sequense
 274     if(raptor.frame < 25)
 275     {
 276         raptor.frame += 0.25;
 277         raptor.velocity_z = min(raptor.velocity_z * 1.5, 256);
 278         self.bomb1.gun1.avelocity_y = 90 + ((raptor.frame / 25) * 25000);
 279         self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 280         player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 281
 282         setorigin(player, raptor.origin + '0 0 32');
 283     }
 284     else
 285         player.PlayerPhysplug = raptor_frame;
 286
 287     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 288         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime);
 289
 290     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 291         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime);
 292
 293     if(self.vehicle_flags  & VHF_ENERGYREGEN)
 294         vehicles_regen(cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime);
 295
 296
 297     raptor.bomb1.alpha = raptor.bomb2.alpha = (time - raptor.lip) / (raptor.delay - raptor.lip);
 298     player.vehicle_reload2 = bound(0, raptor.bomb1.alpha * 100, 100);
 299
 300     VEHICLE_UPDATE_PLAYER(health, raptor);
 301     VEHICLE_UPDATE_PLAYER(energy, raptor);
 302     if(self.vehicle_flags & VHF_HASSHIELD)
 303         VEHICLE_UPDATE_PLAYER(shield, raptor);
 304
 305     player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 306     self = player;
 307     return 1;
 308 }
 309
 310 float raptor_frame()
 311 {
 312     entity player, raptor;
 313     float ftmp, ftmp2;
 314     vector df, ra;
 315
 316     player = self;
 317     raptor = self.vehicle;
 318     self   = raptor;
 319
 320     /*
 321     ftmp = vlen(self.velocity);
 322     if(ftmp > autocvar_g_vehicle_raptor_speed_forward)
 323         ftmp = 1;
 324     else
 325         ftmp = ftmp / autocvar_g_vehicle_raptor_speed_forward;
 326     */
 327
 328     if(self.sound_nexttime < time)
 329     {
 330         self.sound_nexttime = time + 7.955812;
 331         //sound (self.tur_head, CHAN_TRIGGER, "vehicles/raptor_fly.wav", 1 - ftmp,   ATTN_NORM );
 332         sound (self, CHAN_TRIGGER, "vehicles/raptor_speed.wav", 1, ATTN_NORM);
 333         self.wait = ftmp;
 334     }
 335     /*
 336     else if(fabs(ftmp - self.wait) > 0.2)
 337     {
 338         sound (self.tur_head, CHAN_TRIGGER, "", 1 - ftmp,   ATTN_NORM );
 339         sound (self, CHAN_TRIGGER, "", ftmp, ATTN_NORM);
 340         self.wait = ftmp;
 341     }
 342     */
 343
 344     if(player.BUTTON_USE && raptor.deadflag == DEAD_NO)
 345     {
 346         self = raptor;
 347         vehicles_exit(VHEF_NORMAL);
 348         self = player;
 349         return 0;
 350     }
 351
 352     if(raptor.deadflag != DEAD_NO)
 353     {
 354         self = player;
 355         player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 356         return 1;
 357     }
 358     crosshair_trace(player);
 359
 360
 361     vector vang;
 362     vang = raptor.angles;
 363     df = vectoangles(normalize(trace_endpos - self.origin + '0 0 32'));
 364     vang_x *= -1;
 365     df_x *= -1;
 366     if(df_x > 180)  df_x -= 360;
 367     if(df_x < -180) df_x += 360;
 368     if(df_y > 180)  df_y -= 360;
 369     if(df_y < -180) df_y += 360;
 370
 371     ftmp = shortangle_f(player.v_angle_y - vang_y, vang_y);
 372     if(ftmp > 180)  ftmp -= 360; if(ftmp < -180) ftmp += 360;
 373     raptor.avelocity_y = bound(-autocvar_g_vehicle_raptor_turnspeed, ftmp + raptor.avelocity_y * 0.9, autocvar_g_vehicle_raptor_turnspeed);
 374
 375     // Pitch
 376     ftmp = 0;
 377     if(player.movement_x > 0 && vang_x < autocvar_g_vehicle_raptor_pitchlimit) ftmp = 5;
 378     else if(player.movement_x < 0 && vang_x > -autocvar_g_vehicle_raptor_pitchlimit) ftmp = -20;
 379
 380     df_x = bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x , autocvar_g_vehicle_raptor_pitchlimit);
 381     ftmp = vang_x - bound(-autocvar_g_vehicle_raptor_pitchlimit, df_x + ftmp, autocvar_g_vehicle_raptor_pitchlimit);
 382     raptor.avelocity_x = bound(-autocvar_g_vehicle_raptor_pitchspeed, ftmp + raptor.avelocity_x * 0.9, autocvar_g_vehicle_raptor_pitchspeed);
 383
 384     raptor.angles_x = anglemods(raptor.angles_x);
 385     raptor.angles_y = anglemods(raptor.angles_y);
 386     raptor.angles_z = anglemods(raptor.angles_z);
 387
 388
 389     if(autocvar_g_vehicle_raptor_movestyle == 1)
 390         makevectors('0 1 0' * raptor.angles_y);
 391     else
 392         makevectors(player.v_angle);
 393
 394     df = raptor.velocity * -autocvar_g_vehicle_raptor_friction;
 395
 396     if(player.movement_x != 0)
 397     {
 398         if(player.movement_x > 0)
 399             df += v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 400         else if(player.movement_x < 0)
 401             df -= v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 402     }
 403
 404     if(player.movement_y != 0)
 405     {
 406         if(player.movement_y < 0)
 407             df -= v_right * autocvar_g_vehicle_raptor_speed_strafe;
 408         else if(player.movement_y > 0)
 409             df += v_right * autocvar_g_vehicle_raptor_speed_strafe;
 410
 411         raptor.angles_z = bound(-30,raptor.angles_z + (player.movement_y / autocvar_g_vehicle_raptor_speed_strafe),30);
 412     }
 413     else
 414     {
 415         raptor.angles_z *= 0.95;
 416         if(raptor.angles_z >= -1 && raptor.angles_z <= -1)
 417             raptor.angles_z = 0;
 418     }
 419
 420     if(player.BUTTON_CROUCH)
 421         df -=   v_up * autocvar_g_vehicle_raptor_speed_down;
 422     else if (player.BUTTON_JUMP)
 423         df +=  v_up * autocvar_g_vehicle_raptor_speed_up;
 424
 425     raptor.velocity  += df * frametime;
 426     //player.velocity = raptor.velocity;
 427     player.velocity = player.movement  = raptor.velocity;
 428     setorigin(player, raptor.origin + '0 0 32');
 429
 430     vector vf, ad;
 431     // Target lock & predict
 432     if(autocvar_g_vehicle_raptor_cannon_locktarget)
 433     {
 434
 435         vehicles_locktarget((1 / autocvar_g_vehicle_raptor_cannon_locking_time) * frametime,
 436                              (1 / autocvar_g_vehicle_raptor_cannon_locking_releasetime) * frametime,
 437                              autocvar_g_vehicle_raptor_cannon_locked_time);
 438
 439         if(self.lock_target != world)
 440         if(autocvar_g_vehicle_raptor_cannon_predicttarget)
 441         if(self.lock_strength == 1)
 442         {
 443             float i, distance, impact_time;
 444
 445             vf = real_origin(raptor.lock_target);
 446             ad = vf;
 447             for(i = 0; i < 4; ++i)
 448             {
 449                 distance = vlen(ad - raptor.origin);
 450                 impact_time = distance / autocvar_g_vehicle_raptor_cannon_speed;
 451                 ad = vf + raptor.lock_target.velocity * impact_time;
 452             }
 453             trace_endpos = ad;
 454             //UpdateAuxiliaryXhair(player, trace_endpos, '1 1 1', 0);
 455         }
 456
 457         if(self.lock_target)
 458         {
 459             if(raptor.lock_strength == 1)
 460                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '1 0 0', 1);
 461             else if(self.lock_strength > 0.5)
 462                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '0 1 0', 1);
 463             else if(self.lock_strength < 0.5)
 464                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '0 0 1', 1);
 465         }
 466     }
 467
 468     ra = raptor.angles;
 469     ra_z = 0;
 470     // Aim the gunz
 471     ftmp2 = autocvar_g_vehicle_raptor_cannon_turnspeed * frametime;
 472     ftmp = -ftmp2;
 473
 474     // Gun1
 475     df = gettaginfo(raptor.gun1, gettagindex(raptor.gun1, "fire1"));
 476     ad = df;
 477     vf = v_forward;
 478     //if(self.lock_strength == 1)
 479     //{
 480         df = vectoangles(normalize(trace_endpos - df)); // Find the direction & angle
 481         df = shortangle_vxy(df - (ra + raptor.gun1.angles), ra + raptor.gun1.angles);     // Find aim offset
 482     //}
 483     //else
 484     //    df = '0 0 0';
 485
 486     // Bind to aimspeed
 487     df_x = bound(ftmp, df_x, ftmp2);
 488     df_y = bound(ftmp, df_y, ftmp2);
 489     // Bind to limts
 490     raptor.gun1.angles_x = bound(-autocvar_g_vehicle_raptor_cannon_pitchlimit_down, df_x + raptor.gun1.angles_x, autocvar_g_vehicle_raptor_cannon_pitchlimit_up);
 491     raptor.gun1.angles_y = bound(-autocvar_g_vehicle_raptor_cannon_turnlimit,  df_y + raptor.gun1.angles_y, autocvar_g_vehicle_raptor_cannon_turnlimit);
 492
 493     // Gun2
 494     df = gettaginfo(raptor.gun2, gettagindex(raptor.gun2, "fire1"));
 495     ad += df;
 496     vf += v_forward;
 497     //if(self.lock_strength == 1)
 498     //{
 499         df = vectoangles(normalize(trace_endpos - df)); // Find the direction & angle
 500         df = shortangle_vxy(df - (ra + raptor.gun2.angles), ra + raptor.gun2.angles);     // Find aim offset
 501     //}
 502     //else
 503     //    df = '0 0 0';
 504
 505     // Bind to aimspeed
 506     df_x = bound(ftmp, df_x, ftmp2);
 507     df_y = bound(ftmp, df_y, ftmp2);
 508     // Bind to limts
 509     raptor.gun2.angles_x = bound(-autocvar_g_vehicle_raptor_cannon_pitchlimit_down, df_x + raptor.gun2.angles_x, autocvar_g_vehicle_raptor_cannon_pitchlimit_up);
 510     raptor.gun2.angles_y = bound(-autocvar_g_vehicle_raptor_cannon_turnlimit,  df_y + raptor.gun2.angles_y, autocvar_g_vehicle_raptor_cannon_turnlimit);
 511
 512     /*
 513     ad = ad * 0.5;
 514     v_forward = vf * 0.5;
 515     traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, raptor);
 516     UpdateAuxiliaryXhair(player, trace_endpos, '0 1 0', 0);
 517     */
 518
 519     if(player.BUTTON_ATCK)
 520     if(raptor.attack_finished_single <= time)
 521     if(raptor.vehicle_energy > autocvar_g_vehicle_raptor_cannon_cost)
 522     {
 523         raptor.misc_bulletcounter += 1;
 524         raptor.attack_finished_single = time + autocvar_g_vehicle_raptor_cannon_refire;
 525         if(raptor.misc_bulletcounter <= 2)
 526             raptor_fire_cannon(self.gun1, "fire1");
 527         else if(raptor.misc_bulletcounter == 3)
 528             raptor_fire_cannon(self.gun2, "fire1");
 529         else
 530         {
 531             raptor.attack_finished_single = time + autocvar_g_vehicle_raptor_cannon_refire * 2;
 532             raptor_fire_cannon(self.gun2, "fire1");
 533             raptor.misc_bulletcounter = 0;
 534         }
 535         raptor.vehicle_energy -= autocvar_g_vehicle_raptor_cannon_cost;
 536         self.cnt = time;
 537     }
 538
 539     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 540         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime);
 541
 542     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 543         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime);
 544
 545     if(self.vehicle_flags  & VHF_ENERGYREGEN)
 546         vehicles_regen(cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime);
 547
 548
 549     if(time > raptor.delay)
 550     if(player.BUTTON_ATCK2)
 551     {
 552         raptor_bombdrop();
 553         raptor.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 554         raptor.lip   = time;
 555     }
 556
 557     raptor.bomb1.alpha = raptor.bomb2.alpha = (time - raptor.lip) / (raptor.delay - raptor.lip);
 558     player.vehicle_reload2 = bound(0, raptor.bomb1.alpha * 100, 100);
 559
 560     VEHICLE_UPDATE_PLAYER(health, raptor);
 561     VEHICLE_UPDATE_PLAYER(energy, raptor);
 562     if(self.vehicle_flags & VHF_HASSHIELD)
 563         VEHICLE_UPDATE_PLAYER(shield, raptor);
 564
 565     player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 566     return 1;
 567 }
 568
 569 void raptor_blowup()
 570 {
 571     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 572     pointparticles(particleeffectnum("explosion_big"), self.origin, '0 0 0', 1);
 573
 574     self.deadflag    = DEAD_DEAD;
 575     self.vehicle_exit(VHEF_NORMAL);
 576     RadiusDamage (self, self, 250, 15, 250, world, 250, DEATH_WAKIBLOWUP, world);
 577
 578     self.alpha          = -1;
 579     self.movetype       = MOVETYPE_NONE;
 580     self.effects        = EF_NODRAW;
 581     self.colormod       = '0 0 0';
 582     self.avelocity      = '0 0 0';
 583     self.velocity       = '0 0 0';
 584
 585     setorigin(self, self.pos1);
 586     self.touch = SUB_Null;
 587     self.nextthink = 0;
 588 }
 589
 590 void raptor_diethink()
 591 {
 592     //self.avelocity += '0 0.5 1' * (random() * 5);
 593     //self.avelocity -= '0 0.5 1' * (random() * 5);
 594
 595     if(random() < 0.1)
 596     {
 597         sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 598         pointparticles(particleeffectnum("explosion_small"), randomvec() * 80 + (self.origin + '0 0 100'), '0 0 0', 1);
 599     }
 600     self.nextthink = time + 0.1;
 601 }
 602
 603 void raptor_die()
 604 {
 605     self.health       = 0;
 606     self.event_damage = SUB_Null;
 607     self.iscreature   = FALSE;
 608     self.solid        = SOLID_CORPSE;
 609     self.takedamage   = DAMAGE_NO;
 610     self.deadflag     = DEAD_DYING;
 611     self.movetype     = MOVETYPE_BOUNCE;
 612     self.think        = raptor_diethink;
 613     self.nextthink    = time;
 614
 615     pointparticles(particleeffectnum("explosion_medium"), findbetterlocation (self.origin, 16), '0 0 0', 1);
 616
 617     self.velocity_z += 600;
 618
 619     self.avelocity = '0 0.5 1' * (random() * 400);
 620     self.avelocity -= '0 0.5 1' * (random() * 400);
 621
 622     self.colormod = '-0.5 -0.5 -0.5';
 623         self.touch     = raptor_blowup;
 624 }
 625
 626 void raptor_spawn()
 627 {
 628     self.frame          = 0;
 629     self.vehicle_health = autocvar_g_vehicle_raptor_health;
 630     self.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 631     self.movetype       = MOVETYPE_TOSS;
 632     self.solid          = SOLID_SLIDEBOX;
 633     self.vehicle_energy = 1;
 634
 635     self.bomb1.gun1.avelocity_y = 90;
 636     self.bomb1.gun2.avelocity_y = -90;
 637
 638     setsize(self, RAPTOR_MIN, RAPTOR_MAX );
 639     self.delay = time;
 640 }
 641
 642 // If we dont do this ever now and then, the raptors rotors
 643 // stop working, presumably due to angle overflow. cute.
 644 void raptor_rotor_anglefix()
 645 {
 646     self.gun1.angles_y = anglemods(self.gun1.angles_y);
 647     self.gun2.angles_y = anglemods(self.gun2.angles_y);
 648     self.nextthink = time + 15;
 649 }
 650
 651 void raptor_dinit()
 652 {
 653     entity spinner;
 654     vector ofs;
 655
 656     if not (vehicle_initialize(
 657              "Raptor",
 658              "models/vehicles/raptor.dpm",
 659              "",
 660              "models/vehicles/raptor_cockpit.dpm",
 661              "", "tag_hud", "tag_camera",
 662              HUD_RAPTOR,
 663              RAPTOR_MIN, RAPTOR_MAX,
 664              FALSE,
 665              raptor_spawn, autocvar_g_vehicle_raptor_respawntime,
 666              raptor_frame,
 667              raptor_enter, raptor_exit,
 668              raptor_die,   raptor_think,
 669              FALSE))
 670     {
 671         remove(self);
 672         return;
 673     }
 674
 675     //FIXME: Camera is in a bad place in HUD model.
 676     //setorigin(self.vehicle_viewport, '25 0 5');
 677
 678     self.frame = 0;
 679
 680     self.bomb1 = spawn();
 681     self.bomb2 = spawn();
 682     self.gun1  = spawn();
 683     self.gun2  = spawn();
 684
 685     setmodel(self.bomb1,"models/vehicles/clusterbomb_folded.md3");
 686     setmodel(self.bomb2,"models/vehicles/clusterbomb_folded.md3");
 687     setmodel(self.gun1, "models/vehicles/raptor_gun.dpm");
 688     setmodel(self.gun2, "models/vehicles/raptor_gun.dpm");
 689     setmodel(self.tur_head, "models/vehicles/raptor_body.dpm");
 690
 691     setattachment(self.bomb1, self,"bombmount_left");
 692     setattachment(self.bomb2, self,"bombmount_right");
 693     setattachment(self.tur_head, self,"root");
 694
 695
 696     // FIXME Guns mounts to angled bones
 697     self.bomb1.angles = self.angles;
 698     self.angles = '0 0 0';
 699     // This messes up gun-aim, so work arround it.
 700     //setattachment(self.gun1, self, "gunmount_left");
 701     ofs = gettaginfo(self, gettagindex(self, "gunmount_left"));
 702     ofs -= self.origin;
 703     setattachment(self.gun1, self, "");
 704     setorigin(self.gun1, ofs);
 705
 706     //setattachment(self.gun2, self, "gunmount_right");
 707     ofs = gettaginfo(self, gettagindex(self, "gunmount_right"));
 708     ofs -= self.origin;
 709     setattachment(self.gun2, self, "");
 710     setorigin(self.gun2, ofs);
 711
 712     self.angles = self.bomb1.angles;
 713     self.bomb1.angles = '0 0 0';
 714
 715     spinner = spawn();
 716     spinner.owner = self;
 717     setmodel(spinner,"models/vehicles/spinner.dpm");
 718     setattachment(spinner, self, "engine_left");
 719     spinner.movetype = MOVETYPE_NOCLIP;
 720     spinner.avelocity = '0 90 0';
 721     self.bomb1.gun1 = spinner;
 722
 723     spinner = spawn();
 724     spinner.owner = self;
 725     setmodel(spinner,"models/vehicles/spinner.dpm");
 726     setattachment(spinner, self, "engine_right");
 727     spinner.movetype = MOVETYPE_NOCLIP;
 728     spinner.avelocity = '0 -90 0';
 729     self.bomb1.gun2 = spinner;
 730
 731     // Sigh.
 732     self.bomb1.think = raptor_rotor_anglefix;
 733     self.bomb1.nextthink = time;
 734
 735     self.mass               = 1 ;
 736 }
 737
 738 void spawnfunc_vehicle_raptor()
 739 {
 740     vehicles_configcheck("vehicle_raptor.cfg", autocvar_g_vehicle_raptor_health);
 741
 742     if(autocvar_g_vehicle_raptor_shield)
 743         self.vehicle_flags |= VHF_HASSHIELD;
 744
 745     if(autocvar_g_vehicle_raptor_shield_regen)
 746         self.vehicle_flags |= VHF_SHIELDREGEN;
 747
 748     if(autocvar_g_vehicle_raptor_health_regen)
 749         self.vehicle_flags |= VHF_HEALTHREGEN;
 750
 751     if(autocvar_g_vehicle_raptor_energy_regen)
 752         self.vehicle_flags |= VHF_ENERGYREGEN;
 753
 754     precache_model ("models/vehicles/raptor.dpm");
 755     precache_model ("models/vehicles/raptor_gun.dpm");
 756     precache_model ("models/vehicles/spinner.dpm");
 757     precache_model ("models/vehicles/raptor_cockpit.dpm");
 758     precache_model ("models/vehicles/clusterbomb.md3");
 759     precache_model ("models/vehicles/clusterbomb_folded.md3");
 760     precache_model ("models/vehicles/raptor_body.dpm");
 761
 762     precache_sound ("vehicles/raptor_fly.wav");
 763     precache_sound ("vehicles/raptor_speed.wav");
 764     precache_sound ("");
 765
 766     self.think = raptor_dinit;
 767     self.nextthink = time + (autocvar_g_vehicles_delayspawn ? autocvar_g_vehicle_raptor_respawntime + (random() * autocvar_g_vehicles_delayspawn_jitter) : 0.5);
 768 }
 769 #endif // SVQC