qcsrc/server/vehicles/vehicles.qc

   1 float autocvar_g_vehicles_crush_dmg;
   2 float autocvar_g_vehicles_crush_force;
   3 float autocvar_g_vehicles_delayspawn;
   4 float autocvar_g_vehicles_delayspawn_jitter;
   5
   6 var float autocvar_g_vehicles_vortex_damagerate = 0.5;
   7 var float autocvar_g_vehicles_machinegun_damagerate = 0.5;
   8 var float autocvar_g_vehicles_rifle_damagerate = 0.75;
   9 var float autocvar_g_vehicles_vaporizer_damagerate = 0.001;
  10 var float autocvar_g_vehicles_tag_damagerate = 5;
  11
  12 float autocvar_g_vehicles;
  13
  14 void vehicles_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force);
  15 void vehicles_return();
  16 void vehicles_enter();
  17 void vehicles_touch();
  18 void vehicles_reset_colors();
  19 void vehicles_clearreturn();
  20 void vehicles_setreturn();
  21
  22
  23 /** AuxiliaryXhair*
  24     Send additional points of interest to be drawn, to vehicle owner
  25 **/
  26 const float MAX_AXH = 4;
  27 .entity AuxiliaryXhair[MAX_AXH];
  28
  29 float SendAuxiliaryXhair(entity to, float sf)
  30 {
  31
  32         WriteByte(MSG_ENTITY, ENT_CLIENT_AUXILIARYXHAIR);
  33
  34         WriteByte(MSG_ENTITY, self.cnt);
  35
  36         WriteCoord(MSG_ENTITY, self.origin_x);
  37         WriteCoord(MSG_ENTITY, self.origin_y);
  38         WriteCoord(MSG_ENTITY, self.origin_z);
  39
  40     WriteByte(MSG_ENTITY, rint(self.colormod_x * 255));
  41     WriteByte(MSG_ENTITY, rint(self.colormod_y * 255));
  42     WriteByte(MSG_ENTITY, rint(self.colormod_z * 255));
  43
  44     return TRUE;
  45 }
  46
  47 void UpdateAuxiliaryXhair(entity own, vector loc, vector clr, float axh_id)
  48 {
  49     if (!IS_REAL_CLIENT(own))
  50         return;
  51
  52     entity axh;
  53
  54     axh_id = bound(0, axh_id, MAX_AXH);
  55     axh = own.(AuxiliaryXhair[axh_id]);
  56
  57     if(axh == world || wasfreed(axh))  // MADNESS? THIS IS QQQQCCCCCCCCC (wasfreed, why do you exsist?)
  58     {
  59         axh                     = spawn();
  60         axh.cnt                 = axh_id;
  61         axh.drawonlytoclient    = own;
  62         axh.owner               = own;
  63         Net_LinkEntity(axh, FALSE, 0, SendAuxiliaryXhair);
  64     }
  65
  66     setorigin(axh, loc);
  67     axh.colormod            = clr;
  68     axh.SendFlags           = 0x01;
  69     own.(AuxiliaryXhair[axh_id]) = axh;
  70 }
  71
  72 /*
  73 // SVC_TEMPENTITY based, horrible with even 50 ping. hm.
  74 // WriteByte(MSG_ONE, SVC_TEMPENTITY) uses reliable messagess, never use for thinsg that need continous updates.
  75 void SendAuxiliaryXhair2(entity own, vector loc, vector clr, float axh_id)
  76 {
  77         msgexntity = own;
  78
  79         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  80         WriteByte(MSG_ONE, TE_CSQC_AUXILIARYXHAIR);
  81
  82         WriteByte(MSG_ONE, axh_id);
  83
  84         WriteCoord(MSG_ONE, loc_x);
  85         WriteCoord(MSG_ONE, loc_y);
  86         WriteCoord(MSG_ONE, loc_z);
  87
  88     WriteByte(MSG_ONE, rint(clr_x * 255));
  89     WriteByte(MSG_ONE, rint(clr_y * 255));
  90     WriteByte(MSG_ONE, rint(clr_z * 255));
  91
  92 }
  93 */
  94 // End AuxiliaryXhair
  95
  96 /**
  97     Notifies the client that he enterd a vehicle, and sends
  98     realavent data.
  99
 100     only sends vehicle_id atm (wich is a HUD_* constant, ex. HUD_SPIDERBOT)
 101 **/
 102 void CSQCVehicleSetup(entity own, float vehicle_id)
 103 {
 104     if (!IS_REAL_CLIENT(own))
 105         return;
 106
 107         msg_entity = own;
 108
 109         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 110         WriteByte(MSG_ONE, TE_CSQC_VEHICLESETUP);
 111         if(vehicle_id != 0)
 112             WriteByte(MSG_ONE, vehicle_id);
 113         else
 114         WriteByte(MSG_ONE, 1 + own.vehicle.vehicle_weapon2mode + HUD_VEHICLE_LAST);
 115 }
 116
 117 /** vehicles_locktarget
 118
 119     Generic target locking.
 120
 121     Figure out if what target is "locked" (if any), for missile tracking as such.
 122
 123     after calling, "if(self.lock_target != world && self.lock_strength == 1)" mean
 124     you have a locked in target.
 125
 126     Exspects a crosshair_trace() or equivalent to be
 127     dont before calling.
 128
 129 **/
 130 .entity lock_target;
 131 .float  lock_strength;
 132 .float  lock_time;
 133 .float  lock_soundtime;
 134 const float     DAMAGE_TARGETDRONE = 10;
 135
 136 vector targetdrone_getnewspot()
 137 {
 138
 139         vector spot;
 140         float i;
 141         for(i = 0; i < 100; ++i)
 142         {
 143                 spot = self.origin + randomvec() * 1024;
 144                 tracebox(spot, self.mins, self.maxs, spot, MOVE_NORMAL, self);
 145                 if(trace_fraction == 1.0 && trace_startsolid == 0 && trace_allsolid == 0)
 146                         return spot;
 147         }
 148         return self.origin;
 149 }
 150
 151 #if 0
 152 void targetdrone_think();
 153 void targetdrone_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force);
 154 void targetdrone_renwe()
 155 {
 156         self.think = targetdrone_think;
 157         self.nextthink = time + 0.1;
 158         setorigin(self, targetdrone_getnewspot());
 159         self.health = 200;
 160         self.takedamage = DAMAGE_TARGETDRONE;
 161         self.event_damage = targetdrone_damage;
 162         self.solid = SOLID_BBOX;
 163         setmodel(self, "models/runematch/rune.mdl");
 164         self.effects = EF_LOWPRECISION;
 165         self.scale = 10;
 166         self.movetype = MOVETYPE_BOUNCEMISSILE;
 167         setsize(self, '-100 -100 -100', '100 100 100');
 168
 169 }
 170 void targetdrone_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 171 {
 172         self.health -= damage;
 173         if(self.health <= 0)
 174         {
 175                 pointparticles(particleeffectnum("explosion_medium"), self.origin, '0 0 0', 1);
 176
 177                 if(!self.cnt)
 178                         remove(self);
 179                 else
 180                 {
 181                         self.think = targetdrone_renwe;
 182                         self.nextthink = time + 1 + random() * 2;
 183                         self.solid = SOLID_NOT;
 184                         setmodel(self, "");
 185                 }
 186         }
 187 }
 188 entity targetdrone_getfear()
 189 {
 190         entity fear;
 191         float i;
 192
 193         for(i = 64; i <= 1024; i += 64)
 194         {
 195                 fear = findradius(self.origin, i);
 196                 while(fear)
 197                 {
 198                         if(fear.bot_dodge)
 199                                 return fear;
 200
 201                         fear = fear.chain;
 202                 }
 203         }
 204
 205         return world;
 206 }
 207 void targetdrone_think()
 208 {
 209         self.nextthink = time + 0.1;
 210
 211         if(self.wp00)
 212         if(self.wp00.deadflag != DEAD_NO)
 213                 self.wp00 = targetdrone_getfear();
 214
 215         if(!self.wp00)
 216                 self.wp00 = targetdrone_getfear();
 217
 218         vector newdir;
 219
 220         if(self.wp00)
 221                 newdir = steerlib_push(self.wp00.origin) + randomvec() * 0.75;
 222         else
 223                 newdir = randomvec() * 0.75;
 224
 225         newdir = newdir * 0.5 + normalize(self.velocity) * 0.5;
 226
 227         if(self.wp00)
 228                 self.velocity = normalize(newdir) * (500 + (1024 / min(vlen(self.wp00.origin - self.origin), 1024)) * 700);
 229         else
 230                 self.velocity = normalize(newdir) * 750;
 231
 232         tracebox(self.origin, self.mins, self.maxs, self.origin + self.velocity * 2, MOVE_NORMAL, self);
 233         if(trace_fraction != 1.0)
 234                 self.velocity = self.velocity * -1;
 235
 236         //normalize((normalize(self.velocity) * 0.5 + newdir * 0.5)) * 750;
 237 }
 238
 239 void targetdrone_spawn(vector _where, float _autorenew)
 240 {
 241         entity drone = spawn();
 242         setorigin(drone, _where);
 243         drone.think = targetdrone_renwe;
 244         drone.nextthink = time + 0.1;
 245         drone.cnt = _autorenew;
 246 }
 247 #endif
 248
 249 void vehicles_locktarget(float incr, float decr, float _lock_time)
 250 {
 251     if(self.lock_target && self.lock_target.deadflag != DEAD_NO)
 252     {
 253         self.lock_target    = world;
 254         self.lock_strength  = 0;
 255         self.lock_time      = 0;
 256     }
 257
 258     if(self.lock_time > time)
 259     {
 260         if(self.lock_target)
 261         if(self.lock_soundtime < time)
 262         {
 263             self.lock_soundtime = time + 0.5;
 264             play2(self.owner, "vehicles/locked.wav");
 265         }
 266
 267         return;
 268     }
 269
 270     if(trace_ent != world)
 271     {
 272         if(teamplay && trace_ent.team == self.team)
 273             trace_ent = world;
 274
 275         if(trace_ent.deadflag != DEAD_NO)
 276             trace_ent = world;
 277
 278                 if(!((trace_ent.vehicle_flags & VHF_ISVEHICLE) || (trace_ent.turret_flags & TUR_FLAG_ISTURRET)))
 279             trace_ent = world;
 280     }
 281
 282     if(self.lock_target == world && trace_ent != world)
 283         self.lock_target = trace_ent;
 284
 285     if(self.lock_target && trace_ent == self.lock_target)
 286     {
 287         if(self.lock_strength != 1 && self.lock_strength + incr >= 1)
 288         {
 289             play2(self.owner, "vehicles/lock.wav");
 290             self.lock_soundtime = time + 0.8;
 291         }
 292         else if (self.lock_strength != 1 && self.lock_soundtime < time)
 293         {
 294             play2(self.owner, "vehicles/locking.wav");
 295             self.lock_soundtime = time + 0.3;
 296         }
 297
 298     }
 299
 300     // Have a locking target
 301     // Trace hit current target
 302     if(trace_ent == self.lock_target && trace_ent != world)
 303     {
 304         self.lock_strength = min(self.lock_strength + incr, 1);
 305         if(self.lock_strength == 1)
 306             self.lock_time = time + _lock_time;
 307     }
 308     else
 309     {
 310         if(trace_ent)
 311             self.lock_strength = max(self.lock_strength - decr * 2, 0);
 312         else
 313             self.lock_strength = max(self.lock_strength - decr, 0);
 314
 315         if(self.lock_strength == 0)
 316             self.lock_target = world;
 317     }
 318 }
 319
 320 #define VEHICLE_UPDATE_PLAYER(ply,fld,vhname) \
 321 ply.vehicle_##fld = (self.vehicle_##fld / autocvar_g_vehicle_##vhname##_##fld) * 100
 322
 323 #define vehicles_sweap_collision(orig,vel,dt,acm,mult) \
 324 traceline(orig, orig + vel * dt, MOVE_NORMAL, self); \
 325 if(trace_fraction != 1) \
 326     acm += normalize(self.origin - trace_endpos) * (vlen(vel) * mult)
 327
 328 // Hover movement support
 329 float  force_fromtag_power;
 330 float  force_fromtag_normpower;
 331 vector force_fromtag_origin;
 332 vector vehicles_force_fromtag_hover(string tag_name, float spring_length, float max_power)
 333 {
 334     force_fromtag_origin = gettaginfo(self, gettagindex(self, tag_name));
 335     v_forward  = normalize(v_forward) * -1;
 336     traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, self);
 337
 338     force_fromtag_power = (1 - trace_fraction) * max_power;
 339     force_fromtag_normpower = force_fromtag_power / max_power;
 340
 341     return v_forward  * force_fromtag_power;
 342 }
 343
 344 // Experimental hovermode wich uses attraction/repulstion from surface insted of gravity/repulsion
 345 // Can possibly be use to move abt any surface (inclusing walls/celings)
 346 vector vehicles_force_fromtag_maglev(string tag_name, float spring_length, float max_power)
 347 {
 348
 349     force_fromtag_origin = gettaginfo(self, gettagindex(self, tag_name));
 350     v_forward  = normalize(v_forward) * -1;
 351     traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, self);
 352
 353     // TODO - this may NOT be compatible with wall/celing movement, unhardcode 0.25 (engine count multiplier)
 354     if(trace_fraction == 1.0)
 355     {
 356         force_fromtag_normpower = -0.25;
 357         return '0 0 -200';
 358     }
 359
 360     force_fromtag_power = ((1 - trace_fraction) - trace_fraction) * max_power;
 361     force_fromtag_normpower = force_fromtag_power / max_power;
 362
 363     return v_forward  * force_fromtag_power;
 364 }
 365
 366 // Generic vehile projectile system
 367 void vehicles_projectile_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 368 {
 369     // Ignore damage from oterh projectiles from my owner (dont mess up volly's)
 370     if(inflictor.owner == self.owner)
 371         return;
 372
 373     self.health -= damage;
 374     self.velocity += force;
 375     if(self.health < 1)
 376     {
 377         self.takedamage = DAMAGE_NO;
 378         self.event_damage = func_null;
 379         self.think = self.use;
 380         self.nextthink = time;
 381     }
 382 }
 383
 384 void vehicles_projectile_explode()
 385 {
 386     if(self.owner && other != world)
 387     {
 388         if(other == self.owner.vehicle)
 389             return;
 390
 391         if(other == self.owner.vehicle.tur_head)
 392             return;
 393     }
 394
 395         PROJECTILE_TOUCH;
 396
 397         self.event_damage = func_null;
 398     RadiusDamage (self, self.realowner, self.shot_dmg, 0, self.shot_radius, self, world, self.shot_force, self.totalfrags, other);
 399
 400     remove (self);
 401 }
 402
 403 entity vehicles_projectile(string _mzlfx, string _mzlsound,
 404                            vector _org, vector _vel,
 405                            float _dmg, float _radi, float _force,  float _size,
 406                            float _deahtype, float _projtype, float _health,
 407                            float _cull, float _clianim, entity _owner)
 408 {
 409     entity proj;
 410
 411     proj = spawn();
 412
 413     PROJECTILE_MAKETRIGGER(proj);
 414     setorigin(proj, _org);
 415
 416     proj.shot_dmg         = _dmg;
 417     proj.shot_radius      = _radi;
 418     proj.shot_force       = _force;
 419     proj.totalfrags       = _deahtype;
 420     proj.solid            = SOLID_BBOX;
 421     proj.movetype         = MOVETYPE_FLYMISSILE;
 422     proj.flags            = FL_PROJECTILE;
 423     proj.bot_dodge        = TRUE;
 424     proj.bot_dodgerating  = _dmg;
 425     proj.velocity         = _vel;
 426     proj.touch            = vehicles_projectile_explode;
 427     proj.use              = vehicles_projectile_explode;
 428     proj.owner            = self;
 429     proj.realowner        = _owner;
 430     proj.think            = SUB_Remove;
 431     proj.nextthink        = time + 30;
 432
 433     if(_health)
 434     {
 435         proj.takedamage       = DAMAGE_AIM;
 436         proj.event_damage     = vehicles_projectile_damage;
 437         proj.health           = _health;
 438     }
 439     else
 440         proj.flags           = FL_PROJECTILE | FL_NOTARGET;
 441
 442     if(_mzlsound)
 443         sound (self, CH_WEAPON_A, _mzlsound, VOL_BASE, ATTEN_NORM);
 444
 445     if(_mzlfx)
 446         pointparticles(particleeffectnum(_mzlfx), proj.origin, proj.velocity, 1);
 447
 448
 449     setsize (proj, '-1 -1 -1' * _size, '1 1 1' * _size);
 450
 451     CSQCProjectile(proj, _clianim, _projtype, _cull);
 452
 453     return proj;
 454 }
 455 // End generic vehile projectile system
 456
 457 void vehicles_reset()
 458 {
 459         if(self.owner)
 460         {
 461                 entity oldself = self;
 462                 self = self.owner;
 463                 vehicles_exit(VHEF_RELESE);
 464                 self = oldself;
 465         }
 466         self.alpha      = -1;
 467         self.movetype   = MOVETYPE_NONE;
 468         self.effects    = EF_NODRAW;
 469         self.colormod  = '0 0 0';
 470         self.avelocity = '0 0 0';
 471         self.velocity  = '0 0 0';
 472         self.event_damage = func_null;
 473         self.solid = SOLID_NOT;
 474         self.deadflag = DEAD_NO;
 475
 476         self.touch = func_null;
 477         self.nextthink = 0;
 478         vehicles_setreturn();
 479 }
 480
 481 /** vehicles_spawn
 482     Exetuted for all vehicles on (re)spawn.
 483     Sets defaults for newly spawned units.
 484 **/
 485 void vehicles_spawn()
 486 {
 487     dprint("Spawning vehicle: ", self.netname, "\n");
 488
 489     // De-own & reset
 490     self.vehicle_hudmodel.viewmodelforclient = self;
 491
 492     self.owner              = world;
 493     self.touch              = vehicles_touch;
 494     self.event_damage       = vehicles_damage;
 495     self.reset              = vehicles_reset;
 496     self.iscreature         = TRUE;
 497     self.teleportable       = FALSE; // no teleporting for vehicles, too buggy
 498     self.damagedbycontents      = TRUE;
 499     self.movetype           = MOVETYPE_WALK;
 500     self.solid              = SOLID_SLIDEBOX;
 501     self.takedamage         = DAMAGE_AIM;
 502         self.deadflag           = DEAD_NO;
 503     self.bot_attack         = TRUE;
 504     self.flags              = FL_NOTARGET;
 505     self.avelocity          = '0 0 0';
 506     self.velocity           = '0 0 0';
 507
 508     // Reset locking
 509     self.lock_strength      = 0;
 510     self.lock_target        = world;
 511     self.misc_bulletcounter = 0;
 512
 513     // Return to spawn
 514     self.angles             = self.pos2;
 515     setorigin(self, self.pos1 + '0 0 0');
 516     // Show it
 517     pointparticles(particleeffectnum("teleport"), self.origin + '0 0 64', '0 0 0', 1);
 518
 519     if(self.vehicle_controller)
 520         self.team = self.vehicle_controller.team;
 521
 522     vehicles_reset_colors();
 523     self.vehicle_spawn(VHSF_NORMAL);
 524 }
 525
 526 // Better way of determening whats crushable needed! (fl_crushable?)
 527 float vehicles_crushable(entity e)
 528 {
 529     if(IS_PLAYER(e))
 530         return TRUE;
 531
 532     if(e.flags & FL_MONSTER)
 533         return TRUE;
 534
 535     return FALSE;
 536 }
 537
 538 void vehicles_impact(float _minspeed, float _speedfac, float _maxpain)
 539 {
 540     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 541         return;
 542
 543     if(self.play_time < time)
 544     {
 545         float wc = vlen(self.velocity - self.oldvelocity);
 546         //dprint("oldvel: ", vtos(self.oldvelocity), "\n");
 547         //dprint("vel: ", vtos(self.velocity), "\n");
 548         if(_minspeed < wc)
 549         {
 550             float take = min(_speedfac * wc, _maxpain);
 551             Damage (self, world, world, take, DEATH_FALL, self.origin, '0 0 0');
 552             self.play_time = time + 0.25;
 553
 554             //dprint("wc: ", ftos(wc), "\n");
 555             //dprint("take: ", ftos(take), "\n");
 556         }
 557     }
 558 }
 559
 560 .void() vehicle_impact;
 561 void vehicles_touch()
 562 {
 563         if(MUTATOR_CALLHOOK(VehicleTouch))
 564                 return;
 565
 566     // Vehicle currently in use
 567     if(self.owner)
 568     {
 569         if(other != world)
 570         if(vehicles_crushable(other))
 571         {
 572             if(vlen(self.velocity) != 0)
 573                 Damage(other, self, self.owner, autocvar_g_vehicles_crush_dmg, DEATH_VH_CRUSH, '0 0 0', normalize(other.origin - self.origin) * autocvar_g_vehicles_crush_force);
 574
 575             return; // Dont do selfdamage when hitting "soft targets".
 576         }
 577
 578         if(self.play_time < time)
 579         if(self.vehicle_impact)
 580             self.vehicle_impact();
 581
 582         return;
 583     }
 584
 585     if (!IS_PLAYER(other))
 586         return;
 587
 588     if(other.deadflag != DEAD_NO)
 589         return;
 590
 591     if(other.vehicle != world)
 592         return;
 593
 594     vehicles_enter();
 595 }
 596 var float autocvar_g_vehicles_allow_bots = 0;
 597 void vehicles_enter()
 598 {
 599    // Remove this when bots know how to use vehicles
 600
 601     if (IS_BOT_CLIENT(other))
 602         if (autocvar_g_vehicles_allow_bots)
 603             dprint("Bot enters vehicle\n"); // This is where we need to disconnect (some, all?) normal bot AI and hand over to vehicle's _aiframe()
 604         else
 605             return;
 606
 607     if(self.phase > time)
 608         return;
 609     if(other.frozen)
 610         return;
 611     if(other.vehicle)
 612         return;
 613     if(other.deadflag != DEAD_NO)
 614         return;
 615
 616     if(teamplay)
 617     if(self.team)
 618     if(self.team != other.team)
 619         return;
 620
 621     RemoveGrapplingHook(other);
 622
 623     self.vehicle_ammo1   = 0;
 624     self.vehicle_ammo2   = 0;
 625     self.vehicle_reload1 = 0;
 626     self.vehicle_reload2 = 0;
 627     self.vehicle_energy  = 0;
 628
 629     self.owner          = other;
 630     self.switchweapon   = other.switchweapon;
 631
 632     // .viewmodelforclient works better.
 633     //self.vehicle_hudmodel.drawonlytoclient = self.owner;
 634
 635     self.vehicle_hudmodel.viewmodelforclient = self.owner;
 636
 637     self.event_damage         = vehicles_damage;
 638     self.nextthink            = 0;
 639     self.owner.angles         = self.angles;
 640     self.owner.takedamage     = DAMAGE_NO;
 641     self.owner.solid          = SOLID_NOT;
 642     self.owner.movetype       = MOVETYPE_NOCLIP;
 643     self.owner.alpha          = -1;
 644     self.owner.vehicle        = self;
 645     self.owner.event_damage   = func_null;
 646     self.owner.view_ofs       = '0 0 0';
 647     self.colormap             = self.owner.colormap;
 648     if(self.tur_head)
 649         self.tur_head.colormap    = self.owner.colormap;
 650
 651     self.owner.hud            = self.hud;
 652     self.owner.PlayerPhysplug = self.PlayerPhysplug;
 653
 654     self.owner.vehicle_ammo1    = self.vehicle_ammo1;
 655     self.owner.vehicle_ammo2    = self.vehicle_ammo2;
 656     self.owner.vehicle_reload1  = self.vehicle_reload1;
 657     self.owner.vehicle_reload2  = self.vehicle_reload2;
 658
 659     // Cant do this, hides attached objects too.
 660     //self.exteriormodeltoclient = self.owner;
 661     //self.tur_head.exteriormodeltoclient = self.owner;
 662
 663     other.flags &= ~FL_ONGROUND;
 664     self.flags  &= ~FL_ONGROUND;
 665
 666     self.team                 = self.owner.team;
 667     self.flags               -= FL_NOTARGET;
 668     self.monster_attack       = TRUE;
 669
 670     if (IS_REAL_CLIENT(other))
 671     {
 672         msg_entity = other;
 673         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
 674         WriteEntity(MSG_ONE, self.vehicle_viewport);
 675
 676         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
 677         if(self.tur_head)
 678         {
 679             WriteAngle(MSG_ONE, self.tur_head.angles_x + self.angles_x); // tilt
 680             WriteAngle(MSG_ONE, self.tur_head.angles_y + self.angles_y); // yaw
 681             WriteAngle(MSG_ONE, 0);                                      // roll
 682         }
 683         else
 684         {
 685             WriteAngle(MSG_ONE,  self.angles_x * -1); // tilt
 686             WriteAngle(MSG_ONE,  self.angles_y);      // yaw
 687             WriteAngle(MSG_ONE,  0);                  // roll
 688         }
 689     }
 690
 691     vehicles_clearreturn();
 692
 693     CSQCVehicleSetup(self.owner, self.hud);
 694
 695     vh_player = other;
 696     vh_vehicle = self;
 697     MUTATOR_CALLHOOK(VehicleEnter);
 698     other = vh_player;
 699     self = vh_vehicle;
 700
 701     self.vehicle_enter();
 702     antilag_clear(other);
 703 }
 704
 705 /** vehicles_findgoodexit
 706     Locates a valid location for the player to exit the vehicle.
 707     Will first try prefer_spot, then up 100 random spots arround the vehicle
 708     wich are in direct line of sight and empty enougth to hold a players bbox
 709 **/
 710 vector vehicles_findgoodexit(vector prefer_spot)
 711 {
 712     //vector exitspot;
 713     float mysize;
 714
 715     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, prefer_spot, MOVE_NORMAL, self.owner);
 716     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 717         return prefer_spot;
 718
 719     mysize = 1.5 * vlen(self.maxs - self.mins);
 720     float i;
 721     vector v, v2;
 722     v2 = 0.5 * (self.absmin + self.absmax);
 723     for(i = 0; i < 100; ++i)
 724     {
 725         v = randomvec();
 726         v_z = 0;
 727         v = v2 + normalize(v) * mysize;
 728         tracebox(v2, PL_MIN, PL_MAX, v, MOVE_NORMAL, self.owner);
 729         if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 730             return v;
 731     }
 732
 733     /*
 734     exitspot = (self.origin + '0 0 48') + v_forward * mysize;
 735     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 736     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 737         return exitspot;
 738
 739     exitspot = (self.origin + '0 0 48') - v_forward * mysize;
 740     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 741     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 742         return exitspot;
 743
 744     exitspot = (self.origin + '0 0 48') + v_right * mysize;
 745     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 746     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 747         return exitspot;
 748
 749     exitspot = (self.origin + '0 0 48') - v_right * mysize;
 750     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 751     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 752         return exitspot;
 753     */
 754
 755     return self.origin;
 756 }
 757
 758 /** vehicles_exit
 759     Standarrd vehicle release fucntion.
 760     custom code goes in self.vehicle_exit
 761 **/
 762 float vehicles_exit_running;
 763 void vehicles_exit(float eject)
 764 {
 765     entity _vehicle;
 766     entity _player;
 767     entity _oldself = self;
 768
 769     if(vehicles_exit_running)
 770     {
 771         dprint("^1vehicles_exit allready running! this is not good..\n");
 772         return;
 773     }
 774
 775     vehicles_exit_running = TRUE;
 776     if(IS_CLIENT(self))
 777     {
 778         _vehicle = self.vehicle;
 779
 780         if (_vehicle.vehicle_flags & VHF_PLAYERSLOT)
 781         {
 782             _vehicle.vehicle_exit(eject);
 783             self = _oldself;
 784             vehicles_exit_running = FALSE;
 785             return;
 786         }
 787     }
 788     else
 789         _vehicle = self;
 790
 791     _player = _vehicle.owner;
 792
 793     self = _vehicle;
 794
 795     if (_player)
 796     {
 797         if (IS_REAL_CLIENT(_player))
 798         {
 799             msg_entity = _player;
 800             WriteByte (MSG_ONE, SVC_SETVIEWPORT);
 801             WriteEntity( MSG_ONE, _player);
 802
 803             WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
 804             WriteAngle(MSG_ONE, 0);
 805             WriteAngle(MSG_ONE, _vehicle.angles_y);
 806             WriteAngle(MSG_ONE, 0);
 807         }
 808
 809         setsize(_player, PL_MIN,PL_MAX);
 810
 811         _player.takedamage     = DAMAGE_AIM;
 812         _player.solid          = SOLID_SLIDEBOX;
 813         _player.movetype       = MOVETYPE_WALK;
 814         _player.effects        &= ~EF_NODRAW;
 815         _player.alpha          = 1;
 816         _player.PlayerPhysplug = func_null;
 817         _player.vehicle        = world;
 818         _player.view_ofs       = PL_VIEW_OFS;
 819         _player.event_damage   = PlayerDamage;
 820         _player.hud            = HUD_NORMAL;
 821         _player.switchweapon   = _vehicle.switchweapon;
 822
 823         CSQCVehicleSetup(_player, HUD_NORMAL);
 824     }
 825     _vehicle.flags |= FL_NOTARGET;
 826
 827     if(_vehicle.deadflag == DEAD_NO)
 828         _vehicle.avelocity          = '0 0 0';
 829
 830     _vehicle.tur_head.nodrawtoclient             = world;
 831
 832     if(!teamplay)
 833         _vehicle.team = 0;
 834
 835     vh_player = _player;
 836     vh_vehicle = _vehicle;
 837     MUTATOR_CALLHOOK(VehicleExit);
 838     _player = vh_player;
 839     _vehicle = vh_vehicle;
 840
 841     _vehicle.team = _vehicle.tur_head.team;
 842
 843     sound (_vehicle, CH_TRIGGER_SINGLE, "misc/null.wav", 1, ATTEN_NORM);
 844     _vehicle.vehicle_hudmodel.viewmodelforclient = _vehicle;
 845     _vehicle.phase = time + 1;
 846     _vehicle.monster_attack = FALSE;
 847
 848     _vehicle.vehicle_exit(eject);
 849
 850     vehicles_setreturn();
 851     vehicles_reset_colors();
 852     _vehicle.owner = world;
 853     self = _oldself;
 854
 855     vehicles_exit_running = FALSE;
 856 }
 857
 858
 859 void vehicles_regen(float timer, .float regen_field, float field_max, float rpause, float regen, float delta_time, float _healthscale)
 860 {
 861     if(self.regen_field < field_max)
 862     if(timer + rpause < time)
 863     {
 864         if(_healthscale)
 865             regen = regen * (self.vehicle_health / self.tur_health);
 866
 867         self.regen_field = min(self.regen_field + regen * delta_time, field_max);
 868
 869         if(self.owner)
 870             self.owner.regen_field = (self.regen_field / field_max) * 100;
 871     }
 872 }
 873
 874 void shieldhit_think()
 875 {
 876     self.alpha -= 0.1;
 877     if (self.alpha <= 0)
 878     {
 879         //setmodel(self, "");
 880         self.alpha = -1;
 881         self.effects |= EF_NODRAW;
 882     }
 883     else
 884     {
 885         self.nextthink = time + 0.1;
 886     }
 887 }
 888
 889 void vehicles_painframe()
 890 {
 891     if(self.owner.vehicle_health <= 50)
 892     if(self.pain_frame < time)
 893     {
 894         float _ftmp;
 895         _ftmp = self.owner.vehicle_health / 50;
 896         self.pain_frame = time + 0.1 + (random() * 0.5 * _ftmp);
 897         pointparticles(particleeffectnum("smoke_small"), (self.origin + (randomvec() * 80)), '0 0 0', 1);
 898
 899         if(self.vehicle_flags & VHF_DMGSHAKE)
 900             self.velocity += randomvec() * 30;
 901
 902         if(self.vehicle_flags & VHF_DMGROLL)
 903             if(self.vehicle_flags & VHF_DMGHEADROLL)
 904                 self.tur_head.angles += randomvec();
 905             else
 906                 self.angles += randomvec();
 907
 908     }
 909 }
 910
 911 void vehicles_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 912 {
 913     self.dmg_time = time;
 914
 915         // WEAPONTODO
 916     if(DEATH_ISWEAPON(deathtype, WEP_VORTEX))
 917         damage *= autocvar_g_vehicles_vortex_damagerate;
 918
 919     if(DEATH_ISWEAPON(deathtype, WEP_MACHINEGUN))
 920         damage *= autocvar_g_vehicles_machinegun_damagerate;
 921
 922     if(DEATH_ISWEAPON(deathtype, WEP_RIFLE))
 923         damage *= autocvar_g_vehicles_rifle_damagerate;
 924
 925     if(DEATH_ISWEAPON(deathtype, WEP_VAPORIZER))
 926         damage *= autocvar_g_vehicles_vaporizer_damagerate;
 927
 928     if(DEATH_ISWEAPON(deathtype, WEP_SEEKER))
 929         damage *= autocvar_g_vehicles_tag_damagerate;
 930
 931     self.enemy = attacker;
 932
 933     if((self.vehicle_flags & VHF_HASSHIELD) && (self.vehicle_shield > 0))
 934     {
 935         if (wasfreed(self.vehicle_shieldent) || self.vehicle_shieldent == world)
 936         {
 937             self.vehicle_shieldent = spawn();
 938             self.vehicle_shieldent.effects = EF_LOWPRECISION;
 939
 940             setmodel(self.vehicle_shieldent, "models/vhshield.md3");
 941             setattachment(self.vehicle_shieldent, self, "");
 942             setorigin(self.vehicle_shieldent, real_origin(self) - self.origin);
 943             self.vehicle_shieldent.scale       = 256 / vlen(self.maxs - self.mins);
 944             self.vehicle_shieldent.think       = shieldhit_think;
 945         }
 946
 947         self.vehicle_shieldent.colormod    = '1 1 1';
 948         self.vehicle_shieldent.alpha       = 0.45;
 949         self.vehicle_shieldent.angles      = vectoangles(normalize(hitloc - (self.origin + self.vehicle_shieldent.origin))) - self.angles;
 950         self.vehicle_shieldent.nextthink   = time;
 951         self.vehicle_shieldent.effects &= ~EF_NODRAW;
 952
 953         self.vehicle_shield -= damage;
 954
 955         if(self.vehicle_shield < 0)
 956         {
 957             self.vehicle_health            -= fabs(self.vehicle_shield);
 958             self.vehicle_shieldent.colormod = '2 0 0';
 959             self.vehicle_shield             = 0;
 960             self.vehicle_shieldent.alpha    = 0.75;
 961
 962                 if(sound_allowed(MSG_BROADCAST, attacker))
 963                 spamsound (self, CH_PAIN, "onslaught/ons_hit2.wav", VOL_BASE, ATTEN_NORM);   // FIXME: PLACEHOLDER
 964         }
 965         else
 966                 if(sound_allowed(MSG_BROADCAST, attacker))
 967                 spamsound (self, CH_PAIN, "onslaught/electricity_explode.wav", VOL_BASE, ATTEN_NORM);  // FIXME: PLACEHOLDER
 968
 969     }
 970     else
 971     {
 972         self.vehicle_health -= damage;
 973
 974         if(sound_allowed(MSG_BROADCAST, attacker))
 975             spamsound (self, CH_PAIN, "onslaught/ons_hit2.wav", VOL_BASE, ATTEN_NORM);  // FIXME: PLACEHOLDER
 976     }
 977
 978         if(self.damageforcescale < 1 && self.damageforcescale > 0)
 979                 self.velocity += force * self.damageforcescale;
 980         else
 981                 self.velocity += force;
 982
 983     if(self.vehicle_health <= 0)
 984     {
 985         if(self.owner)
 986             if(self.vehicle_flags & VHF_DEATHEJECT)
 987                 vehicles_exit(VHEF_EJECT);
 988             else
 989                 vehicles_exit(VHEF_RELESE);
 990
 991
 992         antilag_clear(self);
 993
 994         self.vehicle_die();
 995         vehicles_setreturn();
 996     }
 997 }
 998
 999 void vehicles_clearreturn()
