qcsrc/server/vehicles/vehicles.qc

   1 float autocvar_g_vehicles_crush_dmg;
   2 float autocvar_g_vehicles_crush_force;
   3
   4 void vehicles_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force);
   5 void vehicles_return();
   6 void vehicles_enter();
   7 void vehicles_touch();
   8 void vehicles_reset_colors();
   9 void vehicles_clearrturn();
  10 void vehicles_setreturn();
  11
  12
  13 /** AuxiliaryXhair*
  14     Send addictional points of interest to be drawn, to vehicle owner
  15 **/
  16 float MAX_AXH = 4;
  17 .entity AuxiliaryXhair[MAX_AXH];
  18
  19 float SendAuxiliaryXhair(entity to, float sf)
  20 {
  21
  22         WriteByte(MSG_ENTITY, ENT_CLIENT_AUXILIARYXHAIR);
  23
  24         WriteByte(MSG_ENTITY, self.cnt);
  25
  26         WriteCoord(MSG_ENTITY, self.origin_x);
  27         WriteCoord(MSG_ENTITY, self.origin_y);
  28         WriteCoord(MSG_ENTITY, self.origin_z);
  29
  30     WriteByte(MSG_ENTITY, rint(self.colormod_x * 255));
  31     WriteByte(MSG_ENTITY, rint(self.colormod_y * 255));
  32     WriteByte(MSG_ENTITY, rint(self.colormod_z * 255));
  33
  34     return TRUE;
  35 }
  36
  37 void UpdateAuxiliaryXhair(entity own, vector loc, vector clr, float axh_id)
  38 {
  39     entity axh;
  40
  41     axh_id = bound(0, axh_id, MAX_AXH);
  42     axh = own.AuxiliaryXhair[axh_id];
  43
  44     if(axh == world || wasfreed(axh))  // MADNESS? THIS IS QQQQCCCCCCCCC (wasfreed, why do you exsist?)
  45     {
  46         axh                     = spawn();
  47         axh.cnt                 = axh_id;
  48         axh.drawonlytoclient    = own;
  49         axh.owner               = own;
  50         Net_LinkEntity(axh, FALSE, 0, SendAuxiliaryXhair);
  51     }
  52
  53     setorigin(axh, loc);
  54     axh.colormod            = clr;
  55     axh.SendFlags           = 0x01;
  56     own.AuxiliaryXhair[axh_id] = axh;
  57 }
  58
  59 /*
  60 // SVC_TEMPENTITY based, horrible with even 50 ping. hm.
  61 // WriteByte(MSG_ONE, SVC_TEMPENTITY) uses reliable messagess, never use for thinsg that need continous updates.
  62 void SendAuxiliaryXhair2(entity own, vector loc, vector clr, float axh_id)
  63 {
  64         msg_entity = own;
  65
  66         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  67         WriteByte(MSG_ONE, TE_CSQC_AUXILIARYXHAIR);
  68
  69         WriteByte(MSG_ONE, axh_id);
  70
  71         WriteCoord(MSG_ONE, loc_x);
  72         WriteCoord(MSG_ONE, loc_y);
  73         WriteCoord(MSG_ONE, loc_z);
  74
  75     WriteByte(MSG_ONE, rint(clr_x * 255));
  76     WriteByte(MSG_ONE, rint(clr_y * 255));
  77     WriteByte(MSG_ONE, rint(clr_z * 255));
  78
  79 }
  80 */
  81 // End AuxiliaryXhair
  82
  83 void CSQCVehicleSetup(entity own, float vehicle_id)
  84 {
  85         msg_entity = own;
  86
  87         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  88         WriteByte(MSG_ONE, TE_CSQC_VEHICLESETUP);
  89         WriteByte(MSG_ONE, vehicle_id);
  90 }
  91
  92 /** vehicles_locktarget
  93
  94     Generic target locking.
  95
  96     Figure out if what target is "locked" (if any), for missile tracking as such.
  97
  98     after calling, "if(self.lock_target != world && self.lock_strength == 1)" mean
  99     you have a locked in target.
 100
 101     Exspects a crosshair_trace() or equivalent to be
 102     dont before calling.
 103
 104 **/
 105 .entity lock_target;
 106 .float  lock_strength;
 107 .float  lock_time;
 108 void vehicles_locktarget(float incr, float decr, float _lock_time)
 109 {
 110     if(self.lock_target && self.lock_target.deadflag != DEAD_NO)
 111     {
 112         self.lock_target    = world;
 113         self.lock_strength  = 0;
 114         self.lock_time      = 0;
 115     }
 116
 117     if(self.lock_time > time)
 118         return;
 119
 120     if(trace_ent != world)
 121     {
 122         if(teams_matter && trace_ent.team == self.team)
 123             trace_ent = world;
 124
 125         if(trace_ent.deadflag != DEAD_NO)
 126             trace_ent = world;
 127
 128         if not (trace_ent.vehicle_flags & VHF_ISVEHICLE || trace_ent.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 129             trace_ent = world;
 130     }
 131
 132     if(self.lock_target == world && trace_ent != world)
 133         self.lock_target = trace_ent;
 134
 135     // Have a locking target
 136     // Trace hit current target
 137     if(trace_ent == self.lock_target && trace_ent != world)
 138     {
 139         self.lock_strength = min(self.lock_strength + incr, 1);
 140         if(self.lock_strength == 1)
 141             self.lock_time = time + _lock_time;
 142     }
 143     else
 144     {
 145         if(trace_ent)
 146             self.lock_strength = max(self.lock_strength - decr * 2, 0);
 147         else
 148             self.lock_strength = max(self.lock_strength - decr, 0);
 149
 150         if(self.lock_strength == 0)
 151             self.lock_target = world;
 152     }
 153 }
 154
 155 #define VEHICLE_UPDATE_PLAYER(fld,vhname) \
 156 self.owner.vehicle_##fld = (self.vehicle_##fld / autocvar_g_vehicle_##vhname##_##fld) * 100
 157
 158 #define vehicles_sweap_collision(orig,vel,dt,acm,mult) \
 159 traceline(orig, orig + vel * dt, MOVE_NORMAL, self); \
 160 if(trace_fraction != 1) \
 161     acm += normalize(self.origin - trace_endpos) * (vlen(vel) * mult)
 162
 163 // Hover movement support
 164 float  force_fromtag_power;
 165 float  force_fromtag_normpower;
 166 vector force_fromtag_origin;
 167 vector vehicles_force_fromtag_hover(string tag_name, float spring_length, float max_power)
 168 {
 169     force_fromtag_origin = gettaginfo(self, gettagindex(self, tag_name));
 170     v_forward  = normalize(v_forward) * -1;
 171     traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, self);
 172
 173     force_fromtag_power = (1 - trace_fraction) * max_power;
 174     force_fromtag_normpower = force_fromtag_power / max_power;
 175
 176     return v_forward  * force_fromtag_power;
 177 }
 178
 179 // Experimental hovermode wich uses attraction/repulstion from surface unsted of gravity/repulsion
 180 // Can possibly be use to move abt any surface (inclusing walls/celings)
 181 vector vehicles_force_fromtag_maglev(string tag_name, float spring_length, float max_power)
 182 {
 183
 184     force_fromtag_origin = gettaginfo(self, gettagindex(self, tag_name));
 185     v_forward  = normalize(v_forward) * -1;
 186     traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, self);
 187
 188     // TODO - this may NOT be compatible with wall/celing movement, unhardcode 0.25 (engine count multiplier)
 189     if(trace_fraction == 1.0)
 190     {
 191         force_fromtag_normpower = -0.25;
 192         return '0 0 -200';
 193     }
 194
 195     force_fromtag_power = ((1 - trace_fraction) - trace_fraction) * max_power;
 196     force_fromtag_normpower = force_fromtag_power / max_power;
 197
 198     return v_forward  * force_fromtag_power;
 199 }
 200
 201 // Generic vehile projectile system
 202 void vehicles_projectile_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 203 {
 204     self.health -= damage;
 205     self.velocity += force;
 206     if(self.health < 1)
 207     {
 208         self.takedamage = DAMAGE_NO;
 209         self.event_damage = SUB_Null;
 210         self.think = self.use;
 211         self.nextthink = time;
 212     }
 213
 214 }
 215
 216 void vehicles_projectile_explode()
 217 {
 218     if(self.owner && other != world)
 219     {
 220         if(other == self.owner.vehicle)
 221             return;
 222
 223         if(other == self.owner.vehicle.tur_head)
 224             return;
 225     }
 226
 227         PROJECTILE_TOUCH;
 228
 229         self.event_damage = SUB_Null;
 230     RadiusDamage (self, self.realowner, self.shot_dmg, 0, self.shot_radius, self, self.shot_force, self.totalfrags, other);
 231
 232     remove (self);
 233 }
 234
 235 entity vehicles_projectile(string _mzlfx, string _mzlsound,
 236                            vector _org, vector _vel,
 237                            float _dmg, float _radi, float _force,  float _size,
 238                            float _deahtype, float _projtype, float _health,
 239                            float _cull, float _clianim)
 240 {
 241     entity proj;
 242
 243     proj = spawn();
 244
 245     PROJECTILE_MAKETRIGGER(proj);
 246     setorigin(proj, _org);
 247
 248     proj.shot_dmg         = _dmg;
 249     proj.shot_radius      = _radi;
 250     proj.shot_force       = _force;
 251     proj.totalfrags       = _deahtype;
 252     proj.solid            = SOLID_BBOX;
 253     proj.movetype         = MOVETYPE_FLYMISSILE;
 254     proj.flags            = FL_PROJECTILE;
 255     proj.bot_dodge        = TRUE;
 256     proj.bot_dodgerating  = _dmg;
 257     proj.velocity         = _vel;
 258     proj.touch            = vehicles_projectile_explode;
 259     proj.use              = vehicles_projectile_explode;
 260     proj.owner            = self;
 261     proj.realowner        = self.owner;
 262     proj.think            = SUB_Remove;
 263     proj.nextthink        = time + 30;
 264
 265     if(_health)
 266     {
 267         proj.takedamage       = DAMAGE_AIM;
 268         proj.event_damage     = vehicles_projectile_damage;
 269         proj.health           = _health;
 270     }
 271     else
 272         proj.flags           = FL_PROJECTILE | FL_NOTARGET;
 273
 274     if(_mzlsound)
 275         sound (self, CHAN_WEAPON, _mzlsound, VOL_BASE, ATTN_NORM);
 276
 277     if(_mzlfx)
 278         pointparticles(particleeffectnum(_mzlfx), proj.origin, proj.velocity, 1);
 279
 280
 281     setsize (proj, '-1 -1 -1' * _size, '1 1 1' * _size);
 282
 283     CSQCProjectile(proj, _clianim, _projtype, _cull);
 284
 285     return proj;
 286 }
 287 // End generic vehile projectile system
 288
 289 /** vehicles_spawn
 290     Exetuted for all vehiles on (re)spawn.
 291     Sets defaults for newly spawned units.
 292 **/
 293 void vehicles_spawn()
 294 {
 295     dprint("Spawning vehicle: ", self.netname, "\n");
 296
 297     // De-own & reset
 298     self.vehicle_hudmodel.viewmodelforclient = self;
 299
 300     self.owner              = world;
 301     self.touch              = vehicles_touch;
 302     self.event_damage       = vehicles_damage;
 303     self.iscreature         = TRUE;
 304     self.movetype           = MOVETYPE_WALK;
 305     self.solid              = SOLID_SLIDEBOX;
 306     self.takedamage         = DAMAGE_AIM;
 307         self.deadflag           = DEAD_NO;
 308     self.bot_attack         = TRUE;
 309     self.flags              = FL_NOTARGET;
 310     self.avelocity          = '0 0 0';
 311
 312     // Reset locking
 313     self.lock_strength      = 0;
 314     self.lock_target        = world;
 315     self.misc_bulletcounter = 0;
 316
 317     // Return to spawn
 318     self.angles             = self.pos2;
 319     setorigin(self, self.pos1 + '0 0 128');
 320     // Show it
 321     pointparticles(particleeffectnum("teleport"), self.origin + '0 0 64', '0 0 0', 1);
 322
 323     vehicles_reset_colors();
 324     self.vehicle_spawn();
 325 }
 326
 327 // Better way of determening whats crushable needed! (fl_crushable?)
 328 float vehicles_crushable(entity e)
 329 {
 330     if(e.classname == "player")
 331         return TRUE;
 332
 333     if(e.classname == "monster_zombie")
 334         return TRUE;
 335
 336     return FALSE;
 337 }
 338
 339 void vehicles_touch()
 340 {
 341     // Vehicle currently in use
 342     if(self.owner)
 343     {
 344         // Colided with world?
 345         if(other == world)
 346         {
 347             // Apply velocity based self damage here
 348         }
 349         else
 350         {
 351             if(other.vehicle_flags & VHF_ISVEHICLE)
 352             {
 353                 //other.velocity += self.velocity * (self.mass / other.mass);
 354             }
 355             else if(vehicles_crushable(other))
 356             {
 357                 if(vlen(self.velocity) != 0)
 358                     Damage(other, self, self.owner, autocvar_g_vehicles_crush_dmg, DEATH_VHCRUSH, '0 0 0', normalize(other.origin - self.origin) * autocvar_g_vehicles_crush_force);
 359             }
 360         }
 361         return;
 362     }
 363
 364     if(other.classname != "player")
 365         return;
 366
 367     if(other.deadflag != DEAD_NO)
 368         return;
 369
 370     if(other.vehicle != world)
 371         return;
 372
 373     // Remove this when bots know how to use vehicles.
 374     if (clienttype(other) != CLIENTTYPE_REAL)
 375         return;
 376
 377     vehicles_enter();
 378 }
 379
 380 void vehicles_enter()
 381 {
 382    // Remove this when bots know how to use vehicles
 383     if (clienttype(other) != CLIENTTYPE_REAL)
 384         return;
 385
 386     if(self.phase > time)
 387         return;
 388
 389     if(teams_matter)
 390     if(self.team)
 391     if(self.team != other.team)
 392         return;
 393
 394     self.vehicle_ammo1   = 0;
 395     self.vehicle_ammo2   = 0;
 396     self.vehicle_reload1 = 0;
 397     self.vehicle_reload2 = 0;
 398     self.vehicle_energy  = 0;
 399
 400     self.owner          = other;
 401     self.switchweapon   = other.switchweapon;
 402
 403     // .viewmodelforclient works better.
 404     //self.vehicle_hudmodel.drawonlytoclient = self.owner;
 405
 406     self.vehicle_hudmodel.viewmodelforclient = self.owner;
 407
 408     self.event_damage         = vehicles_damage;
 409     self.nextthink            = 0;
 410     self.owner.angles         = self.angles;
 411     self.owner.takedamage     = DAMAGE_NO;
 412     self.owner.solid          = SOLID_NOT;
 413     self.owner.movetype       = MOVETYPE_NOCLIP;
 414     self.owner.alpha          = -1;
 415     self.owner.vehicle        = self;
 416     self.owner.event_damage   = SUB_Null;
 417     self.owner.view_ofs       = '0 0 0';
 418     self.colormap             = self.owner.colormap;
 419     if(self.tur_head)
 420         self.tur_head.colormap    = self.owner.colormap;
 421
 422     self.owner.hud            = self.hud;
 423     self.owner.PlayerPhysplug = self.PlayerPhysplug;
 424
 425     self.owner.vehicle_ammo1    = self.vehicle_ammo1;
 426     self.owner.vehicle_ammo2    = self.vehicle_ammo2;
 427     self.owner.vehicle_reload1  = self.vehicle_reload1;
 428     self.owner.vehicle_reload2  = self.vehicle_reload2;
 429
 430     // Cnnt do this, hides attached objects too.
 431     //self.exteriormodeltoclient = self.owner;
 432     //self.tur_head.exteriormodeltoclient = self.owner;
 433
 434     other.flags &~= FL_ONGROUND;
 435     self.flags  &~= FL_ONGROUND;
 436
 437     self.team                 = self.owner.team;
 438     self.flags               -= FL_NOTARGET;
 439
 440 #if 0
 441     other.clientcamera = self.vehicle_viewport;
 442 #else
 443     msg_entity = other;
 444     WriteByte (MSG_ONE, SVC_SETVIEWPORT);
 445     WriteEntity(MSG_ONE, self.vehicle_viewport);
 446
 447     WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
 448     if(self.tur_head)
 449     {
 450         WriteAngle(MSG_ONE, self.tur_head.angles_x + self.angles_x); // tilt
 451         WriteAngle(MSG_ONE, self.tur_head.angles_y + self.angles_y); // yaw
 452         WriteAngle(MSG_ONE, 0);                                      // roll
 453     }
 454     else
 455     {
 456         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
 457         WriteAngle(MSG_ONE,  self.angles_x * -1); // tilt
 458         WriteAngle(MSG_ONE,  self.angles_y);      // yaw
 459         WriteAngle(MSG_ONE,  0);                  // roll
 460     }
 461 #endif
 462
 463     vehicles_clearrturn();
 464
 465     CSQCVehicleSetup(self.owner, self.hud);
 466
 467     self.vehicle_enter();
 468 }
 469
 470 void vehicles_exit(float eject)
 471 {
 472         self.flags |= FL_NOTARGET;
 473
 474     if (self.owner)
 475     {
 476         msg_entity = self.owner;
 477         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
 478         WriteEntity( MSG_ONE, self.owner);
 479
 480         WriteByte (MSG_ONE, SVC_SETVIEWANGLES); // 10 = SVC_SETVIEWANGLES
 481         WriteAngle(MSG_ONE, 0);                 // tilt
 482         WriteAngle(MSG_ONE, self.angles_y);     // yaw
 483         WriteAngle(MSG_ONE, 0);                 // roll
 484
 485         setsize(self.owner, PL_MIN,PL_MAX);
 486
 487         self.owner.takedamage     = DAMAGE_AIM;
 488         self.owner.solid          = SOLID_SLIDEBOX;
 489         self.owner.movetype       = MOVETYPE_WALK;
 490         self.owner.effects        &~= EF_NODRAW;
 491         self.owner.alpha          = 1;
 492         self.owner.PlayerPhysplug = SUB_Null;
 493         self.owner.vehicle        = world;
 494         self.owner.view_ofs       = PL_VIEW_OFS;
 495         self.owner.event_damage   = PlayerDamage;
 496         self.owner.hud            = HUD_NORMAL;
 497         self.owner.switchweapon   = self.switchweapon;
 498         self.owner.BUTTON_USE     = 0;
 499     }
 500
 501     if(self.deadflag == DEAD_NO)
 502         self.avelocity          = '0 0 0';
 503
 504     self.vehicle_hudmodel.viewmodelforclient = self;
 505         self.tur_head.nodrawtoclient             = world;
 506     vehicles_setreturn();
 507
 508     self.phase = time + 1;
 509
 510     if(!teams_matter)
 511         self.team = 0;
 512
 513     self.vehicle_exit(eject);
 514     self.owner = world;
 515 }
 516
 517
 518 void vehicles_regen(.float timer, .float regen_field, float field_max, float rpause, float regen, float delta_time)
 519 {
 520     if(self.regen_field < field_max)
 521     if(self.timer + rpause < time)
 522     {
 523         self.regen_field = min(self.regen_field + regen * delta_time, field_max);
 524
 525         if(self.owner)
 526             self.owner.regen_field = (self.regen_field / field_max) * 100;
 527     }
 528 }
 529
 530 void shieldhit_think()
 531 {
 532     self.alpha -= 0.1;
 533     if (self.alpha <= 0)
 534     {
 535         //setmodel(self, "");
 536         self.alpha = -1;
 537     }
 538     else
 539     {
 540         self.nextthink = time + 0.1;
 541     }
 542 }
 543
 544 void vehicles_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 545 {
 546     self.dmg_time = time;
 547
 548     if((self.vehicle_flags & VHF_HASSHIELD) && (self.vehicle_shield > 0))
 549     {
 550         if (wasfreed(self.vehicle_shieldent) || self.vehicle_shieldent == world)
 551         {
 552             self.vehicle_shieldent = spawn();
 553             self.vehicle_shieldent.effects = EF_LOWPRECISION;
 554
 555             setmodel(self.vehicle_shieldent, "models/vhshield.md3");
 556             setattachment(self.vehicle_shieldent, self, "");
 557             setorigin(self.vehicle_shieldent, real_origin(self) - self.origin);
 558             self.vehicle_shieldent.scale       = 256 / vlen(self.maxs - self.mins);
 559             self.vehicle_shieldent.think       = shieldhit_think;
 560         }
 561
 562
 563         self.vehicle_shieldent.colormod    = '1 1 1';
 564         self.vehicle_shieldent.alpha       = 0.45;
 565         self.vehicle_shieldent.angles      = vectoangles(normalize(hitloc - (self.origin + self.vehicle_shieldent.origin))) - self.angles;
 566         self.vehicle_shieldent.nextthink   = time;
 567
 568         self.vehicle_shield -= damage;
 569
 570         if(self.vehicle_shield < 0)
 571         {
 572             self.vehicle_shieldent.colormod = '2 0 0';
 573             self.vehicle_shield             = 0;
 574             self.vehicle_shieldent.alpha    = 0.75;
 575             self.vehicle_health            -= fabs(self.vehicle_shield);
 576         }
 577     }
 578     else
 579         self.vehicle_health -= damage;
 580
 581     self.velocity += force; // * (vlen(force) / self.mass);
 582
 583     if(self.vehicle_health <= 0)
 584     {
 585         if(self.owner)
 586             if(self.vehicle_flags & VHF_DEATHEJECT)
 587                 vehicles_exit(VHEF_EJECT);
 588             else
 589                 vehicles_exit(VHEF_RELESE);
 590
 591         self.vehicle_die();
 592         vehicles_setreturn();
 593     }
 594 }
 595
 596 void vehicles_return()
 597 {
 598     pointparticles(particleeffectnum("teleport"), self.enemy.origin + '0 0 64', '0 0 0', 1);
 599
 600     self.enemy.think     = vehicles_spawn;
 601     self.enemy.nextthink = time;
 602
 603     remove(self);
 604 }
 605
 606 void vehicles_clearrturn()
 607 {
 608     entity ret;
 609     // Remove "return helper", if any.
 610     ret = findchain(classname, "vehicle_return");
 611     while(ret)
 612     {
 613         if(ret.enemy == self)
 614         {
 615             ret.classname   = "";
 616             ret.think       = SUB_Remove;
 617             ret.nextthink   = time + 0.1;
 618             return;
 619         }
 620
 621         ret = ret.chain;
 622     }
 623 }
 624
 625 void vehicles_setreturn()
 626 {
 627     entity ret;
 628
 629     vehicles_clearrturn();
 630
 631     ret = spawn();
 632     ret.classname   = "vehicle_return";
 633     ret.enemy       = self;
 634     ret.think       = vehicles_return;
 635     ret.nextthink   = time + self.vehicle_respawntime;
 636 }
 637
 638 float vehicles_customizeentityforclient()
 639 {
 640     if(self.deadflag  == DEAD_DEAD)
 641         return FALSE;
 642     else
 643         return TRUE;
 644 }
 645
 646 void vehicles_configcheck(string  configname, float check_cvar)
 647 {
 648     if(check_cvar == 0)
 649         localcmd(strcat("exec ", configname, "\n"));
 650 }
 651
 652 void vehicles_reset_colors()
 653 {
 654     entity e;
 655     float _effects, _colormap;
 656     vector _glowmod, _colormod;
 657
 658     if(autocvar_g_nodepthtestplayers)
 659         _effects = EF_NODEPTHTEST;
 660
 661     if(autocvar_g_fullbrightplayers)
 662         _effects |= EF_FULLBRIGHT;
 663
 664     if(self.team)
 665         _colormap = 1024 + (self.team - 1) * 17;
 666     else
 667         _colormap = 1024;
 668
 669     _glowmod    = '0 0 0';
 670     _colormod   = '0 0 0';
 671
 672     // Find all ents attacked to main model and setup effects, colormod etc.
 673     e = findchainentity(tag_entity, self);
 674     while(e)
 675     {
 676         if(e != self.vehicle_shieldent)
 677         {
 678             e.effects   = _effects  | EF_LOWPRECISION;
 679             e.colormod  = _colormod;
 680             e.colormap  = _colormap;
 681             e.alpha     = 1;
 682         }
 683         e = e.chain;
 684     }
 685
 686     self.vehicle_hudmodel.effects  = self.effects  = _effects | EF_LOWPRECISION;
 687     self.vehicle_hudmodel.colormod = self.colormod = _colormod;
 688     self.vehicle_hudmodel.colormap = self.colormap = _colormap;
 689     self.vehicle_viewport.effects = (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NOGUNBOB | EF_NOSHADOW | EF_LOWPRECISION | EF_SELECTABLE | EF_TELEPORT_BIT);
 690
 691     self.alpha          = 1;
 692     self.avelocity      = '0 0 0';
 693     self.velocity       = '0 0 0';
 694     self.effects        = _effects;
 695 }
 696
 697 float vehicle_initialize(string  net_name,
 698                          string  bodymodel,
 699                          string  topmodel,
 700                          string  hudmodel,
 701                          string  toptag,
 702                          string  hudtag,
 703                          string  viewtag,
 704                          float   vhud,
 705                          vector min_s,
 706                          vector max_s,
 707                          float  nodrop,
 708                          void()  spawnproc,
 709                          float   _respawntime,
 710                          float() physproc,
 711                          void()  enterproc,
 712                          void(float extflag) exitfunc,
 713                          void() dieproc,
 714                          void() thinkproc )
 715 {
 716     addstat(STAT_HUD, AS_INT,  hud);
 717         addstat(STAT_VEHICLESTAT_HEALTH,  AS_INT, vehicle_health);
 718         addstat(STAT_VEHICLESTAT_SHIELD,  AS_INT, vehicle_shield);
 719         addstat(STAT_VEHICLESTAT_ENERGY,  AS_INT, vehicle_energy);
 720
 721         addstat(STAT_VEHICLESTAT_AMMO1,   AS_INT,   vehicle_ammo1);
 722         addstat(STAT_VEHICLESTAT_RELOAD1, AS_INT, vehicle_reload1);
 723
 724         addstat(STAT_VEHICLESTAT_AMMO2,   AS_INT,   vehicle_ammo2);
 725         addstat(STAT_VEHICLESTAT_RELOAD2, AS_INT, vehicle_reload2);
 726
 727     if(bodymodel == "")
 728         error("vehicles: missing bodymodel!");
 729
 730     if(hudmodel == "")
 731         error("vehicles: missing hudmodel!");
 732
 733     if(net_name == "")
 734         self.netname = self.classname;
 735     else
 736         self.netname = net_name;
 737
 738     if(self.team && !teams_matter)
 739         self.team = 0;
 740
 741     self.vehicle_flags |= VHF_ISVEHICLE;
 742
 743     setmodel(self, bodymodel);
 744
 745     self.vehicle_viewport   = spawn();
 746     self.vehicle_hudmodel   = spawn();
 747     self.tur_head           = spawn();
 748     self.tur_head.owner     = self;
 749     self.takedamage         = DAMAGE_AIM;
 750     self.bot_attack         = TRUE;
 751     self.iscreature         = TRUE;
 752     self.hud                = vhud;
 753
 754     //self.customizeentityforclient = vehicles_customizeentityforclient;
 755     self.vehicle_die         = dieproc;
 756     self.vehicle_exit        = exitfunc;
 757     self.vehicle_enter       = enterproc;
 758     self.PlayerPhysplug      = physproc;
 759     self.event_damage        = vehicles_damage;
 760     self.touch               = vehicles_touch;
 761     self.think               = vehicles_spawn;
 762     self.nextthink           = time;
 763     self.vehicle_respawntime = _respawntime;
 764     self.vehicle_spawn       = spawnproc;
 765
 766     if(autocvar_g_nodepthtestplayers)
 767         self.effects = self.effects | EF_NODEPTHTEST;
 768
 769     if(autocvar_g_fullbrightplayers)
 770         self.effects = self.effects | EF_FULLBRIGHT;
 771
 772     setmodel(self.vehicle_hudmodel, hudmodel);
 773     setmodel(self.vehicle_viewport, "null");
 774
 775
 776     if(topmodel != "")
 777     {
 778         setmodel(self.tur_head, topmodel);
 779         setattachment(self.tur_head, self, toptag);
 780         setattachment(self.vehicle_hudmodel, self.tur_head, hudtag);
 781         setattachment(self.vehicle_viewport, self.vehicle_hudmodel, viewtag);
 782     }
 783     else
 784     {
 785         setattachment(self.tur_head, self, "");
 786         setattachment(self.vehicle_hudmodel, self, hudtag);
 787         setattachment(self.vehicle_viewport, self.vehicle_hudmodel, viewtag);
 788     }
 789
 790     setsize(self, min_s, max_s);
 791     if not (nodrop)
 792     {
 793         setorigin(self, self.origin);
 794         tracebox(self.origin + '0 0 100', min_s, max_s, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
 795         setorigin(self, trace_endpos);
 796     }
 797
 798     //self.vehicle_hudmodel.effects = EF_NODEPTHTEST;
 799     self.pos1 = self.origin;
 800     self.pos2 = self.angles;
 801
 802     return TRUE;
 803 }
 804
 805
 806 void bugmenot()
 807 {
 808     self.vehicle_exit       = self.vehicle_exit;
 809     self.vehicle_enter      = self.vehicle_exit;
 810     self.vehicle_die        = self.vehicle_exit;
 811     self.vehicle_spawn      = self.vehicle_exit;
 812     self.AuxiliaryXhair     = self.AuxiliaryXhair;
 813 }
 814
 815 #ifdef VEHICLES_CSQC
 816 // SendFlags
 817 float VSF_SETUP       = 2;          /// Send vehicle type etc
 818 float VSF_ORIGIN      = 4;          /// Send location
 819 float VSF_MOVEMENT    = 8;          /// Send movement update (and angle/avelocity)
 820 float VSF_STATS       = 16;         /// Send ammo, health etc
 821 float VSF_EXTRA       = 32;         /// Send additional data (turret rotations and such). Handeld per vehicle type.
 822 float VSF_ANIMINFO    = 64;         /// Animation info
 823 float VSF_FULL_UPDATE = 16777215    /// Send everything
 824
 825 #ifdef SVQC
 826 float send_vehile(entity to, float sf)
 827 {
 828         float dist;
 829
 830         // Always send a compleate update to owner, minus VSF_SETUP
 831         if(to == self.owner && self.owner != world && sf != VSF_FULL_UPDATE)
 832         sf |= (VSF_FULL_UPDATE &~= VSF_SETUP);
 833
 834     dist = vlen(self.origin - to.origin);
 835     // TODO: Distance based message filtering
 836
 837         WriteByte(MSG_ENTITY, ENT_CLIENT_VEHICLE);
 838
 839         // We need to know client-side what was sent
 840         WriteByte(MSG_ENTITY, sf);
 841
 842         if(sf & VSF_SETUP)
 843         {
 844         WriteByte(MSG_ENTITY,   self.hud);        //vehicle type = hud
 845         WriteByte(MSG_ENTITY,   self.team);
 846         WriteShort(MSG_ENTITY,  self.colormap);
 847         }
 848
 849     if(sf & VSF_ORIGIN)
 850     {
 851         WriteCoord(MSG_ENTITY, self.origin_x);
 852         WriteCoord(MSG_ENTITY, self.origin_y);
 853         WriteCoord(MSG_ENTITY, self.origin_z);
 854     }
 855
 856     if(sf & VSF_MOVEMENT)
 857     {
 858         WriteCoord(MSG_ENTITY, self.velocity_x);
 859         WriteCoord(MSG_ENTITY, self.velocity_y);
 860         WriteCoord(MSG_ENTITY, self.velocity_z);
 861
 862         WriteAngle(MSG_ENTITY, self.angles_x);
 863         WriteAngle(MSG_ENTITY, self.angles_y);
 864         WriteAngle(MSG_ENTITY, self.angles_z);
 865
 866         WriteCoord(MSG_ENTITY, self.avelocity_x);
 867         WriteCoord(MSG_ENTITY, self.avelocity_y);
 868         WriteCoord(MSG_ENTITY, self.avelocity_z);
 869     }
 870
 871     /*
 872     if(sf & VSF_STATS)
 873     {
 874         WriteByte(MSG_ENTITY, self.vehicle_health);
 875         WriteByte(MSG_ENTITY, self.vehicle_shield);
 876         WriteByte(MSG_ENTITY, self.vehicle_energy);
 877
 878         WriteByte(MSG_ENTITY, self.vehicle_ammo1);
 879         WriteByte(MSG_ENTITY, self.vehicle_reload1);
 880
 881         WriteByte(MSG_ENTITY, self.vehicle_ammo2);
 882         WriteByte(MSG_ENTITY, self.vehicle_reload2);
 883     }
 884     */
 885
 886     if(sf & VSF_EXTRA)
 887     {
 888         self.vehile_send_exta(to);
 889     }
 890
 891     return TRUE;
 892 }
 893
 894 void net_link_vehile()
 895 {
 896     self.SendFlags = 0xFFFFFF;
 897     Net_LinkEntity(self, FALSE, 0, send_vehile);
 898 }
 899 #endif // SVQC
 900
 901 #ifdef CSQC
 902 void Net_ReadVehicle(float bIsNew)
 903 {
 904     float sf;
 905
 906     if(bIsNew)
 907     {
 908         setmodel(self, "models/vehicles/wakizashi.dpm");
 909         self.move_movetype = MOVETYPE_BOUNCE;
 910         self.entremove = VehicleRacerRemove;
 911         setsize(self,  '-60 -60 -20', '60 60 20');
 912         self.draw = VehicleRacerDraw;
 913         self.scale = 0.5;
 914     }
 915
 916     sf = ReadByte();
 917         if(sf & VSF_SETUP)
 918         {
 919         self.hud        = ReadByte();
 920         self.team       = ReadByte();
 921         self.colormap   = ReadShort();
 922         }
 923
 924     if(sf & if(sf & VSF_ORIGIN))
 925     {
 926         self.origin_x       = ReadCoord();
 927         self.origin_y       = ReadCoord();
 928         self.origin_z       = ReadCoord();
 929         self.move_origin    = self.origin;
 930     }
 931
 932     if(sf & VSF_MOVEMENT)
 933     {
 934         self.velocity_x     = ReadCoord();
 935         self.velocity_y     = ReadCoord();
 936         self.velocity_z     = ReadCoord();
 937
 938         self.angles_x       = ReadAngle();
 939         self.angles_y       = ReadAngle();
 940         self.angles_z       = ReadAngle();
 941
 942         self.move_velocity  = self.velocity;
 943         self.move_angles    = self.angles;
 944     }
 945
 946 }
 947 #endif // CSQC
 948
 949 #endif // VEHICLES_CSQC