qcsrc/server/vehicles/vehicles.qc

   1 float autocvar_g_vehicles_crush_dmg;
   2 float autocvar_g_vehicles_crush_force;
   3 float autocvar_g_vehicles_delayspawn;
   4 float autocvar_g_vehicles_delayspawn_jitter;
   5
   6 var float autocvar_g_vehicles_nex_damagerate = 0.5;
   7 var float autocvar_g_vehicles_uzi_damagerate = 0.5;
   8 var float autocvar_g_vehicles_rifle_damagerate = 0.75;
   9 var float autocvar_g_vehicles_minstanex_damagerate = 0.001;
  10 var float autocvar_g_vehicles_tag_damagerate = 5;
  11
  12 float autocvar_g_vehicles;
  13
  14 void vehicles_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force);
  15 void vehicles_return();
  16 void vehicles_enter();
  17 void vehicles_touch();
  18 void vehicles_reset_colors();
  19 void vehicles_clearrturn();
  20 void vehicles_setreturn();
  21
  22
  23 /** AuxiliaryXhair*
  24     Send additional points of interest to be drawn, to vehicle owner
  25 **/
  26 float MAX_AXH = 4;
  27 .entity AuxiliaryXhair[MAX_AXH];
  28
  29 float SendAuxiliaryXhair(entity to, float sf)
  30 {
  31
  32         WriteByte(MSG_ENTITY, ENT_CLIENT_AUXILIARYXHAIR);
  33
  34         WriteByte(MSG_ENTITY, self.cnt);
  35
  36         WriteCoord(MSG_ENTITY, self.origin_x);
  37         WriteCoord(MSG_ENTITY, self.origin_y);
  38         WriteCoord(MSG_ENTITY, self.origin_z);
  39
  40     WriteByte(MSG_ENTITY, rint(self.colormod_x * 255));
  41     WriteByte(MSG_ENTITY, rint(self.colormod_y * 255));
  42     WriteByte(MSG_ENTITY, rint(self.colormod_z * 255));
  43
  44     return TRUE;
  45 }
  46
  47 void UpdateAuxiliaryXhair(entity own, vector loc, vector clr, float axh_id)
  48 {
  49     if (clienttype(own) != CLIENTTYPE_REAL)
  50         return;
  51
  52     entity axh;
  53
  54     axh_id = bound(0, axh_id, MAX_AXH);
  55     axh = own.(AuxiliaryXhair[axh_id]);
  56
  57     if(axh == world || wasfreed(axh))  // MADNESS? THIS IS QQQQCCCCCCCCC (wasfreed, why do you exsist?)
  58     {
  59         axh                     = spawn();
  60         axh.cnt                 = axh_id;
  61         axh.drawonlytoclient    = own;
  62         axh.owner               = own;
  63         Net_LinkEntity(axh, FALSE, 0, SendAuxiliaryXhair);
  64     }
  65
  66     setorigin(axh, loc);
  67     axh.colormod            = clr;
  68     axh.SendFlags           = 0x01;
  69     own.(AuxiliaryXhair[axh_id]) = axh;
  70 }
  71
  72 /*
  73 // SVC_TEMPENTITY based, horrible with even 50 ping. hm.
  74 // WriteByte(MSG_ONE, SVC_TEMPENTITY) uses reliable messagess, never use for thinsg that need continous updates.
  75 void SendAuxiliaryXhair2(entity own, vector loc, vector clr, float axh_id)
  76 {
  77         msgexntity = own;
  78
  79         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  80         WriteByte(MSG_ONE, TE_CSQC_AUXILIARYXHAIR);
  81
  82         WriteByte(MSG_ONE, axh_id);
  83
  84         WriteCoord(MSG_ONE, loc_x);
  85         WriteCoord(MSG_ONE, loc_y);
  86         WriteCoord(MSG_ONE, loc_z);
  87
  88     WriteByte(MSG_ONE, rint(clr_x * 255));
  89     WriteByte(MSG_ONE, rint(clr_y * 255));
  90     WriteByte(MSG_ONE, rint(clr_z * 255));
  91
  92 }
  93 */
  94 // End AuxiliaryXhair
  95
  96 /**
  97     Notifies the client that he enterd a vehicle, and sends
  98     realavent data.
  99
 100     only sends vehicle_id atm (wich is a HUD_* constant, ex. HUD_SPIDERBOT)
 101 **/
 102 void CSQCVehicleSetup(entity own, float vehicle_id)
 103 {
 104     if (clienttype(own) != CLIENTTYPE_REAL)
 105         return;
 106
 107         msg_entity = own;
 108
 109         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 110         WriteByte(MSG_ONE, TE_CSQC_VEHICLESETUP);
 111         if(vehicle_id != 0)
 112             WriteByte(MSG_ONE, vehicle_id);
 113         else
 114         WriteByte(MSG_ONE, 1 + own.vehicle.vehicle_weapon2mode + HUD_VEHICLE_LAST);
 115 }
 116
 117 /** vehicles_locktarget
 118
 119     Generic target locking.
 120
 121     Figure out if what target is "locked" (if any), for missile tracking as such.
 122
 123     after calling, "if(self.lock_target != world && self.lock_strength == 1)" mean
 124     you have a locked in target.
 125
 126     Exspects a crosshair_trace() or equivalent to be
 127     dont before calling.
 128
 129 **/
 130 .entity lock_target;
 131 .float  lock_strength;
 132 .float  lock_time;
 133 .float  lock_soundtime;
 134 float   DAMAGE_TARGETDRONE = 10;
 135
 136 vector targetdrone_getnewspot()
 137 {
 138
 139         vector spot;
 140         float i;
 141         for(i = 0; i < 100; ++i)
 142         {
 143                 spot = self.origin + randomvec() * 1024;
 144                 tracebox(spot, self.mins, self.maxs, spot, MOVE_NORMAL, self);
 145                 if(trace_fraction == 1.0 && trace_startsolid == 0 && trace_allsolid == 0)
 146                         return spot;
 147         }
 148         return self.origin;
 149 }
 150
 151 #if 0
 152 void targetdrone_think();
 153 void targetdrone_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force);
 154 void targetdrone_renwe()
 155 {
 156         self.think = targetdrone_think;
 157         self.nextthink = time + 0.1;
 158         setorigin(self, targetdrone_getnewspot());
 159         self.health = 200;
 160         self.takedamage = DAMAGE_TARGETDRONE;
 161         self.event_damage = targetdrone_damage;
 162         self.solid = SOLID_BBOX;
 163         setmodel(self, "models/runematch/rune.mdl");
 164         self.effects = EF_LOWPRECISION;
 165         self.scale = 10;
 166         self.movetype = MOVETYPE_BOUNCEMISSILE;
 167         setsize(self, '-100 -100 -100', '100 100 100');
 168
 169 }
 170 void targetdrone_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 171 {
 172         self.health -= damage;
 173         if(self.health <= 0)
 174         {
 175                 pointparticles(particleeffectnum("explosion_medium"), self.origin, '0 0 0', 1);
 176
 177                 if(!self.cnt)
 178                         remove(self);
 179                 else
 180                 {
 181                         self.think = targetdrone_renwe;
 182                         self.nextthink = time + 1 + random() * 2;
 183                         self.solid = SOLID_NOT;
 184                         setmodel(self, "");
 185                 }
 186         }
 187 }
 188 entity targetdrone_getfear()
 189 {
 190         entity fear;
 191         float i;
 192
 193         for(i = 64; i <= 1024; i += 64)
 194         {
 195                 fear = findradius(self.origin, i);
 196                 while(fear)
 197                 {
 198                         if(fear.bot_dodge)
 199                                 return fear;
 200
 201                         fear = fear.chain;
 202                 }
 203         }
 204
 205         return world;
 206 }
 207 void targetdrone_think()
 208 {
 209         self.nextthink = time + 0.1;
 210
 211         if(self.wp00)
 212         if(self.wp00.deadflag != DEAD_NO)
 213                 self.wp00 = targetdrone_getfear();
 214
 215         if(!self.wp00)
 216                 self.wp00 = targetdrone_getfear();
 217
 218         vector newdir;
 219
 220         if(self.wp00)
 221                 newdir = steerlib_push(self.wp00.origin) + randomvec() * 0.75;
 222         else
 223                 newdir = randomvec() * 0.75;
 224
 225         newdir = newdir * 0.5 + normalize(self.velocity) * 0.5;
 226
 227         if(self.wp00)
 228                 self.velocity = normalize(newdir) * (500 + (1024 / min(vlen(self.wp00.origin - self.origin), 1024)) * 700);
 229         else
 230                 self.velocity = normalize(newdir) * 750;
 231
 232         tracebox(self.origin, self.mins, self.maxs, self.origin + self.velocity * 2, MOVE_NORMAL, self);
 233         if(trace_fraction != 1.0)
 234                 self.velocity = self.velocity * -1;
 235
 236         //normalize((normalize(self.velocity) * 0.5 + newdir * 0.5)) * 750;
 237 }
 238
 239 void targetdrone_spawn(vector _where, float _autorenew)
 240 {
 241         entity drone = spawn();
 242         setorigin(drone, _where);
 243         drone.think = targetdrone_renwe;
 244         drone.nextthink = time + 0.1;
 245         drone.cnt = _autorenew;
 246 }
 247 #endif
 248
 249 void vehicles_locktarget(float incr, float decr, float _lock_time)
 250 {
 251     if(self.lock_target && self.lock_target.deadflag != DEAD_NO)
 252     {
 253         self.lock_target    = world;
 254         self.lock_strength  = 0;
 255         self.lock_time      = 0;
 256     }
 257
 258     if(self.lock_time > time)
 259     {
 260         if(self.lock_target)
 261         if(self.lock_soundtime < time)
 262         {
 263             self.lock_soundtime = time + 0.5;
 264             play2(self.owner, "vehicles/locked.wav");
 265         }
 266
 267         return;
 268     }
 269
 270     if(trace_ent != world)
 271     {
 272         if(teamplay && trace_ent.team == self.team)
 273             trace_ent = world;
 274
 275         if(trace_ent.deadflag != DEAD_NO)
 276             trace_ent = world;
 277
 278         if not (trace_ent.vehicle_flags & VHF_ISVEHICLE ||
 279                                 trace_ent.turrcaps_flags & TFL_TURRCAPS_ISTURRET ||
 280                                 trace_ent.takedamage == DAMAGE_TARGETDRONE)
 281             trace_ent = world;
 282     }
 283
 284     if(self.lock_target == world && trace_ent != world)
 285         self.lock_target = trace_ent;
 286
 287     if(self.lock_target && trace_ent == self.lock_target)
 288     {
 289         if(self.lock_strength != 1 && self.lock_strength + incr >= 1)
 290         {
 291             play2(self.owner, "vehicles/lock.wav");
 292             self.lock_soundtime = time + 0.8;
 293         }
 294         else if (self.lock_strength != 1 && self.lock_soundtime < time)
 295         {
 296             play2(self.owner, "vehicles/locking.wav");
 297             self.lock_soundtime = time + 0.3;
 298         }
 299
 300     }
 301
 302     // Have a locking target
 303     // Trace hit current target
 304     if(trace_ent == self.lock_target && trace_ent != world)
 305     {
 306         self.lock_strength = min(self.lock_strength + incr, 1);
 307         if(self.lock_strength == 1)
 308             self.lock_time = time + _lock_time;
 309     }
 310     else
 311     {
 312         if(trace_ent)
 313             self.lock_strength = max(self.lock_strength - decr * 2, 0);
 314         else
 315             self.lock_strength = max(self.lock_strength - decr, 0);
 316
 317         if(self.lock_strength == 0)
 318             self.lock_target = world;
 319     }
 320 }
 321
 322 #define VEHICLE_UPDATE_PLAYER(ply,fld,vhname) \
 323 ply.vehicle_##fld = (self.vehicle_##fld / autocvar_g_vehicle_##vhname##_##fld) * 100
 324
 325 #define vehicles_sweap_collision(orig,vel,dt,acm,mult) \
 326 traceline(orig, orig + vel * dt, MOVE_NORMAL, self); \
 327 if(trace_fraction != 1) \
 328     acm += normalize(self.origin - trace_endpos) * (vlen(vel) * mult)
 329
 330 // Hover movement support
 331 float  force_fromtag_power;
 332 float  force_fromtag_normpower;
 333 vector force_fromtag_origin;
 334 vector vehicles_force_fromtag_hover(string tag_name, float spring_length, float max_power)
 335 {
 336     force_fromtag_origin = gettaginfo(self, gettagindex(self, tag_name));
 337     v_forward  = normalize(v_forward) * -1;
 338     traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, self);
 339
 340     force_fromtag_power = (1 - trace_fraction) * max_power;
 341     force_fromtag_normpower = force_fromtag_power / max_power;
 342
 343     return v_forward  * force_fromtag_power;
 344 }
 345
 346 // Experimental hovermode wich uses attraction/repulstion from surface insted of gravity/repulsion
 347 // Can possibly be use to move abt any surface (inclusing walls/celings)
 348 vector vehicles_force_fromtag_maglev(string tag_name, float spring_length, float max_power)
 349 {
 350
 351     force_fromtag_origin = gettaginfo(self, gettagindex(self, tag_name));
 352     v_forward  = normalize(v_forward) * -1;
 353     traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, self);
 354
 355     // TODO - this may NOT be compatible with wall/celing movement, unhardcode 0.25 (engine count multiplier)
 356     if(trace_fraction == 1.0)
 357     {
 358         force_fromtag_normpower = -0.25;
 359         return '0 0 -200';
 360     }
 361
 362     force_fromtag_power = ((1 - trace_fraction) - trace_fraction) * max_power;
 363     force_fromtag_normpower = force_fromtag_power / max_power;
 364
 365     return v_forward  * force_fromtag_power;
 366 }
 367
 368 // Generic vehile projectile system
 369 void vehicles_projectile_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 370 {
 371     // Ignore damage from oterh projectiles from my owner (dont mess up volly's)
 372     if(inflictor.owner == self.owner)
 373         return;
 374
 375     self.health -= damage;
 376     self.velocity += force;
 377     if(self.health < 1)
 378     {
 379         self.takedamage = DAMAGE_NO;
 380         self.event_damage = func_null;
 381         self.think = self.use;
 382         self.nextthink = time;
 383     }
 384 }
 385
 386 void vehicles_projectile_explode()
 387 {
 388     if(self.owner && other != world)
 389     {
 390         if(other == self.owner.vehicle)
 391             return;
 392
 393         if(other == self.owner.vehicle.tur_head)
 394             return;
 395     }
 396
 397         PROJECTILE_TOUCH;
 398
 399         self.event_damage = func_null;
 400     RadiusDamage (self, self.realowner, self.shot_dmg, 0, self.shot_radius, self, self.shot_force, self.totalfrags, other);
 401
 402     remove (self);
 403 }
 404
 405 entity vehicles_projectile(string _mzlfx, string _mzlsound,
 406                            vector _org, vector _vel,
 407                            float _dmg, float _radi, float _force,  float _size,
 408                            float _deahtype, float _projtype, float _health,
 409                            float _cull, float _clianim, entity _owner)
 410 {
 411     entity proj;
 412
 413     print(sprintf("2: %i\n", _owner));
 414
 415     proj = spawn();
 416
 417     PROJECTILE_MAKETRIGGER(proj);
 418     setorigin(proj, _org);
 419
 420     proj.shot_dmg         = _dmg;
 421     proj.shot_radius      = _radi;
 422     proj.shot_force       = _force;
 423     proj.totalfrags       = _deahtype;
 424     proj.solid            = SOLID_BBOX;
 425     proj.movetype         = MOVETYPE_FLYMISSILE;
 426     proj.flags            = FL_PROJECTILE;
 427     proj.bot_dodge        = TRUE;
 428     proj.bot_dodgerating  = _dmg;
 429     proj.velocity         = _vel;
 430     proj.touch            = vehicles_projectile_explode;
 431     proj.use              = vehicles_projectile_explode;
 432     proj.owner            = self;
 433     proj.realowner        = _owner;
 434     proj.think            = SUB_Remove;
 435     proj.nextthink        = time + 30;
 436
 437     if(_health)
 438     {
 439         proj.takedamage       = DAMAGE_AIM;
 440         proj.event_damage     = vehicles_projectile_damage;
 441         proj.health           = _health;
 442     }
 443     else
 444         proj.flags           = FL_PROJECTILE | FL_NOTARGET;
 445
 446     if(_mzlsound)
 447         sound (self, CH_WEAPON_A, _mzlsound, VOL_BASE, ATTN_NORM);
 448
 449     if(_mzlfx)
 450         pointparticles(particleeffectnum(_mzlfx), proj.origin, proj.velocity, 1);
 451
 452
 453     setsize (proj, '-1 -1 -1' * _size, '1 1 1' * _size);
 454
 455     print(sprintf("3: %i\n", proj));
 456     print(sprintf("4: %i\n", proj.enemy));
 457     print(sprintf("5: %i\n", proj.owner));
 458     print(sprintf("6: %i\n", proj.realowner));
 459     CSQCProjectile(proj, _clianim, _projtype, _cull);
 460
 461     return proj;
 462 }
 463 // End generic vehile projectile system
 464
 465 /** vehicles_spawn
 466     Exetuted for all vehicles on (re)spawn.
 467     Sets defaults for newly spawned units.
 468 **/
 469 void vehicles_spawn()
 470 {
 471     dprint("Spawning vehicle: ", self.netname, "\n");
 472
 473     // De-own & reset
 474     self.vehicle_hudmodel.viewmodelforclient = self;
 475
 476     self.owner              = world;
 477     self.touch              = vehicles_touch;
 478     self.event_damage       = vehicles_damage;
 479     self.iscreature         = TRUE;
 480     self.teleportable       = FALSE; // no teleporting for vehicles, too buggy
 481     self.damagedbycontents      = TRUE;
 482     self.movetype           = MOVETYPE_WALK;
 483     self.solid              = SOLID_SLIDEBOX;
 484     self.takedamage         = DAMAGE_AIM;
 485         self.deadflag           = DEAD_NO;
 486     self.bot_attack         = TRUE;
 487     self.flags              = FL_NOTARGET;
 488     self.avelocity          = '0 0 0';
 489     self.velocity           = '0 0 0';
 490
 491     // Reset locking
 492     self.lock_strength      = 0;
 493     self.lock_target        = world;
 494     self.misc_bulletcounter = 0;
 495
 496     // Return to spawn
 497     self.angles             = self.pos2;
 498     setorigin(self, self.pos1 + '0 0 0');
 499     // Show it
 500     pointparticles(particleeffectnum("teleport"), self.origin + '0 0 64', '0 0 0', 1);
 501
 502     if(self.vehicle_controller)
 503         self.team = self.vehicle_controller.team;
 504
 505     vehicles_reset_colors();
 506     self.vehicle_spawn(VHSF_NORMAL);
 507 }
 508
 509 // Better way of determening whats crushable needed! (fl_crushable?)
 510 float vehicles_crushable(entity e)
 511 {
 512     if(e.classname == "player")
 513         return TRUE;
 514
 515     if(e.classname == "monster_zombie")
 516         return TRUE;
 517
 518     return FALSE;
 519 }
 520
 521 void vehilces_impact(float _minspeed, float _speedfac, float _maxpain)
 522 {
 523     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 524         return;
 525
 526     if(self.play_time < time)
 527     {
 528         float wc = vlen(self.velocity - self.oldvelocity);
 529         //dprint("oldvel: ", vtos(self.oldvelocity), "\n");
 530         //dprint("vel: ", vtos(self.velocity), "\n");
 531         if(_minspeed < wc)
 532         {
 533             float take = min(_speedfac * wc, _maxpain);
 534             Damage (self, world, world, take, DEATH_FALL, self.origin, '0 0 0');
 535             self.play_time = time + 0.25;
 536
 537             //dprint("wc: ", ftos(wc), "\n");
 538             //dprint("take: ", ftos(take), "\n");
 539         }
 540     }
 541 }
 542
 543 .void() vehicle_impact;
 544 void vehicles_touch()
 545 {
 546     // Vehicle currently in use
 547     if(self.owner)
 548     {
 549         if(other != world)
 550         if(vehicles_crushable(other))
 551         {
 552             if(vlen(self.velocity) != 0)
 553                 Damage(other, self, self.owner, autocvar_g_vehicles_crush_dmg, DEATH_VHCRUSH, '0 0 0', normalize(other.origin - self.origin) * autocvar_g_vehicles_crush_force);
 554
 555             return; // Dont do selfdamage when hitting "soft targets".
 556         }
 557
 558         if(self.play_time < time)
 559         if(self.vehicle_impact)
 560             self.vehicle_impact();
 561
 562         return;
 563     }
 564
 565     if(other.classname != "player")
 566         return;
 567
 568     if(other.deadflag != DEAD_NO)
 569         return;
 570
 571     if(other.vehicle != world)
 572         return;
 573
 574     vehicles_enter();
 575 }
 576 var float autocvar_g_vehicles_allow_bots = 0;
 577 void vehicles_enter()
 578 {
 579    // Remove this when bots know how to use vehicles
 580
 581     if (clienttype(other) == CLIENTTYPE_BOT)
 582         if (autocvar_g_vehicles_allow_bots)
 583             dprint("Bot enters vehicle\n"); // This is where we need to disconnect (some, all?) normal bot AI and hand over to vehicle's _aiframe()
 584         else
 585             return;
 586
 587     if(self.phase > time)
 588         return;
 589
 590     if(teamplay)
 591     if(self.team)
 592     if(self.team != other.team)
 593         return;
 594
 595     RemoveGrapplingHook(other);
 596
 597     self.vehicle_ammo1   = 0;
 598     self.vehicle_ammo2   = 0;
 599     self.vehicle_reload1 = 0;
 600     self.vehicle_reload2 = 0;
 601     self.vehicle_energy  = 0;
 602
 603     self.owner          = other;
 604     self.switchweapon   = other.switchweapon;
 605
 606     // .viewmodelforclient works better.
 607     //self.vehicle_hudmodel.drawonlytoclient = self.owner;
 608
 609     self.vehicle_hudmodel.viewmodelforclient = self.owner;
 610
 611     self.event_damage         = vehicles_damage;
 612     self.nextthink            = 0;
 613     self.owner.angles         = self.angles;
 614     self.owner.takedamage     = DAMAGE_NO;
 615     self.owner.solid          = SOLID_NOT;
 616     self.owner.movetype       = MOVETYPE_NOCLIP;
 617     self.owner.alpha          = -1;
 618     self.owner.vehicle        = self;
 619     self.owner.event_damage   = func_null;
 620     self.owner.view_ofs       = '0 0 0';
 621     self.colormap             = self.owner.colormap;
 622     if(self.tur_head)
 623         self.tur_head.colormap    = self.owner.colormap;
 624
 625     self.owner.hud            = self.hud;
 626     self.owner.PlayerPhysplug = self.PlayerPhysplug;
 627
 628     self.owner.vehicle_ammo1    = self.vehicle_ammo1;
 629     self.owner.vehicle_ammo2    = self.vehicle_ammo2;
 630     self.owner.vehicle_reload1  = self.vehicle_reload1;
 631     self.owner.vehicle_reload2  = self.vehicle_reload2;
 632
 633     // Cant do this, hides attached objects too.
 634     //self.exteriormodeltoclient = self.owner;
 635     //self.tur_head.exteriormodeltoclient = self.owner;
 636
 637     other.flags &~= FL_ONGROUND;
 638     self.flags  &~= FL_ONGROUND;
 639
 640     self.team                 = self.owner.team;
 641     self.flags               -= FL_NOTARGET;
 642
 643     if (clienttype(other) == CLIENTTYPE_REAL)
 644     {
 645         msg_entity = other;
 646         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
 647         WriteEntity(MSG_ONE, self.vehicle_viewport);
 648
 649         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
 650         if(self.tur_head)
 651         {
 652             WriteAngle(MSG_ONE, self.tur_head.angles_x + self.angles_x); // tilt
 653             WriteAngle(MSG_ONE, self.tur_head.angles_y + self.angles_y); // yaw
 654             WriteAngle(MSG_ONE, 0);                                      // roll
 655         }
 656         else
 657         {
 658             WriteAngle(MSG_ONE,  self.angles_x * -1); // tilt
 659             WriteAngle(MSG_ONE,  self.angles_y);      // yaw
 660             WriteAngle(MSG_ONE,  0);                  // roll
 661         }
 662     }
 663
 664     vehicles_clearrturn();
 665
 666     CSQCVehicleSetup(self.owner, self.hud);
 667
 668     vh_player = other;
 669     vh_vehicle = self;
 670     MUTATOR_CALLHOOK(VehicleEnter);
 671     other = vh_player;
 672     self = vh_vehicle;
 673
 674     self.vehicle_enter();
 675     antilag_clear(other);
 676 }
 677
 678 /** vehicles_findgoodexit
 679     Locates a valid location for the player to exit the vehicle.
 680     Will first try prefer_spot, then up 100 random spots arround the vehicle
 681     wich are in direct line of sight and empty enougth to hold a players bbox
 682 **/
 683 vector vehicles_findgoodexit(vector prefer_spot)
 684 {
 685     //vector exitspot;
 686     float mysize;
 687
 688     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, prefer_spot, MOVE_NORMAL, self.owner);
 689     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 690         return prefer_spot;
 691
 692     mysize = 1.5 * vlen(self.maxs - self.mins);
 693     float i;
 694     vector v, v2;
 695     v2 = 0.5 * (self.absmin + self.absmax);
 696     for(i = 0; i < 100; ++i)
 697     {
 698         v = randomvec();
 699         v_z = 0;
 700         v = v2 + normalize(v) * mysize;
 701         tracebox(v2, PL_MIN, PL_MAX, v, MOVE_NORMAL, self.owner);
 702         if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 703             return v;
 704     }
 705
 706     /*
 707     exitspot = (self.origin + '0 0 48') + v_forward * mysize;
 708     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 709     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 710         return exitspot;
 711
 712     exitspot = (self.origin + '0 0 48') - v_forward * mysize;
 713     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 714     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 715         return exitspot;
 716
 717     exitspot = (self.origin + '0 0 48') + v_right * mysize;
 718     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 719     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 720         return exitspot;
 721
 722     exitspot = (self.origin + '0 0 48') - v_right * mysize;
 723     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 724     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 725         return exitspot;
 726     */
 727
 728     return self.origin;
 729 }
 730
 731 /** vehicles_exit
 732     Standarrd vehicle release fucntion.
 733     custom code goes in self.vehicle_exit
 734 **/
 735 float vehicles_exit_running;
 736 void vehicles_exit(float eject)
 737 {
 738     entity _vehicle;
 739     entity _player;
 740     entity _oldself = self;
 741
 742     if(vehicles_exit_running)
 743     {
 744         dprint("^1vehicles_exit allready running! this is not good..\n");
 745         return;
 746     }
 747
 748     vehicles_exit_running = TRUE;
 749     if(self.flags & FL_CLIENT)
 750     {
 751         _vehicle = self.vehicle;
 752
 753         if (_vehicle.vehicle_flags & VHF_PLAYERSLOT)
 754         {
 755             _vehicle.vehicle_exit(eject);
 756             self = _oldself;
 757             vehicles_exit_running = FALSE;
 758             return;
 759         }
 760     }
 761     else
 762         _vehicle = self;
 763
 764     _player = _vehicle.owner;
 765
 766     self = _vehicle;
 767
 768     if (_player)
 769     {
 770         if (clienttype(_player) == CLIENTTYPE_REAL)
 771         {
 772             msg_entity = _player;
 773             WriteByte (MSG_ONE, SVC_SETVIEWPORT);
 774             WriteEntity( MSG_ONE, _player);
 775
 776             WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
 777             WriteAngle(MSG_ONE, 0);
 778             WriteAngle(MSG_ONE, _vehicle.angles_y);
 779             WriteAngle(MSG_ONE, 0);
 780         }
 781
 782         setsize(_player, PL_MIN,PL_MAX);
 783
 784         _player.takedamage     = DAMAGE_AIM;
 785         _player.solid          = SOLID_SLIDEBOX;
 786         _player.movetype       = MOVETYPE_WALK;
 787         _player.effects        &~= EF_NODRAW;
 788         _player.alpha          = 1;
 789         _player.PlayerPhysplug = func_null;
 790         _player.vehicle        = world;
 791         _player.view_ofs       = PL_VIEW_OFS;
 792         _player.event_damage   = PlayerDamage;
 793         _player.hud            = HUD_NORMAL;
 794         _player.switchweapon   = _vehicle.switchweapon;
 795
 796         CSQCVehicleSetup(_player, HUD_NORMAL);
 797     }
 798     _vehicle.flags |= FL_NOTARGET;
 799
 800     if(_vehicle.deadflag == DEAD_NO)
 801         _vehicle.avelocity          = '0 0 0';
 802
 803     _vehicle.tur_head.nodrawtoclient             = world;
 804
 805     if(!teamplay)
 806         _vehicle.team = 0;
 807     else
 808
 809     vh_player = _player;
 810     vh_vehicle = _vehicle;
 811     MUTATOR_CALLHOOK(VehicleExit);
 812     _player = vh_player;
 813     _vehicle = vh_vehicle;
 814
 815     _vehicle.team = _vehicle.tur_head.team;
 816
 817     sound (_vehicle, CH_TRIGGER_SINGLE, "misc/null.wav", 1, ATTN_NORM);
 818     _vehicle.vehicle_hudmodel.viewmodelforclient = _vehicle;
 819     _vehicle.phase = time + 1;
 820
 821     _vehicle.vehicle_exit(eject);
 822
 823     vehicles_setreturn();
 824     vehicles_reset_colors();
 825     _vehicle.owner = world;
 826     self = _oldself;
 827
 828     vehicles_exit_running = FALSE;
 829 }
 830
 831
 832 void vehicles_regen(float timer, .float regen_field, float field_max, float rpause, float regen, float delta_time, float _healthscale)
 833 {
 834     if(self.regen_field < field_max)
 835     if(timer + rpause < time)
 836     {
 837         if(_healthscale)
 838             regen = regen * (self.vehicle_health / self.tur_health);
 839
 840         self.regen_field = min(self.regen_field + regen * delta_time, field_max);
 841
 842         if(self.owner)
 843             self.owner.regen_field = (self.regen_field / field_max) * 100;
 844     }
 845 }
 846
 847 void shieldhit_think()
 848 {
 849     self.alpha -= 0.1;
 850     if (self.alpha <= 0)
 851     {
 852         //setmodel(self, "");
 853         self.alpha = -1;
 854         self.effects |= EF_NODRAW;
 855     }
 856     else
 857     {
 858         self.nextthink = time + 0.1;
 859     }
 860 }
 861
 862 void vehicles_painframe()
 863 {
 864     if(self.owner.vehicle_health <= 50)
 865     if(self.pain_frame < time)
 866     {
 867         float _ftmp;
 868         _ftmp = self.owner.vehicle_health / 50;
 869         self.pain_frame = time + 0.1 + (random() * 0.5 * _ftmp);
 870         pointparticles(particleeffectnum("smoke_small"), (self.origin + (randomvec() * 80)), '0 0 0', 1);
 871
 872         if(self.vehicle_flags & VHF_DMGSHAKE)
 873             self.velocity += randomvec() * 30;
 874
 875         if(self.vehicle_flags & VHF_DMGROLL)
 876             if(self.vehicle_flags & VHF_DMGHEADROLL)
 877                 self.tur_head.angles += randomvec();
 878             else
 879                 self.angles += randomvec();
 880
 881     }
 882 }
 883
 884 void vehicles_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 885 {
 886     self.dmg_time = time;
 887
 888     if(DEATH_ISWEAPON(deathtype, WEP_NEX))
 889         damage *= autocvar_g_vehicles_nex_damagerate;
 890
 891     if(DEATH_ISWEAPON(deathtype, WEP_UZI))
 892         damage *= autocvar_g_vehicles_uzi_damagerate;
 893
 894     if(DEATH_ISWEAPON(deathtype, WEP_RIFLE))
 895         damage *= autocvar_g_vehicles_rifle_damagerate;
 896
 897     if(DEATH_ISWEAPON(deathtype, WEP_MINSTANEX))
 898         damage *= autocvar_g_vehicles_minstanex_damagerate;
 899
 900     if(DEATH_ISWEAPON(deathtype, WEP_SEEKER))
 901         damage *= autocvar_g_vehicles_tag_damagerate;
 902
 903     self.enemy = attacker;
 904
 905     if((self.vehicle_flags & VHF_HASSHIELD) && (self.vehicle_shield > 0))
 906     {
 907         if (wasfreed(self.vehicle_shieldent) || self.vehicle_shieldent == world)
 908         {
 909             self.vehicle_shieldent = spawn();
 910             self.vehicle_shieldent.effects = EF_LOWPRECISION;
 911
 912             setmodel(self.vehicle_shieldent, "models/vhshield.md3");
 913             setattachment(self.vehicle_shieldent, self, "");
 914             setorigin(self.vehicle_shieldent, real_origin(self) - self.origin);
 915             self.vehicle_shieldent.scale       = 256 / vlen(self.maxs - self.mins);
 916             self.vehicle_shieldent.think       = shieldhit_think;
 917         }
 918
 919         self.vehicle_shieldent.colormod    = '1 1 1';
 920         self.vehicle_shieldent.alpha       = 0.45;
 921         self.vehicle_shieldent.angles      = vectoangles(normalize(hitloc - (self.origin + self.vehicle_shieldent.origin))) - self.angles;
 922         self.vehicle_shieldent.nextthink   = time;
 923         self.vehicle_shieldent.effects &~= EF_NODRAW;
 924
 925         self.vehicle_shield -= damage;
 926
 927         if(self.vehicle_shield < 0)
 928         {
 929             self.vehicle_health            -= fabs(self.vehicle_shield);
 930             self.vehicle_shieldent.colormod = '2 0 0';
 931             self.vehicle_shield             = 0;
 932             self.vehicle_shieldent.alpha    = 0.75;
 933
 934                 if(sound_allowed(MSG_BROADCAST, attacker))
 935                 spamsound (self, CH_PAIN, "onslaught/ons_hit2.wav", VOL_BASE, ATTN_NORM);   // FIXME: PLACEHOLDER
 936         }
 937         else
 938                 if(sound_allowed(MSG_BROADCAST, attacker))
 939                 spamsound (self, CH_PAIN, "onslaught/electricity_explode.wav", VOL_BASE, ATTN_NORM);  // FIXME: PLACEHOLDER
 940
 941     }
 942     else
 943     {
 944         self.vehicle_health -= damage;
 945
 946         if(sound_allowed(MSG_BROADCAST, attacker))
 947             spamsound (self, CH_PAIN, "onslaught/ons_hit2.wav", VOL_BASE, ATTN_NORM);  // FIXME: PLACEHOLDER
 948     }
 949
 950         if(self.damageforcescale < 1 && self.damageforcescale > 0)
 951                 self.velocity += force * self.damageforcescale;
 952         else
 953                 self.velocity += force;
 954
 955     if(self.vehicle_health <= 0)
 956     {
 957         if(self.owner)
 958             if(self.vehicle_flags & VHF_DEATHEJECT)
 959                 vehicles_exit(VHEF_EJECT);
 960             else
 961                 vehicles_exit(VHEF_RELESE);
 962
 963
 964         antilag_clear(self);
 965
 966         self.vehicle_die();
 967         vehicles_setreturn();
 968     }
 969 }
 970
 971 void vehicles_clearrturn()
 972 {
 973     entity ret;
 974     // Remove "return helper", if any.
 975     ret = findchain(classname, "vehicle_return");
 976     while(ret)
 977     {
 978         if(ret.wp00 == self)
 979         {
 980             ret.classname   = "";
 981             ret.think       = SUB_Remove;
 982             ret.nextthink   = time + 0.1;
 983
 984             if(ret.waypointsprite_attached)
 985                 WaypointSprite_Kill(ret.waypointsprite_attached);
 986
 987             return;
 988         }
 989         ret = ret.chain;
 990     }
 991 }
 992
 993 void vehicles_return()
 994 {
 995     pointparticles(particleeffectnum("teleport"), self.wp00.origin + '0 0 64', '0 0 0', 1);
 996
 997     self.wp00.think     = vehicles_spawn;
 998     self.wp00.nextthink = time;
 999
1000     if(self.waypointsprite_attached)
1001         WaypointSprite_Kill(self.waypointsprite_attached);
1002
1003     remove(self);
1004 }
1005
1006 void vehicles_showwp_goaway()
1007 {
1008     if(self.waypointsprite_attached)
1009         WaypointSprite_Kill(self.waypointsprite_attached);
1010
1011     remove(self);
1012
1013 }
1014
1015 void vehicles_showwp()
1016 {
1017     entity oldself = world;
1018     vector rgb;
1019
1020     if(self.cnt)
1021     {
1022         self.think      = vehicles_return;
1023         self.nextthink  = self.cnt;
1024     }
1025     else
1026     {
1027         self.think      = vehicles_return;
1028         self.nextthink  = time +1;
1029
1030         oldself = self;
1031         self = spawn();
1032         setmodel(self, "null");
1033         self.team = oldself.wp00.team;
1034         self.wp00 = oldself.wp00;
1035         setorigin(self, oldself.wp00.pos1);
1036
1037         self.nextthink = time + 5;
1038         self.think = vehicles_showwp_goaway;
1039     }
1040
1041     if(teamplay && self.team)
1042             rgb = TeamColor(self.team);
1043     else
1044             rgb = '1 1 1';
1045     WaypointSprite_Spawn("vehicle", 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
1046     if(self.waypointsprite_attached)
1047     {
1048         WaypointSprite_UpdateRule(self.waypointsprite_attached, self.wp00.team, SPRITERULE_DEFAULT);
1049         if(oldself == world)
1050             WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, self.nextthink);
1051         WaypointSprite_Ping(self.waypointsprite_attached);
1052     }
1053
1054     if(oldself != world)
1055         self = oldself;
1056 }
1057
1058 void vehicles_setreturn()
1059 {
1060     entity ret;
1061
1062     vehicles_clearrturn();
1063
1064     ret = spawn();
1065     ret.classname   = "vehicle_return";
1066     ret.wp00       = self;
1067     ret.team        = self.team;
1068     ret.think       = vehicles_showwp;
1069
1070     if(self.deadflag != DEAD_NO)
1071     {
1072         ret.cnt         = time + self.vehicle_respawntime;
1073         ret.nextthink   = min(time + self.vehicle_respawntime, time + self.vehicle_respawntime - 5);
1074     }
1075     else
1076     {
1077         ret.nextthink   = min(time + self.vehicle_respawntime, time + self.vehicle_respawntime - 1);
1078     }
1079
1080     setmodel(ret, "null");
1081     setorigin(ret, self.pos1 + '0 0 96');
1082
1083 }
1084
1085 void vehicles_reset_colors()
1086 {
1087     entity e;
1088     float _effects = 0, _colormap;
1089     vector _glowmod, _colormod;
1090
1091     if(autocvar_g_nodepthtestplayers)
1092         _effects |= EF_NODEPTHTEST;
1093
1094     if(autocvar_g_fullbrightplayers)
1095         _effects |= EF_FULLBRIGHT;
1096
1097     if(self.team)
1098         _colormap = 1024 + (self.team - 1) * 17;
1099     else
1100         _colormap = 1024;
1101
1102     _glowmod  = '0 0 0';
1103     _colormod = '0 0 0';
1104
1105     // Find all ents attacked to main model and setup effects, colormod etc.
1106     e = findchainentity(tag_entity, self);
1107     while(e)
1108     {
1109         if(e != self.vehicle_shieldent)
1110         {
1111             e.effects   = _effects; //  | EF_LOWPRECISION;
1112             e.colormod  = _colormod;
1113             e.colormap  = _colormap;
1114             e.alpha     = 1;
1115         }
1116         e = e.chain;
1117     }
1118
1119     self.vehicle_hudmodel.effects  = self.effects  = _effects; // | EF_LOWPRECISION;
1120     self.vehicle_hudmodel.colormod = self.colormod = _colormod;
1121     self.vehicle_hudmodel.colormap = self.colormap = _colormap;
1122     self.vehicle_viewport.effects = (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NOGUNBOB | EF_NOSHADOW | EF_LOWPRECISION | EF_SELECTABLE | EF_TELEPORT_BIT);
1123
1124     self.alpha     = 1;
1125     self.avelocity = '0 0 0';
1126     self.velocity  = '0 0 0';
1127     self.effects   = _effects;
1128 }
1129
1130 void vehicle_use()
1131 {
1132     dprint("vehicle ",self.netname, " used by ", activator.classname, "\n");
1133
1134     self.tur_head.team = activator.team;
1135
1136     if(self.tur_head.team == 0)
1137         self.active = ACTIVE_NOT;
1138     else
1139         self.active = ACTIVE_ACTIVE;
1140
1141     if(self.active == ACTIVE_ACTIVE && self.deadflag == DEAD_NO)
1142     {
1143         dprint("^3Eat shit yall!\n");
1144         vehicles_setreturn();
1145         vehicles_reset_colors();
1146     }
1147     else if(self.active == ACTIVE_NOT && self.deadflag != DEAD_NO)
1148     {
1149
1150     }
1151 }
1152
1153 float vehicle_addplayerslot(    entity _owner,
1154                                 entity _slot,
1155                                 float _hud,
1156                                 string _hud_model,
1157                                 float() _framefunc,
1158                                 void(float) _exitfunc)
1159 {
1160     if not (_owner.vehicle_flags & VHF_MULTISLOT)
1161         _owner.vehicle_flags |= VHF_MULTISLOT;
1162
1163     _slot.PlayerPhysplug = _framefunc;
1164     _slot.vehicle_exit = _exitfunc;
1165     _slot.hud = _hud;
1166     _slot.vehicle_flags = VHF_PLAYERSLOT;
1167     _slot.vehicle_viewport = spawn();
1168     _slot.vehicle_hudmodel = spawn();
1169     _slot.vehicle_hudmodel.viewmodelforclient = _slot;
1170     _slot.vehicle_viewport.effects = (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NOGUNBOB | EF_NOSHADOW | EF_LOWPRECISION | EF_SELECTABLE | EF_TELEPORT_BIT);
1171
1172     setmodel(_slot.vehicle_hudmodel, _hud_model);
1173     setmodel(_slot.vehicle_viewport, "null");
1174
1175     setattachment(_slot.vehicle_hudmodel, _slot, "");
1176     setattachment(_slot.vehicle_viewport, _slot.vehicle_hudmodel, "");
1177
1178     return TRUE;
1179 }
1180
1181 float vehicle_initialize(string  net_name,
1182                          string  bodymodel,
1183                          string  topmodel,
1184                          string  hudmodel,
1185                          string  toptag,
1186                          string  hudtag,
1187                          string  viewtag,
1188                          float   vhud,
1189                          vector  min_s,
1190                          vector  max_s,
1191                          float   nodrop,
1192                          void(float _spawnflag)  spawnproc,
1193                          float   _respawntime,
1194                          float() physproc,
1195                          void()  enterproc,
1196                          void(float extflag) exitfunc,
1197                          void() dieproc,
1198                          void() thinkproc,
1199                          float  use_csqc,
1200                          float _max_health,
1201                          float _max_shield)
1202 {
1203         if(!autocvar_g_vehicles)
1204                 return FALSE;
1205
1206     if(self.targetname)
1207     {
1208         self.vehicle_controller = find(world, target, self.targetname);
1209         if(!self.vehicle_controller)
1210         {
1211             bprint("^1WARNING: ^7Vehicle with invalid .targetname\n");
1212         }
1213         else
1214         {
1215             self.team = self.vehicle_controller.team;
1216             self.use = vehicle_use;
1217
1218             if(teamplay)
1219             {
1220                 if(self.vehicle_controller.team == 0)
1221                     self.active = ACTIVE_NOT;
1222                 else
1223                     self.active = ACTIVE_ACTIVE;
1224             }
1225         }
1226     }
1227
1228     precache_sound("onslaught/ons_hit2.wav");
1229     precache_sound("onslaught/electricity_explode.wav");
1230
1231
1232     addstat(STAT_HUD, AS_INT,  hud);
1233         addstat(STAT_VEHICLESTAT_HEALTH,  AS_INT, vehicle_health);
1234         addstat(STAT_VEHICLESTAT_SHIELD,  AS_INT, vehicle_shield);
1235         addstat(STAT_VEHICLESTAT_ENERGY,  AS_INT, vehicle_energy);
1236
1237         addstat(STAT_VEHICLESTAT_AMMO1,   AS_INT, vehicle_ammo1);
1238         addstat(STAT_VEHICLESTAT_RELOAD1, AS_INT, vehicle_reload1);
1239
1240         addstat(STAT_VEHICLESTAT_AMMO2,   AS_INT, vehicle_ammo2);
1241         addstat(STAT_VEHICLESTAT_RELOAD2, AS_INT, vehicle_reload2);
1242
1243     if(bodymodel == "")
1244         error("vehicles: missing bodymodel!");
1245
1246     if(hudmodel == "")
1247         error("vehicles: missing hudmodel!");
1248
1249     if(net_name == "")
1250         self.netname = self.classname;
1251     else
1252         self.netname = net_name;
1253
1254     if(self.team && !teamplay)
1255         self.team = 0;
1256
1257     self.vehicle_flags |= VHF_ISVEHICLE;
1258
1259     setmodel(self, bodymodel);
1260
1261     self.vehicle_viewport   = spawn();
1262     self.vehicle_hudmodel   = spawn();
1263     self.tur_head           = spawn();
1264     self.tur_head.owner     = self;
1265     self.takedamage         = DAMAGE_AIM;
1266     self.bot_attack         = TRUE;
1267     self.iscreature         = TRUE;
1268     self.teleportable       = FALSE; // no teleporting for vehicles, too buggy
1269     self.damagedbycontents      = TRUE;
1270     self.hud                = vhud;
1271     self.tur_health          = _max_health;
1272     self.tur_head.tur_health = _max_shield;
1273     self.vehicle_die         = dieproc;
1274     self.vehicle_exit        = exitfunc;
1275     self.vehicle_enter       = enterproc;
1276     self.PlayerPhysplug      = physproc;
1277     self.event_damage        = vehicles_damage;
1278     self.touch               = vehicles_touch;
1279     self.think               = vehicles_spawn;
1280     self.nextthink           = time;
1281     self.vehicle_respawntime = _respawntime;
1282     self.vehicle_spawn       = spawnproc;
1283     self.effects             = EF_NODRAW;
1284     if(g_assault || !autocvar_g_vehicles_delayspawn)
1285         self.nextthink = time + 0.5;
1286     else
1287         self.nextthink = time + _respawntime + (random() * autocvar_g_vehicles_delayspawn_jitter);
1288
1289
1290     if(autocvar_g_nodepthtestplayers)
1291         self.effects = self.effects | EF_NODEPTHTEST;
1292
1293     if(autocvar_g_fullbrightplayers)
1294         self.effects = self.effects | EF_FULLBRIGHT;
1295
1296     setmodel(self.vehicle_hudmodel, hudmodel);
1297     setmodel(self.vehicle_viewport, "null");
1298
1299     if(topmodel != "")
1300     {
1301         setmodel(self.tur_head, topmodel);
1302         setattachment(self.tur_head, self, toptag);
1303         setattachment(self.vehicle_hudmodel, self.tur_head, hudtag);
1304         setattachment(self.vehicle_viewport, self.vehicle_hudmodel, viewtag);
1305     }
1306     else
1307     {
1308         setattachment(self.tur_head, self, "");
1309         setattachment(self.vehicle_hudmodel, self, hudtag);
1310         setattachment(self.vehicle_viewport, self.vehicle_hudmodel, viewtag);
1311     }
1312
1313     setsize(self, min_s, max_s);
1314     if not (nodrop)
1315     {
1316         setorigin(self, self.origin);
1317         tracebox(self.origin + '0 0 100', min_s, max_s, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
1318         setorigin(self, trace_endpos);
1319     }
1320
1321     self.pos1 = self.origin;
1322     self.pos2 = self.angles;
1323     self.tur_head.team = self.team;
1324
1325     return TRUE;
1326 }
1327
1328 vector vehicle_aimturret(entity _vehic, vector _target, entity _turrret, string _tagname,
1329                          float _pichlimit_min, float _pichlimit_max,
1330                          float _rotlimit_min, float _rotlimit_max, float _aimspeed)
1331 {
1332     vector vtmp, vtag;
1333     float ftmp;
1334     vtag = gettaginfo(_turrret, gettagindex(_turrret, _tagname));
1335     vtmp = vectoangles(normalize(_target - vtag));
1336     vtmp = AnglesTransform_ToAngles(AnglesTransform_LeftDivide(AnglesTransform_FromAngles(_vehic.angles), AnglesTransform_FromAngles(vtmp))) - _turrret.angles;
1337     vtmp = AnglesTransform_Normalize(vtmp, TRUE);
1338     ftmp = _aimspeed * frametime;
1339     vtmp_y = bound(-ftmp, vtmp_y, ftmp);
1340     vtmp_x = bound(-ftmp, vtmp_x, ftmp);
1341     _turrret.angles_y = bound(_rotlimit_min, _turrret.angles_y + vtmp_y, _rotlimit_max);
1342     _turrret.angles_x = bound(_pichlimit_min, _turrret.angles_x + vtmp_x, _pichlimit_max);
1343     return vtag;
1344 }
1345
1346 void vehicles_gib_explode()
1347 {
1348         sound (self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
1349         pointparticles(particleeffectnum("explosion_small"), randomvec() * 80 + (self.origin + '0 0 100'), '0 0 0', 1);
1350         remove(self);
1351 }
1352
1353 void vehicles_gib_think()
1354 {
1355         self.alpha -= 0.1;
1356         if(self.cnt >= time)
1357                 remove(self);
1358         else
1359                 self.nextthink = time + 0.1;
1360 }
1361
1362 entity vehicle_tossgib(entity _template, vector _vel, string _tag, float _burn, float _explode, float _maxtime, vector _rot)
1363 {
1364         entity _gib = spawn();
1365         setmodel(_gib, _template.model);
1366         setorigin(_gib, gettaginfo(self, gettagindex(self, _tag)));
1367         _gib.velocity = _vel;
1368         _gib.movetype = MOVETYPE_TOSS;
1369         _gib.solid = SOLID_CORPSE;
1370         _gib.colormod = '-0.5 -0.5 -0.5';
1371         _gib.effects = EF_LOWPRECISION;
1372         _gib.avelocity = _rot;
1373
1374         if(_burn)
1375                 _gib.effects |= EF_FLAME;
1376
1377         if(_explode)
1378         {
1379                 _gib.think = vehicles_gib_explode;
1380                 _gib.nextthink = time + random() * _explode;
1381                 _gib.touch = vehicles_gib_explode;
1382         }
1383         else
1384         {
1385                 _gib.cnt = time + _maxtime;
1386                 _gib.think = vehicles_gib_think;
1387                 _gib.nextthink = time + _maxtime - 1;
1388                 _gib.alpha = 1;
1389         }
1390         return _gib;
1391 }
1392
1393 /*
1394 vector predict_target(entity _targ, vector _from, float _shot_speed)
1395 {
1396     float i;                // loop
1397     float _distance;        // How far to target
1398     float _impact_time;     // How long untill projectile impacts
1399     vector _predict_pos;    // Predicted enemy location
1400     vector _original_origin;// Where target is before predicted
1401
1402      _original_origin = real_origin(_targ); // Typicaly center of target BBOX
1403
1404     _predict_pos = _original_origin;
1405     for(i = 0; i < 4; ++i)  // Loop a few times to increase prediction accuracy (increase loop count if accuracy is to low)
1406     {
1407         _distance = vlen(_predict_pos - _from); // Get distance to previos predicted location
1408         _impact_time = _distance / _shot_speed; // Calculate impact time
1409         _predict_pos = _original_origin + _targ.velocity * _impact_time; // Calculate new predicted location
1410     }
1411
1412     return _predict_pos;
1413 }
1414 */