1000 {
1001     entity ret;
1002     // Remove "return helper", if any.
1003     ret = findchain(classname, "vehicle_return");
1004     while(ret)
1005     {
1006         if(ret.wp00 == self)
1007         {
1008             ret.classname   = "";
1009             ret.think       = SUB_Remove;
1010             ret.nextthink   = time + 0.1;
1011
1012             if(ret.waypointsprite_attached)
1013                 WaypointSprite_Kill(ret.waypointsprite_attached);
1014
1015             return;
1016         }
1017         ret = ret.chain;
1018     }
1019 }
1020
1021 void vehicles_return()
1022 {
1023     pointparticles(particleeffectnum("teleport"), self.wp00.origin + '0 0 64', '0 0 0', 1);
1024
1025     self.wp00.think     = vehicles_spawn;
1026     self.wp00.nextthink = time;
1027
1028     if(self.waypointsprite_attached)
1029         WaypointSprite_Kill(self.waypointsprite_attached);
1030
1031     remove(self);
1032 }
1033
1034 void vehicles_showwp_goaway()
1035 {
1036     if(self.waypointsprite_attached)
1037         WaypointSprite_Kill(self.waypointsprite_attached);
1038
1039     remove(self);
1040
1041 }
1042
1043 void vehicles_showwp()
1044 {
1045     entity oldself = world;
1046     vector rgb;
1047
1048     if(self.cnt)
1049     {
1050         self.think      = vehicles_return;
1051         self.nextthink  = self.cnt;
1052     }
1053     else
1054     {
1055         self.think      = vehicles_return;
1056         self.nextthink  = time +1;
1057
1058         oldself = self;
1059         self = spawn();
1060         setmodel(self, "null");
1061         self.team = oldself.wp00.team;
1062         self.wp00 = oldself.wp00;
1063         setorigin(self, oldself.wp00.pos1);
1064
1065         self.nextthink = time + 5;
1066         self.think = vehicles_showwp_goaway;
1067     }
1068
1069     if(teamplay && self.team)
1070             rgb = Team_ColorRGB(self.team);
1071     else
1072             rgb = '1 1 1';
1073     WaypointSprite_Spawn("vehicle", 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
1074     if(self.waypointsprite_attached)
1075     {
1076         WaypointSprite_UpdateRule(self.waypointsprite_attached, self.wp00.team, SPRITERULE_DEFAULT);
1077         if(oldself == world)
1078             WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, self.nextthink);
1079         WaypointSprite_Ping(self.waypointsprite_attached);
1080     }
1081
1082     if(oldself != world)
1083         self = oldself;
1084 }
1085
1086 void vehicles_setreturn()
1087 {
1088     entity ret;
1089
1090     vehicles_clearreturn();
1091
1092     ret = spawn();
1093     ret.classname   = "vehicle_return";
1094     ret.wp00       = self;
1095     ret.team        = self.team;
1096     ret.think       = vehicles_showwp;
1097
1098         if(self.deadflag != DEAD_NO)
1099         {
1100                 ret.cnt = max(game_starttime, time) + self.vehicle_respawntime;
1101                 ret.nextthink = max(game_starttime, time) + max(0, self.vehicle_respawntime - 5);
1102         }
1103         else
1104                 ret.nextthink = max(game_starttime, time) + max(0, self.vehicle_respawntime - 1);
1105
1106     setmodel(ret, "null");
1107     setorigin(ret, self.pos1 + '0 0 96');
1108 }
1109
1110 void vehicles_reset_colors()
1111 {
1112     entity e;
1113     float _effects = 0, _colormap;
1114     vector _glowmod, _colormod;
1115
1116     if(autocvar_g_nodepthtestplayers)
1117         _effects |= EF_NODEPTHTEST;
1118
1119     if(autocvar_g_fullbrightplayers)
1120         _effects |= EF_FULLBRIGHT;
1121
1122     if(self.team)
1123         _colormap = 1024 + (self.team - 1) * 17;
1124     else
1125         _colormap = 1024;
1126
1127     _glowmod  = '0 0 0';
1128     _colormod = '0 0 0';
1129
1130     // Find all ents attacked to main model and setup effects, colormod etc.
1131     e = findchainentity(tag_entity, self);
1132     while(e)
1133     {
1134         if(e != self.vehicle_shieldent)
1135         {
1136             e.effects   = _effects; //  | EF_LOWPRECISION;
1137             e.colormod  = _colormod;
1138             e.colormap  = _colormap;
1139             e.alpha     = 1;
1140         }
1141         e = e.chain;
1142     }
1143
1144     self.vehicle_hudmodel.effects  = self.effects  = _effects; // | EF_LOWPRECISION;
1145     self.vehicle_hudmodel.colormod = self.colormod = _colormod;
1146     self.vehicle_hudmodel.colormap = self.colormap = _colormap;
1147     self.vehicle_viewport.effects = (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NOGUNBOB | EF_NOSHADOW | EF_LOWPRECISION | EF_SELECTABLE | EF_TELEPORT_BIT);
1148
1149     self.alpha     = 1;
1150     self.avelocity = '0 0 0';
1151     self.velocity  = '0 0 0';
1152     self.effects   = _effects;
1153 }
1154
1155 void vehicle_use()
1156 {
1157     dprint("vehicle ",self.netname, " used by ", activator.classname, "\n");
1158
1159     self.tur_head.team = activator.team;
1160
1161     if(self.tur_head.team == 0)
1162         self.active = ACTIVE_NOT;
1163     else
1164         self.active = ACTIVE_ACTIVE;
1165
1166     if(self.active == ACTIVE_ACTIVE && self.deadflag == DEAD_NO)
1167     {
1168         dprint("^3Eat shit yall!\n");
1169         vehicles_setreturn();
1170         vehicles_reset_colors();
1171     }
1172     else if(self.active == ACTIVE_NOT && self.deadflag != DEAD_NO)
1173     {
1174
1175     }
1176 }
1177
1178 float vehicle_addplayerslot(    entity _owner,
1179                                 entity _slot,
1180                                 float _hud,
1181                                 string _hud_model,
1182                                 float() _framefunc,
1183                                 void(float) _exitfunc)
1184 {
1185     if (!(_owner.vehicle_flags & VHF_MULTISLOT))
1186         _owner.vehicle_flags |= VHF_MULTISLOT;
1187
1188     _slot.PlayerPhysplug = _framefunc;
1189     _slot.vehicle_exit = _exitfunc;
1190     _slot.hud = _hud;
1191     _slot.vehicle_flags = VHF_PLAYERSLOT;
1192     _slot.vehicle_viewport = spawn();
1193     _slot.vehicle_hudmodel = spawn();
1194     _slot.vehicle_hudmodel.viewmodelforclient = _slot;
1195     _slot.vehicle_viewport.effects = (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NOGUNBOB | EF_NOSHADOW | EF_LOWPRECISION | EF_SELECTABLE | EF_TELEPORT_BIT);
1196
1197     setmodel(_slot.vehicle_hudmodel, _hud_model);
1198     setmodel(_slot.vehicle_viewport, "null");
1199
1200     setattachment(_slot.vehicle_hudmodel, _slot, "");
1201     setattachment(_slot.vehicle_viewport, _slot.vehicle_hudmodel, "");
1202
1203     return TRUE;
1204 }
1205
1206 float vehicle_initialize(string  net_name,
1207                          string  bodymodel,
1208                          string  topmodel,
1209                          string  hudmodel,
1210                          string  toptag,
1211                          string  hudtag,
1212                          string  viewtag,
1213                          float   vhud,
1214                          vector  min_s,
1215                          vector  max_s,
1216                          float   nodrop,
1217                          void(float _spawnflag)  spawnproc,
1218                          float   _respawntime,
1219                          float() physproc,
1220                          void()  enterproc,
1221                          void(float extflag) exitfunc,
1222                          void() dieproc,
1223                          void() thinkproc,
1224                          float  use_csqc,
1225                          float _max_health,
1226                          float _max_shield)
1227 {
1228         if(!autocvar_g_vehicles)
1229                 return FALSE;
1230
1231     if(self.targetname)
1232     {
1233         self.vehicle_controller = find(world, target, self.targetname);
1234         if(!self.vehicle_controller)
1235         {
1236             bprint("^1WARNING: ^7Vehicle with invalid .targetname\n");
1237         }
1238         else
1239         {
1240             self.team = self.vehicle_controller.team;
1241             self.use = vehicle_use;
1242
1243             if(teamplay)
1244             {
1245                 if(self.vehicle_controller.team == 0)
1246                     self.active = ACTIVE_NOT;
1247                 else
1248                     self.active = ACTIVE_ACTIVE;
1249             }
1250         }
1251     }
1252
1253     precache_sound("onslaught/ons_hit2.wav");
1254     precache_sound("onslaught/electricity_explode.wav");
1255
1256
1257     addstat(STAT_HUD, AS_INT,  hud);
1258         addstat(STAT_VEHICLESTAT_HEALTH,  AS_INT, vehicle_health);
1259         addstat(STAT_VEHICLESTAT_SHIELD,  AS_INT, vehicle_shield);
1260         addstat(STAT_VEHICLESTAT_ENERGY,  AS_INT, vehicle_energy);
1261
1262         addstat(STAT_VEHICLESTAT_AMMO1,   AS_INT, vehicle_ammo1);
1263         addstat(STAT_VEHICLESTAT_RELOAD1, AS_INT, vehicle_reload1);
1264
1265         addstat(STAT_VEHICLESTAT_AMMO2,   AS_INT, vehicle_ammo2);
1266         addstat(STAT_VEHICLESTAT_RELOAD2, AS_INT, vehicle_reload2);
1267
1268     if(bodymodel == "")
1269         error("vehicles: missing bodymodel!");
1270
1271     if(hudmodel == "")
1272         error("vehicles: missing hudmodel!");
1273
1274     if(net_name == "")
1275         self.netname = self.classname;
1276     else
1277         self.netname = net_name;
1278
1279     if(self.team && !teamplay)
1280         self.team = 0;
1281
1282     self.vehicle_flags |= VHF_ISVEHICLE;
1283
1284     setmodel(self, bodymodel);
1285
1286     self.vehicle_viewport   = spawn();
1287     self.vehicle_hudmodel   = spawn();
1288     self.tur_head           = spawn();
1289     self.tur_head.owner     = self;
1290     self.takedamage         = DAMAGE_AIM;
1291     self.bot_attack         = TRUE;
1292     self.iscreature         = TRUE;
1293     self.teleportable       = FALSE; // no teleporting for vehicles, too buggy
1294     self.damagedbycontents      = TRUE;
1295     self.hud                = vhud;
1296     self.tur_health          = _max_health;
1297     self.tur_head.tur_health = _max_shield;
1298     self.vehicle_die         = dieproc;
1299     self.vehicle_exit        = exitfunc;
1300     self.vehicle_enter       = enterproc;
1301     self.PlayerPhysplug      = physproc;
1302     self.event_damage        = func_null;
1303     self.touch               = vehicles_touch;
1304     self.think               = vehicles_spawn;
1305     self.vehicle_spawn       = spawnproc;
1306         self.vehicle_respawntime = max(0, _respawntime);
1307     self.effects             = EF_NODRAW;
1308         self.dphitcontentsmask   = DPCONTENTS_BODY | DPCONTENTS_SOLID;
1309         if(!autocvar_g_vehicles_delayspawn || !self.vehicle_respawntime)
1310                 self.nextthink = time;
1311         else
1312                 self.nextthink = max(time, game_starttime) + max(0, self.vehicle_respawntime + ((random() * 2 - 1) * autocvar_g_vehicles_delayspawn_jitter));
1313
1314         if(autocvar_g_playerclip_collisions)
1315                 self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
1316
1317     if(autocvar_g_nodepthtestplayers)
1318         self.effects = self.effects | EF_NODEPTHTEST;
1319
1320     if(autocvar_g_fullbrightplayers)
1321         self.effects = self.effects | EF_FULLBRIGHT;
1322
1323     setmodel(self.vehicle_hudmodel, hudmodel);
1324     setmodel(self.vehicle_viewport, "null");
1325
1326     if(topmodel != "")
1327     {
1328         setmodel(self.tur_head, topmodel);
1329         setattachment(self.tur_head, self, toptag);
1330         setattachment(self.vehicle_hudmodel, self.tur_head, hudtag);
1331         setattachment(self.vehicle_viewport, self.vehicle_hudmodel, viewtag);
1332     }
1333     else
1334     {
1335         setattachment(self.tur_head, self, "");
1336         setattachment(self.vehicle_hudmodel, self, hudtag);
1337         setattachment(self.vehicle_viewport, self.vehicle_hudmodel, viewtag);
1338     }
1339
1340     setsize(self, min_s, max_s);
1341     if (!nodrop)
1342     {
1343         setorigin(self, self.origin);
1344         tracebox(self.origin + '0 0 100', min_s, max_s, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
1345         setorigin(self, trace_endpos);
1346     }
1347
1348     self.pos1 = self.origin;
1349     self.pos2 = self.angles;
1350     self.tur_head.team = self.team;
1351
1352         if(MUTATOR_CALLHOOK(VehicleSpawn))
1353                 return FALSE;
1354
1355     return TRUE;
1356 }
1357
1358 vector vehicle_aimturret(entity _vehic, vector _target, entity _turrret, string _tagname,
1359                          float _pichlimit_min, float _pichlimit_max,
1360                          float _rotlimit_min, float _rotlimit_max, float _aimspeed)
1361 {
1362     vector vtmp, vtag;
1363     float ftmp;
1364     vtag = gettaginfo(_turrret, gettagindex(_turrret, _tagname));
1365     vtmp = vectoangles(normalize(_target - vtag));
1366     vtmp = AnglesTransform_ToAngles(AnglesTransform_LeftDivide(AnglesTransform_FromAngles(_vehic.angles), AnglesTransform_FromAngles(vtmp))) - _turrret.angles;
1367     vtmp = AnglesTransform_Normalize(vtmp, TRUE);
1368     ftmp = _aimspeed * frametime;
1369     vtmp_y = bound(-ftmp, vtmp_y, ftmp);
1370     vtmp_x = bound(-ftmp, vtmp_x, ftmp);
1371     _turrret.angles_y = bound(_rotlimit_min, _turrret.angles_y + vtmp_y, _rotlimit_max);
1372     _turrret.angles_x = bound(_pichlimit_min, _turrret.angles_x + vtmp_x, _pichlimit_max);
1373     return vtag;
1374 }
1375
1376 void vehicles_gib_explode()
1377 {
1378         sound (self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTEN_NORM);
1379         pointparticles(particleeffectnum("explosion_small"), randomvec() * 80 + (self.origin + '0 0 100'), '0 0 0', 1);
1380         remove(self);
1381 }
1382
1383 void vehicles_gib_think()
1384 {
1385         self.alpha -= 0.1;
1386         if(self.cnt >= time)
1387                 remove(self);
1388         else
1389                 self.nextthink = time + 0.1;
1390 }
1391
1392 entity vehicle_tossgib(entity _template, vector _vel, string _tag, float _burn, float _explode, float _maxtime, vector _rot)
1393 {
1394         entity _gib = spawn();
1395         setmodel(_gib, _template.model);
1396         setorigin(_gib, gettaginfo(self, gettagindex(self, _tag)));
1397         _gib.velocity = _vel;
1398         _gib.movetype = MOVETYPE_TOSS;
1399         _gib.solid = SOLID_CORPSE;
1400         _gib.colormod = '-0.5 -0.5 -0.5';
1401         _gib.effects = EF_LOWPRECISION;
1402         _gib.avelocity = _rot;
1403
1404         if(_burn)
1405                 _gib.effects |= EF_FLAME;
1406
1407         if(_explode)
1408         {
1409                 _gib.think = vehicles_gib_explode;
1410                 _gib.nextthink = time + random() * _explode;
1411                 _gib.touch = vehicles_gib_explode;
1412         }
1413         else
1414         {
1415                 _gib.cnt = time + _maxtime;
1416                 _gib.think = vehicles_gib_think;
1417                 _gib.nextthink = time + _maxtime - 1;
1418                 _gib.alpha = 1;
1419         }
1420         return _gib;
1421 }
1422
1423 /*
1424 vector predict_target(entity _targ, vector _from, float _shot_speed)
1425 {
1426     float i;                // loop
1427     float _distance;        // How far to target
1428     float _impact_time;     // How long untill projectile impacts
1429     vector _predict_pos;    // Predicted enemy location
1430     vector _original_origin;// Where target is before predicted
1431
1432      _original_origin = real_origin(_targ); // Typicaly center of target BBOX
1433
1434     _predict_pos = _original_origin;
1435     for(i = 0; i < 4; ++i)  // Loop a few times to increase prediction accuracy (increase loop count if accuracy is to low)
1436     {
1437         _distance = vlen(_predict_pos - _from); // Get distance to previos predicted location
1438         _impact_time = _distance / _shot_speed; // Calculate impact time
1439         _predict_pos = _original_origin + _targ.velocity * _impact_time; // Calculate new predicted location
1440     }
1441
1442     return _predict_pos;
1443 }
1444 */