qcsrc/server/vehicles/spiderbot.qc

   1 const vector SPIDERBOT_MIN = '-75 -75 10';
   2 const vector SPIDERBOT_MAX  = '75 75 110';
   3
   4 float autocvar_g_vehicle_spiderbot_respawntime;
   5
   6 //float autocvar_g_vehicle_spiderbot_crush_dmg;
   7 //float autocvar_g_vehicle_spiderbot_crush_force;
   8
   9 float autocvar_g_vehicle_spiderbot_speed_stop;
  10 float autocvar_g_vehicle_spiderbot_speed_strafe;
  11 float autocvar_g_vehicle_spiderbot_speed_walk;
  12 float autocvar_g_vehicle_spiderbot_turnspeed;
  13 float autocvar_g_vehicle_spiderbot_movement_inertia;
  14
  15 float autocvar_g_vehicle_spiderbot_springlength;
  16 float autocvar_g_vehicle_spiderbot_springup;
  17 float autocvar_g_vehicle_spiderbot_springblend;
  18
  19 float autocvar_g_vehicle_spiderbot_head_pitchlimit_down;
  20 float autocvar_g_vehicle_spiderbot_head_pitchlimit_up;
  21 float autocvar_g_vehicle_spiderbot_head_pitchspeed;
  22 float autocvar_g_vehicle_spiderbot_head_turnlimit;
  23 float autocvar_g_vehicle_spiderbot_head_turnspeed;
  24
  25 //float autocvar_g_vehicle_spiderbot_energy;
  26 //float autocvar_g_vehicle_spiderbot_energy_regen;
  27 //float autocvar_g_vehicle_spiderbot_energy_regen_pause;
  28
  29 float autocvar_g_vehicle_spiderbot_health;
  30 float autocvar_g_vehicle_spiderbot_health_regen;
  31 float autocvar_g_vehicle_spiderbot_health_regen_pause;
  32
  33 float autocvar_g_vehicle_spiderbot_shield;
  34 float autocvar_g_vehicle_spiderbot_shield_regen;
  35 float autocvar_g_vehicle_spiderbot_shield_regen_pause;
  36
  37 float autocvar_g_vehicle_spiderbot_minigun_damage;
  38 float autocvar_g_vehicle_spiderbot_minigun_refire;
  39 float autocvar_g_vehicle_spiderbot_minigun_spread;
  40 float autocvar_g_vehicle_spiderbot_minigun_cooldown;
  41 float autocvar_g_vehicle_spiderbot_minigun_heat;
  42
  43 float autocvar_g_vehicle_spiderbot_rocket_damage;
  44 float autocvar_g_vehicle_spiderbot_rocket_edgedamage;
  45 float autocvar_g_vehicle_spiderbot_rocket_force;
  46 float autocvar_g_vehicle_spiderbot_rocket_health;
  47 float autocvar_g_vehicle_spiderbot_rocket_lifetime;
  48 float autocvar_g_vehicle_spiderbot_rocket_noise;
  49 float autocvar_g_vehicle_spiderbot_rocket_radius;
  50 float autocvar_g_vehicle_spiderbot_rocket_refire;
  51 float autocvar_g_vehicle_spiderbot_rocket_reload;
  52 float autocvar_g_vehicle_spiderbot_rocket_speed;
  53 float autocvar_g_vehicle_spiderbot_rocket_turnrate;
  54
  55
  56 void spiderbot_exit(float eject);
  57 void spiderbot_enter();
  58 void spiderbot_spawn();
  59
  60 void spiderbot_rocket_explode()
  61 {
  62     vector org2;
  63
  64     if(self.event_damage != SUB_Null)
  65     {
  66         self.event_damage = SUB_Null;
  67         self.think = spiderbot_rocket_explode;
  68         self.nextthink = time;
  69         return;
  70     }
  71
  72     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
  73     org2 = findbetterlocation (self.origin, 16);
  74     pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
  75     w_deathtypestring = "dident escape the rocket barrage";
  76
  77     if(!self.owner)
  78         self.owner = self.realowner;
  79
  80     RadiusDamage (self, self.owner,
  81         autocvar_g_vehicle_spiderbot_rocket_damage,
  82         autocvar_g_vehicle_spiderbot_rocket_edgedamage,
  83         autocvar_g_vehicle_spiderbot_rocket_radius, world,
  84         autocvar_g_vehicle_spiderbot_rocket_force, DEATH_SBROCKET, world);
  85
  86     remove (self);
  87 }
  88
  89 void spiderbot_rocket_touch()
  90 {
  91     if(self.owner)
  92     {
  93         if(other == self.owner.vehicle)
  94             return;
  95
  96         if(other == self.owner.vehicle.tur_head)
  97             return;
  98     }
  99
 100     PROJECTILE_TOUCH;
 101     spiderbot_rocket_explode();
 102 }
 103
 104 void spiderbot_rocket_unguided()
 105 {
 106     vector newdir, olddir;
 107
 108     self.nextthink  = time;
 109
 110
 111     olddir = normalize(self.velocity);
 112     newdir = normalize(self.pos1 - self.origin) + randomvec() * autocvar_g_vehicle_spiderbot_rocket_noise;
 113     self.velocity = normalize(olddir + newdir * autocvar_g_vehicle_spiderbot_rocket_turnrate) * autocvar_g_vehicle_spiderbot_rocket_speed;
 114
 115     UpdateCSQCProjectile(self);
 116
 117     if (self.owner.deadflag != DEAD_NO || self.cnt < time)
 118         spiderbot_rocket_explode();
 119
 120 }
 121
 122 void spiderbot_rocket_guided()
 123 {
 124     vector newdir, olddir;
 125
 126     self.nextthink  = time;
 127
 128     if not (self.owner.vehicle)
 129         self.think = spiderbot_rocket_unguided;
 130
 131     crosshair_trace(self.owner);
 132     olddir = normalize(self.velocity);
 133     newdir = normalize(trace_endpos - self.origin) + randomvec() * autocvar_g_vehicle_spiderbot_rocket_noise;
 134     self.velocity = normalize(olddir + newdir * autocvar_g_vehicle_spiderbot_rocket_turnrate) * autocvar_g_vehicle_spiderbot_rocket_speed;
 135
 136     UpdateCSQCProjectile(self);
 137
 138     if (self.owner.deadflag != DEAD_NO || self.cnt < time)
 139         spiderbot_rocket_explode();
 140 }
 141
 142 void spiderbot_rocket_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 143 {
 144     self.health -= damage;
 145     self.velocity += force;
 146     if(self.health < 1)
 147         spiderbot_rocket_explode();
 148 }
 149
 150 void spiderbot_guide_release()
 151 {
 152     entity rkt;
 153     rkt = findchainentity(owner,self.owner);
 154     if not (rkt)
 155         return;
 156
 157     crosshair_trace(self.owner);
 158     while(rkt)
 159     {
 160         if(rkt.think == spiderbot_rocket_guided)
 161         {
 162             rkt.pos1 = trace_endpos;
 163             rkt.think = spiderbot_rocket_unguided;
 164         }
 165         rkt = rkt.chain;
 166     }
 167 }
 168
 169 void spiderbot_rocket_do()
 170 {
 171     entity rocket;
 172
 173     if (self.owner.BUTTON_ATCK2)
 174     {
 175         if (self.wait == 1)
 176         if (self.tur_head.frame == 9 || self.tur_head.frame == 1)
 177         {
 178             if(self.gun2.cnt < time && self.tur_head.frame == 9)
 179                 self.tur_head.frame = 1;
 180
 181             return;
 182         }
 183         self.wait = 1;
 184     }
 185     else
 186     {
 187         if(self.wait)
 188             spiderbot_guide_release();
 189
 190         self.wait = 0;
 191     }
 192
 193     if(self.gun2.cnt > time)
 194         return;
 195
 196     if (self.tur_head.frame >= 9)
 197         self.tur_head.frame = 1;
 198
 199     if not (self.owner.BUTTON_ATCK2)
 200         return;
 201
 202     sound (self, CHAN_WEAPON, "weapons/rocket_fire.wav", VOL_BASE, ATTN_NORM);
 203     rocket                    = spawn ();
 204     setsize (rocket, '-1 -1 -1', '1 1 1'); // give it some size so it can be shot
 205     setorigin(rocket,gettaginfo(self.tur_head,gettagindex(self.tur_head,"tag_fire")));
 206     te_explosion (rocket.origin);
 207
 208     crosshair_trace(self.owner);
 209
 210     rocket.classname       = "spiderbot_rocket";
 211     rocket.bot_dodge       = TRUE;
 212     rocket.bot_dodgerating = autocvar_g_vehicle_spiderbot_rocket_damage;
 213     rocket.cnt             = time + autocvar_g_vehicle_spiderbot_rocket_lifetime;
 214     rocket.health          = autocvar_g_vehicle_spiderbot_rocket_health;
 215     rocket.takedamage      = DAMAGE_AIM;
 216     rocket.event_damage    = spiderbot_rocket_damage;
 217     rocket.owner           = self.owner;
 218     rocket.nextthink       = time;
 219     rocket.movetype        = MOVETYPE_FLYMISSILE;
 220     rocket.velocity        = normalize(v_forward + (v_up * 0.5) + randomvec() * 0.25) * autocvar_g_vehicle_spiderbot_rocket_speed;
 221     rocket.angles          = vectoangles(rocket.velocity);
 222     rocket.think           = spiderbot_rocket_guided;
 223     rocket.touch           = spiderbot_rocket_touch;
 224     rocket.flags           = FL_PROJECTILE;
 225     rocket.solid           = SOLID_TRIGGER;
 226     rocket.pos1            = trace_endpos;
 227
 228         CSQCProjectile(rocket, FALSE, PROJECTILE_SPIDERROCKET, FALSE); // no culling, has fly sound
 229
 230     self.tur_head.frame += 1;
 231     if (self.tur_head.frame == 9)
 232         self.attack_finished_single = autocvar_g_vehicle_spiderbot_rocket_reload;
 233     else
 234         self.attack_finished_single = autocvar_g_vehicle_spiderbot_rocket_refire;
 235
 236     self.gun2.cnt = time + self.attack_finished_single;
 237 }
 238
 239 void spiderbot_minigun_fire(entity gun, float trail)
 240 {
 241     vector v;
 242
 243     v = gettaginfo(gun, gettagindex(gun,"barrels"));
 244     v_forward = normalize(v_forward);
 245     v += v_forward * 50;
 246
 247     fireBullet (v, v_forward, autocvar_g_vehicle_spiderbot_minigun_spread, autocvar_g_vehicle_spiderbot_minigun_damage,
 248         autocvar_g_vehicle_spiderbot_minigun_spread, DEATH_SBMINIGUN, 0);
 249
 250     if(trail)
 251     {
 252         sound (gun, CHAN_WEAPON, "weapons/uzi_fire.wav", VOL_BASE, ATTN_NORM);
 253         trailparticles(self, particleeffectnum("spiderbot_minigun_trail"), v, trace_endpos);
 254         pointparticles(particleeffectnum("spiderbot_minigun_muzzleflash"), v, v_forward * 2500, 1);
 255         pointparticles(particleeffectnum("spiderbot_minigun_impact"), trace_endpos, trace_plane_normal * 2500,1);
 256     }
 257 }
 258
 259 void spiderbot_miniguns_do()
 260 {
 261     float ftmp;
 262
 263     if((self.vehicle_reload1 == 1) || (!self.owner.BUTTON_ATCK))
 264     {
 265         ftmp = 1 / autocvar_g_vehicle_spiderbot_minigun_cooldown * sys_frametime;
 266         self.owner.vehicle_reload1 = max(self.owner.vehicle_reload1 - ftmp, 0);
 267         if(self.owner.vehicle_reload1 <= 0)
 268             self.vehicle_reload1 = 0;
 269
 270         return;
 271     }
 272
 273     if (self.owner.BUTTON_ATCK)
 274     {
 275
 276         // Animate miniguns
 277         self.gun1.angles_z += (1440 * sys_frametime);
 278         self.gun2.angles_z -= (1440 * sys_frametime);
 279         if(self.gun1.angles_z >= 360)
 280         {
 281             self.gun1.angles_z = 0;
 282             self.gun2.angles_z = 360;
 283         }
 284
 285         if (self.tur_head.attack_finished_single < time)
 286         {
 287             // Fire bullets, alternating trails left<->right
 288             self = self.owner;
 289             if(self.misc_bulletcounter == 1)
 290             {
 291                 spiderbot_minigun_fire(self.vehicle.gun1, 0);
 292                 spiderbot_minigun_fire(self.vehicle.gun2, 1);
 293                 self.misc_bulletcounter = 0;
 294             }
 295             else
 296             {
 297                 spiderbot_minigun_fire(self.vehicle.gun1, 1);
 298                 spiderbot_minigun_fire(self.vehicle.gun2, 0);
 299                 self.misc_bulletcounter += 1;
 300             }
 301             self = self.vehicle;
 302
 303             ftmp = autocvar_g_vehicle_spiderbot_minigun_refire / autocvar_g_vehicle_spiderbot_minigun_heat;
 304             self.owner.vehicle_reload1 +=  ftmp;
 305
 306             if(self.owner.vehicle_reload1 >= 1)
 307             {
 308                 self.vehicle_reload1 = 1;
 309                 self.owner.vehicle_reload1 = 1;
 310                 self.tur_head.attack_finished_single = autocvar_g_vehicle_spiderbot_minigun_cooldown + time;
 311             }
 312             else
 313                 self.tur_head.attack_finished_single = autocvar_g_vehicle_spiderbot_minigun_refire + time;
 314         }
 315         return;
 316     }
 317 }
 318
 319 float spiderbot_frame()
 320 {
 321     vector ad;
 322     entity player, spider;
 323     float ftmp;
 324
 325     player = self;
 326     spider = self.vehicle;
 327
 328     player.BUTTON_ZOOM      = 0;
 329     player.BUTTON_CROUCH    = 0;
 330     player.switchweapon     = 0;
 331
 332     if(player.BUTTON_USE)
 333     {
 334         self = spider;
 335         vehicles_exit(VHEF_NORMAL);
 336         self = player;
 337         return 0;
 338     }
 339
 340     self = spider;
 341
 342     crosshair_trace(player);
 343     //UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * player.vehicle_reload2) + ('0 1 0' * (1 - player.vehicle_reload2)), 2);
 344
 345 #if VEHICLES_VIEWROTATE_CROSSHAIR
 346     ad = vectoangles(normalize(trace_endpos - gettaginfo(spider.tur_head,gettagindex(spider.tur_head,"tag_hud")))) - (spider.tur_head.angles + spider.angles);
 347     if(ad_x > 180) ad_x -= 360;
 348     if(ad_x < -180) ad_x += 360;
 349     if(ad_y > 180) ad_y -= 360;
 350     if(ad_y < -180) ad_y += 360;
 351
 352     // Rotate head
 353     ftmp = autocvar_g_vehicle_spiderbot_head_turnspeed * sys_frametime;
 354     ad_y = bound(-ftmp, ad_y, ftmp);
 355     spider.tur_head.angles_y = bound(autocvar_g_vehicle_spiderbot_head_turnlimit * -1, spider.tur_head.angles_y + ad_y, autocvar_g_vehicle_spiderbot_head_turnlimit);
 356
 357     // Pitch head
 358     ftmp = autocvar_g_vehicle_spiderbot_head_pitchspeed * sys_frametime;
 359     //ad_x = bound(-ftmp, ad_x, ftmp);
 360     spider.tur_head.angles_x = bound(autocvar_g_vehicle_spiderbot_head_pitchlimit_down, spider.tur_head.angles_x + ad_x, autocvar_g_vehicle_spiderbot_head_pitchlimit_up);
 361
 362     // Turn Body
 363     ftmp = autocvar_g_vehicle_spiderbot_turnspeed * sys_frametime;
 364     ftmp = bound(-ftmp, spider.tur_head.angles_y, ftmp);
 365 #else
 366
 367     player.v_angle_x *= -1;
 368     ad = player.v_angle - (spider.tur_head.angles + spider.angles);
 369     player.v_angle_x *= -1;
 370     if(ad_x > 180)  ad_x -= 360;
 371     if(ad_x < -180) ad_x += 360;
 372     if(ad_y > 180)  ad_y -= 360;
 373     if(ad_y < -180) ad_y += 360;
 374
 375     // Rotate head
 376     ftmp = autocvar_g_vehicle_spiderbot_head_turnspeed * sys_frametime;
 377     ad_y = bound(-ftmp, ad_y, ftmp);
 378     spider.tur_head.angles_y = bound(autocvar_g_vehicle_spiderbot_head_turnlimit * -1, spider.tur_head.angles_y + ad_y, autocvar_g_vehicle_spiderbot_head_turnlimit);
 379
 380
 381     // Pitch head
 382     ad = vectoangles(normalize(trace_endpos - gettaginfo(spider.tur_head,gettagindex(spider.tur_head,"tag_hud")))) - (spider.tur_head.angles + spider.angles);
 383     if(ad_x > 180) ad_x -= 360;
 384     if(ad_x < -180) ad_x += 360;
 385
 386
 387     ftmp = autocvar_g_vehicle_spiderbot_head_pitchspeed * sys_frametime;
 388     ad_x = bound(ftmp * -1, ad_x, ftmp);
 389     spider.tur_head.angles_x = bound(autocvar_g_vehicle_spiderbot_head_pitchlimit_down, spider.tur_head.angles_x + ad_x, autocvar_g_vehicle_spiderbot_head_pitchlimit_up);
 390
 391
 392
 393     // Turn Body
 394     ftmp = autocvar_g_vehicle_spiderbot_turnspeed * sys_frametime;
 395     ftmp = bound(-ftmp, spider.tur_head.angles_y, ftmp);
 396
 397
 398 #endif
 399     makevectors(spider.angles + '-1 0 0' * spider.angles_x);
 400
 401     /*
 402     vector ofs;
 403     ofs = self.origin + v_up * 128;
 404     te_lightning1(world, ofs, ofs + v_up * 32);
 405     te_lightning1(world, ofs, ofs + v_right * 128);
 406     te_lightning1(world, ofs, ofs + v_forward * 256);
 407     */
 408
 409     movelib_groundalign4point(autocvar_g_vehicle_spiderbot_springlength, autocvar_g_vehicle_spiderbot_springup, autocvar_g_vehicle_spiderbot_springblend);
 410
 411     if(spider.flags & FL_ONGROUND)
 412     {
 413         if(player.BUTTON_JUMP && self.tur_head.wait < time)
 414         {
 415             self.tur_head.wait = time + 2;
 416             player.BUTTON_JUMP = 0;
 417             spider.velocity   = v_forward * 700 + v_up * 600;
 418             spider.frame = 4;
 419         }
 420         else
 421         {
 422             if(vlen(player.movement) == 0)
 423             {
 424                 movelib_beak_simple(autocvar_g_vehicle_spiderbot_speed_stop);
 425                 spider.frame = 5;
 426             }
 427             else
 428             {
 429                 spider.angles_y = anglemods(spider.angles_y + ftmp);
 430                 spider.tur_head.angles_y -= ftmp;
 431
 432                 if(player.movement_x != 0)
 433                 {
 434                     if(player.movement_x > 0)
 435                     {
 436                         player.movement_x = 1;
 437                         spider.frame = 0;
 438                     }
 439                     else if(player.movement_x < 0)
 440                     {
 441                         player.movement_x = -1;
 442                         spider.frame = 1;
 443                     }
 444                     player.movement_y = 0;
 445                     movelib_move_simple(normalize(v_forward * player.movement_x),autocvar_g_vehicle_spiderbot_speed_walk,autocvar_g_vehicle_spiderbot_movement_inertia);
 446                 }
 447                 else if(player.movement_y != 0)
 448                 {
 449                     if(player.movement_y < 0)
 450                     {
 451                         player.movement_y = -1;
 452                         spider.frame = 2;
 453                     }
 454                     else if(player.movement_y > 0)
 455                     {
 456                         player.movement_y = 1;
 457                         spider.frame = 3;
 458                     }
 459                     movelib_move_simple(normalize(v_right * player.movement_y),autocvar_g_vehicle_spiderbot_speed_strafe,autocvar_g_vehicle_spiderbot_movement_inertia);
 460                 }
 461             }
 462         }
 463     }
 464
 465     self.angles_x = bound(-45, self.angles_x, 45);
 466     self.angles_z = bound(-45, self.angles_z, 45);
 467
 468     spiderbot_miniguns_do();
 469     spiderbot_rocket_do();
 470
 471     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 472         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_spiderbot_shield, autocvar_g_vehicle_spiderbot_shield_regen_pause, autocvar_g_vehicle_spiderbot_shield_regen, frametime);
 473
 474     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 475         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_spiderbot_health, autocvar_g_vehicle_spiderbot_health_regen_pause, autocvar_g_vehicle_spiderbot_health_regen, frametime);
 476
 477     player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 478     player.vehicle_ammo2 = spider.tur_head.frame;
 479
 480     if(spider.gun2.cnt <= time)
 481         player.vehicle_reload2 = 1;
 482     else
 483         player.vehicle_reload2 = 1 - ((spider.gun2.cnt - time) / spider.attack_finished_single);
 484
 485     setorigin(player, spider.origin + '0 0 1' * SPIDERBOT_MAX_z);
 486     player.velocity = spider.velocity;
 487
 488     VEHICLE_UPDATE_PLAYER(health, spiderbot);
 489
 490     if(self.vehicle_flags & VHF_HASSHIELD)
 491         VEHICLE_UPDATE_PLAYER(shield, spiderbot);
 492
 493 #if 1 // 0 to enable per-gun impact aux crosshairs
 494     // Avarage gun impact point's -> aux cross
 495     vector vf;
 496     ad = gettaginfo(spider.gun1, gettagindex(spider.gun1, "barrels"));
 497     vf = v_forward;
 498     ad += gettaginfo(spider.gun2, gettagindex(spider.gun2, "barrels"));
 499     vf += v_forward;
 500     ad = ad * 0.5;
 501     v_forward = vf * 0.5;
 502     traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, spider);
 503     UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * player.vehicle_reload1) + ('0 1 0' * (1 - player.vehicle_reload1)), 0);
 504
 505 #else
 506     ad = gettaginfo(spider.gun1, gettagindex(spider.gun1, "barrels"));
 507     traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, spider);
 508     UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * player.vehicle_reload1) + ('0 1 0' * (1 - player.vehicle_reload1)), 0);
 509
 510     ad = gettaginfo(spider.gun2, gettagindex(spider.gun2, "barrels"));
 511     traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, spider);
 512     UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * player.vehicle_reload1) + ('0 1 0' * (1 - player.vehicle_reload1)), 1);
 513 #endif
 514
 515     self = player;
 516     return 1;
 517 }
 518
 519 void spiderbot_think()
 520 {
 521     if(self.flags & FL_ONGROUND)
 522         movelib_beak_simple(autocvar_g_vehicle_spiderbot_speed_stop);
 523
 524     self.nextthink = time;
 525 }
 526
 527 void spiderbot_enter()
 528 {
 529     self.movetype   = MOVETYPE_WALK;
 530     self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_spiderbot_health);
 531     self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_spiderbot_shield);
 532 }
 533
 534 void spiderbot_exit(float eject)
 535 {
 536     entity e;
 537
 538     e = findchain(classname,"spiderbot_rocket");
 539     while(e)
 540     {
 541         if(e.owner == self.owner)
 542         {
 543             e.realowner = self.owner;
 544             e.owner = world;
 545         }
 546         e = e.chain;
 547     }
 548
 549     self.velocity   = '0 0 0';
 550     self.think      = spiderbot_think;
 551     self.nextthink  = time;
 552     self.frame      = 5;
 553     self.movetype   = MOVETYPE_WALK;
 554
 555     if not (self.owner)
 556         return;
 557
 558         makevectors(self.angles);
 559         if(eject)
 560         {
 561             setorigin(self.owner ,self.origin + v_forward * 100 + '0 0 64');
 562             self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 563         }
 564         else
 565         setorigin(self.owner, self.origin - v_forward * 200 + '0 0 64');
 566
 567     self.owner = world;
 568 }
 569
 570 // Better way of determening whats crushable needed! (fl_crushable?)
 571 float spiderbot_crushable(entity e)
 572 {
 573     if(e.classname == "corpse")
 574         return 1;
 575
 576     if(e.classname == "player")
 577         return 1;
 578
 579     if(e.classname == "monster_zombie")
 580         return 1;
 581
 582     return 0;
 583 }
 584
 585 /*void spiderbot_touch(
 586 {
 587     //vehicles_touch();
 588     if(self.owner)
 589     {
 590         if(vlen(self.velocity) == 0)
 591             return;
 592
 593         if not (spiderbot_crushable(other))
 594             return;
 595
 596         //todo: add check for velocity/angle here (so we dont cush players runing into us from behind)
 597
 598         Damage(other, self, self.owner,autocvar_g_vehicle_spiderbot_crush_dmg,DEATH_SBCRUSH, '0 0 0', normalize(other.origin - self.origin) * autocvar_g_vehicle_spiderbot_crush_force);
 599         return;
 600     }
 601
 602     if(other.classname != "player")
 603         return;
 604
 605     if(other.deadflag != DEAD_NO)
 606         return;
 607
 608     if(other.vehicle != world)
 609         return;
 610
 611     vehicles_enter();
 612 }*/
 613
 614
 615 void spiderbot_spawn()
 616 {
 617     self.frame              = 5;
 618     self.tur_head.frame     = 1;
 619     self.think              = spiderbot_think;
 620     self.nextthink          = time;
 621     self.vehicle_health     = autocvar_g_vehicle_spiderbot_health;
 622     self.vehicle_shield     = autocvar_g_vehicle_spiderbot_shield;
 623     self.movetype           = MOVETYPE_WALK;
 624     self.solid              = SOLID_SLIDEBOX;
 625     self.alpha              = self.tur_head.alpha = self.gun1.alpha = self.gun2.alpha = 1;
 626     self.tur_head.angles    = '0 0 0';
 627
 628     setorigin(self, self.pos1 + '0 0 128');
 629     self.angles = self.pos2;
 630 }
 631
 632 void spiderbot_headfade()
 633 {
 634         self.think = spiderbot_headfade;
 635         self.nextthink = self.fade_time;
 636         self.alpha = 1 - (time - self.fade_time) * self.fade_rate;
 637
 638     if(self.cnt < time || self.alpha < 0.1)
 639     {
 640         if(self.alpha > 0.1)
 641         {
 642             sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 643             pointparticles(particleeffectnum("rocket_explode"), self.origin + '0 0 100', '0 0 0', 1);
 644         }
 645         remove(self);
 646     }
 647 }
 648
 649 void spiderbot_blowup()
 650 {
 651     float i;
 652     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 653
 654     for(i = 0; i < 5; ++i)
 655         pointparticles(particleeffectnum("rocket_explode"), self.origin + (randomvec() * 100) + '0 0 100', '0 0 0', 1);
 656
 657     entity h, g1, g2, b;
 658     b = spawn();
 659     h = spawn();
 660     g1 = spawn();
 661     g2 = spawn();
 662
 663     setmodel(b,  "models/vehicles/spiderbot.dpm");
 664     setmodel(h,  "models/vehicles/spiderbot_top.dpm");
 665     setmodel(g1, "models/vehicles/spiderbot_barrels.dpm");
 666     setmodel(g2, "models/vehicles/spiderbot_barrels.dpm");
 667
 668     setorigin(b, self.origin);
 669     setorigin(h, gettaginfo(self, gettagindex(self, "tag_head")));
 670     h.movetype      = MOVETYPE_BOUNCE;
 671     h.solid         = SOLID_BBOX;
 672     h.velocity      = v_up * (500 + random() * 500) + randomvec() * 128;
 673     h.modelflags    = MF_ROCKET;
 674     h.effects       = EF_FLAME | EF_LOWPRECISION;
 675     h.avelocity     = randomvec() * 360;
 676
 677     h.alpha         = 1;
 678     h.cnt           = time + (3.5 * random());
 679     h.fade_rate     = 1 / min(autocvar_g_vehicle_spiderbot_respawntime, 10);
 680     h.fade_time     = time;
 681     h.think         = spiderbot_headfade;
 682     h.nextthink     = time;
 683
 684     setorigin(g1, gettaginfo(self.tur_head, gettagindex(self.tur_head, "tag_hardpoint01")));
 685     g1.movetype     = MOVETYPE_TOSS;
 686     g1.solid        = SOLID_CORPSE;
 687     g1.velocity     = v_forward * 700 + (randomvec() * 32);
 688     g1.avelocity    = randomvec() * 180;
 689
 690     setorigin(g2, gettaginfo(self.tur_head, gettagindex(self.tur_head, "tag_hardpoint02")));
 691     g2.movetype     = MOVETYPE_TOSS;
 692     g2.solid        = SOLID_CORPSE;
 693     g2.velocity     = v_forward * 700 + (randomvec() * 32);
 694     g2.avelocity    = randomvec() * 180;
 695     b.frame         = 5;
 696
 697     h.colormod = b.colormod = g1.colormod = g2.colormod = '-2 -2 -2';
 698
 699     SUB_SetFade(b,  time, min(autocvar_g_vehicle_spiderbot_respawntime, 10));
 700     //SUB_SetFade(h,  time, min(autocvar_g_vehicle_spiderbot_respawntime, 10));
 701     SUB_SetFade(g1, time, min(autocvar_g_vehicle_spiderbot_respawntime, 10));
 702     SUB_SetFade(g2, time, min(autocvar_g_vehicle_spiderbot_respawntime, 10));
 703
 704     RadiusDamage (self, self, 250, 15, 250, world, 250, DEATH_SBBLOWUP, world);
 705
 706     self.alpha = self.tur_head.alpha = self.gun1.alpha = self.gun2.alpha = -1;
 707     self.movetype   = MOVETYPE_NONE;
 708     self.deadflag   = DEAD_DEAD;
 709     self.solid      = SOLID_NOT;
 710     self.tur_head.effects  &~=  EF_FLAME;
 711         self.vehicle_hudmodel.viewmodelforclient = self;
 712
 713     //self.nextthink  = time + autocvar_g_vehicle_spiderbot_respawntime;
 714     //self.think      = spiderbot_spawn;
 715
 716     //setorigin(self, self.tur_aimpos);
 717 }
 718
 719 void spiderbot_die()
 720 {
 721     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 722     pointparticles(particleeffectnum("rocket_explode"), self.origin + '0 0 100', '0 0 0', 1);
 723
 724     self.health         = 0;
 725     self.event_damage   = SUB_Null;
 726     self.takedamage     = DAMAGE_NO;
 727     self.touch          = SUB_Null;
 728     self.nextthink      = 1 + time + random() * 2;
 729     self.think          = spiderbot_blowup;
 730     self.deadflag       = DEAD_DYING;
 731         self.frame          = 5;
 732         self.tur_head.effects        |= EF_FLAME;
 733         self.colormod = self.tur_head.colormod = '-1 -1 -1';
 734
 735 }
 736
 737 void vewhicle_spiderbot_dinit()
 738 {
 739     if not (vehicle_initialize(
 740              "Spiderbot",
 741              "models/vehicles/spiderbot.dpm",
 742              "models/vehicles/spiderbot_top.dpm",
 743              "models/vehicles/spiderbot_cockpit.dpm",
 744              "tag_head", "tag_hud", "",
 745              HUD_SPIDERBOT,
 746              SPIDERBOT_MIN, SPIDERBOT_MAX,
 747              FALSE,
 748              spiderbot_spawn, autocvar_g_vehicle_spiderbot_respawntime,
 749              spiderbot_frame,
 750              spiderbot_enter, spiderbot_exit,
 751              spiderbot_die,   spiderbot_think))
 752     {
 753         remove(self);
 754         return;
 755     }
 756
 757     self.gun1               = spawn();
 758     self.gun2               = spawn();
 759
 760     setmodel(self.gun1, "models/vehicles/spiderbot_barrels.dpm");
 761     setmodel(self.gun2, "models/vehicles/spiderbot_barrels.dpm");
 762
 763     setattachment(self.gun1, self.tur_head, "tag_hardpoint01");
 764     setattachment(self.gun2, self.tur_head, "tag_hardpoint02");
 765
 766     self.gravity            = 2;
 767     self.mass               = 5000;
 768 }
 769
 770 void spawnfunc_vehicle_spiderbot()
 771 {
 772     precache_model ( "models/vhshield.md3");
 773     precache_model ( "models/vehicles/spiderbot.dpm");
 774     precache_model ( "models/vehicles/spiderbot_top.dpm");
 775     precache_model ( "models/vehicles/spiderbot_barrels.dpm");
 776     precache_model ( "models/vehicles/spiderbot_cockpit.dpm");
 777     precache_model ( "models/uziflash.md3");
 778
 779     precache_sound ( "weapons/rocket_impact.wav" );
 780     precache_sound ( "weapons/uzi_fire.wav" );
 781     precache_sound ( "weapons/rocket_impact.wav" );
 782
 783     vehicles_configcheck("vehicle_spiderbot.cfg", autocvar_g_vehicle_spiderbot_health);
 784     if(autocvar_g_vehicle_spiderbot_shield)
 785         self.vehicle_flags |= VHF_HASSHIELD;
 786
 787     if(autocvar_g_vehicle_spiderbot_shield_regen)
 788         self.vehicle_flags |= VHF_SHIELDREGEN;
 789
 790     if(autocvar_g_vehicle_spiderbot_health_regen)
 791         self.vehicle_flags |= VHF_HEALTHREGEN;
 792
 793     self.think = vewhicle_spiderbot_dinit;
 794     self.nextthink = time + 0.5;
 795 }