qcsrc/server/vehicles/vehicles.qc

   1 float autocvar_g_vehicles_crush_dmg;
   2 float autocvar_g_vehicles_crush_force;
   3
   4 void vehicles_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force);
   5 void vehicles_return();
   6 void vehicles_enter();
   7 void vehicles_touch();
   8 void vehicles_reset_colors();
   9 void vehicles_clearrturn();
  10 void vehicles_setreturn();
  11
  12
  13 #define MAX_AXH 4
  14 .entity AuxiliaryXhair[MAX_AXH];
  15
  16 float SendAuxiliaryXhair(entity to, float sf)
  17 {
  18
  19         WriteByte(MSG_ENTITY, ENT_CLIENT_AUXILIARYXHAIR);
  20
  21         WriteByte(MSG_ENTITY, self.cnt);
  22
  23         WriteCoord(MSG_ENTITY, self.origin_x);
  24         WriteCoord(MSG_ENTITY, self.origin_y);
  25         WriteCoord(MSG_ENTITY, self.origin_z);
  26
  27     WriteByte(MSG_ENTITY, rint(self.colormod_x * 255));
  28     WriteByte(MSG_ENTITY, rint(self.colormod_y * 255));
  29     WriteByte(MSG_ENTITY, rint(self.colormod_z * 255));
  30
  31     return TRUE;
  32 }
  33
  34 void UpdateAuxiliaryXhair(entity own, vector loc, vector clr, float axh_id)
  35 {
  36     entity axh;
  37
  38     axh_id = bound(0, axh_id, MAX_AXH);
  39     axh = own.AuxiliaryXhair[axh_id];
  40
  41     if(axh == world || wasfreed(axh))  // MADNESS? THIS IS QQQQCCCCCCCCC (wasfreed, why do you exsist?)
  42     {
  43         axh                     = spawn();
  44         axh.cnt                 = axh_id;
  45         axh.drawonlytoclient    = own;
  46         axh.owner               = own;
  47         Net_LinkEntity(axh, FALSE, 0, SendAuxiliaryXhair);
  48     }
  49
  50     setorigin(axh, loc);
  51     axh.colormod            = clr;
  52     axh.SendFlags           = 0x01;
  53     own.AuxiliaryXhair[axh_id] = axh;
  54 }
  55
  56 /*
  57 // SVC_TEMPENTITY based, horrible with even 50 ping. hm.
  58 // WriteByte(MSG_ONE, SVC_TEMPENTITY) uses reliable messagess, never use for thinsg that need continous updates.
  59 void SendAuxiliaryXhair2(entity own, vector loc, vector clr, float axh_id)
  60 {
  61         msg_entity = own;
  62
  63         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  64         WriteByte(MSG_ONE, TE_CSQC_AUXILIARYXHAIR);
  65
  66         WriteByte(MSG_ONE, axh_id);
  67
  68         WriteCoord(MSG_ONE, loc_x);
  69         WriteCoord(MSG_ONE, loc_y);
  70         WriteCoord(MSG_ONE, loc_z);
  71
  72     WriteByte(MSG_ONE, rint(clr_x * 255));
  73     WriteByte(MSG_ONE, rint(clr_y * 255));
  74     WriteByte(MSG_ONE, rint(clr_z * 255));
  75
  76 }
  77 */
  78
  79 void CSQCVehicleSetup(entity own, float vehicle_id)
  80 {
  81         msg_entity = own;
  82
  83         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  84         WriteByte(MSG_ONE, TE_CSQC_VEHICLESETUP);
  85         WriteByte(MSG_ONE, vehicle_id);
  86 }
  87
  88 .entity lock_target;
  89 .float  lock_strength;
  90 .float  lock_time;
  91 void vehicles_locktarget(float incr, float decr, float _lock_time)
  92 {
  93     if(self.lock_target && self.lock_target.deadflag != DEAD_NO)
  94     {
  95         self.lock_target    = world;
  96         self.lock_strength  = 0;
  97         self.lock_time      = 0;
  98     }
  99
 100     if(self.lock_time > time)
 101         return;
 102
 103     if(trace_ent != world)
 104     {
 105         if(teams_matter && trace_ent.team == self.team)
 106             trace_ent = world;
 107
 108         if(trace_ent.deadflag != DEAD_NO)
 109             trace_ent = world;
 110
 111         if not (trace_ent.vehicle_flags & VHF_ISVEHICLE || trace_ent.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 112             trace_ent = world;
 113     }
 114
 115     if(self.lock_target == world && trace_ent != world)
 116         self.lock_target = trace_ent;
 117
 118     // Have a locking target
 119     // Trace hit current target
 120     if(trace_ent == self.lock_target && trace_ent != world)
 121     {
 122         self.lock_strength = min(self.lock_strength + incr, 1);
 123         if(self.lock_strength == 1)
 124             self.lock_time = time + _lock_time;
 125     }
 126     else
 127     {
 128         if(trace_ent)
 129             self.lock_strength = max(self.lock_strength - decr * 2, 0);
 130         else
 131             self.lock_strength = max(self.lock_strength - decr, 0);
 132
 133         if(self.lock_strength == 0)
 134             self.lock_target = world;
 135     }
 136 }
 137
 138
 139 #define VEHICLE_UPDATE_PLAYER(fld,vhname) \
 140 self.owner.vehicle_##fld = self.vehicle_##fld / autocvar_g_vehicle_##vhname##_##fld
 141
 142 #define vehicles_sweap_collision(orig,vel,dt,acm,mult) \
 143 traceline(orig, orig + vel * dt, MOVE_NORMAL, self); \
 144 if(trace_fraction != 1) \
 145     acm += normalize(self.origin - trace_endpos) * (vlen(vel) * mult)
 146
 147 float  force_fromtag_power;
 148 float  force_fromtag_normpower;
 149 vector force_fromtag_origin;
 150 vector vehicles_force_fromtag_hover(string tag_name, float spring_length, float max_power)
 151 {
 152     force_fromtag_origin = gettaginfo(self, gettagindex(self, tag_name));
 153     v_forward  = normalize(v_forward) * -1;
 154     traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, self);
 155
 156     force_fromtag_power = (1 - trace_fraction) * max_power;
 157     force_fromtag_normpower = force_fromtag_power / max_power;
 158
 159     return v_forward  * force_fromtag_power;
 160 }
 161
 162 vector vehicles_force_fromtag_maglev(string tag_name, float spring_length, float max_power)
 163 {
 164
 165     force_fromtag_origin = gettaginfo(self, gettagindex(self, tag_name));
 166     v_forward  = normalize(v_forward) * -1;
 167     traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, self);
 168
 169     if(trace_fraction == 1.0)
 170     {
 171         force_fromtag_normpower = -0.25;
 172         return '0 0 -200';
 173     }
 174
 175     force_fromtag_power = ((1 - trace_fraction) - trace_fraction) * max_power;
 176     force_fromtag_normpower = force_fromtag_power / max_power;
 177
 178     return v_forward  * force_fromtag_power;
 179 }
 180
 181 void vehicles_projectile_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 182 {
 183     self.health -= damage;
 184     self.velocity += force;
 185     if(self.health < 1)
 186     {
 187         self.takedamage = DAMAGE_NO;
 188         self.event_damage = SUB_Null;
 189         self.think = self.use;
 190         self.nextthink = time;
 191     }
 192
 193 }
 194
 195 void vehicles_projectile_explode()
 196 {
 197     if(self.owner && other != world)
 198     {
 199         if(other == self.owner.vehicle)
 200             return;
 201
 202         if(other == self.owner.vehicle.tur_head)
 203             return;
 204     }
 205
 206         PROJECTILE_TOUCH;
 207
 208         self.event_damage = SUB_Null;
 209     sound (self, CHAN_PROJECTILE, self.target2, VOL_BASE, ATTN_NORM);
 210     pointparticles(particleeffectnum(self.target3), findbetterlocation (self.origin, 16), '0 0 0', 1);
 211     RadiusDamage (self, self.realowner, self.shot_dmg, 0, self.shot_radius, self, self.shot_force, self.totalfrags, other);
 212
 213     remove (self);
 214 }
 215
 216 entity vehicles_projectile(string _impactfx, string _impactsnd, string _mzlfx, string _mzlsound,
 217                            vector _org, vector _vel,
 218                            float _dmg, float _radi, float _force,  float _size,
 219                            float _deahtype, float _projtype, float _health)
 220 {
 221     entity proj;
 222
 223     proj = spawn();
 224
 225     PROJECTILE_MAKETRIGGER(proj);
 226     setorigin(proj, _org);
 227
 228     proj.shot_dmg         = _dmg;
 229     proj.shot_radius      = _radi;
 230     proj.shot_force       = _force;
 231     proj.totalfrags       = _deahtype;
 232     proj.target2          = _impactsnd;
 233     proj.target3          = _impactfx;
 234     proj.solid            = SOLID_BBOX;
 235     proj.movetype         = MOVETYPE_FLYMISSILE;
 236     proj.flags            = FL_PROJECTILE;
 237     proj.bot_dodge        = TRUE;
 238     proj.bot_dodgerating  = _dmg;
 239     proj.velocity         = _vel;
 240     proj.touch            = vehicles_projectile_explode;
 241     proj.use              = vehicles_projectile_explode;
 242     proj.owner            = self;
 243     proj.realowner        = self.owner;
 244     proj.think            = SUB_Remove;
 245     proj.nextthink        = time + 30;
 246
 247     if(_health)
 248     {
 249         proj.takedamage       = DAMAGE_AIM;
 250         proj.event_damage     = vehicles_projectile_damage;
 251         proj.health           = _health;
 252     }
 253     else
 254         proj.flags           = FL_PROJECTILE | FL_NOTARGET;
 255
 256     if(_mzlsound)
 257         sound (self, CHAN_WEAPON, _mzlsound, VOL_BASE, ATTN_NORM);
 258
 259     if(_mzlfx)
 260         pointparticles(particleeffectnum(_mzlfx), proj.origin, proj.velocity, 1);
 261
 262
 263     setsize (proj, '-1 -1 -1' * _size, '1 1 1' * _size);
 264
 265     CSQCProjectile(proj, TRUE, _projtype, TRUE);
 266
 267     return proj;
 268 }
 269
 270 void vehicles_spawn()
 271 {
 272     dprint("Spawning vehicle: ", self.netname, "\n");
 273
 274     // De-own & reset
 275     self.vehicle_hudmodel.viewmodelforclient = self;
 276
 277     self.owner              = world;
 278     self.touch              = vehicles_touch;
 279     self.event_damage       = vehicles_damage;
 280     self.iscreature         = TRUE;
 281     self.movetype           = MOVETYPE_WALK;
 282     self.solid              = SOLID_SLIDEBOX;
 283     self.takedamage         = DAMAGE_AIM;
 284         self.deadflag           = DEAD_NO;
 285     self.bot_attack         = TRUE;
 286     self.flags              = FL_NOTARGET;
 287     self.avelocity          = '0 0 0';
 288
 289     // Reset locking
 290     self.lock_strength      = 0;
 291     self.lock_target        = world;
 292     self.misc_bulletcounter = 0;
 293
 294     // Return to spawn
 295     self.angles             = self.pos2;
 296     setorigin(self, self.pos1 + '0 0 128');
 297     // Show it
 298     pointparticles(particleeffectnum("teleport"), self.origin + '0 0 64', '0 0 0', 1);
 299
 300     vehicles_reset_colors();
 301     self.vehicle_spawn();
 302 }
 303
 304 // Better way of determening whats crushable needed! (fl_crushable?)
 305 float vehicles_crushable(entity e)
 306 {
 307     if(e.classname == "player")
 308         return TRUE;
 309
 310     if(e.classname == "monster_zombie")
 311         return TRUE;
 312
 313     return FALSE;
 314 }
 315
 316 void vehicles_touch()
 317 {
 318     // Vehicle currently in use
 319     if(self.owner)
 320     {
 321         // Colided with world?
 322         if(other == world)
 323         {
 324             // Apply velocity based self damage here
 325         }
 326         else
 327         {
 328             if(other.vehicle_flags & VHF_ISVEHICLE)
 329             {
 330                 //other.velocity += self.velocity * (self.mass / other.mass);
 331             }
 332             else if(vehicles_crushable(other))
 333             {
 334                 if(vlen(self.velocity) != 0)
 335                     Damage(other, self, self.owner, autocvar_g_vehicles_crush_dmg, DEATH_VHCRUSH, '0 0 0', normalize(other.origin - self.origin) * autocvar_g_vehicles_crush_force);
 336             }
 337         }
 338         return;
 339     }
 340
 341     if(other.classname != "player")
 342         return;
 343
 344     if(other.deadflag != DEAD_NO)
 345         return;
 346
 347     if(other.vehicle != world)
 348         return;
 349
 350     // Remove this when bots know how to use vehicles.
 351     if (clienttype(other) != CLIENTTYPE_REAL)
 352         return;
 353
 354     vehicles_enter();
 355 }
 356
 357 void vehicles_enter()
 358 {
 359    // Remove this when bots know how to use vehicles
 360     if (clienttype(other) != CLIENTTYPE_REAL)
 361         return;
 362
 363     if(self.phase > time)
 364         return;
 365
 366     if(teams_matter)
 367     if(self.team)
 368     if(self.team != other.team)
 369         return;
 370
 371     self.vehicle_ammo1   = 0;
 372     self.vehicle_ammo2   = 0;
 373     self.vehicle_reload1 = 0;
 374     self.vehicle_reload2 = 0;
 375     self.vehicle_energy  = 0;
 376
 377     self.owner          = other;
 378     self.switchweapon   = other.switchweapon;
 379
 380     // .viewmodelforclient works better.
 381     //self.vehicle_hudmodel.drawonlytoclient = self.owner;
 382
 383     self.vehicle_hudmodel.viewmodelforclient = self.owner;
 384
 385     self.event_damage         = vehicles_damage;
 386     self.nextthink            = 0;
 387     self.owner.angles         = self.angles;
 388     self.owner.takedamage     = DAMAGE_NO;
 389     self.owner.solid          = SOLID_NOT;
 390     self.owner.movetype       = MOVETYPE_NOCLIP;
 391     self.owner.alpha          = -1;
 392     self.owner.vehicle        = self;
 393     self.owner.event_damage   = SUB_Null;
 394     self.owner.view_ofs       = '0 0 0';
 395     self.colormap             = self.owner.colormap;
 396     if(self.tur_head)
 397         self.tur_head.colormap    = self.owner.colormap;
 398
 399     self.owner.hud            = self.hud;
 400     self.owner.PlayerPhysplug = self.PlayerPhysplug;
 401
 402     self.owner.vehicle_ammo1    = self.vehicle_ammo1;
 403     self.owner.vehicle_ammo2    = self.vehicle_ammo2;
 404     self.owner.vehicle_reload1  = self.vehicle_reload1;
 405     self.owner.vehicle_reload2  = self.vehicle_reload2;
 406
 407     // Cnnt do this, hides attached objects too.
 408     //self.exteriormodeltoclient = self.owner;
 409     //self.tur_head.exteriormodeltoclient = self.owner;
 410
 411     other.flags &~= FL_ONGROUND;
 412     self.flags  &~= FL_ONGROUND;
 413
 414     self.team                 = self.owner.team;
 415     self.flags               -= FL_NOTARGET;
 416
 417     msg_entity = other;
 418     WriteByte (MSG_ONE, SVC_SETVIEWPORT);
 419     WriteEntity(MSG_ONE, self.vehicle_viewport);
 420
 421     WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
 422     if(self.tur_head)
 423     {
 424         WriteAngle(MSG_ONE, self.tur_head.angles_x + self.angles_x); // tilt
 425         WriteAngle(MSG_ONE, self.tur_head.angles_y + self.angles_y); // yaw
 426         WriteAngle(MSG_ONE, 0);                                      // roll
 427     }
 428     else
 429     {
 430         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
 431         WriteAngle(MSG_ONE,  self.angles_x * -1); // tilt
 432         WriteAngle(MSG_ONE,  self.angles_y);      // yaw
 433         WriteAngle(MSG_ONE,  0);                  // roll
 434     }
 435
 436     vehicles_clearrturn();
 437
 438     CSQCVehicleSetup(self.owner, self.hud);
 439
 440     self.vehicle_enter();
 441 }
 442
 443 void vehicles_exit(float eject)
 444 {
 445         self.flags |= FL_NOTARGET;
 446
 447     if (self.owner)
 448     {
 449         msg_entity = self.owner;
 450         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
 451         WriteEntity( MSG_ONE, self.owner);
 452
 453         WriteByte (MSG_ONE, SVC_SETVIEWANGLES); // 10 = SVC_SETVIEWANGLES
 454         WriteAngle(MSG_ONE, 0);                 // tilt
 455         WriteAngle(MSG_ONE, self.angles_y);     // yaw
 456         WriteAngle(MSG_ONE, 0);                 // roll
 457
 458         setsize(self.owner, PL_MIN,PL_MAX);
 459
 460         self.owner.takedamage     = DAMAGE_AIM;
 461         self.owner.solid          = SOLID_SLIDEBOX;
 462         self.owner.movetype       = MOVETYPE_WALK;
 463         self.owner.effects        &~= EF_NODRAW;
 464         self.owner.alpha          = 1;
 465         self.owner.PlayerPhysplug = SUB_Null;
 466         self.owner.vehicle        = world;
 467         self.owner.view_ofs       = PL_VIEW_OFS;
 468         self.owner.event_damage   = PlayerDamage;
 469         self.owner.hud            = HUD_NORMAL;
 470         self.owner.switchweapon   = self.switchweapon;
 471         self.owner.BUTTON_USE     = 0;
 472     }
 473
 474     if(self.deadflag == DEAD_NO)
 475         self.avelocity          = '0 0 0';
 476
 477     self.vehicle_hudmodel.viewmodelforclient = self;
 478         self.tur_head.nodrawtoclient             = world;
 479     vehicles_setreturn();
 480
 481     self.phase = time + 1;
 482
 483     if(!teams_matter)
 484         self.team = 0;
 485
 486     self.vehicle_exit(eject);
 487     self.owner = world;
 488 }
 489
 490
 491 void vehicles_regen(.float timer, .float regen_field, float field_max, float rpause, float regen, float delta_time)
 492 {
 493     if(self.regen_field < field_max)
 494     if(self.timer + rpause < time)
 495     {
 496         self.regen_field = min(self.regen_field + regen * delta_time, field_max);
 497
 498         if(self.owner)
 499             self.owner.regen_field = self.regen_field / field_max;
 500     }
 501 }
 502
 503 void shieldhit_think()
 504 {
 505     self.alpha -= 0.1;
 506     if (self.alpha <= 0)
 507     {
 508         //setmodel(self, "");
 509         self.alpha = -1;
 510     }
 511     else
 512     {
 513         self.nextthink = time + 0.1;
 514     }
 515 }
 516
 517 void vehicles_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 518 {
 519     self.dmg_time = time;
 520
 521     if((self.vehicle_flags & VHF_HASSHIELD) && (self.vehicle_shield > 0))
 522     {
 523         if (wasfreed(self.vehicle_shieldent) || self.vehicle_shieldent == world)
 524         {
 525             self.vehicle_shieldent = spawn();
 526             self.vehicle_shieldent.effects = EF_LOWPRECISION;
 527
 528             setmodel(self.vehicle_shieldent, "models/vhshield.md3");
 529             setattachment(self.vehicle_shieldent, self, "");
 530             setorigin(self.vehicle_shieldent, real_origin(self) - self.origin);
 531             self.vehicle_shieldent.scale       = 256 / vlen(self.maxs - self.mins);
 532             self.vehicle_shieldent.think       = shieldhit_think;
 533         }
 534
 535
 536         self.vehicle_shieldent.colormod    = '1 1 1';
 537         self.vehicle_shieldent.alpha       = 0.45;
 538         self.vehicle_shieldent.angles      = vectoangles(normalize(hitloc - (self.origin + self.vehicle_shieldent.origin))) - self.angles;
 539         self.vehicle_shieldent.nextthink   = time;
 540
 541         self.vehicle_shield -= damage;
 542
 543         if(self.vehicle_shield < 0)
 544         {
 545             self.vehicle_shieldent.colormod = '2 0 0';
 546             self.vehicle_shield             = 0;
 547             self.vehicle_shieldent.alpha    = 0.75;
 548             self.vehicle_health            -= fabs(self.vehicle_shield);
 549         }
 550     }
 551     else
 552         self.vehicle_health -= damage;
 553
 554     self.velocity += force; // * (vlen(force) / self.mass);
 555
 556     if(self.vehicle_health <= 0)
 557     {
 558         if(self.owner)
 559             if(self.vehicle_flags & VHF_DEATHEJECT)
 560                 vehicles_exit(VHEF_EJECT);
 561             else
 562                 vehicles_exit(VHEF_RELESE);
 563
 564         self.vehicle_die();
 565         vehicles_setreturn();
 566     }
 567 }
 568
 569 void vehicles_return()
 570 {
 571     pointparticles(particleeffectnum("teleport"), self.enemy.origin + '0 0 64', '0 0 0', 1);
 572
 573     self.enemy.think     = vehicles_spawn;
 574     self.enemy.nextthink = time;
 575
 576     remove(self);
 577 }
 578
 579 void vehicles_clearrturn()
 580 {
 581     entity ret;
 582     // Remove "return helper", if any.
 583     ret = findchain(classname, "vehicle_return");
 584     while(ret)
 585     {
 586         if(ret.enemy == self)
 587         {
 588             ret.classname   = "";
 589             ret.think       = SUB_Remove;
 590             ret.nextthink   = time + 0.1;
 591             return;
 592         }
 593
 594         ret = ret.chain;
 595     }
 596 }
 597
 598 void vehicles_setreturn()
 599 {
 600     entity ret;
 601
 602     vehicles_clearrturn();
 603
 604     ret = spawn();
 605     ret.classname   = "vehicle_return";
 606     ret.enemy       = self;
 607     ret.think       = vehicles_return;
 608     ret.nextthink   = time + self.vehicle_respawntime;
 609 }
 610
 611 float vehicles_customizeentityforclient()
 612 {
 613     if(self.deadflag  == DEAD_DEAD)
 614         return FALSE;
 615     else
 616         return TRUE;
 617 }
 618
 619 void vehicles_configcheck(string  configname, float check_cvar)
 620 {
 621     if(check_cvar == 0)
 622         localcmd(strcat("exec ", configname, "\n"));
 623 }
 624
 625 void vehicles_reset_colors()
 626 {
 627     entity e;
 628     float _effects, _colormap;
 629     vector _glowmod, _colormod;
 630
 631     if(autocvar_g_nodepthtestplayers)
 632         _effects = EF_NODEPTHTEST;
 633
 634     if(autocvar_g_fullbrightplayers)
 635         _effects |= EF_FULLBRIGHT;
 636
 637     if(self.team)
 638         _colormap = 1024 + (self.team - 1) * 17;
 639     else
 640         _colormap = 1024;
 641
 642     _glowmod    = '0 0 0';
 643     _colormod   = '0 0 0';
 644
 645     // Find all ents attacked to main model and setup effects, colormod etc.
 646     e = findchainentity(tag_entity, self);
 647     while(e)
 648     {
 649         if(e != self.vehicle_shieldent)
 650         {
 651             e.effects   = _effects;
 652             e.colormod  = _colormod;
 653             e.colormap  = _colormap;
 654             e.alpha     = 1;
 655         }
 656         e = e.chain;
 657     }
 658
 659     self.vehicle_hudmodel.effects  = self.effects  = _effects;
 660     self.vehicle_hudmodel.colormod = self.colormod = _colormod;
 661     self.vehicle_hudmodel.colormap = self.colormap = _colormap;
 662
 663     self.alpha          = 1;
 664     self.avelocity      = '0 0 0';
 665     self.velocity       = '0 0 0';
 666
 667 }
 668
 669 //#define VEHICLES_CSQC
 670 #ifdef VEHICLES_CSQC
 671 #define VSF_ORG 2
 672 #define VSF_VEL 4
 673 #define VSF_ANG 8
 674 #define VSF_COLORMAP 16
 675 #define VSF_STAT1 32
 676
 677 float SendVehicle(entity to, float sf)
 678 {
 679         WriteByte(MSG_ENTITY, ENT_CLIENT_VEHICLE_RACER);
 680
 681         WriteByte(MSG_ENTITY, self.cnt);
 682
 683         WriteCoord(MSG_ENTITY, self.origin_x);
 684         WriteCoord(MSG_ENTITY, self.origin_y);
 685         WriteCoord(MSG_ENTITY, self.origin_z);
 686
 687         WriteCoord(MSG_ENTITY, self.velocity_x);
 688         WriteCoord(MSG_ENTITY, self.velocity_y);
 689         WriteCoord(MSG_ENTITY, self.velocity_z);
 690
 691         WriteAngle(MSG_ENTITY, self.angles_x);
 692         WriteAngle(MSG_ENTITY, self.angles_y);
 693         WriteAngle(MSG_ENTITY, self.angles_z);
 694
 695     return TRUE;
 696 }
 697
 698 void NetLinkVehicle()
 699 {
 700     self.SendFlags = 0xFFFFFF;
 701     Net_LinkEntity(self, FALSE, 0, SendVehicle);
 702 }
 703 #endif
 704
 705 float vehicle_initialize(string  net_name,
 706                          string  bodymodel,
 707                          string  topmodel,
 708                          string  hudmodel,
 709                          string  toptag,
 710                          string  hudtag,
 711                          string  viewtag,
 712                          float   vhud,
 713                          vector min_s,
 714                          vector max_s,
 715                          float  nodrop,
 716                          void()  spawnproc,
 717                          float   _respawntime,
 718                          float() physproc,
 719                          void()  enterproc,
 720                          void(float extflag) exitfunc,
 721                          void() dieproc,
 722                          void() thinkproc )
 723 {
 724     addstat(STAT_HUD, AS_INT,  hud);
 725         addstat(STAT_VEHICLESTAT_HEALTH,  AS_FLOAT, vehicle_health);
 726         addstat(STAT_VEHICLESTAT_SHIELD,  AS_FLOAT, vehicle_shield);
 727         addstat(STAT_VEHICLESTAT_ENERGY,  AS_FLOAT, vehicle_energy);
 728
 729         addstat(STAT_VEHICLESTAT_AMMO1,   AS_INT,   vehicle_ammo1);
 730         addstat(STAT_VEHICLESTAT_RELOAD1, AS_FLOAT, vehicle_reload1);
 731
 732         addstat(STAT_VEHICLESTAT_AMMO2,   AS_INT,   vehicle_ammo2);
 733         addstat(STAT_VEHICLESTAT_RELOAD2, AS_FLOAT, vehicle_reload2);
 734
 735     if(bodymodel == "")
 736         error("vehicles: missing bodymodel!");
 737
 738     if(hudmodel == "")
 739         error("vehicles: missing hudmodel!");
 740
 741     if(net_name == "")
 742         self.netname = self.classname;
 743     else
 744         self.netname = net_name;
 745
 746     if(self.team && !teams_matter)
 747         self.team = 0;
 748
 749     self.vehicle_flags |= VHF_ISVEHICLE;
 750
 751     setmodel(self, bodymodel);
 752
 753     self.vehicle_viewport   = spawn();
 754     self.vehicle_hudmodel   = spawn();
 755     self.tur_head           = spawn();
 756     self.tur_head.owner     = self;
 757     self.takedamage         = DAMAGE_AIM;
 758     self.bot_attack         = TRUE;
 759     self.iscreature         = TRUE;
 760     self.hud                = vhud;
 761
 762     //self.customizeentityforclient = vehicles_customizeentityforclient;
 763     self.vehicle_die         = dieproc;
 764     self.vehicle_exit        = exitfunc;
 765     self.vehicle_enter       = enterproc;
 766     self.PlayerPhysplug      = physproc;
 767     self.event_damage        = vehicles_damage;
 768     self.touch               = vehicles_touch;
 769     self.think               = vehicles_spawn;
 770     self.nextthink           = time;
 771     self.vehicle_respawntime = _respawntime;
 772     self.vehicle_spawn       = spawnproc;
 773
 774     if(autocvar_g_nodepthtestplayers)
 775         self.effects = self.effects | EF_NODEPTHTEST;
 776
 777     if(autocvar_g_fullbrightplayers)
 778         self.effects = self.effects | EF_FULLBRIGHT;
 779
 780     setmodel(self.vehicle_hudmodel, hudmodel);
 781     setmodel(self.vehicle_viewport, "null");
 782
 783
 784     if(topmodel != "")
 785     {
 786         setmodel(self.tur_head, topmodel);
 787         setattachment(self.tur_head, self, toptag);
 788         setattachment(self.vehicle_hudmodel, self.tur_head, hudtag);
 789         setattachment(self.vehicle_viewport, self.vehicle_hudmodel, viewtag);
 790     }
 791     else
 792     {
 793         setattachment(self.tur_head, self, "");
 794         setattachment(self.vehicle_hudmodel, self, hudtag);
 795         setattachment(self.vehicle_viewport, self.vehicle_hudmodel, viewtag);
 796     }
 797
 798     setsize(self, min_s, max_s);
 799     if not (nodrop)
 800     {
 801         setorigin(self, self.origin);
 802         tracebox(self.origin + '0 0 100', min_s, max_s, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
 803         setorigin(self, trace_endpos);
 804     }
 805
 806     //self.vehicle_hudmodel.effects = EF_NODEPTHTEST;
 807     self.pos1 = self.origin;
 808     self.pos2 = self.angles;
 809
 810     return TRUE;
 811 }
 812
 813
 814 void bugmenot()
 815 {
 816     self.vehicle_exit       = self.vehicle_exit;
 817     self.vehicle_enter      = self.vehicle_exit;
 818     self.vehicle_die        = self.vehicle_exit;
 819     self.vehicle_spawn      = self.vehicle_exit;
 820     self.AuxiliaryXhair     = self.AuxiliaryXhair;
 821 }