qcsrc/server/w_crylink.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(CRYLINK, w_crylink, IT_CELLS, 6, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_MID, "crylink", "crylink", _("Crylink"));
   3 #else
   4 #ifdef SVQC
   5 .float gravity;
   6 .float crylink_waitrelease;
   7 .entity crylink_lastgroup;
   8
   9 .entity queuenext;
  10 .entity queueprev;
  11
  12 void W_Crylink_CheckLinks(entity e)
  13 {
  14         float i;
  15         entity p;
  16
  17         if(e == world)
  18                 error("W_Crylink_CheckLinks: entity is world");
  19         if(e.classname != "spike" || wasfreed(e))
  20                 error(sprintf("W_Crylink_CheckLinks: entity is not a spike but a %s (freed: %d)", e.classname, wasfreed(e)));
  21
  22         p = e;
  23         for(i = 0; i < 1000; ++i)
  24         {
  25                 if(p.queuenext.queueprev != p || p.queueprev.queuenext != p)
  26                         error("W_Crylink_CheckLinks: queue is inconsistent");
  27                 p = p.queuenext;
  28                 if(p == e)
  29                         break;
  30         }
  31         if(i >= 1000)
  32                 error("W_Crylink_CheckLinks: infinite chain");
  33 }
  34
  35 void W_Crylink_Dequeue_Raw(entity own, entity prev, entity me, entity next)
  36 {
  37         W_Crylink_CheckLinks(next);
  38         if(me == own.crylink_lastgroup)
  39                 own.crylink_lastgroup = ((me == next) ? world : next);
  40         prev.queuenext = next;
  41         next.queueprev = prev;
  42         me.classname = "spike_oktoremove";
  43         if(me != next)
  44                 W_Crylink_CheckLinks(next);
  45 }
  46
  47 void W_Crylink_Dequeue(entity e)
  48 {
  49         W_Crylink_Dequeue_Raw(e.realowner, e.queueprev, e, e.queuenext);
  50 }
  51
  52 // force projectile to explode
  53 void W_Crylink_LinkExplode (entity e, entity e2)
  54 {
  55         float a;
  56         a = bound(0, 1 - (time - e.fade_time) * e.fade_rate, 1);
  57
  58         if(e == e.realowner.crylink_lastgroup)
  59                 e.realowner.crylink_lastgroup = world;
  60
  61         if(e.projectiledeathtype & HITTYPE_SECONDARY)
  62                 RadiusDamage (e, e.realowner, autocvar_g_balance_crylink_secondary_damage * a, autocvar_g_balance_crylink_secondary_edgedamage * a, autocvar_g_balance_crylink_secondary_radius, world, autocvar_g_balance_crylink_secondary_force * a, e.projectiledeathtype, other);
  63         else
  64                 RadiusDamage (e, e.realowner, autocvar_g_balance_crylink_primary_damage * a, autocvar_g_balance_crylink_primary_edgedamage * a, autocvar_g_balance_crylink_primary_radius, world, autocvar_g_balance_crylink_primary_force * a, e.projectiledeathtype, other);
  65
  66         if(e.queuenext != e2)
  67                 W_Crylink_LinkExplode(e.queuenext, e2);
  68
  69         e.classname = "spike_oktoremove";
  70         remove (e);
  71 }
  72
  73 // adjust towards center
  74 // returns the origin where they will meet... and the time till the meeting is
  75 // stored in w_crylink_linkjoin_time.
  76 // could possibly network this origin and time, and display a special particle
  77 // effect when projectiles meet there :P
  78 // jspeed: MINIMUM jing speed
  79 // jtime: MAXIMUM jing time (0: none)
  80 float w_crylink_linkjoin_time;
  81 vector W_Crylink_LinkJoin(entity e, float jspeed, float jtime)
  82 {
  83         vector avg_origin, avg_velocity;
  84         vector targ_origin;
  85         float avg_dist, n;
  86         entity p;
  87
  88         // FIXME remove this debug code
  89         W_Crylink_CheckLinks(e);
  90
  91         w_crylink_linkjoin_time = 0;
  92
  93         avg_origin = e.origin;
  94         avg_velocity = e.velocity;
  95         n = 1;
  96         for(p = e; (p = p.queuenext) != e; )
  97         {
  98                 avg_origin += WarpZone_RefSys_TransformOrigin(p, e, p.origin);
  99                 avg_velocity += WarpZone_RefSys_TransformVelocity(p, e, p.velocity);
 100                 ++n;
 101         }
 102         avg_origin *= (1.0 / n);
 103         avg_velocity *= (1.0 / n);
 104
 105         if(n < 2)
 106                 return avg_origin; // nothing to do
 107
 108         // yes, mathematically we can do this in ONE step, but beware of 32bit floats...
 109         avg_dist = pow(vlen(e.origin - avg_origin), 2);
 110         for(p = e; (p = p.queuenext) != e; )
 111                 avg_dist += pow(vlen(WarpZone_RefSys_TransformOrigin(p, e, p.origin) - avg_origin), 2);
 112         avg_dist *= (1.0 / n);
 113         avg_dist = sqrt(avg_dist);
 114
 115         if(avg_dist == 0)
 116                 return avg_origin; // no change needed
 117
 118         if(jspeed == 0 && jtime == 0)
 119         {
 120                 e.velocity = avg_velocity;
 121                 UpdateCSQCProjectile(e);
 122                 for(p = e; (p = p.queuenext) != e; )
 123                 {
 124                         p.velocity = WarpZone_RefSys_TransformVelocity(e, p, avg_velocity);
 125                         UpdateCSQCProjectile(p);
 126                 }
 127         }
 128         else
 129         {
 130                 if(jtime)
 131                 {
 132                         if(jspeed)
 133                                 w_crylink_linkjoin_time = min(jtime, avg_dist / jspeed);
 134                         else
 135                                 w_crylink_linkjoin_time = jtime;
 136                 }
 137                 else
 138                         w_crylink_linkjoin_time = avg_dist / jspeed;
 139                 targ_origin = avg_origin + w_crylink_linkjoin_time * avg_velocity;
 140
 141                 e.velocity = (targ_origin - e.origin) * (1.0 / w_crylink_linkjoin_time);
 142                 UpdateCSQCProjectile(e);
 143                 for(p = e; (p = p.queuenext) != e; )
 144                 {
 145                         p.velocity = WarpZone_RefSys_TransformVelocity(e, p, (targ_origin - WarpZone_RefSys_TransformOrigin(p, e, p.origin)) * (1.0 / w_crylink_linkjoin_time));
 146                         UpdateCSQCProjectile(p);
 147                 }
 148
 149                 // analysis:
 150                 //   jspeed -> +infinity:
 151                 //      w_crylink_linkjoin_time -> +0
 152                 //      targ_origin -> avg_origin
 153                 //      p->velocity -> HUEG towards center
 154                 //   jspeed -> 0:
 155                 //      w_crylink_linkjoin_time -> +/- infinity
 156                 //      targ_origin -> avg_velocity * +/- infinity
 157                 //      p->velocity -> avg_velocity
 158                 //   jspeed -> -infinity:
 159                 //      w_crylink_linkjoin_time -> -0
 160                 //      targ_origin -> avg_origin
 161                 //      p->velocity -> HUEG away from center
 162         }
 163
 164         W_Crylink_CheckLinks(e);
 165
 166         return targ_origin;
 167 }
 168
 169 void W_Crylink_LinkJoinEffect_Think()
 170 {
 171         // is there at least 2 projectiles very close?
 172         entity e, p;
 173         float n;
 174         e = self.owner.crylink_lastgroup;
 175         n = 0;
 176         if(e)
 177         {
 178                 if(vlen(e.origin - self.origin) < vlen(e.velocity) * frametime)
 179                         ++n;
 180                 for(p = e; (p = p.queuenext) != e; )
 181                 {
 182                         if(vlen(p.origin - self.origin) < vlen(p.velocity) * frametime)
 183                                 ++n;
 184                 }
 185                 if(n >= 2)
 186                 {
 187                         if(e.projectiledeathtype & HITTYPE_SECONDARY)
 188                         {
 189                                 if(autocvar_g_balance_crylink_secondary_joinexplode)
 190                                 {
 191                                         n = n / autocvar_g_balance_crylink_secondary_shots;
 192                                         RadiusDamage (e, e.realowner, autocvar_g_balance_crylink_secondary_joinexplode_damage * n,
 193                                                                         autocvar_g_balance_crylink_secondary_joinexplode_edgedamage * n,
 194                                                                         autocvar_g_balance_crylink_secondary_joinexplode_radius * n, e.realowner,
 195                                                                         autocvar_g_balance_crylink_secondary_joinexplode_force * n, e.projectiledeathtype, other);
 196
 197                                         pointparticles(particleeffectnum("crylink_joinexplode"), self.origin, '0 0 0', n);
 198                                 }
 199                         }
 200                         else
 201                         {
 202                                 if(autocvar_g_balance_crylink_primary_joinexplode)
 203                                 {
 204                                         n = n / autocvar_g_balance_crylink_primary_shots;
 205                                         RadiusDamage (e, e.realowner, autocvar_g_balance_crylink_primary_joinexplode_damage * n,
 206                                                                         autocvar_g_balance_crylink_primary_joinexplode_edgedamage * n,
 207                                                                         autocvar_g_balance_crylink_primary_joinexplode_radius * n, e.realowner,
 208                                                                         autocvar_g_balance_crylink_primary_joinexplode_force * n, e.projectiledeathtype, other);
 209
 210                                         pointparticles(particleeffectnum("crylink_joinexplode"), self.origin, '0 0 0', n);
 211                                 }
 212                         }
 213                 }
 214         }
 215         remove(self);
 216 }
 217
 218 // NO bounce protection, as bounces are limited!
 219 void W_Crylink_Touch (void)
 220 {
 221         float finalhit;
 222         float f;
 223         PROJECTILE_TOUCH;
 224
 225         float a;
 226         a = bound(0, 1 - (time - self.fade_time) * self.fade_rate, 1);
 227
 228         finalhit = ((self.cnt <= 0) || (other.takedamage != DAMAGE_NO));
 229         if(finalhit)
 230                 f = 1;
 231         else
 232                 f = autocvar_g_balance_crylink_primary_bouncedamagefactor;
 233         if(a)
 234                 f *= a;
 235         if (RadiusDamage (self, self.realowner, autocvar_g_balance_crylink_primary_damage * f, autocvar_g_balance_crylink_primary_edgedamage * f, autocvar_g_balance_crylink_primary_radius, world, autocvar_g_balance_crylink_primary_force * f, self.projectiledeathtype, other) && autocvar_g_balance_crylink_primary_linkexplode)
 236         {
 237                 if(self == self.realowner.crylink_lastgroup)
 238                         self.realowner.crylink_lastgroup = world;
 239                 W_Crylink_LinkExplode(self.queuenext, self);
 240                 remove (self);
 241                 return;
 242         }
 243         else if(finalhit)
 244         {
 245                 // just unlink
 246                 W_Crylink_Dequeue(self);
 247                 remove(self);
 248                 return;
 249         }
 250         self.cnt = self.cnt - 1;
 251         self.angles = vectoangles(self.velocity);
 252         self.owner = world;
 253         self.projectiledeathtype |= HITTYPE_BOUNCE;
 254         // commented out as it causes a little hitch...
 255         //if(proj.cnt == 0)
 256         //      CSQCProjectile(proj, TRUE, PROJECTILE_CRYLINK, TRUE);
 257 }
 258
 259 void W_Crylink_Touch2 (void)
 260 {
 261         float finalhit;
 262         float f;
 263         PROJECTILE_TOUCH;
 264
 265         float a;
 266         a = bound(0, 1 - (time - self.fade_time) * self.fade_rate, 1);
 267
 268         finalhit = ((self.cnt <= 0) || (other.takedamage != DAMAGE_NO));
 269         if(finalhit)
 270                 f = 1;
 271         else
 272                 f = autocvar_g_balance_crylink_secondary_bouncedamagefactor;
 273         if(a)
 274                 f *= a;
 275         if (RadiusDamage (self, self.realowner, autocvar_g_balance_crylink_secondary_damage * f, autocvar_g_balance_crylink_secondary_edgedamage * f, autocvar_g_balance_crylink_secondary_radius, world, autocvar_g_balance_crylink_secondary_force * f, self.projectiledeathtype, other) && autocvar_g_balance_crylink_secondary_linkexplode)
 276         {
 277                 if(self == self.realowner.crylink_lastgroup)
 278                         self.realowner.crylink_lastgroup = world;
 279                 W_Crylink_LinkExplode(self.queuenext, self);
 280                 remove (self);
 281                 return;
 282         }
 283         else if(finalhit)
 284         {
 285                 // just unlink
 286                 W_Crylink_Dequeue(self);
 287                 remove(self);
 288                 return;
 289         }
 290         self.cnt = self.cnt - 1;
 291         self.angles = vectoangles(self.velocity);
 292         self.owner = world;
 293         self.projectiledeathtype |= HITTYPE_BOUNCE;
 294         // commented out as it causes a little hitch...
 295         //if(proj.cnt == 0)
 296         //      CSQCProjectile(proj, TRUE, PROJECTILE_CRYLINK, TRUE);
 297 }
 298
 299 void W_Crylink_Fadethink (void)
 300 {
 301         W_Crylink_Dequeue(self);
 302         remove(self);
 303 }
 304
 305 void W_Crylink_Attack (void)
 306 {
 307         local float counter, shots;
 308         local entity proj, prevproj, firstproj;
 309         local vector s;
 310         vector forward, right, up;
 311         float maxdmg;
 312
 313         W_DecreaseAmmo(ammo_cells, autocvar_g_balance_crylink_primary_ammo, autocvar_g_balance_crylink_reload_ammo);
 314
 315         maxdmg = autocvar_g_balance_crylink_primary_damage*autocvar_g_balance_crylink_primary_shots;
 316         maxdmg *= 1 + autocvar_g_balance_crylink_primary_bouncedamagefactor * autocvar_g_balance_crylink_primary_bounces;
 317         if(autocvar_g_balance_crylink_primary_joinexplode)
 318                 maxdmg += autocvar_g_balance_crylink_primary_joinexplode_damage;
 319
 320         W_SetupShot (self, FALSE, 2, "weapons/crylink_fire.wav", CH_WEAPON_A, maxdmg);
 321         forward = v_forward;
 322         right = v_right;
 323         up = v_up;
 324
 325         shots = autocvar_g_balance_crylink_primary_shots;
 326         pointparticles(particleeffectnum("crylink_muzzleflash"), w_shotorg, w_shotdir * 1000, shots);
 327         proj = world;
 328         while (counter < shots)
 329         {
 330                 proj = spawn ();
 331                 proj.realowner = proj.owner = self;
 332                 proj.classname = "spike";
 333                 proj.bot_dodge = TRUE;
 334                 proj.bot_dodgerating = autocvar_g_balance_crylink_primary_damage;
 335                 if(shots == 1) {
 336                         proj.queuenext = proj;
 337                         proj.queueprev = proj;
 338                 }
 339                 else if(counter == 0) { // first projectile, store in firstproj for now
 340                         firstproj = proj;
 341                 }
 342                 else if(counter == shots - 1) { // last projectile, link up with first projectile
 343                         prevproj.queuenext = proj;
 344                         firstproj.queueprev = proj;
 345                         proj.queuenext = firstproj;
 346                         proj.queueprev = prevproj;
 347                 }
 348                 else { // else link up with previous projectile
 349                         prevproj.queuenext = proj;
 350                         proj.queueprev = prevproj;
 351                 }
 352
 353                 prevproj = proj;
 354
 355                 proj.movetype = MOVETYPE_BOUNCEMISSILE;
 356                 PROJECTILE_MAKETRIGGER(proj);
 357                 proj.projectiledeathtype = WEP_CRYLINK;
 358                 //proj.gravity = 0.001;
 359
 360                 setorigin (proj, w_shotorg);
 361                 setsize(proj, '0 0 0', '0 0 0');
 362
 363
 364                 s = '0 0 0';
 365                 if (counter == 0)
 366                         s = '0 0 0';
 367                 else
 368                 {
 369                         makevectors('0 360 0' * (0.75 + (counter - 0.5) / (shots - 1)));
 370                         s_y = v_forward_x;
 371                         s_z = v_forward_y;
 372                 }
 373                 s = s * autocvar_g_balance_crylink_primary_spread * g_weaponspreadfactor;
 374                 W_SetupProjectileVelocityEx(proj, w_shotdir + right * s_y + up * s_z, v_up, autocvar_g_balance_crylink_primary_speed, 0, 0, 0, FALSE);
 375                 proj.touch = W_Crylink_Touch;
 376
 377                 proj.think = W_Crylink_Fadethink;
 378                 if(counter == 0)
 379                 {
 380                         proj.fade_time = time + autocvar_g_balance_crylink_primary_middle_lifetime;
 381                         proj.fade_rate = 1 / autocvar_g_balance_crylink_primary_middle_fadetime;
 382                         proj.nextthink = time + autocvar_g_balance_crylink_primary_middle_lifetime + autocvar_g_balance_crylink_primary_middle_fadetime;
 383                 }
 384                 else
 385                 {
 386                         proj.fade_time = time + autocvar_g_balance_crylink_primary_other_lifetime;
 387                         proj.fade_rate = 1 / autocvar_g_balance_crylink_primary_other_fadetime;
 388                         proj.nextthink = time + autocvar_g_balance_crylink_primary_other_lifetime + autocvar_g_balance_crylink_primary_other_fadetime;
 389                 }
 390                 proj.teleport_time = time + autocvar_g_balance_crylink_primary_joindelay;
 391                 proj.cnt = autocvar_g_balance_crylink_primary_bounces;
 392                 //proj.scale = 1 + 1 * proj.cnt;
 393
 394                 proj.angles = vectoangles (proj.velocity);
 395
 396                 //proj.glow_size = 20;
 397
 398                 proj.flags = FL_PROJECTILE;
 399
 400                 CSQCProjectile(proj, TRUE, (proj.cnt ? PROJECTILE_CRYLINK_BOUNCING : PROJECTILE_CRYLINK), TRUE);
 401
 402                 other = proj; MUTATOR_CALLHOOK(EditProjectile);
 403
 404                 counter = counter + 1;
 405         }
 406         if(autocvar_g_balance_crylink_primary_joinspread != 0 || autocvar_g_balance_crylink_primary_jointime != 0)
 407         {
 408                 self.crylink_lastgroup = proj;
 409                 W_Crylink_CheckLinks(proj);
 410                 self.crylink_waitrelease = 1;
 411         }
 412 }
 413
 414 void W_Crylink_Attack2 (void)
 415 {
 416         local float counter, shots;
 417         local entity proj, prevproj, firstproj;
 418         float maxdmg;
 419
 420         W_DecreaseAmmo(ammo_cells, autocvar_g_balance_crylink_secondary_ammo, autocvar_g_balance_crylink_reload_ammo);
 421
 422         maxdmg = autocvar_g_balance_crylink_secondary_damage*autocvar_g_balance_crylink_secondary_shots;
 423         maxdmg *= 1 + autocvar_g_balance_crylink_secondary_bouncedamagefactor * autocvar_g_balance_crylink_secondary_bounces;
 424         if(autocvar_g_balance_crylink_secondary_joinexplode)
 425                 maxdmg += autocvar_g_balance_crylink_secondary_joinexplode_damage;
 426
 427         W_SetupShot (self, FALSE, 2, "weapons/crylink_fire2.wav", CH_WEAPON_A, maxdmg);
 428
 429         shots = autocvar_g_balance_crylink_secondary_shots;
 430         pointparticles(particleeffectnum("crylink_muzzleflash"), w_shotorg, w_shotdir * 1000, shots);
 431         proj = world;
 432         while (counter < shots)
 433         {
 434                 proj = spawn ();
 435                 proj.realowner = proj.owner = self;
 436                 proj.classname = "spike";
 437                 proj.bot_dodge = TRUE;
 438                 proj.bot_dodgerating = autocvar_g_balance_crylink_secondary_damage;
 439                 if(shots == 1) {
 440                         proj.queuenext = proj;
 441                         proj.queueprev = proj;
 442                 }
 443                 else if(counter == 0) { // first projectile, store in firstproj for now
 444                         firstproj = proj;
 445                 }
 446                 else if(counter == shots - 1) { // last projectile, link up with first projectile
 447                         prevproj.queuenext = proj;
 448                         firstproj.queueprev = proj;
 449                         proj.queuenext = firstproj;
 450                         proj.queueprev = prevproj;
 451                 }
 452                 else { // else link up with previous projectile
 453                         prevproj.queuenext = proj;
 454                         proj.queueprev = prevproj;
 455                 }
 456
 457                 prevproj = proj;
 458
 459                 proj.movetype = MOVETYPE_BOUNCEMISSILE;
 460                 PROJECTILE_MAKETRIGGER(proj);
 461                 proj.projectiledeathtype = WEP_CRYLINK | HITTYPE_SECONDARY;
 462                 //proj.gravity = 0.001;
 463
 464                 setorigin (proj, w_shotorg);
 465                 setsize(proj, '0 0 0', '0 0 0');
 466
 467                 W_SetupProjectileVelocityEx(proj, (w_shotdir + (((counter + 0.5) / shots) * 2 - 1) * v_right * autocvar_g_balance_crylink_secondary_spread * g_weaponspreadfactor), v_up, autocvar_g_balance_crylink_secondary_speed, 0, 0, 0, FALSE);
 468                 proj.touch = W_Crylink_Touch2;
 469                 proj.think = W_Crylink_Fadethink;
 470                 if(counter == (shots - 1) / 2)
 471                 {
 472                         proj.fade_time = time + autocvar_g_balance_crylink_secondary_middle_lifetime;
 473                         proj.fade_rate = 1 / autocvar_g_balance_crylink_secondary_middle_fadetime;
 474                         proj.nextthink = time + autocvar_g_balance_crylink_secondary_middle_lifetime + autocvar_g_balance_crylink_secondary_middle_fadetime;
 475                 }
 476                 else
 477                 {
 478                         proj.fade_time = time + autocvar_g_balance_crylink_secondary_line_lifetime;
 479                         proj.fade_rate = 1 / autocvar_g_balance_crylink_secondary_line_fadetime;
 480                         proj.nextthink = time + autocvar_g_balance_crylink_secondary_line_lifetime + autocvar_g_balance_crylink_secondary_line_fadetime;
 481                 }
 482                 proj.teleport_time = time + autocvar_g_balance_crylink_secondary_joindelay;
 483                 proj.cnt = autocvar_g_balance_crylink_secondary_bounces;
 484                 //proj.scale = 1 + 1 * proj.cnt;
 485
 486                 proj.angles = vectoangles (proj.velocity);
 487
 488                 //proj.glow_size = 20;
 489
 490                 proj.flags = FL_PROJECTILE;
 491
 492                 CSQCProjectile(proj, TRUE, (proj.cnt ? PROJECTILE_CRYLINK_BOUNCING : PROJECTILE_CRYLINK), TRUE);
 493
 494                 other = proj; MUTATOR_CALLHOOK(EditProjectile);
 495
 496                 counter = counter + 1;
 497         }
 498         if(autocvar_g_balance_crylink_secondary_joinspread != 0 || autocvar_g_balance_crylink_secondary_jointime != 0)
 499         {
 500                 self.crylink_lastgroup = proj;
 501                 W_Crylink_CheckLinks(proj);
 502                 self.crylink_waitrelease = 2;
 503         }
 504 }
 505
 506 void spawnfunc_weapon_crylink (void)
 507 {
 508         weapon_defaultspawnfunc(WEP_CRYLINK);
 509 }
 510
 511 float w_crylink(float req)
 512 {
 513         float ammo_amount;
 514         if (req == WR_AIM)
 515         {
 516                 if (random() < 0.10)
 517                         self.BUTTON_ATCK = bot_aim(autocvar_g_balance_crylink_primary_speed, 0, autocvar_g_balance_crylink_primary_middle_lifetime, FALSE);
 518                 else
 519                         self.BUTTON_ATCK2 = bot_aim(autocvar_g_balance_crylink_secondary_speed, 0, autocvar_g_balance_crylink_secondary_middle_lifetime, FALSE);
 520         }
 521         else if (req == WR_THINK)
 522         {
 523                 if(autocvar_g_balance_crylink_reload_ammo && self.clip_load < min(autocvar_g_balance_crylink_primary_ammo, autocvar_g_balance_crylink_secondary_ammo)) // forced reload
 524                         weapon_action(self.weapon, WR_RELOAD);
 525
 526                 if (self.BUTTON_ATCK)
 527                 {
 528                         if (self.crylink_waitrelease != 1)
 529                         if (weapon_prepareattack(0, autocvar_g_balance_crylink_primary_refire))
 530                         {
 531                                 W_Crylink_Attack();
 532                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_crylink_primary_animtime, w_ready);
 533                         }
 534                 }
 535
 536                 if(self.BUTTON_ATCK2 && autocvar_g_balance_crylink_secondary)
 537                 {
 538                         if (self.crylink_waitrelease != 2)
 539                         if (weapon_prepareattack(1, autocvar_g_balance_crylink_secondary_refire))
 540                         {
 541                                 W_Crylink_Attack2();
 542                                 weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_crylink_secondary_animtime, w_ready);
 543                         }
 544                 }
 545
 546                 if ((self.crylink_waitrelease == 1 && !self.BUTTON_ATCK) || (self.crylink_waitrelease == 2 && !self.BUTTON_ATCK2))
 547                 {
 548                         if (!self.crylink_lastgroup || time > self.crylink_lastgroup.teleport_time)
 549                         {
 550                                 // fired and released now!
 551                                 if(self.crylink_lastgroup)
 552                                 {
 553                                         vector pos;
 554                                         entity linkjoineffect;
 555
 556                                         if(self.crylink_waitrelease == 1)
 557                                         {
 558                                                 pos = W_Crylink_LinkJoin(self.crylink_lastgroup, autocvar_g_balance_crylink_primary_joinspread * autocvar_g_balance_crylink_primary_speed, autocvar_g_balance_crylink_primary_jointime);
 559
 560                                         }
 561                                         else
 562                                         {
 563                                                 pos = W_Crylink_LinkJoin(self.crylink_lastgroup, autocvar_g_balance_crylink_secondary_joinspread * autocvar_g_balance_crylink_secondary_speed, autocvar_g_balance_crylink_secondary_jointime);
 564                                         }
 565
 566                                         linkjoineffect = spawn();
 567                                         linkjoineffect.think = W_Crylink_LinkJoinEffect_Think;
 568                                         linkjoineffect.classname = "linkjoineffect";
 569                                         linkjoineffect.nextthink = time + w_crylink_linkjoin_time;
 570                                         linkjoineffect.owner = self;
 571                                         setorigin(linkjoineffect, pos);
 572                                 }
 573                                 self.crylink_waitrelease = 0;
 574                                 if(!w_crylink(WR_CHECKAMMO1) && !w_crylink(WR_CHECKAMMO2))
 575                                 if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 576                                 {
 577                                         // ran out of ammo!
 578                                         self.cnt = WEP_CRYLINK;
 579                                         self.switchweapon = w_getbestweapon(self);
 580                                 }
 581                         }
 582                 }
 583         }
 584         else if (req == WR_PRECACHE)
 585         {
 586                 precache_model ("models/weapons/g_crylink.md3");
 587                 precache_model ("models/weapons/v_crylink.md3");
 588                 precache_model ("models/weapons/h_crylink.iqm");
 589                 precache_sound ("weapons/crylink_fire.wav");
 590                 precache_sound ("weapons/crylink_fire2.wav");
 591                 precache_sound ("weapons/crylink_linkjoin.wav");
 592                 //precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound somewhere else
 593         }
 594         else if (req == WR_SETUP)
 595         {
 596                 weapon_setup(WEP_CRYLINK);
 597                 self.current_ammo = ammo_cells;
 598         }
 599         else if (req == WR_CHECKAMMO1)
 600         {
 601                 // don't "run out of ammo" and switch weapons while waiting for release
 602                 if(self.crylink_lastgroup && self.crylink_waitrelease)
 603                         return TRUE;
 604
 605                 ammo_amount = self.ammo_cells >= autocvar_g_balance_crylink_primary_ammo;
 606                 ammo_amount += self.weapon_load[WEP_CRYLINK] >= autocvar_g_balance_crylink_primary_ammo;
 607                 return ammo_amount;
 608         }
 609         else if (req == WR_CHECKAMMO2)
 610         {
 611                 // don't "run out of ammo" and switch weapons while waiting for release
 612                 if(self.crylink_lastgroup && self.crylink_waitrelease)
 613                         return TRUE;
 614
 615                 ammo_amount = self.ammo_cells >= autocvar_g_balance_crylink_secondary_ammo;
 616                 ammo_amount += self.weapon_load[WEP_CRYLINK] >= autocvar_g_balance_crylink_secondary_ammo;
 617                 return ammo_amount;
 618         }
 619         else if (req == WR_RELOAD)
 620         {
 621                 W_Reload(min(autocvar_g_balance_crylink_primary_ammo, autocvar_g_balance_crylink_secondary_ammo), autocvar_g_balance_crylink_reload_ammo, autocvar_g_balance_crylink_reload_time, "weapons/reload.wav");
 622         }
 623         return TRUE;
 624 };
 625 #endif
 626 #ifdef CSQC
 627 float w_crylink(float req)
 628 {
 629         if(req == WR_IMPACTEFFECT)
 630         {
 631                 vector org2;
 632                 org2 = w_org + w_backoff * 2;
 633                 if(w_deathtype & HITTYPE_SECONDARY)
 634                 {
 635                         pointparticles(particleeffectnum("crylink_impact"), org2, '0 0 0', 1);
 636                         if(!w_issilent)
 637                                 sound(self, CH_SHOTS, "weapons/crylink_impact2.wav", VOL_BASE, ATTN_NORM);
 638                 }
 639                 else
 640                 {
 641                         pointparticles(particleeffectnum("crylink_impactbig"), org2, '0 0 0', 1);
 642                         if(!w_issilent)
 643                                 sound(self, CH_SHOTS, "weapons/crylink_impact.wav", VOL_BASE, ATTN_NORM);
 644                 }
 645         }
 646         else if(req == WR_PRECACHE)
 647         {
 648                 precache_sound("weapons/crylink_impact2.wav");
 649                 precache_sound("weapons/crylink_impact.wav");
 650         }
 651         else if (req == WR_SUICIDEMESSAGE)
 652         {
 653                 w_deathtypestring = _("%s succeeded at self-destructing themself with the Crylink");
 654         }
 655         else if (req == WR_KILLMESSAGE)
 656         {
 657                 if(w_deathtype & HITTYPE_BOUNCE)
 658                         w_deathtypestring = _("%s could not hide from %s's Crylink"); // unchecked: SPLASH (SECONDARY can't be)
 659                 else if(w_deathtype & HITTYPE_SPLASH)
 660                         w_deathtypestring = _("%s was too close to %s's Crylink"); // unchecked: SECONDARY
 661                 else
 662                         w_deathtypestring = _("%s took a close look at %s's Crylink"); // unchecked: SECONDARY
 663         }
 664         return TRUE;
 665 }
 666 #endif
 667 #endif