qcsrc/server/vehicles/vehicles.qc

   1 float autocvar_g_vehicles_crush_dmg;
   2 float autocvar_g_vehicles_crush_force;
   3 float autocvar_g_vehicles_delayspawn;
   4 float autocvar_g_vehicles_delayspawn_jitter;
   5
   6 void vehicles_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force);
   7 void vehicles_return();
   8 void vehicles_enter();
   9 void vehicles_touch();
  10 void vehicles_reset_colors();
  11 void vehicles_clearrturn();
  12 void vehicles_setreturn();
  13
  14
  15 /** AuxiliaryXhair*
  16     Send additional points of interest to be drawn, to vehicle owner
  17 **/
  18 float MAX_AXH = 4;
  19 .entity AuxiliaryXhair[MAX_AXH];
  20
  21 float SendAuxiliaryXhair(entity to, float sf)
  22 {
  23
  24         WriteByte(MSG_ENTITY, ENT_CLIENT_AUXILIARYXHAIR);
  25
  26         WriteByte(MSG_ENTITY, self.cnt);
  27
  28         WriteCoord(MSG_ENTITY, self.origin_x);
  29         WriteCoord(MSG_ENTITY, self.origin_y);
  30         WriteCoord(MSG_ENTITY, self.origin_z);
  31
  32     WriteByte(MSG_ENTITY, rint(self.colormod_x * 255));
  33     WriteByte(MSG_ENTITY, rint(self.colormod_y * 255));
  34     WriteByte(MSG_ENTITY, rint(self.colormod_z * 255));
  35
  36     return TRUE;
  37 }
  38
  39 void UpdateAuxiliaryXhair(entity own, vector loc, vector clr, float axh_id)
  40 {
  41     entity axh;
  42
  43     axh_id = bound(0, axh_id, MAX_AXH);
  44     axh = own.AuxiliaryXhair[axh_id];
  45
  46     if(axh == world || wasfreed(axh))  // MADNESS? THIS IS QQQQCCCCCCCCC (wasfreed, why do you exsist?)
  47     {
  48         axh                     = spawn();
  49         axh.cnt                 = axh_id;
  50         axh.drawonlytoclient    = own;
  51         axh.owner               = own;
  52         Net_LinkEntity(axh, FALSE, 0, SendAuxiliaryXhair);
  53     }
  54
  55     setorigin(axh, loc);
  56     axh.colormod            = clr;
  57     axh.SendFlags           = 0x01;
  58     own.AuxiliaryXhair[axh_id] = axh;
  59 }
  60
  61 /*
  62 // SVC_TEMPENTITY based, horrible with even 50 ping. hm.
  63 // WriteByte(MSG_ONE, SVC_TEMPENTITY) uses reliable messagess, never use for thinsg that need continous updates.
  64 void SendAuxiliaryXhair2(entity own, vector loc, vector clr, float axh_id)
  65 {
  66         msg_entity = own;
  67
  68         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  69         WriteByte(MSG_ONE, TE_CSQC_AUXILIARYXHAIR);
  70
  71         WriteByte(MSG_ONE, axh_id);
  72
  73         WriteCoord(MSG_ONE, loc_x);
  74         WriteCoord(MSG_ONE, loc_y);
  75         WriteCoord(MSG_ONE, loc_z);
  76
  77     WriteByte(MSG_ONE, rint(clr_x * 255));
  78     WriteByte(MSG_ONE, rint(clr_y * 255));
  79     WriteByte(MSG_ONE, rint(clr_z * 255));
  80
  81 }
  82 */
  83 // End AuxiliaryXhair
  84
  85 /**
  86     Notifies the client that he enterd a vehicle, and sends
  87     realavent data.
  88
  89     only sends vehicle_id atm (wich is a HUD_* constant, ex. HUD_SPIDERBOT)
  90 **/
  91 void CSQCVehicleSetup(entity own, float vehicle_id)
  92 {
  93         msg_entity = own;
  94
  95         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  96         WriteByte(MSG_ONE, TE_CSQC_VEHICLESETUP);
  97         WriteByte(MSG_ONE, vehicle_id);
  98 }
  99
 100 /** vehicles_locktarget
 101
 102     Generic target locking.
 103
 104     Figure out if what target is "locked" (if any), for missile tracking as such.
 105
 106     after calling, "if(self.lock_target != world && self.lock_strength == 1)" mean
 107     you have a locked in target.
 108
 109     Exspects a crosshair_trace() or equivalent to be
 110     dont before calling.
 111
 112 **/
 113 .entity lock_target;
 114 .float  lock_strength;
 115 .float  lock_time;
 116 .float  lock_soundtime;
 117 void vehicles_locktarget(float incr, float decr, float _lock_time)
 118 {
 119     if(self.lock_target && self.lock_target.deadflag != DEAD_NO)
 120     {
 121         self.lock_target    = world;
 122         self.lock_strength  = 0;
 123         self.lock_time      = 0;
 124     }
 125
 126     if(self.lock_time > time)
 127     {
 128         if(self.lock_target)
 129         if(self.lock_soundtime < time)
 130         {
 131             self.lock_soundtime = time + 0.5;
 132             play2(self.owner, "vehicles/locked.wav");
 133         }
 134
 135         return;
 136     }
 137
 138     if(trace_ent != world)
 139     {
 140         if(teams_matter && trace_ent.team == self.team)
 141             trace_ent = world;
 142
 143         if(trace_ent.deadflag != DEAD_NO)
 144             trace_ent = world;
 145
 146         if not (trace_ent.vehicle_flags & VHF_ISVEHICLE || trace_ent.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 147             trace_ent = world;
 148     }
 149
 150     if(self.lock_target == world && trace_ent != world)
 151         self.lock_target = trace_ent;
 152
 153     if(self.lock_target && trace_ent == self.lock_target)
 154     {
 155         if(self.lock_strength != 1 && self.lock_strength + incr >= 1)
 156         {
 157             play2(self.owner, "vehicles/lock.wav");
 158             self.lock_soundtime = time + 0.8;
 159         }
 160         else if (self.lock_strength != 1 && self.lock_soundtime < time)
 161         {
 162             play2(self.owner, "vehicles/locking.wav");
 163             self.lock_soundtime = time + 0.3;
 164         }
 165
 166     }
 167
 168     // Have a locking target
 169     // Trace hit current target
 170     if(trace_ent == self.lock_target && trace_ent != world)
 171     {
 172         self.lock_strength = min(self.lock_strength + incr, 1);
 173         if(self.lock_strength == 1)
 174             self.lock_time = time + _lock_time;
 175     }
 176     else
 177     {
 178         if(trace_ent)
 179             self.lock_strength = max(self.lock_strength - decr * 2, 0);
 180         else
 181             self.lock_strength = max(self.lock_strength - decr, 0);
 182
 183         if(self.lock_strength == 0)
 184             self.lock_target = world;
 185     }
 186 }
 187
 188 #define VEHICLE_UPDATE_PLAYER(fld,vhname) \
 189 self.owner.vehicle_##fld = (self.vehicle_##fld / autocvar_g_vehicle_##vhname##_##fld) * 100
 190
 191 #define vehicles_sweap_collision(orig,vel,dt,acm,mult) \
 192 traceline(orig, orig + vel * dt, MOVE_NORMAL, self); \
 193 if(trace_fraction != 1) \
 194     acm += normalize(self.origin - trace_endpos) * (vlen(vel) * mult)
 195
 196 // Hover movement support
 197 float  force_fromtag_power;
 198 float  force_fromtag_normpower;
 199 vector force_fromtag_origin;
 200 vector vehicles_force_fromtag_hover(string tag_name, float spring_length, float max_power)
 201 {
 202     force_fromtag_origin = gettaginfo(self, gettagindex(self, tag_name));
 203     v_forward  = normalize(v_forward) * -1;
 204     traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, self);
 205
 206     force_fromtag_power = (1 - trace_fraction) * max_power;
 207     force_fromtag_normpower = force_fromtag_power / max_power;
 208
 209     return v_forward  * force_fromtag_power;
 210 }
 211
 212 // Experimental hovermode wich uses attraction/repulstion from surface insted of gravity/repulsion
 213 // Can possibly be use to move abt any surface (inclusing walls/celings)
 214 vector vehicles_force_fromtag_maglev(string tag_name, float spring_length, float max_power)
 215 {
 216
 217     force_fromtag_origin = gettaginfo(self, gettagindex(self, tag_name));
 218     v_forward  = normalize(v_forward) * -1;
 219     traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, self);
 220
 221     // TODO - this may NOT be compatible with wall/celing movement, unhardcode 0.25 (engine count multiplier)
 222     if(trace_fraction == 1.0)
 223     {
 224         force_fromtag_normpower = -0.25;
 225         return '0 0 -200';
 226     }
 227
 228     force_fromtag_power = ((1 - trace_fraction) - trace_fraction) * max_power;
 229     force_fromtag_normpower = force_fromtag_power / max_power;
 230
 231     return v_forward  * force_fromtag_power;
 232 }
 233
 234 // Generic vehile projectile system
 235 void vehicles_projectile_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 236 {
 237     self.health -= damage;
 238     self.velocity += force;
 239     if(self.health < 1)
 240     {
 241         self.takedamage = DAMAGE_NO;
 242         self.event_damage = SUB_Null;
 243         self.think = self.use;
 244         self.nextthink = time;
 245     }
 246
 247 }
 248
 249 void vehicles_projectile_explode()
 250 {
 251     if(self.owner && other != world)
 252     {
 253         if(other == self.owner.vehicle)
 254             return;
 255
 256         if(other == self.owner.vehicle.tur_head)
 257             return;
 258     }
 259
 260         PROJECTILE_TOUCH;
 261
 262         self.event_damage = SUB_Null;
 263     RadiusDamage (self, self.realowner, self.shot_dmg, 0, self.shot_radius, self, self.shot_force, self.totalfrags, other);
 264
 265     remove (self);
 266 }
 267
 268 entity vehicles_projectile(string _mzlfx, string _mzlsound,
 269                            vector _org, vector _vel,
 270                            float _dmg, float _radi, float _force,  float _size,
 271                            float _deahtype, float _projtype, float _health,
 272                            float _cull, float _clianim)
 273 {
 274     entity proj;
 275
 276     proj = spawn();
 277
 278     PROJECTILE_MAKETRIGGER(proj);
 279     setorigin(proj, _org);
 280
 281     proj.shot_dmg         = _dmg;
 282     proj.shot_radius      = _radi;
 283     proj.shot_force       = _force;
 284     proj.totalfrags       = _deahtype;
 285     proj.solid            = SOLID_BBOX;
 286     proj.movetype         = MOVETYPE_FLYMISSILE;
 287     proj.flags            = FL_PROJECTILE;
 288     proj.bot_dodge        = TRUE;
 289     proj.bot_dodgerating  = _dmg;
 290     proj.velocity         = _vel;
 291     proj.touch            = vehicles_projectile_explode;
 292     proj.use              = vehicles_projectile_explode;
 293     proj.owner            = self;
 294     proj.realowner        = self.owner;
 295     proj.think            = SUB_Remove;
 296     proj.nextthink        = time + 30;
 297
 298     if(_health)
 299     {
 300         proj.takedamage       = DAMAGE_AIM;
 301         proj.event_damage     = vehicles_projectile_damage;
 302         proj.health           = _health;
 303     }
 304     else
 305         proj.flags           = FL_PROJECTILE | FL_NOTARGET;
 306
 307     if(_mzlsound)
 308         sound (self, CHAN_WEAPON, _mzlsound, VOL_BASE, ATTN_NORM);
 309
 310     if(_mzlfx)
 311         pointparticles(particleeffectnum(_mzlfx), proj.origin, proj.velocity, 1);
 312
 313
 314     setsize (proj, '-1 -1 -1' * _size, '1 1 1' * _size);
 315
 316     CSQCProjectile(proj, _clianim, _projtype, _cull);
 317
 318     return proj;
 319 }
 320 // End generic vehile projectile system
 321
 322 /** vehicles_spawn
 323     Exetuted for all vehicles on (re)spawn.
 324     Sets defaults for newly spawned units.
 325 **/
 326 void vehicles_spawn()
 327 {
 328     dprint("Spawning vehicle: ", self.netname, "\n");
 329
 330     // De-own & reset
 331     self.vehicle_hudmodel.viewmodelforclient = self;
 332
 333     self.owner              = world;
 334     self.touch              = vehicles_touch;
 335     self.event_damage       = vehicles_damage;
 336     self.iscreature         = TRUE;
 337     self.movetype           = MOVETYPE_WALK;
 338     self.solid              = SOLID_SLIDEBOX;
 339     self.takedamage         = DAMAGE_AIM;
 340         self.deadflag           = DEAD_NO;
 341     self.bot_attack         = TRUE;
 342     self.flags              = FL_NOTARGET;
 343     self.avelocity          = '0 0 0';
 344     self.velocity           = '0 0 0';
 345
 346     // Reset locking
 347     self.lock_strength      = 0;
 348     self.lock_target        = world;
 349     self.misc_bulletcounter = 0;
 350
 351     // Return to spawn
 352     self.angles             = self.pos2;
 353     setorigin(self, self.pos1 + '0 0 128');
 354     // Show it
 355     pointparticles(particleeffectnum("teleport"), self.origin + '0 0 64', '0 0 0', 1);
 356
 357     vehicles_reset_colors();
 358     self.vehicle_spawn();
 359 }
 360
 361 // Better way of determening whats crushable needed! (fl_crushable?)
 362 float vehicles_crushable(entity e)
 363 {
 364     if(e.classname == "player")
 365         return TRUE;
 366
 367     if(e.classname == "monster_zombie")
 368         return TRUE;
 369
 370     return FALSE;
 371 }
 372
 373 void vehicles_touch()
 374 {
 375     // Vehicle currently in use
 376     if(self.owner)
 377     {
 378         // Colided with world?
 379         if(other == world)
 380         {
 381             // Apply velocity based self damage here
 382         }
 383         else
 384         {
 385             if(other.vehicle_flags & VHF_ISVEHICLE)
 386             {
 387                 //other.velocity += self.velocity * (self.mass / other.mass);
 388             }
 389             else if(vehicles_crushable(other))
 390             {
 391                 if(vlen(self.velocity) != 0)
 392                     Damage(other, self, self.owner, autocvar_g_vehicles_crush_dmg, DEATH_VHCRUSH, '0 0 0', normalize(other.origin - self.origin) * autocvar_g_vehicles_crush_force);
 393             }
 394         }
 395         return;
 396     }
 397
 398     if(other.classname != "player")
 399         return;
 400
 401     if(other.deadflag != DEAD_NO)
 402         return;
 403
 404     if(other.vehicle != world)
 405         return;
 406
 407     // Remove this when bots know how to use vehicles.
 408     if (clienttype(other) != CLIENTTYPE_REAL)
 409         return;
 410
 411     vehicles_enter();
 412 }
 413
 414 void vehicles_enter()
 415 {
 416    // Remove this when bots know how to use vehicles
 417     if (clienttype(other) != CLIENTTYPE_REAL)
 418         return;
 419
 420     if(self.phase > time)
 421         return;
 422
 423     if(teams_matter)
 424     if(self.team)
 425     if(self.team != other.team)
 426         return;
 427
 428     self.vehicle_ammo1   = 0;
 429     self.vehicle_ammo2   = 0;
 430     self.vehicle_reload1 = 0;
 431     self.vehicle_reload2 = 0;
 432     self.vehicle_energy  = 0;
 433
 434     self.owner          = other;
 435     self.switchweapon   = other.switchweapon;
 436
 437     // .viewmodelforclient works better.
 438     //self.vehicle_hudmodel.drawonlytoclient = self.owner;
 439
 440     self.vehicle_hudmodel.viewmodelforclient = self.owner;
 441
 442     self.event_damage         = vehicles_damage;
 443     self.nextthink            = 0;
 444     self.owner.angles         = self.angles;
 445     self.owner.takedamage     = DAMAGE_NO;
 446     self.owner.solid          = SOLID_NOT;
 447     self.owner.movetype       = MOVETYPE_NOCLIP;
 448     self.owner.alpha          = -1;
 449     self.owner.vehicle        = self;
 450     self.owner.event_damage   = SUB_Null;
 451     self.owner.view_ofs       = '0 0 0';
 452     self.colormap             = self.owner.colormap;
 453     if(self.tur_head)
 454         self.tur_head.colormap    = self.owner.colormap;
 455
 456     self.owner.hud            = self.hud;
 457     self.owner.PlayerPhysplug = self.PlayerPhysplug;
 458
 459     self.owner.vehicle_ammo1    = self.vehicle_ammo1;
 460     self.owner.vehicle_ammo2    = self.vehicle_ammo2;
 461     self.owner.vehicle_reload1  = self.vehicle_reload1;
 462     self.owner.vehicle_reload2  = self.vehicle_reload2;
 463
 464     // Cant do this, hides attached objects too.
 465     //self.exteriormodeltoclient = self.owner;
 466     //self.tur_head.exteriormodeltoclient = self.owner;
 467
 468     other.flags &~= FL_ONGROUND;
 469     self.flags  &~= FL_ONGROUND;
 470
 471     self.team                 = self.owner.team;
 472     self.flags               -= FL_NOTARGET;
 473
 474     msg_entity = other;
 475     WriteByte (MSG_ONE, SVC_SETVIEWPORT);
 476     WriteEntity(MSG_ONE, self.vehicle_viewport);
 477
 478     WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
 479     if(self.tur_head)
 480     {
 481         WriteAngle(MSG_ONE, self.tur_head.angles_x + self.angles_x); // tilt
 482         WriteAngle(MSG_ONE, self.tur_head.angles_y + self.angles_y); // yaw
 483         WriteAngle(MSG_ONE, 0);                                      // roll
 484     }
 485     else
 486     {
 487         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
 488         WriteAngle(MSG_ONE,  self.angles_x * -1); // tilt
 489         WriteAngle(MSG_ONE,  self.angles_y);      // yaw
 490         WriteAngle(MSG_ONE,  0);                  // roll
 491     }
 492
 493     vehicles_clearrturn();
 494
 495     CSQCVehicleSetup(self.owner, self.hud);
 496
 497     self.vehicle_enter();
 498 }
 499
 500 /** vehicles_findgoodexit
 501     Locates a valid location for the player to exit the vehicle.
 502     Will first try prefer_spot, then up 100 random spots arround the vehicle
 503     wich are in direct line of sight and empty enougth to hold a players bbox
 504 **/
 505 vector vehicles_findgoodexit(vector prefer_spot)
 506 {
 507     vector exitspot;
 508     float mysize;
 509
 510     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, prefer_spot, MOVE_NORMAL, self.owner);
 511     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 512         return prefer_spot;
 513
 514     mysize = vlen(self.maxs - self.mins);
 515     float i;
 516     vector v, v2;
 517     v2 = 0.5 * (self.absmin + self.absmax);
 518     for(i = 0; i < 100; ++i)
 519     {
 520         v = randomvec();
 521         v_z = 0;
 522         v = v2 + normalize(v) * mysize;
 523         tracebox(v2, PL_MIN, PL_MAX, v, MOVE_NORMAL, self.owner);
 524         if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 525             return v;
 526     }
 527
 528     /*
 529     exitspot = (self.origin + '0 0 48') + v_forward * mysize;
 530     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 531     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 532         return exitspot;
 533
 534     exitspot = (self.origin + '0 0 48') - v_forward * mysize;
 535     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 536     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 537         return exitspot;
 538
 539     exitspot = (self.origin + '0 0 48') + v_right * mysize;
 540     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 541     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 542         return exitspot;
 543
 544     exitspot = (self.origin + '0 0 48') - v_right * mysize;
 545     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 546     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 547         return exitspot;
 548     */
 549
 550     return self.origin;
 551 }
 552
 553 /** vehicles_exit
 554     Standarrd vehicle release fucntion.
 555     custom code goes in self.vehicle_exit
 556 **/
 557 void vehicles_exit(float eject)
 558 {
 559         self.flags |= FL_NOTARGET;
 560
 561     if (self.owner)
 562     {
 563         msg_entity = self.owner;
 564         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
 565         WriteEntity( MSG_ONE, self.owner);
 566
 567         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
 568         WriteAngle(MSG_ONE, 0);                 // pich
 569         WriteAngle(MSG_ONE, self.angles_y);     // yaw
 570         WriteAngle(MSG_ONE, 0);                 // roll
 571
 572         setsize(self.owner, PL_MIN,PL_MAX);
 573
 574         self.owner.takedamage     = DAMAGE_AIM;
 575         self.owner.solid          = SOLID_SLIDEBOX;
 576         self.owner.movetype       = MOVETYPE_WALK;
 577         self.owner.effects        &~= EF_NODRAW;
 578         self.owner.alpha          = 1;
 579         self.owner.PlayerPhysplug = SUB_Null;
 580         self.owner.vehicle        = world;
 581         self.owner.view_ofs       = PL_VIEW_OFS;
 582         self.owner.event_damage   = PlayerDamage;
 583         self.owner.hud            = HUD_NORMAL;
 584         self.owner.switchweapon   = self.switchweapon;
 585         self.owner.BUTTON_USE     = 0;
 586     }
 587
 588     if(self.deadflag == DEAD_NO)
 589         self.avelocity          = '0 0 0';
 590
 591     self.vehicle_hudmodel.viewmodelforclient = self;
 592         self.tur_head.nodrawtoclient             = world;
 593     vehicles_setreturn();
 594
 595     self.phase = time + 1;
 596
 597     if(!teams_matter)
 598         self.team = 0;
 599
 600     self.vehicle_exit(eject);
 601     self.owner = world;
 602 }
 603
 604
 605 void vehicles_regen(.float timer, .float regen_field, float field_max, float rpause, float regen, float delta_time)
 606 {
 607     if(self.regen_field < field_max)
 608     if(self.timer + rpause < time)
 609     {
 610         self.regen_field = min(self.regen_field + regen * delta_time, field_max);
 611
 612         if(self.owner)
 613             self.owner.regen_field = (self.regen_field / field_max) * 100;
 614     }
 615 }
 616
 617 void shieldhit_think()
 618 {
 619     self.alpha -= 0.1;
 620     if (self.alpha <= 0)
 621     {
 622         //setmodel(self, "");
 623         self.alpha = -1;
 624     }
 625     else
 626     {
 627         self.nextthink = time + 0.1;
 628     }
 629 }
 630
 631 void vehicles_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 632 {
 633     self.dmg_time = time;
 634
 635     if((self.vehicle_flags & VHF_HASSHIELD) && (self.vehicle_shield > 0))
 636     {
 637         if (wasfreed(self.vehicle_shieldent) || self.vehicle_shieldent == world)
 638         {
 639             self.vehicle_shieldent = spawn();
 640             self.vehicle_shieldent.effects = EF_LOWPRECISION;
 641
 642             setmodel(self.vehicle_shieldent, "models/vhshield.md3");
 643             setattachment(self.vehicle_shieldent, self, "");
 644             setorigin(self.vehicle_shieldent, real_origin(self) - self.origin);
 645             self.vehicle_shieldent.scale       = 256 / vlen(self.maxs - self.mins);
 646             self.vehicle_shieldent.think       = shieldhit_think;
 647         }
 648
 649
 650         self.vehicle_shieldent.colormod    = '1 1 1';
 651         self.vehicle_shieldent.alpha       = 0.45;
 652         self.vehicle_shieldent.angles      = vectoangles(normalize(hitloc - (self.origin + self.vehicle_shieldent.origin))) - self.angles;
 653         self.vehicle_shieldent.nextthink   = time;
 654
 655         self.vehicle_shield -= damage;
 656
 657         if(self.vehicle_shield < 0)
 658         {
 659             self.vehicle_shieldent.colormod = '2 0 0';
 660             self.vehicle_shield             = 0;
 661             self.vehicle_shieldent.alpha    = 0.75;
 662             self.vehicle_health            -= fabs(self.vehicle_shield);
 663         }
 664     }
 665     else
 666         self.vehicle_health -= damage;
 667
 668     self.velocity += force; // * (vlen(force) / self.mass);
 669
 670     if(self.vehicle_health <= 0)
 671     {
 672         if(self.owner)
 673             if(self.vehicle_flags & VHF_DEATHEJECT)
 674                 vehicles_exit(VHEF_EJECT);
 675             else
 676                 vehicles_exit(VHEF_RELESE);
 677
 678         self.vehicle_die();
 679         vehicles_setreturn();
 680     }
 681 }
 682
 683 void vehicles_return()
 684 {
 685     pointparticles(particleeffectnum("teleport"), self.enemy.origin + '0 0 64', '0 0 0', 1);
 686
 687     self.enemy.think     = vehicles_spawn;
 688     self.enemy.nextthink = time;
 689
 690     remove(self);
 691 }
 692
 693 void vehicles_clearrturn()
 694 {
 695     entity ret;
 696     // Remove "return helper", if any.
 697     ret = findchain(classname, "vehicle_return");
 698     while(ret)
 699     {
 700         if(ret.enemy == self)
 701         {
 702             ret.classname   = "";
 703             ret.think       = SUB_Remove;
 704             ret.nextthink   = time + 0.1;
 705             return;
 706         }
 707         ret = ret.chain;
 708     }
 709 }
 710
 711 void vehicles_setreturn()
 712 {
 713     entity ret;
 714
 715     vehicles_clearrturn();
 716
 717     ret = spawn();
 718     ret.classname   = "vehicle_return";
 719     ret.enemy       = self;
 720     ret.think       = vehicles_return;
 721     ret.nextthink   = time + self.vehicle_respawntime;
 722 }
 723
 724 void vehicles_configcheck(string  configname, float check_cvar)
 725 {
 726     if(check_cvar == 0)
 727         localcmd(strcat("exec ", configname, "\n"));
 728 }
 729
 730 void vehicles_reset_colors()
 731 {
 732     entity e;
 733     float _effects, _colormap;
 734     vector _glowmod, _colormod;
 735
 736     if(autocvar_g_nodepthtestplayers)
 737         _effects = EF_NODEPTHTEST;
 738
 739     if(autocvar_g_fullbrightplayers)
 740         _effects |= EF_FULLBRIGHT;
 741
 742     if(self.team)
 743         _colormap = 1024 + (self.team - 1) * 17;
 744     else
 745         _colormap = 1024;
 746
 747     _glowmod  = '0 0 0';
 748     _colormod = '0 0 0';
 749
 750     // Find all ents attacked to main model and setup effects, colormod etc.
 751     e = findchainentity(tag_entity, self);
 752     while(e)
 753     {
 754         if(e != self.vehicle_shieldent)
 755         {
 756             e.effects   = _effects  | EF_LOWPRECISION;
 757             e.colormod  = _colormod;
 758             e.colormap  = _colormap;
 759             e.alpha     = 1;
 760         }
 761         e = e.chain;
 762     }
 763
 764     self.vehicle_hudmodel.effects  = self.effects  = _effects | EF_LOWPRECISION;
 765     self.vehicle_hudmodel.colormod = self.colormod = _colormod;
 766     self.vehicle_hudmodel.colormap = self.colormap = _colormap;
 767     self.vehicle_viewport.effects = (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NOGUNBOB | EF_NOSHADOW | EF_LOWPRECISION | EF_SELECTABLE | EF_TELEPORT_BIT);
 768
 769     self.alpha     = 1;
 770     self.avelocity = '0 0 0';
 771     self.velocity  = '0 0 0';
 772     self.effects   = _effects;
 773 }
 774
 775 float vehicle_initialize(string  net_name,
 776                          string  bodymodel,
 777                          string  topmodel,
 778                          string  hudmodel,
 779                          string  toptag,
 780                          string  hudtag,
 781                          string  viewtag,
 782                          float   vhud,
 783                          vector  min_s,
 784                          vector  max_s,
 785                          float   nodrop,
 786                          void()  spawnproc,
 787                          float   _respawntime,
 788                          float() physproc,
 789                          void()  enterproc,
 790                          void(float extflag) exitfunc,
 791                          void() dieproc,
 792                          void() thinkproc,
 793                          float  use_csqc)
 794 {
 795     addstat(STAT_HUD, AS_INT,  hud);
 796         addstat(STAT_VEHICLESTAT_HEALTH,  AS_INT, vehicle_health);
 797         addstat(STAT_VEHICLESTAT_SHIELD,  AS_INT, vehicle_shield);
 798         addstat(STAT_VEHICLESTAT_ENERGY,  AS_INT, vehicle_energy);
 799
 800         addstat(STAT_VEHICLESTAT_AMMO1,   AS_INT,   vehicle_ammo1);
 801         addstat(STAT_VEHICLESTAT_RELOAD1, AS_INT, vehicle_reload1);
 802
 803         addstat(STAT_VEHICLESTAT_AMMO2,   AS_INT,   vehicle_ammo2);
 804         addstat(STAT_VEHICLESTAT_RELOAD2, AS_INT, vehicle_reload2);
 805
 806     if(bodymodel == "")
 807         error("vehicles: missing bodymodel!");
 808
 809     if(hudmodel == "")
 810         error("vehicles: missing hudmodel!");
 811
 812     if(net_name == "")
 813         self.netname = self.classname;
 814     else
 815         self.netname = net_name;
 816
 817     if(self.team && !teams_matter)
 818         self.team = 0;
 819
 820     self.vehicle_flags |= VHF_ISVEHICLE;
 821
 822     setmodel(self, bodymodel);
 823
 824     self.vehicle_viewport   = spawn();
 825     self.vehicle_hudmodel   = spawn();
 826     self.tur_head           = spawn();
 827     self.tur_head.owner     = self;
 828     self.takedamage         = DAMAGE_AIM;
 829     self.bot_attack         = TRUE;
 830     self.iscreature         = TRUE;
 831     self.hud                = vhud;
 832
 833     self.vehicle_die         = dieproc;
 834     self.vehicle_exit        = exitfunc;
 835     self.vehicle_enter       = enterproc;
 836     self.PlayerPhysplug      = physproc;
 837     self.event_damage        = vehicles_damage;
 838     self.touch               = vehicles_touch;
 839     self.think               = vehicles_spawn;
 840     self.nextthink           = time;
 841     self.vehicle_respawntime = _respawntime;
 842     self.vehicle_spawn       = spawnproc;
 843
 844     if(autocvar_g_nodepthtestplayers)
 845         self.effects = self.effects | EF_NODEPTHTEST;
 846
 847     if(autocvar_g_fullbrightplayers)
 848         self.effects = self.effects | EF_FULLBRIGHT;
 849
 850     setmodel(self.vehicle_hudmodel, hudmodel);
 851     setmodel(self.vehicle_viewport, "null");
 852
 853
 854     if(topmodel != "")
 855     {
 856         setmodel(self.tur_head, topmodel);
 857         setattachment(self.tur_head, self, toptag);
 858         setattachment(self.vehicle_hudmodel, self.tur_head, hudtag);
 859         setattachment(self.vehicle_viewport, self.vehicle_hudmodel, viewtag);
 860     }
 861     else
 862     {
 863         setattachment(self.tur_head, self, "");
 864         setattachment(self.vehicle_hudmodel, self, hudtag);
 865         setattachment(self.vehicle_viewport, self.vehicle_hudmodel, viewtag);
 866     }
 867
 868     setsize(self, min_s, max_s);
 869     if not (nodrop)
 870     {
 871         setorigin(self, self.origin);
 872         tracebox(self.origin + '0 0 100', min_s, max_s, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
 873         setorigin(self, trace_endpos);
 874     }
 875
 876     self.pos1 = self.origin;
 877     self.pos2 = self.angles;
 878
 879     return TRUE;
 880 }
 881
 882 void bugmenot()
 883 {
 884     self.vehicle_exit       = self.vehicle_exit;
 885     self.vehicle_enter      = self.vehicle_exit;
 886     self.vehicle_die        = self.vehicle_exit;
 887     self.vehicle_spawn      = self.vehicle_exit;
 888     self.AuxiliaryXhair     = self.AuxiliaryXhair;
 889 }