qcsrc/server/vehicles/vehicles.qc

   1 float autocvar_g_vehicles_crush_dmg;
   2 float autocvar_g_vehicles_crush_force;
   3
   4 void vehicles_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force);
   5 void vehicles_return();
   6 void vehicles_enter();
   7 void vehicles_touch();
   8 void vehicles_reset_colors();
   9 void vehicles_clearrturn();
  10 void vehicles_setreturn();
  11
  12
  13 #define MAX_AXH 4
  14 .entity AuxiliaryXhair[MAX_AXH];
  15
  16 float SendAuxiliaryXhair(entity to, float sf)
  17 {
  18
  19         WriteByte(MSG_ENTITY, ENT_CLIENT_AUXILIARYXHAIR);
  20
  21         WriteByte(MSG_ENTITY, self.cnt);
  22
  23         WriteCoord(MSG_ENTITY, self.origin_x);
  24         WriteCoord(MSG_ENTITY, self.origin_y);
  25         WriteCoord(MSG_ENTITY, self.origin_z);
  26
  27     WriteByte(MSG_ENTITY, rint(self.colormod_x * 255));
  28     WriteByte(MSG_ENTITY, rint(self.colormod_y * 255));
  29     WriteByte(MSG_ENTITY, rint(self.colormod_z * 255));
  30
  31     return TRUE;
  32 }
  33
  34 void UpdateAuxiliaryXhair(entity own, vector loc, vector clr, float axh_id)
  35 {
  36     entity axh;
  37
  38     axh_id = bound(0, axh_id, MAX_AXH);
  39     axh = own.AuxiliaryXhair[axh_id];
  40
  41     if(axh == world || wasfreed(axh))  // MADNESS? THIS IS QQQQCCCCCCCCC (wasfreed, why do you exsist?)
  42     {
  43         axh                     = spawn();
  44         axh.cnt                 = axh_id;
  45         axh.drawonlytoclient    = own;
  46         axh.owner               = own;
  47         Net_LinkEntity(axh, FALSE, 0, SendAuxiliaryXhair);
  48     }
  49
  50     setorigin(axh, loc);
  51     axh.colormod            = clr;
  52     axh.SendFlags           = 0x01;
  53     own.AuxiliaryXhair[axh_id] = axh;
  54 }
  55
  56 /*
  57 // SVC_TEMPENTITY based, horrible with even 50 ping. hm.
  58 // WriteByte(MSG_ONE, SVC_TEMPENTITY) uses reliable messagess, never use for thinsg that need continous updates.
  59 void SendAuxiliaryXhair2(entity own, vector loc, vector clr, float axh_id)
  60 {
  61         msg_entity = own;
  62
  63         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  64         WriteByte(MSG_ONE, TE_CSQC_AUXILIARYXHAIR);
  65
  66         WriteByte(MSG_ONE, axh_id);
  67
  68         WriteCoord(MSG_ONE, loc_x);
  69         WriteCoord(MSG_ONE, loc_y);
  70         WriteCoord(MSG_ONE, loc_z);
  71
  72     WriteByte(MSG_ONE, rint(clr_x * 255));
  73     WriteByte(MSG_ONE, rint(clr_y * 255));
  74     WriteByte(MSG_ONE, rint(clr_z * 255));
  75
  76 }
  77 */
  78
  79 void CSQCVehicleSetup(entity own, float vehicle_id)
  80 {
  81         msg_entity = own;
  82
  83         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  84         WriteByte(MSG_ONE, TE_CSQC_VEHICLESETUP);
  85         WriteByte(MSG_ONE, vehicle_id);
  86 }
  87
  88 .entity lock_target;
  89 .float  lock_strength;
  90 .float  lock_time;
  91 void vehicles_locktarget(float incr, float decr, float _lock_time)
  92 {
  93     if(self.lock_target && self.lock_target.deadflag != DEAD_NO)
  94     {
  95         self.lock_target    = world;
  96         self.lock_strength  = 0;
  97         self.lock_time      = 0;
  98     }
  99
 100     if(trace_ent != world)
 101     {
 102         if(teams_matter && trace_ent.team == self.team)
 103             trace_ent = world;
 104
 105         if(trace_ent.deadflag != DEAD_NO)
 106             trace_ent = world;
 107
 108         if not (trace_ent.vehicle_flags & VHF_ISVEHICLE || trace_ent.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 109             trace_ent = world;
 110     }
 111
 112     if(self.lock_time > time)
 113         return;
 114
 115     if(self.lock_target == world && trace_ent != world)
 116         self.lock_target = trace_ent;
 117
 118     // Have a locking target
 119     // Trace hit current target
 120     if(trace_ent == self.lock_target && trace_ent != world)
 121     {
 122         self.lock_strength = min(self.lock_strength + incr, 1);
 123         if(self.lock_strength == 1)
 124             self.lock_time = time + _lock_time;
 125     }
 126     else
 127     {
 128         self.lock_strength = max(self.lock_strength - decr, 0);
 129
 130         if(self.lock_strength == 0)
 131             self.lock_target = world;
 132     }
 133 }
 134
 135
 136 #define VEHICLE_UPDATE_PLAYER(fld,vhname) \
 137 self.owner.vehicle_##fld = self.vehicle_##fld / autocvar_g_vehicle_##vhname##_##fld
 138
 139 #define vehicles_sweap_collision(orig,vel,dt,acm,mult) \
 140 traceline(orig, orig + vel * dt, MOVE_NORMAL, self); \
 141 if(trace_fraction != 1) \
 142     acm += normalize(self.origin - trace_endpos) * (vlen(vel) * mult)
 143
 144 float  force_fromtag_power;
 145 float  force_fromtag_normpower;
 146 vector force_fromtag_origin;
 147 vector vehicles_force_fromtag_hover(string tag_name, float spring_length, float max_power)
 148 {
 149     force_fromtag_origin = gettaginfo(self, gettagindex(self, tag_name));
 150     v_forward  = normalize(v_forward) * -1;
 151     traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, self);
 152
 153     force_fromtag_power = (1 - trace_fraction) * max_power;
 154     force_fromtag_normpower = force_fromtag_power / max_power;
 155
 156     return v_forward  * force_fromtag_power;
 157 }
 158
 159 vector vehicles_force_fromtag_maglev(string tag_name, float spring_length, float max_power)
 160 {
 161
 162     force_fromtag_origin = gettaginfo(self, gettagindex(self, tag_name));
 163     v_forward  = normalize(v_forward) * -1;
 164     traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, self);
 165
 166     if(trace_fraction == 1.0)
 167     {
 168         force_fromtag_normpower = -0.25;
 169         return '0 0 -200';
 170     }
 171
 172     force_fromtag_power = ((1 - trace_fraction) - trace_fraction) * max_power;
 173     force_fromtag_normpower = force_fromtag_power / max_power;
 174
 175     return v_forward  * force_fromtag_power;
 176 }
 177
 178
 179
 180 void vehicles_spawn()
 181 {
 182     dprint("Spawning vehicle: ", self.netname, "\n");
 183
 184     // De-own & reset
 185     self.vehicle_hudmodel.viewmodelforclient = self;
 186     self.owner              = world;
 187     self.touch              = vehicles_touch;
 188     self.event_damage       = vehicles_damage;
 189     self.iscreature         = TRUE;
 190     self.movetype           = MOVETYPE_WALK;
 191     self.solid              = SOLID_SLIDEBOX;
 192     self.takedamage         = DAMAGE_AIM;
 193         self.deadflag           = DEAD_NO;
 194     self.bot_attack         = TRUE;
 195     self.flags              = FL_NOTARGET;
 196     self.avelocity          = '0 0 0';
 197
 198     // Reset locking
 199     self.lock_strength      = 0;
 200     self.lock_target        = world;
 201     self.misc_bulletcounter = 0;
 202
 203     // Return to spawn
 204     self.angles             = self.pos2;
 205     setorigin(self, self.pos1 + '0 0 128');
 206     // Show it
 207     pointparticles(particleeffectnum("teleport"), self.origin + '0 0 64', '0 0 0', 1);
 208
 209     vehicles_reset_colors();
 210     self.vehicle_spawn();
 211 }
 212
 213 // Better way of determening whats crushable needed! (fl_crushable?)
 214 float vehicles_crushable(entity e)
 215 {
 216     if(e.classname == "player")
 217         return TRUE;
 218
 219     if(e.classname == "monster_zombie")
 220         return TRUE;
 221
 222     return FALSE;
 223 }
 224
 225 void vehicles_touch()
 226 {
 227     // Vehicle currently in use
 228     if(self.owner)
 229     {
 230         // Colided with world?
 231         if(other == world)
 232         {
 233             // Apply velocity based self damage here
 234         }
 235         else
 236         {
 237             if(other.vehicle_flags & VHF_ISVEHICLE)
 238             {
 239                 //other.velocity += self.velocity * (self.mass / other.mass);
 240             }
 241             else if(vehicles_crushable(other))
 242             {
 243                 if(vlen(self.velocity) != 0)
 244                     Damage(other, self, self.owner, autocvar_g_vehicles_crush_dmg, DEATH_SBCRUSH, '0 0 0', normalize(other.origin - self.origin) * autocvar_g_vehicles_crush_force);
 245             }
 246         }
 247
 248         return;
 249     }
 250
 251     if(other.classname != "player")
 252         return;
 253
 254     if(other.deadflag != DEAD_NO)
 255         return;
 256
 257     if(other.vehicle != world)
 258         return;
 259
 260     // Remove this when bots know how to use vehicles.
 261     if (clienttype(other) != CLIENTTYPE_REAL)
 262         return;
 263
 264     vehicles_enter();
 265 }
 266
 267 void vehicles_enter()
 268 {
 269    // Remove this when bots know how to use vehicles
 270     if (clienttype(other) != CLIENTTYPE_REAL)
 271         return;
 272
 273     if(self.phase > time)
 274         return;
 275
 276     if(teams_matter)
 277     if(self.team)
 278     if(self.team != other.team)
 279         return;
 280
 281     self.vehicle_ammo1   = 0;
 282     self.vehicle_ammo2   = 0;
 283     self.vehicle_reload1 = 0;
 284     self.vehicle_reload2 = 0;
 285     self.vehicle_energy  = 0;
 286
 287     self.owner          = other;
 288     self.switchweapon   = other.switchweapon;
 289
 290     self.vehicle_hudmodel.viewmodelforclient = self.owner;
 291     self.event_damage         = vehicles_damage;
 292     self.nextthink            = 0;
 293     self.owner.angles         = self.angles;
 294     self.owner.takedamage     = DAMAGE_NO;
 295     self.owner.solid          = SOLID_NOT;
 296     self.owner.movetype       = MOVETYPE_NOCLIP;
 297     self.owner.alpha          = -1;
 298     self.owner.vehicle        = self;
 299     self.owner.event_damage   = SUB_Null;
 300     self.owner.view_ofs       = '0 0 0';
 301     self.colormap             = self.owner.colormap;
 302     if(self.tur_head)
 303         self.tur_head.colormap    = self.owner.colormap;
 304
 305     self.owner.hud            = self.hud;
 306     self.owner.PlayerPhysplug = self.PlayerPhysplug;
 307
 308     self.owner.vehicle_ammo1    = self.vehicle_ammo1;
 309     self.owner.vehicle_ammo2    = self.vehicle_ammo2;
 310     self.owner.vehicle_reload1  = self.vehicle_reload1;
 311     self.owner.vehicle_reload2  = self.vehicle_reload2;
 312
 313     other.flags &~= FL_ONGROUND;
 314     self.flags  &~= FL_ONGROUND;
 315
 316     self.team                 = self.owner.team;
 317     self.flags               -= FL_NOTARGET;
 318
 319     msg_entity = other;
 320     WriteByte (MSG_ONE, SVC_SETVIEWPORT);
 321     WriteEntity(MSG_ONE, self.vehicle_viewport);
 322
 323     WriteByte (MSG_ONE, SVC_SETVIEWANGLES);  // 10 = SVC_SETVIEWANGLES
 324     if(self.tur_head)
 325     {
 326         WriteAngle(MSG_ONE, self.tur_head.angles_x + self.angles_x);    // tilt
 327         WriteAngle(MSG_ONE, self.tur_head.angles_y + self.angles_y);    // yaw
 328         WriteAngle(MSG_ONE, 0);    // roll
 329     }
 330     else
 331     {
 332         WriteByte (MSG_ONE, SVC_SETVIEWANGLES); // 10 = SVC_SETVIEWANGLES
 333         WriteAngle(MSG_ONE,  self.angles_x * -1);    // tilt
 334         WriteAngle(MSG_ONE,  self.angles_y);    // yaw
 335         WriteAngle(MSG_ONE,  0);                // roll
 336     }
 337
 338     vehicles_clearrturn();
 339
 340     CSQCVehicleSetup(self.owner, self.hud);
 341
 342     self.vehicle_enter();
 343 }
 344
 345 void vehicles_exit(float eject)
 346 {
 347         self.flags |= FL_NOTARGET;
 348
 349     if (self.owner)
 350     {
 351         msg_entity = self.owner;
 352         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
 353         WriteEntity( MSG_ONE, self.owner);
 354
 355         WriteByte (MSG_ONE, SVC_SETVIEWANGLES); // 10 = SVC_SETVIEWANGLES
 356         WriteAngle(MSG_ONE, 0);                 // tilt
 357         WriteAngle(MSG_ONE, self.angles_y);     // yaw
 358         WriteAngle(MSG_ONE, 0);                 // roll
 359
 360         setsize(self.owner, PL_MIN,PL_MAX);
 361
 362         self.owner.takedamage     = DAMAGE_AIM;
 363         self.owner.solid          = SOLID_SLIDEBOX;
 364         self.owner.movetype       = MOVETYPE_WALK;
 365         self.owner.effects        &~= EF_NODRAW;
 366         self.owner.alpha          = 1;
 367         self.owner.PlayerPhysplug = SUB_Null;
 368         self.owner.vehicle        = world;
 369         self.owner.view_ofs       = PL_VIEW_OFS;
 370         self.owner.event_damage   = PlayerDamage;
 371         self.owner.hud            = HUD_NORMAL;
 372         self.owner.switchweapon   = self.switchweapon;
 373     }
 374
 375     if(self.deadflag == DEAD_NO)
 376         self.avelocity          = '0 0 0';
 377
 378     self.vehicle_hudmodel.viewmodelforclient = self;
 379         self.tur_head.nodrawtoclient             = self;
 380     vehicles_setreturn();
 381
 382     self.phase = time + 1;
 383
 384     if(!teams_matter)
 385         self.team = 0;
 386
 387     self.vehicle_exit(eject);
 388     self.owner = world;
 389 }
 390
 391
 392 void vehicles_regen(.float timer, .float regen_field, float field_max, float rpause, float regen, float delta_time)
 393 {
 394     if(self.regen_field < field_max)
 395     if(self.timer + rpause < time)
 396     {
 397         self.regen_field = min(self.regen_field + regen * delta_time, field_max);
 398
 399         if(self.owner)
 400             self.owner.regen_field = self.regen_field / field_max;
 401     }
 402 }
 403
 404 void shieldhit_think()
 405 {
 406     self.alpha -= 0.1;
 407     if (self.alpha <= 0)
 408     {
 409         setmodel(self, "");
 410         self.alpha = -1;
 411     }
 412     else
 413     {
 414         self.nextthink = time + 0.1;
 415     }
 416 }
 417
 418 void vehicles_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 419 {
 420     float ddmg_take;
 421
 422     self.dmg_time = time;
 423
 424     if((self.vehicle_flags & VHF_HASSHIELD) && (self.vehicle_shield > 0))
 425     {
 426         if (wasfreed(self.tur_head.enemy) || self.tur_head.enemy == world)
 427         {
 428             self.tur_head.enemy = spawn();
 429             self.tur_head.enemy.effects = EF_LOWPRECISION;
 430         }
 431
 432         setmodel(self.tur_head.enemy, "models/vhshield.md3");
 433         setattachment(self.tur_head.enemy, self, "");
 434
 435         self.tur_head.enemy.colormod    = '1 1 1';
 436         self.tur_head.enemy.alpha       = 0.45;
 437         self.tur_head.enemy.scale       = 256 / vlen(self.maxs - self.mins);
 438         self.tur_head.enemy.angles      = vectoangles(normalize(hitloc - self.origin)) - self.angles;
 439         self.tur_head.enemy.think       = shieldhit_think;
 440         self.tur_head.enemy.nextthink   = time;
 441
 442         self.vehicle_shield -= damage;
 443         if(self.vehicle_shield < 0)
 444         {
 445             self.tur_head.enemy.colormod = '2 0 0';
 446             ddmg_take = fabs(self.vehicle_shield);
 447             self.vehicle_shield         = 0;
 448             self.tur_head.enemy.alpha   = 0.75;
 449             self.vehicle_health         -= ddmg_take;
 450         }
 451     }
 452     else
 453         self.vehicle_health -= damage;
 454
 455     self.velocity += force; // * (vlen(force) / self.mass);
 456
 457     if(self.vehicle_health <= 0)
 458     {
 459         if(self.owner)
 460             if(self.vehicle_flags & VHF_DEATHEJECT)
 461                 vehicles_exit(VHEF_EJECT);
 462             else
 463                 vehicles_exit(VHEF_RELESE);
 464
 465         self.vehicle_die();
 466         vehicles_setreturn();
 467     }
 468 }
 469
 470 void vehicles_return()
 471 {
 472     pointparticles(particleeffectnum("teleport"), self.enemy.origin + '0 0 64', '0 0 0', 1);
 473
 474     self.enemy.think     = vehicles_spawn;
 475     self.enemy.nextthink = time;
 476
 477     remove(self);
 478 }
 479
 480 void vehicles_clearrturn()
 481 {
 482     entity ret;
 483     // Remove "return helper", if any.
 484     ret = findchain(classname, "vehicle_return");
 485     while(ret)
 486     {
 487         if(ret.enemy == self)
 488         {
 489             ret.classname   = "";
 490             ret.think       = SUB_Remove;
 491             ret.nextthink   = time + 0.1;
 492             return;
 493         }
 494
 495         ret = ret.chain;
 496     }
 497 }
 498
 499 void vehicles_setreturn()
 500 {
 501     entity ret;
 502
 503     vehicles_clearrturn();
 504
 505     ret = spawn();
 506     ret.classname   = "vehicle_return";
 507     ret.enemy       = self;
 508     ret.think       = vehicles_return;
 509     ret.nextthink   = time + self.vehicle_respawntime;
 510 }
 511
 512 float vehicles_customizeentityforclient()
 513 {
 514     if(self.deadflag  == DEAD_DEAD)
 515         return FALSE;
 516     else
 517         return TRUE;
 518 }
 519
 520 void vehicles_configcheck(string  configname, float check_cvar)
 521 {
 522     if(check_cvar == 0)
 523         localcmd(strcat("exec ", configname, "\n"));
 524 }
 525
 526 void vehicles_reset_colors()
 527 {
 528     entity e;
 529     float _effects, _colormap;
 530     vector _glowmod, _colormod;
 531
 532     if(autocvar_g_nodepthtestplayers)
 533         _effects = EF_NODEPTHTEST;
 534
 535     if(autocvar_g_fullbrightplayers)
 536         _effects |= EF_FULLBRIGHT;
 537
 538     if(self.team)
 539         _colormap = 1024 + (self.team - 1) * 17;
 540     else
 541         _colormap = 1024;
 542
 543     _glowmod    = '0 0 0';
 544     _colormod   = '0 0 0';
 545
 546     // Find all ents attacked to main model and setup effects, colormod etc.
 547     e = findchainentity(tag_entity, self);
 548     while(e)
 549     {
 550         e.effects   = _effects;
 551         e.colormod  = _colormod;
 552         e.colormap  = _colormap;
 553         e.alpha     = 1;
 554
 555         e = e.chain;
 556     }
 557
 558     self.effects  = _effects;
 559     self.colormod = _colormod;
 560     self.colormap = _colormap;
 561
 562     self.alpha          = 1;
 563     self.avelocity      = '0 0 0';
 564     self.velocity       = '0 0 0';
 565
 566 }
 567
 568 float vehicle_initialize(string  net_name,
 569                          string  bodymodel,
 570                          string  topmodel,
 571                          string  hudmodel,
 572                          string  toptag,
 573                          string  hudtag,
 574                          string  viewtag,
 575                          float   vhud,
 576                          vector min_s,
 577                          vector max_s,
 578                          float  nodrop,
 579                          void()  spawnproc,
 580                          float   _respawntime,
 581                          float() physproc,
 582                          void()  enterproc,
 583                          void(float extflag) exitfunc,
 584                          void() dieproc,
 585                          void() thinkproc )
 586 {
 587     addstat(STAT_HUD, AS_INT,  hud);
 588         addstat(STAT_VEHICLESTAT_HEALTH,  AS_FLOAT, vehicle_health);
 589         addstat(STAT_VEHICLESTAT_SHIELD,  AS_FLOAT, vehicle_shield);
 590         addstat(STAT_VEHICLESTAT_ENERGY,  AS_FLOAT, vehicle_energy);
 591
 592         addstat(STAT_VEHICLESTAT_AMMO1,   AS_INT,   vehicle_ammo1);
 593         addstat(STAT_VEHICLESTAT_RELOAD1, AS_FLOAT, vehicle_reload1);
 594
 595         addstat(STAT_VEHICLESTAT_AMMO2,   AS_INT,   vehicle_ammo2);
 596         addstat(STAT_VEHICLESTAT_RELOAD2, AS_FLOAT, vehicle_reload2);
 597
 598     if(bodymodel == "")
 599         error("vehicles: missing bodymodel!");
 600
 601     if(hudmodel == "")
 602         error("vehicles: missing hudmodel!");
 603
 604     if(net_name == "")
 605         self.netname = self.classname;
 606     else
 607         self.netname = net_name;
 608
 609     if(self.team && !teams_matter)
 610         self.team = 0;
 611
 612     self.vehicle_flags |= VHF_ISVEHICLE;
 613
 614     setmodel(self, bodymodel);
 615
 616     self.vehicle_viewport   = spawn();
 617     self.vehicle_hudmodel   = spawn();
 618     self.tur_head           = spawn();
 619     self.tur_head.owner     = self;
 620     self.takedamage         = DAMAGE_AIM;
 621     self.bot_attack         = TRUE;
 622     self.iscreature         = TRUE;
 623     self.hud                = vhud;
 624
 625     self.customizeentityforclient = vehicles_customizeentityforclient;
 626     self.vehicle_die         = dieproc;
 627     self.vehicle_exit        = exitfunc;
 628     self.vehicle_enter       = enterproc;
 629     self.PlayerPhysplug      = physproc;
 630     self.event_damage        = vehicles_damage;
 631     self.touch               = vehicles_touch;
 632     self.think               = vehicles_spawn;
 633     self.nextthink           = time;
 634     self.vehicle_respawntime = _respawntime;
 635     self.vehicle_spawn       = spawnproc;
 636
 637     if(autocvar_g_nodepthtestplayers)
 638         self.effects = self.effects | EF_NODEPTHTEST;
 639
 640     if(autocvar_g_fullbrightplayers)
 641         self.effects = self.effects | EF_FULLBRIGHT;
 642
 643     setmodel(self.vehicle_hudmodel, hudmodel);
 644     setmodel(self.vehicle_viewport, "null");
 645
 646
 647     if(topmodel != "")
 648     {
 649         setmodel(self.tur_head, topmodel);
 650         setattachment(self.tur_head, self, toptag);
 651         setattachment(self.vehicle_hudmodel, self.tur_head, hudtag);
 652         setattachment(self.vehicle_viewport, self.vehicle_hudmodel, viewtag);
 653     }
 654     else
 655     {
 656         setattachment(self.tur_head, self, "");
 657         setattachment(self.vehicle_hudmodel, self, hudtag);
 658         setattachment(self.vehicle_viewport, self.vehicle_hudmodel, viewtag);
 659     }
 660
 661     setsize(self, min_s, max_s);
 662     if not (nodrop)
 663     {
 664         setorigin(self, self.origin);
 665         tracebox(self.origin + '0 0 100', min_s, max_s, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
 666         setorigin(self, trace_endpos);
 667     }
 668
 669     self.pos1 = self.origin;
 670     self.pos2 = self.angles;
 671
 672     return TRUE;
 673 }
 674
 675
 676 void bugmenot()
 677 {
 678     self.vehicle_exit       = self.vehicle_exit;
 679     self.vehicle_enter      = self.vehicle_exit;
 680     self.vehicle_die        = self.vehicle_exit;
 681     self.vehicle_spawn      = self.vehicle_exit;
 682     self.AuxiliaryXhair     = self.AuxiliaryXhair;
 683 }