qcsrc/server/vehicles/vehicles.qc

   1 float autocvar_g_vehicles_crush_dmg;
   2 float autocvar_g_vehicles_crush_force;
   3
   4 void vehicles_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force);
   5 void vehicles_return();
   6 void vehicles_enter();
   7 void vehicles_touch();
   8 void vehicles_reset_colors();
   9 void vehicles_clearrturn();
  10 void vehicles_setreturn();
  11
  12
  13 /** AuxiliaryXhair*
  14     Send addictional points of interest to be drawn, to vehicle owner
  15 **/
  16 float MAX_AXH = 4;
  17 .entity AuxiliaryXhair[MAX_AXH];
  18
  19 float SendAuxiliaryXhair(entity to, float sf)
  20 {
  21
  22         WriteByte(MSG_ENTITY, ENT_CLIENT_AUXILIARYXHAIR);
  23
  24         WriteByte(MSG_ENTITY, self.cnt);
  25
  26         WriteCoord(MSG_ENTITY, self.origin_x);
  27         WriteCoord(MSG_ENTITY, self.origin_y);
  28         WriteCoord(MSG_ENTITY, self.origin_z);
  29
  30     WriteByte(MSG_ENTITY, rint(self.colormod_x * 255));
  31     WriteByte(MSG_ENTITY, rint(self.colormod_y * 255));
  32     WriteByte(MSG_ENTITY, rint(self.colormod_z * 255));
  33
  34     return TRUE;
  35 }
  36
  37 void UpdateAuxiliaryXhair(entity own, vector loc, vector clr, float axh_id)
  38 {
  39     entity axh;
  40
  41     axh_id = bound(0, axh_id, MAX_AXH);
  42     axh = own.AuxiliaryXhair[axh_id];
  43
  44     if(axh == world || wasfreed(axh))  // MADNESS? THIS IS QQQQCCCCCCCCC (wasfreed, why do you exsist?)
  45     {
  46         axh                     = spawn();
  47         axh.cnt                 = axh_id;
  48         axh.drawonlytoclient    = own;
  49         axh.owner               = own;
  50         Net_LinkEntity(axh, FALSE, 0, SendAuxiliaryXhair);
  51     }
  52
  53     setorigin(axh, loc);
  54     axh.colormod            = clr;
  55     axh.SendFlags           = 0x01;
  56     own.AuxiliaryXhair[axh_id] = axh;
  57 }
  58
  59 /*
  60 // SVC_TEMPENTITY based, horrible with even 50 ping. hm.
  61 // WriteByte(MSG_ONE, SVC_TEMPENTITY) uses reliable messagess, never use for thinsg that need continous updates.
  62 void SendAuxiliaryXhair2(entity own, vector loc, vector clr, float axh_id)
  63 {
  64         msg_entity = own;
  65
  66         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  67         WriteByte(MSG_ONE, TE_CSQC_AUXILIARYXHAIR);
  68
  69         WriteByte(MSG_ONE, axh_id);
  70
  71         WriteCoord(MSG_ONE, loc_x);
  72         WriteCoord(MSG_ONE, loc_y);
  73         WriteCoord(MSG_ONE, loc_z);
  74
  75     WriteByte(MSG_ONE, rint(clr_x * 255));
  76     WriteByte(MSG_ONE, rint(clr_y * 255));
  77     WriteByte(MSG_ONE, rint(clr_z * 255));
  78
  79 }
  80 */
  81 // End AuxiliaryXhair
  82
  83 void CSQCVehicleSetup(entity own, float vehicle_id)
  84 {
  85         msg_entity = own;
  86
  87         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  88         WriteByte(MSG_ONE, TE_CSQC_VEHICLESETUP);
  89         WriteByte(MSG_ONE, vehicle_id);
  90 }
  91
  92 /** vehicles_locktarget
  93
  94     Generic target locking.
  95
  96     Figure out if what target is "locked" (if any), for missile tracking as such.
  97
  98     after calling, "if(self.lock_target != world && self.lock_strength == 1)" mean
  99     you have a locked in target.
 100
 101     Exspects a crosshair_trace() or equivalent to be
 102     dont before calling.
 103
 104 **/
 105 .entity lock_target;
 106 .float  lock_strength;
 107 .float  lock_time;
 108 void vehicles_locktarget(float incr, float decr, float _lock_time)
 109 {
 110     if(self.lock_target && self.lock_target.deadflag != DEAD_NO)
 111     {
 112         self.lock_target    = world;
 113         self.lock_strength  = 0;
 114         self.lock_time      = 0;
 115     }
 116
 117     if(self.lock_time > time)
 118         return;
 119
 120     if(trace_ent != world)
 121     {
 122         if(teams_matter && trace_ent.team == self.team)
 123             trace_ent = world;
 124
 125         if(trace_ent.deadflag != DEAD_NO)
 126             trace_ent = world;
 127
 128         if not (trace_ent.vehicle_flags & VHF_ISVEHICLE || trace_ent.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 129             trace_ent = world;
 130     }
 131
 132     if(self.lock_target == world && trace_ent != world)
 133         self.lock_target = trace_ent;
 134
 135     // Have a locking target
 136     // Trace hit current target
 137     if(trace_ent == self.lock_target && trace_ent != world)
 138     {
 139         self.lock_strength = min(self.lock_strength + incr, 1);
 140         if(self.lock_strength == 1)
 141             self.lock_time = time + _lock_time;
 142     }
 143     else
 144     {
 145         if(trace_ent)
 146             self.lock_strength = max(self.lock_strength - decr * 2, 0);
 147         else
 148             self.lock_strength = max(self.lock_strength - decr, 0);
 149
 150         if(self.lock_strength == 0)
 151             self.lock_target = world;
 152     }
 153 }
 154
 155 #define VEHICLE_UPDATE_PLAYER(fld,vhname) \
 156 self.owner.vehicle_##fld = (self.vehicle_##fld / autocvar_g_vehicle_##vhname##_##fld) * 100
 157
 158 #define vehicles_sweap_collision(orig,vel,dt,acm,mult) \
 159 traceline(orig, orig + vel * dt, MOVE_NORMAL, self); \
 160 if(trace_fraction != 1) \
 161     acm += normalize(self.origin - trace_endpos) * (vlen(vel) * mult)
 162
 163 // Hover movement support
 164 float  force_fromtag_power;
 165 float  force_fromtag_normpower;
 166 vector force_fromtag_origin;
 167 vector vehicles_force_fromtag_hover(string tag_name, float spring_length, float max_power)
 168 {
 169     force_fromtag_origin = gettaginfo(self, gettagindex(self, tag_name));
 170     v_forward  = normalize(v_forward) * -1;
 171     traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, self);
 172
 173     force_fromtag_power = (1 - trace_fraction) * max_power;
 174     force_fromtag_normpower = force_fromtag_power / max_power;
 175
 176     return v_forward  * force_fromtag_power;
 177 }
 178
 179 // Experimental hovermode wich uses attraction/repulstion from surface insted of gravity/repulsion
 180 // Can possibly be use to move abt any surface (inclusing walls/celings)
 181 vector vehicles_force_fromtag_maglev(string tag_name, float spring_length, float max_power)
 182 {
 183
 184     force_fromtag_origin = gettaginfo(self, gettagindex(self, tag_name));
 185     v_forward  = normalize(v_forward) * -1;
 186     traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, self);
 187
 188     // TODO - this may NOT be compatible with wall/celing movement, unhardcode 0.25 (engine count multiplier)
 189     if(trace_fraction == 1.0)
 190     {
 191         force_fromtag_normpower = -0.25;
 192         return '0 0 -200';
 193     }
 194
 195     force_fromtag_power = ((1 - trace_fraction) - trace_fraction) * max_power;
 196     force_fromtag_normpower = force_fromtag_power / max_power;
 197
 198     return v_forward  * force_fromtag_power;
 199 }
 200
 201 // Generic vehile projectile system
 202 void vehicles_projectile_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 203 {
 204     self.health -= damage;
 205     self.velocity += force;
 206     if(self.health < 1)
 207     {
 208         self.takedamage = DAMAGE_NO;
 209         self.event_damage = SUB_Null;
 210         self.think = self.use;
 211         self.nextthink = time;
 212     }
 213
 214 }
 215
 216 void vehicles_projectile_explode()
 217 {
 218     if(self.owner && other != world)
 219     {
 220         if(other == self.owner.vehicle)
 221             return;
 222
 223         if(other == self.owner.vehicle.tur_head)
 224             return;
 225     }
 226
 227         PROJECTILE_TOUCH;
 228
 229         self.event_damage = SUB_Null;
 230     RadiusDamage (self, self.realowner, self.shot_dmg, 0, self.shot_radius, self, self.shot_force, self.totalfrags, other);
 231
 232     remove (self);
 233 }
 234
 235 entity vehicles_projectile(string _mzlfx, string _mzlsound,
 236                            vector _org, vector _vel,
 237                            float _dmg, float _radi, float _force,  float _size,
 238                            float _deahtype, float _projtype, float _health,
 239                            float _cull, float _clianim)
 240 {
 241     entity proj;
 242
 243     proj = spawn();
 244
 245     PROJECTILE_MAKETRIGGER(proj);
 246     setorigin(proj, _org);
 247
 248     proj.shot_dmg         = _dmg;
 249     proj.shot_radius      = _radi;
 250     proj.shot_force       = _force;
 251     proj.totalfrags       = _deahtype;
 252     proj.solid            = SOLID_BBOX;
 253     proj.movetype         = MOVETYPE_FLYMISSILE;
 254     proj.flags            = FL_PROJECTILE;
 255     proj.bot_dodge        = TRUE;
 256     proj.bot_dodgerating  = _dmg;
 257     proj.velocity         = _vel;
 258     proj.touch            = vehicles_projectile_explode;
 259     proj.use              = vehicles_projectile_explode;
 260     proj.owner            = self;
 261     proj.realowner        = self.owner;
 262     proj.think            = SUB_Remove;
 263     proj.nextthink        = time + 30;
 264
 265     if(_health)
 266     {
 267         proj.takedamage       = DAMAGE_AIM;
 268         proj.event_damage     = vehicles_projectile_damage;
 269         proj.health           = _health;
 270     }
 271     else
 272         proj.flags           = FL_PROJECTILE | FL_NOTARGET;
 273
 274     if(_mzlsound)
 275         sound (self, CHAN_WEAPON, _mzlsound, VOL_BASE, ATTN_NORM);
 276
 277     if(_mzlfx)
 278         pointparticles(particleeffectnum(_mzlfx), proj.origin, proj.velocity, 1);
 279
 280
 281     setsize (proj, '-1 -1 -1' * _size, '1 1 1' * _size);
 282
 283     CSQCProjectile(proj, _clianim, _projtype, _cull);
 284
 285     return proj;
 286 }
 287 // End generic vehile projectile system
 288
 289 /** vehicles_spawn
 290     Exetuted for all vehiles on (re)spawn.
 291     Sets defaults for newly spawned units.
 292 **/
 293 void vehicles_spawn()
 294 {
 295     dprint("Spawning vehicle: ", self.netname, "\n");
 296
 297     // De-own & reset
 298     self.vehicle_hudmodel.viewmodelforclient = self;
 299
 300     self.owner              = world;
 301     self.touch              = vehicles_touch;
 302     self.event_damage       = vehicles_damage;
 303     self.iscreature         = TRUE;
 304     self.movetype           = MOVETYPE_WALK;
 305     self.solid              = SOLID_SLIDEBOX;
 306     self.takedamage         = DAMAGE_AIM;
 307         self.deadflag           = DEAD_NO;
 308     self.bot_attack         = TRUE;
 309     self.flags              = FL_NOTARGET;
 310     self.avelocity          = '0 0 0';
 311     self.velocity           = '0 0 0';
 312
 313     // Reset locking
 314     self.lock_strength      = 0;
 315     self.lock_target        = world;
 316     self.misc_bulletcounter = 0;
 317
 318     // Return to spawn
 319     self.angles             = self.pos2;
 320     setorigin(self, self.pos1 + '0 0 128');
 321     // Show it
 322     pointparticles(particleeffectnum("teleport"), self.origin + '0 0 64', '0 0 0', 1);
 323
 324     vehicles_reset_colors();
 325     self.vehicle_spawn();
 326 }
 327
 328 // Better way of determening whats crushable needed! (fl_crushable?)
 329 float vehicles_crushable(entity e)
 330 {
 331     if(e.classname == "player")
 332         return TRUE;
 333
 334     if(e.classname == "monster_zombie")
 335         return TRUE;
 336
 337     return FALSE;
 338 }
 339
 340 void vehicles_touch()
 341 {
 342     // Vehicle currently in use
 343     if(self.owner)
 344     {
 345         // Colided with world?
 346         if(other == world)
 347         {
 348             // Apply velocity based self damage here
 349         }
 350         else
 351         {
 352             if(other.vehicle_flags & VHF_ISVEHICLE)
 353             {
 354                 //other.velocity += self.velocity * (self.mass / other.mass);
 355             }
 356             else if(vehicles_crushable(other))
 357             {
 358                 if(vlen(self.velocity) != 0)
 359                     Damage(other, self, self.owner, autocvar_g_vehicles_crush_dmg, DEATH_VHCRUSH, '0 0 0', normalize(other.origin - self.origin) * autocvar_g_vehicles_crush_force);
 360             }
 361         }
 362         return;
 363     }
 364
 365     if(other.classname != "player")
 366         return;
 367
 368     if(other.deadflag != DEAD_NO)
 369         return;
 370
 371     if(other.vehicle != world)
 372         return;
 373
 374     // Remove this when bots know how to use vehicles.
 375     if (clienttype(other) != CLIENTTYPE_REAL)
 376         return;
 377
 378     vehicles_enter();
 379 }
 380
 381 void vehicles_enter()
 382 {
 383    // Remove this when bots know how to use vehicles
 384     if (clienttype(other) != CLIENTTYPE_REAL)
 385         return;
 386
 387     if(self.phase > time)
 388         return;
 389
 390     if(teams_matter)
 391     if(self.team)
 392     if(self.team != other.team)
 393         return;
 394
 395     self.vehicle_ammo1   = 0;
 396     self.vehicle_ammo2   = 0;
 397     self.vehicle_reload1 = 0;
 398     self.vehicle_reload2 = 0;
 399     self.vehicle_energy  = 0;
 400
 401     self.owner          = other;
 402     self.switchweapon   = other.switchweapon;
 403
 404     // .viewmodelforclient works better.
 405     //self.vehicle_hudmodel.drawonlytoclient = self.owner;
 406
 407 #ifndef VEHICLES_CSQC
 408         self.vehicle_hudmodel.viewmodelforclient = self.owner;
 409 #endif
 410
 411     self.event_damage         = vehicles_damage;
 412     self.nextthink            = 0;
 413     self.owner.angles         = self.angles;
 414     self.owner.takedamage     = DAMAGE_NO;
 415     self.owner.solid          = SOLID_NOT;
 416     self.owner.movetype       = MOVETYPE_NOCLIP;
 417     self.owner.alpha          = -1;
 418     self.owner.vehicle        = self;
 419     self.owner.event_damage   = SUB_Null;
 420     self.owner.view_ofs       = '0 0 0';
 421     self.colormap             = self.owner.colormap;
 422     if(self.tur_head)
 423         self.tur_head.colormap    = self.owner.colormap;
 424
 425     self.owner.hud            = self.hud;
 426     self.owner.PlayerPhysplug = self.PlayerPhysplug;
 427
 428     self.owner.vehicle_ammo1    = self.vehicle_ammo1;
 429     self.owner.vehicle_ammo2    = self.vehicle_ammo2;
 430     self.owner.vehicle_reload1  = self.vehicle_reload1;
 431     self.owner.vehicle_reload2  = self.vehicle_reload2;
 432
 433     // Cant do this, hides attached objects too.
 434     //self.exteriormodeltoclient = self.owner;
 435     //self.tur_head.exteriormodeltoclient = self.owner;
 436
 437     other.flags &~= FL_ONGROUND;
 438     self.flags  &~= FL_ONGROUND;
 439
 440     self.team                 = self.owner.team;
 441     self.flags               -= FL_NOTARGET;
 442
 443 #ifndef VEHICLES_CSQC
 444     msg_entity = other;
 445     WriteByte (MSG_ONE, SVC_SETVIEWPORT);
 446     WriteEntity(MSG_ONE, self.vehicle_viewport);
 447
 448     WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
 449     if(self.tur_head)
 450     {
 451         WriteAngle(MSG_ONE, self.tur_head.angles_x + self.angles_x); // tilt
 452         WriteAngle(MSG_ONE, self.tur_head.angles_y + self.angles_y); // yaw
 453         WriteAngle(MSG_ONE, 0);                                      // roll
 454     }
 455     else
 456     {
 457         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
 458         WriteAngle(MSG_ONE,  self.angles_x * -1); // tilt
 459         WriteAngle(MSG_ONE,  self.angles_y);      // yaw
 460         WriteAngle(MSG_ONE,  0);                  // roll
 461     }
 462 #endif
 463 //#endif
 464
 465     vehicles_clearrturn();
 466
 467     CSQCVehicleSetup(self.owner, self.hud);
 468
 469     self.vehicle_enter();
 470 }
 471
 472 void vehicles_exit(float eject)
 473 {
 474         self.flags |= FL_NOTARGET;
 475
 476     if (self.owner)
 477     {
 478         msg_entity = self.owner;
 479         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
 480         WriteEntity( MSG_ONE, self.owner);
 481
 482         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
 483         WriteAngle(MSG_ONE, 0);                 // pich
 484         WriteAngle(MSG_ONE, self.angles_y);     // yaw
 485         WriteAngle(MSG_ONE, 0);                 // roll
 486
 487         setsize(self.owner, PL_MIN,PL_MAX);
 488
 489         self.owner.takedamage     = DAMAGE_AIM;
 490         self.owner.solid          = SOLID_SLIDEBOX;
 491         self.owner.movetype       = MOVETYPE_WALK;
 492         self.owner.effects        &~= EF_NODRAW;
 493         self.owner.alpha          = 1;
 494         self.owner.PlayerPhysplug = SUB_Null;
 495         self.owner.vehicle        = world;
 496         self.owner.view_ofs       = PL_VIEW_OFS;
 497         self.owner.event_damage   = PlayerDamage;
 498         self.owner.hud            = HUD_NORMAL;
 499         self.owner.switchweapon   = self.switchweapon;
 500         self.owner.BUTTON_USE     = 0;
 501     }
 502
 503     if(self.deadflag == DEAD_NO)
 504         self.avelocity          = '0 0 0';
 505
 506     self.vehicle_hudmodel.viewmodelforclient = self;
 507         self.tur_head.nodrawtoclient             = world;
 508     vehicles_setreturn();
 509
 510     self.phase = time + 1;
 511
 512     if(!teams_matter)
 513         self.team = 0;
 514
 515     self.vehicle_exit(eject);
 516     self.owner = world;
 517 }
 518
 519
 520 void vehicles_regen(.float timer, .float regen_field, float field_max, float rpause, float regen, float delta_time)
 521 {
 522     if(self.regen_field < field_max)
 523     if(self.timer + rpause < time)
 524     {
 525         self.regen_field = min(self.regen_field + regen * delta_time, field_max);
 526
 527         if(self.owner)
 528             self.owner.regen_field = (self.regen_field / field_max) * 100;
 529     }
 530 }
 531
 532 void shieldhit_think()
 533 {
 534     self.alpha -= 0.1;
 535     if (self.alpha <= 0)
 536     {
 537         //setmodel(self, "");
 538         self.alpha = -1;
 539     }
 540     else
 541     {
 542         self.nextthink = time + 0.1;
 543     }
 544 }
 545
 546 void vehicles_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 547 {
 548     self.dmg_time = time;
 549
 550     if((self.vehicle_flags & VHF_HASSHIELD) && (self.vehicle_shield > 0))
 551     {
 552         if (wasfreed(self.vehicle_shieldent) || self.vehicle_shieldent == world)
 553         {
 554             self.vehicle_shieldent = spawn();
 555             self.vehicle_shieldent.effects = EF_LOWPRECISION;
 556
 557             setmodel(self.vehicle_shieldent, "models/vhshield.md3");
 558             setattachment(self.vehicle_shieldent, self, "");
 559             setorigin(self.vehicle_shieldent, real_origin(self) - self.origin);
 560             self.vehicle_shieldent.scale       = 256 / vlen(self.maxs - self.mins);
 561             self.vehicle_shieldent.think       = shieldhit_think;
 562         }
 563
 564
 565         self.vehicle_shieldent.colormod    = '1 1 1';
 566         self.vehicle_shieldent.alpha       = 0.45;
 567         self.vehicle_shieldent.angles      = vectoangles(normalize(hitloc - (self.origin + self.vehicle_shieldent.origin))) - self.angles;
 568         self.vehicle_shieldent.nextthink   = time;
 569
 570         self.vehicle_shield -= damage;
 571
 572         if(self.vehicle_shield < 0)
 573         {
 574             self.vehicle_shieldent.colormod = '2 0 0';
 575             self.vehicle_shield             = 0;
 576             self.vehicle_shieldent.alpha    = 0.75;
 577             self.vehicle_health            -= fabs(self.vehicle_shield);
 578         }
 579     }
 580     else
 581         self.vehicle_health -= damage;
 582
 583     self.velocity += force; // * (vlen(force) / self.mass);
 584
 585     if(self.vehicle_health <= 0)
 586     {
 587         if(self.owner)
 588             if(self.vehicle_flags & VHF_DEATHEJECT)
 589                 vehicles_exit(VHEF_EJECT);
 590             else
 591                 vehicles_exit(VHEF_RELESE);
 592
 593         self.vehicle_die();
 594         vehicles_setreturn();
 595     }
 596 }
 597
 598 void vehicles_return()
 599 {
 600     pointparticles(particleeffectnum("teleport"), self.enemy.origin + '0 0 64', '0 0 0', 1);
 601
 602     self.enemy.think     = vehicles_spawn;
 603     self.enemy.nextthink = time;
 604
 605     remove(self);
 606 }
 607
 608 void vehicles_clearrturn()
 609 {
 610     entity ret;
 611     // Remove "return helper", if any.
 612     ret = findchain(classname, "vehicle_return");
 613     while(ret)
 614     {
 615         if(ret.enemy == self)
 616         {
 617             ret.classname   = "";
 618             ret.think       = SUB_Remove;
 619             ret.nextthink   = time + 0.1;
 620             return;
 621         }
 622
 623         ret = ret.chain;
 624     }
 625 }
 626
 627 void vehicles_setreturn()
 628 {
 629     entity ret;
 630
 631     vehicles_clearrturn();
 632
 633     ret = spawn();
 634     ret.classname   = "vehicle_return";
 635     ret.enemy       = self;
 636     ret.think       = vehicles_return;
 637     ret.nextthink   = time + self.vehicle_respawntime;
 638 }
 639
 640 float vehicles_customizeentityforclient()
 641 {
 642     if(self.deadflag  == DEAD_DEAD)
 643         return FALSE;
 644     else
 645         return TRUE;
 646 }
 647
 648 void vehicles_configcheck(string  configname, float check_cvar)
 649 {
 650     if(check_cvar == 0)
 651         localcmd(strcat("exec ", configname, "\n"));
 652 }
 653
 654 void vehicles_reset_colors()
 655 {
 656     entity e;
 657     float _effects, _colormap;
 658     vector _glowmod, _colormod;
 659
 660     if(autocvar_g_nodepthtestplayers)
 661         _effects = EF_NODEPTHTEST;
 662
 663     if(autocvar_g_fullbrightplayers)
 664         _effects |= EF_FULLBRIGHT;
 665
 666     if(self.team)
 667         _colormap = 1024 + (self.team - 1) * 17;
 668     else
 669         _colormap = 1024;
 670
 671     _glowmod  = '0 0 0';
 672     _colormod = '0 0 0';
 673
 674     // Find all ents attacked to main model and setup effects, colormod etc.
 675     e = findchainentity(tag_entity, self);
 676     while(e)
 677     {
 678         if(e != self.vehicle_shieldent)
 679         {
 680             e.effects   = _effects  | EF_LOWPRECISION;
 681             e.colormod  = _colormod;
 682             e.colormap  = _colormap;
 683             e.alpha     = 1;
 684         }
 685         e = e.chain;
 686     }
 687
 688     self.vehicle_hudmodel.effects  = self.effects  = _effects | EF_LOWPRECISION;
 689     self.vehicle_hudmodel.colormod = self.colormod = _colormod;
 690     self.vehicle_hudmodel.colormap = self.colormap = _colormap;
 691     self.vehicle_viewport.effects = (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NOGUNBOB | EF_NOSHADOW | EF_LOWPRECISION | EF_SELECTABLE | EF_TELEPORT_BIT);
 692
 693     self.alpha     = 1;
 694     self.avelocity = '0 0 0';
 695     self.velocity  = '0 0 0';
 696     self.effects   = _effects;
 697 }
 698
 699 float vehicle_initialize(string  net_name,
 700                          string  bodymodel,
 701                          string  topmodel,
 702                          string  hudmodel,
 703                          string  toptag,
 704                          string  hudtag,
 705                          string  viewtag,
 706                          float   vhud,
 707                          vector  min_s,
 708                          vector  max_s,
 709                          float   nodrop,
 710                          void()  spawnproc,
 711                          float   _respawntime,
 712                          float() physproc,
 713                          void()  enterproc,
 714                          void(float extflag) exitfunc,
 715                          void() dieproc,
 716                          void() thinkproc,
 717                          float  use_csqc)
 718 {
 719     addstat(STAT_HUD, AS_INT,  hud);
 720         addstat(STAT_VEHICLESTAT_HEALTH,  AS_INT, vehicle_health);
 721         addstat(STAT_VEHICLESTAT_SHIELD,  AS_INT, vehicle_shield);
 722         addstat(STAT_VEHICLESTAT_ENERGY,  AS_INT, vehicle_energy);
 723
 724         addstat(STAT_VEHICLESTAT_AMMO1,   AS_INT,   vehicle_ammo1);
 725         addstat(STAT_VEHICLESTAT_RELOAD1, AS_INT, vehicle_reload1);
 726
 727         addstat(STAT_VEHICLESTAT_AMMO2,   AS_INT,   vehicle_ammo2);
 728         addstat(STAT_VEHICLESTAT_RELOAD2, AS_INT, vehicle_reload2);
 729
 730     if(bodymodel == "")
 731         error("vehicles: missing bodymodel!");
 732
 733     if(hudmodel == "")
 734         error("vehicles: missing hudmodel!");
 735
 736     if(net_name == "")
 737         self.netname = self.classname;
 738     else
 739         self.netname = net_name;
 740
 741     if(self.team && !teams_matter)
 742         self.team = 0;
 743
 744     self.vehicle_flags |= VHF_ISVEHICLE;
 745
 746     setmodel(self, bodymodel);
 747
 748     self.vehicle_viewport   = spawn();
 749     self.vehicle_hudmodel   = spawn();
 750     self.tur_head           = spawn();
 751     self.tur_head.owner     = self;
 752     self.takedamage         = DAMAGE_AIM;
 753     self.bot_attack         = TRUE;
 754     self.iscreature         = TRUE;
 755     self.hud                = vhud;
 756
 757     //self.customizeentityforclient = vehicles_customizeentityforclient;
 758     self.vehicle_die         = dieproc;
 759     self.vehicle_exit        = exitfunc;
 760     self.vehicle_enter       = enterproc;
 761     self.PlayerPhysplug      = physproc;
 762     self.event_damage        = vehicles_damage;
 763     self.touch               = vehicles_touch;
 764     self.think               = vehicles_spawn;
 765     self.nextthink           = time;
 766     self.vehicle_respawntime = _respawntime;
 767     self.vehicle_spawn       = spawnproc;
 768
 769     if(autocvar_g_nodepthtestplayers)
 770         self.effects = self.effects | EF_NODEPTHTEST;
 771
 772     if(autocvar_g_fullbrightplayers)
 773         self.effects = self.effects | EF_FULLBRIGHT;
 774
 775     setmodel(self.vehicle_hudmodel, hudmodel);
 776     setmodel(self.vehicle_viewport, "null");
 777
 778
 779     if(topmodel != "")
 780     {
 781         setmodel(self.tur_head, topmodel);
 782         setattachment(self.tur_head, self, toptag);
 783         setattachment(self.vehicle_hudmodel, self.tur_head, hudtag);
 784         setattachment(self.vehicle_viewport, self.vehicle_hudmodel, viewtag);
 785     }
 786     else
 787     {
 788         setattachment(self.tur_head, self, "");
 789         setattachment(self.vehicle_hudmodel, self, hudtag);
 790         setattachment(self.vehicle_viewport, self.vehicle_hudmodel, viewtag);
 791     }
 792
 793     setsize(self, min_s, max_s);
 794     if not (nodrop)
 795     {
 796         setorigin(self, self.origin);
 797         tracebox(self.origin + '0 0 100', min_s, max_s, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
 798         setorigin(self, trace_endpos);
 799     }
 800
 801     self.pos1 = self.origin;
 802     self.pos2 = self.angles;
 803 #ifdef VEHICLES_CSQC
 804     if(use_csqc)
 805         net_link_vehile();
 806 #endif
 807     return TRUE;
 808 }
 809
 810
 811 void bugmenot()
 812 {
 813     self.vehicle_exit       = self.vehicle_exit;
 814     self.vehicle_enter      = self.vehicle_exit;
 815     self.vehicle_die        = self.vehicle_exit;
 816     self.vehicle_spawn      = self.vehicle_exit;
 817     self.AuxiliaryXhair     = self.AuxiliaryXhair;
 818 }