qcsrc/server/w_grenadelauncher.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(GRENADE_LAUNCHER, w_glauncher, IT_ROCKETS, 4, WEP_FLAG_NORMAL | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_MID, "gl", "grenadelauncher", "Mortar");
   3 #else
   4 #ifdef SVQC
   5 void W_Grenade_Explode (void)
   6 {
   7         if(other.takedamage == DAMAGE_AIM)
   8                 if(other.classname == "player")
   9                         if(IsDifferentTeam(self.owner, other))
  10                                 if(other.deadflag == DEAD_NO)
  11                                         if(IsFlying(other))
  12                                                 AnnounceTo(self.owner, "airshot");
  13
  14         self.event_damage = SUB_Null;
  15         self.takedamage = DAMAGE_NO;
  16         RadiusDamage (self, self.owner, cvar("g_balance_grenadelauncher_primary_damage"), cvar("g_balance_grenadelauncher_primary_edgedamage"), cvar("g_balance_grenadelauncher_primary_radius"), world, cvar("g_balance_grenadelauncher_primary_force"), self.projectiledeathtype, other);
  17
  18         remove (self);
  19 }
  20
  21 void W_Grenade_Explode2 (void)
  22 {
  23         if(other.takedamage == DAMAGE_AIM)
  24                 if(other.classname == "player")
  25                         if(IsDifferentTeam(self.owner, other))
  26                                 if(IsFlying(other))
  27                                         AnnounceTo(self.owner, "airshot");
  28
  29         self.event_damage = SUB_Null;
  30         self.takedamage = DAMAGE_NO;
  31         RadiusDamage (self, self.owner, cvar("g_balance_grenadelauncher_secondary_damage"), cvar("g_balance_grenadelauncher_secondary_edgedamage"), cvar("g_balance_grenadelauncher_secondary_radius"), world, cvar("g_balance_grenadelauncher_secondary_force"), self.projectiledeathtype, other);
  32
  33         remove (self);
  34 }
  35
  36 void W_Grenade_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
  37 {
  38         if (self.health <= 0)
  39                 return;
  40         self.health = self.health - damage;
  41         if (self.health <= 0)
  42         {
  43                 W_PrepareExplosionByDamage(attacker, self.think);
  44         }
  45 }
  46
  47 void W_Grenade_Touch1 (void)
  48 {
  49         PROJECTILE_TOUCH;
  50         if(cvar("g_balance_grenadelauncher_primary_sticky") && other.takedamage != DAMAGE_AIM)
  51         {
  52                 spamsound (self, CHAN_PROJECTILE, "weapons/grenade_stick.wav", VOL_BASE, ATTN_NORM);
  53
  54                 // let it stick whereever it is
  55                 self.velocity = '0 0 0';
  56                 self.movetype = MOVETYPE_NONE; // also disables gravity
  57                 UpdateCSQCProjectile(self);
  58
  59                 // do not respond to any more touches
  60                 self.solid = SOLID_NOT;
  61
  62                 self.nextthink = min(self.nextthink, time + cvar("g_balance_grenadelauncher_primary_lifetime2"));
  63         }
  64         else
  65                 W_Grenade_Explode ();
  66 }
  67
  68 void W_Grenade_Touch2 (void)
  69 {
  70         PROJECTILE_TOUCH;
  71         if (other.takedamage == DAMAGE_AIM)
  72         {
  73                 self.use ();
  74         }
  75         else
  76         {
  77                 float r;
  78                 r = random() * 6;
  79                 if(r < 1)
  80                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce1.wav", VOL_BASE, ATTN_NORM);
  81                 else if(r < 2)
  82                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce2.wav", VOL_BASE, ATTN_NORM);
  83                 else if(r < 3)
  84                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce3.wav", VOL_BASE, ATTN_NORM);
  85                 else if(r < 4)
  86                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce4.wav", VOL_BASE, ATTN_NORM);
  87                 else if(r < 5)
  88                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce5.wav", VOL_BASE, ATTN_NORM);
  89                 else
  90                         spamsound (self, CHAN_PROJECTILE, "weapons/grenade_bounce6.wav", VOL_BASE, ATTN_NORM);
  91                 self.projectiledeathtype |= HITTYPE_BOUNCE;
  92         }
  93 }
  94
  95 void W_Grenade_Attack (void)
  96 {
  97         local entity gren;
  98
  99         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 100                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_grenadelauncher_primary_ammo");
 101         W_SetupShot_ProjectileSize (self, '0 0 -3', '0 0 -3', FALSE, 4, "weapons/grenade_fire.wav", cvar("g_balance_grenadelauncher_primary_damage"));
 102         w_shotdir = v_forward; // no TrueAim for grenades please
 103
 104         pointparticles(particleeffectnum("grenadelauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 105
 106         gren = spawn ();
 107         gren.owner = self;
 108         gren.classname = "grenade";
 109         gren.bot_dodge = TRUE;
 110         gren.bot_dodgerating = cvar("g_balance_grenadelauncher_primary_damage");
 111         gren.movetype = MOVETYPE_BOUNCE;
 112         PROJECTILE_MAKETRIGGER(gren);
 113         gren.projectiledeathtype = WEP_GRENADE_LAUNCHER;
 114         setorigin(gren, w_shotorg);
 115         setsize(gren, '0 0 -3', '0 0 -3');
 116
 117         gren.nextthink = time + cvar("g_balance_grenadelauncher_primary_lifetime");
 118         gren.think = adaptor_think2use_hittype_splash;
 119         gren.use = W_Grenade_Explode;
 120         gren.touch = W_Grenade_Touch1;
 121
 122         gren.takedamage = DAMAGE_YES;
 123         gren.health = cvar("g_balance_grenadelauncher_primary_health");
 124         gren.event_damage = W_Grenade_Damage;
 125         W_SETUPPROJECTILEVELOCITY_UP(gren, g_balance_grenadelauncher_primary);
 126
 127         gren.angles = vectoangles (gren.velocity);
 128         gren.flags = FL_PROJECTILE;
 129
 130         CSQCProjectile(gren, TRUE, PROJECTILE_GRENADE, TRUE);
 131 }
 132
 133 void W_Grenade_Attack2 (void)
 134 {
 135         local entity gren;
 136
 137         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 138                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_grenadelauncher_secondary_ammo");
 139         W_SetupShot_ProjectileSize (self, '0 0 -3', '0 0 -3', FALSE, 4, "weapons/grenade_fire.wav", cvar("g_balance_grenadelauncher_secondary_damage"));
 140         w_shotdir = v_forward; // no TrueAim for grenades please
 141
 142         pointparticles(particleeffectnum("grenadelauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 143
 144         gren = spawn ();
 145         gren.owner = self;
 146         gren.classname = "grenade";
 147         gren.bot_dodge = TRUE;
 148         gren.bot_dodgerating = cvar("g_balance_grenadelauncher_secondary_damage");
 149         gren.movetype = MOVETYPE_BOUNCE;
 150         gren.bouncefactor = cvar("g_balance_grenadelauncher_secondary_bouncefactor");
 151         gren.bouncestop = cvar("g_balance_grenadelauncher_secondary_bouncestop");
 152         PROJECTILE_MAKETRIGGER(gren);
 153         gren.projectiledeathtype = WEP_GRENADE_LAUNCHER | HITTYPE_SECONDARY;
 154         setorigin(gren, w_shotorg);
 155         setsize(gren, '0 0 -3', '0 0 -3');
 156
 157         gren.nextthink = time + cvar("g_balance_grenadelauncher_secondary_lifetime");
 158         gren.think = adaptor_think2use_hittype_splash;
 159         gren.use = W_Grenade_Explode2;
 160         gren.touch = W_Grenade_Touch2;
 161
 162         gren.takedamage = DAMAGE_YES;
 163         gren.health = cvar("g_balance_grenadelauncher_secondary_health");
 164         gren.damageforcescale = cvar("g_balance_grenadelauncher_secondary_damageforcescale");
 165         gren.event_damage = W_Grenade_Damage;
 166         W_SETUPPROJECTILEVELOCITY_UP(gren, g_balance_grenadelauncher_secondary);
 167
 168         gren.angles = vectoangles (gren.velocity);
 169         gren.flags = FL_PROJECTILE;
 170
 171         CSQCProjectile(gren, TRUE, PROJECTILE_GRENADE_BOUNCING, TRUE);
 172 }
 173
 174 void spawnfunc_weapon_grenadelauncher (void)
 175 {
 176         weapon_defaultspawnfunc(WEP_GRENADE_LAUNCHER);
 177 }
 178
 179 .float bot_secondary_grenademooth;
 180 float w_glauncher(float req)
 181 {
 182         if (req == WR_AIM)
 183         {
 184                 self.BUTTON_ATCK = FALSE;
 185                 self.BUTTON_ATCK2 = FALSE;
 186                 if (self.bot_secondary_grenademooth == 0)
 187                 {
 188                         if(bot_aim(cvar("g_balance_grenadelauncher_primary_speed"), cvar("g_balance_grenadelauncher_primary_speed_up"), cvar("g_balance_grenadelauncher_primary_lifetime"), TRUE))
 189                         {
 190                                 self.BUTTON_ATCK = TRUE;
 191                                 if(random() < 0.01) self.bot_secondary_grenademooth = 1;
 192                         }
 193                 }
 194                 else
 195                 {
 196                         if(bot_aim(cvar("g_balance_grenadelauncher_secondary_speed"), cvar("g_balance_grenadelauncher_secondary_speed_up"), cvar("g_balance_grenadelauncher_secondary_lifetime"), TRUE))
 197                         {
 198                                 self.BUTTON_ATCK2 = TRUE;
 199                                 if(random() < 0.02) self.bot_secondary_grenademooth = 0;
 200                         }
 201                 }
 202         }
 203         else if (req == WR_THINK)
 204         {
 205                 if (self.BUTTON_ATCK)
 206                 if (weapon_prepareattack(0, cvar("g_balance_grenadelauncher_primary_refire")))
 207                 {
 208                         if(cvar("g_balance_grenadelauncher_primary2secondary"))
 209                                 W_Grenade_Attack2();
 210                         else
 211                                 W_Grenade_Attack();
 212                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_grenadelauncher_primary_animtime"), w_ready);
 213                 }
 214                 if (self.BUTTON_ATCK2 && !cvar("g_balance_grenadelauncher_primary2secondary"))
 215                 if (weapon_prepareattack(1, cvar("g_balance_grenadelauncher_secondary_refire")))
 216                 {
 217                         W_Grenade_Attack2();
 218                         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_grenadelauncher_secondary_animtime"), w_ready);
 219                 }
 220         }
 221         else if (req == WR_PRECACHE)
 222         {
 223                 precache_model ("models/weapons/g_gl.md3");
 224                 precache_model ("models/weapons/v_gl.md3");
 225                 precache_model ("models/weapons/h_gl.iqm");
 226                 precache_sound ("weapons/grenade_bounce1.wav");
 227                 precache_sound ("weapons/grenade_bounce2.wav");
 228                 precache_sound ("weapons/grenade_bounce3.wav");
 229                 precache_sound ("weapons/grenade_bounce4.wav");
 230                 precache_sound ("weapons/grenade_bounce5.wav");
 231                 precache_sound ("weapons/grenade_bounce6.wav");
 232                 precache_sound ("weapons/grenade_stick.wav");
 233                 precache_sound ("weapons/grenade_fire.wav");
 234         }
 235         else if (req == WR_SETUP)
 236                 weapon_setup(WEP_GRENADE_LAUNCHER);
 237         else if (req == WR_CHECKAMMO1)
 238                 return self.ammo_rockets >= cvar("g_balance_grenadelauncher_primary_ammo");
 239         else if (req == WR_CHECKAMMO2)
 240                 return self.ammo_rockets >= cvar("g_balance_grenadelauncher_secondary_ammo");
 241         return TRUE;
 242 };
 243 #endif
 244 #ifdef CSQC
 245 float w_glauncher(float req)
 246 {
 247         if(req == WR_IMPACTEFFECT)
 248         {
 249                 vector org2;
 250                 org2 = w_org + w_backoff * 12;
 251                 pointparticles(particleeffectnum("grenade_explode"), org2, '0 0 0', 1);
 252                 if(!w_issilent)
 253                         sound(self, CHAN_PROJECTILE, "weapons/grenade_impact.wav", VOL_BASE, ATTN_NORM);
 254         }
 255         else if(req == WR_PRECACHE)
 256         {
 257                 precache_sound("weapons/grenade_impact.wav");
 258         }
 259         else if (req == WR_SUICIDEMESSAGE)
 260         {
 261                 if(w_deathtype & HITTYPE_SECONDARY)
 262                         w_deathtypestring = "tried out his own grenade";
 263                 else
 264                         w_deathtypestring = "detonated";
 265         }
 266         else if (req == WR_KILLMESSAGE)
 267         {
 268                 if(w_deathtype & HITTYPE_SPLASH)
 269                         if(w_deathtype & HITTYPE_BOUNCE) // (must be secondary then)
 270                                 w_deathtypestring = "didn't see #'s grenade";
 271                         else // unchecked: SECONDARY
 272                                 w_deathtypestring = "almost dodged #'s grenade";
 273                 else // unchecked: SECONDARY, BOUNCE
 274                         w_deathtypestring = "ate #'s grenade";
 275         }
 276         return TRUE;
 277 }
 278 #endif
 279 #endif