qcsrc/server/vehicles/vehicles.qc

   1 float autocvar_g_vehicles_crush_dmg;
   2 float autocvar_g_vehicles_crush_force;
   3
   4 void vehicles_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force);
   5 void vehicles_return();
   6 void vehicles_enter();
   7 void vehicles_touch();
   8 void vehicles_reset_colors();
   9 void vehicles_clearrturn();
  10 void vehicles_setreturn();
  11
  12
  13 #define MAX_AXH 4
  14 .entity AuxiliaryXhair[MAX_AXH];
  15
  16 float SendAuxiliaryXhair(entity to, float sf)
  17 {
  18
  19         WriteByte(MSG_ENTITY, ENT_CLIENT_AUXILIARYXHAIR);
  20
  21         WriteByte(MSG_ENTITY, self.cnt);
  22
  23         WriteCoord(MSG_ENTITY, self.origin_x);
  24         WriteCoord(MSG_ENTITY, self.origin_y);
  25         WriteCoord(MSG_ENTITY, self.origin_z);
  26
  27     WriteByte(MSG_ENTITY, rint(self.colormod_x * 255));
  28     WriteByte(MSG_ENTITY, rint(self.colormod_y * 255));
  29     WriteByte(MSG_ENTITY, rint(self.colormod_z * 255));
  30
  31     return TRUE;
  32 }
  33
  34 void UpdateAuxiliaryXhair(entity own, vector loc, vector clr, float axh_id)
  35 {
  36     entity axh;
  37
  38     axh_id = bound(0, axh_id, MAX_AXH);
  39     axh = own.AuxiliaryXhair[axh_id];
  40
  41     if(axh == world || wasfreed(axh))  // MADNESS? THIS IS QQQQCCCCCCCCC (wasfreed, why do you exsist?)
  42     {
  43         axh                     = spawn();
  44         axh.cnt                 = axh_id;
  45         axh.drawonlytoclient    = own;
  46         axh.owner               = own;
  47         Net_LinkEntity(axh, FALSE, 0, SendAuxiliaryXhair);
  48     }
  49
  50     setorigin(axh, loc);
  51     axh.colormod            = clr;
  52     axh.SendFlags           = 0x01;
  53     own.AuxiliaryXhair[axh_id] = axh;
  54 }
  55
  56 /*
  57 // SVC_TEMPENTITY based, horrible with even 50 ping. hm.
  58 // WriteByte(MSG_ONE, SVC_TEMPENTITY) uses reliable messagess, never use for thinsg that need continous updates.
  59 void SendAuxiliaryXhair2(entity own, vector loc, vector clr, float axh_id)
  60 {
  61         msg_entity = own;
  62
  63         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  64         WriteByte(MSG_ONE, TE_CSQC_AUXILIARYXHAIR);
  65
  66         WriteByte(MSG_ONE, axh_id);
  67
  68         WriteCoord(MSG_ONE, loc_x);
  69         WriteCoord(MSG_ONE, loc_y);
  70         WriteCoord(MSG_ONE, loc_z);
  71
  72     WriteByte(MSG_ONE, rint(clr_x * 255));
  73     WriteByte(MSG_ONE, rint(clr_y * 255));
  74     WriteByte(MSG_ONE, rint(clr_z * 255));
  75
  76 }
  77 */
  78
  79 void CSQCVehicleSetup(entity own, float vehicle_id)
  80 {
  81         msg_entity = own;
  82
  83         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  84         WriteByte(MSG_ONE, TE_CSQC_VEHICLESETUP);
  85         WriteByte(MSG_ONE, vehicle_id);
  86 }
  87
  88 .entity lock_target;
  89 .float  lock_strength;
  90 .float  lock_time;
  91 void vehicles_locktarget(float incr, float decr, float _lock_time)
  92 {
  93     if(self.lock_target && self.lock_target.deadflag != DEAD_NO)
  94     {
  95         self.lock_target    = world;
  96         self.lock_strength  = 0;
  97         self.lock_time      = 0;
  98     }
  99
 100     if(self.lock_time > time)
 101         return;
 102
 103     if(trace_ent != world)
 104     {
 105         if(teams_matter && trace_ent.team == self.team)
 106             trace_ent = world;
 107
 108         if(trace_ent.deadflag != DEAD_NO)
 109             trace_ent = world;
 110
 111         if not (trace_ent.vehicle_flags & VHF_ISVEHICLE || trace_ent.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 112             trace_ent = world;
 113     }
 114
 115     if(self.lock_target == world && trace_ent != world)
 116         self.lock_target = trace_ent;
 117
 118     // Have a locking target
 119     // Trace hit current target
 120     if(trace_ent == self.lock_target && trace_ent != world)
 121     {
 122         self.lock_strength = min(self.lock_strength + incr, 1);
 123         if(self.lock_strength == 1)
 124             self.lock_time = time + _lock_time;
 125     }
 126     else
 127     {
 128         if(trace_ent)
 129             self.lock_strength = max(self.lock_strength - decr * 2, 0);
 130         else
 131             self.lock_strength = max(self.lock_strength - decr, 0);
 132
 133         if(self.lock_strength == 0)
 134             self.lock_target = world;
 135     }
 136 }
 137
 138 #define VEHICLE_UPDATE_PLAYER(fld,vhname) \
 139 self.owner.vehicle_##fld = self.vehicle_##fld / autocvar_g_vehicle_##vhname##_##fld
 140
 141 #define vehicles_sweap_collision(orig,vel,dt,acm,mult) \
 142 traceline(orig, orig + vel * dt, MOVE_NORMAL, self); \
 143 if(trace_fraction != 1) \
 144     acm += normalize(self.origin - trace_endpos) * (vlen(vel) * mult)
 145
 146 float  force_fromtag_power;
 147 float  force_fromtag_normpower;
 148 vector force_fromtag_origin;
 149 vector vehicles_force_fromtag_hover(string tag_name, float spring_length, float max_power)
 150 {
 151     force_fromtag_origin = gettaginfo(self, gettagindex(self, tag_name));
 152     v_forward  = normalize(v_forward) * -1;
 153     traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, self);
 154
 155     force_fromtag_power = (1 - trace_fraction) * max_power;
 156     force_fromtag_normpower = force_fromtag_power / max_power;
 157
 158     return v_forward  * force_fromtag_power;
 159 }
 160
 161 vector vehicles_force_fromtag_maglev(string tag_name, float spring_length, float max_power)
 162 {
 163
 164     force_fromtag_origin = gettaginfo(self, gettagindex(self, tag_name));
 165     v_forward  = normalize(v_forward) * -1;
 166     traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, self);
 167
 168     if(trace_fraction == 1.0)
 169     {
 170         force_fromtag_normpower = -0.25;
 171         return '0 0 -200';
 172     }
 173
 174     force_fromtag_power = ((1 - trace_fraction) - trace_fraction) * max_power;
 175     force_fromtag_normpower = force_fromtag_power / max_power;
 176
 177     return v_forward  * force_fromtag_power;
 178 }
 179
 180 void vehicles_projectile_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 181 {
 182     self.health -= damage;
 183     self.velocity += force;
 184     if(self.health < 1)
 185     {
 186         self.takedamage = DAMAGE_NO;
 187         self.event_damage = SUB_Null;
 188         self.think = self.use;
 189         self.nextthink = time;
 190     }
 191
 192 }
 193
 194 void vehicles_projectile_explode()
 195 {
 196     if(self.owner && other != world)
 197     {
 198         if(other == self.owner.vehicle)
 199             return;
 200
 201         if(other == self.owner.vehicle.tur_head)
 202             return;
 203     }
 204
 205         PROJECTILE_TOUCH;
 206
 207         self.event_damage = SUB_Null;
 208     RadiusDamage (self, self.realowner, self.shot_dmg, 0, self.shot_radius, self, self.shot_force, self.totalfrags, other);
 209
 210     remove (self);
 211 }
 212
 213 entity vehicles_projectile(string _mzlfx, string _mzlsound,
 214                            vector _org, vector _vel,
 215                            float _dmg, float _radi, float _force,  float _size,
 216                            float _deahtype, float _projtype, float _health,
 217                            float _cull, float _clianim)
 218 {
 219     entity proj;
 220
 221     proj = spawn();
 222
 223     PROJECTILE_MAKETRIGGER(proj);
 224     setorigin(proj, _org);
 225
 226     proj.shot_dmg         = _dmg;
 227     proj.shot_radius      = _radi;
 228     proj.shot_force       = _force;
 229     proj.totalfrags       = _deahtype;
 230     proj.solid            = SOLID_BBOX;
 231     proj.movetype         = MOVETYPE_FLYMISSILE;
 232     proj.flags            = FL_PROJECTILE;
 233     proj.bot_dodge        = TRUE;
 234     proj.bot_dodgerating  = _dmg;
 235     proj.velocity         = _vel;
 236     proj.touch            = vehicles_projectile_explode;
 237     proj.use              = vehicles_projectile_explode;
 238     proj.owner            = self;
 239     proj.realowner        = self.owner;
 240     proj.think            = SUB_Remove;
 241     proj.nextthink        = time + 30;
 242
 243     if(_health)
 244     {
 245         proj.takedamage       = DAMAGE_AIM;
 246         proj.event_damage     = vehicles_projectile_damage;
 247         proj.health           = _health;
 248     }
 249     else
 250         proj.flags           = FL_PROJECTILE | FL_NOTARGET;
 251
 252     if(_mzlsound)
 253         sound (self, CHAN_WEAPON, _mzlsound, VOL_BASE, ATTN_NORM);
 254
 255     if(_mzlfx)
 256         pointparticles(particleeffectnum(_mzlfx), proj.origin, proj.velocity, 1);
 257
 258
 259     setsize (proj, '-1 -1 -1' * _size, '1 1 1' * _size);
 260
 261     CSQCProjectile(proj, _clianim, _projtype, _cull);
 262
 263     return proj;
 264 }
 265
 266 void vehicles_spawn()
 267 {
 268     dprint("Spawning vehicle: ", self.netname, "\n");
 269
 270     // De-own & reset
 271     self.vehicle_hudmodel.viewmodelforclient = self;
 272
 273     self.owner              = world;
 274     self.touch              = vehicles_touch;
 275     self.event_damage       = vehicles_damage;
 276     self.iscreature         = TRUE;
 277     self.movetype           = MOVETYPE_WALK;
 278     self.solid              = SOLID_SLIDEBOX;
 279     self.takedamage         = DAMAGE_AIM;
 280         self.deadflag           = DEAD_NO;
 281     self.bot_attack         = TRUE;
 282     self.flags              = FL_NOTARGET;
 283     self.avelocity          = '0 0 0';
 284
 285     // Reset locking
 286     self.lock_strength      = 0;
 287     self.lock_target        = world;
 288     self.misc_bulletcounter = 0;
 289
 290     // Return to spawn
 291     self.angles             = self.pos2;
 292     setorigin(self, self.pos1 + '0 0 128');
 293     // Show it
 294     pointparticles(particleeffectnum("teleport"), self.origin + '0 0 64', '0 0 0', 1);
 295
 296     vehicles_reset_colors();
 297     self.vehicle_spawn();
 298 }
 299
 300 // Better way of determening whats crushable needed! (fl_crushable?)
 301 float vehicles_crushable(entity e)
 302 {
 303     if(e.classname == "player")
 304         return TRUE;
 305
 306     if(e.classname == "monster_zombie")
 307         return TRUE;
 308
 309     return FALSE;
 310 }
 311
 312 void vehicles_touch()
 313 {
 314     // Vehicle currently in use
 315     if(self.owner)
 316     {
 317         // Colided with world?
 318         if(other == world)
 319         {
 320             // Apply velocity based self damage here
 321         }
 322         else
 323         {
 324             if(other.vehicle_flags & VHF_ISVEHICLE)
 325             {
 326                 //other.velocity += self.velocity * (self.mass / other.mass);
 327             }
 328             else if(vehicles_crushable(other))
 329             {
 330                 if(vlen(self.velocity) != 0)
 331                     Damage(other, self, self.owner, autocvar_g_vehicles_crush_dmg, DEATH_VHCRUSH, '0 0 0', normalize(other.origin - self.origin) * autocvar_g_vehicles_crush_force);
 332             }
 333         }
 334         return;
 335     }
 336
 337     if(other.classname != "player")
 338         return;
 339
 340     if(other.deadflag != DEAD_NO)
 341         return;
 342
 343     if(other.vehicle != world)
 344         return;
 345
 346     // Remove this when bots know how to use vehicles.
 347     if (clienttype(other) != CLIENTTYPE_REAL)
 348         return;
 349
 350     vehicles_enter();
 351 }
 352
 353 void vehicles_enter()
 354 {
 355    // Remove this when bots know how to use vehicles
 356     if (clienttype(other) != CLIENTTYPE_REAL)
 357         return;
 358
 359     if(self.phase > time)
 360         return;
 361
 362     if(teams_matter)
 363     if(self.team)
 364     if(self.team != other.team)
 365         return;
 366
 367     self.vehicle_ammo1   = 0;
 368     self.vehicle_ammo2   = 0;
 369     self.vehicle_reload1 = 0;
 370     self.vehicle_reload2 = 0;
 371     self.vehicle_energy  = 0;
 372
 373     self.owner          = other;
 374     self.switchweapon   = other.switchweapon;
 375
 376     // .viewmodelforclient works better.
 377     //self.vehicle_hudmodel.drawonlytoclient = self.owner;
 378
 379     self.vehicle_hudmodel.viewmodelforclient = self.owner;
 380
 381     self.event_damage         = vehicles_damage;
 382     self.nextthink            = 0;
 383     self.owner.angles         = self.angles;
 384     self.owner.takedamage     = DAMAGE_NO;
 385     self.owner.solid          = SOLID_NOT;
 386     self.owner.movetype       = MOVETYPE_NOCLIP;
 387     self.owner.alpha          = -1;
 388     self.owner.vehicle        = self;
 389     self.owner.event_damage   = SUB_Null;
 390     self.owner.view_ofs       = '0 0 0';
 391     self.colormap             = self.owner.colormap;
 392     if(self.tur_head)
 393         self.tur_head.colormap    = self.owner.colormap;
 394
 395     self.owner.hud            = self.hud;
 396     self.owner.PlayerPhysplug = self.PlayerPhysplug;
 397
 398     self.owner.vehicle_ammo1    = self.vehicle_ammo1;
 399     self.owner.vehicle_ammo2    = self.vehicle_ammo2;
 400     self.owner.vehicle_reload1  = self.vehicle_reload1;
 401     self.owner.vehicle_reload2  = self.vehicle_reload2;
 402
 403     // Cnnt do this, hides attached objects too.
 404     //self.exteriormodeltoclient = self.owner;
 405     //self.tur_head.exteriormodeltoclient = self.owner;
 406
 407     other.flags &~= FL_ONGROUND;
 408     self.flags  &~= FL_ONGROUND;
 409
 410     self.team                 = self.owner.team;
 411     self.flags               -= FL_NOTARGET;
 412
 413     msg_entity = other;
 414     WriteByte (MSG_ONE, SVC_SETVIEWPORT);
 415     WriteEntity(MSG_ONE, self.vehicle_viewport);
 416
 417     WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
 418     if(self.tur_head)
 419     {
 420         WriteAngle(MSG_ONE, self.tur_head.angles_x + self.angles_x); // tilt
 421         WriteAngle(MSG_ONE, self.tur_head.angles_y + self.angles_y); // yaw
 422         WriteAngle(MSG_ONE, 0);                                      // roll
 423     }
 424     else
 425     {
 426         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
 427         WriteAngle(MSG_ONE,  self.angles_x * -1); // tilt
 428         WriteAngle(MSG_ONE,  self.angles_y);      // yaw
 429         WriteAngle(MSG_ONE,  0);                  // roll
 430     }
 431
 432     vehicles_clearrturn();
 433
 434     CSQCVehicleSetup(self.owner, self.hud);
 435
 436     self.vehicle_enter();
 437 }
 438
 439 void vehicles_exit(float eject)
 440 {
 441         self.flags |= FL_NOTARGET;
 442
 443     if (self.owner)
 444     {
 445         msg_entity = self.owner;
 446         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
 447         WriteEntity( MSG_ONE, self.owner);
 448
 449         WriteByte (MSG_ONE, SVC_SETVIEWANGLES); // 10 = SVC_SETVIEWANGLES
 450         WriteAngle(MSG_ONE, 0);                 // tilt
 451         WriteAngle(MSG_ONE, self.angles_y);     // yaw
 452         WriteAngle(MSG_ONE, 0);                 // roll
 453
 454         setsize(self.owner, PL_MIN,PL_MAX);
 455
 456         self.owner.takedamage     = DAMAGE_AIM;
 457         self.owner.solid          = SOLID_SLIDEBOX;
 458         self.owner.movetype       = MOVETYPE_WALK;
 459         self.owner.effects        &~= EF_NODRAW;
 460         self.owner.alpha          = 1;
 461         self.owner.PlayerPhysplug = SUB_Null;
 462         self.owner.vehicle        = world;
 463         self.owner.view_ofs       = PL_VIEW_OFS;
 464         self.owner.event_damage   = PlayerDamage;
 465         self.owner.hud            = HUD_NORMAL;
 466         self.owner.switchweapon   = self.switchweapon;
 467         self.owner.BUTTON_USE     = 0;
 468     }
 469
 470     if(self.deadflag == DEAD_NO)
 471         self.avelocity          = '0 0 0';
 472
 473     self.vehicle_hudmodel.viewmodelforclient = self;
 474         self.tur_head.nodrawtoclient             = world;
 475     vehicles_setreturn();
 476
 477     self.phase = time + 1;
 478
 479     if(!teams_matter)
 480         self.team = 0;
 481
 482     self.vehicle_exit(eject);
 483     self.owner = world;
 484 }
 485
 486
 487 void vehicles_regen(.float timer, .float regen_field, float field_max, float rpause, float regen, float delta_time)
 488 {
 489     if(self.regen_field < field_max)
 490     if(self.timer + rpause < time)
 491     {
 492         self.regen_field = min(self.regen_field + regen * delta_time, field_max);
 493
 494         if(self.owner)
 495             self.owner.regen_field = self.regen_field / field_max;
 496     }
 497 }
 498
 499 void shieldhit_think()
 500 {
 501     self.alpha -= 0.1;
 502     if (self.alpha <= 0)
 503     {
 504         //setmodel(self, "");
 505         self.alpha = -1;
 506     }
 507     else
 508     {
 509         self.nextthink = time + 0.1;
 510     }
 511 }
 512
 513 void vehicles_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 514 {
 515     self.dmg_time = time;
 516
 517     if((self.vehicle_flags & VHF_HASSHIELD) && (self.vehicle_shield > 0))
 518     {
 519         if (wasfreed(self.vehicle_shieldent) || self.vehicle_shieldent == world)
 520         {
 521             self.vehicle_shieldent = spawn();
 522             self.vehicle_shieldent.effects = EF_LOWPRECISION;
 523
 524             setmodel(self.vehicle_shieldent, "models/vhshield.md3");
 525             setattachment(self.vehicle_shieldent, self, "");
 526             setorigin(self.vehicle_shieldent, real_origin(self) - self.origin);
 527             self.vehicle_shieldent.scale       = 256 / vlen(self.maxs - self.mins);
 528             self.vehicle_shieldent.think       = shieldhit_think;
 529         }
 530
 531
 532         self.vehicle_shieldent.colormod    = '1 1 1';
 533         self.vehicle_shieldent.alpha       = 0.45;
 534         self.vehicle_shieldent.angles      = vectoangles(normalize(hitloc - (self.origin + self.vehicle_shieldent.origin))) - self.angles;
 535         self.vehicle_shieldent.nextthink   = time;
 536
 537         self.vehicle_shield -= damage;
 538
 539         if(self.vehicle_shield < 0)
 540         {
 541             self.vehicle_shieldent.colormod = '2 0 0';
 542             self.vehicle_shield             = 0;
 543             self.vehicle_shieldent.alpha    = 0.75;
 544             self.vehicle_health            -= fabs(self.vehicle_shield);
 545         }
 546     }
 547     else
 548         self.vehicle_health -= damage;
 549
 550     self.velocity += force; // * (vlen(force) / self.mass);
 551
 552     if(self.vehicle_health <= 0)
 553     {
 554         if(self.owner)
 555             if(self.vehicle_flags & VHF_DEATHEJECT)
 556                 vehicles_exit(VHEF_EJECT);
 557             else
 558                 vehicles_exit(VHEF_RELESE);
 559
 560         self.vehicle_die();
 561         vehicles_setreturn();
 562     }
 563 }
 564
 565 void vehicles_return()
 566 {
 567     pointparticles(particleeffectnum("teleport"), self.enemy.origin + '0 0 64', '0 0 0', 1);
 568
 569     self.enemy.think     = vehicles_spawn;
 570     self.enemy.nextthink = time;
 571
 572     remove(self);
 573 }
 574
 575 void vehicles_clearrturn()
 576 {
 577     entity ret;
 578     // Remove "return helper", if any.
 579     ret = findchain(classname, "vehicle_return");
 580     while(ret)
 581     {
 582         if(ret.enemy == self)
 583         {
 584             ret.classname   = "";
 585             ret.think       = SUB_Remove;
 586             ret.nextthink   = time + 0.1;
 587             return;
 588         }
 589
 590         ret = ret.chain;
 591     }
 592 }
 593
 594 void vehicles_setreturn()
 595 {
 596     entity ret;
 597
 598     vehicles_clearrturn();
 599
 600     ret = spawn();
 601     ret.classname   = "vehicle_return";
 602     ret.enemy       = self;
 603     ret.think       = vehicles_return;
 604     ret.nextthink   = time + self.vehicle_respawntime;
 605 }
 606
 607 float vehicles_customizeentityforclient()
 608 {
 609     if(self.deadflag  == DEAD_DEAD)
 610         return FALSE;
 611     else
 612         return TRUE;
 613 }
 614
 615 void vehicles_configcheck(string  configname, float check_cvar)
 616 {
 617     if(check_cvar == 0)
 618         localcmd(strcat("exec ", configname, "\n"));
 619 }
 620
 621 void vehicles_reset_colors()
 622 {
 623     entity e;
 624     float _effects, _colormap;
 625     vector _glowmod, _colormod;
 626
 627     if(autocvar_g_nodepthtestplayers)
 628         _effects = EF_NODEPTHTEST;
 629
 630     if(autocvar_g_fullbrightplayers)
 631         _effects |= EF_FULLBRIGHT;
 632
 633     if(self.team)
 634         _colormap = 1024 + (self.team - 1) * 17;
 635     else
 636         _colormap = 1024;
 637
 638     _glowmod    = '0 0 0';
 639     _colormod   = '0 0 0';
 640
 641     // Find all ents attacked to main model and setup effects, colormod etc.
 642     e = findchainentity(tag_entity, self);
 643     while(e)
 644     {
 645         if(e != self.vehicle_shieldent)
 646         {
 647             e.effects   = _effects  | EF_LOWPRECISION;
 648             e.colormod  = _colormod;
 649             e.colormap  = _colormap;
 650             e.alpha     = 1;
 651         }
 652         e = e.chain;
 653     }
 654
 655     self.vehicle_hudmodel.effects  = self.effects  = _effects | EF_LOWPRECISION;
 656     self.vehicle_hudmodel.colormod = self.colormod = _colormod;
 657     self.vehicle_hudmodel.colormap = self.colormap = _colormap;
 658     self.vehicle_viewport.effects = (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NOGUNBOB | EF_NOSHADOW | EF_LOWPRECISION | EF_SELECTABLE | EF_TELEPORT_BIT);
 659
 660     self.alpha          = 1;
 661     self.avelocity      = '0 0 0';
 662     self.velocity       = '0 0 0';
 663     self.effects        = _effects;
 664 }
 665
 666 //#define VEHICLES_CSQC
 667 #ifdef VEHICLES_CSQC
 668 #define VSF_ORG 2
 669 #define VSF_VEL 4
 670 #define VSF_ANG 8
 671 #define VSF_COLORMAP 16
 672 #define VSF_STAT1 32
 673
 674 float SendVehicle(entity to, float sf)
 675 {
 676         WriteByte(MSG_ENTITY, ENT_CLIENT_VEHICLE_RACER);
 677
 678         WriteByte(MSG_ENTITY, self.cnt);
 679
 680         WriteCoord(MSG_ENTITY, self.origin_x);
 681         WriteCoord(MSG_ENTITY, self.origin_y);
 682         WriteCoord(MSG_ENTITY, self.origin_z);
 683
 684         WriteCoord(MSG_ENTITY, self.velocity_x);
 685         WriteCoord(MSG_ENTITY, self.velocity_y);
 686         WriteCoord(MSG_ENTITY, self.velocity_z);
 687
 688         WriteAngle(MSG_ENTITY, self.angles_x);
 689         WriteAngle(MSG_ENTITY, self.angles_y);
 690         WriteAngle(MSG_ENTITY, self.angles_z);
 691
 692     return TRUE;
 693 }
 694
 695 void NetLinkVehicle()
 696 {
 697     self.SendFlags = 0xFFFFFF;
 698     Net_LinkEntity(self, FALSE, 0, SendVehicle);
 699 }
 700 #endif
 701
 702 float vehicle_initialize(string  net_name,
 703                          string  bodymodel,
 704                          string  topmodel,
 705                          string  hudmodel,
 706                          string  toptag,
 707                          string  hudtag,
 708                          string  viewtag,
 709                          float   vhud,
 710                          vector min_s,
 711                          vector max_s,
 712                          float  nodrop,
 713                          void()  spawnproc,
 714                          float   _respawntime,
 715                          float() physproc,
 716                          void()  enterproc,
 717                          void(float extflag) exitfunc,
 718                          void() dieproc,
 719                          void() thinkproc )
 720 {
 721     addstat(STAT_HUD, AS_INT,  hud);
 722         addstat(STAT_VEHICLESTAT_HEALTH,  AS_FLOAT, vehicle_health);
 723         addstat(STAT_VEHICLESTAT_SHIELD,  AS_FLOAT, vehicle_shield);
 724         addstat(STAT_VEHICLESTAT_ENERGY,  AS_FLOAT, vehicle_energy);
 725
 726         addstat(STAT_VEHICLESTAT_AMMO1,   AS_INT,   vehicle_ammo1);
 727         addstat(STAT_VEHICLESTAT_RELOAD1, AS_FLOAT, vehicle_reload1);
 728
 729         addstat(STAT_VEHICLESTAT_AMMO2,   AS_INT,   vehicle_ammo2);
 730         addstat(STAT_VEHICLESTAT_RELOAD2, AS_FLOAT, vehicle_reload2);
 731
 732     if(bodymodel == "")
 733         error("vehicles: missing bodymodel!");
 734
 735     if(hudmodel == "")
 736         error("vehicles: missing hudmodel!");
 737
 738     if(net_name == "")
 739         self.netname = self.classname;
 740     else
 741         self.netname = net_name;
 742
 743     if(self.team && !teams_matter)
 744         self.team = 0;
 745
 746     self.vehicle_flags |= VHF_ISVEHICLE;
 747
 748     setmodel(self, bodymodel);
 749
 750     self.vehicle_viewport   = spawn();
 751     self.vehicle_hudmodel   = spawn();
 752     self.tur_head           = spawn();
 753     self.tur_head.owner     = self;
 754     self.takedamage         = DAMAGE_AIM;
 755     self.bot_attack         = TRUE;
 756     self.iscreature         = TRUE;
 757     self.hud                = vhud;
 758
 759     //self.customizeentityforclient = vehicles_customizeentityforclient;
 760     self.vehicle_die         = dieproc;
 761     self.vehicle_exit        = exitfunc;
 762     self.vehicle_enter       = enterproc;
 763     self.PlayerPhysplug      = physproc;
 764     self.event_damage        = vehicles_damage;
 765     self.touch               = vehicles_touch;
 766     self.think               = vehicles_spawn;
 767     self.nextthink           = time;
 768     self.vehicle_respawntime = _respawntime;
 769     self.vehicle_spawn       = spawnproc;
 770
 771     if(autocvar_g_nodepthtestplayers)
 772         self.effects = self.effects | EF_NODEPTHTEST;
 773
 774     if(autocvar_g_fullbrightplayers)
 775         self.effects = self.effects | EF_FULLBRIGHT;
 776
 777     setmodel(self.vehicle_hudmodel, hudmodel);
 778     setmodel(self.vehicle_viewport, "null");
 779
 780
 781     if(topmodel != "")
 782     {
 783         setmodel(self.tur_head, topmodel);
 784         setattachment(self.tur_head, self, toptag);
 785         setattachment(self.vehicle_hudmodel, self.tur_head, hudtag);
 786         setattachment(self.vehicle_viewport, self.vehicle_hudmodel, viewtag);
 787     }
 788     else
 789     {
 790         setattachment(self.tur_head, self, "");
 791         setattachment(self.vehicle_hudmodel, self, hudtag);
 792         setattachment(self.vehicle_viewport, self.vehicle_hudmodel, viewtag);
 793     }
 794
 795     setsize(self, min_s, max_s);
 796     if not (nodrop)
 797     {
 798         setorigin(self, self.origin);
 799         tracebox(self.origin + '0 0 100', min_s, max_s, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
 800         setorigin(self, trace_endpos);
 801     }
 802
 803     //self.vehicle_hudmodel.effects = EF_NODEPTHTEST;
 804     self.pos1 = self.origin;
 805     self.pos2 = self.angles;
 806
 807     return TRUE;
 808 }
 809
 810
 811 void bugmenot()
 812 {
 813     self.vehicle_exit       = self.vehicle_exit;
 814     self.vehicle_enter      = self.vehicle_exit;
 815     self.vehicle_die        = self.vehicle_exit;
 816     self.vehicle_spawn      = self.vehicle_exit;
 817     self.AuxiliaryXhair     = self.AuxiliaryXhair;
 818 }